ghc/compiler/hsSyn/HsExpr.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1994
   3 %
   4 \section[HsExpr]{Abstract Haskell syntax: expressions}
   5
   6 \begin{code}
   7 #include "HsVersions.h"
   8
   9 module HsExpr where
  10
  11 IMP_Ubiq(){-uitous-}
  12 IMPORT_DELOOPER(HsLoop) -- for paranoia checking
  13
  14 -- friends:
  15 import HsBinds          ( HsBinds )
  16 import HsLit            ( HsLit )
  17 import HsMatches        ( pprMatches, pprMatch, Match )
  18 import HsTypes          ( HsType )
  19
  20 -- others:
  21 import Id               ( SYN_IE(DictVar), GenId, SYN_IE(Id) )
  22 import Name             ( pprNonSym, pprSym )
  23 import Outputable       ( interppSP, interpp'SP, ifnotPprForUser )
  24 import PprType          ( pprGenType, pprParendGenType, GenType{-instance-} )
  25 import Pretty
  26 import PprStyle         ( PprStyle(..) )
  27 import SrcLoc           ( SrcLoc )
  28 import Usage            ( GenUsage{-instance-} )
  29 --import Util           ( panic{-ToDo:rm eventually-} )
  30 \end{code}
  31
  32 %************************************************************************
  33 %*                                                                      *
  34 \subsection{Expressions proper}
  35 %*                                                                      *
  36 %************************************************************************
  37
  38 \begin{code}
  39 data HsExpr tyvar uvar id pat
  40   = HsVar       id                              -- variable
  41   | HsLit       HsLit                           -- literal
  42   | HsLitOut    HsLit                           -- TRANSLATION
  43                 (GenType tyvar uvar)            -- (with its type)
  44
  45   | HsLam       (Match  tyvar uvar id pat)      -- lambda
  46   | HsApp       (HsExpr tyvar uvar id pat)      -- application
  47                 (HsExpr tyvar uvar id pat)
  48
  49   -- Operator applications:
  50   -- NB Bracketed ops such as (+) come out as Vars.
  51
  52   -- NB We need an expr for the operator in an OpApp/Section since
  53   -- the typechecker may need to apply the operator to a few types.
  54
  55   | OpApp       (HsExpr tyvar uvar id pat)      -- left operand
  56                 (HsExpr tyvar uvar id pat)      -- operator
  57                 (HsExpr tyvar uvar id pat)      -- right operand
  58
  59   -- We preserve prefix negation and parenthesis for the precedence parser.
  60   -- They are eventually removed by the type checker.
  61
  62   | NegApp      (HsExpr tyvar uvar id pat)      -- negated expr
  63                 (HsExpr tyvar uvar id pat)      -- the negate id (in a HsVar)
  64
  65   | HsPar       (HsExpr tyvar uvar id pat)      -- parenthesised expr
  66
  67   | SectionL    (HsExpr tyvar uvar id pat)      -- operand
  68                 (HsExpr tyvar uvar id pat)      -- operator
  69   | SectionR    (HsExpr tyvar uvar id pat)      -- operator
  70                 (HsExpr tyvar uvar id pat)      -- operand
  71
  72   | HsCase      (HsExpr tyvar uvar id pat)
  73                 [Match  tyvar uvar id pat]      -- must have at least one Match
  74                 SrcLoc
  75
  76   | HsIf        (HsExpr tyvar uvar id pat)      --  predicate
  77                 (HsExpr tyvar uvar id pat)      --  then part
  78                 (HsExpr tyvar uvar id pat)      --  else part
  79                 SrcLoc
  80
  81   | HsLet       (HsBinds tyvar uvar id pat)     -- let(rec)
  82                 (HsExpr  tyvar uvar id pat)
  83
  84   | HsDo        [Stmt tyvar uvar id pat]        -- "do":one or more stmts
  85                 SrcLoc
  86
  87   | HsDoOut     [Stmt   tyvar uvar id pat]      -- "do":one or more stmts
  88                 id                              -- id for >>=,  types applied
  89                 id                              -- id for zero, typed applied
  90                 SrcLoc
  91
  92   | ListComp    (HsExpr    tyvar uvar id pat)   -- list comprehension
  93                 [Qualifier tyvar uvar id pat]   -- at least one Qualifier
  94
  95   | ExplicitList                -- syntactic list
  96                 [HsExpr tyvar uvar id pat]
  97   | ExplicitListOut             -- TRANSLATION
  98                 (GenType tyvar uvar)    -- Gives type of components of list
  99                 [HsExpr tyvar uvar id pat]
 100
 101   | ExplicitTuple               -- tuple
 102                 [HsExpr tyvar uvar id pat]
 103                                 -- NB: Unit is ExplicitTuple []
 104                                 -- for tuples, we can get the types
 105                                 -- direct from the components
 106
 107         -- Record construction
 108   | RecordCon   (HsExpr tyvar uvar id pat)      -- Always (HsVar id) until type checker,
 109                                                 -- but the latter adds its type args too
 110                 (HsRecordBinds tyvar uvar id pat)
 111
 112         -- Record update
 113   | RecordUpd   (HsExpr tyvar uvar id pat)
 114                 (HsRecordBinds tyvar uvar id pat)
 115
 116   | RecordUpdOut (HsExpr tyvar uvar id pat)     -- TRANSLATION
 117                  [id]                           -- Dicts needed for construction
 118                  (HsRecordBinds tyvar uvar id pat)
 119
 120   | ExprWithTySig               -- signature binding
 121                 (HsExpr tyvar uvar id pat)
 122                 (HsType id)
 123   | ArithSeqIn                  -- arithmetic sequence
 124                 (ArithSeqInfo tyvar uvar id pat)
 125   | ArithSeqOut
 126                 (HsExpr       tyvar uvar id pat) -- (typechecked, of course)
 127                 (ArithSeqInfo tyvar uvar id pat)
 128
 129   | CCall       FAST_STRING     -- call into the C world; string is
 130                 [HsExpr tyvar uvar id pat]      -- the C function; exprs are the
 131                                 -- arguments to pass.
 132                 Bool            -- True <=> might cause Haskell
 133                                 -- garbage-collection (must generate
 134                                 -- more paranoid code)
 135                 Bool            -- True <=> it's really a "casm"
 136                                 -- NOTE: this CCall is the *boxed*
 137                                 -- version; the desugarer will convert
 138                                 -- it into the unboxed "ccall#".
 139                 (GenType tyvar uvar)    -- The result type; will be *bottom*
 140                                 -- until the typechecker gets ahold of it
 141
 142   | HsSCC       FAST_STRING     -- "set cost centre" (_scc_) annotation
 143                 (HsExpr tyvar uvar id pat) -- expr whose cost is to be measured
 144 \end{code}
 145
 146 Everything from here on appears only in typechecker output.
 147
 148 \begin{code}
 149   | TyLam                       -- TRANSLATION
 150                 [tyvar]
 151                 (HsExpr tyvar uvar id pat)
 152   | TyApp                       -- TRANSLATION
 153                 (HsExpr  tyvar uvar id pat) -- generated by Spec
 154                 [GenType tyvar uvar]
 155
 156   -- DictLam and DictApp are "inverses"
 157   |  DictLam
 158                 [id]
 159                 (HsExpr tyvar uvar id pat)
 160   |  DictApp
 161                 (HsExpr tyvar uvar id pat)
 162                 [id]
 163
 164   -- ClassDictLam and Dictionary are "inverses" (see note below)
 165   |  ClassDictLam
 166                 [id]            -- superclass dicts
 167                 [id]            -- methods
 168                 (HsExpr tyvar uvar id pat)
 169   |  Dictionary
 170                 [id]            -- superclass dicts
 171                 [id]            -- methods
 172
 173   |  SingleDict                 -- a simple special case of Dictionary
 174                 id              -- local dictionary name
 175
 176 type HsRecordBinds tyvar uvar id pat
 177   = [(id, HsExpr tyvar uvar id pat, Bool)]
 178         -- True <=> source code used "punning",
 179         -- i.e. {op1, op2} rather than {op1=e1, op2=e2}
 180 \end{code}
 181
 182 A @Dictionary@, unless of length 0 or 1, becomes a tuple.  A
 183 @ClassDictLam dictvars methods expr@ is, therefore:
 184 \begin{verbatim}
 185 \ x -> case x of ( dictvars-and-methods-tuple ) -> expr
 186 \end{verbatim}
 187
 188 \begin{code}
 189 instance (NamedThing id, Outputable id, Outputable pat,
 190           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 191                 Outputable (HsExpr tyvar uvar id pat) where
 192     ppr = pprExpr
 193 \end{code}
 194
 195 \begin{code}
 196 pprExpr sty (HsVar v) = ppr sty v
 197
 198 pprExpr sty (HsLit    lit)   = ppr sty lit
 199 pprExpr sty (HsLitOut lit _) = ppr sty lit
 200
 201 pprExpr sty (HsLam match)
 202   = ppCat [ppStr "\\", ppNest 2 (pprMatch sty True match)]
 203
 204 pprExpr sty expr@(HsApp e1 e2)
 205   = let (fun, args) = collect_args expr [] in
 206     ppHang (pprExpr sty fun) 4 (ppSep (map (pprExpr sty) args))
 207   where
 208     collect_args (HsApp fun arg) args = collect_args fun (arg:args)
 209     collect_args fun             args = (fun, args)
 210
 211 pprExpr sty (OpApp e1 op e2)
 212   = case op of
 213       HsVar v -> pp_infixly v
 214       _       -> pp_prefixly
 215   where
 216     pp_e1 = pprExpr sty e1
 217     pp_e2 = pprExpr sty e2
 218
 219     pp_prefixly
 220       = ppHang (pprExpr sty op) 4 (ppSep [pp_e1, pp_e2])
 221
 222     pp_infixly v
 223       = ppSep [pp_e1, ppCat [ppr sty v, pp_e2]]
 224
 225 pprExpr sty (NegApp e _)
 226   = ppBeside (ppChar '-') (pprParendExpr sty e)
 227
 228 pprExpr sty (HsPar e)
 229   = ppParens (pprExpr sty e)
 230
 231 pprExpr sty (SectionL expr op)
 232   = case op of
 233       HsVar v -> pp_infixly v
 234       _       -> pp_prefixly
 235   where
 236     pp_expr = pprParendExpr sty expr
 237
 238     pp_prefixly = ppHang (ppCat [ppStr "( \\ x_ ->", ppr sty op])
 239                        4 (ppCat [pp_expr, ppStr "x_ )"])
 240     pp_infixly v
 241       = ppSep [ ppBeside ppLparen pp_expr,
 242                 ppBeside (ppr sty v) ppRparen ]
 243
 244 pprExpr sty (SectionR op expr)
 245   = case op of
 246       HsVar v -> pp_infixly v
 247       _       -> pp_prefixly
 248   where
 249     pp_expr = pprParendExpr sty expr
 250
 251     pp_prefixly = ppHang (ppCat [ppStr "( \\ x_ ->", ppr sty op, ppPStr SLIT("x_")])
 252                        4 (ppBeside pp_expr ppRparen)
 253     pp_infixly v
 254       = ppSep [ ppBeside ppLparen (ppr sty v),
 255                 ppBeside pp_expr  ppRparen ]
 256
 257 pprExpr sty (HsCase expr matches _)
 258   = ppSep [ ppSep [ppPStr SLIT("case"), ppNest 4 (pprExpr sty expr), ppPStr SLIT("of")],
 259             ppNest 2 (pprMatches sty (True, ppNil) matches) ]
 260
 261 pprExpr sty (HsIf e1 e2 e3 _)
 262   = ppSep [ppCat [ppPStr SLIT("if"), ppNest 2 (pprExpr sty e1), ppPStr SLIT("then")],
 263            ppNest 4 (pprExpr sty e2),
 264            ppPStr SLIT("else"),
 265            ppNest 4 (pprExpr sty e3)]
 266
 267 -- special case: let ... in let ...
 268 pprExpr sty (HsLet binds expr@(HsLet _ _))
 269   = ppSep [ppHang (ppPStr SLIT("let")) 2 (ppCat [ppr sty binds, ppPStr SLIT("in")]),
 270            ppr sty expr]
 271
 272 pprExpr sty (HsLet binds expr)
 273   = ppSep [ppHang (ppPStr SLIT("let")) 2 (ppr sty binds),
 274            ppHang (ppPStr SLIT("in"))  2 (ppr sty expr)]
 275
 276 pprExpr sty (HsDo stmts _)
 277   = ppHang (ppPStr SLIT("do")) 2 (ppAboves (map (ppr sty) stmts))
 278 pprExpr sty (HsDoOut stmts _ _ _)
 279   = ppHang (ppPStr SLIT("do")) 2 (ppAboves (map (ppr sty) stmts))
 280
 281 pprExpr sty (ListComp expr quals)
 282   = ppHang (ppCat [ppLbrack, pprExpr sty expr, ppChar '|'])
 283          4 (ppSep [interpp'SP sty quals, ppRbrack])
 284
 285 pprExpr sty (ExplicitList exprs)
 286   = ppBracket (ppInterleave ppComma (map (pprExpr sty) exprs))
 287 pprExpr sty (ExplicitListOut ty exprs)
 288   = ppBesides [ ppBracket (ppInterleave ppComma (map (pprExpr sty) exprs)),
 289                 ifnotPprForUser sty (ppBeside ppSP (ppParens (pprGenType sty ty))) ]
 290
 291 pprExpr sty (ExplicitTuple exprs)
 292   = ppParens (ppInterleave ppComma (map (pprExpr sty) exprs))
 293
 294 pprExpr sty (RecordCon con  rbinds)
 295   = pp_rbinds sty (ppr sty con) rbinds
 296
 297 pprExpr sty (RecordUpd aexp rbinds)
 298   = pp_rbinds sty (pprParendExpr sty aexp) rbinds
 299 pprExpr sty (RecordUpdOut aexp _ rbinds)
 300   = pp_rbinds sty (pprParendExpr sty aexp) rbinds
 301
 302 pprExpr sty (ExprWithTySig expr sig)
 303   = ppHang (ppBeside (ppNest 2 (pprExpr sty expr)) (ppPStr SLIT(" ::")))
 304          4 (ppr sty sig)
 305
 306 pprExpr sty (ArithSeqIn info)
 307   = ppBracket (ppr sty info)
 308 pprExpr sty (ArithSeqOut expr info)
 309   = case sty of
 310         PprForUser ->
 311           ppBracket (ppr sty info)
 312         _          ->
 313           ppBesides [ppLbrack, ppParens (ppr sty expr), ppr sty info, ppRbrack]
 314
 315 pprExpr sty (CCall fun args _ is_asm result_ty)
 316   = ppHang (if is_asm
 317             then ppBesides [ppStr "_casm_ ``", ppPStr fun, ppStr "''"]
 318             else ppBeside  (ppPStr SLIT("_ccall_ ")) (ppPStr fun))
 319          4 (ppSep (map (pprParendExpr sty) args))
 320
 321 pprExpr sty (HsSCC label expr)
 322   = ppSep [ ppBeside (ppPStr SLIT("_scc_ ")) (ppBesides [ppChar '"', ppPStr label, ppChar '"']),
 323             pprParendExpr sty expr ]
 324
 325 pprExpr sty (TyLam tyvars expr)
 326   = ppHang (ppCat [ppStr "/\\", interppSP sty tyvars, ppStr "->"])
 327          4 (pprExpr sty expr)
 328
 329 pprExpr sty (TyApp expr [ty])
 330   = ppHang (pprExpr sty expr) 4 (pprParendGenType sty ty)
 331
 332 pprExpr sty (TyApp expr tys)
 333   = ppHang (pprExpr sty expr)
 334          4 (ppBracket (interpp'SP sty tys))
 335
 336 pprExpr sty (DictLam dictvars expr)
 337   = ppHang (ppCat [ppStr "\\{-dict-}", interppSP sty dictvars, ppStr "->"])
 338          4 (pprExpr sty expr)
 339
 340 pprExpr sty (DictApp expr [dname])
 341   = ppHang (pprExpr sty expr) 4 (ppr sty dname)
 342
 343 pprExpr sty (DictApp expr dnames)
 344   = ppHang (pprExpr sty expr)
 345          4 (ppBracket (interpp'SP sty dnames))
 346
 347 pprExpr sty (ClassDictLam dicts methods expr)
 348   = ppHang (ppCat [ppStr "\\{-classdict-}",
 349                    ppBracket (interppSP sty dicts),
 350                    ppBracket (interppSP sty methods),
 351                    ppStr "->"])
 352          4 (pprExpr sty expr)
 353
 354 pprExpr sty (Dictionary dicts methods)
 355   = ppSep [ppBesides [ppLparen, ppPStr SLIT("{-dict-}")],
 356            ppBracket (interpp'SP sty dicts),
 357            ppBesides [ppBracket (interpp'SP sty methods), ppRparen]]
 358
 359 pprExpr sty (SingleDict dname)
 360   = ppCat [ppPStr SLIT("{-singleDict-}"), ppr sty dname]
 361
 362 \end{code}
 363
 364 Parenthesize unless very simple:
 365 \begin{code}
 366 pprParendExpr :: (NamedThing id, Outputable id, Outputable pat,
 367                   Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar)
 368               => PprStyle -> HsExpr tyvar uvar id pat -> Pretty
 369
 370 pprParendExpr sty expr
 371   = let
 372         pp_as_was = pprExpr sty expr
 373     in
 374     case expr of
 375       HsLit l               -> ppr sty l
 376       HsLitOut l _          -> ppr sty l
 377       HsVar _               -> pp_as_was
 378       ExplicitList _        -> pp_as_was
 379       ExplicitListOut _ _   -> pp_as_was
 380       ExplicitTuple _       -> pp_as_was
 381       _                     -> ppParens pp_as_was
 382 \end{code}
 383
 384 %************************************************************************
 385 %*                                                                      *
 386 \subsection{Record binds}
 387 %*                                                                      *
 388 %************************************************************************
 389
 390 \begin{code}
 391 pp_rbinds :: (NamedThing id, Outputable id, Outputable pat,
 392                   Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar)
 393               => PprStyle -> Pretty
 394               -> HsRecordBinds tyvar uvar id pat -> Pretty
 395
 396 pp_rbinds sty thing rbinds
 397   = ppHang thing
 398          4 (ppCurlies (ppIntersperse pp'SP (map (pp_rbind sty) rbinds)))
 399   where
 400     pp_rbind PprForUser (v, _, True) = ppr PprForUser v
 401     pp_rbind sty        (v, e, _)    = ppCat [ppr sty v, ppStr "=", ppr sty e]
 402 \end{code}
 403
 404 %************************************************************************
 405 %*                                                                      *
 406 \subsection{Do stmts}
 407 %*                                                                      *
 408 %************************************************************************
 409
 410 \begin{code}
 411 data Stmt tyvar uvar id pat
 412   = BindStmt    pat
 413                 (HsExpr  tyvar uvar id pat)
 414                 SrcLoc
 415   | ExprStmt    (HsExpr  tyvar uvar id pat)
 416                 SrcLoc
 417   | LetStmt     (HsBinds tyvar uvar id pat)
 418
 419         -- Translations; the types are the "a" and "b" types of the monad.
 420   | BindStmtOut pat (HsExpr tyvar uvar id pat) SrcLoc (GenType tyvar uvar) (GenType tyvar uvar)
 421   | ExprStmtOut (HsExpr tyvar uvar id pat)     SrcLoc (GenType tyvar uvar) (GenType tyvar uvar)
 422 \end{code}
 423
 424 \begin{code}
 425 instance (NamedThing id, Outputable id, Outputable pat,
 426           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 427                 Outputable (Stmt tyvar uvar id pat) where
 428     ppr sty (BindStmt pat expr _)
 429      = ppCat [ppr sty pat, ppStr "<-", ppr sty expr]
 430     ppr sty (LetStmt binds)
 431      = ppCat [ppPStr SLIT("let"), ppr sty binds]
 432     ppr sty (ExprStmt expr _)
 433      = ppr sty expr
 434     ppr sty (BindStmtOut pat expr _ _ _)
 435      = ppCat [ppr sty pat, ppStr "<-", ppr sty expr]
 436     ppr sty (ExprStmtOut expr _ _ _)
 437      = ppr sty expr
 438 \end{code}
 439
 440 %************************************************************************
 441 %*                                                                      *
 442 \subsection{Enumerations and list comprehensions}
 443 %*                                                                      *
 444 %************************************************************************
 445
 446 \begin{code}
 447 data ArithSeqInfo  tyvar uvar id pat
 448   = From            (HsExpr tyvar uvar id pat)
 449   | FromThen        (HsExpr tyvar uvar id pat)
 450                     (HsExpr tyvar uvar id pat)
 451   | FromTo          (HsExpr tyvar uvar id pat)
 452                     (HsExpr tyvar uvar id pat)
 453   | FromThenTo      (HsExpr tyvar uvar id pat)
 454                     (HsExpr tyvar uvar id pat)
 455                     (HsExpr tyvar uvar id pat)
 456 \end{code}
 457
 458 \begin{code}
 459 instance (NamedThing id, Outputable id, Outputable pat,
 460           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 461                 Outputable (ArithSeqInfo tyvar uvar id pat) where
 462     ppr sty (From e1)           = ppBesides [ppr sty e1, pp_dotdot]
 463     ppr sty (FromThen e1 e2)    = ppBesides [ppr sty e1, pp'SP, ppr sty e2, pp_dotdot]
 464     ppr sty (FromTo e1 e3)      = ppBesides [ppr sty e1, pp_dotdot, ppr sty e3]
 465     ppr sty (FromThenTo e1 e2 e3)
 466       = ppBesides [ppr sty e1, pp'SP, ppr sty e2, pp_dotdot, ppr sty e3]
 467
 468 pp_dotdot = ppPStr SLIT(" .. ")
 469 \end{code}
 470
 471 ``Qualifiers'' in list comprehensions:
 472 \begin{code}
 473 data Qualifier tyvar uvar id pat
 474   = GeneratorQual   pat
 475                     (HsExpr  tyvar uvar id pat)
 476   | LetQual         (HsBinds tyvar uvar id pat)
 477   | FilterQual      (HsExpr  tyvar uvar id pat)
 478 \end{code}
 479
 480 \begin{code}
 481 instance (NamedThing id, Outputable id, Outputable pat,
 482           Eq tyvar, Outputable tyvar, Eq uvar, Outputable uvar) =>
 483                 Outputable (Qualifier tyvar uvar id pat) where
 484     ppr sty (GeneratorQual pat expr)
 485      = ppCat [ppr sty pat, ppStr "<-", ppr sty expr]
 486     ppr sty (LetQual binds)
 487      = ppCat [ppPStr SLIT("let"), ppr sty binds]
 488     ppr sty (FilterQual expr)
 489      = ppr sty expr
 490 \end{code}