ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg )
  16 import DsMonad
  17 import DsUtils
  18
  19 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  20 import HsDecls          ( extNameStatic )
  21 import CallConv
  22 import TcHsSyn          ( TypecheckedForeignDecl )
  23 import CoreUtils        ( exprType, mkInlineMe )
  24 import DataCon          ( DataCon, dataConWrapId )
  25 import Id               ( Id, idType, idName, mkWildId, mkVanillaId, mkSysLocal )
  26 import MkId             ( mkWorkerId )
  27 import Literal          ( Literal(..) )
  28 import Module           ( Module, moduleUserString )
  29 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  30                           mkForeignExportOcc, isLocalName,
  31                           NamedThing(..), Provenance(..), ExportFlag(..)
  32                         )
  33 import PrelInfo         ( deRefStablePtr_NAME, returnIO_NAME, bindIO_NAME, makeStablePtr_NAME )
  34 import Type             ( unUsgTy,
  35                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  36                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  37                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  38                         )
  39 import PprType          ( {- instance Outputable Type -} )
  40 import PrimOp           ( PrimOp(..), CCall(..), CCallTarget(..) )
  41 import Var              ( TyVar )
  42 import TysPrim          ( realWorldStatePrimTy, addrPrimTy )
  43 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  44                           unboxedTupleCon, addrDataCon
  45                         )
  46 import Unique
  47 import Maybes           ( maybeToBool )
  48 import Outputable
  49 \end{code}
  50
  51 Desugaring of @foreign@ declarations is naturally split up into
  52 parts, an @import@ and an @export@  part. A @foreign import@
  53 declaration
  54 \begin{verbatim}
  55   foreign import cc nm f :: prim_args -> IO prim_res
  56 \end{verbatim}
  57 is the same as
  58 \begin{verbatim}
  59   f :: prim_args -> IO prim_res
  60   f a1 ... an = _ccall_ nm cc a1 ... an
  61 \end{verbatim}
  62 so we reuse the desugaring code in @DsCCall@ to deal with these.
  63
  64 \begin{code}
  65 dsForeigns :: Module
  66            -> [TypecheckedForeignDecl]
  67            -> DsM ( [CoreBind]        -- desugared foreign imports
  68                   , [CoreBind]        -- helper functions for foreign exports
  69                   , SDoc              -- Header file prototypes for
  70                                       -- "foreign exported" functions.
  71                   , SDoc              -- C stubs to use when calling
  72                                       -- "foreign exported" functions.
  73                   )
  74 dsForeigns mod_name fos = foldlDs combine ([],[],empty,empty) fos
  75  where
  76   combine (acc_fi, acc_fe, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  77     | isForeignImport =   -- foreign import (dynamic)?
  78         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  79         returnDs (bs ++ acc_fi, acc_fe, acc_h, acc_c)
  80     | isForeignLabel =
  81         dsFLabel i ext_nm `thenDs` \ b ->
  82         returnDs (b:acc_fi, acc_fe, acc_h, acc_c)
  83     | isDynamicExtName ext_nm =
  84         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (fi,fe,h,c) ->
  85         returnDs (fi:acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  86
  87     | otherwise        =  -- foreign export
  88         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (fe,h,c) ->
  89         returnDs (acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  90    where
  91     isForeignImport =
  92         case imp_exp of
  93           FoImport _ -> True
  94           _          -> False
  95
  96     isForeignLabel =
  97         case imp_exp of
  98           FoLabel -> True
  99           _       -> False
 100
 101     (FoImport uns)   = imp_exp
 102
 103 \end{code}
 104
 105 Desugaring foreign imports is just the matter of creating a binding
 106 that on its RHS unboxes its arguments, performs the external call
 107 (using the @CCallOp@ primop), before boxing the result up and returning it.
 108
 109 However, we create a worker/wrapper pair, thus:
 110
 111         foreign import f :: Int -> IO Int
 112 ==>
 113         f x = IO ( \s -> case x of { I# x# ->
 114                          case fw s x# of { (# s1, y# #) ->
 115                          (# s1, I# y# #)}})
 116
 117         fw s x# = ccall f s x#
 118
 119 The strictness/CPR analyser won't do this automatically because it doesn't look
 120 inside returned tuples; but inlining this wrapper is a Really Good Idea
 121 because it exposes the boxing to the call site.
 122
 123
 124 \begin{code}
 125 dsFImport :: Id
 126           -> Type               -- Type of foreign import.
 127           -> Bool               -- True <=> might cause Haskell GC
 128           -> ExtName
 129           -> CallConv
 130           -> DsM [CoreBind]
 131 dsFImport fn_id ty may_not_gc ext_name cconv
 132   = let
 133         (tvs, fun_ty)        = splitForAllTys ty
 134         (arg_tys, io_res_ty) = splitFunTys fun_ty
 135     in
 136     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 137     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 138     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 139
 140     (case ext_name of
 141        Dynamic       -> getUniqueDs `thenDs` \ u ->
 142                         returnDs (DynamicTarget u)
 143        ExtName fs _  -> returnDs (StaticTarget fs))     `thenDs` \ lbl ->
 144
 145     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 146     getUniqueDs                                         `thenDs` \ work_uniq ->
 147     let
 148         -- Build the worker
 149         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 150         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 151         the_ccall     = CCall lbl False (not may_not_gc) cconv
 152         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 153         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 154         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 155
 156         -- Build the wrapper
 157         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 158         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 159         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 160     in
 161     returnDs [NonRec fn_id wrap_rhs, NonRec work_id work_rhs]
 162 \end{code}
 163
 164 Foreign labels
 165
 166 \begin{code}
 167 dsFLabel :: Id -> ExtName -> DsM CoreBind
 168 dsFLabel nm ext_name = returnDs (NonRec nm fo_rhs)
 169   where
 170    fo_rhs = mkConApp addrDataCon [mkLit (MachLitLit enm addrPrimTy)]
 171    enm    = extNameStatic ext_name
 172 \end{code}
 173
 174 The function that does most of the work for `@foreign export@' declarations.
 175 (see below for the boilerplate code a `@foreign export@' declaration expands
 176  into.)
 177
 178 For each `@foreign export foo@' in a module M we generate:
 179 \begin{itemize}
 180 \item a C function `@foo@', which calls
 181 \item a Haskell stub `@M.$ffoo@', which calls
 182 \end{itemize}
 183 the user-written Haskell function `@M.foo@'.
 184
 185 \begin{code}
 186 dsFExport :: Id
 187           -> Type               -- Type of foreign export.
 188           -> Module
 189           -> ExtName
 190           -> CallConv
 191           -> Bool               -- True => invoke IO action that's hanging off
 192                                 -- the first argument's stable pointer
 193           -> DsM ( CoreBind
 194                  , SDoc
 195                  , SDoc
 196                  )
 197 dsFExport fn_id ty mod_name ext_name cconv isDyn
 198   =     -- BUILD THE returnIO WRAPPER, if necessary
 199         -- Look at the result type of the exported function, orig_res_ty
 200         -- If it's IO t, return         (\x.x,          IO t, t)
 201         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 202      (case splitTyConApp_maybe orig_res_ty of
 203         Just (ioTyCon, [res_ty])
 204               -> ASSERT( getUnique ioTyCon == ioTyConKey )
 205                         -- The function already returns IO t
 206                  returnDs (\body -> body, orig_res_ty, res_ty)
 207
 208         other ->        -- The function returns t, so wrap the call in returnIO
 209                  dsLookupGlobalValue returnIO_NAME      `thenDs` \ retIOId ->
 210                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 211                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 212                                 -- We don't have ioTyCon conveniently to hand
 213                            orig_res_ty)
 214
 215      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 216                             io_res_ty,          -- IO t
 217                             res_ty) ->          -- t
 218
 219
 220         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 221      (if isDyn then
 222         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 223         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 224         dsLookupGlobalValue deRefStablePtr_NAME         `thenDs` \ deRefStablePtrId ->
 225         let
 226          the_deref_app = mkApps (Var deRefStablePtrId)
 227                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 228         in
 229         dsLookupGlobalValue bindIO_NAME                  `thenDs` \ bindIOId ->
 230         let
 231          stbl_app cont = mkApps (Var bindIOId)
 232                                 [ Type stbl_ptr_to_ty
 233                                 , Type res_ty
 234                                 , the_deref_app
 235                                 , mkLams [stbl_value] cont]
 236         in
 237         returnDs (stbl_value, stbl_app, stbl_ptr)
 238       else
 239         returnDs (fn_id,
 240                   \ body -> body,
 241                   panic "stbl_ptr"  -- should never be touched.
 242                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 243
 244
 245         -- BUILD THE HELPER
 246      getModuleDs                        `thenDs` \ mod ->
 247      getUniqueDs                        `thenDs` \ uniq ->
 248      getSrcLocDs                        `thenDs` \ src_loc ->
 249      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 250      let
 251         wrapper_args | isDyn      = stbl_ptr:fe_args
 252                      | otherwise  = fe_args
 253
 254         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 255                         | otherwise  = fe_arg_tys
 256
 257         helper_ty =  mkForAllTys tvs $
 258                      mkFunTys wrapper_arg_tys io_res_ty
 259
 260         f_helper_glob = mkVanillaId helper_name helper_ty
 261                       where
 262                         name                = idName fn_id
 263                         mod
 264                          | isLocalName name = mod_name
 265                          | otherwise        = nameModule name
 266
 267                         occ                 = mkForeignExportOcc (nameOccName name)
 268                         prov                = LocalDef src_loc Exported
 269                         helper_name         = mkGlobalName uniq mod occ prov
 270
 271         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 272         the_body = mkLams (tvs ++ wrapper_args) the_app
 273         c_nm     = extNameStatic ext_name
 274
 275         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 276                                       c_nm f_helper_glob
 277                                       wrapper_arg_tys res_ty cconv isDyn
 278      in
 279      returnDs (NonRec f_helper_glob the_body, h_stub, c_stub)
 280
 281   where
 282    (tvs,sans_foralls)                   = splitForAllTys ty
 283    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 284
 285    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 286    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 287
 288    fe_arg_tys | isDyn     = tail fe_arg_tys'
 289               | otherwise = fe_arg_tys'
 290
 291    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 292                | otherwise = error "stbl_ptr_ty"
 293 \end{code}
 294
 295 @foreign export dynamic@ lets you dress up Haskell IO actions
 296 of some fixed type behind an externally callable interface (i.e.,
 297 as a C function pointer). Useful for callbacks and stuff.
 298
 299 \begin{verbatim}
 300 foreign export stdcall f :: (Addr -> Int -> IO Int) -> IO Addr
 301
 302 -- Haskell-visible constructor, which is generated from the
 303 -- above:
 304
 305 f :: (Addr -> Int -> IO Int) -> IO Addr
 306 f cback = IO ( \ s1# ->
 307   case makeStablePtr# cback s1# of { StateAndStablePtr# s2# sp# ->
 308   case _ccall_ "mkAdjustor" sp# ``f_helper'' s2# of
 309     StateAndAddr# s3# a# ->
 310     case addr2Int# a# of
 311       0# -> IOfail s# err
 312       _  ->
 313          let
 314           a :: Addr
 315           a = A# a#
 316          in
 317          IOok s3# a)
 318
 319 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 320 -- `special' foreign export that invokes the closure pointed to by the
 321 -- first argument.
 322 \end{verbatim}
 323
 324 \begin{code}
 325 dsFExportDynamic :: Id
 326                  -> Type                -- Type of foreign export.
 327                  -> Module
 328                  -> ExtName
 329                  -> CallConv
 330                  -> DsM (CoreBind, CoreBind, SDoc, SDoc)
 331 dsFExportDynamic i ty mod_name ext_name cconv =
 332      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 333      let
 334         -- hack: need to get at the name of the C stub we're about to generate.
 335        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 336        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 337      in
 338      dsFExport  i export_ty mod_name fe_ext_name cconv True
 339      `thenDs` \ (fe@(NonRec fe_helper fe_expr), h_code, c_code) ->
 340      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 341      dsLookupGlobalValue makeStablePtr_NAME     `thenDs` \ makeStablePtrId ->
 342      let
 343         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 344      in
 345      dsLookupGlobalValue bindIO_NAME                    `thenDs` \ bindIOId ->
 346      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 347      let
 348       stbl_app cont ret_ty
 349         = mkApps (Var bindIOId)
 350                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 351                  , Type ret_ty
 352                  , mk_stbl_ptr_app
 353                  , cont
 354                  ]
 355
 356        {-
 357         The arguments to the external function which will
 358         create a little bit of (template) code on the fly
 359         for allowing the (stable pointed) Haskell closure
 360         to be entered using an external calling convention
 361         (stdcall, ccall).
 362        -}
 363       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 364                       , Var stbl_value
 365                       , mkLit (MachLitLit (_PK_ fe_nm) addrPrimTy)
 366                       ]
 367         -- name of external entry point providing these services.
 368         -- (probably in the RTS.)
 369       adjustor      = SLIT("createAdjustor")
 370      in
 371      dsCCall adjustor adj_args False False ioAddrTy `thenDs` \ ccall_adj ->
 372      let ccall_adj_ty = exprType ccall_adj
 373          ccall_io_adj = mkLams [stbl_value]                  $
 374                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 375                              ccall_adj
 376      in
 377      let io_app = mkLams tvs     $
 378                   mkLams [cback] $
 379                   stbl_app ccall_io_adj addrTy
 380      in
 381      returnDs (NonRec i io_app, fe, h_code, c_code)
 382
 383  where
 384   (tvs,sans_foralls)               = splitForAllTys ty
 385   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 386
 387   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 388
 389   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 390
 391   ioAddrTy :: Type      -- IO Addr
 392   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 393
 394 toCName :: Id -> String
 395 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 396 \end{code}
 397
 398 %*
 399 %
 400 \subsection{Generating @foreign export@ stubs}
 401 %
 402 %*
 403
 404 For each @foreign export@ function, a C stub function is generated.
 405 The C stub constructs the application of the exported Haskell function
 406 using the hugs/ghc rts invocation API.
 407
 408 \begin{code}
 409 fexportEntry :: String
 410              -> FAST_STRING
 411              -> Id
 412              -> [Type]
 413              -> Type
 414              -> CallConv
 415              -> Bool
 416              -> (SDoc, SDoc)
 417 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 418  where
 419    -- name of the (Haskell) helper function generated by the desugarer.
 420   h_nm      = ppr helper <> text "_closure"
 421    -- prototype for the exported function.
 422   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 423
 424   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 425               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 426
 427   c_bits =
 428     externDecl $$
 429     fun_proto  $$
 430     vcat
 431      [ lbrace
 432      ,   text "SchedulerStatus rc;"
 433      ,   declareResult
 434           -- create the application + perform it.
 435      ,   text "rc=rts_evalIO" <>
 436                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 437      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 438                                                 <> comma <> text "rc") <> semi
 439      ,   text "return" <> return_what <> semi
 440      , rbrace
 441      ]
 442
 443   appArg acc (a,c_a) =
 444      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 445
 446   cParamTypes  = map showStgType real_args
 447
 448   res_ty_is_unit = res_ty == unitTy
 449
 450   cResType | res_ty_is_unit = text "void"
 451            | otherwise      = showStgType res_ty
 452
 453   pprCconv
 454    | cc == cCallConv = empty
 455    | otherwise       = pprCallConv cc
 456
 457   declareResult  = text "HaskellObj ret;"
 458
 459   externDecl     = mkExtern (text "HaskellObj") h_nm
 460
 461   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 462
 463   return_what | res_ty_is_unit = empty
 464               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 465
 466   c_args = mkCArgNames 0 args
 467
 468   {-
 469    If we're generating an entry point for a 'foreign export ccall dynamic',
 470    then we receive the return address of the C function that wants to
 471    invoke a Haskell function as any other C function, as second arg.
 472    This arg is unused within the body of the generated C stub, but
 473    needed by the Adjustor.c code to get the stack cleanup right.
 474   -}
 475   (proto_args, real_args)
 476     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 477                                 , head args : addrTy : tail args)
 478     | otherwise = (mkCArgNames 0 args, args)
 479
 480 mkCArgNames :: Int -> [a] -> [SDoc]
 481 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 482
 483 mkHObj :: Type -> SDoc
 484 mkHObj t = text "rts_mk" <> text (showFFIType t)
 485
 486 unpackHObj :: Type -> SDoc
 487 unpackHObj t = text "rts_get" <> text (showFFIType t)
 488
 489 showStgType :: Type -> SDoc
 490 showStgType t = text "Stg" <> text (showFFIType t)
 491
 492 showFFIType :: Type -> String
 493 showFFIType t = getOccString (getName tc)
 494  where
 495   tc = case splitTyConApp_maybe t of
 496             Just (tc,_) -> tc
 497             Nothing     -> pprPanic "showFFIType" (ppr t)
 498 \end{code}