ghc/compiler/iface/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5 \begin{code}
   6 module MkIface (
   7         showIface,      -- Print the iface in Foo.hi
   8
   9         mkUsageInfo,    -- Construct the usage info for a module
  10
  11         mkIface,        -- Build a ModIface from a ModGuts,
  12                         -- including computing version information
  13
  14         checkOldIface   -- See if recompilation is required, by
  15                         -- comparing version information
  16  ) where
  17 \end{code}
  18
  19         -----------------------------------------------
  20                 MkIface.lhs deals with versioning
  21         -----------------------------------------------
  22
  23 Here's the version-related info in an interface file
  24
  25   module Foo 8          -- module-version
  26              3          -- export-list-version
  27              2          -- rule-version
  28     Usages:     -- Version info for what this compilation of Foo imported
  29         Baz 3           -- Module version
  30             [4]         -- The export-list version if Foo depended on it
  31             (g,2)       -- Function and its version
  32             (T,1)       -- Type and its version
  33
  34     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  35                 -- The [2] says that f's unfolding
  36                 -- mentions verison 2 of Wib.t
  37
  38         -----------------------------------------------
  39                         Basic idea
  40         -----------------------------------------------
  41
  42 Basic idea:
  43   * In the mi_usages information in an interface, we record the
  44     version number of each free variable of the module
  45
  46   * In mkIface, we compute the version number of each exported thing A.f
  47     by comparing its A.f's info with its new info, and bumping its
  48     version number if it differs.  If A.f mentions B.g, and B.g's version
  49     number has changed, then we count A.f as having changed too.
  50
  51   * In checkOldIface we compare the mi_usages for the module with
  52     the actual version info for all each thing recorded in mi_usages
  53
  54
  55 Fixities
  56 ~~~~~~~~
  57 We count A.f as changing if its fixity changes
  58
  59 Rules
  60 ~~~~~
  61 If a rule changes, we want to recompile any module that might be
  62 affected by that rule.  For non-orphan rules, this is relatively easy.
  63 If module M defines f, and a rule for f, just arrange that the version
  64 number for M.f changes if any of the rules for M.f change.  Any module
  65 that does not depend on M.f can't be affected by the rule-change
  66 either.
  67
  68 Orphan rules (ones whose 'head function' is not defined in M) are
  69 harder.  Here's what we do.
  70
  71   * We have a per-module orphan-rule version number which changes if
  72     any orphan rule changes. (It's unaffected by non-orphan rules.)
  73
  74   * We record usage info for any orphan module 'below' this one,
  75     giving the orphan-rule version number.  We recompile if this
  76     changes.
  77
  78 The net effect is that if an orphan rule changes, we recompile every
  79 module above it.  That's very conservative, but it's devilishly hard
  80 to know what it might affect, so we just have to be conservative.
  81
  82 Instance decls
  83 ~~~~~~~~~~~~~~
  84 In an iface file we have
  85      module A where
  86         instance Eq a => Eq [a]  =  dfun29
  87         dfun29 :: ...
  88
  89 We have a version number for dfun29, covering its unfolding
  90 etc. Suppose we are compiling a module M that imports A only
  91 indirectly.  If typechecking M uses this instance decl, we record the
  92 dependency on A.dfun29 as if it were a free variable of the module
  93 (via the tcg_inst_usages accumulator).  That means that A will appear
  94 in M's usage list.  If the shape of the instance declaration changes,
  95 then so will dfun29's version, triggering a recompilation.
  96
  97 Adding an instance declaration, or changing an instance decl that is
  98 not currently used, is more tricky.  (This really only makes a
  99 difference when we have overlapping instance decls, because then the
 100 new instance decl might kick in to override the old one.)  We handle
 101 this in a very similar way that we handle rules above.
 102
 103   * For non-orphan instance decls, identify one locally-defined tycon/class
 104     mentioned in the decl.  Treat the instance decl as part of the defn of that
 105     tycon/class, so that if the shape of the instance decl changes, so does the
 106     tycon/class; that in turn will force recompilation of anything that uses
 107     that tycon/class.
 108
 109   * For orphan instance decls, act the same way as for orphan rules.
 110     Indeed, we use the same global orphan-rule version number.
 111
 112 mkUsageInfo
 113 ~~~~~~~~~~~
 114 mkUsageInfo figures out what the ``usage information'' for this
 115 moudule is; that is, what it must record in its interface file as the
 116 things it uses.
 117
 118 We produce a line for every module B below the module, A, currently being
 119 compiled:
 120         import B <n> ;
 121 to record the fact that A does import B indirectly.  This is used to decide
 122 to look to look for B.hi rather than B.hi-boot when compiling a module that
 123 imports A.  This line says that A imports B, but uses nothing in it.
 124 So we'll get an early bale-out when compiling A if B's version changes.
 125
 126 The usage information records:
 127
 128 \begin{itemize}
 129 \item   (a) anything reachable from its body code
 130 \item   (b) any module exported with a @module Foo@
 131 \item   (c) anything reachable from an exported item
 132 \end{itemize}
 133
 134 Why (b)?  Because if @Foo@ changes then this module's export list
 135 will change, so we must recompile this module at least as far as
 136 making a new interface file --- but in practice that means complete
 137 recompilation.
 138
 139 Why (c)?  Consider this:
 140 \begin{verbatim}
 141         module A( f, g ) where  |       module B( f ) where
 142           import B( f )         |         f = h 3
 143           g = ...               |         h = ...
 144 \end{verbatim}
 145
 146 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 147 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 148 *identical* to what it was before.  If anything about @B.f@ changes
 149 than anyone who imports @A@ should be recompiled in case they use
 150 @B.f@ (they'll get an early exit if they don't).  So, if anything
 151 about @B.f@ changes we'd better make sure that something in A.hi
 152 changes, and the convenient way to do that is to record the version
 153 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 154 complete recompiation of A, which is overkill but it's the only way to
 155 write a new, slightly different, A.hi.
 156
 157 But the example is tricker.  Even if @B.f@ doesn't change at all,
 158 @B.h@ may do so, and this change may not be reflected in @f@'s version
 159 number.  But with -O, a module that imports A must be recompiled if
 160 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 161 the occurrence of @B.f@ in the export list *just as if* it were in the
 162 code of A, and thereby haul in all the stuff reachable from it.
 163
 164         *** Conclusion: if A mentions B.f in its export list,
 165             behave just as if A mentioned B.f in its source code,
 166             and slurp in B.f and all its transitive closure ***
 167
 168 [NB: If B was compiled with -O, but A isn't, we should really *still*
 169 haul in all the unfoldings for B, in case the module that imports A *is*
 170 compiled with -O.  I think this is the case.]
 171
 172
 173 \begin{code}
 174 #include "HsVersions.h"
 175
 176 import HsSyn
 177 import Packages         ( isHomeModule )
 178 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 179                           IfaceRule(..), IfaceInst(..), IfaceExtName(..), IfaceTyCon(..),
 180                           eqIfDecl, eqIfRule, eqIfInst, IfaceEq(..), (&&&), bool,
 181                           eqMaybeBy, eqListBy, visibleIfConDecls,
 182                           tyThingToIfaceDecl, dfunToIfaceInst, coreRuleToIfaceRule )
 183 import LoadIface        ( readIface, loadInterface, ifaceInstGates )
 184 import BasicTypes       ( Version, initialVersion, bumpVersion )
 185 import TcRnMonad
 186 import TcRnTypes        ( mkModDeps )
 187 import TcType           ( isFFITy )
 188 import HscTypes         ( ModIface(..), TyThing(..), IfacePackage(..),
 189                           ModGuts(..), ModGuts, IfaceExport,
 190                           GhciMode(..), HscEnv(..), hscEPS,
 191                           Dependencies(..), FixItem(..),
 192                           mkIfaceDepCache, mkIfaceFixCache, mkIfaceVerCache,
 193                           typeEnvElts,
 194                           GenAvailInfo(..), availName,
 195                           ExternalPackageState(..),
 196                           Usage(..), IsBootInterface,
 197                           Deprecs(..), IfaceDeprecs, Deprecations,
 198                           lookupIfaceByModule
 199                         )
 200
 201
 202 import CmdLineOpts
 203 import Name             ( Name, nameModule, nameOccName, nameParent,
 204                           isExternalName, nameParent_maybe, isWiredInName,
 205                           NamedThing(..) )
 206 import NameEnv
 207 import NameSet
 208 import OccName          ( OccName, OccEnv, mkOccEnv, lookupOccEnv, emptyOccEnv,
 209                           extendOccEnv_C,
 210                           OccSet, emptyOccSet, elemOccSet, occSetElts,
 211                           extendOccSet, extendOccSetList,
 212                           isEmptyOccSet, intersectOccSet, intersectsOccSet,
 213                           occNameFS, isTcOcc )
 214 import TyCon            ( tyConDataCons, isNewTyCon, newTyConRep )
 215 import Class            ( classSelIds )
 216 import DataCon          ( dataConName, dataConFieldLabels )
 217 import Module           ( Module, moduleFS,
 218                           ModLocation(..), mkSysModuleFS, moduleUserString,
 219                           ModuleEnv, emptyModuleEnv, lookupModuleEnv,
 220                           extendModuleEnv_C
 221                         )
 222 import Outputable
 223 import DriverUtil       ( createDirectoryHierarchy, directoryOf )
 224 import Util             ( sortLe, seqList )
 225 import Binary           ( getBinFileWithDict )
 226 import BinIface         ( writeBinIface, v_IgnoreHiWay )
 227 import Unique           ( Unique, Uniquable(..) )
 228 import ErrUtils         ( dumpIfSet_dyn, showPass )
 229 import Digraph          ( stronglyConnComp, SCC(..) )
 230 import SrcLoc           ( SrcSpan )
 231 import FiniteMap
 232 import FastString
 233
 234 import DATA_IOREF       ( writeIORef )
 235 import Monad            ( when )
 236 import List             ( insert )
 237 import Maybes           ( orElse, mapCatMaybes, isNothing, isJust, fromJust, expectJust )
 238 \end{code}
 239
 240
 241
 242 %************************************************************************
 243 %*                                                                      *
 244 \subsection{Completing an interface}
 245 %*                                                                      *
 246 %************************************************************************
 247
 248 \begin{code}
 249 mkIface :: HscEnv
 250         -> ModLocation
 251         -> Maybe ModIface       -- The old interface, if we have it
 252         -> ModGuts              -- The compiled, tidied module
 253         -> IO ModIface          -- The new one, complete with decls and versions
 254 -- mkIface
 255 --      a) Builds the ModIface
 256 --      b) Writes it out to a file if necessary
 257
 258 mkIface hsc_env location maybe_old_iface
 259         guts@ModGuts{ mg_module = this_mod,
 260                       mg_usages = usages,
 261                       mg_deps   = deps,
 262                       mg_exports = exports,
 263                       mg_fix_env = fix_env,
 264                       mg_deprecs = src_deprecs,
 265                       mg_insts = insts,
 266                       mg_rules = rules,
 267                       mg_types = type_env }
 268   = do  { eps <- hscEPS hsc_env
 269         ; let   { ext_nm = mkExtNameFn hsc_env eps this_mod
 270                 ; local_things = [thing | thing <- typeEnvElts type_env,
 271                                           not (isWiredInName (getName thing)) ]
 272                         -- Do not export anything about wired-in things
 273                         --  (GHC knows about them already)
 274
 275                 ; abstract_tcs :: NameSet -- TyCons and Classes whose representation is not exposed
 276                 ; abstract_tcs
 277                     | not omit_prags = emptyNameSet             -- In the -O case, nothing is abstract
 278                     | otherwise      = mkNameSet [ getName thing
 279                                                  | thing <- local_things
 280                                                  , not (mustExposeThing exports thing)]
 281
 282                 ; decls  = [ tyThingToIfaceDecl omit_prags abstract_tcs ext_nm thing
 283                            | thing <- local_things, wantDeclFor exports abstract_tcs thing ]
 284                                 -- Don't put implicit Ids and class tycons in the interface file
 285
 286                 ; fixities = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 287                 ; deprecs  = mkIfaceDeprec src_deprecs
 288                 ; iface_rules
 289                      | omit_prags = []
 290                      | otherwise  = sortLe le_rule $
 291                                     map (coreRuleToIfaceRule this_mod ext_nm) rules
 292                 ; iface_insts = sortLe le_inst (map dfunToIfaceInst insts)
 293
 294                 ; intermediate_iface = ModIface {
 295                         mi_module   = this_mod,
 296                         mi_package  = ThisPackage,
 297                         mi_boot     = False,
 298                         mi_deps     = deps,
 299                         mi_usages   = usages,
 300                         mi_exports  = mkIfaceExports exports,
 301                         mi_insts    = iface_insts,
 302                         mi_rules    = iface_rules,
 303                         mi_fixities = fixities,
 304                         mi_deprecs  = deprecs,
 305
 306                         -- Left out deliberately: filled in by addVersionInfo
 307                         mi_mod_vers  = initialVersion,
 308                         mi_exp_vers  = initialVersion,
 309                         mi_rule_vers = initialVersion,
 310                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 311                                                 -- it's a strict field, so we can't omit it.
 312                         mi_decls     = deliberatelyOmitted "decls",
 313                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 314
 315                         -- And build the cached values
 316                         mi_dep_fn = mkIfaceDepCache deprecs,
 317                         mi_fix_fn = mkIfaceFixCache fixities }
 318
 319                 -- Add version information
 320                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs)
 321                         = _scc_ "versioninfo"
 322                          addVersionInfo maybe_old_iface intermediate_iface decls
 323                 }
 324
 325                 -- Write the interface file, if necessary
 326         ; when (not no_change_at_all && ghci_mode /= Interactive) $ do
 327                 createDirectoryHierarchy (directoryOf hi_file_path)
 328                 writeBinIface hi_file_path new_iface
 329
 330                 -- Debug printing
 331         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags)
 332                (printDump (fromJust pp_orphs))
 333         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 334         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 335                         (pprModIface new_iface)
 336
 337         ; return new_iface }
 338   where
 339      r1 `le_rule` r2 = ifRuleName r1 <= ifRuleName r2
 340      i1 `le_inst` i2 = ifDFun     i1 <= ifDFun     i2
 341
 342      dflags    = hsc_dflags hsc_env
 343      ghci_mode = hsc_mode hsc_env
 344      hi_file_path = ml_hi_file location
 345      omit_prags = dopt Opt_OmitInterfacePragmas dflags
 346
 347
 348 mustExposeThing :: NameSet -> TyThing -> Bool
 349 -- We are compiling without -O, and thus trying to write as little as
 350 -- possible into the interface file.  But we must expose the details of
 351 -- any data types and classes whose constructors, fields, methods are
 352 -- visible to an importing module
 353 mustExposeThing exports (ATyCon tc)
 354   =  any exported_data_con (tyConDataCons tc)
 355         -- Expose rep if any datacon or field is exported
 356
 357   || (isNewTyCon tc && isFFITy (snd (newTyConRep tc)))
 358         -- Expose the rep for newtypes if the rep is an FFI type.
 359         -- For a very annoying reason.  'Foreign import' is meant to
 360         -- be able to look through newtypes transparently, but it
 361         -- can only do that if it can "see" the newtype representation
 362   where
 363      exported_data_con con
 364         = any (`elemNameSet` exports) (dataConName con : dataConFieldLabels con)
 365
 366 mustExposeThing exports (AClass cls)
 367   = any exported_class_op (classSelIds cls)
 368   where         -- Expose rep if any classs op is exported
 369      exported_class_op op = getName op `elemNameSet` exports
 370
 371 mustExposeThing exports other = False
 372
 373
 374 wantDeclFor :: NameSet  -- User-exported things
 375             -> NameSet  -- Abstract things
 376             -> TyThing -> Bool
 377 wantDeclFor exports abstracts thing
 378   | Just parent <- nameParent_maybe name        -- An implicit thing
 379   = parent `elemNameSet` abstracts && name `elemNameSet` exports
 380   | otherwise
 381   = True
 382   where
 383     name = getName thing
 384
 385
 386 deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 387
 388 -----------------------------
 389 mkExtNameFn :: HscEnv -> ExternalPackageState -> Module -> Name -> IfaceExtName
 390 mkExtNameFn hsc_env eps this_mod
 391   = ext_nm
 392   where
 393     dflags = hsc_dflags hsc_env
 394     hpt = hsc_HPT hsc_env
 395     pit = eps_PIT eps
 396
 397     ext_nm name
 398       | mod == this_mod = case nameParent_maybe name of
 399                                 Nothing  -> LocalTop occ
 400                                 Just par -> LocalTopSub occ (nameOccName par)
 401       | isWiredInName name       = ExtPkg  mod occ
 402       | isHomeModule dflags mod  = HomePkg mod occ vers
 403       | otherwise                = ExtPkg  mod occ
 404       where
 405         mod      = nameModule name
 406         occ      = nameOccName name
 407         par_occ  = nameOccName (nameParent name)
 408                 -- The version of the *parent* is the one want
 409         vers     = lookupVersion mod par_occ
 410
 411     lookupVersion :: Module -> OccName -> Version
 412         -- Even though we're looking up a home-package thing, in
 413         -- one-shot mode the imported interfaces may be in the PIT
 414     lookupVersion mod occ
 415       = mi_ver_fn iface occ `orElse`
 416         pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 417       where
 418         iface = lookupIfaceByModule hpt pit mod `orElse`
 419                 pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 420
 421 -----------------------------
 422 -- Compute version numbers for local decls
 423
 424 addVersionInfo :: Maybe ModIface        -- The old interface, read from M.hi
 425                -> ModIface              -- The new interface decls (lacking decls)
 426                -> [IfaceDecl]           -- The new decls
 427                -> (ModIface,
 428                    Bool,                -- True <=> no changes at all; no need to write new Iface
 429                    SDoc,                -- Differences
 430                    Maybe SDoc)          -- Warnings about orphans
 431
 432 addVersionInfo Nothing new_iface new_decls
 433 -- No old interface, so definitely write a new one!
 434   = (new_iface { mi_orphan = anyNothing getInstKey (mi_insts new_iface)
 435                           || anyNothing getRuleKey (mi_rules new_iface),
 436                  mi_decls  = [(initialVersion, decl) | decl <- new_decls],
 437                  mi_ver_fn = \n -> Just initialVersion },
 438      False,
 439      ptext SLIT("No old interface file"),
 440      pprOrphans orph_insts orph_rules)
 441   where
 442     orph_insts = filter (isNothing . getInstKey) (mi_insts new_iface)
 443     orph_rules = filter (isNothing . getRuleKey) (mi_rules new_iface)
 444
 445 addVersionInfo (Just old_iface@(ModIface { mi_mod_vers  = old_mod_vers,
 446                                            mi_exp_vers  = old_exp_vers,
 447                                            mi_rule_vers = old_rule_vers,
 448                                            mi_decls     = old_decls,
 449                                            mi_ver_fn    = old_decl_vers,
 450                                            mi_fix_fn    = old_fixities }))
 451                new_iface@(ModIface { mi_fix_fn = new_fixities })
 452                new_decls
 453
 454   | no_change_at_all = (old_iface,   True,  ptext SLIT("Interface file unchanged"), pp_orphs)
 455   | otherwise        = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 456                                                   nest 2 pp_diffs], pp_orphs)
 457   where
 458     final_iface = new_iface { mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 459                               mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 460                               mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 461                               mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 462                               mi_decls     = decls_w_vers,
 463                               mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 464
 465     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 466
 467     -------------------
 468     (old_non_orph_insts, old_orph_insts) = mkRuleMap getInstKey (mi_insts old_iface)
 469     (new_non_orph_insts, new_orph_insts) = mkRuleMap getInstKey (mi_insts new_iface)
 470     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 471                                 (lookupOccEnv old_non_orph_insts occ)
 472                                 (lookupOccEnv new_non_orph_insts occ)
 473
 474     (old_non_orph_rules, old_orph_rules) = mkRuleMap getRuleKey (mi_rules old_iface)
 475     (new_non_orph_rules, new_orph_rules) = mkRuleMap getRuleKey (mi_rules new_iface)
 476     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 477                                 (lookupOccEnv old_non_orph_rules occ)
 478                                 (lookupOccEnv new_non_orph_rules occ)
 479     -------------------
 480     -- Computing what changed
 481     no_output_change = no_decl_change   && no_rule_change &&
 482                        no_export_change && no_deprec_change
 483     no_export_change = mi_exports new_iface == mi_exports old_iface     -- Kept sorted
 484     no_decl_change   = isEmptyOccSet changed_occs
 485     no_rule_change   = not (changedWrt changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 486                          || changedWrt changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts))
 487     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 488
 489         -- If the usages havn't changed either, we don't need to write the interface file
 490     no_other_changes = mi_usages new_iface == mi_usages old_iface &&
 491                        mi_deps new_iface == mi_deps old_iface
 492     no_change_at_all = no_output_change && no_other_changes
 493
 494     pp_diffs = vcat [pp_change no_export_change "Export list"
 495                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 496                      pp_change no_rule_change "Rules"
 497                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 498                      pp_change no_deprec_change "Deprecations" empty,
 499                      pp_change no_other_changes  "Usages" empty,
 500                      pp_decl_diffs]
 501     pp_change True  what info = empty
 502     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 503
 504     -------------------
 505     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 506     same_fixity n = bool (old_fixities n == new_fixities n)
 507
 508     -------------------
 509     -- Adding version info
 510     new_version     = bumpVersion old_mod_vers
 511     add_vers decl | occ `elemOccSet` changed_occs = new_version
 512                   | otherwise = expectJust "add_vers" (old_decl_vers occ)
 513                                 -- If it's unchanged, there jolly well
 514                   where         -- should be an old version number
 515                     occ = ifName decl
 516
 517     -------------------
 518     changed_occs :: OccSet
 519     changed_occs = computeChangedOccs eq_info
 520
 521     eq_info :: [(OccName, IfaceEq)]
 522     eq_info = map check_eq new_decls
 523     check_eq new_decl | Just old_decl <- lookupOccEnv old_decl_env occ
 524                       = (occ, new_decl `eqIfDecl` old_decl &&&
 525                               eq_indirects new_decl)
 526                       | otherwise {- No corresponding old decl -}
 527                       = (occ, NotEqual)
 528                       where
 529                         occ = ifName new_decl
 530
 531     eq_indirects :: IfaceDecl -> IfaceEq
 532                 -- When seeing if two decls are the same, remember to
 533                 -- check whether any relevant fixity or rules have changed
 534     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 535     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 536         = same_insts cls_occ &&&
 537           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 538     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 539         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 540           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
 541     eq_indirects other = Equal  -- Synonyms and foreign declarations
 542
 543     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 544     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 545     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 546
 547     -------------------
 548     -- Diffs
 549     pp_decl_diffs :: SDoc       -- Nothing => no changes
 550     pp_decl_diffs
 551         | isEmptyOccSet changed_occs = empty
 552         | otherwise
 553         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 554                 ptext SLIT("Version change for these decls:"),
 555                 nest 2 (vcat (map show_change new_decls))]
 556
 557     eq_env = mkOccEnv eq_info
 558     show_change new_decl
 559         | not (occ `elemOccSet` changed_occs) = empty
 560         | otherwise
 561         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 562                 nest 2 why]
 563         where
 564           occ = ifName new_decl
 565           why = case lookupOccEnv eq_env occ of
 566                     Just (EqBut occs) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:"),
 567                                               nest 2 (braces (fsep (map ppr (occSetElts
 568                                                 (occs `intersectOccSet` changed_occs)))))]
 569                     Just NotEqual
 570                         | Just old_decl <- lookupOccEnv old_decl_env occ
 571                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 572                          ptext SLIT("New:") <+> ppr new_decl]
 573                         | otherwise
 574                         -> ppr occ <+> ptext SLIT("only in new interface")
 575                     other -> pprPanic "MkIface.show_change" (ppr occ)
 576
 577     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 578
 579 pprOrphans insts rules
 580   | null insts && null rules = Nothing
 581   | otherwise
 582   = Just $ vcat [
 583         if null insts then empty else
 584              hang (ptext SLIT("Warning: orphan instances:"))
 585                 2 (vcat (map ppr insts)),
 586         if null rules then empty else
 587              hang (ptext SLIT("Warning: orphan rules:"))
 588                 2 (vcat (map ppr rules))
 589     ]
 590
 591 computeChangedOccs :: [(OccName, IfaceEq)] -> OccSet
 592 computeChangedOccs eq_info
 593   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 594   where
 595     edges :: [((OccName,IfaceEq), Unique, [Unique])]
 596     edges = [ (node, getUnique occ, map getUnique occs)
 597             | node@(occ, iface_eq) <- eq_info
 598             , let occs = case iface_eq of
 599                            EqBut occ_set -> occSetElts occ_set
 600                            other -> [] ]
 601
 602     -- Changes in declarations
 603     add_changes :: OccSet -> SCC (OccName, IfaceEq) -> OccSet
 604     add_changes so_far (AcyclicSCC (occ, iface_eq))
 605         | changedWrt so_far iface_eq                            -- This one has changed
 606         = extendOccSet so_far occ
 607     add_changes so_far (CyclicSCC pairs)
 608         | changedWrt so_far (foldr1 (&&&) (map snd pairs))      -- One of this group has changed
 609         = extendOccSetList so_far (map fst pairs)
 610     add_changes so_far other = so_far
 611
 612 changedWrt :: OccSet -> IfaceEq -> Bool
 613 changedWrt so_far Equal        = False
 614 changedWrt so_far NotEqual     = True
 615 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 616
 617 ----------------------
 618 -- mkRuleMap partitions instance decls or rules into
 619 --      (a) an OccEnv for ones that are not orphans,
 620 --          mapping the local OccName to a list of its decls
 621 --      (b) a list of orphan decls
 622 mkRuleMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 623                                         -- Nothing for an orphan decl
 624           -> [decl]                     -- Sorted into canonical order
 625           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 626                                         --      each sublist in canonical order
 627               [decl])                   -- Orphan decls; in canonical order
 628 mkRuleMap get_key decls
 629   = foldl go (emptyOccEnv, []) decls
 630   where
 631     go (non_orphs, orphs) d
 632         | Just occ <- get_key d
 633         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 634         | otherwise = (non_orphs, d:orphs)
 635
 636 -- getXxKey: find at least one local OccName that belongs to this decl
 637
 638 getInstKey :: IfaceInst -> Maybe OccName
 639 getInstKey (IfaceInst {ifInstHead = inst_ty})
 640   = case [occ | LocalTop occ <- cls_ext : tc_exts] of
 641         []      -> Nothing
 642         (occ:_) -> Just occ
 643   where
 644     (cls_ext, tcs) = ifaceInstGates inst_ty
 645     tc_exts = [tc | IfaceTc tc <- tcs]
 646         -- Ignore the wired-in IfaceTyCons; the class will do as the key
 647
 648 getRuleKey :: IfaceRule -> Maybe OccName
 649 getRuleKey (IfaceRule {ifRuleHead = LocalTop occ}) = Just occ
 650 getRuleKey other                                   = Nothing
 651
 652 anyNothing :: (a -> Maybe b) -> [a] -> Bool
 653 anyNothing p []     = False
 654 anyNothing p (x:xs) = isNothing (p x) || anyNothing p xs
 655
 656 ----------------------
 657 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 658 mkIfaceDeprec NoDeprecs        = NoDeprecs
 659 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 660 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
 661
 662 ----------------------
 663 bump_unless :: Bool -> Version -> Version
 664 bump_unless True  v = v -- True <=> no change
 665 bump_unless False v = bumpVersion v
 666 \end{code}
 667
 668
 669 %*********************************************************
 670 %*                                                      *
 671 \subsection{Keeping track of what we've slurped, and version numbers}
 672 %*                                                      *
 673 %*********************************************************
 674
 675
 676 \begin{code}
 677 mkUsageInfo :: HscEnv
 678             -> ModuleEnv (Module, Maybe Bool, SrcSpan)
 679             -> [(Module, IsBootInterface)]
 680             -> NameSet -> IO [Usage]
 681 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 682   = do  { eps <- hscEPS hsc_env
 683         ; let usages = mk_usage_info (eps_PIT eps) hsc_env
 684                                      dir_imp_mods dep_mods used_names
 685         ; usages `seqList`  return usages }
 686          -- seq the list of Usages returned: occasionally these
 687          -- don't get evaluated for a while and we can end up hanging on to
 688          -- the entire collection of Ifaces.
 689
 690 mk_usage_info pit hsc_env dir_imp_mods dep_mods proto_used_names
 691   = mapCatMaybes mkUsage dep_mods
 692         -- ToDo: do we need to sort into canonical order?
 693   where
 694     dflags = hsc_dflags hsc_env
 695     hpt = hsc_HPT hsc_env
 696
 697     used_names = mkNameSet $                    -- Eliminate duplicates
 698                  [ nameParent n                 -- Just record usage on the 'main' names
 699                  | n <- nameSetToList proto_used_names
 700                  , not (isWiredInName n)        -- Don't record usages for wired-in names
 701                  , isExternalName n             -- Ignore internal names
 702                  ]
 703
 704     -- ent_map groups together all the things imported and used
 705     -- from a particular module in this package
 706     ent_map :: ModuleEnv [OccName]
 707     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 708     add_mv name mv_map = extendModuleEnv_C add_item mv_map mod [occ]
 709                    where
 710                      occ = nameOccName name
 711                      mod = nameModule name
 712                      add_item occs _ = occ:occs
 713
 714     import_all mod = case lookupModuleEnv dir_imp_mods mod of
 715                         Just (_,imp_all,_) -> isNothing imp_all
 716                         Nothing            -> False
 717
 718     -- We want to create a Usage for a home module if
 719     --  a) we used something from; has something in used_names
 720     --  b) we imported all of it, even if we used nothing from it
 721     --          (need to recompile if its export list changes: export_vers)
 722     --  c) is a home-package orphan module (need to recompile if its
 723     --          instance decls change: rules_vers)
 724     mkUsage :: (Module, Bool) -> Maybe Usage
 725     mkUsage (mod_name, _)
 726       |  isNothing maybe_iface  -- We can't depend on it if we didn't
 727       || not (isHomeModule dflags mod)  -- even open the interface!
 728       || (null used_occs
 729           && not all_imported
 730           && not orphan_mod)
 731       = Nothing                 -- Record no usage info
 732
 733       | otherwise
 734       = Just (Usage { usg_name     = mod,
 735                       usg_mod      = mod_vers,
 736                       usg_exports  = export_vers,
 737                       usg_entities = ent_vers,
 738                       usg_rules    = rules_vers })
 739       where
 740         maybe_iface  = lookupIfaceByModule hpt pit mod_name
 741                 -- In one-shot mode, the interfaces for home-package
 742                 -- modules accumulate in the PIT not HPT.  Sigh.
 743
 744         Just iface   = maybe_iface
 745         mod          = mi_module    iface
 746         orphan_mod   = mi_orphan    iface
 747         version_env  = mi_ver_fn    iface
 748         mod_vers     = mi_mod_vers  iface
 749         rules_vers   = mi_rule_vers iface
 750         all_imported = import_all mod
 751         export_vers | all_imported = Just (mi_exp_vers iface)
 752                     | otherwise    = Nothing
 753
 754         -- The sort is to put them into canonical order
 755         used_occs = lookupModuleEnv ent_map mod `orElse` []
 756         ent_vers :: [(OccName,Version)]
 757         ent_vers = [ (occ, version_env occ `orElse` initialVersion)
 758                    | occ <- sortLe (<=) used_occs]
 759 \end{code}
 760
 761 \begin{code}
 762 mkIfaceExports :: NameSet -> [(Module, [GenAvailInfo OccName])]
 763   -- Group by module and sort by occurrence
 764   -- This keeps the list in canonical order
 765 mkIfaceExports exports
 766   = [ (mkSysModuleFS fs, eltsFM avails)
 767     | (fs, avails) <- fmToList groupFM
 768     ]
 769   where
 770     groupFM :: FiniteMap FastString (FiniteMap FastString (GenAvailInfo OccName))
 771         -- Deliberately use the FastString so we
 772         -- get a canonical ordering
 773     groupFM = foldl add emptyFM (nameSetToList exports)
 774
 775     add env name = addToFM_C add_avail env mod_fs
 776                              (unitFM avail_fs avail)
 777       where
 778         occ    = nameOccName name
 779         mod_fs = moduleFS (nameModule name)
 780         avail | Just p <- nameParent_maybe name = AvailTC (nameOccName p) [occ]
 781               | isTcOcc occ                     = AvailTC occ [occ]
 782               | otherwise                       = Avail occ
 783         avail_fs = occNameFS (availName avail)
 784         add_avail avail_fm _ = addToFM_C add_item avail_fm avail_fs avail
 785
 786         add_item (AvailTC p occs) _ = AvailTC p (List.insert occ occs)
 787         add_item (Avail n)        _ = pprPanic "MkIface.addAvail" (ppr n <+> ppr name)
 788 \end{code}
 789
 790
 791 %************************************************************************
 792 %*                                                                      *
 793         Load the old interface file for this module (unless
 794         we have it aleady), and check whether it is up to date
 795
 796 %*                                                                      *
 797 %************************************************************************
 798
 799 \begin{code}
 800 checkOldIface :: HscEnv
 801               -> Module
 802               -> FilePath               -- Where the interface file is
 803               -> Bool                   -- Source unchanged
 804               -> Maybe ModIface         -- Old interface from compilation manager, if any
 805               -> IO (RecompileRequired, Maybe ModIface)
 806
 807 checkOldIface hsc_env mod iface_path source_unchanged maybe_iface
 808   = do  { showPass (hsc_dflags hsc_env)
 809                    ("Checking old interface for " ++ moduleUserString mod) ;
 810
 811         ; initIfaceCheck hsc_env $
 812           check_old_iface mod iface_path source_unchanged maybe_iface
 813      }
 814
 815 check_old_iface this_mod iface_path source_unchanged maybe_iface
 816  =      -- CHECK WHETHER THE SOURCE HAS CHANGED
 817     ifM (not source_unchanged)
 818         (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 819                                                 `thenM_`
 820
 821      -- If the source has changed and we're in interactive mode, avoid reading
 822      -- an interface; just return the one we might have been supplied with.
 823     getGhciMode                                 `thenM` \ ghci_mode ->
 824     if (ghci_mode == Interactive) && not source_unchanged then
 825          returnM (outOfDate, maybe_iface)
 826     else
 827
 828     case maybe_iface of {
 829        Just old_iface -> -- Use the one we already have
 830                          checkVersions source_unchanged old_iface       `thenM` \ recomp ->
 831                          returnM (recomp, Just old_iface)
 832
 833     ;  Nothing ->
 834
 835         -- Try and read the old interface for the current module
 836         -- from the .hi file left from the last time we compiled it
 837     readIface this_mod iface_path False         `thenM` \ read_result ->
 838     case read_result of {
 839        Left err ->      -- Old interface file not found, or garbled; give up
 840                    traceIf (text "FYI: cannot read old interface file:"
 841                                  $$ nest 4 err)         `thenM_`
 842                    returnM (outOfDate, Nothing)
 843
 844     ;  Right iface ->
 845
 846         -- We have got the old iface; check its versions
 847     checkVersions source_unchanged iface        `thenM` \ recomp ->
 848     returnM (recomp, Just iface)
 849     }}
 850 \end{code}
 851
 852 @recompileRequired@ is called from the HscMain.   It checks whether
 853 a recompilation is required.  It needs access to the persistent state,
 854 finder, etc, because it may have to load lots of interface files to
 855 check their versions.
 856
 857 \begin{code}
 858 type RecompileRequired = Bool
 859 upToDate  = False       -- Recompile not required
 860 outOfDate = True        -- Recompile required
 861
 862 checkVersions :: Bool           -- True <=> source unchanged
 863               -> ModIface       -- Old interface
 864               -> IfG RecompileRequired
 865 checkVersions source_unchanged iface
 866   | not source_unchanged
 867   = returnM outOfDate
 868   | otherwise
 869   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+>
 870                         ppr (mi_module iface) <> colon)
 871
 872         -- Source code unchanged and no errors yet... carry on
 873
 874         -- First put the dependent-module info, read from the old interface, into the envt,
 875         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 876         --
 877         -- It's just temporary because either the usage check will succeed
 878         -- (in which case we are done with this module) or it'll fail (in which
 879         -- case we'll compile the module from scratch anyhow).
 880         --
 881         -- We do this regardless of compilation mode
 882         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
 883
 884         ; checkList [checkModUsage u | u <- mi_usages iface]
 885     }
 886   where
 887         -- This is a bit of a hack really
 888     mod_deps :: ModuleEnv (Module, IsBootInterface)
 889     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 890
 891 checkModUsage :: Usage -> IfG RecompileRequired
 892 -- Given the usage information extracted from the old
 893 -- M.hi file for the module being compiled, figure out
 894 -- whether M needs to be recompiled.
 895
 896 checkModUsage (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 897                        usg_rules = old_rule_vers,
 898                        usg_exports = maybe_old_export_vers,
 899                        usg_entities = old_decl_vers })
 900   =     -- Load the imported interface is possible
 901     let
 902         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 903     in
 904     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 905
 906     loadInterface doc_str mod_name ImportBySystem       `thenM` \ mb_iface ->
 907         -- Load the interface, but don't complain on failure;
 908         -- Instead, get an Either back which we can test
 909
 910     case mb_iface of {
 911         Left exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 912                                        ppr mod_name]));
 913                 -- Couldn't find or parse a module mentioned in the
 914                 -- old interface file.  Don't complain -- it might just be that
 915                 -- the current module doesn't need that import and it's been deleted
 916
 917         Right iface ->
 918     let
 919         new_mod_vers    = mi_mod_vers  iface
 920         new_decl_vers   = mi_ver_fn    iface
 921         new_export_vers = mi_exp_vers  iface
 922         new_rule_vers   = mi_rule_vers iface
 923     in
 924         -- CHECK MODULE
 925     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
 926     if not recompile then
 927         returnM upToDate
 928     else
 929
 930         -- CHECK EXPORT LIST
 931     if checkExportList maybe_old_export_vers new_export_vers then
 932         out_of_date_vers (ptext SLIT("  Export list changed"))
 933                          (fromJust maybe_old_export_vers)
 934                          new_export_vers
 935     else
 936
 937         -- CHECK RULES
 938     if old_rule_vers /= new_rule_vers then
 939         out_of_date_vers (ptext SLIT("  Rules changed"))
 940                          old_rule_vers new_rule_vers
 941     else
 942
 943         -- CHECK ITEMS ONE BY ONE
 944     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
 945     if recompile then
 946         returnM outOfDate       -- This one failed, so just bail out now
 947     else
 948         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
 949     }
 950
 951 ------------------------
 952 checkModuleVersion old_mod_vers new_mod_vers
 953   | new_mod_vers == old_mod_vers
 954   = up_to_date (ptext SLIT("Module version unchanged"))
 955
 956   | otherwise
 957   = out_of_date_vers (ptext SLIT("  Module version has changed"))
 958                      old_mod_vers new_mod_vers
 959
 960 ------------------------
 961 checkExportList Nothing  new_vers = upToDate
 962 checkExportList (Just v) new_vers = v /= new_vers
 963
 964 ------------------------
 965 checkEntityUsage new_vers (name,old_vers)
 966   = case new_vers name of
 967
 968         Nothing       ->        -- We used it before, but it ain't there now
 969                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 970
 971         Just new_vers   -- It's there, but is it up to date?
 972           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
 973                                     returnM upToDate
 974           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
 975                                                      old_vers new_vers
 976
 977 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
 978 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
 979 out_of_date_vers msg old_vers new_vers
 980   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
 981
 982 ----------------------
 983 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
 984 -- This helper is used in two places
 985 checkList []             = returnM upToDate
 986 checkList (check:checks) = check        `thenM` \ recompile ->
 987                            if recompile then
 988                                 returnM outOfDate
 989                            else
 990                                 checkList checks
 991 \end{code}
 992
 993 %************************************************************************
 994 %*                                                                      *
 995                 Printing interfaces
 996 %*                                                                      *
 997 %************************************************************************
 998
 999 \begin{code}
1000 showIface :: FilePath -> IO ()
1001 -- Raad binary interface, and print it out
1002 showIface filename = do
1003    -- skip the version check; we don't want to worry about profiled vs.
1004    -- non-profiled interfaces, for example.
1005    writeIORef v_IgnoreHiWay True
1006    iface <- Binary.getBinFileWithDict filename
1007    printDump (pprModIface iface)
1008  where
1009 \end{code}
1010
1011
1012 \begin{code}
1013 pprModIface :: ModIface -> SDoc
1014 -- Show a ModIface
1015 pprModIface iface
1016  = vcat [ ptext SLIT("interface")
1017                 <+> ppr_package (mi_package iface)
1018                 <+> ppr (mi_module iface) <+> ppr (mi_mod_vers iface)
1019                 <+> pp_sub_vers
1020                 <+> (if mi_orphan iface then ptext SLIT("[orphan module]") else empty)
1021                 <+> int opt_HiVersion
1022                 <+> ptext SLIT("where")
1023         , vcat (map pprExport (mi_exports iface))
1024         , pprDeps (mi_deps iface)
1025         , vcat (map pprUsage (mi_usages iface))
1026         , pprFixities (mi_fixities iface)
1027         , vcat (map pprIfaceDecl (mi_decls iface))
1028         , vcat (map ppr (mi_insts iface))
1029         , vcat (map ppr (mi_rules iface))
1030         , pprDeprecs (mi_deprecs iface)
1031         ]
1032   where
1033     ppr_package ThisPackage = empty
1034     ppr_package (ExternalPackage id) = doubleQuotes (ftext id)
1035
1036     exp_vers  = mi_exp_vers iface
1037     rule_vers = mi_rule_vers iface
1038
1039     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
1040                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
1041 \end{code}
1042
1043 When printing export lists, we print like this:
1044         Avail   f               f
1045         AvailTC C [C, x, y]     C(x,y)
1046         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
1047
1048 \begin{code}
1049 pprExport :: IfaceExport -> SDoc
1050 pprExport (mod, items)
1051  = hsep [ ptext SLIT("export"), ppr mod, hsep (map pp_avail items) ]
1052   where
1053     pp_avail :: GenAvailInfo OccName -> SDoc
1054     pp_avail (Avail occ)    = ppr occ
1055     pp_avail (AvailTC _ []) = empty
1056     pp_avail (AvailTC n (n':ns))
1057         | n==n'     = ppr n <> pp_export ns
1058         | otherwise = ppr n <> char '|' <> pp_export (n':ns)
1059
1060     pp_export []    = empty
1061     pp_export names = braces (hsep (map ppr names))
1062
1063 pprUsage :: Usage -> SDoc
1064 pprUsage usage
1065   = hsep [ptext SLIT("import"), ppr (usg_name usage),
1066           int (usg_mod usage),
1067           pp_export_version (usg_exports usage),
1068           int (usg_rules usage),
1069           pp_versions (usg_entities usage) ]
1070   where
1071     pp_versions nvs = hsep [ ppr n <+> int v | (n,v) <- nvs ]
1072     pp_export_version Nothing  = empty
1073     pp_export_version (Just v) = int v
1074
1075 pprDeps :: Dependencies -> SDoc
1076 pprDeps (Deps { dep_mods = mods, dep_pkgs = pkgs, dep_orphs = orphs})
1077   = vcat [ptext SLIT("module dependencies:") <+> fsep (map ppr_mod mods),
1078           ptext SLIT("package dependencies:") <+> fsep (map ppr pkgs),
1079           ptext SLIT("orphans:") <+> fsep (map ppr orphs)
1080         ]
1081   where
1082     ppr_mod (mod_name, boot) = ppr mod_name <+> ppr_boot boot
1083     ppr_boot True  = text "[boot]"
1084     ppr_boot False = empty
1085
1086 pprIfaceDecl :: (Version, IfaceDecl) -> SDoc
1087 pprIfaceDecl (ver, decl)
1088   = ppr_vers ver <+> ppr decl
1089   where
1090         -- Print the version for the decl
1091     ppr_vers v | v == initialVersion = empty
1092                | otherwise           = int v
1093
1094 pprFixities :: [(OccName, Fixity)] -> SDoc
1095 pprFixities []    = empty
1096 pprFixities fixes = ptext SLIT("fixities") <+> pprWithCommas pprFix fixes
1097                   where
1098                     pprFix (occ,fix) = ppr fix <+> ppr occ
1099
1100 pprDeprecs NoDeprecs        = empty
1101 pprDeprecs (DeprecAll txt)  = ptext SLIT("Deprecate all") <+> doubleQuotes (ftext txt)
1102 pprDeprecs (DeprecSome prs) = ptext SLIT("Deprecate") <+> vcat (map pprDeprec prs)
1103                             where
1104                               pprDeprec (name, txt) = ppr name <+> doubleQuotes (ftext txt)
1105 \end{code}