ghc/compiler/hsSyn/HsTypes.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[HsTypes]{Abstract syntax: user-defined types}
   5
   6 \begin{code}
   7 module HsTypes (
   8           HsType(..), HsUsageAnn(..), HsTyVarBndr(..),
   9         , HsContext, HsPred(..)
  10         , HsTupCon(..), hsTupParens, mkHsTupCon,
  11
  12         , mkHsForAllTy, mkHsUsForAllTy, mkHsDictTy, mkHsIParamTy
  13         , getTyVarName, replaceTyVarName
  14
  15         -- Printing
  16         , pprParendHsType, pprHsForAll, pprHsContext, pprHsTyVarBndr
  17
  18         -- Equality over Hs things
  19         , EqHsEnv, emptyEqHsEnv, extendEqHsEnv,
  20         , eqWithHsTyVars, eq_hsVar, eq_hsVars, eq_hsType, eq_hsContext, eqListBy
  21
  22         -- Converting from Type to HsType
  23         , toHsType, toHsTyVar, toHsTyVars, toHsContext, toHsFDs
  24     ) where
  25
  26 #include "HsVersions.h"
  27
  28 import Class            ( FunDep )
  29 import Type             ( Type, Kind, PredType(..), UsageAnn(..), ClassContext,
  30                           getTyVar_maybe, splitSigmaTy, unUsgTy, boxedTypeKind
  31                         )
  32 import TypeRep          ( Type(..), TyNote(..) )        -- toHsType sees the representation
  33 import TyCon            ( isTupleTyCon, tupleTyConBoxity, tyConArity, tyConClass_maybe )
  34 import PrelInfo         ( mkTupConRdrName )
  35 import RdrName          ( RdrName )
  36 import Name             ( toRdrName )
  37 import OccName          ( NameSpace )
  38 import Var              ( TyVar, tyVarKind )
  39 import PprType          ( {- instance Outputable Kind -}, pprParendKind )
  40 import BasicTypes       ( Arity, Boxity(..), tupleParens )
  41 import Unique           ( hasKey, listTyConKey, Uniquable(..) )
  42 import Maybes           ( maybeToBool )
  43 import FiniteMap
  44 import Outputable
  45 \end{code}
  46
  47 This is the syntax for types as seen in type signatures.
  48
  49 \begin{code}
  50 type HsContext name = [HsPred name]
  51
  52 data HsPred name = HsPClass name [HsType name]
  53                  | HsPIParam name (HsType name)
  54
  55 data HsType name
  56   = HsForAllTy  (Maybe [HsTyVarBndr name])      -- Nothing for implicitly quantified signatures
  57                 (HsContext name)
  58                 (HsType name)
  59
  60   | HsTyVar             name            -- Type variable
  61
  62   | HsAppTy             (HsType name)
  63                         (HsType name)
  64
  65   | HsFunTy             (HsType name) -- function type
  66                         (HsType name)
  67
  68   | HsListTy            (HsType name)   -- Element type
  69
  70   | HsTupleTy           (HsTupCon name)
  71                         [HsType name]   -- Element types (length gives arity)
  72
  73   -- these next two are only used in interfaces
  74   | HsPredTy            (HsPred name)
  75
  76   | HsUsgTy           (HsUsageAnn name)
  77                         (HsType name)
  78
  79   | HsUsgForAllTy     name
  80                         (HsType name)
  81
  82 data HsUsageAnn name
  83   = HsUsOnce
  84   | HsUsMany
  85   | HsUsVar name
  86
  87
  88 -----------------------
  89 data HsTupCon name = HsTupCon name Boxity
  90
  91 instance Eq name => Eq (HsTupCon name) where
  92   (HsTupCon _ b1) == (HsTupCon _ b2) = b1==b2
  93
  94 mkHsTupCon :: NameSpace -> Boxity -> [a] -> HsTupCon RdrName
  95 mkHsTupCon space boxity args = HsTupCon (mkTupConRdrName space boxity (length args)) boxity
  96
  97 hsTupParens :: HsTupCon name -> SDoc -> SDoc
  98 hsTupParens (HsTupCon _ b) p = tupleParens b p
  99
 100 -----------------------
 101 -- Combine adjacent for-alls.
 102 -- The following awkward situation can happen otherwise:
 103 --      f :: forall a. ((Num a) => Int)
 104 -- might generate HsForAll (Just [a]) [] (HsForAll Nothing [Num a] t)
 105 -- Then a isn't discovered as ambiguous, and we abstract the AbsBinds wrt []
 106 -- but the export list abstracts f wrt [a].  Disaster.
 107 --
 108 -- A valid type must have one for-all at the top of the type, or of the fn arg types
 109
 110 mkHsForAllTy (Just []) [] ty = ty       -- Explicit for-all with no tyvars
 111 mkHsForAllTy mtvs1     [] (HsForAllTy mtvs2 ctxt ty) = mkHsForAllTy (mtvs1 `plus` mtvs2) ctxt ty
 112                                                      where
 113                                                        mtvs1       `plus` Nothing     = mtvs1
 114                                                        Nothing     `plus` mtvs2       = mtvs2
 115                                                        (Just tvs1) `plus` (Just tvs2) = Just (tvs1 ++ tvs2)
 116 mkHsForAllTy tvs ctxt ty = HsForAllTy tvs ctxt ty
 117
 118 mkHsUsForAllTy uvs ty = foldr (\ uv ty -> HsUsgForAllTy uv ty)
 119                               ty uvs
 120
 121 mkHsDictTy cls tys = HsPredTy (HsPClass cls tys)
 122 mkHsIParamTy v ty  = HsPredTy (HsPIParam v ty)
 123
 124 data HsTyVarBndr name
 125   = UserTyVar name
 126   | IfaceTyVar name Kind
 127         -- *** NOTA BENE *** A "monotype" in a pragma can have
 128         -- for-alls in it, (mostly to do with dictionaries).  These
 129         -- must be explicitly Kinded.
 130
 131 getTyVarName (UserTyVar n)    = n
 132 getTyVarName (IfaceTyVar n _) = n
 133
 134 replaceTyVarName :: HsTyVarBndr name1 -> name2 -> HsTyVarBndr name2
 135 replaceTyVarName (UserTyVar n)    n' = UserTyVar n'
 136 replaceTyVarName (IfaceTyVar n k) n' = IfaceTyVar n' k
 137 \end{code}
 138
 139
 140 %************************************************************************
 141 %*                                                                      *
 142 \subsection{Pretty printing}
 143 %*                                                                      *
 144 %************************************************************************
 145
 146 NB: these types get printed into interface files, so
 147     don't change the printing format lightly
 148
 149 \begin{code}
 150 instance (Outputable name) => Outputable (HsType name) where
 151     ppr ty = pprHsType ty
 152
 153 instance (Outputable name) => Outputable (HsTyVarBndr name) where
 154     ppr (UserTyVar name)       = ppr name
 155     ppr (IfaceTyVar name kind) = pprHsTyVarBndr name kind
 156
 157 instance Outputable name => Outputable (HsPred name) where
 158     ppr (HsPClass clas tys) = ppr clas <+> hsep (map pprParendHsType tys)
 159     ppr (HsPIParam n ty)    = hsep [char '?' <> ppr n, text "::", ppr ty]
 160
 161 pprHsTyVarBndr :: Outputable name => name -> Kind -> SDoc
 162 pprHsTyVarBndr name kind | kind == boxedTypeKind = ppr name
 163                          | otherwise             = hsep [ppr name, dcolon, pprParendKind kind]
 164
 165 pprHsForAll []  []  = empty
 166 pprHsForAll tvs cxt
 167         -- This printer is used for both interface files and
 168         -- printing user types in error messages; and alas the
 169         -- two use slightly different syntax.  Ah well.
 170   = getPprStyle $ \ sty ->
 171     if userStyle sty then
 172         ptext SLIT("forall") <+> interppSP tvs <> dot <+>
 173         (if null cxt then
 174                 empty
 175          else
 176                 ppr_context cxt <+> ptext SLIT("=>")
 177         )
 178     else        -- Used in interfaces
 179         ptext SLIT("__forall") <+> interppSP tvs <+>
 180         ppr_context cxt <+> ptext SLIT("=>")
 181
 182 pprHsContext :: (Outputable name) => HsContext name -> SDoc
 183 pprHsContext []  = empty
 184 pprHsContext cxt = ppr_context cxt <+> ptext SLIT("=>")
 185
 186 ppr_context []  = empty
 187 ppr_context cxt = parens (interpp'SP cxt)
 188 \end{code}
 189
 190 \begin{code}
 191 pREC_TOP = (0 :: Int)
 192 pREC_FUN = (1 :: Int)
 193 pREC_CON = (2 :: Int)
 194
 195 maybeParen :: Bool -> SDoc -> SDoc
 196 maybeParen True  p = parens p
 197 maybeParen False p = p
 198
 199 -- printing works more-or-less as for Types
 200
 201 pprHsType, pprParendHsType :: (Outputable name) => HsType name -> SDoc
 202
 203 pprHsType ty       = ppr_mono_ty pREC_TOP ty
 204 pprParendHsType ty = ppr_mono_ty pREC_CON ty
 205
 206 ppr_mono_ty ctxt_prec (HsForAllTy maybe_tvs ctxt ty)
 207   = maybeParen (ctxt_prec >= pREC_FUN) $
 208     sep [pp_header, pprHsType ty]
 209   where
 210     pp_header = case maybe_tvs of
 211                   Just tvs -> pprHsForAll tvs ctxt
 212                   Nothing  -> pprHsContext ctxt
 213
 214 ppr_mono_ty ctxt_prec (HsTyVar name)
 215   = ppr name
 216
 217 ppr_mono_ty ctxt_prec (HsFunTy ty1 ty2)
 218   = let p1 = ppr_mono_ty pREC_FUN ty1
 219         p2 = ppr_mono_ty pREC_TOP ty2
 220     in
 221     maybeParen (ctxt_prec >= pREC_FUN)
 222                (sep [p1, (<>) (ptext SLIT("-> ")) p2])
 223
 224 ppr_mono_ty ctxt_prec (HsTupleTy con tys) = hsTupParens con (interpp'SP tys)
 225 ppr_mono_ty ctxt_prec (HsListTy ty)       = brackets (ppr_mono_ty pREC_TOP ty)
 226
 227 ppr_mono_ty ctxt_prec (HsAppTy fun_ty arg_ty)
 228   = maybeParen (ctxt_prec >= pREC_CON)
 229                (hsep [ppr_mono_ty pREC_FUN fun_ty, ppr_mono_ty pREC_CON arg_ty])
 230
 231 ppr_mono_ty ctxt_prec (HsPredTy pred)
 232   = maybeParen (ctxt_prec >= pREC_FUN) $
 233     braces (ppr pred)
 234
 235 ppr_mono_ty ctxt_prec ty@(HsUsgForAllTy _ _)
 236   =
 237     sep [ ptext SLIT("__fuall") <+> brackets pp_uvars <+> ptext SLIT("=>"),
 238           ppr_mono_ty pREC_TOP sigma
 239         ]
 240   where
 241     (uvars,sigma) = split [] ty
 242     pp_uvars      = interppSP uvars
 243
 244     split uvs (HsUsgForAllTy uv ty') = split (uv:uvs) ty'
 245     split uvs ty'                      = (reverse uvs,ty')
 246
 247 ppr_mono_ty ctxt_prec (HsUsgTy u ty)
 248   = maybeParen (ctxt_prec >= pREC_CON) $
 249     ptext SLIT("__u") <+> pp_ua <+> ppr_mono_ty pREC_CON ty
 250   where
 251     pp_ua = case u of
 252               HsUsOnce   -> ptext SLIT("-")
 253               HsUsMany   -> ptext SLIT("!")
 254               HsUsVar uv -> ppr uv
 255 \end{code}
 256
 257
 258 %************************************************************************
 259 %*                                                                      *
 260 \subsection{Converting from Type to HsType}
 261 %*                                                                      *
 262 %************************************************************************
 263
 264 @toHsType@ converts from a Type to a HsType, making the latter look as
 265 user-friendly as possible.  Notably, it uses synonyms where possible, and
 266 expresses overloaded functions using the '=>' context part of a HsForAllTy.
 267
 268 \begin{code}
 269 toHsTyVar :: TyVar -> HsTyVarBndr RdrName
 270 toHsTyVar tv = IfaceTyVar (toRdrName tv) (tyVarKind tv)
 271
 272 toHsTyVars tvs = map toHsTyVar tvs
 273
 274 toHsType :: Type -> HsType RdrName
 275 toHsType ty = toHsType' (unUsgTy ty)
 276         -- For now we just discard the usage
 277 --  = case splitUsgTy ty of
 278 --      (usg, tau) -> HsUsgTy (toHsUsg usg) (toHsType' tau)
 279
 280 toHsType' :: Type -> HsType RdrName
 281 -- Called after the usage is stripped off
 282 -- This function knows the representation of types
 283 toHsType' (TyVarTy tv)    = HsTyVar (toRdrName tv)
 284 toHsType' (FunTy arg res) = HsFunTy (toHsType arg) (toHsType res)
 285 toHsType' (AppTy fun arg) = HsAppTy (toHsType fun) (toHsType arg)
 286
 287 toHsType' (NoteTy (SynNote ty) _) = toHsType ty         -- Use synonyms if possible!!
 288 toHsType' (NoteTy _ ty)           = toHsType ty
 289
 290 toHsType' ty@(TyConApp tc tys)  -- Must be saturated because toHsType's arg is of kind *
 291   | not saturated            = generic_case
 292   | isTupleTyCon tc          = HsTupleTy (HsTupCon (toRdrName tc) (tupleTyConBoxity tc)) tys'
 293   | tc `hasKey` listTyConKey = HsListTy (head tys')
 294   | maybeToBool maybe_class  = HsPredTy (HsPClass (toRdrName clas) tys')
 295   | otherwise                = generic_case
 296   where
 297      generic_case = foldl HsAppTy (HsTyVar (toRdrName tc)) tys'
 298      maybe_class  = tyConClass_maybe tc
 299      Just clas    = maybe_class
 300      tys'         = map toHsType tys
 301      saturated    = length tys == tyConArity tc
 302
 303 toHsType' ty@(ForAllTy _ _) = case splitSigmaTy ty of
 304                                 (tvs, preds, tau) -> HsForAllTy (Just (map toHsTyVar tvs))
 305                                                                 (map toHsPred preds)
 306                                                                 (toHsType tau)
 307
 308
 309 toHsPred (Class cls tys) = HsPClass (toRdrName cls) (map toHsType tys)
 310 toHsPred (IParam n ty)   = HsPIParam (toRdrName n)  (toHsType ty)
 311
 312 toHsContext :: ClassContext -> HsContext RdrName
 313 toHsContext cxt = [HsPClass (toRdrName cls) (map toHsType tys) | (cls,tys) <- cxt]
 314
 315 toHsUsg UsOnce    = HsUsOnce
 316 toHsUsg UsMany    = HsUsMany
 317 toHsUsg (UsVar v) = HsUsVar (toRdrName v)
 318
 319 toHsFDs :: [FunDep TyVar] -> [FunDep RdrName]
 320 toHsFDs fds = [(map toRdrName ns, map toRdrName ms) | (ns,ms) <- fds]
 321 \end{code}
 322
 323
 324 %************************************************************************
 325 %*                                                                      *
 326 \subsection{Comparison}
 327 %*                                                                      *
 328 %************************************************************************
 329
 330 \begin{code}
 331 instance Ord a => Eq (HsType a) where
 332         -- The Ord is needed because we keep a
 333         -- finite map of variables to variables
 334    (==) a b = eq_hsType emptyEqHsEnv a b
 335
 336 instance Ord a => Eq (HsPred a) where
 337    (==) a b = eq_hsPred emptyEqHsEnv a b
 338
 339 eqWithHsTyVars :: Ord name =>
 340                   [HsTyVarBndr name] -> [HsTyVarBndr name]
 341                -> (EqHsEnv name -> Bool) -> Bool
 342 eqWithHsTyVars = eq_hsTyVars emptyEqHsEnv
 343 \end{code}
 344
 345 \begin{code}
 346 type EqHsEnv n = FiniteMap n n
 347 -- Tracks the mapping from L-variables to R-variables
 348
 349 eq_hsVar :: Ord n => EqHsEnv n -> n -> n -> Bool
 350 eq_hsVar env n1 n2 = case lookupFM env n1 of
 351                       Just n1 -> n1 == n2
 352                       Nothing -> n1 == n2
 353
 354 extendEqHsEnv env n1 n2
 355   | n1 == n2  = env
 356   | otherwise = addToFM env n1 n2
 357
 358 emptyEqHsEnv :: EqHsEnv n
 359 emptyEqHsEnv = emptyFM
 360 \end{code}
 361
 362 We do define a specialised equality for these \tr{*Type} types; used
 363 in checking interfaces.
 364
 365 \begin{code}
 366 -------------------
 367 eq_hsTyVars env []          []         k = k env
 368 eq_hsTyVars env (tv1:tvs1) (tv2:tvs2)  k = eq_hsTyVar env tv1 tv2 $ \ env ->
 369                                            eq_hsTyVars env tvs1 tvs2 k
 370 eq_hsTyVars env _ _ _ = False
 371
 372 eq_hsTyVar env (UserTyVar v1)     (UserTyVar v2)     k = k (extendEqHsEnv env v1 v2)
 373 eq_hsTyVar env (IfaceTyVar v1 k1) (IfaceTyVar v2 k2) k = k1 == k2 && k (extendEqHsEnv env v1 v2)
 374 eq_hsTyVar env _ _ _ = False
 375
 376 eq_hsVars env []       []       k = k env
 377 eq_hsVars env (v1:bs1) (v2:bs2) k = eq_hsVars (extendEqHsEnv env v1 v2) bs1 bs2 k
 378 eq_hsVars env _ _ _ = False
 379 \end{code}
 380
 381 \begin{code}
 382 -------------------
 383 eq_hsTypes env = eqListBy (eq_hsType env)
 384
 385 -------------------
 386 eq_hsType env (HsForAllTy tvs1 c1 t1) (HsForAllTy tvs2 c2 t2)
 387   = eq_tvs tvs1 tvs2            $ \env ->
 388     eq_hsContext env c1 c2      &&
 389     eq_hsType env t1 t2
 390   where
 391     eq_tvs Nothing     (Just _) k    = False
 392     eq_tvs Nothing     Nothing  k    = k env
 393     eq_tvs (Just _)    Nothing  k    = False
 394     eq_tvs (Just tvs1) (Just tvs2) k = eq_hsTyVars env tvs1 tvs2 k
 395
 396 eq_hsType env (HsTyVar n1) (HsTyVar n2)
 397   = eq_hsVar env n1 n2
 398
 399 eq_hsType env (HsTupleTy c1 tys1) (HsTupleTy c2 tys2)
 400   = (c1 == c2) && eq_hsTypes env tys1 tys2
 401
 402 eq_hsType env (HsListTy ty1) (HsListTy ty2)
 403   = eq_hsType env ty1 ty2
 404
 405 eq_hsType env (HsAppTy fun_ty1 arg_ty1) (HsAppTy fun_ty2 arg_ty2)
 406   = eq_hsType env fun_ty1 fun_ty2 && eq_hsType env arg_ty1 arg_ty2
 407
 408 eq_hsType env (HsFunTy a1 b1) (HsFunTy a2 b2)
 409   = eq_hsType env a1 a2 && eq_hsType env b1 b2
 410
 411 eq_hsType env (HsPredTy p1) (HsPredTy p2)
 412   = eq_hsPred env p1 p2
 413
 414 eq_hsType env (HsUsgTy u1 ty1) (HsUsgTy u2 ty2)
 415   = eqUsg u1 u2 && eq_hsType env ty1 ty2
 416
 417 eq_hsType env ty1 ty2 = False
 418
 419
 420 -------------------
 421 eq_hsContext env a b = eqListBy (eq_hsPred env) a b
 422
 423 -------------------
 424 eq_hsPred env (HsPClass c1 tys1) (HsPClass c2 tys2)
 425   = c1 == c2 &&  eq_hsTypes env tys1 tys2
 426 eq_hsPred env (HsPIParam n1 ty1) (HsPIParam n2 ty2)
 427   = n1 == n2 && eq_hsType env ty1 ty2
 428 eq_hsPred env _ _ = False
 429
 430 -------------------
 431 eqUsg  HsUsOnce     HsUsOnce    = True
 432 eqUsg  HsUsMany     HsUsMany    = True
 433 eqUsg (HsUsVar u1) (HsUsVar u2) = u1 == u2
 434 eqUsg _ _ = False
 435
 436 -------------------
 437 eqListBy :: (a->a->Bool) -> [a] -> [a] -> Bool
 438 eqListBy eq []     []     = True
 439 eqListBy eq (x:xs) (y:ys) = eq x y && eqListBy eq xs ys
 440 eqListBy eq xs     ys     = False
 441 \end{code}