ghc/compiler/deSugar/DsUtils.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[DsUtils]{Utilities for desugaring}
   5
   6 This module exports some utility functions of no great interest.
   7
   8 \begin{code}
   9 module DsUtils (
  10         EquationInfo(..),
  11         firstPat, shiftEqns,
  12
  13         mkDsLet,
  14
  15         MatchResult(..), CanItFail(..),
  16         cantFailMatchResult, alwaysFailMatchResult,
  17         extractMatchResult, combineMatchResults,
  18         adjustMatchResult,  adjustMatchResultDs,
  19         mkCoLetsMatchResult, mkCoLetMatchResult,
  20         mkGuardedMatchResult,
  21         mkCoPrimCaseMatchResult, mkCoAlgCaseMatchResult,
  22         bindInMatchResult, bindOneInMatchResult,
  23
  24         mkErrorAppDs, mkNilExpr, mkConsExpr, mkListExpr,
  25         mkIntExpr, mkCharExpr,
  26         mkStringExpr, mkStringExprFS, mkIntegerExpr,
  27
  28         mkSelectorBinds, mkTupleExpr, mkTupleSelector,
  29         mkTupleType, mkTupleCase, mkBigCoreTup,
  30         mkCoreTup, mkCoreTupTy,
  31
  32         dsReboundNames, lookupReboundName,
  33
  34         selectSimpleMatchVarL, selectMatchVars
  35     ) where
  36
  37 #include "HsVersions.h"
  38
  39 import {-# SOURCE #-}   Match ( matchSimply )
  40 import {-# SOURCE #-}   DsExpr( dsExpr )
  41
  42 import HsSyn
  43 import TcHsSyn          ( hsPatType )
  44 import CoreSyn
  45 import Constants        ( mAX_TUPLE_SIZE )
  46 import DsMonad
  47
  48 import CoreUtils        ( exprType, mkIfThenElse, mkCoerce, bindNonRec )
  49 import MkId             ( iRREFUT_PAT_ERROR_ID, mkReboxingAlt, mkNewTypeBody )
  50 import Id               ( idType, Id, mkWildId, mkTemplateLocals, mkSysLocal )
  51 import Var              ( Var )
  52 import Name             ( Name )
  53 import Literal          ( Literal(..), mkStringLit, inIntRange, tARGET_MAX_INT )
  54 import TyCon            ( isNewTyCon, tyConDataCons )
  55 import DataCon          ( DataCon, dataConSourceArity, dataConTyCon )
  56 import Type             ( mkFunTy, isUnLiftedType, Type, splitTyConApp, mkTyVarTy )
  57 import TcType           ( tcTyConAppTyCon, tcEqType )
  58 import TysPrim          ( intPrimTy )
  59 import TysWiredIn       ( nilDataCon, consDataCon,
  60                           tupleCon, mkTupleTy,
  61                           unitDataConId, unitTy,
  62                           charTy, charDataCon,
  63                           intTy, intDataCon,
  64                           isPArrFakeCon )
  65 import BasicTypes       ( Boxity(..) )
  66 import UniqSet          ( mkUniqSet, minusUniqSet, isEmptyUniqSet )
  67 import UniqSupply       ( splitUniqSupply, uniqFromSupply, uniqsFromSupply )
  68 import PrelNames        ( unpackCStringName, unpackCStringUtf8Name,
  69                           plusIntegerName, timesIntegerName, smallIntegerDataConName,
  70                           lengthPName, indexPName )
  71 import Outputable
  72 import UnicodeUtil      ( intsToUtf8 )
  73 import SrcLoc           ( Located(..), unLoc, noLoc )
  74 import Util             ( isSingleton, notNull, zipEqual )
  75 import ListSetOps       ( assocDefault )
  76 import FastString
  77 \end{code}
  78
  79
  80
  81 %************************************************************************
  82 %*                                                                      *
  83                 Rebindable syntax
  84 %*                                                                      *
  85 %************************************************************************
  86
  87 \begin{code}
  88 dsReboundNames :: ReboundNames Id
  89                -> DsM ([CoreBind],      -- Auxiliary bindings
  90                        [(Name,Id)])     -- Maps the standard name to its value
  91
  92 dsReboundNames rebound_ids
  93   = mapAndUnzipDs mk_bind rebound_ids   `thenDs` \ (binds_s, prs) ->
  94     return (concat binds_s, prs)
  95   where
  96         -- The cheapo special case can happen when we
  97         -- make an intermediate HsDo when desugaring a RecStmt
  98     mk_bind (std_name, HsVar id) = return ([], (std_name, id))
  99     mk_bind (std_name, expr)
 100          = dsExpr expr                          `thenDs` \ rhs ->
 101            newSysLocalDs (exprType rhs)         `thenDs` \ id ->
 102            return ([NonRec id rhs], (std_name, id))
 103
 104 lookupReboundName :: [(Name,Id)] -> Name -> CoreExpr
 105 lookupReboundName prs std_name
 106   = Var (assocDefault (mk_panic std_name) prs std_name)
 107   where
 108     mk_panic std_name = pprPanic "dsReboundNames" (ptext SLIT("Not found:") <+> ppr std_name)
 109 \end{code}
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114 \subsection{Building lets}
 115 %*                                                                      *
 116 %************************************************************************
 117
 118 Use case, not let for unlifted types.  The simplifier will turn some
 119 back again.
 120
 121 \begin{code}
 122 mkDsLet :: CoreBind -> CoreExpr -> CoreExpr
 123 mkDsLet (NonRec bndr rhs) body
 124   | isUnLiftedType (idType bndr)
 125   = Case rhs bndr (exprType body) [(DEFAULT,[],body)]
 126 mkDsLet bind body
 127   = Let bind body
 128
 129 mkDsLets :: [CoreBind] -> CoreExpr -> CoreExpr
 130 mkDsLets binds body = foldr mkDsLet body binds
 131 \end{code}
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{ Selecting match variables}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 We're about to match against some patterns.  We want to make some
 141 @Ids@ to use as match variables.  If a pattern has an @Id@ readily at
 142 hand, which should indeed be bound to the pattern as a whole, then use it;
 143 otherwise, make one up.
 144
 145 \begin{code}
 146 selectSimpleMatchVarL :: LPat Id -> DsM Id
 147 selectSimpleMatchVarL pat = selectMatchVar (unLoc pat) (hsPatType pat)
 148
 149 -- (selectMatchVars ps tys) chooses variables of type tys
 150 -- to use for matching ps against.  If the pattern is a variable,
 151 -- we try to use that, to save inventing lots of fresh variables.
 152 -- But even if it is a variable, its type might not match.  Consider
 153 --      data T a where
 154 --        T1 :: Int -> T Int
 155 --        T2 :: a   -> T a
 156 --
 157 --      f :: T a -> a -> Int
 158 --      f (T1 i) (x::Int) = x
 159 --      f (T2 i) (y::a)   = 0
 160 -- Then we must not choose (x::Int) as the matching variable!
 161
 162 selectMatchVars :: [Pat Id] -> [Type] -> DsM [Id]
 163 selectMatchVars []     []       = return []
 164 selectMatchVars (p:ps) (ty:tys) = do { v  <- selectMatchVar  p  ty
 165                                      ; vs <- selectMatchVars ps tys
 166                                      ; return (v:vs) }
 167
 168 selectMatchVar (LazyPat pat)   pat_ty  = selectMatchVar (unLoc pat) pat_ty
 169 selectMatchVar (VarPat var)    pat_ty  = try_for var         pat_ty
 170 selectMatchVar (AsPat var pat) pat_ty  = try_for (unLoc var) pat_ty
 171 selectMatchVar other_pat       pat_ty  = newSysLocalDs pat_ty   -- OK, better make up one...
 172
 173 try_for var pat_ty
 174   | idType var `tcEqType` pat_ty = returnDs var
 175   | otherwise                    = newSysLocalDs pat_ty
 176 \end{code}
 177
 178
 179 %************************************************************************
 180 %*                                                                      *
 181 %* type synonym EquationInfo and access functions for its pieces        *
 182 %*                                                                      *
 183 %************************************************************************
 184 \subsection[EquationInfo-synonym]{@EquationInfo@: a useful synonym}
 185
 186 The ``equation info'' used by @match@ is relatively complicated and
 187 worthy of a type synonym and a few handy functions.
 188
 189 \begin{code}
 190 data EquationInfo
 191   = EqnInfo { eqn_pats :: [Pat Id],     -- The patterns for an eqn
 192               eqn_rhs  :: MatchResult } -- What to do after match
 193
 194 -- The semantics of (match vs (EqnInfo wrap pats rhs)) is the MatchResult
 195 --      \fail. wrap (case vs of { pats -> rhs fail })
 196 -- where vs are not in the domain of wrap
 197
 198 firstPat :: EquationInfo -> Pat Id
 199 firstPat eqn = head (eqn_pats eqn)
 200
 201 shiftEqns :: [EquationInfo] -> [EquationInfo]
 202 -- Drop the outermost layer of the first pattern in each equation
 203 shiftEqns eqns = [ eqn { eqn_pats = shiftPats (eqn_pats eqn) }
 204                  | eqn <- eqns ]
 205
 206 shiftPats :: [Pat Id] -> [Pat Id]
 207 shiftPats (ConPatOut _ _ _ _ (PrefixCon arg_pats) _ : pats) = map unLoc arg_pats ++ pats
 208 shiftPats (pat_with_no_sub_pats                     : pats) = pats
 209 \end{code}
 210
 211
 212 \begin{code}
 213 -- A MatchResult is an expression with a hole in it
 214 data MatchResult
 215   = MatchResult
 216         CanItFail       -- Tells whether the failure expression is used
 217         (CoreExpr -> DsM CoreExpr)
 218                         -- Takes a expression to plug in at the
 219                         -- failure point(s). The expression should
 220                         -- be duplicatable!
 221
 222 data CanItFail = CanFail | CantFail
 223
 224 orFail CantFail CantFail = CantFail
 225 orFail _        _        = CanFail
 226 \end{code}
 227
 228 Functions on MatchResults
 229
 230 \begin{code}
 231 alwaysFailMatchResult :: MatchResult
 232 alwaysFailMatchResult = MatchResult CanFail (\fail -> returnDs fail)
 233
 234 cantFailMatchResult :: CoreExpr -> MatchResult
 235 cantFailMatchResult expr = MatchResult CantFail (\ ignore -> returnDs expr)
 236
 237 extractMatchResult :: MatchResult -> CoreExpr -> DsM CoreExpr
 238 extractMatchResult (MatchResult CantFail match_fn) fail_expr
 239   = match_fn (error "It can't fail!")
 240
 241 extractMatchResult (MatchResult CanFail match_fn) fail_expr
 242   = mkFailurePair fail_expr             `thenDs` \ (fail_bind, if_it_fails) ->
 243     match_fn if_it_fails                `thenDs` \ body ->
 244     returnDs (mkDsLet fail_bind body)
 245
 246
 247 combineMatchResults :: MatchResult -> MatchResult -> MatchResult
 248 combineMatchResults (MatchResult CanFail      body_fn1)
 249                     (MatchResult can_it_fail2 body_fn2)
 250   = MatchResult can_it_fail2 body_fn
 251   where
 252     body_fn fail = body_fn2 fail                        `thenDs` \ body2 ->
 253                    mkFailurePair body2                  `thenDs` \ (fail_bind, duplicatable_expr) ->
 254                    body_fn1 duplicatable_expr           `thenDs` \ body1 ->
 255                    returnDs (Let fail_bind body1)
 256
 257 combineMatchResults match_result1@(MatchResult CantFail body_fn1) match_result2
 258   = match_result1
 259
 260 adjustMatchResult :: (CoreExpr -> CoreExpr) -> MatchResult -> MatchResult
 261 adjustMatchResult encl_fn (MatchResult can_it_fail body_fn)
 262   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 263                                       returnDs (encl_fn body))
 264
 265 adjustMatchResultDs :: (CoreExpr -> DsM CoreExpr) -> MatchResult -> MatchResult
 266 adjustMatchResultDs encl_fn (MatchResult can_it_fail body_fn)
 267   = MatchResult can_it_fail (\fail -> body_fn fail      `thenDs` \ body ->
 268                                       encl_fn body)
 269
 270 bindInMatchResult :: [(Var,Var)] -> MatchResult -> MatchResult
 271 bindInMatchResult binds = adjustMatchResult (\e -> foldr bind e binds)
 272   where
 273     bind (new,old) body = bindMR new old body
 274
 275 bindOneInMatchResult :: Var -> Var -> MatchResult -> MatchResult
 276 bindOneInMatchResult new old = adjustMatchResult (bindMR new old)
 277
 278 bindMR :: Var -> Var -> CoreExpr -> CoreExpr
 279 bindMR new old body
 280   | new==old    = body
 281   | isTyVar new = App (Lam new body) (Type (mkTyVarTy old))
 282   | otherwise   = Let (NonRec new (Var old)) body
 283
 284 mkCoLetsMatchResult :: [CoreBind] -> MatchResult -> MatchResult
 285 mkCoLetsMatchResult binds match_result
 286   = adjustMatchResult (mkDsLets binds) match_result
 287
 288 mkCoLetMatchResult :: CoreBind -> MatchResult -> MatchResult
 289 mkCoLetMatchResult bind match_result
 290   = adjustMatchResult (mkDsLet bind) match_result
 291
 292 mkGuardedMatchResult :: CoreExpr -> MatchResult -> MatchResult
 293 mkGuardedMatchResult pred_expr (MatchResult can_it_fail body_fn)
 294   = MatchResult CanFail (\fail -> body_fn fail  `thenDs` \ body ->
 295                                   returnDs (mkIfThenElse pred_expr body fail))
 296
 297 mkCoPrimCaseMatchResult :: Id                           -- Scrutinee
 298                     -> Type                             -- Type of the case
 299                     -> [(Literal, MatchResult)]         -- Alternatives
 300                     -> MatchResult
 301 mkCoPrimCaseMatchResult var ty match_alts
 302   = MatchResult CanFail mk_case
 303   where
 304     mk_case fail
 305       = mappM (mk_alt fail) match_alts          `thenDs` \ alts ->
 306         returnDs (Case (Var var) var ty ((DEFAULT, [], fail) : alts))
 307
 308     mk_alt fail (lit, MatchResult _ body_fn) = body_fn fail     `thenDs` \ body ->
 309                                                returnDs (LitAlt lit, [], body)
 310
 311
 312 mkCoAlgCaseMatchResult :: Id                                    -- Scrutinee
 313                     -> Type                                     -- Type of exp
 314                     -> [(DataCon, [CoreBndr], MatchResult)]     -- Alternatives
 315                     -> MatchResult
 316 mkCoAlgCaseMatchResult var ty match_alts
 317   | isNewTyCon tycon            -- Newtype case; use a let
 318   = ASSERT( null (tail match_alts) && null (tail arg_ids1) )
 319     mkCoLetsMatchResult [NonRec arg_id1 newtype_rhs] match_result1
 320
 321   | isPArrFakeAlts match_alts   -- Sugared parallel array; use a literal case
 322   = MatchResult CanFail mk_parrCase
 323
 324   | otherwise                   -- Datatype case; use a case
 325   = MatchResult fail_flag mk_case
 326   where
 327     tycon = dataConTyCon con1
 328         -- [Interesting: becuase of GADTs, we can't rely on the type of
 329         --  the scrutinised Id to be sufficiently refined to have a TyCon in it]
 330
 331         -- Stuff for newtype
 332     (con1, arg_ids1, match_result1) = head match_alts
 333     arg_id1     = head arg_ids1
 334     newtype_rhs = mkNewTypeBody tycon (idType arg_id1) (Var var)
 335
 336         -- Stuff for data types
 337     data_cons      = tyConDataCons tycon
 338     match_results  = [match_result | (_,_,match_result) <- match_alts]
 339
 340     fail_flag | exhaustive_case
 341               = foldr1 orFail [can_it_fail | MatchResult can_it_fail _ <- match_results]
 342               | otherwise
 343               = CanFail
 344
 345     wild_var = mkWildId (idType var)
 346     mk_case fail = mappM (mk_alt fail) match_alts       `thenDs` \ alts ->
 347                    returnDs (Case (Var var) wild_var ty (mk_default fail ++ alts))
 348
 349     mk_alt fail (con, args, MatchResult _ body_fn)
 350         = body_fn fail                          `thenDs` \ body ->
 351           newUniqueSupply                       `thenDs` \ us ->
 352           returnDs (mkReboxingAlt (uniqsFromSupply us) con args body)
 353
 354     mk_default fail | exhaustive_case = []
 355                     | otherwise       = [(DEFAULT, [], fail)]
 356
 357     un_mentioned_constructors
 358         = mkUniqSet data_cons `minusUniqSet` mkUniqSet [ con | (con, _, _) <- match_alts]
 359     exhaustive_case = isEmptyUniqSet un_mentioned_constructors
 360
 361         -- Stuff for parallel arrays
 362         --
 363         -- * the following is to desugar cases over fake constructors for
 364         --   parallel arrays, which are introduced by `tidy1' in the `PArrPat'
 365         --   case
 366         --
 367         -- Concerning `isPArrFakeAlts':
 368         --
 369         -- * it is *not* sufficient to just check the type of the type
 370         --   constructor, as we have to be careful not to confuse the real
 371         --   representation of parallel arrays with the fake constructors;
 372         --   moreover, a list of alternatives must not mix fake and real
 373         --   constructors (this is checked earlier on)
 374         --
 375         -- FIXME: We actually go through the whole list and make sure that
 376         --        either all or none of the constructors are fake parallel
 377         --        array constructors.  This is to spot equations that mix fake
 378         --        constructors with the real representation defined in
 379         --        `PrelPArr'.  It would be nicer to spot this situation
 380         --        earlier and raise a proper error message, but it can really
 381         --        only happen in `PrelPArr' anyway.
 382         --
 383     isPArrFakeAlts [(dcon, _, _)]      = isPArrFakeCon dcon
 384     isPArrFakeAlts ((dcon, _, _):alts) =
 385       case (isPArrFakeCon dcon, isPArrFakeAlts alts) of
 386         (True , True ) -> True
 387         (False, False) -> False
 388         _              ->
 389           panic "DsUtils: You may not mix `[:...:]' with `PArr' patterns"
 390     --
 391     mk_parrCase fail =
 392       dsLookupGlobalId lengthPName                      `thenDs` \lengthP  ->
 393       unboxAlt                                          `thenDs` \alt      ->
 394       returnDs (Case (len lengthP) (mkWildId intTy) ty [alt])
 395       where
 396         elemTy      = case splitTyConApp (idType var) of
 397                         (_, [elemTy]) -> elemTy
 398                         _               -> panic panicMsg
 399         panicMsg    = "DsUtils.mkCoAlgCaseMatchResult: not a parallel array?"
 400         len lengthP = mkApps (Var lengthP) [Type elemTy, Var var]
 401         --
 402         unboxAlt =
 403           newSysLocalDs intPrimTy                       `thenDs` \l        ->
 404           dsLookupGlobalId indexPName           `thenDs` \indexP   ->
 405           mappM (mkAlt indexP) match_alts               `thenDs` \alts     ->
 406           returnDs (DataAlt intDataCon, [l], (Case (Var l) wild ty (dft : alts)))
 407           where
 408             wild = mkWildId intPrimTy
 409             dft  = (DEFAULT, [], fail)
 410         --
 411         -- each alternative matches one array length (corresponding to one
 412         -- fake array constructor), so the match is on a literal; each
 413         -- alternative's body is extended by a local binding for each
 414         -- constructor argument, which are bound to array elements starting
 415         -- with the first
 416         --
 417         mkAlt indexP (con, args, MatchResult _ bodyFun) =
 418           bodyFun fail                                  `thenDs` \body     ->
 419           returnDs (LitAlt lit, [], mkDsLets binds body)
 420           where
 421             lit   = MachInt $ toInteger (dataConSourceArity con)
 422             binds = [NonRec arg (indexExpr i) | (i, arg) <- zip [1..] args]
 423             --
 424             indexExpr i = mkApps (Var indexP) [Type elemTy, Var var, mkIntExpr i]
 425 \end{code}
 426
 427
 428 %************************************************************************
 429 %*                                                                      *
 430 \subsection{Desugarer's versions of some Core functions}
 431 %*                                                                      *
 432 %************************************************************************
 433
 434 \begin{code}
 435 mkErrorAppDs :: Id              -- The error function
 436              -> Type            -- Type to which it should be applied
 437              -> String          -- The error message string to pass
 438              -> DsM CoreExpr
 439
 440 mkErrorAppDs err_id ty msg
 441   = getSrcSpanDs                `thenDs` \ src_loc ->
 442     let
 443         full_msg = showSDoc (hcat [ppr src_loc, text "|", text msg])
 444         core_msg = Lit (mkStringLit full_msg)
 445     in
 446     returnDs (mkApps (Var err_id) [Type ty, core_msg])
 447 \end{code}
 448
 449
 450 *************************************************************
 451 %*                                                                      *
 452 \subsection{Making literals}
 453 %*                                                                      *
 454 %************************************************************************
 455
 456 \begin{code}
 457 mkCharExpr     :: Char       -> CoreExpr      -- Returns        C# c :: Int
 458 mkIntExpr      :: Integer    -> CoreExpr      -- Returns        I# i :: Int
 459 mkIntegerExpr  :: Integer    -> DsM CoreExpr  -- Result :: Integer
 460 mkStringExpr   :: String     -> DsM CoreExpr  -- Result :: String
 461 mkStringExprFS :: FastString -> DsM CoreExpr  -- Result :: String
 462
 463 mkIntExpr  i = mkConApp intDataCon  [mkIntLit i]
 464 mkCharExpr c = mkConApp charDataCon [mkLit (MachChar c)]
 465
 466 mkIntegerExpr i
 467   | inIntRange i        -- Small enough, so start from an Int
 468   = dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 469     returnDs (mkSmallIntegerLit integer_dc i)
 470
 471 -- Special case for integral literals with a large magnitude:
 472 -- They are transformed into an expression involving only smaller
 473 -- integral literals. This improves constant folding.
 474
 475   | otherwise           -- Big, so start from a string
 476   = dsLookupGlobalId plusIntegerName            `thenDs` \ plus_id ->
 477     dsLookupGlobalId timesIntegerName           `thenDs` \ times_id ->
 478     dsLookupDataCon  smallIntegerDataConName    `thenDs` \ integer_dc ->
 479     let
 480         lit i = mkSmallIntegerLit integer_dc i
 481         plus a b  = Var plus_id  `App` a `App` b
 482         times a b = Var times_id `App` a `App` b
 483
 484         -- Transform i into (x1 + (x2 + (x3 + (...) * b) * b) * b) with abs xi <= b
 485         horner :: Integer -> Integer -> CoreExpr
 486         horner b i | abs q <= 1 = if r == 0 || r == i
 487                                   then lit i
 488                                   else lit r `plus` lit (i-r)
 489                    | r == 0     =               horner b q `times` lit b
 490                    | otherwise  = lit r `plus` (horner b q `times` lit b)
 491                    where
 492                      (q,r) = i `quotRem` b
 493
 494     in
 495     returnDs (horner tARGET_MAX_INT i)
 496
 497 mkSmallIntegerLit small_integer_data_con i = mkConApp small_integer_data_con [mkIntLit i]
 498
 499 mkStringExpr str = mkStringExprFS (mkFastString str)
 500
 501 mkStringExprFS str
 502   | nullFastString str
 503   = returnDs (mkNilExpr charTy)
 504
 505   | lengthFS str == 1
 506   = let
 507         the_char = mkCharExpr (headFS str)
 508     in
 509     returnDs (mkConsExpr charTy the_char (mkNilExpr charTy))
 510
 511   | all safeChar int_chars
 512   = dsLookupGlobalId unpackCStringName  `thenDs` \ unpack_id ->
 513     returnDs (App (Var unpack_id) (Lit (MachStr str)))
 514
 515   | otherwise
 516   = dsLookupGlobalId unpackCStringUtf8Name      `thenDs` \ unpack_id ->
 517     returnDs (App (Var unpack_id) (Lit (MachStr (mkFastString (intsToUtf8 int_chars)))))
 518
 519   where
 520     int_chars = unpackIntFS str
 521     safeChar c = c >= 1 && c <= 0xFF
 522 \end{code}
 523
 524
 525 %************************************************************************
 526 %*                                                                      *
 527 \subsection[mkSelectorBind]{Make a selector bind}
 528 %*                                                                      *
 529 %************************************************************************
 530
 531 This is used in various places to do with lazy patterns.
 532 For each binder $b$ in the pattern, we create a binding:
 533 \begin{verbatim}
 534     b = case v of pat' -> b'
 535 \end{verbatim}
 536 where @pat'@ is @pat@ with each binder @b@ cloned into @b'@.
 537
 538 ToDo: making these bindings should really depend on whether there's
 539 much work to be done per binding.  If the pattern is complex, it
 540 should be de-mangled once, into a tuple (and then selected from).
 541 Otherwise the demangling can be in-line in the bindings (as here).
 542
 543 Boring!  Boring!  One error message per binder.  The above ToDo is
 544 even more helpful.  Something very similar happens for pattern-bound
 545 expressions.
 546
 547 \begin{code}
 548 mkSelectorBinds :: LPat Id      -- The pattern
 549                 -> CoreExpr     -- Expression to which the pattern is bound
 550                 -> DsM [(Id,CoreExpr)]
 551
 552 mkSelectorBinds (L _ (VarPat v)) val_expr
 553   = returnDs [(v, val_expr)]
 554
 555 mkSelectorBinds pat val_expr
 556   | isSingleton binders || is_simple_lpat pat
 557   =     -- Given   p = e, where p binds x,y
 558         -- we are going to make
 559         --      v = p   (where v is fresh)
 560         --      x = case v of p -> x
 561         --      y = case v of p -> x
 562
 563         -- Make up 'v'
 564         -- NB: give it the type of *pattern* p, not the type of the *rhs* e.
 565         -- This does not matter after desugaring, but there's a subtle
 566         -- issue with implicit parameters. Consider
 567         --      (x,y) = ?i
 568         -- Then, ?i is given type {?i :: Int}, a PredType, which is opaque
 569         -- to the desugarer.  (Why opaque?  Because newtypes have to be.  Why
 570         -- does it get that type?  So that when we abstract over it we get the
 571         -- right top-level type  (?i::Int) => ...)
 572         --
 573         -- So to get the type of 'v', use the pattern not the rhs.  Often more
 574         -- efficient too.
 575     newSysLocalDs (hsPatType pat)       `thenDs` \ val_var ->
 576
 577         -- For the error message we make one error-app, to avoid duplication.
 578         -- But we need it at different types... so we use coerce for that
 579     mkErrorAppDs iRREFUT_PAT_ERROR_ID
 580                  unitTy (showSDoc (ppr pat))    `thenDs` \ err_expr ->
 581     newSysLocalDs unitTy                        `thenDs` \ err_var ->
 582     mappM (mk_bind val_var err_var) binders     `thenDs` \ binds ->
 583     returnDs ( (val_var, val_expr) :
 584                (err_var, err_expr) :
 585                binds )
 586
 587
 588   | otherwise
 589   = mkErrorAppDs iRREFUT_PAT_ERROR_ID
 590                  tuple_ty (showSDoc (ppr pat))                  `thenDs` \ error_expr ->
 591     matchSimply val_expr PatBindRhs pat local_tuple error_expr  `thenDs` \ tuple_expr ->
 592     newSysLocalDs tuple_ty                                      `thenDs` \ tuple_var ->
 593     let
 594         mk_tup_bind binder
 595           = (binder, mkTupleSelector binders binder tuple_var (Var tuple_var))
 596     in
 597     returnDs ( (tuple_var, tuple_expr) : map mk_tup_bind binders )
 598   where
 599     binders     = collectPatBinders pat
 600     local_tuple = mkTupleExpr binders
 601     tuple_ty    = exprType local_tuple
 602
 603     mk_bind scrut_var err_var bndr_var
 604     -- (mk_bind sv err_var) generates
 605     --          bv = case sv of { pat -> bv; other -> coerce (type-of-bv) err_var }
 606     -- Remember, pat binds bv
 607       = matchSimply (Var scrut_var) PatBindRhs pat
 608                     (Var bndr_var) error_expr                   `thenDs` \ rhs_expr ->
 609         returnDs (bndr_var, rhs_expr)
 610       where
 611         error_expr = mkCoerce (idType bndr_var) (Var err_var)
 612
 613     is_simple_lpat p = is_simple_pat (unLoc p)
 614
 615     is_simple_pat (TuplePat ps Boxed)      = all is_triv_lpat ps
 616     is_simple_pat (ConPatOut _ _ _ _ ps _) = all is_triv_lpat (hsConArgs ps)
 617     is_simple_pat (VarPat _)               = True
 618     is_simple_pat (ParPat p)               = is_simple_lpat p
 619     is_simple_pat other                    = False
 620
 621     is_triv_lpat p = is_triv_pat (unLoc p)
 622
 623     is_triv_pat (VarPat v)  = True
 624     is_triv_pat (WildPat _) = True
 625     is_triv_pat (ParPat p)  = is_triv_lpat p
 626     is_triv_pat other       = False
 627 \end{code}
 628
 629
 630 %************************************************************************
 631 %*                                                                      *
 632                 Tuples
 633 %*                                                                      *
 634 %************************************************************************
 635
 636 @mkTupleExpr@ builds a tuple; the inverse to @mkTupleSelector@.
 637
 638 * If it has only one element, it is the identity function.
 639
 640 * If there are more elements than a big tuple can have, it nests
 641   the tuples.
 642
 643 Nesting policy.  Better a 2-tuple of 10-tuples (3 objects) than
 644 a 10-tuple of 2-tuples (11 objects).  So we want the leaves to be big.
 645
 646 \begin{code}
 647 mkTupleExpr :: [Id] -> CoreExpr
 648 mkTupleExpr ids = mkBigCoreTup (map Var ids)
 649
 650 -- corresponding type
 651 mkTupleType :: [Id] -> Type
 652 mkTupleType ids = mkBigTuple mkCoreTupTy (map idType ids)
 653
 654 mkBigCoreTup :: [CoreExpr] -> CoreExpr
 655 mkBigCoreTup = mkBigTuple mkCoreTup
 656
 657 mkBigTuple :: ([a] -> a) -> [a] -> a
 658 mkBigTuple small_tuple as = mk_big_tuple (chunkify as)
 659   where
 660         -- Each sub-list is short enough to fit in a tuple
 661     mk_big_tuple [as] = small_tuple as
 662     mk_big_tuple as_s = mk_big_tuple (chunkify (map small_tuple as_s))
 663
 664 chunkify :: [a] -> [[a]]
 665 -- The sub-lists of the result all have length <= mAX_TUPLE_SIZE
 666 -- But there may be more than mAX_TUPLE_SIZE sub-lists
 667 chunkify xs
 668   | n_xs <= mAX_TUPLE_SIZE = {- pprTrace "Small" (ppr n_xs) -} [xs]
 669   | otherwise              = {- pprTrace "Big"   (ppr n_xs) -} (split xs)
 670   where
 671     n_xs     = length xs
 672     split [] = []
 673     split xs = take mAX_TUPLE_SIZE xs : split (drop mAX_TUPLE_SIZE xs)
 674 \end{code}
 675
 676
 677 @mkTupleSelector@ builds a selector which scrutises the given
 678 expression and extracts the one name from the list given.
 679 If you want the no-shadowing rule to apply, the caller
 680 is responsible for making sure that none of these names
 681 are in scope.
 682
 683 If there is just one id in the ``tuple'', then the selector is
 684 just the identity.
 685
 686 If it's big, it does nesting
 687         mkTupleSelector [a,b,c,d] b v e
 688           = case e of v {
 689                 (p,q) -> case p of p {
 690                            (a,b) -> b }}
 691 We use 'tpl' vars for the p,q, since shadowing does not matter.
 692
 693 In fact, it's more convenient to generate it innermost first, getting
 694
 695         case (case e of v
 696                 (p,q) -> p) of p
 697           (a,b) -> b
 698
 699 \begin{code}
 700 mkTupleSelector :: [Id]         -- The tuple args
 701                 -> Id           -- The selected one
 702                 -> Id           -- A variable of the same type as the scrutinee
 703                 -> CoreExpr     -- Scrutinee
 704                 -> CoreExpr
 705
 706 mkTupleSelector vars the_var scrut_var scrut
 707   = mk_tup_sel (chunkify vars) the_var
 708   where
 709     mk_tup_sel [vars] the_var = mkCoreSel vars the_var scrut_var scrut
 710     mk_tup_sel vars_s the_var = mkCoreSel group the_var tpl_v $
 711                                 mk_tup_sel (chunkify tpl_vs) tpl_v
 712         where
 713           tpl_tys = [mkCoreTupTy (map idType gp) | gp <- vars_s]
 714           tpl_vs  = mkTemplateLocals tpl_tys
 715           [(tpl_v, group)] = [(tpl,gp) | (tpl,gp) <- zipEqual "mkTupleSelector" tpl_vs vars_s,
 716                                          the_var `elem` gp ]
 717 \end{code}
 718
 719 A generalization of @mkTupleSelector@, allowing the body
 720 of the case to be an arbitrary expression.
 721
 722 If the tuple is big, it is nested:
 723
 724         mkTupleCase uniqs [a,b,c,d] body v e
 725           = case e of v { (p,q) ->
 726             case p of p { (a,b) ->
 727             case q of q { (c,d) ->
 728             body }}}
 729
 730 To avoid shadowing, we use uniqs to invent new variables p,q.
 731
 732 ToDo: eliminate cases where none of the variables are needed.
 733
 734 \begin{code}
 735 mkTupleCase
 736         :: UniqSupply   -- for inventing names of intermediate variables
 737         -> [Id]         -- the tuple args
 738         -> CoreExpr     -- body of the case
 739         -> Id           -- a variable of the same type as the scrutinee
 740         -> CoreExpr     -- scrutinee
 741         -> CoreExpr
 742
 743 mkTupleCase uniqs vars body scrut_var scrut
 744   = mk_tuple_case uniqs (chunkify vars) body
 745   where
 746     mk_tuple_case us [vars] body
 747       = mkSmallTupleCase vars body scrut_var scrut
 748     mk_tuple_case us vars_s body
 749       = let
 750             (us', vars', body') = foldr one_tuple_case (us, [], body) vars_s
 751         in
 752         mk_tuple_case us' (chunkify vars') body'
 753     one_tuple_case chunk_vars (us, vs, body)
 754       = let
 755             (us1, us2) = splitUniqSupply us
 756             scrut_var = mkSysLocal FSLIT("ds") (uniqFromSupply us1)
 757                         (mkCoreTupTy (map idType chunk_vars))
 758             body' = mkSmallTupleCase chunk_vars body scrut_var (Var scrut_var)
 759         in (us2, scrut_var:vs, body')
 760 \end{code}
 761
 762 The same, but with a tuple small enough not to need nesting.
 763
 764 \begin{code}
 765 mkSmallTupleCase
 766         :: [Id]         -- the tuple args
 767         -> CoreExpr     -- body of the case
 768         -> Id           -- a variable of the same type as the scrutinee
 769         -> CoreExpr     -- scrutinee
 770         -> CoreExpr
 771
 772 mkSmallTupleCase [var] body _scrut_var scrut
 773   = bindNonRec var scrut body
 774 mkSmallTupleCase vars body scrut_var scrut
 775 -- gaw 2004
 776 -- One branch no refinement?
 777   = Case scrut scrut_var (exprType body) [(DataAlt (tupleCon Boxed (length vars)), vars, body)]
 778 \end{code}
 779
 780 %************************************************************************
 781 %*                                                                      *
 782 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 783 %*                                                                      *
 784 %************************************************************************
 785
 786 Call the constructor Ids when building explicit lists, so that they
 787 interact well with rules.
 788
 789 \begin{code}
 790 mkNilExpr :: Type -> CoreExpr
 791 mkNilExpr ty = mkConApp nilDataCon [Type ty]
 792
 793 mkConsExpr :: Type -> CoreExpr -> CoreExpr -> CoreExpr
 794 mkConsExpr ty hd tl = mkConApp consDataCon [Type ty, hd, tl]
 795
 796 mkListExpr :: Type -> [CoreExpr] -> CoreExpr
 797 mkListExpr ty xs = foldr (mkConsExpr ty) (mkNilExpr ty) xs
 798
 799
 800 -- The next three functions make tuple types, constructors and selectors,
 801 -- with the rule that a 1-tuple is represented by the thing itselg
 802 mkCoreTupTy :: [Type] -> Type
 803 mkCoreTupTy [ty] = ty
 804 mkCoreTupTy tys  = mkTupleTy Boxed (length tys) tys
 805
 806 mkCoreTup :: [CoreExpr] -> CoreExpr
 807 -- Builds exactly the specified tuple.
 808 -- No fancy business for big tuples
 809 mkCoreTup []  = Var unitDataConId
 810 mkCoreTup [c] = c
 811 mkCoreTup cs  = mkConApp (tupleCon Boxed (length cs))
 812                          (map (Type . exprType) cs ++ cs)
 813
 814 mkCoreSel :: [Id]       -- The tuple args
 815           -> Id         -- The selected one
 816           -> Id         -- A variable of the same type as the scrutinee
 817           -> CoreExpr   -- Scrutinee
 818           -> CoreExpr
 819 -- mkCoreSel [x,y,z] x v e
 820 -- ===>  case e of v { (x,y,z) -> x
 821 mkCoreSel [var] should_be_the_same_var scrut_var scrut
 822   = ASSERT(var == should_be_the_same_var)
 823     scrut
 824
 825 mkCoreSel vars the_var scrut_var scrut
 826   = ASSERT( notNull vars )
 827 -- gaw 2004
 828     Case scrut scrut_var (idType the_var)
 829          [(DataAlt (tupleCon Boxed (length vars)), vars, Var the_var)]
 830 \end{code}
 831
 832
 833 %************************************************************************
 834 %*                                                                      *
 835 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
 836 %*                                                                      *
 837 %************************************************************************
 838
 839 Generally, we handle pattern matching failure like this: let-bind a
 840 fail-variable, and use that variable if the thing fails:
 841 \begin{verbatim}
 842         let fail.33 = error "Help"
 843         in
 844         case x of
 845                 p1 -> ...
 846                 p2 -> fail.33
 847                 p3 -> fail.33
 848                 p4 -> ...
 849 \end{verbatim}
 850 Then
 851 \begin{itemize}
 852 \item
 853 If the case can't fail, then there'll be no mention of @fail.33@, and the
 854 simplifier will later discard it.
 855
 856 \item
 857 If it can fail in only one way, then the simplifier will inline it.
 858
 859 \item
 860 Only if it is used more than once will the let-binding remain.
 861 \end{itemize}
 862
 863 There's a problem when the result of the case expression is of
 864 unboxed type.  Then the type of @fail.33@ is unboxed too, and
 865 there is every chance that someone will change the let into a case:
 866 \begin{verbatim}
 867         case error "Help" of
 868           fail.33 -> case ....
 869 \end{verbatim}
 870
 871 which is of course utterly wrong.  Rather than drop the condition that
 872 only boxed types can be let-bound, we just turn the fail into a function
 873 for the primitive case:
 874 \begin{verbatim}
 875         let fail.33 :: Void -> Int#
 876             fail.33 = \_ -> error "Help"
 877         in
 878         case x of
 879                 p1 -> ...
 880                 p2 -> fail.33 void
 881                 p3 -> fail.33 void
 882                 p4 -> ...
 883 \end{verbatim}
 884
 885 Now @fail.33@ is a function, so it can be let-bound.
 886
 887 \begin{code}
 888 mkFailurePair :: CoreExpr       -- Result type of the whole case expression
 889               -> DsM (CoreBind, -- Binds the newly-created fail variable
 890                                 -- to either the expression or \ _ -> expression
 891                       CoreExpr) -- Either the fail variable, or fail variable
 892                                 -- applied to unit tuple
 893 mkFailurePair expr
 894   | isUnLiftedType ty
 895   = newFailLocalDs (unitTy `mkFunTy` ty)        `thenDs` \ fail_fun_var ->
 896     newSysLocalDs unitTy                        `thenDs` \ fail_fun_arg ->
 897     returnDs (NonRec fail_fun_var (Lam fail_fun_arg expr),
 898               App (Var fail_fun_var) (Var unitDataConId))
 899
 900   | otherwise
 901   = newFailLocalDs ty           `thenDs` \ fail_var ->
 902     returnDs (NonRec fail_var expr, Var fail_var)
 903   where
 904     ty = exprType expr
 905 \end{code}
 906
 907