ghc/compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsTypes]{Abstract syntax: user-defined types}
   5
   6 \begin{code}
   7 module HsTypes (
   8           HsType(..), HsTyVarBndr(..), HsTyOp(..),
   9         , HsContext, HsPred(..)
  10         , HsTupCon(..), hsTupParens, mkHsTupCon,
  11         , hsUsOnce, hsUsMany
  12
  13         , mkHsForAllTy, mkHsDictTy, mkHsIParamTy
  14         , hsTyVarName, hsTyVarNames, replaceTyVarName
  15         , getHsInstHead
  16
  17         -- Type place holder
  18         , PostTcType, placeHolderType,
  19
  20         -- Name place holder
  21         , SyntaxName, placeHolderName,
  22
  23         -- Printing
  24         , pprParendHsType, pprHsForAll, pprHsContext, ppr_hs_context, pprHsTyVarBndr
  25
  26         -- Equality over Hs things
  27         , EqHsEnv, emptyEqHsEnv, extendEqHsEnv,
  28         , eqWithHsTyVars, eq_hsVar, eq_hsVars, eq_hsTyVars, eq_hsType, eq_hsContext, eqListBy
  29
  30         -- Converting from Type to HsType
  31         , toHsType, toHsTyVar, toHsTyVars, toHsContext, toHsFDs
  32     ) where
  33
  34 #include "HsVersions.h"
  35
  36 import Class            ( FunDep )
  37 import TcType           ( Type, Kind, ThetaType, SourceType(..),
  38                           tcSplitSigmaTy, liftedTypeKind, eqKind, tcEqType
  39                         )
  40 import TypeRep          ( Type(..), TyNote(..) )        -- toHsType sees the representation
  41 import TyCon            ( isTupleTyCon, tupleTyConBoxity, tyConArity, isNewTyCon, getSynTyConDefn )
  42 import RdrName          ( RdrName, mkUnqual )
  43 import Name             ( Name, getName, mkInternalName )
  44 import OccName          ( NameSpace, mkVarOcc, tvName )
  45 import Var              ( TyVar, tyVarKind )
  46 import Subst            ( substTyWith )
  47 import PprType          ( {- instance Outputable Kind -}, pprParendKind, pprKind )
  48 import BasicTypes       ( Boxity(..), Arity, IPName, tupleParens )
  49 import PrelNames        ( mkTupConRdrName, listTyConKey, parrTyConKey,
  50                           usOnceTyConKey, usManyTyConKey, hasKey, unboundKey,
  51                           usOnceTyConName, usManyTyConName )
  52 import SrcLoc           ( builtinSrcLoc )
  53 import Util             ( eqListBy, lengthIs )
  54 import FiniteMap
  55 import Outputable
  56 \end{code}
  57
  58
  59 %************************************************************************
  60 %*                                                                      *
  61 \subsection{Annotating the syntax}
  62 %*                                                                      *
  63 %************************************************************************
  64
  65 \begin{code}
  66 type PostTcType = Type          -- Used for slots in the abstract syntax
  67                                 -- where we want to keep slot for a type
  68                                 -- to be added by the type checker...but
  69                                 -- before typechecking it's just bogus
  70
  71 placeHolderType :: PostTcType   -- Used before typechecking
  72 placeHolderType  = panic "Evaluated the place holder for a PostTcType"
  73
  74
  75 type SyntaxName = Name          -- These names are filled in by the renamer
  76                                 -- Before then they are a placeHolderName (so that
  77                                 --      we can still print the HsSyn)
  78                                 -- They correspond to "rebindable syntax";
  79                                 -- See RnEnv.lookupSyntaxName
  80
  81 placeHolderName :: SyntaxName
  82 placeHolderName = mkInternalName unboundKey
  83                         (mkVarOcc FSLIT("syntaxPlaceHolder"))
  84                         builtinSrcLoc
  85 \end{code}
  86
  87
  88 %************************************************************************
  89 %*                                                                      *
  90 \subsection{Data types}
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 This is the syntax for types as seen in type signatures.
  95
  96 \begin{code}
  97 type HsContext name = [HsPred name]
  98
  99 data HsPred name = HsClassP name [HsType name]
 100                  | HsIParam (IPName name) (HsType name)
 101
 102 data HsType name
 103   = HsForAllTy  (Maybe [HsTyVarBndr name])      -- Nothing for implicitly quantified signatures
 104                 (HsContext name)
 105                 (HsType name)
 106
 107   | HsTyVar             name            -- Type variable or type constructor
 108
 109   | HsAppTy             (HsType name)
 110                         (HsType name)
 111
 112   | HsFunTy             (HsType name)   -- function type
 113                         (HsType name)
 114
 115   | HsListTy            (HsType name)   -- Element type
 116
 117   | HsPArrTy            (HsType name)   -- Elem. type of parallel array: [:t:]
 118
 119   | HsTupleTy           (HsTupCon name)
 120                         [HsType name]   -- Element types (length gives arity)
 121
 122   | HsOpTy              (HsType name) (HsTyOp name) (HsType name)
 123
 124   | HsParTy             (HsType name)   -- Parenthesis preserved for the
 125                                         -- precedence parser; are removed by
 126                                         -- the type checker
 127
 128   | HsNumTy             Integer         -- Generics only
 129
 130   -- these next two are only used in interfaces
 131   | HsPredTy            (HsPred name)
 132
 133   | HsKindSig           (HsType name)   -- (ty :: kind)
 134                         Kind            -- A type with a kind signature
 135
 136
 137 data HsTyOp name = HsArrow | HsTyOp name
 138         -- Function arrows from *source* get read in as HsOpTy t1 HsArrow t2
 139         -- But when we generate or parse interface files, we use HsFunTy.
 140         -- This keeps interfaces a bit smaller, because there are a lot of arrows
 141
 142 -----------------------
 143 hsUsOnce, hsUsMany :: HsType RdrName
 144 hsUsOnce = HsTyVar (mkUnqual tvName FSLIT("."))  -- deep magic
 145 hsUsMany = HsTyVar (mkUnqual tvName FSLIT("!"))  -- deep magic
 146
 147 hsUsOnce_Name, hsUsMany_Name :: HsType Name
 148 hsUsOnce_Name = HsTyVar usOnceTyConName
 149 hsUsMany_Name = HsTyVar usManyTyConName
 150
 151 -----------------------
 152 data HsTupCon name = HsTupCon name Boxity Arity
 153
 154 instance Eq name => Eq (HsTupCon name) where
 155   (HsTupCon _ b1 a1) == (HsTupCon _ b2 a2) = b1==b2 && a1==a2
 156
 157 mkHsTupCon :: NameSpace -> Boxity -> [a] -> HsTupCon RdrName
 158 mkHsTupCon space boxity args = HsTupCon (mkTupConRdrName space boxity arity) boxity arity
 159                              where
 160                                arity = length args
 161
 162 hsTupParens :: HsTupCon name -> SDoc -> SDoc
 163 hsTupParens (HsTupCon _ b _) p = tupleParens b p
 164
 165 -----------------------
 166 -- Combine adjacent for-alls.
 167 -- The following awkward situation can happen otherwise:
 168 --      f :: forall a. ((Num a) => Int)
 169 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 170 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 171 -- but the export list abstracts f wrt [a].  Disaster.
 172 --
 173 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 174
 175 mkHsForAllTy mtvs []   ty = mk_forall_ty mtvs ty
 176 mkHsForAllTy mtvs ctxt ty = HsForAllTy mtvs ctxt ty
 177
 178 -- mk_forall_ty makes a pure for-all type (no context)
 179 mk_forall_ty (Just []) ty                         = ty  -- Explicit for-all with no tyvars
 180 mk_forall_ty mtvs1     (HsParTy ty)               = mk_forall_ty mtvs1 ty
 181 mk_forall_ty mtvs1     (HsForAllTy mtvs2 ctxt ty) = mkHsForAllTy (mtvs1 `plus` mtvs2) ctxt ty
 182 mk_forall_ty mtvs1     ty                         = HsForAllTy mtvs1 [] ty
 183
 184 mtvs1       `plus` Nothing     = mtvs1
 185 Nothing     `plus` mtvs2       = mtvs2
 186 (Just tvs1) `plus` (Just tvs2) = Just (tvs1 ++ tvs2)
 187
 188 mkHsDictTy cls tys = HsPredTy (HsClassP cls tys)
 189 mkHsIParamTy v ty  = HsPredTy (HsIParam v ty)
 190
 191 data HsTyVarBndr name
 192   = UserTyVar name
 193   | IfaceTyVar name Kind
 194         -- *** NOTA BENE *** A "monotype" in a pragma can have
 195         -- for-alls in it, (mostly to do with dictionaries).  These
 196         -- must be explicitly Kinded.
 197
 198 hsTyVarName (UserTyVar n)    = n
 199 hsTyVarName (IfaceTyVar n _) = n
 200
 201 hsTyVarNames tvs = map hsTyVarName tvs
 202
 203 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 204 replaceTyVarName (UserTyVar n)    n' = UserTyVar n'
 205 replaceTyVarName (IfaceTyVar n k) n' = IfaceTyVar n' k
 206 \end{code}
 207
 208
 209 \begin{code}
 210 getHsInstHead :: HsType name -> ([HsTyVarBndr name], (name, [HsType name]))
 211         -- Split up an instance decl type, returning the 'head' part
 212
 213 -- In interface fiels, the type of the decl is held like this:
 214 --      forall a. Foo a -> Baz (T a)
 215 -- so we have to strip off function argument types,
 216 -- as well as the bit before the '=>' (which is always
 217 -- empty in interface files)
 218 --
 219 -- The parser ensures the type will have the right shape.
 220 -- (e.g. see ParseUtil.checkInstType)
 221
 222 getHsInstHead  (HsForAllTy (Just tvs) _ tau) = (tvs, get_head1 tau)
 223 getHsInstHead  tau                           = ([],  get_head1 tau)
 224
 225 get_head1 (HsFunTy _ ty)                = get_head1 ty
 226 get_head1 (HsPredTy (HsClassP cls tys)) = (cls,tys)
 227 \end{code}
 228
 229
 230 %************************************************************************
 231 %*                                                                      *
 232 \subsection{Pretty printing}
 233 %*                                                                      *
 234 %************************************************************************
 235
 236 NB: these types get printed into interface files, so
 237     don't change the printing format lightly
 238
 239 \begin{code}
 240 instance (Outputable name) => Outputable (HsType name) where
 241     ppr ty = pprHsType ty
 242
 243 instance (Outputable name) => Outputable (HsTyOp name) where
 244     ppr HsArrow    = ftext FSLIT("->")
 245     ppr (HsTyOp n) = ppr n
 246
 247 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 248     ppr (UserTyVar name)       = ppr name
 249     ppr (IfaceTyVar name kind) = pprHsTyVarBndr name kind
 250
 251 instance Outputable name => Outputable (HsPred name) where
 252     ppr (HsClassP clas tys) = ppr clas <+> hsep (map pprParendHsType tys)
 253     ppr (HsIParam n ty)    = hsep [ppr n, dcolon, ppr ty]
 254
 255 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 256 pprHsTyVarBndr name kind | kind `eqKind` liftedTypeKind = ppr name
 257                          | otherwise                    = hsep [ppr name, dcolon, pprParendKind kind]
 258
 259 pprHsForAll []  []  = empty
 260 pprHsForAll tvs cxt
 261         -- This printer is used for both interface files and
 262         -- printing user types in error messages; and alas the
 263         -- two use slightly different syntax.  Ah well.
 264   = getPprStyle $ \ sty ->
 265     if userStyle sty then
 266         ptext SLIT("forall") <+> interppSP tvs <> dot <+>
 267               -- **! ToDo: want to hide uvars from user, but not enough info
 268               -- in a HsTyVarBndr name (see PprType).  KSW 2000-10.
 269         pprHsContext cxt
 270     else        -- Used in interfaces
 271         ptext SLIT("__forall") <+> interppSP tvs <+>
 272         ppr_hs_context cxt <+> ptext SLIT("=>")
 273
 274 pprHsContext :: (Outputable name) => HsContext name -> SDoc
 275 pprHsContext []  = empty
 276 pprHsContext cxt = ppr_hs_context cxt <+> ptext SLIT("=>")
 277
 278 ppr_hs_context []  = empty
 279 ppr_hs_context cxt = parens (interpp'SP cxt)
 280 \end{code}
 281
 282 \begin{code}
 283 pREC_TOP = (0 :: Int)  -- type   in ParseIface.y
 284 pREC_FUN = (1 :: Int)  -- btype  in ParseIface.y
 285 pREC_CON = (2 :: Int)  -- atype  in ParseIface.y
 286
 287 maybeParen :: Bool -> SDoc -> SDoc
 288 maybeParen True  p = parens p
 289 maybeParen False p = p
 290
 291 -- printing works more-or-less as for Types
 292
 293 pprHsType, pprParendHsType :: (Outputable name) => HsType name -> SDoc
 294
 295 pprHsType ty       = ppr_mono_ty pREC_TOP ty
 296 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 297
 298 ppr_mono_ty ctxt_prec (HsForAllTy maybe_tvs ctxt ty)
 299   = maybeParen (ctxt_prec >= pREC_FUN) $
 300     sep [pp_header, pprHsType ty]
 301   where
 302     pp_header = case maybe_tvs of
 303                   Just tvs -> pprHsForAll tvs ctxt
 304                   Nothing  -> pprHsContext ctxt
 305
 306 ppr_mono_ty ctxt_prec (HsTyVar name)
 307   = ppr name
 308
 309 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)
 310   = let p1 = ppr_mono_ty pREC_FUN ty1
 311         p2 = ppr_mono_ty pREC_TOP ty2
 312     in
 313     maybeParen (ctxt_prec >= pREC_FUN)
 314                (sep [p1, ptext SLIT("->") <+> p2])
 315
 316 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = hsTupParens con (interpp'SP tys)
 317 ppr_mono_ty ctxt_prec (HsKindSig ty kind) = parens (ppr_mono_ty pREC_TOP ty <+> dcolon <+> pprKind kind)
 318 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_ty pREC_TOP ty)
 319 ppr_mono_ty ctxt_prec (HsPArrTy ty)       = pabrackets (ppr_mono_ty pREC_TOP ty)
 320   where
 321     pabrackets p = ptext SLIT("[:") <> p <> ptext SLIT(":]")
 322
 323 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty) =
 324   maybeParen (ctxt_prec >= pREC_CON)
 325              (hsep [ppr_mono_ty pREC_FUN fun_ty, ppr_mono_ty pREC_CON arg_ty])
 326
 327 ppr_mono_ty ctxt_prec (HsPredTy pred)
 328   = braces (ppr pred)
 329
 330 ppr_mono_ty ctxt_prec (HsOpTy ty1 op ty2) =
 331   maybeParen (ctxt_prec >= pREC_FUN)
 332              (ppr_mono_ty pREC_FUN ty1 <+> ppr op <+> ppr_mono_ty pREC_FUN ty2)
 333
 334 ppr_mono_ty ctxt_prec (HsParTy ty)        = ppr_mono_ty ctxt_prec ty
 335   -- `HsParTy' isn't useful for pretty printing, as it is removed by the type
 336   -- checker and we need to be able to pretty print after type checking
 337
 338 ppr_mono_ty ctxt_prec (HsNumTy n)         = integer n  -- generics only
 339 \end{code}
 340
 341
 342 %************************************************************************
 343 %*                                                                      *
 344 \subsection{Converting from Type to HsType}
 345 %*                                                                      *
 346 %************************************************************************
 347
 348 @toHsType@ converts from a Type to a HsType, making the latter look as
 349 user-friendly as possible.  Notably, it uses synonyms where possible, and
 350 expresses overloaded functions using the '=>' context part of a HsForAllTy.
 351
 352 \begin{code}
 353 toHsTyVar :: TyVar -> HsTyVarBndr Name
 354 toHsTyVar tv = IfaceTyVar (getName tv) (tyVarKind tv)
 355
 356 toHsTyVars tvs = map toHsTyVar tvs
 357
 358 toHsType :: Type -> HsType Name
 359 -- This function knows the representation of types
 360 toHsType (TyVarTy tv)    = HsTyVar (getName tv)
 361 toHsType (FunTy arg res) = HsFunTy (toHsType arg) (toHsType res)
 362 toHsType (AppTy fun arg) = HsAppTy (toHsType fun) (toHsType arg)
 363
 364 toHsType (NoteTy (SynNote ty@(TyConApp tycon tyargs)) real_ty)
 365   | isNewTyCon tycon = toHsType ty
 366   | syn_matches      = toHsType ty             -- Use synonyms if possible!!
 367   | otherwise        =
 368 #ifdef DEBUG
 369                        pprTrace "WARNING: synonym info lost in .hi file for " (ppr syn_ty) $
 370 #endif
 371                        toHsType real_ty              -- but drop it if not.
 372   where
 373     syn_matches      = ty_from_syn `tcEqType` real_ty
 374     (tyvars,syn_ty)  = getSynTyConDefn tycon
 375     ty_from_syn      = substTyWith tyvars tyargs syn_ty
 376
 377     -- We only use the type synonym in the file if this doesn't cause
 378     -- us to lose important information.  This matters for usage
 379     -- annotations.  It's an issue if some of the args to the synonym
 380     -- have arrows in them, or if the synonym's RHS has an arrow; for
 381     -- example, with nofib/real/ebnf2ps/ in Parsers.using.
 382
 383     -- **! It would be nice if when this test fails we could still
 384     -- write the synonym in as a Note, so we don't lose the info for
 385     -- error messages, but it's too much work for right now.
 386     -- KSW 2000-07.
 387
 388 toHsType (NoteTy _ ty)         = toHsType ty
 389
 390 toHsType (SourceTy (NType tc tys)) = foldl HsAppTy (HsTyVar (getName tc)) (map toHsType tys)
 391 toHsType (SourceTy pred)           = HsPredTy (toHsPred pred)
 392
 393 toHsType ty@(TyConApp tc tys)   -- Must be saturated because toHsType's arg is of kind *
 394   | not saturated              = generic_case
 395   | isTupleTyCon tc            = HsTupleTy (HsTupCon (getName tc) (tupleTyConBoxity tc) (tyConArity tc)) tys'
 396   | tc `hasKey` listTyConKey   = HsListTy (head tys')
 397   | tc `hasKey` parrTyConKey   = HsPArrTy (head tys')
 398   | tc `hasKey` usOnceTyConKey = hsUsOnce_Name           -- must print !, . unqualified
 399   | tc `hasKey` usManyTyConKey = hsUsMany_Name           -- must print !, . unqualified
 400   | otherwise                  = generic_case
 401   where
 402      generic_case = foldl HsAppTy (HsTyVar (getName tc)) tys'
 403      tys'         = map toHsType tys
 404      saturated    = tys `lengthIs` tyConArity tc
 405
 406 toHsType ty@(ForAllTy _ _) = case tcSplitSigmaTy ty of
 407                                 (tvs, preds, tau) -> HsForAllTy (Just (map toHsTyVar tvs))
 408                                                                 (map toHsPred preds)
 409                                                                 (toHsType tau)
 410
 411 toHsPred (ClassP cls tys) = HsClassP (getName cls) (map toHsType tys)
 412 toHsPred (IParam n ty)    = HsIParam n             (toHsType ty)
 413
 414 toHsContext :: ThetaType -> HsContext Name
 415 toHsContext theta = map toHsPred theta
 416
 417 toHsFDs :: [FunDep TyVar] -> [FunDep Name]
 418 toHsFDs fds = [(map getName ns, map getName ms) | (ns,ms) <- fds]
 419 \end{code}
 420
 421
 422 %************************************************************************
 423 %*                                                                      *
 424 \subsection{Comparison}
 425 %*                                                                      *
 426 %************************************************************************
 427
 428 \begin{code}
 429 instance Ord a => Eq (HsType a) where
 430         -- The Ord is needed because we keep a
 431         -- finite map of variables to variables
 432    (==) a b = eq_hsType emptyEqHsEnv a b
 433
 434 instance Ord a => Eq (HsPred a) where
 435    (==) a b = eq_hsPred emptyEqHsEnv a b
 436
 437 eqWithHsTyVars :: Ord name =>
 438                   [HsTyVarBndr name] -> [HsTyVarBndr name]
 439                -> (EqHsEnv name -> Bool) -> Bool
 440 eqWithHsTyVars = eq_hsTyVars emptyEqHsEnv
 441 \end{code}
 442
 443 \begin{code}
 444 type EqHsEnv n = FiniteMap n n
 445 -- Tracks the mapping from L-variables to R-variables
 446
 447 eq_hsVar :: Ord n => EqHsEnv n -> n -> n -> Bool
 448 eq_hsVar env n1 n2 = case lookupFM env n1 of
 449                       Just n1 -> n1 == n2
 450                       Nothing -> n1 == n2
 451
 452 extendEqHsEnv env n1 n2
 453   | n1 == n2  = env
 454   | otherwise = addToFM env n1 n2
 455
 456 emptyEqHsEnv :: EqHsEnv n
 457 emptyEqHsEnv = emptyFM
 458 \end{code}
 459
 460 We do define a specialised equality for these \tr{*Type} types; used
 461 in checking interfaces.
 462
 463 \begin{code}
 464 -------------------
 465 eq_hsTyVars env []          []         k = k env
 466 eq_hsTyVars env (tv1:tvs1) (tv2:tvs2)  k = eq_hsTyVar env tv1 tv2 $ \ env ->
 467                                            eq_hsTyVars env tvs1 tvs2 k
 468 eq_hsTyVars env _ _ _ = False
 469
 470 eq_hsTyVar env (UserTyVar v1)     (UserTyVar v2)     k = k (extendEqHsEnv env v1 v2)
 471 eq_hsTyVar env (IfaceTyVar v1 k1) (IfaceTyVar v2 k2) k = k1 `eqKind` k2 && k (extendEqHsEnv env v1 v2)
 472 eq_hsTyVar env _ _ _ = False
 473
 474 eq_hsVars env []       []       k = k env
 475 eq_hsVars env (v1:bs1) (v2:bs2) k = eq_hsVars (extendEqHsEnv env v1 v2) bs1 bs2 k
 476 eq_hsVars env _ _ _ = False
 477 \end{code}
 478
 479 \begin{code}
 480 -------------------
 481 eq_hsTypes env = eqListBy (eq_hsType env)
 482
 483 -------------------
 484 eq_hsType env (HsForAllTy tvs1 c1 t1) (HsForAllTy tvs2 c2 t2)
 485   = eq_tvs tvs1 tvs2            $ \env ->
 486     eq_hsContext env c1 c2      &&
 487     eq_hsType env t1 t2
 488   where
 489     eq_tvs Nothing     (Just _) k    = False
 490     eq_tvs Nothing     Nothing  k    = k env
 491     eq_tvs (Just _)    Nothing  k    = False
 492     eq_tvs (Just tvs1) (Just tvs2) k = eq_hsTyVars env tvs1 tvs2 k
 493
 494 eq_hsType env (HsTyVar n1) (HsTyVar n2)
 495   = eq_hsVar env n1 n2
 496
 497 eq_hsType env (HsTupleTy c1 tys1) (HsTupleTy c2 tys2)
 498   = (c1 == c2) && eq_hsTypes env tys1 tys2
 499
 500 eq_hsType env (HsListTy ty1) (HsListTy ty2)
 501   = eq_hsType env ty1 ty2
 502
 503 eq_hsType env (HsKindSig ty1 k1) (HsKindSig ty2 k2)
 504   = eq_hsType env ty1 ty2 && k1 `eqKind` k2
 505
 506 eq_hsType env (HsPArrTy ty1) (HsPArrTy ty2)
 507   = eq_hsType env ty1 ty2
 508
 509 eq_hsType env (HsAppTy fun_ty1 arg_ty1) (HsAppTy fun_ty2 arg_ty2)
 510   = eq_hsType env fun_ty1 fun_ty2 && eq_hsType env arg_ty1 arg_ty2
 511
 512 eq_hsType env (HsFunTy a1 b1) (HsFunTy a2 b2)
 513   = eq_hsType env a1 a2 && eq_hsType env b1 b2
 514
 515 eq_hsType env (HsPredTy p1) (HsPredTy p2)
 516   = eq_hsPred env p1 p2
 517
 518 eq_hsType env (HsOpTy lty1 op1 rty1) (HsOpTy lty2 op2 rty2)
 519   = eq_hsOp env op1 op2 && eq_hsType env lty1 lty2 && eq_hsType env rty1 rty2
 520
 521 eq_hsType env ty1 ty2 = False
 522
 523
 524 eq_hsOp env (HsTyOp n1) (HsTyOp n2) = eq_hsVar env n1 n2
 525 eq_hsOp env HsArrow     HsArrow     = True
 526 eq_hsOp env op1         op2         = False
 527
 528 -------------------
 529 eq_hsContext env a b = eqListBy (eq_hsPred env) a b
 530
 531 -------------------
 532 eq_hsPred env (HsClassP c1 tys1) (HsClassP c2 tys2)
 533   = c1 == c2 &&  eq_hsTypes env tys1 tys2
 534 eq_hsPred env (HsIParam n1 ty1) (HsIParam n2 ty2)
 535   = n1 == n2 && eq_hsType env ty1 ty2
 536 eq_hsPred env _ _ = False
 537 \end{code}