ghc/compiler/deSugar/DsForeign.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1998
   3 %
   4 \section[DsCCall]{Desugaring \tr{foreign} declarations}
   5
   6 Expanding out @foreign import@ and @foreign export@ declarations.
   7
   8 \begin{code}
   9 module DsForeign ( dsForeigns ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14
  15 import DsCCall          ( dsCCall, mkCCall, boxResult, unboxArg )
  16 import DsMonad
  17
  18 import HsSyn            ( ExtName(..), ForeignDecl(..), isDynamicExtName, ForKind(..) )
  19 import HsDecls          ( extNameStatic )
  20 import CallConv
  21 import TcHsSyn          ( TypecheckedForeignDecl )
  22 import CoreUtils        ( exprType, mkInlineMe )
  23 import Id               ( Id, idType, idName, mkVanillaId, mkSysLocal,
  24                           setInlinePragma )
  25 import IdInfo           ( neverInlinePrag )
  26 import Literal          ( Literal(..) )
  27 import Module           ( Module, moduleUserString )
  28 import Name             ( mkGlobalName, nameModule, nameOccName, getOccString,
  29                           mkForeignExportOcc, isLocalName,
  30                           NamedThing(..), Provenance(..), ExportFlag(..)
  31                         )
  32 import Type             ( unUsgTy, repType,
  33                           splitTyConApp_maybe, splitFunTys, splitForAllTys,
  34                           Type, mkFunTys, mkForAllTys, mkTyConApp,
  35                           mkTyVarTy, mkFunTy, splitAppTy, applyTy, funResultTy
  36                         )
  37 import PrimOp           ( PrimOp(..), CCall(..),
  38                           CCallTarget(..), dynamicTarget )
  39 import TysWiredIn       ( unitTy, addrTy, stablePtrTyCon,
  40                           addrDataCon
  41                         )
  42 import Unique           ( Uniquable(..), hasKey,
  43                           ioTyConKey, deRefStablePtrIdKey, returnIOIdKey,
  44                           bindIOIdKey, makeStablePtrIdKey
  45                 )
  46 import Outputable
  47 \end{code}
  48
  49 Desugaring of @foreign@ declarations is naturally split up into
  50 parts, an @import@ and an @export@  part. A @foreign import@
  51 declaration
  52 \begin{verbatim}
  53   foreign import cc nm f :: prim_args -> IO prim_res
  54 \end{verbatim}
  55 is the same as
  56 \begin{verbatim}
  57   f :: prim_args -> IO prim_res
  58   f a1 ... an = _ccall_ nm cc a1 ... an
  59 \end{verbatim}
  60 so we reuse the desugaring code in @DsCCall@ to deal with these.
  61
  62 \begin{code}
  63 dsForeigns :: Module
  64            -> [TypecheckedForeignDecl]
  65            -> DsM ( [CoreBind]        -- desugared foreign imports
  66                   , [CoreBind]        -- helper functions for foreign exports
  67                   , SDoc              -- Header file prototypes for
  68                                       -- "foreign exported" functions.
  69                   , SDoc              -- C stubs to use when calling
  70                                       -- "foreign exported" functions.
  71                   )
  72 dsForeigns mod_name fos = foldlDs combine ([],[],empty,empty) fos
  73  where
  74   combine (acc_fi, acc_fe, acc_h, acc_c) fo@(ForeignDecl i imp_exp _ ext_nm cconv _)
  75     | isForeignImport =   -- foreign import (dynamic)?
  76         dsFImport i (idType i) uns ext_nm cconv  `thenDs` \ bs ->
  77         returnDs (bs ++ acc_fi, acc_fe, acc_h, acc_c)
  78     | isForeignLabel =
  79         dsFLabel i ext_nm `thenDs` \ b ->
  80         returnDs (b:acc_fi, acc_fe, acc_h, acc_c)
  81     | isDynamicExtName ext_nm =
  82         dsFExportDynamic i (idType i) mod_name ext_nm cconv  `thenDs` \ (fi,fe,h,c) ->
  83         returnDs (fi:acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  84
  85     | otherwise        =  -- foreign export
  86         dsFExport i (idType i) mod_name ext_nm cconv False   `thenDs` \ (fe,h,c) ->
  87         returnDs (acc_fi, fe:acc_fe, h $$ acc_h, c $$ acc_c)
  88    where
  89     isForeignImport =
  90         case imp_exp of
  91           FoImport _ -> True
  92           _          -> False
  93
  94     isForeignLabel =
  95         case imp_exp of
  96           FoLabel -> True
  97           _       -> False
  98
  99     (FoImport uns)   = imp_exp
 100
 101 \end{code}
 102
 103 Desugaring foreign imports is just the matter of creating a binding
 104 that on its RHS unboxes its arguments, performs the external call
 105 (using the @CCallOp@ primop), before boxing the result up and returning it.
 106
 107 However, we create a worker/wrapper pair, thus:
 108
 109         foreign import f :: Int -> IO Int
 110 ==>
 111         f x = IO ( \s -> case x of { I# x# ->
 112                          case fw s x# of { (# s1, y# #) ->
 113                          (# s1, I# y# #)}})
 114
 115         fw s x# = ccall f s x#
 116
 117 The strictness/CPR analyser won't do this automatically because it doesn't look
 118 inside returned tuples; but inlining this wrapper is a Really Good Idea
 119 because it exposes the boxing to the call site.
 120
 121
 122 \begin{code}
 123 dsFImport :: Id
 124           -> Type               -- Type of foreign import.
 125           -> Bool               -- True <=> might cause Haskell GC
 126           -> ExtName
 127           -> CallConv
 128           -> DsM [CoreBind]
 129 dsFImport fn_id ty may_not_gc ext_name cconv
 130   = let
 131         (tvs, fun_ty)        = splitForAllTys ty
 132         (arg_tys, io_res_ty) = splitFunTys fun_ty
 133     in
 134     newSysLocalsDs arg_tys                      `thenDs` \ args ->
 135     mapAndUnzipDs unboxArg (map Var args)       `thenDs` \ (val_args, arg_wrappers) ->
 136     boxResult io_res_ty                         `thenDs` \ (ccall_result_ty, res_wrapper) ->
 137
 138     getUniqueDs                                         `thenDs` \ ccall_uniq ->
 139     getUniqueDs                                         `thenDs` \ work_uniq ->
 140     let
 141         lbl = case ext_name of
 142                 Dynamic      -> dynamicTarget
 143                 ExtName fs _ -> StaticTarget fs
 144
 145         -- Build the worker
 146         work_arg_ids  = [v | Var v <- val_args]         -- All guaranteed to be vars
 147         worker_ty     = mkForAllTys tvs (mkFunTys (map idType work_arg_ids) ccall_result_ty)
 148         the_ccall     = CCall lbl False (not may_not_gc) cconv
 149         the_ccall_app = mkCCall ccall_uniq the_ccall val_args ccall_result_ty
 150         work_rhs      = mkLams tvs (mkLams work_arg_ids the_ccall_app)
 151         work_id       = mkSysLocal SLIT("$wccall") work_uniq worker_ty
 152
 153         -- Build the wrapper
 154         work_app     = mkApps (mkVarApps (Var work_id) tvs) val_args
 155         wrapper_body = foldr ($) (res_wrapper work_app) arg_wrappers
 156         wrap_rhs     = mkInlineMe (mkLams (tvs ++ args) wrapper_body)
 157     in
 158     returnDs [NonRec fn_id wrap_rhs, NonRec work_id work_rhs]
 159 \end{code}
 160
 161 Foreign labels
 162
 163 \begin{code}
 164 dsFLabel :: Id -> ExtName -> DsM CoreBind
 165 dsFLabel nm ext_name = returnDs (NonRec nm fo_rhs)
 166   where
 167    fo_rhs = mkConApp addrDataCon [mkLit (MachLabel enm)]
 168    enm    = extNameStatic ext_name
 169 \end{code}
 170
 171 The function that does most of the work for `@foreign export@' declarations.
 172 (see below for the boilerplate code a `@foreign export@' declaration expands
 173  into.)
 174
 175 For each `@foreign export foo@' in a module M we generate:
 176 \begin{itemize}
 177 \item a C function `@foo@', which calls
 178 \item a Haskell stub `@M.$ffoo@', which calls
 179 \end{itemize}
 180 the user-written Haskell function `@M.foo@'.
 181
 182 \begin{code}
 183 dsFExport :: Id
 184           -> Type               -- Type of foreign export.
 185           -> Module
 186           -> ExtName
 187           -> CallConv
 188           -> Bool               -- True => invoke IO action that's hanging off
 189                                 -- the first argument's stable pointer
 190           -> DsM ( CoreBind
 191                  , SDoc
 192                  , SDoc
 193                  )
 194 dsFExport fn_id ty mod_name ext_name cconv isDyn
 195   =     -- BUILD THE returnIO WRAPPER, if necessary
 196         -- Look at the result type of the exported function, orig_res_ty
 197         -- If it's IO t, return         (\x.x,          IO t, t)
 198         -- If it's plain t, return      (\x.returnIO x, IO t, t)
 199      (case splitTyConApp_maybe orig_res_ty of
 200         Just (ioTyCon, [res_ty])
 201               -> ASSERT( ioTyCon `hasKey` ioTyConKey )
 202                         -- The function already returns IO t
 203                  returnDs (\body -> body, orig_res_ty, res_ty)
 204
 205         other ->        -- The function returns t, so wrap the call in returnIO
 206                  dsLookupGlobalValue returnIOIdKey      `thenDs` \ retIOId ->
 207                  returnDs (\body -> mkApps (Var retIOId) [Type orig_res_ty, body],
 208                            funResultTy (applyTy (idType retIOId) orig_res_ty),
 209                                 -- We don't have ioTyCon conveniently to hand
 210                            orig_res_ty)
 211
 212      )          `thenDs` \ (return_io_wrapper,  -- Either identity or returnIO
 213                             io_res_ty,          -- IO t
 214                             res_ty) ->          -- t
 215
 216
 217         -- BUILD THE deRefStablePtr WRAPPER, if necessary
 218      (if isDyn then
 219         newSysLocalDs stbl_ptr_ty                       `thenDs` \ stbl_ptr ->
 220         newSysLocalDs stbl_ptr_to_ty                    `thenDs` \ stbl_value ->
 221         dsLookupGlobalValue deRefStablePtrIdKey         `thenDs` \ deRefStablePtrId ->
 222         dsLookupGlobalValue bindIOIdKey                 `thenDs` \ bindIOId ->
 223         let
 224          the_deref_app = mkApps (Var deRefStablePtrId)
 225                                 [ Type stbl_ptr_to_ty, Var stbl_ptr ]
 226
 227          stbl_app cont = mkApps (Var bindIOId)
 228                                 [ Type stbl_ptr_to_ty
 229                                 , Type res_ty
 230                                 , the_deref_app
 231                                 , mkLams [stbl_value] cont]
 232         in
 233         returnDs (stbl_value, stbl_app, stbl_ptr)
 234       else
 235         returnDs (fn_id,
 236                   \ body -> body,
 237                   panic "stbl_ptr"  -- should never be touched.
 238                   ))                    `thenDs` \ (i, getFun_wrapper, stbl_ptr) ->
 239
 240
 241         -- BUILD THE HELPER
 242      getModuleDs                        `thenDs` \ mod ->
 243      getUniqueDs                        `thenDs` \ uniq ->
 244      getSrcLocDs                        `thenDs` \ src_loc ->
 245      newSysLocalsDs fe_arg_tys          `thenDs` \ fe_args ->
 246      let
 247         wrapper_args | isDyn      = stbl_ptr:fe_args
 248                      | otherwise  = fe_args
 249
 250         wrapper_arg_tys | isDyn      = stbl_ptr_ty:fe_arg_tys
 251                         | otherwise  = fe_arg_tys
 252
 253         helper_ty =  mkForAllTys tvs $
 254                      mkFunTys wrapper_arg_tys io_res_ty
 255
 256         f_helper_glob = mkVanillaId helper_name helper_ty
 257                       where
 258                         name                = idName fn_id
 259                         mod
 260                          | isLocalName name = mod_name
 261                          | otherwise        = nameModule name
 262
 263                         occ                 = mkForeignExportOcc (nameOccName name)
 264                         prov                = LocalDef src_loc Exported
 265                         helper_name         = mkGlobalName uniq mod occ prov
 266
 267         the_app = getFun_wrapper (return_io_wrapper (mkVarApps (Var i) (tvs ++ fe_args)))
 268         the_body = mkLams (tvs ++ wrapper_args) the_app
 269         c_nm     = extNameStatic ext_name
 270
 271         (h_stub, c_stub) = fexportEntry (moduleUserString mod)
 272                                       c_nm f_helper_glob
 273                                       wrapper_arg_tys res_ty cconv isDyn
 274      in
 275      returnDs (NonRec f_helper_glob the_body, h_stub, c_stub)
 276
 277   where
 278    (tvs,sans_foralls)                   = splitForAllTys ty
 279    (fe_arg_tys', orig_res_ty)           = splitFunTys sans_foralls
 280
 281    (_, stbl_ptr_ty')                    = splitForAllTys stbl_ptr_ty
 282    (_, stbl_ptr_to_ty)                  = splitAppTy stbl_ptr_ty'
 283
 284    fe_arg_tys | isDyn     = tail fe_arg_tys'
 285               | otherwise = fe_arg_tys'
 286
 287    stbl_ptr_ty | isDyn     = head fe_arg_tys'
 288                | otherwise = error "stbl_ptr_ty"
 289 \end{code}
 290
 291 @foreign export dynamic@ lets you dress up Haskell IO actions
 292 of some fixed type behind an externally callable interface (i.e.,
 293 as a C function pointer). Useful for callbacks and stuff.
 294
 295 \begin{verbatim}
 296 foreign export dynamic f :: (Addr -> Int -> IO Int) -> IO Addr
 297
 298 -- Haskell-visible constructor, which is generated from the above:
 299 -- SUP: No check for NULL from createAdjustor anymore???
 300
 301 f :: (Addr -> Int -> IO Int) -> IO Addr
 302 f cback =
 303    bindIO (makeStablePtr cback)
 304           (\StablePtr sp# -> IO (\s1# ->
 305               case _ccall_ createAdjustor cconv sp# ``f_helper'' s1# of
 306                  (# s2#, a# #) -> (# s2#, A# a# #)))
 307
 308 foreign export "f_helper" f_helper :: StablePtr (Addr -> Int -> IO Int) -> Addr -> Int -> IO Int
 309 -- `special' foreign export that invokes the closure pointed to by the
 310 -- first argument.
 311 \end{verbatim}
 312
 313 \begin{code}
 314 dsFExportDynamic :: Id
 315                  -> Type                -- Type of foreign export.
 316                  -> Module
 317                  -> ExtName
 318                  -> CallConv
 319                  -> DsM (CoreBind, CoreBind, SDoc, SDoc)
 320 dsFExportDynamic i ty mod_name ext_name cconv =
 321      newSysLocalDs ty                                    `thenDs` \ fe_id ->
 322      let
 323         -- hack: need to get at the name of the C stub we're about to generate.
 324        fe_nm       = moduleUserString mod_name ++ "_" ++ toCName fe_id
 325        fe_ext_name = ExtName (_PK_ fe_nm) Nothing
 326      in
 327      dsFExport  i export_ty mod_name fe_ext_name cconv True
 328      `thenDs` \ (fe@(NonRec fe_helper fe_expr), h_code, c_code) ->
 329      newSysLocalDs arg_ty                       `thenDs` \ cback ->
 330      dsLookupGlobalValue makeStablePtrIdKey     `thenDs` \ makeStablePtrId ->
 331      let
 332         mk_stbl_ptr_app    = mkApps (Var makeStablePtrId) [ Type arg_ty, Var cback ]
 333      in
 334      dsLookupGlobalValue bindIOIdKey                    `thenDs` \ bindIOId ->
 335      newSysLocalDs (mkTyConApp stablePtrTyCon [arg_ty]) `thenDs` \ stbl_value ->
 336      let
 337       stbl_app cont ret_ty
 338         = mkApps (Var bindIOId)
 339                  [ Type (mkTyConApp stablePtrTyCon [arg_ty])
 340                  , Type ret_ty
 341                  , mk_stbl_ptr_app
 342                  , cont
 343                  ]
 344
 345        {-
 346         The arguments to the external function which will
 347         create a little bit of (template) code on the fly
 348         for allowing the (stable pointed) Haskell closure
 349         to be entered using an external calling convention
 350         (stdcall, ccall).
 351        -}
 352       adj_args      = [ mkIntLitInt (callConvToInt cconv)
 353                       , Var stbl_value
 354                       , mkLit (MachLabel (_PK_ fe_nm))
 355                       ]
 356         -- name of external entry point providing these services.
 357         -- (probably in the RTS.)
 358       adjustor      = SLIT("createAdjustor")
 359      in
 360      dsCCall adjustor adj_args False False ioAddrTy `thenDs` \ ccall_adj ->
 361      let ccall_adj_ty = exprType ccall_adj
 362          ccall_io_adj = mkLams [stbl_value]                  $
 363                         Note (Coerce io_res_ty (unUsgTy ccall_adj_ty))
 364                              ccall_adj
 365      in
 366      let io_app = mkLams tvs     $
 367                   mkLams [cback] $
 368                   stbl_app ccall_io_adj addrTy
 369      in
 370         -- Never inline the f.e.d. function, because the litlit might not be in scope
 371         -- in other modules.
 372      returnDs (NonRec (i `setInlinePragma` neverInlinePrag) io_app, fe, h_code, c_code)
 373
 374  where
 375   (tvs,sans_foralls)               = splitForAllTys ty
 376   ([arg_ty], io_res_ty)            = splitFunTys sans_foralls
 377
 378   Just (ioTyCon, [res_ty])         = splitTyConApp_maybe io_res_ty
 379
 380   export_ty                        = mkFunTy (mkTyConApp stablePtrTyCon [arg_ty]) arg_ty
 381
 382   ioAddrTy :: Type      -- IO Addr
 383   ioAddrTy = mkTyConApp ioTyCon [addrTy]
 384
 385 toCName :: Id -> String
 386 toCName i = showSDoc (pprCode CStyle (ppr (idName i)))
 387 \end{code}
 388
 389 %*
 390 %
 391 \subsection{Generating @foreign export@ stubs}
 392 %
 393 %*
 394
 395 For each @foreign export@ function, a C stub function is generated.
 396 The C stub constructs the application of the exported Haskell function
 397 using the hugs/ghc rts invocation API.
 398
 399 \begin{code}
 400 fexportEntry :: String
 401              -> FAST_STRING
 402              -> Id
 403              -> [Type]
 404              -> Type
 405              -> CallConv
 406              -> Bool
 407              -> (SDoc, SDoc)
 408 fexportEntry mod_nm c_nm helper args res_ty cc isDyn = (header_bits, c_bits)
 409  where
 410    -- name of the (Haskell) helper function generated by the desugarer.
 411   h_nm      = ppr helper <> text "_closure"
 412    -- prototype for the exported function.
 413   header_bits = ptext SLIT("extern") <+> fun_proto <> semi
 414
 415   fun_proto = cResType <+> pprCconv <+> ptext c_nm <>
 416               parens (hsep (punctuate comma (zipWith (<+>) cParamTypes proto_args)))
 417
 418   c_bits =
 419     externDecl $$
 420     fun_proto  $$
 421     vcat
 422      [ lbrace
 423      ,   text "SchedulerStatus rc;"
 424      ,   declareResult
 425           -- create the application + perform it.
 426      ,   text "rc=rts_evalIO" <>
 427                   parens (foldl appArg (text "(StgClosure*)&" <> h_nm) (zip args c_args) <> comma <> text "&ret") <> semi
 428      ,   text "rts_checkSchedStatus" <> parens (doubleQuotes (ptext c_nm)
 429                                                 <> comma <> text "rc") <> semi
 430      ,   text "return" <> return_what <> semi
 431      , rbrace
 432      ]
 433
 434   appArg acc (a,c_a) =
 435      text "rts_apply" <> parens (acc <> comma <> mkHObj a <> parens c_a)
 436
 437   cParamTypes  = map showStgType real_args
 438
 439   res_ty_is_unit = res_ty == unitTy
 440
 441   cResType | res_ty_is_unit = text "void"
 442            | otherwise      = showStgType res_ty
 443
 444   pprCconv
 445    | cc == cCallConv = empty
 446    | otherwise       = pprCallConv cc
 447
 448   declareResult  = text "HaskellObj ret;"
 449
 450   externDecl     = mkExtern (text "HaskellObj") h_nm
 451
 452   mkExtern ty nm = text "extern" <+> ty <+> nm <> semi
 453
 454   return_what | res_ty_is_unit = empty
 455               | otherwise      = parens (unpackHObj res_ty <> parens (text "ret"))
 456
 457   c_args = mkCArgNames 0 args
 458
 459   {-
 460    If we're generating an entry point for a 'foreign export ccall dynamic',
 461    then we receive the return address of the C function that wants to
 462    invoke a Haskell function as any other C function, as second arg.
 463    This arg is unused within the body of the generated C stub, but
 464    needed by the Adjustor.c code to get the stack cleanup right.
 465   -}
 466   (proto_args, real_args)
 467     | cc == cCallConv && isDyn = ( text "a0" : text "a_" : mkCArgNames 1 (tail args)
 468                                 , head args : addrTy : tail args)
 469     | otherwise = (mkCArgNames 0 args, args)
 470
 471 mkCArgNames :: Int -> [a] -> [SDoc]
 472 mkCArgNames n as = zipWith (\ _ n -> text ('a':show n)) as [n..]
 473
 474 mkHObj :: Type -> SDoc
 475 mkHObj t = text "rts_mk" <> text (showFFIType t)
 476
 477 unpackHObj :: Type -> SDoc
 478 unpackHObj t = text "rts_get" <> text (showFFIType t)
 479
 480 showStgType :: Type -> SDoc
 481 showStgType t = text "Stg" <> text (showFFIType t)
 482
 483 showFFIType :: Type -> String
 484 showFFIType t = getOccString (getName tc)
 485  where
 486   tc = case splitTyConApp_maybe (repType t) of
 487             Just (tc,_) -> tc
 488             Nothing     -> pprPanic "showFFIType" (ppr t)
 489 \end{code}