ghc/compiler/hsSyn/HsDecls.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsDecls]{Abstract syntax: global declarations}
   5
   6 Definitions for: @TyDecl@ and @oCnDecl@, @ClassDecl@,
   7 @InstDecl@, @DefaultDecl@ and @ForeignDecl@.
   8
   9 \begin{code}
  10 module HsDecls (
  11         HsDecl(..), TyClDecl(..), InstDecl(..), RuleDecl(..), RuleBndr(..),
  12         DefaultDecl(..),
  13         ForeignDecl(..), FoImport(..), FoExport(..), FoType(..),
  14         ConDecl(..), ConDetails(..),
  15         BangType(..), getBangType, getBangStrictness, unbangedType,
  16         DeprecDecl(..), DeprecTxt,
  17         hsDeclName, instDeclName,
  18         tyClDeclName, tyClDeclNames, tyClDeclSysNames, tyClDeclTyVars,
  19         isClassDecl, isSynDecl, isDataDecl, isIfaceSigDecl, countTyClDecls,
  20         mkClassDeclSysNames, isIfaceRuleDecl, ifaceRuleDeclName,
  21         getClassDeclSysNames, conDetailsTys,
  22         collectRuleBndrSigTys
  23     ) where
  24
  25 #include "HsVersions.h"
  26
  27 -- friends:
  28 import HsBinds          ( HsBinds, MonoBinds, Sig(..), FixitySig(..) )
  29 import HsExpr           ( HsExpr )
  30 import HsImpExp         ( ppr_var )
  31 import HsTypes
  32 import PprCore          ( pprCoreRule )
  33 import HsCore           ( UfExpr, UfBinder, HsIdInfo, pprHsIdInfo,
  34                           eq_ufBinders, eq_ufExpr, pprUfExpr
  35                         )
  36 import CoreSyn          ( CoreRule(..), RuleName )
  37 import BasicTypes       ( NewOrData(..), StrictnessMark(..), Activation(..) )
  38 import ForeignCall      ( CExportSpec, CCallSpec, DNCallSpec, CCallConv )
  39
  40 -- others:
  41 import Name             ( NamedThing )
  42 import FunDeps          ( pprFundeps )
  43 import Class            ( FunDep, DefMeth(..) )
  44 import CStrings         ( CLabelString )
  45 import Outputable
  46 import Util             ( eqListBy, count )
  47 import SrcLoc           ( SrcLoc )
  48 import FastString
  49
  50 import Maybe            ( isNothing, fromJust )
  51 \end{code}
  52
  53
  54 %************************************************************************
  55 %*                                                                      *
  56 \subsection[HsDecl]{Declarations}
  57 %*                                                                      *
  58 %************************************************************************
  59
  60 \begin{code}
  61 data HsDecl name pat
  62   = TyClD       (TyClDecl name pat)
  63   | InstD       (InstDecl  name pat)
  64   | DefD        (DefaultDecl name)
  65   | ValD        (HsBinds name pat)
  66   | ForD        (ForeignDecl name)
  67   | FixD        (FixitySig name)
  68   | DeprecD     (DeprecDecl name)
  69   | RuleD       (RuleDecl name pat)
  70
  71 -- NB: all top-level fixity decls are contained EITHER
  72 -- EITHER FixDs
  73 -- OR     in the ClassDecls in TyClDs
  74 --
  75 -- The former covers
  76 --      a) data constructors
  77 --      b) class methods (but they can be also done in the
  78 --              signatures of class decls)
  79 --      c) imported functions (that have an IfacSig)
  80 --      d) top level decls
  81 --
  82 -- The latter is for class methods only
  83 \end{code}
  84
  85 \begin{code}
  86 #ifdef DEBUG
  87 hsDeclName :: (NamedThing name, Outputable name, Outputable pat)
  88            => HsDecl name pat -> name
  89 #endif
  90 hsDeclName (TyClD decl)                   = tyClDeclName decl
  91 hsDeclName (InstD   decl)                 = instDeclName decl
  92 hsDeclName (ForD    decl)                 = forDeclName decl
  93 hsDeclName (FixD    (FixitySig name _ _)) = name
  94 -- Others don't make sense
  95 #ifdef DEBUG
  96 hsDeclName x                                  = pprPanic "HsDecls.hsDeclName" (ppr x)
  97 #endif
  98
  99
 100 instDeclName :: InstDecl name pat -> name
 101 instDeclName (InstDecl _ _ _ (Just name) _) = name
 102
 103 \end{code}
 104
 105 \begin{code}
 106 instance (NamedThing name, Outputable name, Outputable pat)
 107         => Outputable (HsDecl name pat) where
 108
 109     ppr (TyClD dcl)  = ppr dcl
 110     ppr (ValD binds) = ppr binds
 111     ppr (DefD def)   = ppr def
 112     ppr (InstD inst) = ppr inst
 113     ppr (ForD fd)    = ppr fd
 114     ppr (FixD fd)    = ppr fd
 115     ppr (RuleD rd)   = ppr rd
 116     ppr (DeprecD dd) = ppr dd
 117 \end{code}
 118
 119
 120 %************************************************************************
 121 %*                                                                      *
 122 \subsection[TyDecl]{@data@, @newtype@ or @type@ (synonym) type declaration}
 123 %*                                                                      *
 124 %************************************************************************
 125
 126                 --------------------------------
 127                         THE NAMING STORY
 128                 --------------------------------
 129
 130 Here is the story about the implicit names that go with type, class, and instance
 131 decls.  It's a bit tricky, so pay attention!
 132
 133 "Implicit" (or "system") binders
 134 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 135   Each data type decl defines
 136         a worker name for each constructor
 137         to-T and from-T convertors
 138   Each class decl defines
 139         a tycon for the class
 140         a data constructor for that tycon
 141         the worker for that constructor
 142         a selector for each superclass
 143
 144 All have occurrence names that are derived uniquely from their parent declaration.
 145
 146 None of these get separate definitions in an interface file; they are
 147 fully defined by the data or class decl.  But they may *occur* in
 148 interface files, of course.  Any such occurrence must haul in the
 149 relevant type or class decl.
 150
 151 Plan of attack:
 152  - Make up their occurrence names immediately
 153    This is done in RdrHsSyn.mkClassDecl, mkTyDecl, mkConDecl
 154
 155  - Ensure they "point to" the parent data/class decl
 156    when loading that decl from an interface file
 157    (See RnHiFiles.getTyClDeclSysNames)
 158
 159  - When renaming the decl look them up in the name cache,
 160    ensure correct module and provenance is set
 161
 162 Default methods
 163 ~~~~~~~~~~~~~~~
 164  - Occurrence name is derived uniquely from the method name
 165    E.g. $dmmax
 166
 167  - If there is a default method name at all, it's recorded in
 168    the ClassOpSig (in HsBinds), in the DefMeth field.
 169    (DefMeth is defined in Class.lhs)
 170
 171 Source-code class decls and interface-code class decls are treated subtly
 172 differently, which has given me a great deal of confusion over the years.
 173 Here's the deal.  (We distinguish the two cases because source-code decls
 174 have (Just binds) in the tcdMeths field, whereas interface decls have Nothing.
 175
 176 In *source-code* class declarations:
 177  - When parsing, every ClassOpSig gets a DefMeth with a suitable RdrName
 178    This is done by RdrHsSyn.mkClassOpSigDM
 179
 180  - The renamer renames it to a Name
 181
 182  - During typechecking, we generate a binding for each $dm for
 183    which there's a programmer-supplied default method:
 184         class Foo a where
 185           op1 :: <type>
 186           op2 :: <type>
 187           op1 = ...
 188    We generate a binding for $dmop1 but not for $dmop2.
 189    The Class for Foo has a NoDefMeth for op2 and a DefMeth for op1.
 190    The Name for $dmop2 is simply discarded.
 191
 192 In *interface-file* class declarations:
 193   - When parsing, we see if there's an explicit programmer-supplied default method
 194     because there's an '=' sign to indicate it:
 195         class Foo a where
 196           op1 = :: <type>       -- NB the '='
 197           op2   :: <type>
 198     We use this info to generate a DefMeth with a suitable RdrName for op1,
 199     and a NoDefMeth for op2
 200   - The interface file has a separate definition for $dmop1, with unfolding etc.
 201   - The renamer renames it to a Name.
 202   - The renamer treats $dmop1 as a free variable of the declaration, so that
 203     the binding for $dmop1 will be sucked in.  (See RnHsSyn.tyClDeclFVs)
 204     This doesn't happen for source code class decls, because they *bind* the default method.
 205
 206 Dictionary functions
 207 ~~~~~~~~~~~~~~~~~~~~
 208 Each instance declaration gives rise to one dictionary function binding.
 209
 210 The type checker makes up new source-code instance declarations
 211 (e.g. from 'deriving' or generic default methods --- see
 212 TcInstDcls.tcInstDecls1).  So we can't generate the names for
 213 dictionary functions in advance (we don't know how many we need).
 214
 215 On the other hand for interface-file instance declarations, the decl
 216 specifies the name of the dictionary function, and it has a binding elsewhere
 217 in the interface file:
 218         instance {Eq Int} = dEqInt
 219         dEqInt :: {Eq Int} <pragma info>
 220
 221 So again we treat source code and interface file code slightly differently.
 222
 223 Source code:
 224   - Source code instance decls have a Nothing in the (Maybe name) field
 225     (see data InstDecl below)
 226
 227   - The typechecker makes up a Local name for the dict fun for any source-code
 228     instance decl, whether it comes from a source-code instance decl, or whether
 229     the instance decl is derived from some other construct (e.g. 'deriving').
 230
 231   - The occurrence name it chooses is derived from the instance decl (just for
 232     documentation really) --- e.g. dNumInt.  Two dict funs may share a common
 233     occurrence name, but will have different uniques.  E.g.
 234         instance Foo [Int]  where ...
 235         instance Foo [Bool] where ...
 236     These might both be dFooList
 237
 238   - The CoreTidy phase globalises the name, and ensures the occurrence name is
 239     unique (this isn't special to dict funs).  So we'd get dFooList and dFooList1.
 240
 241   - We can take this relaxed approach (changing the occurrence name later)
 242     because dict fun Ids are not captured in a TyCon or Class (unlike default
 243     methods, say).  Instead, they are kept separately in the InstEnv.  This
 244     makes it easy to adjust them after compiling a module.  (Once we've finished
 245     compiling that module, they don't change any more.)
 246
 247
 248 Interface file code:
 249   - The instance decl gives the dict fun name, so the InstDecl has a (Just name)
 250     in the (Maybe name) field.
 251
 252   - RnHsSyn.instDeclFVs treats the dict fun name as free in the decl, so that we
 253     suck in the dfun binding
 254
 255
 256 \begin{code}
 257 -- TyClDecls are precisely the kind of declarations that can
 258 -- appear in interface files; or (internally) in GHC's interface
 259 -- for a module.  That's why (despite the misnomer) IfaceSig and ForeignType
 260 -- are both in TyClDecl
 261
 262 data TyClDecl name pat
 263   = IfaceSig {  tcdName :: name,                -- It may seem odd to classify an interface-file signature
 264                 tcdType :: HsType name,         -- as a 'TyClDecl', but it's very convenient.
 265                 tcdIdInfo :: [HsIdInfo name],
 266                 tcdLoc :: SrcLoc
 267     }
 268
 269   | ForeignType { tcdName    :: name,           -- See remarks about IfaceSig above
 270                   tcdExtName :: Maybe FastString,
 271                   tcdFoType  :: FoType,
 272                   tcdLoc     :: SrcLoc }
 273
 274   | TyData {    tcdND     :: NewOrData,
 275                 tcdCtxt   :: HsContext name,     -- context
 276                 tcdName   :: name,               -- type constructor
 277                 tcdTyVars :: [HsTyVarBndr name], -- type variables
 278                 tcdCons   :: [ConDecl name],     -- data constructors (empty if abstract)
 279                 tcdNCons  :: Int,                -- Number of data constructors (valid even if type is abstract)
 280                 tcdDerivs :: Maybe [name],       -- derivings; Nothing => not specified
 281                                  -- (i.e., derive default); Just [] => derive
 282                                  -- *nothing*; Just <list> => as you would
 283                                  -- expect...
 284                 tcdSysNames :: DataSysNames name,       -- Generic converter functions
 285                 tcdLoc      :: SrcLoc
 286     }
 287
 288   | TySynonym { tcdName :: name,                        -- type constructor
 289                 tcdTyVars :: [HsTyVarBndr name],        -- type variables
 290                 tcdSynRhs :: HsType name,               -- synonym expansion
 291                 tcdLoc    :: SrcLoc
 292     }
 293
 294   | ClassDecl { tcdCtxt    :: HsContext name,           -- Context...
 295                 tcdName    :: name,                     -- Name of the class
 296                 tcdTyVars  :: [HsTyVarBndr name],       -- The class type variables
 297                 tcdFDs     :: [FunDep name],            -- Functional dependencies
 298                 tcdSigs    :: [Sig name],               -- Methods' signatures
 299                 tcdMeths   :: Maybe (MonoBinds name pat),       -- Default methods
 300                                                                 -- Nothing for imported class decls
 301                                                                 -- Just bs for source   class decls
 302                 tcdSysNames :: ClassSysNames name,
 303                 tcdLoc      :: SrcLoc
 304     }
 305 \end{code}
 306
 307 Simple classifiers
 308
 309 \begin{code}
 310 isIfaceSigDecl, isDataDecl, isSynDecl, isClassDecl :: TyClDecl name pat -> Bool
 311
 312 isIfaceSigDecl (IfaceSig {}) = True
 313 isIfaceSigDecl other         = False
 314
 315 isSynDecl (TySynonym {}) = True
 316 isSynDecl other          = False
 317
 318 isDataDecl (TyData {}) = True
 319 isDataDecl other       = False
 320
 321 isClassDecl (ClassDecl {}) = True
 322 isClassDecl other          = False
 323 \end{code}
 324
 325 Dealing with names
 326
 327 \begin{code}
 328 --------------------------------
 329 tyClDeclName :: TyClDecl name pat -> name
 330 tyClDeclName tycl_decl = tcdName tycl_decl
 331
 332 --------------------------------
 333 tyClDeclNames :: Eq name => TyClDecl name pat -> [(name, SrcLoc)]
 334 -- Returns all the *binding* names of the decl, along with their SrcLocs
 335 -- The first one is guaranteed to be the name of the decl
 336 -- For record fields, the first one counts as the SrcLoc
 337 -- We use the equality to filter out duplicate field names
 338
 339 tyClDeclNames (TySynonym   {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 340 tyClDeclNames (IfaceSig    {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 341 tyClDeclNames (ForeignType {tcdName = name, tcdLoc = loc})  = [(name,loc)]
 342
 343 tyClDeclNames (ClassDecl {tcdName = cls_name, tcdSigs = sigs, tcdLoc = loc})
 344   = (cls_name,loc) : [(n,loc) | ClassOpSig n _ _ loc <- sigs]
 345
 346 tyClDeclNames (TyData {tcdName = tc_name, tcdCons = cons, tcdLoc = loc})
 347   = (tc_name,loc) : conDeclsNames cons
 348
 349
 350 tyClDeclTyVars (TySynonym {tcdTyVars = tvs}) = tvs
 351 tyClDeclTyVars (TyData    {tcdTyVars = tvs}) = tvs
 352 tyClDeclTyVars (ClassDecl {tcdTyVars = tvs}) = tvs
 353 tyClDeclTyVars (ForeignType {})              = []
 354 tyClDeclTyVars (IfaceSig {})                 = []
 355
 356
 357 --------------------------------
 358 -- The "system names" are extra implicit names *bound* by the decl.
 359 -- They are kept in a list rather than a tuple
 360 -- to make the renamer easier.
 361
 362 type ClassSysNames name = [name]
 363 -- For class decls they are:
 364 --      [tycon, datacon wrapper, datacon worker,
 365 --       superclass selector 1, ..., superclass selector n]
 366
 367 type DataSysNames name =  [name]
 368 -- For data decls they are
 369 --      [from, to]
 370 -- where from :: T -> Tring
 371 --       to   :: Tring -> T
 372
 373 tyClDeclSysNames :: TyClDecl name pat -> [(name, SrcLoc)]
 374 -- Similar to tyClDeclNames, but returns the "implicit"
 375 -- or "system" names of the declaration
 376
 377 tyClDeclSysNames (ClassDecl {tcdSysNames = names, tcdLoc = loc})
 378   = [(n,loc) | n <- names]
 379 tyClDeclSysNames (TyData {tcdCons = cons, tcdSysNames = names, tcdLoc = loc})
 380   = [(n,loc) | n <- names] ++
 381     [(wkr_name,loc) | ConDecl _ wkr_name _ _ _ loc <- cons]
 382 tyClDeclSysNames decl = []
 383
 384
 385 mkClassDeclSysNames  :: (name, name, name, [name]) -> [name]
 386 getClassDeclSysNames :: [name] -> (name, name, name, [name])
 387 mkClassDeclSysNames  (a,b,c,ds) = a:b:c:ds
 388 getClassDeclSysNames (a:b:c:ds) = (a,b,c,ds)
 389 \end{code}
 390
 391 \begin{code}
 392 instance (NamedThing name, Ord name) => Eq (TyClDecl name pat) where
 393         -- Used only when building interface files
 394   (==) d1@(IfaceSig {}) d2@(IfaceSig {})
 395       = tcdName d1 == tcdName d2 &&
 396         tcdType d1 == tcdType d2 &&
 397         tcdIdInfo d1 == tcdIdInfo d2
 398
 399   (==) d1@(ForeignType {}) d2@(ForeignType {})
 400       = tcdName d1 == tcdName d2 &&
 401         tcdFoType d1 == tcdFoType d2
 402
 403   (==) d1@(TyData {}) d2@(TyData {})
 404       = tcdName d1 == tcdName d2 &&
 405         tcdND d1   == tcdND   d2 &&
 406         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 407           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 408           eqListBy (eq_ConDecl env) (tcdCons d1) (tcdCons d2)
 409         )
 410
 411   (==) d1@(TySynonym {}) d2@(TySynonym {})
 412       = tcdName d1 == tcdName d2 &&
 413         eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 414           eq_hsType env (tcdSynRhs d1) (tcdSynRhs d2)
 415         )
 416
 417   (==) d1@(ClassDecl {}) d2@(ClassDecl {})
 418     = tcdName d1 == tcdName d2 &&
 419       eqWithHsTyVars (tcdTyVars d1) (tcdTyVars d2) (\ env ->
 420           eq_hsContext env (tcdCtxt d1) (tcdCtxt d2)  &&
 421           eqListBy (eq_hsFD env) (tcdFDs d1) (tcdFDs d2) &&
 422           eqListBy (eq_cls_sig env) (tcdSigs d1) (tcdSigs d2)
 423        )
 424
 425   (==) _ _ = False      -- default case
 426
 427 eq_hsFD env (ns1,ms1) (ns2,ms2)
 428   = eqListBy (eq_hsVar env) ns1 ns2 && eqListBy (eq_hsVar env) ms1 ms2
 429
 430 eq_cls_sig env (ClassOpSig n1 dm1 ty1 _) (ClassOpSig n2 dm2 ty2 _)
 431   = n1==n2 && dm1 `eq_dm` dm2 && eq_hsType env ty1 ty2
 432   where
 433         -- Ignore the name of the default method for (DefMeth id)
 434         -- This is used for comparing declarations before putting
 435         -- them into interface files, and the name of the default
 436         -- method isn't relevant
 437     NoDefMeth  `eq_dm` NoDefMeth  = True
 438     GenDefMeth `eq_dm` GenDefMeth = True
 439     DefMeth _  `eq_dm` DefMeth _  = True
 440     dm1        `eq_dm` dm2        = False
 441
 442
 443 \end{code}
 444
 445 \begin{code}
 446 countTyClDecls :: [TyClDecl name pat] -> (Int, Int, Int, Int, Int)
 447         -- class, data, newtype, synonym decls
 448 countTyClDecls decls
 449  = (count isClassDecl     decls,
 450     count isSynDecl       decls,
 451     count isIfaceSigDecl  decls,
 452     count isDataTy        decls,
 453     count isNewTy         decls)
 454  where
 455    isDataTy TyData{tcdND=DataType} = True
 456    isDataTy _                      = False
 457
 458    isNewTy TyData{tcdND=NewType} = True
 459    isNewTy _                     = False
 460 \end{code}
 461
 462 \begin{code}
 463 instance (NamedThing name, Outputable name, Outputable pat)
 464               => Outputable (TyClDecl name pat) where
 465
 466     ppr (IfaceSig {tcdName = var, tcdType = ty, tcdIdInfo = info})
 467         = getPprStyle $ \ sty ->
 468            hsep [ if ifaceStyle sty then ppr var else ppr_var var,
 469                   dcolon, ppr ty, pprHsIdInfo info
 470                 ]
 471
 472     ppr (ForeignType {tcdName = tycon})
 473         = hsep [ptext SLIT("foreign import type dotnet"), ppr tycon]
 474
 475     ppr (TySynonym {tcdName = tycon, tcdTyVars = tyvars, tcdSynRhs = mono_ty})
 476       = hang (ptext SLIT("type") <+> pp_decl_head [] tycon tyvars <+> equals)
 477              4 (ppr mono_ty)
 478
 479     ppr (TyData {tcdND = new_or_data, tcdCtxt = context, tcdName = tycon,
 480                  tcdTyVars = tyvars, tcdCons = condecls, tcdNCons = ncons,
 481                  tcdDerivs = derivings})
 482       = pp_tydecl (ptext keyword <+> pp_decl_head context tycon tyvars)
 483                   (pp_condecls condecls ncons)
 484                   derivings
 485       where
 486         keyword = case new_or_data of
 487                         NewType  -> SLIT("newtype")
 488                         DataType -> SLIT("data")
 489
 490     ppr (ClassDecl {tcdCtxt = context, tcdName = clas, tcdTyVars = tyvars, tcdFDs = fds,
 491                     tcdSigs = sigs, tcdMeths = methods})
 492       | null sigs       -- No "where" part
 493       = top_matter
 494
 495       | otherwise       -- Laid out
 496       = sep [hsep [top_matter, ptext SLIT("where {")],
 497              nest 4 (sep [sep (map ppr_sig sigs), pp_methods, char '}'])]
 498       where
 499         top_matter  = ptext SLIT("class") <+> pp_decl_head context clas tyvars <+> pprFundeps fds
 500         ppr_sig sig = ppr sig <> semi
 501
 502         pp_methods = getPprStyle $ \ sty ->
 503                      if ifaceStyle sty || isNothing methods
 504                         then empty
 505                         else ppr (fromJust methods)
 506
 507 pp_decl_head :: Outputable name => HsContext name -> name -> [HsTyVarBndr name] -> SDoc
 508 pp_decl_head context thing tyvars = hsep [pprHsContext context, ppr thing, interppSP tyvars]
 509
 510 pp_condecls []     ncons = ptext SLIT("{- abstract with") <+> int ncons <+> ptext SLIT("constructors -}")
 511 pp_condecls (c:cs) ncons = equals <+> sep (ppr c : map (\ c -> ptext SLIT("|") <+> ppr c) cs)
 512
 513 pp_tydecl pp_head pp_decl_rhs derivings
 514   = hang pp_head 4 (sep [
 515         pp_decl_rhs,
 516         case derivings of
 517           Nothing          -> empty
 518           Just ds          -> hsep [ptext SLIT("deriving"), parens (interpp'SP ds)]
 519     ])
 520 \end{code}
 521
 522
 523 %************************************************************************
 524 %*                                                                      *
 525 \subsection[ConDecl]{A data-constructor declaration}
 526 %*                                                                      *
 527 %************************************************************************
 528
 529 \begin{code}
 530 data ConDecl name
 531   = ConDecl     name                    -- Constructor name; this is used for the
 532                                         -- DataCon itself, and for the user-callable wrapper Id
 533
 534                 name                    -- Name of the constructor's 'worker Id'
 535                                         -- Filled in as the ConDecl is built
 536
 537                 [HsTyVarBndr name]      -- Existentially quantified type variables
 538                 (HsContext name)        -- ...and context
 539                                         -- If both are empty then there are no existentials
 540
 541                 (ConDetails name)
 542                 SrcLoc
 543
 544 data ConDetails name
 545   = VanillaCon                  -- prefix-style con decl
 546                 [BangType name]
 547
 548   | InfixCon                    -- infix-style con decl
 549                 (BangType name)
 550                 (BangType name)
 551
 552   | RecCon                      -- record-style con decl
 553                 [([name], BangType name)]       -- list of "fields"
 554 \end{code}
 555
 556 \begin{code}
 557 conDeclsNames :: Eq name => [ConDecl name] -> [(name,SrcLoc)]
 558   -- See tyClDeclNames for what this does
 559   -- The function is boringly complicated because of the records
 560   -- And since we only have equality, we have to be a little careful
 561 conDeclsNames cons
 562   = snd (foldl do_one ([], []) cons)
 563   where
 564     do_one (flds_seen, acc) (ConDecl name _ _ _ details loc)
 565         = do_details ((name,loc):acc) details
 566         where
 567           do_details acc (RecCon flds) = foldl do_fld (flds_seen, acc) flds
 568           do_details acc other         = (flds_seen, acc)
 569
 570           do_fld acc (flds, _) = foldl do_fld1 acc flds
 571
 572           do_fld1 (flds_seen, acc) fld
 573                 | fld `elem` flds_seen = (flds_seen,acc)
 574                 | otherwise            = (fld:flds_seen, (fld,loc):acc)
 575 \end{code}
 576
 577 \begin{code}
 578 conDetailsTys :: ConDetails name -> [HsType name]
 579 conDetailsTys (VanillaCon btys)    = map getBangType btys
 580 conDetailsTys (InfixCon bty1 bty2) = [getBangType bty1, getBangType bty2]
 581 conDetailsTys (RecCon fields)      = [getBangType bty | (_, bty) <- fields]
 582
 583
 584 eq_ConDecl env (ConDecl n1 _ tvs1 cxt1 cds1 _)
 585                (ConDecl n2 _ tvs2 cxt2 cds2 _)
 586   = n1 == n2 &&
 587     (eq_hsTyVars env tvs1 tvs2  $ \ env ->
 588      eq_hsContext env cxt1 cxt2 &&
 589      eq_ConDetails env cds1 cds2)
 590
 591 eq_ConDetails env (VanillaCon bts1) (VanillaCon bts2)
 592   = eqListBy (eq_btype env) bts1 bts2
 593 eq_ConDetails env (InfixCon bta1 btb1) (InfixCon bta2 btb2)
 594   = eq_btype env bta1 bta2 && eq_btype env btb1 btb2
 595 eq_ConDetails env (RecCon fs1) (RecCon fs2)
 596   = eqListBy (eq_fld env) fs1 fs2
 597 eq_ConDetails env _ _ = False
 598
 599 eq_fld env (ns1,bt1) (ns2, bt2) = ns1==ns2 && eq_btype env bt1 bt2
 600 \end{code}
 601
 602 \begin{code}
 603 data BangType name = BangType StrictnessMark (HsType name)
 604
 605 getBangType       (BangType _ ty) = ty
 606 getBangStrictness (BangType s _)  = s
 607
 608 unbangedType ty = BangType NotMarkedStrict ty
 609
 610 eq_btype env (BangType s1 t1) (BangType s2 t2) = s1==s2 && eq_hsType env t1 t2
 611 \end{code}
 612
 613 \begin{code}
 614 instance (Outputable name) => Outputable (ConDecl name) where
 615     ppr (ConDecl con _ tvs cxt con_details  loc)
 616       = sep [pprHsForAll tvs cxt, ppr_con_details con con_details]
 617
 618 ppr_con_details con (InfixCon ty1 ty2)
 619   = hsep [ppr_bang ty1, ppr con, ppr_bang ty2]
 620
 621 -- ConDecls generated by MkIface.ifaceTyThing always have a VanillaCon, even
 622 -- if the constructor is an infix one.  This is because in an interface file
 623 -- we don't distinguish between the two.  Hence when printing these for the
 624 -- user, we need to parenthesise infix constructor names.
 625 ppr_con_details con (VanillaCon tys)
 626   = getPprStyle $ \ sty ->
 627     hsep ((if ifaceStyle sty then ppr con else ppr_var con)
 628           : map (ppr_bang) tys)
 629
 630 ppr_con_details con (RecCon fields)
 631   = ppr con <+> braces (sep (punctuate comma (map ppr_field fields)))
 632   where
 633     ppr_field (ns, ty) = hsep (map (ppr) ns) <+>
 634                          dcolon <+>
 635                          ppr_bang ty
 636
 637 instance Outputable name => Outputable (BangType name) where
 638     ppr = ppr_bang
 639
 640 ppr_bang (BangType s ty) = ppr s <> pprParendHsType ty
 641 \end{code}
 642
 643
 644 %************************************************************************
 645 %*                                                                      *
 646 \subsection[InstDecl]{An instance declaration
 647 %*                                                                      *
 648 %************************************************************************
 649
 650 \begin{code}
 651 data InstDecl name pat
 652   = InstDecl    (HsType name)   -- Context => Class Instance-type
 653                                 -- Using a polytype means that the renamer conveniently
 654                                 -- figures out the quantified type variables for us.
 655
 656                 (MonoBinds name pat)
 657
 658                 [Sig name]              -- User-supplied pragmatic info
 659
 660                 (Maybe name)            -- Name for the dictionary function
 661                                         -- Nothing for source-file instance decls
 662
 663                 SrcLoc
 664 \end{code}
 665
 666 \begin{code}
 667 instance (Outputable name, Outputable pat)
 668               => Outputable (InstDecl name pat) where
 669
 670     ppr (InstDecl inst_ty binds uprags maybe_dfun_name src_loc)
 671       = getPprStyle $ \ sty ->
 672         if ifaceStyle sty then
 673            hsep [ptext SLIT("instance"), ppr inst_ty, equals, pp_dfun]
 674         else
 675            vcat [hsep [ptext SLIT("instance"), ppr inst_ty, ptext SLIT("where")],
 676                  nest 4 (ppr uprags),
 677                  nest 4 (ppr binds) ]
 678       where
 679         pp_dfun = case maybe_dfun_name of
 680                     Just df -> ppr df
 681                     Nothing -> empty
 682 \end{code}
 683
 684 \begin{code}
 685 instance Ord name => Eq (InstDecl name pat) where
 686         -- Used for interface comparison only, so don't compare bindings
 687   (==) (InstDecl inst_ty1 _ _ dfun1 _) (InstDecl inst_ty2 _ _ dfun2 _)
 688        = inst_ty1 == inst_ty2 && dfun1 == dfun2
 689 \end{code}
 690
 691
 692 %************************************************************************
 693 %*                                                                      *
 694 \subsection[DefaultDecl]{A @default@ declaration}
 695 %*                                                                      *
 696 %************************************************************************
 697
 698 There can only be one default declaration per module, but it is hard
 699 for the parser to check that; we pass them all through in the abstract
 700 syntax, and that restriction must be checked in the front end.
 701
 702 \begin{code}
 703 data DefaultDecl name
 704   = DefaultDecl [HsType name]
 705                 SrcLoc
 706
 707 instance (Outputable name)
 708               => Outputable (DefaultDecl name) where
 709
 710     ppr (DefaultDecl tys src_loc)
 711       = ptext SLIT("default") <+> parens (interpp'SP tys)
 712 \end{code}
 713
 714 %************************************************************************
 715 %*                                                                      *
 716 \subsection{Foreign function interface declaration}
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 \begin{code}
 721 data ForeignDecl name
 722   = ForeignImport name (HsType name) FoImport     SrcLoc
 723   | ForeignExport name (HsType name) FoExport     SrcLoc
 724
 725 forDeclName (ForeignImport n _ _ _) = n
 726 forDeclName (ForeignExport n _ _ _) = n
 727
 728 data FoImport
 729   = LblImport  CLabelString     -- foreign label
 730   | CImport    CCallSpec        -- foreign import
 731   | CDynImport CCallConv        -- foreign export dynamic
 732   | DNImport   DNCallSpec       -- foreign import dotnet
 733
 734 data FoExport = CExport CExportSpec
 735
 736 data FoType = DNType            -- In due course we'll add subtype stuff
 737             deriving( Eq )      -- Used for equality instance for TyClDecl
 738
 739 instance Outputable name => Outputable (ForeignDecl name) where
 740   ppr (ForeignImport nm ty (LblImport lbl) src_loc)
 741     = ptext SLIT("foreign label") <+> ppr lbl <+> ppr nm <+> dcolon <+> ppr ty
 742   ppr (ForeignImport nm ty decl src_loc)
 743     = ptext SLIT("foreign import") <+> ppr decl <+> ppr nm <+> dcolon <+> ppr ty
 744   ppr (ForeignExport nm ty decl src_loc)
 745     = ptext SLIT("foreign export") <+> ppr decl <+> ppr nm <+> dcolon <+> ppr ty
 746
 747 instance Outputable FoImport where
 748    ppr (CImport  d)      = ppr d
 749    ppr (CDynImport conv) = text "dynamic" <+> ppr conv
 750    ppr (DNImport d)      = ptext SLIT("dotnet") <+> ppr d
 751    ppr (LblImport l)     = ptext SLIT("label") <+> ppr l
 752
 753 instance Outputable FoExport where
 754    ppr (CExport d) = ppr d
 755
 756 instance Outputable FoType where
 757    ppr DNType = ptext SLIT("type dotnet")
 758 \end{code}
 759
 760
 761 %************************************************************************
 762 %*                                                                      *
 763 \subsection{Transformation rules}
 764 %*                                                                      *
 765 %************************************************************************
 766
 767 \begin{code}
 768 data RuleDecl name pat
 769   = HsRule                      -- Source rule
 770         RuleName                -- Rule name
 771         Activation
 772         [RuleBndr name]         -- Forall'd vars; after typechecking this includes tyvars
 773         (HsExpr name pat)       -- LHS
 774         (HsExpr name pat)       -- RHS
 775         SrcLoc
 776
 777   | IfaceRule                   -- One that's come in from an interface file; pre-typecheck
 778         RuleName
 779         Activation
 780         [UfBinder name]         -- Tyvars and term vars
 781         name                    -- Head of lhs
 782         [UfExpr name]           -- Args of LHS
 783         (UfExpr name)           -- Pre typecheck
 784         SrcLoc
 785
 786   | IfaceRuleOut                -- Post typecheck
 787         name                    -- Head of LHS
 788         CoreRule
 789
 790 isIfaceRuleDecl :: RuleDecl name pat -> Bool
 791 isIfaceRuleDecl (HsRule _ _ _ _ _ _) = False
 792 isIfaceRuleDecl other                = True
 793
 794 ifaceRuleDeclName :: RuleDecl name pat -> name
 795 ifaceRuleDeclName (IfaceRule _ _ _ n _ _ _) = n
 796 ifaceRuleDeclName (IfaceRuleOut n r)        = n
 797 ifaceRuleDeclName (HsRule fs _ _ _ _ _)     = pprPanic "ifaceRuleDeclName" (ppr fs)
 798
 799 data RuleBndr name
 800   = RuleBndr name
 801   | RuleBndrSig name (HsType name)
 802
 803 collectRuleBndrSigTys :: [RuleBndr name] -> [HsType name]
 804 collectRuleBndrSigTys bndrs = [ty | RuleBndrSig _ ty <- bndrs]
 805
 806 instance (NamedThing name, Ord name) => Eq (RuleDecl name pat) where
 807   -- Works for IfaceRules only; used when comparing interface file versions
 808   (IfaceRule n1 a1 bs1 f1 es1 rhs1 _) == (IfaceRule n2 a2 bs2 f2 es2 rhs2 _)
 809      = n1==n2 && f1 == f2 && a1==a2 &&
 810        eq_ufBinders emptyEqHsEnv bs1 bs2 (\env ->
 811        eqListBy (eq_ufExpr env) (rhs1:es1) (rhs2:es2))
 812
 813 instance (NamedThing name, Outputable name, Outputable pat)
 814               => Outputable (RuleDecl name pat) where
 815   ppr (HsRule name act ns lhs rhs loc)
 816         = sep [text "{-# RULES" <+> doubleQuotes (ptext name) <+> ppr act,
 817                pp_forall, ppr lhs, equals <+> ppr rhs,
 818                text "#-}" ]
 819         where
 820           pp_forall | null ns   = empty
 821                     | otherwise = text "forall" <+> fsep (map ppr ns) <> dot
 822
 823   ppr (IfaceRule name act tpl_vars fn tpl_args rhs loc)
 824     = hsep [ doubleQuotes (ptext name), ppr act,
 825            ptext SLIT("__forall") <+> braces (interppSP tpl_vars),
 826            ppr fn <+> sep (map (pprUfExpr parens) tpl_args),
 827            ptext SLIT("=") <+> ppr rhs
 828       ] <+> semi
 829
 830   ppr (IfaceRuleOut fn rule) = pprCoreRule (ppr fn) rule
 831
 832 instance Outputable name => Outputable (RuleBndr name) where
 833    ppr (RuleBndr name) = ppr name
 834    ppr (RuleBndrSig name ty) = ppr name <> dcolon <> ppr ty
 835 \end{code}
 836
 837
 838 %************************************************************************
 839 %*                                                                      *
 840 \subsection[DeprecDecl]{Deprecations}
 841 %*                                                                      *
 842 %************************************************************************
 843
 844 We use exported entities for things to deprecate.
 845
 846 \begin{code}
 847 data DeprecDecl name = Deprecation name DeprecTxt SrcLoc
 848
 849 type DeprecTxt = FAST_STRING    -- reason/explanation for deprecation
 850
 851 instance Outputable name => Outputable (DeprecDecl name) where
 852     ppr (Deprecation thing txt _)
 853       = hsep [text "{-# DEPRECATED", ppr thing, doubleQuotes (ppr txt), text "#-}"]
 854 \end{code}