ghc/compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), TyClDecl(..), InstDecl(..), RuleDecl(..), RuleBndr(..),
  12         DefaultDecl(..),
  13         ForeignDecl(..), ForeignImport(..), ForeignExport(..),
  14         CImportSpec(..), FoType(..),
  15         ConDecl(..), ConDetails(..),
  16         BangType(..), getBangType, getBangStrictness, unbangedType,
  17         DeprecDecl(..), DeprecTxt,
  18         hsDeclName, instDeclName,
  19         tyClDeclName, tyClDeclNames, tyClDeclSysNames, tyClDeclTyVars,
  20         isClassDecl, isSynDecl, isDataDecl, isIfaceSigDecl, countTyClDecls,
  21         mkClassDeclSysNames, isSourceInstDecl, ifaceRuleDeclName,
  22         getClassDeclSysNames, conDetailsTys,
  23         collectRuleBndrSigTys
  24     ) where
  25
  26 #include "HsVersions.h"
  27
  28 -- friends:
  29 import HsBinds          ( HsBinds, MonoBinds, Sig(..), FixitySig(..) )
  30 import HsExpr           ( HsExpr )
  31 import HsImpExp         ( ppr_var )
  32 import HsTypes
  33 import PprCore          ( pprCoreRule )
  34 import HsCore           ( UfExpr, UfBinder, HsIdInfo, pprHsIdInfo,
  35                           eq_ufBinders, eq_ufExpr, pprUfExpr
  36                         )
  37 import CoreSyn          ( CoreRule(..), RuleName )
  38 import BasicTypes       ( NewOrData(..), StrictnessMark(..), Activation(..) )
  39 import ForeignCall      ( CCallTarget(..), DNCallSpec, CCallConv, Safety,
  40                           CExportSpec(..))
  41
  42 -- others:
  43 import Name             ( NamedThing )
  44 import FunDeps          ( pprFundeps )
  45 import TyCon            ( DataConDetails(..), visibleDataCons )
  46 import Class            ( FunDep, DefMeth(..) )
  47 import CStrings         ( CLabelString )
  48 import Outputable
  49 import Util             ( eqListBy, count )
  50 import SrcLoc           ( SrcLoc )
  51 import FastString
  52
  53 import Maybe            ( isNothing, fromJust )
  54 \end{code}
  55
  56
  57 %************************************************************************
  58 %*                                                                      *
  59 \subsection[HsDecl]{Declarations}
  60 %*                                                                      *
  61 %************************************************************************
  62
  63 \begin{code}
  64 data HsDecl name pat
  65   = TyClD       (TyClDecl name pat)
  66   | InstD       (InstDecl  name pat)
  67   | DefD        (DefaultDecl name)
  68   | ValD        (HsBinds name pat)
  69   | ForD        (ForeignDecl name)
  70   | FixD        (FixitySig name)
  71   | DeprecD     (DeprecDecl name)
  72   | RuleD       (RuleDecl name pat)
  73
  74 -- NB: all top-level fixity decls are contained EITHER
  75 -- EITHER FixDs
  76 -- OR     in the ClassDecls in TyClDs
  77 --
  78 -- The former covers
  79 --      a) data constructors
  80 --      b) class methods (but they can be also done in the
  81 --              signatures of class decls)
  82 --      c) imported functions (that have an IfacSig)
  83 --      d) top level decls
  84 --
  85 -- The latter is for class methods only
  86 \end{code}
  87
  88 \begin{code}
  89 #ifdef DEBUG
  90 hsDeclName :: (NamedThing name, Outputable name, Outputable pat)
  91            => HsDecl name pat -> name
  92 #endif
  93 hsDeclName (TyClD decl)                 = tyClDeclName     decl
  94 hsDeclName (InstD decl)                 = instDeclName     decl
  95 hsDeclName (ForD  decl)                 = foreignDeclName decl
  96 hsDeclName (FixD  (FixitySig name _ _)) = name
  97 -- Others don't make sense
  98 #ifdef DEBUG
  99 hsDeclName x                            = pprPanic "HsDecls.hsDeclName" (ppr x)
 100 #endif
 101
 102
 103 instDeclName :: InstDecl name pat -> name
 104 instDeclName (InstDecl _ _ _ (Just name) _) = name
 105
 106 \end{code}
 107
 108 \begin{code}
 109 instance (NamedThing name, Outputable name, Outputable pat)
 110         => Outputable (HsDecl name pat) where
 111
 112     ppr (TyClD dcl)  = ppr dcl
 113     ppr (ValD binds) = ppr binds
 114     ppr (DefD def)   = ppr def
 115     ppr (InstD inst) = ppr inst
 116     ppr (ForD fd)    = ppr fd
 117     ppr (FixD fd)    = ppr fd
 118     ppr (RuleD rd)   = ppr rd
 119     ppr (DeprecD dd) = ppr dd
 120 \end{code}
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 126 %*                                                                      *
 127 %************************************************************************
 128
 129                 --------------------------------
 130                         THE NAMING STORY
 131                 --------------------------------
 132
 133 Here is the story about the implicit names that go with type, class, and instance
 134 decls.  It's a bit tricky, so pay attention!
 135
 136 "Implicit" (or "system") binders
 137 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 138   Each data type decl defines
 139         a worker name for each constructor
 140         to-T and from-T convertors
 141   Each class decl defines
 142         a tycon for the class
 143         a data constructor for that tycon
 144         the worker for that constructor
 145         a selector for each superclass
 146
 147 All have occurrence names that are derived uniquely from their parent declaration.
 148
 149 None of these get separate definitions in an interface file; they are
 150 fully defined by the data or class decl.  But they may *occur* in
 151 interface files, of course.  Any such occurrence must haul in the
 152 relevant type or class decl.
 153
 154 Plan of attack:
 155  - Make up their occurrence names immediately
 156    This is done in RdrHsSyn.mkClassDecl, mkTyDecl, mkConDecl
 157
 158  - Ensure they "point to" the parent data/class decl
 159    when loading that decl from an interface file
 160    (See RnHiFiles.getTyClDeclSysNames)
 161
 162  - When renaming the decl look them up in the name cache,
 163    ensure correct module and provenance is set
 164
 165 Default methods
 166 ~~~~~~~~~~~~~~~
 167  - Occurrence name is derived uniquely from the method name
 168    E.g. $dmmax
 169
 170  - If there is a default method name at all, it's recorded in
 171    the ClassOpSig (in HsBinds), in the DefMeth field.
 172    (DefMeth is defined in Class.lhs)
 173
 174 Source-code class decls and interface-code class decls are treated subtly
 175 differently, which has given me a great deal of confusion over the years.
 176 Here's the deal.  (We distinguish the two cases because source-code decls
 177 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 178
 179 In *source-code* class declarations:
 180  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 181    This is done by RdrHsSyn.mkClassOpSigDM
 182
 183  - The renamer renames it to a Name
 184
 185  - During typechecking, we generate a binding for each $dm for
 186    which there's a programmer-supplied default method:
 187         class Foo a where
 188           op1 :: <type>
 189           op2 :: <type>
 190           op1 = ...
 191    We generate a binding for $dmop1 but not for $dmop2.
 192    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 193    The Name for $dmop2 is simply discarded.
 194
 195 In *interface-file* class declarations:
 196   - When parsing, we see if there's an explicit programmer-supplied default method
 197     because there's an '=' sign to indicate it:
 198         class Foo a where
 199           op1 = :: <type>       -- NB the '='
 200           op2   :: <type>
 201     We use this info to generate a DefMeth with a suitable RdrName for op1,
 202     and a NoDefMeth for op2
 203   - The interface file has a separate definition for $dmop1, with unfolding etc.
 204   - The renamer renames it to a Name.
 205   - The renamer treats $dmop1 as a free variable of the declaration, so that
 206     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 207     This doesn't happen for source code class decls, because they *bind* the default method.
 208
 209 Dictionary functions
 210 ~~~~~~~~~~~~~~~~~~~~
 211 Each instance declaration gives rise to one dictionary function binding.
 212
 213 The type checker makes up new source-code instance declarations
 214 (e.g. from 'deriving' or generic default methods --- see
 215 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 216 dictionary functions in advance (we don't know how many we need).
 217
 218 On the other hand for interface-file instance declarations, the decl
 219 specifies the name of the dictionary function, and it has a binding elsewhere
 220 in the interface file:
 221         instance {Eq Int} = dEqInt
 222         dEqInt :: {Eq Int} <pragma info>
 223
 224 So again we treat source code and interface file code slightly differently.
 225
 226 Source code:
 227   - Source code instance decls have a Nothing in the (Maybe name) field
 228     (see data InstDecl below)
 229
 230   - The typechecker makes up a Local name for the dict fun for any source-code
 231     instance decl, whether it comes from a source-code instance decl, or whether
 232     the instance decl is derived from some other construct (e.g. 'deriving').
 233
 234   - The occurrence name it chooses is derived from the instance decl (just for
 235     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 236     occurrence name, but will have different uniques.  E.g.
 237         instance Foo [Int]  where ...
 238         instance Foo [Bool] where ...
 239     These might both be dFooList
 240
 241   - The CoreTidy phase externalises the name, and ensures the occurrence name is
 242     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 243
 244   - We can take this relaxed approach (changing the occurrence name later)
 245     because dict fun Ids are not captured in a TyCon or Class (unlike default
 246     methods, say).  Instead, they are kept separately in the InstEnv.  This
 247     makes it easy to adjust them after compiling a module.  (Once we've finished
 248     compiling that module, they don't change any more.)
 249
 250
 251 Interface file code:
 252   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 253     in the (Maybe name) field.
 254
 255   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 256     suck in the dfun binding
 257
 258
 259 \begin{code}
 260 -- TyClDecls are precisely the kind of declarations that can
 261 -- appear in interface files; or (internally) in GHC's interface
 262 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 263 -- are both in TyClDecl
 264
 265 data TyClDecl name pat
 266   = IfaceSig {  tcdName :: name,                -- It may seem odd to classify an interface-file signature
 267                 tcdType :: HsType name,         -- as a 'TyClDecl', but it's very convenient.
 268                 tcdIdInfo :: [HsIdInfo name],
 269                 tcdLoc :: SrcLoc
 270     }
 271
 272   | ForeignType { tcdName    :: name,           -- See remarks about IfaceSig above
 273                   tcdExtName :: Maybe FastString,
 274                   tcdFoType  :: FoType,
 275                   tcdLoc     :: SrcLoc }
 276
 277   | TyData {    tcdND     :: NewOrData,
 278                 tcdCtxt   :: HsContext name,     -- context
 279                 tcdName   :: name,               -- type constructor
 280                 tcdTyVars :: [HsTyVarBndr name], -- type variables
 281                 tcdCons   :: DataConDetails (ConDecl name),      -- data constructors (empty if abstract)
 282                 tcdDerivs :: Maybe (HsContext name),    -- derivings; Nothing => not specified
 283                                                         -- Just [] => derive exactly what is asked
 284                 tcdSysNames :: DataSysNames name,       -- Generic converter functions
 285                 tcdLoc      :: SrcLoc
 286     }
 287
 288   | TySynonym { tcdName :: name,                        -- type constructor
 289                 tcdTyVars :: [HsTyVarBndr name],        -- type variables
 290                 tcdSynRhs :: HsType name,               -- synonym expansion
 291                 tcdLoc    :: SrcLoc
 292     }
 293
 294   | ClassDecl { tcdCtxt    :: HsContext name,           -- Context...
 295                 tcdName    :: name,                     -- Name of the class
 296                 tcdTyVars  :: [HsTyVarBndr name],       -- The class type variables
 297                 tcdFDs     :: [FunDep name],            -- Functional dependencies
 298                 tcdSigs    :: [Sig name],               -- Methods' signatures
 299                 tcdMeths   :: Maybe (MonoBinds name pat),       -- Default methods
 300                                                                 -- Nothing for imported class decls
 301                                                                 -- Just bs for source   class decls
 302                 tcdSysNames :: ClassSysNames name,
 303                 tcdLoc      :: SrcLoc
 304     }
 305 \end{code}
 306
 307 Simple classifiers
 308
 309 \begin{code}
 310 isIfaceSigDecl, isDataDecl, isSynDecl, isClassDecl :: TyClDecl name pat -> Bool
 311
 312 isIfaceSigDecl (IfaceSig {}) = True
 313 isIfaceSigDecl other         = False
 314
 315 isSynDecl (TySynonym {}) = True
 316 isSynDecl other          = False
 317
 318 isDataDecl (TyData {}) = True
 319 isDataDecl other       = False
 320
 321 isClassDecl (ClassDecl {}) = True
 322 isClassDecl other          = False
 323 \end{code}
 324
 325 Dealing with names
 326
 327 \begin{code}
 328 --------------------------------
 329 tyClDeclName :: TyClDecl name pat -> name
 330 tyClDeclName tycl_decl = tcdName tycl_decl
 331
 332 --------------------------------
 333 tyClDeclNames :: Eq name => TyClDecl name pat -> [(name, SrcLoc)]
 334 -- Returns all the *binding* names of the decl, along with their SrcLocs
 335 -- The first one is guaranteed to be the name of the decl
 336 -- For record fields, the first one counts as the SrcLoc
 337 -- We use the equality to filter out duplicate field names
 338
 339 tyClDeclNames (TySynonym   {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 340 tyClDeclNames (IfaceSig    {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 341 tyClDeclNames (ForeignType {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 342
 343 tyClDeclNames (ClassDecl {tcdName = cls_name, tcdSigs = sigs, tcdLoc = loc})
 344   = (cls_name,loc) : [(n,loc) | ClassOpSig n _ _ loc <- sigs]
 345
 346 tyClDeclNames (TyData {tcdName = tc_name, tcdCons = cons, tcdLoc = loc})
 347   = (tc_name,loc) : conDeclsNames cons
 348
 349
 350 tyClDeclTyVars (TySynonym {tcdTyVars = tvs}) = tvs
 351 tyClDeclTyVars (TyData    {tcdTyVars = tvs}) = tvs
 352 tyClDeclTyVars (ClassDecl {tcdTyVars = tvs}) = tvs
 353 tyClDeclTyVars (ForeignType {})              = []
 354 tyClDeclTyVars (IfaceSig {})                 = []
 355
 356
 357 --------------------------------
 358 -- The "system names" are extra implicit names *bound* by the decl.
 359 -- They are kept in a list rather than a tuple
 360 -- to make the renamer easier.
 361
 362 type ClassSysNames name = [name]
 363 -- For class decls they are:
 364 --      [tycon, datacon wrapper, datacon worker,
 365 --       superclass selector 1, ..., superclass selector n]
 366
 367 type DataSysNames name =  [name]
 368 -- For data decls they are
 369 --      [from, to]
 370 -- where from :: T -> Tring
 371 --       to   :: Tring -> T
 372
 373 tyClDeclSysNames :: TyClDecl name pat -> [(name, SrcLoc)]
 374 -- Similar to tyClDeclNames, but returns the "implicit"
 375 -- or "system" names of the declaration
 376
 377 tyClDeclSysNames (ClassDecl {tcdSysNames = names, tcdLoc = loc})
 378   = [(n,loc) | n <- names]
 379 tyClDeclSysNames (TyData {tcdCons = DataCons cons, tcdSysNames = names, tcdLoc = loc})
 380   = [(n,loc) | n <- names] ++
 381     [(wkr_name,loc) | ConDecl _ wkr_name _ _ _ loc <- cons]
 382 tyClDeclSysNames decl = []
 383
 384
 385 mkClassDeclSysNames  :: (name, name, name, [name]) -> [name]
 386 getClassDeclSysNames :: [name] -> (name, name, name, [name])
 387 mkClassDeclSysNames  (a,b,c,ds) = a:b:c:ds
 388 getClassDeclSysNames (a:b:c:ds) = (a,b,c,ds)
 389 \end{code}
 390
 391 \begin{code}
 392 instance (NamedThing name, Ord name) => Eq (TyClDecl name pat) where
 393         -- Used only when building interface files
 394   (==) d1@(IfaceSig {}) d2@(IfaceSig {})
 395       = tcdName d1 == tcdName d2 &&
 396         tcdType d1 == tcdType d2 &&
 397         tcdIdInfo d1 == tcdIdInfo d2
 398
 399   (==) d1@(ForeignType {}) d2@(ForeignType {})
 400       = tcdName d1 == tcdName d2 &&
 401         tcdFoType d1 == tcdFoType d2
 402
 403   (==) d1@(TyData {}) d2@(TyData {})
 404       = tcdName d1 == tcdName d2 &&
 405         tcdND d1   == tcdND   d2 &&
 406         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 407           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 408           eq_hsCD      env (tcdCons d1) (tcdCons d2)
 409         )
 410
 411   (==) d1@(TySynonym {}) d2@(TySynonym {})
 412       = tcdName d1 == tcdName d2 &&
 413         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 414           eq_hsType env (tcdSynRhs d1) (tcdSynRhs d2)
 415         )
 416
 417   (==) d1@(ClassDecl {}) d2@(ClassDecl {})
 418     = tcdName d1 == tcdName d2 &&
 419       eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 420           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 421           eqListBy (eq_hsFD env) (tcdFDs d1) (tcdFDs d2) &&
 422           eqListBy (eq_cls_sig env) (tcdSigs d1) (tcdSigs d2)
 423        )
 424
 425   (==) _ _ = False      -- default case
 426
 427 eq_hsCD env (DataCons c1) (DataCons c2) = eqListBy (eq_ConDecl env) c1 c2
 428 eq_hsCD env Unknown       Unknown       = True
 429 eq_hsCD env (HasCons n1)  (HasCons n2)  = n1 == n2
 430 eq_hsCD env d1            d2            = False
 431
 432 eq_hsFD env (ns1,ms1) (ns2,ms2)
 433   = eqListBy (eq_hsVar env) ns1 ns2 && eqListBy (eq_hsVar env) ms1 ms2
 434
 435 eq_cls_sig env (ClassOpSig n1 dm1 ty1 _) (ClassOpSig n2 dm2 ty2 _)
 436   = n1==n2 && dm1 `eq_dm` dm2 && eq_hsType env ty1 ty2
 437   where
 438         -- Ignore the name of the default method for (DefMeth id)
 439         -- This is used for comparing declarations before putting
 440         -- them into interface files, and the name of the default
 441         -- method isn't relevant
 442     NoDefMeth  `eq_dm` NoDefMeth  = True
 443     GenDefMeth `eq_dm` GenDefMeth = True
 444     DefMeth _  `eq_dm` DefMeth _  = True
 445     dm1        `eq_dm` dm2        = False
 446
 447
 448 \end{code}
 449
 450 \begin{code}
 451 countTyClDecls :: [TyClDecl name pat] -> (Int, Int, Int, Int, Int)
 452         -- class, data, newtype, synonym decls
 453 countTyClDecls decls
 454  = (count isClassDecl     decls,
 455     count isSynDecl       decls,
 456     count isIfaceSigDecl  decls,
 457     count isDataTy        decls,
 458     count isNewTy         decls)
 459  where
 460    isDataTy TyData{tcdND=DataType} = True
 461    isDataTy _                      = False
 462
 463    isNewTy TyData{tcdND=NewType} = True
 464    isNewTy _                     = False
 465 \end{code}
 466
 467 \begin{code}
 468 instance (NamedThing name, Outputable name, Outputable pat)
 469               => Outputable (TyClDecl name pat) where
 470
 471     ppr (IfaceSig {tcdName = var, tcdType = ty, tcdIdInfo = info})
 472         = getPprStyle $ \ sty ->
 473            hsep [ ppr_var var, dcolon, ppr ty, pprHsIdInfo info ]
 474
 475     ppr (ForeignType {tcdName = tycon})
 476         = hsep [ptext SLIT("foreign import type dotnet"), ppr tycon]
 477
 478     ppr (TySynonym {tcdName = tycon, tcdTyVars = tyvars, tcdSynRhs = mono_ty})
 479       = hang (ptext SLIT("type") <+> pp_decl_head [] tycon tyvars <+> equals)
 480              4 (ppr mono_ty)
 481
 482     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdName = tycon,
 483                  tcdTyVars = tyvars, tcdCons = condecls,
 484                  tcdDerivs = derivings})
 485       = pp_tydecl (ptext keyword <+> pp_decl_head context tycon tyvars)
 486                   (pp_condecls condecls)
 487                   derivings
 488       where
 489         keyword = case new_or_data of
 490                         NewType  -> SLIT("newtype")
 491                         DataType -> SLIT("data")
 492
 493     ppr (ClassDecl {tcdCtxt = context, tcdName = clas, tcdTyVars = tyvars, tcdFDs = fds,
 494                     tcdSigs = sigs, tcdMeths = methods})
 495       | null sigs       -- No "where" part
 496       = top_matter
 497
 498       | otherwise       -- Laid out
 499       = sep [hsep [top_matter, ptext SLIT("where {")],
 500              nest 4 (sep [sep (map ppr_sig sigs), pp_methods, char '}'])]
 501       where
 502         top_matter  = ptext SLIT("class") <+> pp_decl_head context clas tyvars <+> pprFundeps fds
 503         ppr_sig sig = ppr sig <> semi
 504
 505         pp_methods = if isNothing methods
 506                         then empty
 507                         else ppr (fromJust methods)
 508
 509 pp_decl_head :: Outputable name => HsContext name -> name -> [HsTyVarBndr name] -> SDoc
 510 pp_decl_head context thing tyvars = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 511
 512 pp_condecls Unknown       = ptext SLIT("{- abstract -}")
 513 pp_condecls (HasCons n)   = ptext SLIT("{- abstract with") <+> int n <+> ptext SLIT("constructors -}")
 514 pp_condecls (DataCons cs) = equals <+> sep (punctuate (ptext SLIT(" |")) (map ppr cs))
 515
 516 pp_tydecl pp_head pp_decl_rhs derivings
 517   = hang pp_head 4 (sep [
 518         pp_decl_rhs,
 519         case derivings of
 520           Nothing          -> empty
 521           Just ds          -> hsep [ptext SLIT("deriving"), ppr_hs_context ds]
 522     ])
 523 \end{code}
 524
 525
 526 %************************************************************************
 527 %*                                                                      *
 528 \subsection[ConDecl]{A data-constructor declaration}
 529 %*                                                                      *
 530 %************************************************************************
 531
 532 \begin{code}
 533 data ConDecl name
 534   = ConDecl     name                    -- Constructor name; this is used for the
 535                                         -- DataCon itself, and for the user-callable wrapper Id
 536
 537                 name                    -- Name of the constructor's 'worker Id'
 538                                         -- Filled in as the ConDecl is built
 539
 540                 [HsTyVarBndr name]      -- Existentially quantified type variables
 541                 (HsContext name)        -- ...and context
 542                                         -- If both are empty then there are no existentials
 543
 544                 (ConDetails name)
 545                 SrcLoc
 546
 547 data ConDetails name
 548   = VanillaCon                  -- prefix-style con decl
 549                 [BangType name]
 550
 551   | InfixCon                    -- infix-style con decl
 552                 (BangType name)
 553                 (BangType name)
 554
 555   | RecCon                      -- record-style con decl
 556                 [([name], BangType name)]       -- list of "fields"
 557 \end{code}
 558
 559 \begin{code}
 560 conDeclsNames :: Eq name => DataConDetails (ConDecl name) -> [(name,SrcLoc)]
 561   -- See tyClDeclNames for what this does
 562   -- The function is boringly complicated because of the records
 563   -- And since we only have equality, we have to be a little careful
 564 conDeclsNames cons
 565   = snd (foldl do_one ([], []) (visibleDataCons cons))
 566   where
 567     do_one (flds_seen, acc) (ConDecl name _ _ _ details loc)
 568         = do_details ((name,loc):acc) details
 569         where
 570           do_details acc (RecCon flds) = foldl do_fld (flds_seen, acc) flds
 571           do_details acc other         = (flds_seen, acc)
 572
 573           do_fld acc (flds, _) = foldl do_fld1 acc flds
 574
 575           do_fld1 (flds_seen, acc) fld
 576                 | fld `elem` flds_seen = (flds_seen,acc)
 577                 | otherwise            = (fld:flds_seen, (fld,loc):acc)
 578 \end{code}
 579
 580 \begin{code}
 581 conDetailsTys :: ConDetails name -> [HsType name]
 582 conDetailsTys (VanillaCon btys)    = map getBangType btys
 583 conDetailsTys (InfixCon bty1 bty2) = [getBangType bty1, getBangType bty2]
 584 conDetailsTys (RecCon fields)      = [getBangType bty | (_, bty) <- fields]
 585
 586
 587 eq_ConDecl env (ConDecl n1 _ tvs1 cxt1 cds1 _)
 588                (ConDecl n2 _ tvs2 cxt2 cds2 _)
 589   = n1 == n2 &&
 590     (eq_hsTyVars env tvs1 tvs2  $ \ env ->
 591      eq_hsContext env cxt1 cxt2 &&
 592      eq_ConDetails env cds1 cds2)
 593
 594 eq_ConDetails env (VanillaCon bts1) (VanillaCon bts2)
 595   = eqListBy (eq_btype env) bts1 bts2
 596 eq_ConDetails env (InfixCon bta1 btb1) (InfixCon bta2 btb2)
 597   = eq_btype env bta1 bta2 && eq_btype env btb1 btb2
 598 eq_ConDetails env (RecCon fs1) (RecCon fs2)
 599   = eqListBy (eq_fld env) fs1 fs2
 600 eq_ConDetails env _ _ = False
 601
 602 eq_fld env (ns1,bt1) (ns2, bt2) = ns1==ns2 && eq_btype env bt1 bt2
 603 \end{code}
 604
 605 \begin{code}
 606 data BangType name = BangType StrictnessMark (HsType name)
 607
 608 getBangType       (BangType _ ty) = ty
 609 getBangStrictness (BangType s _)  = s
 610
 611 unbangedType ty = BangType NotMarkedStrict ty
 612
 613 eq_btype env (BangType s1 t1) (BangType s2 t2) = s1==s2 && eq_hsType env t1 t2
 614 \end{code}
 615
 616 \begin{code}
 617 instance (Outputable name) => Outputable (ConDecl name) where
 618     ppr (ConDecl con _ tvs cxt con_details  loc)
 619       = sep [pprHsForAll tvs cxt, ppr_con_details con con_details]
 620
 621 ppr_con_details con (InfixCon ty1 ty2)
 622   = hsep [ppr_bang ty1, ppr con, ppr_bang ty2]
 623
 624 -- ConDecls generated by MkIface.ifaceTyThing always have a VanillaCon, even
 625 -- if the constructor is an infix one.  This is because in an interface file
 626 -- we don't distinguish between the two.  Hence when printing these for the
 627 -- user, we need to parenthesise infix constructor names.
 628 ppr_con_details con (VanillaCon tys)
 629   = hsep (ppr_var con : map (ppr_bang) tys)
 630
 631 ppr_con_details con (RecCon fields)
 632   = ppr con <+> braces (sep (punctuate comma (map ppr_field fields)))
 633   where
 634     ppr_field (ns, ty) = hsep (map (ppr) ns) <+>
 635                          dcolon <+>
 636                          ppr_bang ty
 637
 638 instance Outputable name => Outputable (BangType name) where
 639     ppr = ppr_bang
 640
 641 ppr_bang (BangType s ty) = ppr s <> pprParendHsType ty
 642 \end{code}
 643
 644
 645 %************************************************************************
 646 %*                                                                      *
 647 \subsection[InstDecl]{An instance declaration
 648 %*                                                                      *
 649 %************************************************************************
 650
 651 \begin{code}
 652 data InstDecl name pat
 653   = InstDecl    (HsType name)   -- Context => Class Instance-type
 654                                 -- Using a polytype means that the renamer conveniently
 655                                 -- figures out the quantified type variables for us.
 656
 657                 (MonoBinds name pat)
 658
 659                 [Sig name]              -- User-supplied pragmatic info
 660
 661                 (Maybe name)            -- Name for the dictionary function
 662                                         -- Nothing for source-file instance decls
 663
 664                 SrcLoc
 665
 666 isSourceInstDecl :: InstDecl name pat -> Bool
 667 isSourceInstDecl (InstDecl _ _ _ maybe_dfun _) = isNothing maybe_dfun
 668 \end{code}
 669
 670 \begin{code}
 671 instance (Outputable name, Outputable pat)
 672               => Outputable (InstDecl name pat) where
 673
 674     ppr (InstDecl inst_ty binds uprags maybe_dfun_name src_loc)
 675       = vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 676               nest 4 (ppr uprags),
 677               nest 4 (ppr binds) ]
 678       where
 679         pp_dfun = case maybe_dfun_name of
 680                     Just df -> ppr df
 681                     Nothing -> empty
 682 \end{code}
 683
 684 \begin{code}
 685 instance Ord name => Eq (InstDecl name pat) where
 686         -- Used for interface comparison only, so don't compare bindings
 687   (==) (InstDecl inst_ty1 _ _ dfun1 _) (InstDecl inst_ty2 _ _ dfun2 _)
 688        = inst_ty1 == inst_ty2 && dfun1 == dfun2
 689 \end{code}
 690
 691
 692 %************************************************************************
 693 %*                                                                      *
 694 \subsection[DefaultDecl]{A @default@ declaration}
 695 %*                                                                      *
 696 %************************************************************************
 697
 698 There can only be one default declaration per module, but it is hard
 699 for the parser to check that; we pass them all through in the abstract
 700 syntax, and that restriction must be checked in the front end.
 701
 702 \begin{code}
 703 data DefaultDecl name
 704   = DefaultDecl [HsType name]
 705                 SrcLoc
 706
 707 instance (Outputable name)
 708               => Outputable (DefaultDecl name) where
 709
 710     ppr (DefaultDecl tys src_loc)
 711       = ptext SLIT("default") <+> parens (interpp'SP tys)
 712 \end{code}
 713
 714 %************************************************************************
 715 %*                                                                      *
 716 \subsection{Foreign function interface declaration}
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 \begin{code}
 721
 722 -- foreign declarations are distinguished as to whether they define or use a
 723 -- Haskell name
 724 --
 725 -- * the Boolean value indicates whether the pre-standard deprecated syntax
 726 --   has been used
 727 --
 728 data ForeignDecl name
 729   = ForeignImport name (HsType name) ForeignImport Bool SrcLoc  -- defines name
 730   | ForeignExport name (HsType name) ForeignExport Bool SrcLoc  -- uses name
 731
 732 -- yield the Haskell name defined or used in a foreign declaration
 733 --
 734 foreignDeclName                           :: ForeignDecl name -> name
 735 foreignDeclName (ForeignImport n _ _ _ _)  = n
 736 foreignDeclName (ForeignExport n _ _ _ _)  = n
 737
 738 -- specification of an imported external entity in dependence on the calling
 739 -- convention
 740 --
 741 data ForeignImport = -- import of a C entity
 742                      --
 743                      -- * the two strings specifying a header file or library
 744                      --   may be empty, which indicates the absence of a
 745                      --   header or object specification (both are not used
 746                      --   in the case of `CWrapper' and when `CFunction'
 747                      --   has a dynamic target)
 748                      --
 749                      -- * the calling convention is irrelevant for code
 750                      --   generation in the case of `CLabel', but is needed
 751                      --   for pretty printing
 752                      --
 753                      -- * `Safety' is irrelevant for `CLabel' and `CWrapper'
 754                      --
 755                      CImport  CCallConv       -- ccall or stdcall
 756                               Safety          -- safe or unsafe
 757                               FastString      -- name of C header
 758                               FastString      -- name of library object
 759                               CImportSpec     -- details of the C entity
 760
 761                      -- import of a .NET function
 762                      --
 763                    | DNImport DNCallSpec
 764
 765 -- details of an external C entity
 766 --
 767 data CImportSpec = CLabel    CLabelString     -- import address of a C label
 768                  | CFunction CCallTarget      -- static or dynamic function
 769                  | CWrapper                   -- wrapper to expose closures
 770                                               -- (former f.e.d.)
 771
 772 -- specification of an externally exported entity in dependence on the calling
 773 -- convention
 774 --
 775 data ForeignExport = CExport  CExportSpec    -- contains the calling convention
 776                    | DNExport                -- presently unused
 777
 778 -- abstract type imported from .NET
 779 --
 780 data FoType = DNType            -- In due course we'll add subtype stuff
 781             deriving (Eq)       -- Used for equality instance for TyClDecl
 782
 783
 784 -- pretty printing of foreign declarations
 785 --
 786
 787 instance Outputable name => Outputable (ForeignDecl name) where
 788   ppr (ForeignImport n ty fimport _ _) =
 789     ptext SLIT("foreign import") <+> ppr fimport <+>
 790     ppr n <+> dcolon <+> ppr ty
 791   ppr (ForeignExport n ty fexport _ _) =
 792     ptext SLIT("foreign export") <+> ppr fexport <+>
 793     ppr n <+> dcolon <+> ppr ty
 794
 795 instance Outputable ForeignImport where
 796   ppr (DNImport                         spec) =
 797     ptext SLIT("dotnet") <+> ppr spec
 798   ppr (CImport  cconv safety header lib spec) =
 799     ppr cconv <+> ppr safety <+>
 800     char '"' <> pprCEntity header lib spec <> char '"'
 801     where
 802       pprCEntity header lib (CLabel lbl) =
 803         ptext SLIT("static") <+> ptext header <+> char '&' <>
 804         pprLib lib <> ppr lbl
 805       pprCEntity header lib (CFunction (StaticTarget lbl)) =
 806         ptext SLIT("static") <+> ptext header <+> char '&' <>
 807         pprLib lib <> ppr lbl
 808       pprCEntity header lib (CFunction (DynamicTarget)) =
 809         ptext SLIT("dynamic")
 810       pprCEntity header lib (CFunction (CasmTarget _)) =
 811         panic "HsDecls.pprCEntity: malformed C function target"
 812       pprCEntity _      _   (CWrapper) = ptext SLIT("wrapper")
 813       --
 814       pprLib lib | nullFastString lib = empty
 815                  | otherwise          = char '[' <> ppr lib <> char ']'
 816
 817 instance Outputable ForeignExport where
 818   ppr (CExport  (CExportStatic lbl cconv)) =
 819     ppr cconv <+> char '"' <> ppr lbl <> char '"'
 820   ppr (DNExport                          ) =
 821     ptext SLIT("dotnet") <+> ptext SLIT("\"<unused>\"")
 822
 823 instance Outputable FoType where
 824   ppr DNType = ptext SLIT("type dotnet")
 825 \end{code}
 826
 827
 828 %************************************************************************
 829 %*                                                                      *
 830 \subsection{Transformation rules}
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 \begin{code}
 835 data RuleDecl name pat
 836   = HsRule                      -- Source rule
 837         RuleName                -- Rule name
 838         Activation
 839         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 840         (HsExpr name pat)       -- LHS
 841         (HsExpr name pat)       -- RHS
 842         SrcLoc
 843
 844   | IfaceRule                   -- One that's come in from an interface file; pre-typecheck
 845         RuleName
 846         Activation
 847         [UfBinder name]         -- Tyvars and term vars
 848         name                    -- Head of lhs
 849         [UfExpr name]           -- Args of LHS
 850         (UfExpr name)           -- Pre typecheck
 851         SrcLoc
 852
 853   | IfaceRuleOut                -- Post typecheck
 854         name                    -- Head of LHS
 855         CoreRule
 856
 857 ifaceRuleDeclName :: RuleDecl name pat -> name
 858 ifaceRuleDeclName (IfaceRule _ _ _ n _ _ _) = n
 859 ifaceRuleDeclName (IfaceRuleOut n r)        = n
 860 ifaceRuleDeclName (HsRule fs _ _ _ _ _)     = pprPanic "ifaceRuleDeclName" (ppr fs)
 861
 862 data RuleBndr name
 863   = RuleBndr name
 864   | RuleBndrSig name (HsType name)
 865
 866 collectRuleBndrSigTys :: [RuleBndr name] -> [HsType name]
 867 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 868
 869 instance (NamedThing name, Ord name) => Eq (RuleDecl name pat) where
 870   -- Works for IfaceRules only; used when comparing interface file versions
 871   (IfaceRule n1 a1 bs1 f1 es1 rhs1 _) == (IfaceRule n2 a2 bs2 f2 es2 rhs2 _)
 872      = n1==n2 && f1 == f2 && a1==a2 &&
 873        eq_ufBinders emptyEqHsEnv bs1 bs2 (\env ->
 874        eqListBy (eq_ufExpr env) (rhs1:es1) (rhs2:es2))
 875
 876 instance (NamedThing name, Outputable name, Outputable pat)
 877               => Outputable (RuleDecl name pat) where
 878   ppr (HsRule name act ns lhs rhs loc)
 879         = sep [text "{-# RULES" <+> doubleQuotes (ptext name) <+> ppr act,
 880                pp_forall, ppr lhs, equals <+> ppr rhs,
 881                text "#-}" ]
 882         where
 883           pp_forall | null ns   = empty
 884                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 885
 886   ppr (IfaceRule name act tpl_vars fn tpl_args rhs loc)
 887     = hsep [ doubleQuotes (ptext name), ppr act,
 888            ptext SLIT("__forall") <+> braces (interppSP tpl_vars),
 889            ppr fn <+> sep (map (pprUfExpr parens) tpl_args),
 890            ptext SLIT("=") <+> ppr rhs
 891       ] <+> semi
 892
 893   ppr (IfaceRuleOut fn rule) = pprCoreRule (ppr fn) rule
 894
 895 instance Outputable name => Outputable (RuleBndr name) where
 896    ppr (RuleBndr name) = ppr name
 897    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 898 \end{code}
 899
 900
 901 %************************************************************************
 902 %*                                                                      *
 903 \subsection[DeprecDecl]{Deprecations}
 904 %*                                                                      *
 905 %************************************************************************
 906
 907 We use exported entities for things to deprecate.
 908
 909 \begin{code}
 910 data DeprecDecl name = Deprecation name DeprecTxt SrcLoc
 911
 912 type DeprecTxt = FAST_STRING    -- reason/explanation for deprecation
 913
 914 instance Outputable name => Outputable (DeprecDecl name) where
 915     ppr (Deprecation thing txt _)
 916       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 917 \end{code}