ghc/compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsExpr]{Abstract Haskell syntax: expressions}
   5
   6 \begin{code}
   7 module HsExpr where
   8
   9 #include "HsVersions.h"
  10
  11 -- friends:
  12 import {-# SOURCE #-} HsMatches ( pprMatches, pprMatch, Match )
  13
  14 import HsBinds          ( HsBinds(..) )
  15 import HsBasic          ( HsLit )
  16 import BasicTypes       ( Fixity(..), FixityDirection(..) )
  17 import HsTypes          ( HsType )
  18
  19 -- others:
  20 import Name             ( Name, isLexId )
  21 import Outputable
  22 import PprType          ( pprType, pprParendType )
  23 import Type             ( Type )
  24 import Var              ( TyVar, Id )
  25 import DataCon          ( DataCon )
  26 import CStrings         ( CLabelString, pprCLabelString )
  27 import SrcLoc           ( SrcLoc )
  28 \end{code}
  29
  30 %************************************************************************
  31 %*                                                                      *
  32 \subsection{Expressions proper}
  33 %*                                                                      *
  34 %************************************************************************
  35
  36 \begin{code}
  37 data HsExpr id pat
  38   = HsVar       id                              -- variable
  39   | HsIPVar     id                              -- implicit parameter
  40   | HsLit       HsLit                           -- literal
  41   | HsLitOut    HsLit                           -- TRANSLATION
  42                 Type            -- (with its type)
  43
  44   | HsLam       (Match  id pat) -- lambda
  45   | HsApp       (HsExpr id pat) -- application
  46                 (HsExpr id pat)
  47
  48   -- Operator applications:
  49   -- NB Bracketed ops such as (+) come out as Vars.
  50
  51   -- NB We need an expr for the operator in an OpApp/Section since
  52   -- the typechecker may need to apply the operator to a few types.
  53
  54   | OpApp       (HsExpr id pat) -- left operand
  55                 (HsExpr id pat) -- operator
  56                 Fixity                          -- Renamer adds fixity; bottom until then
  57                 (HsExpr id pat) -- right operand
  58
  59   -- We preserve prefix negation and parenthesis for the precedence parser.
  60   -- They are eventually removed by the type checker.
  61
  62   | NegApp      (HsExpr id pat) -- negated expr
  63                 (HsExpr id pat) -- the negate id (in a HsVar)
  64
  65   | HsPar       (HsExpr id pat) -- parenthesised expr
  66
  67   | SectionL    (HsExpr id pat) -- operand
  68                 (HsExpr id pat) -- operator
  69   | SectionR    (HsExpr id pat) -- operator
  70                 (HsExpr id pat) -- operand
  71
  72   | HsCase      (HsExpr id pat)
  73                 [Match id pat]
  74                 SrcLoc
  75
  76   | HsIf        (HsExpr id pat) --  predicate
  77                 (HsExpr id pat) --  then part
  78                 (HsExpr id pat) --  else part
  79                 SrcLoc
  80
  81   | HsLet       (HsBinds id pat)        -- let(rec)
  82                 (HsExpr  id pat)
  83
  84   | HsWith      (HsExpr id pat) -- implicit parameter binding
  85                 [(id, HsExpr id pat)]
  86
  87   | HsDo        StmtCtxt
  88                 [Stmt id pat]   -- "do":one or more stmts
  89                 SrcLoc
  90
  91   | HsDoOut     StmtCtxt
  92                 [Stmt id pat]   -- "do":one or more stmts
  93                 id              -- id for return
  94                 id              -- id for >>=
  95                 id                              -- id for zero
  96                 Type            -- Type of the whole expression
  97                 SrcLoc
  98
  99   | ExplicitList                -- syntactic list
 100                 [HsExpr id pat]
 101   | ExplicitListOut             -- TRANSLATION
 102                 Type    -- Gives type of components of list
 103                 [HsExpr id pat]
 104
 105   | ExplicitTuple               -- tuple
 106                 [HsExpr id pat]
 107                                 -- NB: Unit is ExplicitTuple []
 108                                 -- for tuples, we can get the types
 109                                 -- direct from the components
 110                 Bool            -- boxed?
 111
 112
 113         -- Record construction
 114   | RecordCon   id                              -- The constructor
 115                 (HsRecordBinds id pat)
 116
 117   | RecordConOut DataCon
 118                 (HsExpr id pat)         -- Data con Id applied to type args
 119                 (HsRecordBinds id pat)
 120
 121
 122         -- Record update
 123   | RecordUpd   (HsExpr id pat)
 124                 (HsRecordBinds id pat)
 125
 126   | RecordUpdOut (HsExpr id pat)        -- TRANSLATION
 127                  Type                   -- Type of *result* record (may differ from
 128                                                 -- type of input record)
 129                  [id]                   -- Dicts needed for construction
 130                  (HsRecordBinds id pat)
 131
 132   | ExprWithTySig                       -- signature binding
 133                 (HsExpr id pat)
 134                 (HsType id)
 135   | ArithSeqIn                          -- arithmetic sequence
 136                 (ArithSeqInfo id pat)
 137   | ArithSeqOut
 138                 (HsExpr id pat)         -- (typechecked, of course)
 139                 (ArithSeqInfo id pat)
 140
 141   | HsCCall     CLabelString    -- call into the C world; string is
 142                 [HsExpr id pat] -- the C function; exprs are the
 143                                 -- arguments to pass.
 144                 Bool            -- True <=> might cause Haskell
 145                                 -- garbage-collection (must generate
 146                                 -- more paranoid code)
 147                 Bool            -- True <=> it's really a "casm"
 148                                 -- NOTE: this CCall is the *boxed*
 149                                 -- version; the desugarer will convert
 150                                 -- it into the unboxed "ccall#".
 151                 Type    -- The result type; will be *bottom*
 152                                 -- until the typechecker gets ahold of it
 153
 154   | HsSCC       FAST_STRING     -- "set cost centre" (_scc_) annotation
 155                 (HsExpr id pat) -- expr whose cost is to be measured
 156 \end{code}
 157
 158 These constructors only appear temporarily in the parser.
 159 The renamer translates them into the Right Thing.
 160
 161 \begin{code}
 162   | EWildPat                    -- wildcard
 163
 164   | EAsPat      id              -- as pattern
 165                 (HsExpr id pat)
 166
 167   | ELazyPat    (HsExpr id pat) -- ~ pattern
 168 \end{code}
 169
 170 Everything from here on appears only in typechecker output.
 171
 172 \begin{code}
 173   | TyLam                       -- TRANSLATION
 174                 [TyVar]
 175                 (HsExpr id pat)
 176   | TyApp                       -- TRANSLATION
 177                 (HsExpr id pat) -- generated by Spec
 178                 [Type]
 179
 180   -- DictLam and DictApp are "inverses"
 181   |  DictLam
 182                 [id]
 183                 (HsExpr id pat)
 184   |  DictApp
 185                 (HsExpr id pat)
 186                 [id]
 187
 188 type HsRecordBinds id pat
 189   = [(id, HsExpr id pat, Bool)]
 190         -- True <=> source code used "punning",
 191         -- i.e. {op1, op2} rather than {op1=e1, op2=e2}
 192 \end{code}
 193
 194 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 195 @ClassDictLam dictvars methods expr@ is, therefore:
 196 \begin{verbatim}
 197 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 198 \end{verbatim}
 199
 200 \begin{code}
 201 instance (Outputable id, Outputable pat) =>
 202                 Outputable (HsExpr id pat) where
 203     ppr expr = pprExpr expr
 204 \end{code}
 205
 206 \begin{code}
 207 pprExpr :: (Outputable id, Outputable pat)
 208         => HsExpr id pat -> SDoc
 209
 210 pprExpr e = pprDeeper (ppr_expr e)
 211 pprBinds b = pprDeeper (ppr b)
 212
 213 ppr_expr (HsVar v) = ppr v
 214 ppr_expr (HsIPVar v) = {- char '?' <> -} ppr v
 215
 216 ppr_expr (HsLit    lit)   = ppr lit
 217 ppr_expr (HsLitOut lit _) = ppr lit
 218
 219 ppr_expr (HsLam match)
 220   = hsep [char '\\', nest 2 (pprMatch (True,empty) match)]
 221
 222 ppr_expr expr@(HsApp e1 e2)
 223   = let (fun, args) = collect_args expr [] in
 224     (ppr_expr fun) <+> (sep (map ppr_expr args))
 225   where
 226     collect_args (HsApp fun arg) args = collect_args fun (arg:args)
 227     collect_args fun             args = (fun, args)
 228
 229 ppr_expr (OpApp e1 op fixity e2)
 230   = case op of
 231       HsVar v -> pp_infixly v
 232       _       -> pp_prefixly
 233   where
 234     pp_e1 = pprParendExpr e1            -- Add parens to make precedence clear
 235     pp_e2 = pprParendExpr e2
 236
 237     pp_prefixly
 238       = hang (pprExpr op) 4 (sep [pp_e1, pp_e2])
 239
 240     pp_infixly v
 241       = sep [pp_e1, hsep [pp_v_op, pp_e2]]
 242       where
 243         pp_v = ppr v
 244         pp_v_op | isLexId (_PK_ (showSDoc pp_v)) = char '`' <> pp_v <> char '`'
 245                 | otherwise                      = pp_v
 246         -- Put it in backquotes if it's not an operator already
 247         -- We use (showSDoc pp_v), rather than isSymOcc (getOccName v) simply so
 248         -- that we don't need NamedThing in the context of all these funcions.
 249         -- Gruesome, but simple.
 250
 251 ppr_expr (NegApp e _)
 252   = char '-' <+> pprParendExpr e
 253
 254 ppr_expr (HsPar e) = parens (ppr_expr e)
 255
 256 ppr_expr (SectionL expr op)
 257   = case op of
 258       HsVar v -> pp_infixly v
 259       _       -> pp_prefixly
 260   where
 261     pp_expr = pprParendExpr expr
 262
 263     pp_prefixly = hang (hsep [text " \\ x_ ->", ppr op])
 264                        4 (hsep [pp_expr, ptext SLIT("x_ )")])
 265     pp_infixly v = parens (sep [pp_expr, ppr v])
 266
 267 ppr_expr (SectionR op expr)
 268   = case op of
 269       HsVar v -> pp_infixly v
 270       _       -> pp_prefixly
 271   where
 272     pp_expr = pprParendExpr expr
 273
 274     pp_prefixly = hang (hsep [text "( \\ x_ ->", ppr op, ptext SLIT("x_")])
 275                        4 ((<>) pp_expr rparen)
 276     pp_infixly v
 277       = parens (sep [ppr v, pp_expr])
 278
 279 ppr_expr (HsCase expr matches _)
 280   = sep [ sep [ptext SLIT("case"), nest 4 (pprExpr expr), ptext SLIT("of")],
 281             nest 2 (pprMatches (True, empty) matches) ]
 282
 283 ppr_expr (HsIf e1 e2 e3 _)
 284   = sep [hsep [ptext SLIT("if"), nest 2 (pprExpr e1), ptext SLIT("then")],
 285            nest 4 (pprExpr e2),
 286            ptext SLIT("else"),
 287            nest 4 (pprExpr e3)]
 288
 289 -- special case: let ... in let ...
 290 ppr_expr (HsLet binds expr@(HsLet _ _))
 291   = sep [hang (ptext SLIT("let")) 2 (hsep [pprBinds binds, ptext SLIT("in")]),
 292          pprExpr expr]
 293
 294 ppr_expr (HsLet binds expr)
 295   = sep [hang (ptext SLIT("let")) 2 (pprBinds binds),
 296          hang (ptext SLIT("in"))  2 (ppr expr)]
 297
 298 ppr_expr (HsWith expr binds)
 299   = hsep [ppr expr, ptext SLIT("with"), ppr binds]
 300
 301 ppr_expr (HsDo do_or_list_comp stmts _)            = pprDo do_or_list_comp stmts
 302 ppr_expr (HsDoOut do_or_list_comp stmts _ _ _ _ _) = pprDo do_or_list_comp stmts
 303
 304 ppr_expr (ExplicitList exprs)
 305   = brackets (fsep (punctuate comma (map ppr_expr exprs)))
 306 ppr_expr (ExplicitListOut ty exprs)
 307   = hcat [ brackets (fsep (punctuate comma (map ppr_expr exprs))),
 308            ifNotPprForUser ((<>) space (parens (pprType ty))) ]
 309
 310 ppr_expr (ExplicitTuple exprs True)
 311   = parens (sep (punctuate comma (map ppr_expr exprs)))
 312
 313 ppr_expr (ExplicitTuple exprs False)
 314   = ptext SLIT("(#") <> sep (punctuate comma (map ppr_expr exprs)) <> ptext SLIT("#)")
 315
 316 ppr_expr (RecordCon con_id rbinds)
 317   = pp_rbinds (ppr con_id) rbinds
 318 ppr_expr (RecordConOut data_con con rbinds)
 319   = pp_rbinds (ppr con) rbinds
 320
 321 ppr_expr (RecordUpd aexp rbinds)
 322   = pp_rbinds (pprParendExpr aexp) rbinds
 323 ppr_expr (RecordUpdOut aexp _ _ rbinds)
 324   = pp_rbinds (pprParendExpr aexp) rbinds
 325
 326 ppr_expr (ExprWithTySig expr sig)
 327   = hang (nest 2 (ppr_expr expr) <+> dcolon)
 328          4 (ppr sig)
 329
 330 ppr_expr (ArithSeqIn info)
 331   = brackets (ppr info)
 332 ppr_expr (ArithSeqOut expr info)
 333   = brackets (ppr info)
 334
 335 ppr_expr EWildPat = char '_'
 336 ppr_expr (ELazyPat e) = char '~' <> pprParendExpr e
 337 ppr_expr (EAsPat v e) = ppr v <> char '@' <> pprParendExpr e
 338
 339 ppr_expr (HsCCall fun args _ is_asm result_ty)
 340   = hang (if is_asm
 341           then ptext SLIT("_casm_ ``") <> pprCLabelString fun <> ptext SLIT("''")
 342           else ptext SLIT("_ccall_") <+> pprCLabelString fun)
 343        4 (sep (map pprParendExpr args))
 344
 345 ppr_expr (HsSCC lbl expr)
 346   = sep [ ptext SLIT("_scc_") <+> doubleQuotes (ptext lbl), pprParendExpr expr ]
 347
 348 ppr_expr (TyLam tyvars expr)
 349   = hang (hsep [ptext SLIT("/\\"), interppSP tyvars, ptext SLIT("->")])
 350          4 (ppr_expr expr)
 351
 352 ppr_expr (TyApp expr [ty])
 353   = hang (ppr_expr expr) 4 (pprParendType ty)
 354
 355 ppr_expr (TyApp expr tys)
 356   = hang (ppr_expr expr)
 357          4 (brackets (interpp'SP tys))
 358
 359 ppr_expr (DictLam dictvars expr)
 360   = hang (hsep [ptext SLIT("\\{-dict-}"), interppSP dictvars, ptext SLIT("->")])
 361          4 (ppr_expr expr)
 362
 363 ppr_expr (DictApp expr [dname])
 364   = hang (ppr_expr expr) 4 (ppr dname)
 365
 366 ppr_expr (DictApp expr dnames)
 367   = hang (ppr_expr expr)
 368          4 (brackets (interpp'SP dnames))
 369
 370 \end{code}
 371
 372 Parenthesize unless very simple:
 373 \begin{code}
 374 pprParendExpr :: (Outputable id, Outputable pat)
 375               => HsExpr id pat -> SDoc
 376
 377 pprParendExpr expr
 378   = let
 379         pp_as_was = pprExpr expr
 380     in
 381     case expr of
 382       HsLit l               -> ppr l
 383       HsLitOut l _          -> ppr l
 384
 385       HsVar _               -> pp_as_was
 386       HsIPVar _             -> pp_as_was
 387       ExplicitList _        -> pp_as_was
 388       ExplicitListOut _ _   -> pp_as_was
 389       ExplicitTuple _ _     -> pp_as_was
 390       HsPar _               -> pp_as_was
 391
 392       _                     -> parens pp_as_was
 393 \end{code}
 394
 395 %************************************************************************
 396 %*                                                                      *
 397 \subsection{Record binds}
 398 %*                                                                      *
 399 %************************************************************************
 400
 401 \begin{code}
 402 pp_rbinds :: (Outputable id, Outputable pat)
 403               => SDoc
 404               -> HsRecordBinds id pat -> SDoc
 405
 406 pp_rbinds thing rbinds
 407   = hang thing
 408          4 (braces (hsep (punctuate comma (map (pp_rbind) rbinds))))
 409   where
 410     pp_rbind (v, e, pun_flag)
 411       = getPprStyle $ \ sty ->
 412         if pun_flag && userStyle sty then
 413            ppr v
 414         else
 415            hsep [ppr v, char '=', ppr e]
 416 \end{code}
 417
 418 %************************************************************************
 419 %*                                                                      *
 420 \subsection{Do stmts and list comprehensions}
 421 %*                                                                      *
 422 %************************************************************************
 423
 424 \begin{code}
 425 data StmtCtxt   -- Context of a Stmt
 426   = DoStmt              -- Do Statment
 427   | ListComp            -- List comprehension
 428   | CaseAlt             -- Guard on a case alternative
 429   | PatBindRhs          -- Guard on a pattern binding
 430   | FunRhs Name         -- Guard on a function defn for f
 431   | LambdaBody          -- Body of a lambda abstraction
 432
 433 pprDo DoStmt stmts
 434   = hang (ptext SLIT("do")) 2 (vcat (map ppr stmts))
 435 pprDo ListComp stmts
 436   = brackets $
 437     hang (pprExpr expr <+> char '|')
 438        4 (interpp'SP quals)
 439   where
 440     ReturnStmt expr = last stmts        -- Last stmt should be a ReturnStmt for list comps
 441     quals           = init stmts
 442 \end{code}
 443
 444 \begin{code}
 445 data Stmt id pat
 446   = BindStmt    pat
 447                 (HsExpr id pat)
 448                 SrcLoc
 449
 450   | LetStmt     (HsBinds id pat)
 451
 452   | GuardStmt   (HsExpr id pat)         -- List comps only
 453                 SrcLoc
 454
 455   | ExprStmt    (HsExpr id pat)         -- Do stmts; and guarded things at the end
 456                 SrcLoc
 457
 458   | ReturnStmt  (HsExpr id pat)         -- List comps only, at the end
 459
 460 consLetStmt :: HsBinds id pat -> [Stmt id pat] -> [Stmt id pat]
 461 consLetStmt EmptyBinds stmts = stmts
 462 consLetStmt binds      stmts = LetStmt binds : stmts
 463 \end{code}
 464
 465 \begin{code}
 466 instance (Outputable id, Outputable pat) =>
 467                 Outputable (Stmt id pat) where
 468     ppr stmt = pprStmt stmt
 469
 470 pprStmt (BindStmt pat expr _)
 471  = hsep [ppr pat, ptext SLIT("<-"), ppr expr]
 472 pprStmt (LetStmt binds)
 473  = hsep [ptext SLIT("let"), pprBinds binds]
 474 pprStmt (ExprStmt expr _)
 475  = ppr expr
 476 pprStmt (GuardStmt expr _)
 477  = ppr expr
 478 pprStmt (ReturnStmt expr)
 479  = hsep [ptext SLIT("return"), ppr expr]
 480 \end{code}
 481
 482 %************************************************************************
 483 %*                                                                      *
 484 \subsection{Enumerations and list comprehensions}
 485 %*                                                                      *
 486 %************************************************************************
 487
 488 \begin{code}
 489 data ArithSeqInfo id pat
 490   = From            (HsExpr id pat)
 491   | FromThen        (HsExpr id pat)
 492                     (HsExpr id pat)
 493   | FromTo          (HsExpr id pat)
 494                     (HsExpr id pat)
 495   | FromThenTo      (HsExpr id pat)
 496                     (HsExpr id pat)
 497                     (HsExpr id pat)
 498 \end{code}
 499
 500 \begin{code}
 501 instance (Outputable id, Outputable pat) =>
 502                 Outputable (ArithSeqInfo id pat) where
 503     ppr (From e1)               = hcat [ppr e1, pp_dotdot]
 504     ppr (FromThen e1 e2)        = hcat [ppr e1, comma, space, ppr e2, pp_dotdot]
 505     ppr (FromTo e1 e3)  = hcat [ppr e1, pp_dotdot, ppr e3]
 506     ppr (FromThenTo e1 e2 e3)
 507       = hcat [ppr e1, comma, space, ppr e2, pp_dotdot, ppr e3]
 508
 509 pp_dotdot = ptext SLIT(" .. ")
 510 \end{code}