ghc/compiler/ghci/ByteCodeGen.lhs

   1 %
   2 % (c) The University of Glasgow 2002
   3 %
   4 \section[ByteCodeGen]{Generate bytecode from Core}
   5
   6 \begin{code}
   7 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
   8
   9 #include "HsVersions.h"
  10
  11 import ByteCodeInstr
  12 import ByteCodeFFI      ( mkMarshalCode, moan64 )
  13 import ByteCodeAsm      ( CompiledByteCode(..), UnlinkedBCO,
  14                           assembleBCO, assembleBCOs, iNTERP_STACK_CHECK_THRESH )
  15 import ByteCodeLink     ( lookupStaticPtr )
  16
  17 import Outputable
  18 import Name             ( Name, getName, mkSystemName )
  19 import Id
  20 import FiniteMap
  21 import ForeignCall      ( ForeignCall(..), CCallTarget(..), CCallSpec(..) )
  22 import HscTypes         ( ModGuts(..), ModGuts, typeEnvTyCons, typeEnvClasses )
  23 import CoreUtils        ( exprType )
  24 import CoreSyn
  25 import PprCore          ( pprCoreExpr )
  26 import Literal          ( Literal(..), literalPrimRep )
  27 import PrimRep
  28 import PrimOp           ( PrimOp(..) )
  29 import CoreFVs          ( freeVars )
  30 import Type             ( typePrimRep, isUnLiftedType, splitTyConApp_maybe,
  31                           isTyVarTy )
  32 import DataCon          ( DataCon, dataConTag, fIRST_TAG, dataConTyCon,
  33                           isUnboxedTupleCon, isNullaryDataCon, dataConWorkId,
  34                           dataConRepArity )
  35 import TyCon            ( tyConFamilySize, isDataTyCon, tyConDataCons,
  36                           isFunTyCon, isUnboxedTupleTyCon )
  37 import Class            ( Class, classTyCon )
  38 import Type             ( Type, repType, splitFunTys, dropForAlls )
  39 import Util
  40 import DataCon          ( dataConRepArity )
  41 import Var              ( isTyVar )
  42 import VarSet           ( VarSet, varSetElems )
  43 import TysPrim          ( foreignObjPrimTyCon,
  44                           arrayPrimTyCon, mutableArrayPrimTyCon,
  45                           byteArrayPrimTyCon, mutableByteArrayPrimTyCon
  46                         )
  47 import PrimRep          ( isFollowableRep )
  48 import CmdLineOpts      ( DynFlags, DynFlag(..) )
  49 import ErrUtils         ( showPass, dumpIfSet_dyn )
  50 import Unique           ( mkPseudoUnique3 )
  51 import FastString       ( FastString(..), unpackFS )
  52 import Panic            ( GhcException(..) )
  53 import PprType          ( pprType )
  54 import SMRep            ( arrWordsHdrSize, arrPtrsHdrSize )
  55 import OrdList
  56 import Constants        ( wORD_SIZE )
  57 import BasicTypes       ( TopLevelFlag(..), isTopLevel, isNotTopLevel )
  58
  59 import Data.List        ( intersperse, sortBy, zip4, zip5, partition )
  60 import Foreign          ( Ptr, castPtr, mallocBytes, pokeByteOff, Word8 )
  61 import Foreign.C        ( CInt )
  62 import Control.Exception        ( throwDyn )
  63
  64 import GHC.Exts         ( Int(..), ByteArray# )
  65
  66 import Control.Monad    ( when, mapAndUnzipM )
  67 import Data.Char        ( ord )
  68 import Data.Bits
  69
  70 -- -----------------------------------------------------------------------------
  71 -- Generating byte code for a complete module
  72
  73 byteCodeGen :: DynFlags
  74             -> ModGuts
  75             -> IO CompiledByteCode
  76 byteCodeGen dflags (ModGuts { mg_binds = binds, mg_types = type_env })
  77    = do showPass dflags "ByteCodeGen"
  78         let  local_tycons  = typeEnvTyCons  type_env
  79              local_classes = typeEnvClasses type_env
  80              tycs = local_tycons ++ map classTyCon local_classes
  81
  82         let flatBinds = [ (bndr, freeVars rhs)
  83                         | (bndr, rhs) <- flattenBinds binds]
  84
  85         (BcM_State final_ctr mallocd, proto_bcos)
  86            <- runBc (mapM schemeTopBind flatBinds)
  87
  88         when (notNull mallocd)
  89              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
  90
  91         dumpIfSet_dyn dflags Opt_D_dump_BCOs
  92            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
  93
  94         assembleBCOs proto_bcos tycs
  95
  96 -- -----------------------------------------------------------------------------
  97 -- Generating byte code for an expression
  98
  99 -- Returns: (the root BCO for this expression,
 100 --           a list of auxilary BCOs resulting from compiling closures)
 101 coreExprToBCOs :: DynFlags
 102                -> CoreExpr
 103                -> IO UnlinkedBCO
 104 coreExprToBCOs dflags expr
 105  = do showPass dflags "ByteCodeGen"
 106
 107       -- create a totally bogus name for the top-level BCO; this
 108       -- should be harmless, since it's never used for anything
 109       let invented_name  = mkSystemName (mkPseudoUnique3 0) FSLIT("ExprTopLevel")
 110           invented_id    = mkLocalId invented_name (panic "invented_id's type")
 111
 112       (BcM_State final_ctr mallocd, proto_bco)
 113          <- runBc (schemeTopBind (invented_id, freeVars expr))
 114
 115       when (notNull mallocd)
 116            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
 117
 118       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
 119
 120       assembleBCO proto_bco
 121
 122
 123 -- -----------------------------------------------------------------------------
 124 -- Compilation schema for the bytecode generator
 125
 126 type BCInstrList = OrdList BCInstr
 127
 128 type Sequel = Int       -- back off to this depth before ENTER
 129
 130 -- Maps Ids to the offset from the stack _base_ so we don't have
 131 -- to mess with it after each push/pop.
 132 type BCEnv = FiniteMap Id Int   -- To find vars on the stack
 133
 134 ppBCEnv :: BCEnv -> SDoc
 135 ppBCEnv p
 136    = text "begin-env"
 137      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (fmToList p))))
 138      $$ text "end-env"
 139      where
 140         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (idPrimRep var)
 141         cmp_snd x y = compare (snd x) (snd y)
 142
 143 -- Create a BCO and do a spot of peephole optimisation on the insns
 144 -- at the same time.
 145 mkProtoBCO
 146    :: name
 147    -> BCInstrList
 148    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
 149    -> Int
 150    -> Int
 151    -> [StgWord]
 152    -> Bool      -- True <=> is a return point, rather than a function
 153    -> [Ptr ()]
 154    -> ProtoBCO name
 155 mkProtoBCO nm instrs_ordlist origin arity bitmap_size bitmap
 156   is_ret mallocd_blocks
 157    = ProtoBCO {
 158         protoBCOName = nm,
 159         protoBCOInstrs = maybe_with_stack_check,
 160         protoBCOBitmap = bitmap,
 161         protoBCOBitmapSize = bitmap_size,
 162         protoBCOArity = arity,
 163         protoBCOExpr = origin,
 164         protoBCOPtrs = mallocd_blocks
 165       }
 166      where
 167         -- Overestimate the stack usage (in words) of this BCO,
 168         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
 169         -- stack check.  (The interpreter always does a stack check
 170         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
 171         -- BCO anyway, so we only need to add an explicit on in the
 172         -- (hopefully rare) cases when the (overestimated) stack use
 173         -- exceeds iNTERP_STACK_CHECK_THRESH.
 174         maybe_with_stack_check
 175            | is_ret = peep_d
 176                 -- don't do stack checks at return points;
 177                 -- everything is aggregated up to the top BCO
 178                 -- (which must be a function)
 179            | stack_overest >= 65535
 180            = pprPanic "mkProtoBCO: stack use won't fit in 16 bits"
 181                       (int stack_overest)
 182            | stack_overest >= iNTERP_STACK_CHECK_THRESH
 183            = STKCHECK stack_overest : peep_d
 184            | otherwise
 185            = peep_d     -- the supposedly common case
 186
 187         stack_overest = sum (map bciStackUse peep_d)
 188
 189         -- Merge local pushes
 190         peep_d = peep (fromOL instrs_ordlist)
 191
 192         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
 193            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
 194         peep (PUSH_L off1 : PUSH_L off2 : rest)
 195            = PUSH_LL off1 (off2-1) : peep rest
 196         peep (i:rest)
 197            = i : peep rest
 198         peep []
 199            = []
 200
 201 argBits :: [PrimRep] -> [Bool]
 202 argBits [] = []
 203 argBits (rep : args)
 204   | isFollowableRep rep = False : argBits args
 205   | otherwise = take (getPrimRepSize rep) (repeat True) ++ argBits args
 206
 207 mkBitmap :: [Bool] -> [StgWord]
 208 mkBitmap [] = []
 209 mkBitmap stuff = chunkToLiveness chunk : mkBitmap rest
 210   where (chunk, rest) = splitAt wORD_SIZE_IN_BITS stuff
 211
 212 chunkToLiveness :: [Bool] -> StgWord
 213 chunkToLiveness chunk =
 214   foldr (.|.) 0 [ 1 `shiftL` n | (True,n) <- zip chunk [0..] ]
 215
 216 -- make a bitmap where the slots specified are the *zeros* in the bitmap.
 217 -- eg. [1,2,4], size 4 ==> 0x8  (we leave any bits outside the size as zero,
 218 -- just to make the bitmap easier to read).
 219 intsToBitmap :: Int -> [Int] -> [StgWord]
 220 intsToBitmap size slots{- must be sorted -}
 221   | size <= 0 = []
 222   | otherwise =
 223     (foldr xor init (map (1 `shiftL`) these)) :
 224         intsToBitmap (size - wORD_SIZE_IN_BITS)
 225              (map (\x -> x - wORD_SIZE_IN_BITS) rest)
 226    where (these,rest) = span (<wORD_SIZE_IN_BITS) slots
 227          init
 228            | size >= wORD_SIZE_IN_BITS = complement 0
 229            | otherwise                 = (1 `shiftL` size) - 1
 230
 231 wORD_SIZE_IN_BITS = wORD_SIZE * 8 :: Int
 232
 233 -- -----------------------------------------------------------------------------
 234 -- schemeTopBind
 235
 236 -- Compile code for the right-hand side of a top-level binding
 237
 238 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
 239
 240
 241 schemeTopBind (id, rhs)
 242   | Just data_con <- isDataConWorkId_maybe id,
 243     isNullaryDataCon data_con
 244   =     -- Special case for the worker of a nullary data con.
 245         -- It'll look like this:        Nil = /\a -> Nil a
 246         -- If we feed it into schemeR, we'll get
 247         --      Nil = Nil
 248         -- because mkConAppCode treats nullary constructor applications
 249         -- by just re-using the single top-level definition.  So
 250         -- for the worker itself, we must allocate it directly.
 251     emitBc (mkProtoBCO (getName id) (toOL [PACK data_con 0, ENTER])
 252                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
 253
 254   | otherwise
 255   = schemeR [{- No free variables -}] (id, rhs)
 256
 257 -- -----------------------------------------------------------------------------
 258 -- schemeR
 259
 260 -- Compile code for a right-hand side, to give a BCO that,
 261 -- when executed with the free variables and arguments on top of the stack,
 262 -- will return with a pointer to the result on top of the stack, after
 263 -- removing the free variables and arguments.
 264 --
 265 -- Park the resulting BCO in the monad.  Also requires the
 266 -- variable to which this value was bound, so as to give the
 267 -- resulting BCO a name.
 268
 269 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
 270                                 -- will appear in the thunk.  Empty for
 271                                 -- top-level things, which have no free vars.
 272         -> (Id, AnnExpr Id VarSet)
 273         -> BcM (ProtoBCO Name)
 274 schemeR fvs (nm, rhs)
 275 {-
 276    | trace (showSDoc (
 277               (char ' '
 278                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
 279                $$ pprCoreExpr (deAnnotate rhs)
 280                $$ char ' '
 281               ))) False
 282    = undefined
 283    | otherwise
 284 -}
 285    = schemeR_wrk fvs nm rhs (collect [] rhs)
 286
 287 collect xs (_, AnnNote note e) = collect xs e
 288 collect xs (_, AnnLam x e)     = collect (if isTyVar x then xs else (x:xs)) e
 289 collect xs (_, not_lambda)     = (reverse xs, not_lambda)
 290
 291 schemeR_wrk fvs nm original_body (args, body)
 292    = let
 293          all_args  = reverse args ++ fvs
 294          arity     = length all_args
 295          -- all_args are the args in reverse order.  We're compiling a function
 296          -- \fv1..fvn x1..xn -> e
 297          -- i.e. the fvs come first
 298
 299          szsw_args = map idSizeW all_args
 300          szw_args  = sum szsw_args
 301          p_init    = listToFM (zip all_args (mkStackOffsets 0 szsw_args))
 302
 303          -- make the arg bitmap
 304          bits = argBits (reverse (map idPrimRep all_args))
 305          bitmap_size = length bits
 306          bitmap = mkBitmap bits
 307      in
 308      schemeE szw_args 0 p_init body             `thenBc` \ body_code ->
 309      emitBc (mkProtoBCO (getName nm) body_code (Right original_body)
 310                 arity bitmap_size bitmap False{-not alts-})
 311
 312
 313 fvsToEnv :: BCEnv -> VarSet -> [Id]
 314 -- Takes the free variables of a right-hand side, and
 315 -- delivers an ordered list of the local variables that will
 316 -- be captured in the thunk for the RHS
 317 -- The BCEnv argument tells which variables are in the local
 318 -- environment: these are the ones that should be captured
 319 --
 320 -- The code that constructs the thunk, and the code that executes
 321 -- it, have to agree about this layout
 322 fvsToEnv p fvs = [v | v <- varSetElems fvs,
 323                       isId v,           -- Could be a type variable
 324                       v `elemFM` p]
 325
 326 -- -----------------------------------------------------------------------------
 327 -- schemeE
 328
 329 -- Compile code to apply the given expression to the remaining args
 330 -- on the stack, returning a HNF.
 331 schemeE :: Int -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
 332
 333 -- Delegate tail-calls to schemeT.
 334 schemeE d s p e@(AnnApp f a)
 335    = schemeT d s p e
 336
 337 schemeE d s p e@(AnnVar v)
 338    | not (isUnLiftedType v_type)
 339    =  -- Lifted-type thing; push it in the normal way
 340      schemeT d s p e
 341
 342    | otherwise
 343    = -- Returning an unlifted value.
 344      -- Heave it on the stack, SLIDE, and RETURN.
 345      pushAtom d p (AnnVar v)    `thenBc` \ (push, szw) ->
 346      returnBc (push                     -- value onto stack
 347                `appOL`  mkSLIDE szw (d-s)       -- clear to sequel
 348                `snocOL` RETURN_UBX v_rep)       -- go
 349    where
 350       v_type = idType v
 351       v_rep = typePrimRep v_type
 352
 353 schemeE d s p (AnnLit literal)
 354    = pushAtom d p (AnnLit literal)      `thenBc` \ (push, szw) ->
 355      let l_rep = literalPrimRep literal
 356      in  returnBc (push                         -- value onto stack
 357                    `appOL`  mkSLIDE szw (d-s)   -- clear to sequel
 358                    `snocOL` RETURN_UBX l_rep)   -- go
 359
 360
 361 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
 362    | (AnnVar v, args_r_to_l) <- splitApp rhs,
 363      Just data_con <- isDataConWorkId_maybe v,
 364      dataConRepArity data_con == length args_r_to_l
 365    =    -- Special case for a non-recursive let whose RHS is a
 366         -- saturatred constructor application.
 367         -- Just allocate the constructor and carry on
 368      mkConAppCode d s p data_con args_r_to_l    `thenBc` \ alloc_code ->
 369      schemeE (d+1) s (addToFM p x d) body       `thenBc` \ body_code ->
 370      returnBc (alloc_code `appOL` body_code)
 371
 372 -- General case for let.  Generates correct, if inefficient, code in
 373 -- all situations.
 374 schemeE d s p (AnnLet binds (_,body))
 375    = let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
 376                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
 377          n_binds = length xs
 378
 379          fvss  = map (fvsToEnv p' . fst) rhss
 380
 381          -- Sizes of free vars, + 1 for the fn
 382          sizes = map (\rhs_fvs -> 1 + sum (map idSizeW rhs_fvs)) fvss
 383
 384          -- the arity of each rhs
 385          arities = map (length . fst . collect []) rhss
 386
 387          -- This p', d' defn is safe because all the items being pushed
 388          -- are ptrs, so all have size 1.  d' and p' reflect the stack
 389          -- after the closures have been allocated in the heap (but not
 390          -- filled in), and pointers to them parked on the stack.
 391          p'    = addListToFM p (zipE xs (mkStackOffsets d (nOfThem n_binds 1)))
 392          d'    = d + n_binds
 393          zipE  = zipEqual "schemeE"
 394
 395          -- ToDo: don't build thunks for things with no free variables
 396          build_thunk dd [] size bco off
 397             = returnBc (PUSH_BCO bco
 398                         `consOL` unitOL (MKAP (off+size-1) size))
 399          build_thunk dd (fv:fvs) size bco off = do
 400               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
 401               more_push_code <- build_thunk (dd+pushed_szw) fvs size bco off
 402               returnBc (push_code `appOL` more_push_code)
 403
 404          alloc_code = toOL (zipWith mkAlloc sizes arities)
 405            where mkAlloc sz 0     = ALLOC_AP sz
 406                  mkAlloc sz arity = ALLOC_PAP arity sz
 407
 408          compile_bind d' fvs x rhs size off = do
 409                 bco <- schemeR fvs (x,rhs)
 410                 build_thunk d' fvs size bco off
 411
 412          compile_binds =
 413             [ compile_bind d' fvs x rhs size n
 414             | (fvs, x, rhs, size, n) <-
 415                 zip5 fvss xs rhss sizes [n_binds, n_binds-1 .. 1]
 416             ]
 417      in do
 418      body_code <- schemeE d' s p' body
 419      thunk_codes <- sequence compile_binds
 420      returnBc (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
 421
 422
 423
 424 schemeE d s p (AnnCase scrut bndr [(DataAlt dc, [bind1, bind2], rhs)])
 425    | isUnboxedTupleCon dc && VoidRep == typePrimRep (idType bind1)
 426         -- Convert
 427         --      case .... of x { (# VoidRep'd-thing, a #) -> ... }
 428         -- to
 429         --      case .... of a { DEFAULT -> ... }
 430         -- becuse the return convention for both are identical.
 431         --
 432         -- Note that it does not matter losing the void-rep thing from the
 433         -- envt (it won't be bound now) because we never look such things up.
 434
 435    = --trace "automagic mashing of case alts (# VoidRep, a #)" $
 436      doCase d s p scrut bind2 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 437
 438    | isUnboxedTupleCon dc && VoidRep == typePrimRep (idType bind2)
 439    = --trace "automagic mashing of case alts (# a, VoidRep #)" $
 440      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 441
 442 schemeE d s p (AnnCase scrut bndr [(DataAlt dc, [bind1], rhs)])
 443    | isUnboxedTupleCon dc
 444         -- Similarly, convert
 445         --      case .... of x { (# a #) -> ... }
 446         -- to
 447         --      case .... of a { DEFAULT -> ... }
 448    = --trace "automagic mashing of case alts (# a #)"  $
 449      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
 450
 451 schemeE d s p (AnnCase scrut bndr alts)
 452    = doCase d s p scrut bndr alts False{-not an unboxed tuple-}
 453
 454 schemeE d s p (AnnNote note (_, body))
 455    = schemeE d s p body
 456
 457 schemeE d s p other
 458    = pprPanic "ByteCodeGen.schemeE: unhandled case"
 459                (pprCoreExpr (deAnnotate' other))
 460
 461
 462 -- Compile code to do a tail call.  Specifically, push the fn,
 463 -- slide the on-stack app back down to the sequel depth,
 464 -- and enter.  Four cases:
 465 --
 466 -- 0.  (Nasty hack).
 467 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
 468 --     The int will be on the stack.  Generate a code sequence
 469 --     to convert it to the relevant constructor, SLIDE and ENTER.
 470 --
 471 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
 472 --
 473 -- 2.  (Another nasty hack).  Spot (# a::VoidRep, b #) and treat
 474 --     it simply as  b  -- since the representations are identical
 475 --     (the VoidRep takes up zero stack space).  Also, spot
 476 --     (# b #) and treat it as  b.
 477 --
 478 -- 3.  Application of a constructor, by defn saturated.
 479 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
 480 --     then the ptrs, and then do PACK and RETURN.
 481 --
 482 -- 4.  Otherwise, it must be a function call.  Push the args
 483 --     right to left, SLIDE and ENTER.
 484
 485 schemeT :: Int          -- Stack depth
 486         -> Sequel       -- Sequel depth
 487         -> BCEnv        -- stack env
 488         -> AnnExpr' Id VarSet
 489         -> BcM BCInstrList
 490
 491 schemeT d s p app
 492
 493 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
 494 --   = panic "schemeT ?!?!"
 495
 496 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
 497 --   = error "?!?!"
 498
 499    -- Case 0
 500    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
 501    = pushAtom d p arg                   `thenBc` \ (push, arg_words) ->
 502      implement_tagToId constr_names     `thenBc` \ tagToId_sequence ->
 503      returnBc (push `appOL`  tagToId_sequence
 504                     `appOL`  mkSLIDE 1 (d+arg_words-s)
 505                     `snocOL` ENTER)
 506
 507    -- Case 1
 508    | Just (CCall ccall_spec) <- isFCallId_maybe fn
 509    = generateCCall d s p ccall_spec fn args_r_to_l
 510
 511    -- Case 2: Constructor application
 512    | Just con <- maybe_saturated_dcon,
 513      isUnboxedTupleCon con
 514    = case args_r_to_l of
 515         [arg1,arg2] | isVoidRepAtom arg1 ->
 516                   unboxedTupleReturn d s p arg2
 517         [arg1,arg2] | isVoidRepAtom arg2 ->
 518                   unboxedTupleReturn d s p arg1
 519         _other -> unboxedTupleException
 520
 521    -- Case 3: Ordinary data constructor
 522    | Just con <- maybe_saturated_dcon
 523    = mkConAppCode d s p con args_r_to_l `thenBc` \ alloc_con ->
 524      returnBc (alloc_con         `appOL`
 525                mkSLIDE 1 (d - s) `snocOL`
 526                ENTER)
 527
 528    -- Case 4: Tail call of function
 529    | otherwise
 530    = doTailCall d s p fn args_r_to_l
 531
 532    where
 533       -- Detect and extract relevant info for the tagToEnum kludge.
 534       maybe_is_tagToEnum_call
 535          = let extract_constr_Names ty
 536                   = case splitTyConApp_maybe (repType ty) of
 537                        (Just (tyc, [])) |  isDataTyCon tyc
 538                                         -> map getName (tyConDataCons tyc)
 539                        other -> panic "maybe_is_tagToEnum_call.extract_constr_Ids"
 540            in
 541            case app of
 542               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
 543                  -> case isPrimOpId_maybe v of
 544                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
 545                        other            -> Nothing
 546               other -> Nothing
 547
 548         -- Extract the args (R->L) and fn
 549         -- The function will necessarily be a variable,
 550         -- because we are compiling a tail call
 551       (AnnVar fn, args_r_to_l) = splitApp app
 552
 553       -- Only consider this to be a constructor application iff it is
 554       -- saturated.  Otherwise, we'll call the constructor wrapper.
 555       n_args = length args_r_to_l
 556       maybe_saturated_dcon
 557         = case isDataConWorkId_maybe fn of
 558                 Just con | dataConRepArity con == n_args -> Just con
 559                 _ -> Nothing
 560
 561 -- -----------------------------------------------------------------------------
 562 -- Generate code to build a constructor application,
 563 -- leaving it on top of the stack
 564
 565 mkConAppCode :: Int -> Sequel -> BCEnv
 566              -> DataCon                 -- The data constructor
 567              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
 568              -> BcM BCInstrList
 569
 570 mkConAppCode orig_d s p con []  -- Nullary constructor
 571   = ASSERT( isNullaryDataCon con )
 572     returnBc (unitOL (PUSH_G (getName (dataConWorkId con))))
 573         -- Instead of doing a PACK, which would allocate a fresh
 574         -- copy of this constructor, use the single shared version.
 575
 576 mkConAppCode orig_d s p con args_r_to_l
 577   = ASSERT( dataConRepArity con == length args_r_to_l )
 578     do_pushery orig_d (non_ptr_args ++ ptr_args)
 579  where
 580         -- The args are already in reverse order, which is the way PACK
 581         -- expects them to be.  We must push the non-ptrs after the ptrs.
 582       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
 583
 584       do_pushery d (arg:args)
 585          = pushAtom d p arg                     `thenBc` \ (push, arg_words) ->
 586            do_pushery (d+arg_words) args        `thenBc` \ more_push_code ->
 587            returnBc (push `appOL` more_push_code)
 588       do_pushery d []
 589          = returnBc (unitOL (PACK con n_arg_words))
 590          where
 591            n_arg_words = d - orig_d
 592
 593
 594 -- -----------------------------------------------------------------------------
 595 -- Returning an unboxed tuple with one non-void component (the only
 596 -- case we can handle).
 597 --
 598 -- Remember, we don't want to *evaluate* the component that is being
 599 -- returned, even if it is a pointed type.  We always just return.
 600
 601 unboxedTupleReturn
 602         :: Int -> Sequel -> BCEnv
 603         -> AnnExpr' Id VarSet -> BcM BCInstrList
 604 unboxedTupleReturn d s p arg = do
 605   (push, sz) <- pushAtom d p arg
 606   returnBc (push `appOL`
 607             mkSLIDE sz (d-s) `snocOL`
 608             RETURN_UBX (atomRep arg))
 609
 610 -- -----------------------------------------------------------------------------
 611 -- Generate code for a tail-call
 612
 613 doTailCall
 614         :: Int -> Sequel -> BCEnv
 615         -> Id -> [AnnExpr' Id VarSet]
 616         -> BcM BCInstrList
 617 doTailCall init_d s p fn args
 618   = do_pushes init_d args (map (primRepToArgRep.atomRep) args)
 619   where
 620   do_pushes d [] reps = do
 621         ASSERTM( null reps )
 622         (push_fn, sz) <- pushAtom d p (AnnVar fn)
 623         ASSERTM( sz == 1 )
 624         returnBc (push_fn `appOL` (
 625                   mkSLIDE ((d-init_d) + 1) (init_d - s) `appOL`
 626                   unitOL ENTER))
 627   do_pushes d args reps = do
 628       let (push_apply, n, rest_of_reps) = findPushSeq reps
 629           (these_args, rest_of_args) = splitAt n args
 630       (next_d, push_code) <- push_seq d these_args
 631       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
 632                 --                ^^^ for the PUSH_APPLY_ instruction
 633       returnBc (push_code `appOL` (push_apply `consOL` instrs))
 634
 635   push_seq d [] = return (d, nilOL)
 636   push_seq d (arg:args) = do
 637     (push_code, sz) <- pushAtom d p arg
 638     (final_d, more_push_code) <- push_seq (d+sz) args
 639     return (final_d, push_code `appOL` more_push_code)
 640
 641 -- v. similar to CgStackery.findMatch, ToDo: merge
 642 findPushSeq (RepP: RepP: RepP: RepP: RepP: RepP: RepP: rest)
 643   = (PUSH_APPLY_PPPPPPP, 7, rest)
 644 findPushSeq (RepP: RepP: RepP: RepP: RepP: RepP: rest)
 645   = (PUSH_APPLY_PPPPPP, 6, rest)
 646 findPushSeq (RepP: RepP: RepP: RepP: RepP: rest)
 647   = (PUSH_APPLY_PPPPP, 5, rest)
 648 findPushSeq (RepP: RepP: RepP: RepP: rest)
 649   = (PUSH_APPLY_PPPP, 4, rest)
 650 findPushSeq (RepP: RepP: RepP: rest)
 651   = (PUSH_APPLY_PPP, 3, rest)
 652 findPushSeq (RepP: RepP: rest)
 653   = (PUSH_APPLY_PP, 2, rest)
 654 findPushSeq (RepP: rest)
 655   = (PUSH_APPLY_P, 1, rest)
 656 findPushSeq (RepV: rest)
 657   = (PUSH_APPLY_V, 1, rest)
 658 findPushSeq (RepN: rest)
 659   = (PUSH_APPLY_N, 1, rest)
 660 findPushSeq (RepF: rest)
 661   = (PUSH_APPLY_F, 1, rest)
 662 findPushSeq (RepD: rest)
 663   = (PUSH_APPLY_D, 1, rest)
 664 findPushSeq (RepL: rest)
 665   = (PUSH_APPLY_L, 1, rest)
 666 findPushSeq _
 667   = panic "ByteCodeGen.findPushSeq"
 668
 669 -- -----------------------------------------------------------------------------
 670 -- Case expressions
 671
 672 doCase  :: Int -> Sequel -> BCEnv
 673         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
 674         -> Bool  -- True <=> is an unboxed tuple case, don't enter the result
 675         -> BcM BCInstrList
 676 doCase d s p (_,scrut)
 677  bndr alts is_unboxed_tuple
 678   = let
 679         -- Top of stack is the return itbl, as usual.
 680         -- underneath it is the pointer to the alt_code BCO.
 681         -- When an alt is entered, it assumes the returned value is
 682         -- on top of the itbl.
 683         ret_frame_sizeW = 2
 684
 685         -- An unlifted value gets an extra info table pushed on top
 686         -- when it is returned.
 687         unlifted_itbl_sizeW | isAlgCase = 0
 688                             | otherwise = 1
 689
 690         -- depth of stack after the return value has been pushed
 691         d_bndr = d + ret_frame_sizeW + idSizeW bndr
 692
 693         -- depth of stack after the extra info table for an unboxed return
 694         -- has been pushed, if any.  This is the stack depth at the
 695         -- continuation.
 696         d_alts = d_bndr + unlifted_itbl_sizeW
 697
 698         -- Env in which to compile the alts, not including
 699         -- any vars bound by the alts themselves
 700         p_alts = addToFM p bndr (d_bndr - 1)
 701
 702         bndr_ty = idType bndr
 703         isAlgCase = not (isUnLiftedType bndr_ty) && not is_unboxed_tuple
 704
 705         -- given an alt, return a discr and code for it.
 706         codeALt alt@(DEFAULT, _, (_,rhs))
 707            = schemeE d_alts s p_alts rhs        `thenBc` \ rhs_code ->
 708              returnBc (NoDiscr, rhs_code)
 709         codeAlt alt@(discr, bndrs, (_,rhs))
 710            -- primitive or nullary constructor alt: no need to UNPACK
 711            | null real_bndrs = do
 712                 rhs_code <- schemeE d_alts s p_alts rhs
 713                 returnBc (my_discr alt, rhs_code)
 714            -- algebraic alt with some binders
 715            | ASSERT(isAlgCase) otherwise =
 716              let
 717                  (ptrs,nptrs) = partition (isFollowableRep.idPrimRep) real_bndrs
 718                  ptr_sizes    = map idSizeW ptrs
 719                  nptrs_sizes  = map idSizeW nptrs
 720                  bind_sizes   = ptr_sizes ++ nptrs_sizes
 721                  size         = sum ptr_sizes + sum nptrs_sizes
 722                  -- the UNPACK instruction unpacks in reverse order...
 723                  p' = addListToFM p_alts
 724                         (zip (reverse (ptrs ++ nptrs))
 725                           (mkStackOffsets d_alts (reverse bind_sizes)))
 726              in do
 727              rhs_code <- schemeE (d_alts+size) s p' rhs
 728              return (my_discr alt, unitOL (UNPACK size) `appOL` rhs_code)
 729            where
 730              real_bndrs = filter (not.isTyVar) bndrs
 731
 732
 733         my_discr (DEFAULT, binds, rhs) = NoDiscr {-shouldn't really happen-}
 734         my_discr (DataAlt dc, binds, rhs)
 735            | isUnboxedTupleCon dc
 736            = unboxedTupleException
 737            | otherwise
 738            = DiscrP (dataConTag dc - fIRST_TAG)
 739         my_discr (LitAlt l, binds, rhs)
 740            = case l of MachInt i     -> DiscrI (fromInteger i)
 741                        MachFloat r   -> DiscrF (fromRational r)
 742                        MachDouble r  -> DiscrD (fromRational r)
 743                        MachChar i    -> DiscrI i
 744                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
 745
 746         maybe_ncons
 747            | not isAlgCase = Nothing
 748            | otherwise
 749            = case [dc | (DataAlt dc, _, _) <- alts] of
 750                 []     -> Nothing
 751                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
 752
 753         -- the bitmap is relative to stack depth d, i.e. before the
 754         -- BCO, info table and return value are pushed on.
 755         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
 756         -- except that here we build the bitmap from the known bindings of
 757         -- things that are pointers, whereas in CgBindery the code builds the
 758         -- bitmap from the free slots and unboxed bindings.
 759         -- (ToDo: merge?)
 760         bitmap = intsToBitmap d{-size-} (sortLt (<) rel_slots)
 761           where
 762           binds = fmToList p
 763           rel_slots = concat (map spread binds)
 764           spread (id, offset)
 765                 | isFollowableRep (idPrimRep id) = [ rel_offset ]
 766                 | otherwise = []
 767                 where rel_offset = d - offset - 1
 768
 769      in do
 770      alt_stuff <- mapM codeAlt alts
 771      alt_final <- mkMultiBranch maybe_ncons alt_stuff
 772      let
 773          alt_bco_name = getName bndr
 774          alt_bco = mkProtoBCO alt_bco_name alt_final (Left alts)
 775                         0{-no arity-} d{-bitmap size-} bitmap True{-is alts-}
 776      -- in
 777 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
 778 --           "\n      bitmap = " ++ show bitmap) $ do
 779      scrut_code <- schemeE (d + ret_frame_sizeW) (d + ret_frame_sizeW) p scrut
 780      alt_bco' <- emitBc alt_bco
 781      let push_alts
 782             | isAlgCase = PUSH_ALTS alt_bco'
 783             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typePrimRep bndr_ty)
 784      returnBc (push_alts `consOL` scrut_code)
 785
 786
 787 -- -----------------------------------------------------------------------------
 788 -- Deal with a CCall.
 789
 790 -- Taggedly push the args onto the stack R->L,
 791 -- deferencing ForeignObj#s and adjusting addrs to point to
 792 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
 793 -- (machine) code for the ccall, and create bytecodes to call that and
 794 -- then return in the right way.
 795
 796 generateCCall :: Int -> Sequel          -- stack and sequel depths
 797               -> BCEnv
 798               -> CCallSpec              -- where to call
 799               -> Id                     -- of target, for type info
 800               -> [AnnExpr' Id VarSet]   -- args (atoms)
 801               -> BcM BCInstrList
 802
 803 generateCCall d0 s p ccall_spec@(CCallSpec target cconv safety) fn args_r_to_l
 804    = let
 805          -- useful constants
 806          addr_sizeW = getPrimRepSize AddrRep
 807
 808          -- Get the args on the stack, with tags and suitably
 809          -- dereferenced for the CCall.  For each arg, return the
 810          -- depth to the first word of the bits for that arg, and the
 811          -- PrimRep of what was actually pushed.
 812
 813          pargs d [] = returnBc []
 814          pargs d (a:az)
 815             = let arg_ty = repType (exprType (deAnnotate' a))
 816
 817               in case splitTyConApp_maybe arg_ty of
 818                     -- Don't push the FO; instead push the Addr# it
 819                     -- contains.
 820                     Just (t, _)
 821                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
 822                        -> pargs (d + addr_sizeW) az     `thenBc` \ rest ->
 823                           parg_ArrayishRep arrPtrsHdrSize d p a
 824                                                         `thenBc` \ code ->
 825                           returnBc ((code,AddrRep):rest)
 826
 827                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
 828                        -> pargs (d + addr_sizeW) az     `thenBc` \ rest ->
 829                           parg_ArrayishRep arrWordsHdrSize d p a
 830                                                         `thenBc` \ code ->
 831                           returnBc ((code,AddrRep):rest)
 832
 833                     -- Default case: push taggedly, but otherwise intact.
 834                     other
 835                        -> pushAtom d p a                `thenBc` \ (code_a, sz_a) ->
 836                           pargs (d+sz_a) az             `thenBc` \ rest ->
 837                           returnBc ((code_a, atomRep a) : rest)
 838
 839          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
 840          -- the stack but then advance it over the headers, so as to
 841          -- point to the payload.
 842          parg_ArrayishRep hdrSizeW d p a
 843             = pushAtom d p a `thenBc` \ (push_fo, _) ->
 844               -- The ptr points at the header.  Advance it over the
 845               -- header and then pretend this is an Addr#.
 846               returnBc (push_fo `snocOL`
 847                         SWIZZLE 0 (hdrSizeW * getPrimRepSize WordRep
 848                                             * wORD_SIZE))
 849
 850      in
 851          pargs d0 args_r_to_l                   `thenBc` \ code_n_reps ->
 852      let
 853          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
 854
 855          push_args    = concatOL pushs_arg
 856          d_after_args = d0 + sum (map getPrimRepSize a_reps_pushed_r_to_l)
 857          a_reps_pushed_RAW
 858             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidRep
 859             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
 860             | otherwise
 861             = reverse (tail a_reps_pushed_r_to_l)
 862
 863          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
 864          -- push_args is the code to do that.
 865          -- d_after_args is the stack depth once the args are on.
 866
 867          -- Get the result rep.
 868          (returns_void, r_rep)
 869             = case maybe_getCCallReturnRep (idType fn) of
 870                  Nothing -> (True,  VoidRep)
 871                  Just rr -> (False, rr)
 872          {-
 873          Because the Haskell stack grows down, the a_reps refer to
 874          lowest to highest addresses in that order.  The args for the call
 875          are on the stack.  Now push an unboxed Addr# indicating
 876          the C function to call.  Then push a dummy placeholder for the
 877          result.  Finally, emit a CCALL insn with an offset pointing to the
 878          Addr# just pushed, and a literal field holding the mallocville
 879          address of the piece of marshalling code we generate.
 880          So, just prior to the CCALL insn, the stack looks like this
 881          (growing down, as usual):
 882
 883             <arg_n>
 884             ...
 885             <arg_1>
 886             Addr# address_of_C_fn
 887             <placeholder-for-result#> (must be an unboxed type)
 888
 889          The interpreter then calls the marshall code mentioned
 890          in the CCALL insn, passing it (& <placeholder-for-result#>),
 891          that is, the addr of the topmost word in the stack.
 892          When this returns, the placeholder will have been
 893          filled in.  The placeholder is slid down to the sequel
 894          depth, and we RETURN.
 895
 896          This arrangement makes it simple to do f-i-dynamic since the Addr#
 897          value is the first arg anyway.
 898
 899          The marshalling code is generated specifically for this
 900          call site, and so knows exactly the (Haskell) stack
 901          offsets of the args, fn address and placeholder.  It
 902          copies the args to the C stack, calls the stacked addr,
 903          and parks the result back in the placeholder.  The interpreter
 904          calls it as a normal C call, assuming it has a signature
 905             void marshall_code ( StgWord* ptr_to_top_of_stack )
 906          -}
 907          -- resolve static address
 908          get_target_info
 909             = case target of
 910                  DynamicTarget
 911                     -> returnBc (False, panic "ByteCodeGen.generateCCall(dyn)")
 912                  StaticTarget target
 913                     -> ioToBc (lookupStaticPtr target) `thenBc` \res ->
 914                        returnBc (True, res)
 915                  CasmTarget _
 916                     -> pprPanic "ByteCodeGen.generateCCall: casm" (ppr ccall_spec)
 917      in
 918          get_target_info        `thenBc` \ (is_static, static_target_addr) ->
 919      let
 920
 921          -- Get the arg reps, zapping the leading Addr# in the dynamic case
 922          a_reps -- | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
 923                 | is_static = a_reps_pushed_RAW
 924                 | otherwise = if null a_reps_pushed_RAW
 925                               then panic "ByteCodeGen.generateCCall: dyn with no args"
 926                               else tail a_reps_pushed_RAW
 927
 928          -- push the Addr#
 929          (push_Addr, d_after_Addr)
 930             | is_static
 931             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
 932                d_after_args + addr_sizeW)
 933             | otherwise -- is already on the stack
 934             = (nilOL, d_after_args)
 935
 936          -- Push the return placeholder.  For a call returning nothing,
 937          -- this is a VoidRep (tag).
 938          r_sizeW   = getPrimRepSize r_rep
 939          d_after_r = d_after_Addr + r_sizeW
 940          r_lit     = mkDummyLiteral r_rep
 941          push_r    = (if   returns_void
 942                       then nilOL
 943                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
 944
 945          -- generate the marshalling code we're going to call
 946          r_offW       = 0
 947          addr_offW    = r_sizeW
 948          arg1_offW    = r_sizeW + addr_sizeW
 949          args_offW    = map (arg1_offW +)
 950                             (init (scanl (+) 0 (map getPrimRepSize a_reps)))
 951      in
 952          ioToBc (mkMarshalCode cconv
 953                     (r_offW, r_rep) addr_offW
 954                     (zip args_offW a_reps))     `thenBc` \ addr_of_marshaller ->
 955          recordMallocBc addr_of_marshaller      `thenBc_`
 956      let
 957          -- Offset of the next stack frame down the stack.  The CCALL
 958          -- instruction needs to describe the chunk of stack containing
 959          -- the ccall args to the GC, so it needs to know how large it
 960          -- is.  See comment in Interpreter.c with the CCALL instruction.
 961          stk_offset   = d_after_r - s
 962
 963          -- do the call
 964          do_call      = unitOL (CCALL stk_offset (castPtr addr_of_marshaller))
 965          -- slide and return
 966          wrapup       = mkSLIDE r_sizeW (d_after_r - r_sizeW - s)
 967                         `snocOL` RETURN_UBX r_rep
 968      in
 969          --trace (show (arg1_offW, args_offW  ,  (map getPrimRepSize a_reps) )) $
 970          returnBc (
 971          push_args `appOL`
 972          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
 973          )
 974
 975
 976 -- Make a dummy literal, to be used as a placeholder for FFI return
 977 -- values on the stack.
 978 mkDummyLiteral :: PrimRep -> Literal
 979 mkDummyLiteral pr
 980    = case pr of
 981         CharRep   -> MachChar 0
 982         IntRep    -> MachInt 0
 983         WordRep   -> MachWord 0
 984         DoubleRep -> MachDouble 0
 985         FloatRep  -> MachFloat 0
 986         AddrRep   | getPrimRepSize AddrRep == getPrimRepSize WordRep -> MachWord 0
 987         _         -> moan64 "mkDummyLiteral" (ppr pr)
 988
 989
 990 -- Convert (eg)
 991 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
 992 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
 993 --
 994 -- to  Just IntRep
 995 -- and check that an unboxed pair is returned wherein the first arg is VoidRep'd.
 996 --
 997 -- Alternatively, for call-targets returning nothing, convert
 998 --
 999 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1000 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
1001 --
1002 -- to  Nothing
1003
1004 maybe_getCCallReturnRep :: Type -> Maybe PrimRep
1005 maybe_getCCallReturnRep fn_ty
1006    = let (a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
1007          maybe_r_rep_to_go
1008             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
1009          (r_tycon, r_reps)
1010             = case splitTyConApp_maybe (repType r_ty) of
1011                       (Just (tyc, tys)) -> (tyc, map typePrimRep tys)
1012                       Nothing -> blargh
1013          ok = ( ( r_reps `lengthIs` 2 && VoidRep == head r_reps)
1014                 || r_reps == [VoidRep] )
1015               && isUnboxedTupleTyCon r_tycon
1016               && case maybe_r_rep_to_go of
1017                     Nothing    -> True
1018                     Just r_rep -> r_rep /= PtrRep
1019                                   -- if it was, it would be impossible
1020                                   -- to create a valid return value
1021                                   -- placeholder on the stack
1022          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
1023                            (pprType fn_ty)
1024      in
1025      --trace (showSDoc (ppr (a_reps, r_reps))) $
1026      if ok then maybe_r_rep_to_go else blargh
1027
1028 -- Compile code which expects an unboxed Int on the top of stack,
1029 -- (call it i), and pushes the i'th closure in the supplied list
1030 -- as a consequence.
1031 implement_tagToId :: [Name] -> BcM BCInstrList
1032 implement_tagToId names
1033    = ASSERT( notNull names )
1034      getLabelsBc (length names)                 `thenBc` \ labels ->
1035      getLabelBc                                 `thenBc` \ label_fail ->
1036      getLabelBc                                 `thenBc` \ label_exit ->
1037      zip4 labels (tail labels ++ [label_fail])
1038                  [0 ..] names                   `bind`   \ infos ->
1039      map (mkStep label_exit) infos              `bind`   \ steps ->
1040      returnBc (concatOL steps
1041                `appOL`
1042                toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1043      where
1044         mkStep l_exit (my_label, next_label, n, name_for_n)
1045            = toOL [LABEL my_label,
1046                    TESTEQ_I n next_label,
1047                    PUSH_G name_for_n,
1048                    JMP l_exit]
1049
1050
1051 -- -----------------------------------------------------------------------------
1052 -- pushAtom
1053
1054 -- Push an atom onto the stack, returning suitable code & number of
1055 -- stack words used.
1056 --
1057 -- The env p must map each variable to the highest- numbered stack
1058 -- slot for it.  For example, if the stack has depth 4 and we
1059 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1060 -- the tag in stack[5], the stack will have depth 6, and p must map v
1061 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1062 -- depth 6 stack has valid words 0 .. 5.
1063
1064 pushAtom :: Int -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Int)
1065
1066 pushAtom d p (AnnApp f (_, AnnType _))
1067    = pushAtom d p (snd f)
1068
1069 pushAtom d p (AnnNote note e)
1070    = pushAtom d p (snd e)
1071
1072 pushAtom d p (AnnLam x e)
1073    | isTyVar x
1074    = pushAtom d p (snd e)
1075
1076 pushAtom d p (AnnVar v)
1077
1078    | idPrimRep v == VoidRep
1079    = returnBc (nilOL, 0)
1080
1081    | isFCallId v
1082    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1083
1084    | Just primop <- isPrimOpId_maybe v
1085    = returnBc (unitOL (PUSH_PRIMOP primop), 1)
1086
1087    | Just d_v <- lookupBCEnv_maybe p v  -- v is a local variable
1088    = returnBc (toOL (nOfThem sz (PUSH_L (d-d_v+sz-2))), sz)
1089          -- d - d_v                 the number of words between the TOS
1090          --                         and the 1st slot of the object
1091          --
1092          -- d - d_v - 1             the offset from the TOS of the 1st slot
1093          --
1094          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1095          --                         of the object.
1096          --
1097          -- Having found the last slot, we proceed to copy the right number of
1098          -- slots on to the top of the stack.
1099
1100     | otherwise  -- v must be a global variable
1101     = ASSERT(sz == 1)
1102       returnBc (unitOL (PUSH_G (getName v)), sz)
1103
1104     where
1105          sz = idSizeW v
1106
1107
1108 pushAtom d p (AnnLit lit)
1109    = case lit of
1110         MachLabel fs -> code CodePtrRep
1111         MachWord w   -> code WordRep
1112         MachInt i    -> code IntRep
1113         MachFloat r  -> code FloatRep
1114         MachDouble r -> code DoubleRep
1115         MachChar c   -> code CharRep
1116         MachStr s    -> pushStr s
1117      where
1118         code rep
1119            = let size_host_words = getPrimRepSize rep
1120              in  returnBc (unitOL (PUSH_UBX (Left lit) size_host_words),
1121                            size_host_words)
1122
1123         pushStr s
1124            = let getMallocvilleAddr
1125                     = case s of
1126                          FastString _ l ba ->
1127                             -- sigh, a string in the heap is no good to us.
1128                             -- We need a static C pointer, since the type of
1129                             -- a string literal is Addr#.  So, copy the string
1130                             -- into C land and remember the pointer so we can
1131                             -- free it later.
1132                             let n = I# l
1133                             -- CAREFUL!  Chars are 32 bits in ghc 4.09+
1134                             in  ioToBc (mallocBytes (n+1)) `thenBc` \ ptr ->
1135                                 recordMallocBc ptr         `thenBc_`
1136                                 ioToBc (
1137                                    do memcpy ptr ba (fromIntegral n)
1138                                       pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1139                                       return ptr
1140                                    )
1141                          other -> panic "ByteCodeGen.pushAtom.pushStr"
1142              in
1143                 getMallocvilleAddr `thenBc` \ addr ->
1144                 -- Get the addr on the stack, untaggedly
1145                    returnBc (unitOL (PUSH_UBX (Right addr) 1), 1)
1146
1147 pushAtom d p other
1148    = pprPanic "ByteCodeGen.pushAtom"
1149               (pprCoreExpr (deAnnotate (undefined, other)))
1150
1151 foreign import ccall unsafe "memcpy"
1152  memcpy :: Ptr a -> ByteArray# -> CInt -> IO ()
1153
1154
1155 -- -----------------------------------------------------------------------------
1156 -- Given a bunch of alts code and their discrs, do the donkey work
1157 -- of making a multiway branch using a switch tree.
1158 -- What a load of hassle!
1159
1160 mkMultiBranch :: Maybe Int      -- # datacons in tycon, if alg alt
1161                                 -- a hint; generates better code
1162                                 -- Nothing is always safe
1163               -> [(Discr, BCInstrList)]
1164               -> BcM BCInstrList
1165 mkMultiBranch maybe_ncons raw_ways
1166    = let d_way     = filter (isNoDiscr.fst) raw_ways
1167          notd_ways = naturalMergeSortLe
1168                         (\w1 w2 -> leAlt (fst w1) (fst w2))
1169                         (filter (not.isNoDiscr.fst) raw_ways)
1170
1171          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1172          mkTree [] range_lo range_hi = returnBc the_default
1173
1174          mkTree [val] range_lo range_hi
1175             | range_lo `eqAlt` range_hi
1176             = returnBc (snd val)
1177             | otherwise
1178             = getLabelBc                                `thenBc` \ label_neq ->
1179               returnBc (mkTestEQ (fst val) label_neq
1180                         `consOL` (snd val
1181                         `appOL`   unitOL (LABEL label_neq)
1182                         `appOL`   the_default))
1183
1184          mkTree vals range_lo range_hi
1185             = let n = length vals `div` 2
1186                   vals_lo = take n vals
1187                   vals_hi = drop n vals
1188                   v_mid = fst (head vals_hi)
1189               in
1190               getLabelBc                                `thenBc` \ label_geq ->
1191               mkTree vals_lo range_lo (dec v_mid)       `thenBc` \ code_lo ->
1192               mkTree vals_hi v_mid range_hi             `thenBc` \ code_hi ->
1193               returnBc (mkTestLT v_mid label_geq
1194                         `consOL` (code_lo
1195                         `appOL`   unitOL (LABEL label_geq)
1196                         `appOL`   code_hi))
1197
1198          the_default
1199             = case d_way of [] -> unitOL CASEFAIL
1200                             [(_, def)] -> def
1201
1202          -- None of these will be needed if there are no non-default alts
1203          (mkTestLT, mkTestEQ, init_lo, init_hi)
1204             | null notd_ways
1205             = panic "mkMultiBranch: awesome foursome"
1206             | otherwise
1207             = case fst (head notd_ways) of {
1208               DiscrI _ -> ( \(DiscrI i) fail_label -> TESTLT_I i fail_label,
1209                             \(DiscrI i) fail_label -> TESTEQ_I i fail_label,
1210                             DiscrI minBound,
1211                             DiscrI maxBound );
1212               DiscrF _ -> ( \(DiscrF f) fail_label -> TESTLT_F f fail_label,
1213                             \(DiscrF f) fail_label -> TESTEQ_F f fail_label,
1214                             DiscrF minF,
1215                             DiscrF maxF );
1216               DiscrD _ -> ( \(DiscrD d) fail_label -> TESTLT_D d fail_label,
1217                             \(DiscrD d) fail_label -> TESTEQ_D d fail_label,
1218                             DiscrD minD,
1219                             DiscrD maxD );
1220               DiscrP _ -> ( \(DiscrP i) fail_label -> TESTLT_P i fail_label,
1221                             \(DiscrP i) fail_label -> TESTEQ_P i fail_label,
1222                             DiscrP algMinBound,
1223                             DiscrP algMaxBound )
1224               }
1225
1226          (algMinBound, algMaxBound)
1227             = case maybe_ncons of
1228                  Just n  -> (0, n - 1)
1229                  Nothing -> (minBound, maxBound)
1230
1231          (DiscrI i1) `eqAlt` (DiscrI i2) = i1 == i2
1232          (DiscrF f1) `eqAlt` (DiscrF f2) = f1 == f2
1233          (DiscrD d1) `eqAlt` (DiscrD d2) = d1 == d2
1234          (DiscrP i1) `eqAlt` (DiscrP i2) = i1 == i2
1235          NoDiscr     `eqAlt` NoDiscr     = True
1236          _           `eqAlt` _           = False
1237
1238          (DiscrI i1) `leAlt` (DiscrI i2) = i1 <= i2
1239          (DiscrF f1) `leAlt` (DiscrF f2) = f1 <= f2
1240          (DiscrD d1) `leAlt` (DiscrD d2) = d1 <= d2
1241          (DiscrP i1) `leAlt` (DiscrP i2) = i1 <= i2
1242          NoDiscr     `leAlt` NoDiscr     = True
1243          _           `leAlt` _           = False
1244
1245          isNoDiscr NoDiscr = True
1246          isNoDiscr _       = False
1247
1248          dec (DiscrI i) = DiscrI (i-1)
1249          dec (DiscrP i) = DiscrP (i-1)
1250          dec other      = other         -- not really right, but if you
1251                 -- do cases on floating values, you'll get what you deserve
1252
1253          -- same snotty comment applies to the following
1254          minF, maxF :: Float
1255          minD, maxD :: Double
1256          minF = -1.0e37
1257          maxF =  1.0e37
1258          minD = -1.0e308
1259          maxD =  1.0e308
1260      in
1261          mkTree notd_ways init_lo init_hi
1262
1263
1264 -- -----------------------------------------------------------------------------
1265 -- Supporting junk for the compilation schemes
1266
1267 -- Describes case alts
1268 data Discr
1269    = DiscrI Int
1270    | DiscrF Float
1271    | DiscrD Double
1272    | DiscrP Int
1273    | NoDiscr
1274
1275 instance Outputable Discr where
1276    ppr (DiscrI i) = int i
1277    ppr (DiscrF f) = text (show f)
1278    ppr (DiscrD d) = text (show d)
1279    ppr (DiscrP i) = int i
1280    ppr NoDiscr    = text "DEF"
1281
1282
1283 lookupBCEnv_maybe :: BCEnv -> Id -> Maybe Int
1284 lookupBCEnv_maybe = lookupFM
1285
1286 idSizeW :: Id -> Int
1287 idSizeW id = getPrimRepSize (typePrimRep (idType id))
1288
1289 unboxedTupleException :: a
1290 unboxedTupleException
1291    = throwDyn
1292         (Panic
1293            ("Bytecode generator can't handle unboxed tuples.  Possibly due\n" ++
1294             "\tto foreign import/export decls in source.  Workaround:\n" ++
1295             "\tcompile this module to a .o file, then restart session."))
1296
1297
1298 mkSLIDE n d = if d == 0 then nilOL else unitOL (SLIDE n d)
1299 bind x f    = f x
1300
1301 splitApp :: AnnExpr' id ann -> (AnnExpr' id ann, [AnnExpr' id ann])
1302         -- The arguments are returned in *right-to-left* order
1303 splitApp (AnnApp (_,f) (_,a))
1304                | isTypeAtom a = splitApp f
1305                | otherwise    = case splitApp f of
1306                                      (f', as) -> (f', a:as)
1307 splitApp (AnnNote n (_,e))    = splitApp e
1308 splitApp e                    = (e, [])
1309
1310
1311 isTypeAtom :: AnnExpr' id ann -> Bool
1312 isTypeAtom (AnnType _) = True
1313 isTypeAtom _           = False
1314
1315 isVoidRepAtom :: AnnExpr' id ann -> Bool
1316 isVoidRepAtom (AnnVar v)        = typePrimRep (idType v) == VoidRep
1317 isVoidRepAtom (AnnNote n (_,e)) = isVoidRepAtom e
1318 isVoidRepAtom _                 = False
1319
1320 atomRep :: AnnExpr' Id ann -> PrimRep
1321 atomRep (AnnVar v)    = typePrimRep (idType v)
1322 atomRep (AnnLit l)    = literalPrimRep l
1323 atomRep (AnnNote n b) = atomRep (snd b)
1324 atomRep (AnnApp f (_, AnnType _)) = atomRep (snd f)
1325 atomRep (AnnLam x e) | isTyVar x = atomRep (snd e)
1326 atomRep other = pprPanic "atomRep" (ppr (deAnnotate (undefined,other)))
1327
1328 isPtrAtom :: AnnExpr' Id ann -> Bool
1329 isPtrAtom e = isFollowableRep (atomRep e)
1330
1331 -- Let szsw be the sizes in words of some items pushed onto the stack,
1332 -- which has initial depth d'.  Return the values which the stack environment
1333 -- should map these items to.
1334 mkStackOffsets :: Int -> [Int] -> [Int]
1335 mkStackOffsets original_depth szsw
1336    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1337
1338 -- -----------------------------------------------------------------------------
1339 -- The bytecode generator's monad
1340
1341 data BcM_State
1342    = BcM_State {
1343         nextlabel :: Int,               -- for generating local labels
1344         malloced  :: [Ptr ()] }         -- ptrs malloced for current BCO
1345                                         -- Should be free()d when it is GCd
1346
1347 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1348
1349 ioToBc :: IO a -> BcM a
1350 ioToBc io = BcM $ \st -> do
1351   x <- io
1352   return (st, x)
1353
1354 runBc :: BcM r -> IO (BcM_State, r)
1355 runBc (BcM m) = m (BcM_State 0 [])
1356
1357 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1358 thenBc (BcM expr) cont = BcM $ \st0 -> do
1359   (st1, q) <- expr st0
1360   let BcM k = cont q
1361   (st2, r) <- k st1
1362   return (st2, r)
1363
1364 thenBc_ :: BcM a -> BcM b -> BcM b
1365 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1366   (st1, q) <- expr st0
1367   (st2, r) <- cont st1
1368   return (st2, r)
1369
1370 returnBc :: a -> BcM a
1371 returnBc result = BcM $ \st -> (return (st, result))
1372
1373 instance Monad BcM where
1374   (>>=) = thenBc
1375   (>>)  = thenBc_
1376   return = returnBc
1377
1378 emitBc :: ([Ptr ()] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1379 emitBc bco
1380   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1381
1382 recordMallocBc :: Ptr a -> BcM ()
1383 recordMallocBc a
1384   = BcM $ \st -> return (st{malloced = castPtr a : malloced st}, ())
1385
1386 getLabelBc :: BcM Int
1387 getLabelBc
1388   = BcM $ \st -> return (st{nextlabel = 1 + nextlabel st}, nextlabel st)
1389
1390 getLabelsBc :: Int -> BcM [Int]
1391 getLabelsBc n
1392   = BcM $ \st -> let ctr = nextlabel st
1393                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1394 \end{code}