ghc/compiler/iface/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5 \begin{code}
   6 module MkIface (
   7         showIface,      -- Print the iface in Foo.hi
   8
   9         mkUsageInfo,    -- Construct the usage info for a module
  10
  11         mkIface,        -- Build a ModIface from a ModGuts,
  12                         -- including computing version information
  13
  14         checkOldIface   -- See if recompilation is required, by
  15                         -- comparing version information
  16  ) where
  17 \end{code}
  18
  19         -----------------------------------------------
  20                 MkIface.lhs deals with versioning
  21         -----------------------------------------------
  22
  23 Here's the version-related info in an interface file
  24
  25   module Foo 8          -- module-version
  26              3          -- export-list-version
  27              2          -- rule-version
  28     Usages:     -- Version info for what this compilation of Foo imported
  29         Baz 3           -- Module version
  30             [4]         -- The export-list version if Foo depended on it
  31             (g,2)       -- Function and its version
  32             (T,1)       -- Type and its version
  33
  34     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
  35                 -- The [2] says that f's unfolding
  36                 -- mentions verison 2 of Wib.t
  37
  38         -----------------------------------------------
  39                         Basic idea
  40         -----------------------------------------------
  41
  42 Basic idea:
  43   * In the mi_usages information in an interface, we record the
  44     version number of each free variable of the module
  45
  46   * In mkIface, we compute the version number of each exported thing A.f
  47     by comparing its A.f's info with its new info, and bumping its
  48     version number if it differs.  If A.f mentions B.g, and B.g's version
  49     number has changed, then we count A.f as having changed too.
  50
  51   * In checkOldIface we compare the mi_usages for the module with
  52     the actual version info for all each thing recorded in mi_usages
  53
  54
  55 Fixities
  56 ~~~~~~~~
  57 We count A.f as changing if its fixity changes
  58
  59 Rules
  60 ~~~~~
  61 If a rule changes, we want to recompile any module that might be
  62 affected by that rule.  For non-orphan rules, this is relatively easy.
  63 If module M defines f, and a rule for f, just arrange that the version
  64 number for M.f changes if any of the rules for M.f change.  Any module
  65 that does not depend on M.f can't be affected by the rule-change
  66 either.
  67
  68 Orphan rules (ones whose 'head function' is not defined in M) are
  69 harder.  Here's what we do.
  70
  71   * We have a per-module orphan-rule version number which changes if
  72     any orphan rule changes. (It's unaffected by non-orphan rules.)
  73
  74   * We record usage info for any orphan module 'below' this one,
  75     giving the orphan-rule version number.  We recompile if this
  76     changes.
  77
  78 The net effect is that if an orphan rule changes, we recompile every
  79 module above it.  That's very conservative, but it's devilishly hard
  80 to know what it might affect, so we just have to be conservative.
  81
  82 Instance decls
  83 ~~~~~~~~~~~~~~
  84 In an iface file we have
  85      module A where
  86         instance Eq a => Eq [a]  =  dfun29
  87         dfun29 :: ...
  88
  89 We have a version number for dfun29, covering its unfolding
  90 etc. Suppose we are compiling a module M that imports A only
  91 indirectly.  If typechecking M uses this instance decl, we record the
  92 dependency on A.dfun29 as if it were a free variable of the module
  93 (via the tcg_inst_usages accumulator).  That means that A will appear
  94 in M's usage list.  If the shape of the instance declaration changes,
  95 then so will dfun29's version, triggering a recompilation.
  96
  97 Adding an instance declaration, or changing an instance decl that is
  98 not currently used, is more tricky.  (This really only makes a
  99 difference when we have overlapping instance decls, because then the
 100 new instance decl might kick in to override the old one.)  We handle
 101 this in a very similar way that we handle rules above.
 102
 103   * For non-orphan instance decls, identify one locally-defined tycon/class
 104     mentioned in the decl.  Treat the instance decl as part of the defn of that
 105     tycon/class, so that if the shape of the instance decl changes, so does the
 106     tycon/class; that in turn will force recompilation of anything that uses
 107     that tycon/class.
 108
 109   * For orphan instance decls, act the same way as for orphan rules.
 110     Indeed, we use the same global orphan-rule version number.
 111
 112 mkUsageInfo
 113 ~~~~~~~~~~~
 114 mkUsageInfo figures out what the ``usage information'' for this
 115 moudule is; that is, what it must record in its interface file as the
 116 things it uses.
 117
 118 We produce a line for every module B below the module, A, currently being
 119 compiled:
 120         import B <n> ;
 121 to record the fact that A does import B indirectly.  This is used to decide
 122 to look to look for B.hi rather than B.hi-boot when compiling a module that
 123 imports A.  This line says that A imports B, but uses nothing in it.
 124 So we'll get an early bale-out when compiling A if B's version changes.
 125
 126 The usage information records:
 127
 128 \begin{itemize}
 129 \item   (a) anything reachable from its body code
 130 \item   (b) any module exported with a @module Foo@
 131 \item   (c) anything reachable from an exported item
 132 \end{itemize}
 133
 134 Why (b)?  Because if @Foo@ changes then this module's export list
 135 will change, so we must recompile this module at least as far as
 136 making a new interface file --- but in practice that means complete
 137 recompilation.
 138
 139 Why (c)?  Consider this:
 140 \begin{verbatim}
 141         module A( f, g ) where  |       module B( f ) where
 142           import B( f )         |         f = h 3
 143           g = ...               |         h = ...
 144 \end{verbatim}
 145
 146 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 147 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 148 *identical* to what it was before.  If anything about @B.f@ changes
 149 than anyone who imports @A@ should be recompiled in case they use
 150 @B.f@ (they'll get an early exit if they don't).  So, if anything
 151 about @B.f@ changes we'd better make sure that something in A.hi
 152 changes, and the convenient way to do that is to record the version
 153 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 154 complete recompiation of A, which is overkill but it's the only way to
 155 write a new, slightly different, A.hi.
 156
 157 But the example is tricker.  Even if @B.f@ doesn't change at all,
 158 @B.h@ may do so, and this change may not be reflected in @f@'s version
 159 number.  But with -O, a module that imports A must be recompiled if
 160 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 161 the occurrence of @B.f@ in the export list *just as if* it were in the
 162 code of A, and thereby haul in all the stuff reachable from it.
 163
 164         *** Conclusion: if A mentions B.f in its export list,
 165             behave just as if A mentioned B.f in its source code,
 166             and slurp in B.f and all its transitive closure ***
 167
 168 [NB: If B was compiled with -O, but A isn't, we should really *still*
 169 haul in all the unfoldings for B, in case the module that imports A *is*
 170 compiled with -O.  I think this is the case.]
 171
 172
 173 \begin{code}
 174 #include "HsVersions.h"
 175
 176 import HsSyn
 177 import Packages         ( isHomeModule, PackageIdH(..) )
 178 import IfaceSyn         ( IfaceDecl(..), IfaceClassOp(..), IfaceConDecl(..),
 179                           IfaceRule(..), IfaceInst(..), IfaceExtName(..), IfaceTyCon(..),
 180                           eqIfDecl, eqIfRule, eqIfInst, IfaceEq(..), (&&&), bool,
 181                           eqMaybeBy, eqListBy, visibleIfConDecls,
 182                           tyThingToIfaceDecl, dfunToIfaceInst, coreRuleToIfaceRule )
 183 import LoadIface        ( readIface, loadInterface, ifaceInstGates )
 184 import BasicTypes       ( Version, initialVersion, bumpVersion )
 185 import TcRnMonad
 186 import TcRnTypes        ( mkModDeps )
 187 import TcType           ( isFFITy )
 188 import HscTypes         ( ModIface(..), TyThing(..),
 189                           ModGuts(..), ModGuts, IfaceExport,
 190                           GhciMode(..), HscEnv(..), hscEPS,
 191                           Dependencies(..), FixItem(..),
 192                           mkIfaceDepCache, mkIfaceFixCache, mkIfaceVerCache,
 193                           typeEnvElts,
 194                           GenAvailInfo(..), availName,
 195                           ExternalPackageState(..),
 196                           Usage(..), IsBootInterface,
 197                           Deprecs(..), IfaceDeprecs, Deprecations,
 198                           lookupIfaceByModule
 199                         )
 200
 201
 202 import CmdLineOpts
 203 import Name             ( Name, nameModule, nameOccName, nameParent,
 204                           isExternalName, nameParent_maybe, isWiredInName,
 205                           NamedThing(..) )
 206 import NameEnv
 207 import NameSet
 208 import OccName          ( OccName, OccEnv, mkOccEnv, lookupOccEnv, emptyOccEnv,
 209                           extendOccEnv_C,
 210                           OccSet, emptyOccSet, elemOccSet, occSetElts,
 211                           extendOccSet, extendOccSetList,
 212                           isEmptyOccSet, intersectOccSet, intersectsOccSet,
 213                           occNameFS, isTcOcc )
 214 import TyCon            ( tyConDataCons, isNewTyCon, newTyConRep )
 215 import Class            ( classSelIds )
 216 import DataCon          ( dataConName, dataConFieldLabels )
 217 import Module           ( Module, moduleFS,
 218                           ModLocation(..), mkSysModuleFS, moduleUserString,
 219                           ModuleEnv, emptyModuleEnv, lookupModuleEnv,
 220                           extendModuleEnv_C
 221                         )
 222 import Outputable
 223 import DriverUtil       ( createDirectoryHierarchy, directoryOf )
 224 import Util             ( sortLe, seqList )
 225 import Binary           ( getBinFileWithDict )
 226 import BinIface         ( writeBinIface, v_IgnoreHiWay )
 227 import Unique           ( Unique, Uniquable(..) )
 228 import ErrUtils         ( dumpIfSet_dyn, showPass )
 229 import Digraph          ( stronglyConnComp, SCC(..) )
 230 import SrcLoc           ( SrcSpan )
 231 import FiniteMap
 232 import FastString
 233
 234 import DATA_IOREF       ( writeIORef )
 235 import Monad            ( when )
 236 import List             ( insert )
 237 import Maybes           ( orElse, mapCatMaybes, isNothing, isJust,
 238                           fromJust, expectJust, MaybeErr(..) )
 239 \end{code}
 240
 241
 242
 243 %************************************************************************
 244 %*                                                                      *
 245 \subsection{Completing an interface}
 246 %*                                                                      *
 247 %************************************************************************
 248
 249 \begin{code}
 250 mkIface :: HscEnv
 251         -> ModLocation
 252         -> Maybe ModIface       -- The old interface, if we have it
 253         -> ModGuts              -- The compiled, tidied module
 254         -> IO ModIface          -- The new one, complete with decls and versions
 255 -- mkIface
 256 --      a) Builds the ModIface
 257 --      b) Writes it out to a file if necessary
 258
 259 mkIface hsc_env location maybe_old_iface
 260         guts@ModGuts{ mg_module = this_mod,
 261                       mg_usages = usages,
 262                       mg_deps   = deps,
 263                       mg_exports = exports,
 264                       mg_fix_env = fix_env,
 265                       mg_deprecs = src_deprecs,
 266                       mg_insts = insts,
 267                       mg_rules = rules,
 268                       mg_types = type_env }
 269   = do  { eps <- hscEPS hsc_env
 270         ; let   { ext_nm = mkExtNameFn hsc_env eps this_mod
 271                 ; local_things = [thing | thing <- typeEnvElts type_env,
 272                                           not (isWiredInName (getName thing)) ]
 273                         -- Do not export anything about wired-in things
 274                         --  (GHC knows about them already)
 275
 276                 ; abstract_tcs :: NameSet -- TyCons and Classes whose representation is not exposed
 277                 ; abstract_tcs
 278                     | not omit_prags = emptyNameSet             -- In the -O case, nothing is abstract
 279                     | otherwise      = mkNameSet [ getName thing
 280                                                  | thing <- local_things
 281                                                  , not (mustExposeThing exports thing)]
 282
 283                 ; decls  = [ tyThingToIfaceDecl omit_prags abstract_tcs ext_nm thing
 284                            | thing <- local_things, wantDeclFor exports abstract_tcs thing ]
 285                                 -- Don't put implicit Ids and class tycons in the interface file
 286
 287                 ; fixities = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
 288                 ; deprecs  = mkIfaceDeprec src_deprecs
 289                 ; iface_rules
 290                      | omit_prags = []
 291                      | otherwise  = sortLe le_rule $
 292                                     map (coreRuleToIfaceRule this_mod ext_nm) rules
 293                 ; iface_insts = sortLe le_inst (map dfunToIfaceInst insts)
 294
 295                 ; intermediate_iface = ModIface {
 296                         mi_module   = this_mod,
 297                         mi_package  = HomePackage,
 298                         mi_boot     = False,
 299                         mi_deps     = deps,
 300                         mi_usages   = usages,
 301                         mi_exports  = mkIfaceExports exports,
 302                         mi_insts    = iface_insts,
 303                         mi_rules    = iface_rules,
 304                         mi_fixities = fixities,
 305                         mi_deprecs  = deprecs,
 306
 307                         -- Left out deliberately: filled in by addVersionInfo
 308                         mi_mod_vers  = initialVersion,
 309                         mi_exp_vers  = initialVersion,
 310                         mi_rule_vers = initialVersion,
 311                         mi_orphan    = False,   -- Always set by addVersionInfo, but
 312                                                 -- it's a strict field, so we can't omit it.
 313                         mi_decls     = deliberatelyOmitted "decls",
 314                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
 315
 316                         -- And build the cached values
 317                         mi_dep_fn = mkIfaceDepCache deprecs,
 318                         mi_fix_fn = mkIfaceFixCache fixities }
 319
 320                 -- Add version information
 321                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs)
 322                         = _scc_ "versioninfo"
 323                          addVersionInfo maybe_old_iface intermediate_iface decls
 324                 }
 325
 326                 -- Write the interface file, if necessary
 327         ; when (not no_change_at_all && ghci_mode /= Interactive) $ do
 328                 createDirectoryHierarchy (directoryOf hi_file_path)
 329                 writeBinIface hi_file_path new_iface
 330
 331                 -- Debug printing
 332         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags)
 333                (printDump (fromJust pp_orphs))
 334         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
 335         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE"
 336                         (pprModIface new_iface)
 337
 338         ; return new_iface }
 339   where
 340      r1 `le_rule` r2 = ifRuleName r1 <= ifRuleName r2
 341      i1 `le_inst` i2 = ifDFun     i1 <= ifDFun     i2
 342
 343      dflags    = hsc_dflags hsc_env
 344      ghci_mode = hsc_mode hsc_env
 345      hi_file_path = ml_hi_file location
 346      omit_prags = dopt Opt_OmitInterfacePragmas dflags
 347
 348
 349 mustExposeThing :: NameSet -> TyThing -> Bool
 350 -- We are compiling without -O, and thus trying to write as little as
 351 -- possible into the interface file.  But we must expose the details of
 352 -- any data types and classes whose constructors, fields, methods are
 353 -- visible to an importing module
 354 mustExposeThing exports (ATyCon tc)
 355   =  any exported_data_con (tyConDataCons tc)
 356         -- Expose rep if any datacon or field is exported
 357
 358   || (isNewTyCon tc && isFFITy (snd (newTyConRep tc)))
 359         -- Expose the rep for newtypes if the rep is an FFI type.
 360         -- For a very annoying reason.  'Foreign import' is meant to
 361         -- be able to look through newtypes transparently, but it
 362         -- can only do that if it can "see" the newtype representation
 363   where
 364      exported_data_con con
 365         = any (`elemNameSet` exports) (dataConName con : dataConFieldLabels con)
 366
 367 mustExposeThing exports (AClass cls)
 368   = any exported_class_op (classSelIds cls)
 369   where         -- Expose rep if any classs op is exported
 370      exported_class_op op = getName op `elemNameSet` exports
 371
 372 mustExposeThing exports other = False
 373
 374
 375 wantDeclFor :: NameSet  -- User-exported things
 376             -> NameSet  -- Abstract things
 377             -> TyThing -> Bool
 378 wantDeclFor exports abstracts thing
 379   | Just parent <- nameParent_maybe name        -- An implicit thing
 380   = parent `elemNameSet` abstracts && name `elemNameSet` exports
 381   | otherwise
 382   = True
 383   where
 384     name = getName thing
 385
 386
 387 deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
 388
 389 -----------------------------
 390 mkExtNameFn :: HscEnv -> ExternalPackageState -> Module -> Name -> IfaceExtName
 391 mkExtNameFn hsc_env eps this_mod
 392   = ext_nm
 393   where
 394     dflags = hsc_dflags hsc_env
 395     hpt = hsc_HPT hsc_env
 396     pit = eps_PIT eps
 397
 398     ext_nm name
 399       | mod == this_mod = case nameParent_maybe name of
 400                                 Nothing  -> LocalTop occ
 401                                 Just par -> LocalTopSub occ (nameOccName par)
 402       | isWiredInName name       = ExtPkg  mod occ
 403       | isHomeModule dflags mod  = HomePkg mod occ vers
 404       | otherwise                = ExtPkg  mod occ
 405       where
 406         mod      = nameModule name
 407         occ      = nameOccName name
 408         par_occ  = nameOccName (nameParent name)
 409                 -- The version of the *parent* is the one want
 410         vers     = lookupVersion mod par_occ
 411
 412     lookupVersion :: Module -> OccName -> Version
 413         -- Even though we're looking up a home-package thing, in
 414         -- one-shot mode the imported interfaces may be in the PIT
 415     lookupVersion mod occ
 416       = mi_ver_fn iface occ `orElse`
 417         pprPanic "lookupVers1" (ppr mod <+> ppr occ)
 418       where
 419         iface = lookupIfaceByModule hpt pit mod `orElse`
 420                 pprPanic "lookupVers2" (ppr mod <+> ppr occ)
 421
 422 -----------------------------
 423 -- Compute version numbers for local decls
 424
 425 addVersionInfo :: Maybe ModIface        -- The old interface, read from M.hi
 426                -> ModIface              -- The new interface decls (lacking decls)
 427                -> [IfaceDecl]           -- The new decls
 428                -> (ModIface,
 429                    Bool,                -- True <=> no changes at all; no need to write new Iface
 430                    SDoc,                -- Differences
 431                    Maybe SDoc)          -- Warnings about orphans
 432
 433 addVersionInfo Nothing new_iface new_decls
 434 -- No old interface, so definitely write a new one!
 435   = (new_iface { mi_orphan = anyNothing getInstKey (mi_insts new_iface)
 436                           || anyNothing getRuleKey (mi_rules new_iface),
 437                  mi_decls  = [(initialVersion, decl) | decl <- new_decls],
 438                  mi_ver_fn = \n -> Just initialVersion },
 439      False,
 440      ptext SLIT("No old interface file"),
 441      pprOrphans orph_insts orph_rules)
 442   where
 443     orph_insts = filter (isNothing . getInstKey) (mi_insts new_iface)
 444     orph_rules = filter (isNothing . getRuleKey) (mi_rules new_iface)
 445
 446 addVersionInfo (Just old_iface@(ModIface { mi_mod_vers  = old_mod_vers,
 447                                            mi_exp_vers  = old_exp_vers,
 448                                            mi_rule_vers = old_rule_vers,
 449                                            mi_decls     = old_decls,
 450                                            mi_ver_fn    = old_decl_vers,
 451                                            mi_fix_fn    = old_fixities }))
 452                new_iface@(ModIface { mi_fix_fn = new_fixities })
 453                new_decls
 454
 455   | no_change_at_all = (old_iface,   True,  ptext SLIT("Interface file unchanged"), pp_orphs)
 456   | otherwise        = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
 457                                                   nest 2 pp_diffs], pp_orphs)
 458   where
 459     final_iface = new_iface { mi_mod_vers  = bump_unless no_output_change old_mod_vers,
 460                               mi_exp_vers  = bump_unless no_export_change old_exp_vers,
 461                               mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
 462                               mi_orphan    = not (null new_orph_rules && null new_orph_insts),
 463                               mi_decls     = decls_w_vers,
 464                               mi_ver_fn    = mkIfaceVerCache decls_w_vers }
 465
 466     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
 467
 468     -------------------
 469     (old_non_orph_insts, old_orph_insts) = mkRuleMap getInstKey (mi_insts old_iface)
 470     (new_non_orph_insts, new_orph_insts) = mkRuleMap getInstKey (mi_insts new_iface)
 471     same_insts occ = eqMaybeBy  (eqListBy eqIfInst)
 472                                 (lookupOccEnv old_non_orph_insts occ)
 473                                 (lookupOccEnv new_non_orph_insts occ)
 474
 475     (old_non_orph_rules, old_orph_rules) = mkRuleMap getRuleKey (mi_rules old_iface)
 476     (new_non_orph_rules, new_orph_rules) = mkRuleMap getRuleKey (mi_rules new_iface)
 477     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
 478                                 (lookupOccEnv old_non_orph_rules occ)
 479                                 (lookupOccEnv new_non_orph_rules occ)
 480     -------------------
 481     -- Computing what changed
 482     no_output_change = no_decl_change   && no_rule_change &&
 483                        no_export_change && no_deprec_change
 484     no_export_change = mi_exports new_iface == mi_exports old_iface     -- Kept sorted
 485     no_decl_change   = isEmptyOccSet changed_occs
 486     no_rule_change   = not (changedWrt changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
 487                          || changedWrt changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts))
 488     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
 489
 490         -- If the usages havn't changed either, we don't need to write the interface file
 491     no_other_changes = mi_usages new_iface == mi_usages old_iface &&
 492                        mi_deps new_iface == mi_deps old_iface
 493     no_change_at_all = no_output_change && no_other_changes
 494
 495     pp_diffs = vcat [pp_change no_export_change "Export list"
 496                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
 497                      pp_change no_rule_change "Rules"
 498                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
 499                      pp_change no_deprec_change "Deprecations" empty,
 500                      pp_change no_other_changes  "Usages" empty,
 501                      pp_decl_diffs]
 502     pp_change True  what info = empty
 503     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
 504
 505     -------------------
 506     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
 507     same_fixity n = bool (old_fixities n == new_fixities n)
 508
 509     -------------------
 510     -- Adding version info
 511     new_version     = bumpVersion old_mod_vers
 512     add_vers decl | occ `elemOccSet` changed_occs = new_version
 513                   | otherwise = expectJust "add_vers" (old_decl_vers occ)
 514                                 -- If it's unchanged, there jolly well
 515                   where         -- should be an old version number
 516                     occ = ifName decl
 517
 518     -------------------
 519     changed_occs :: OccSet
 520     changed_occs = computeChangedOccs eq_info
 521
 522     eq_info :: [(OccName, IfaceEq)]
 523     eq_info = map check_eq new_decls
 524     check_eq new_decl | Just old_decl <- lookupOccEnv old_decl_env occ
 525                       = (occ, new_decl `eqIfDecl` old_decl &&&
 526                               eq_indirects new_decl)
 527                       | otherwise {- No corresponding old decl -}
 528                       = (occ, NotEqual)
 529                       where
 530                         occ = ifName new_decl
 531
 532     eq_indirects :: IfaceDecl -> IfaceEq
 533                 -- When seeing if two decls are the same, remember to
 534                 -- check whether any relevant fixity or rules have changed
 535     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
 536     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
 537         = same_insts cls_occ &&&
 538           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs]
 539     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
 540         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
 541           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
 542     eq_indirects other = Equal  -- Synonyms and foreign declarations
 543
 544     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
 545     eq_ind_occ occ = same_fixity occ &&& same_rules occ
 546     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal
 547
 548     -------------------
 549     -- Diffs
 550     pp_decl_diffs :: SDoc       -- Nothing => no changes
 551     pp_decl_diffs
 552         | isEmptyOccSet changed_occs = empty
 553         | otherwise
 554         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
 555                 ptext SLIT("Version change for these decls:"),
 556                 nest 2 (vcat (map show_change new_decls))]
 557
 558     eq_env = mkOccEnv eq_info
 559     show_change new_decl
 560         | not (occ `elemOccSet` changed_occs) = empty
 561         | otherwise
 562         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version,
 563                 nest 2 why]
 564         where
 565           occ = ifName new_decl
 566           why = case lookupOccEnv eq_env occ of
 567                     Just (EqBut occs) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:"),
 568                                               nest 2 (braces (fsep (map ppr (occSetElts
 569                                                 (occs `intersectOccSet` changed_occs)))))]
 570                     Just NotEqual
 571                         | Just old_decl <- lookupOccEnv old_decl_env occ
 572                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
 573                          ptext SLIT("New:") <+> ppr new_decl]
 574                         | otherwise
 575                         -> ppr occ <+> ptext SLIT("only in new interface")
 576                     other -> pprPanic "MkIface.show_change" (ppr occ)
 577
 578     pp_orphs = pprOrphans new_orph_insts new_orph_rules
 579
 580 pprOrphans insts rules
 581   | null insts && null rules = Nothing
 582   | otherwise
 583   = Just $ vcat [
 584         if null insts then empty else
 585              hang (ptext SLIT("Warning: orphan instances:"))
 586                 2 (vcat (map ppr insts)),
 587         if null rules then empty else
 588              hang (ptext SLIT("Warning: orphan rules:"))
 589                 2 (vcat (map ppr rules))
 590     ]
 591
 592 computeChangedOccs :: [(OccName, IfaceEq)] -> OccSet
 593 computeChangedOccs eq_info
 594   = foldl add_changes emptyOccSet (stronglyConnComp edges)
 595   where
 596     edges :: [((OccName,IfaceEq), Unique, [Unique])]
 597     edges = [ (node, getUnique occ, map getUnique occs)
 598             | node@(occ, iface_eq) <- eq_info
 599             , let occs = case iface_eq of
 600                            EqBut occ_set -> occSetElts occ_set
 601                            other -> [] ]
 602
 603     -- Changes in declarations
 604     add_changes :: OccSet -> SCC (OccName, IfaceEq) -> OccSet
 605     add_changes so_far (AcyclicSCC (occ, iface_eq))
 606         | changedWrt so_far iface_eq                            -- This one has changed
 607         = extendOccSet so_far occ
 608     add_changes so_far (CyclicSCC pairs)
 609         | changedWrt so_far (foldr1 (&&&) (map snd pairs))      -- One of this group has changed
 610         = extendOccSetList so_far (map fst pairs)
 611     add_changes so_far other = so_far
 612
 613 changedWrt :: OccSet -> IfaceEq -> Bool
 614 changedWrt so_far Equal        = False
 615 changedWrt so_far NotEqual     = True
 616 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
 617
 618 ----------------------
 619 -- mkRuleMap partitions instance decls or rules into
 620 --      (a) an OccEnv for ones that are not orphans,
 621 --          mapping the local OccName to a list of its decls
 622 --      (b) a list of orphan decls
 623 mkRuleMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
 624                                         -- Nothing for an orphan decl
 625           -> [decl]                     -- Sorted into canonical order
 626           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
 627                                         --      each sublist in canonical order
 628               [decl])                   -- Orphan decls; in canonical order
 629 mkRuleMap get_key decls
 630   = foldl go (emptyOccEnv, []) decls
 631   where
 632     go (non_orphs, orphs) d
 633         | Just occ <- get_key d
 634         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
 635         | otherwise = (non_orphs, d:orphs)
 636
 637 -- getXxKey: find at least one local OccName that belongs to this decl
 638
 639 getInstKey :: IfaceInst -> Maybe OccName
 640 getInstKey (IfaceInst {ifInstHead = inst_ty})
 641   = case [occ | LocalTop occ <- cls_ext : tc_exts] of
 642         []      -> Nothing
 643         (occ:_) -> Just occ
 644   where
 645     (cls_ext, tcs) = ifaceInstGates inst_ty
 646     tc_exts = [tc | IfaceTc tc <- tcs]
 647         -- Ignore the wired-in IfaceTyCons; the class will do as the key
 648
 649 getRuleKey :: IfaceRule -> Maybe OccName
 650 getRuleKey (IfaceRule {ifRuleHead = LocalTop occ}) = Just occ
 651 getRuleKey other                                   = Nothing
 652
 653 anyNothing :: (a -> Maybe b) -> [a] -> Bool
 654 anyNothing p []     = False
 655 anyNothing p (x:xs) = isNothing (p x) || anyNothing p xs
 656
 657 ----------------------
 658 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
 659 mkIfaceDeprec NoDeprecs        = NoDeprecs
 660 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
 661 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
 662
 663 ----------------------
 664 bump_unless :: Bool -> Version -> Version
 665 bump_unless True  v = v -- True <=> no change
 666 bump_unless False v = bumpVersion v
 667 \end{code}
 668
 669
 670 %*********************************************************
 671 %*                                                      *
 672 \subsection{Keeping track of what we've slurped, and version numbers}
 673 %*                                                      *
 674 %*********************************************************
 675
 676
 677 \begin{code}
 678 mkUsageInfo :: HscEnv
 679             -> ModuleEnv (Module, Maybe Bool, SrcSpan)
 680             -> [(Module, IsBootInterface)]
 681             -> NameSet -> IO [Usage]
 682 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
 683   = do  { eps <- hscEPS hsc_env
 684         ; let usages = mk_usage_info (eps_PIT eps) hsc_env
 685                                      dir_imp_mods dep_mods used_names
 686         ; usages `seqList`  return usages }
 687          -- seq the list of Usages returned: occasionally these
 688          -- don't get evaluated for a while and we can end up hanging on to
 689          -- the entire collection of Ifaces.
 690
 691 mk_usage_info pit hsc_env dir_imp_mods dep_mods proto_used_names
 692   = mapCatMaybes mkUsage dep_mods
 693         -- ToDo: do we need to sort into canonical order?
 694   where
 695     dflags = hsc_dflags hsc_env
 696     hpt = hsc_HPT hsc_env
 697
 698     used_names = mkNameSet $                    -- Eliminate duplicates
 699                  [ nameParent n                 -- Just record usage on the 'main' names
 700                  | n <- nameSetToList proto_used_names
 701                  , not (isWiredInName n)        -- Don't record usages for wired-in names
 702                  , isExternalName n             -- Ignore internal names
 703                  ]
 704
 705     -- ent_map groups together all the things imported and used
 706     -- from a particular module in this package
 707     ent_map :: ModuleEnv [OccName]
 708     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
 709     add_mv name mv_map = extendModuleEnv_C add_item mv_map mod [occ]
 710                    where
 711                      occ = nameOccName name
 712                      mod = nameModule name
 713                      add_item occs _ = occ:occs
 714
 715     import_all mod = case lookupModuleEnv dir_imp_mods mod of
 716                         Just (_,imp_all,_) -> isNothing imp_all
 717                         Nothing            -> False
 718
 719     -- We want to create a Usage for a home module if
 720     --  a) we used something from; has something in used_names
 721     --  b) we imported all of it, even if we used nothing from it
 722     --          (need to recompile if its export list changes: export_vers)
 723     --  c) is a home-package orphan module (need to recompile if its
 724     --          instance decls change: rules_vers)
 725     mkUsage :: (Module, Bool) -> Maybe Usage
 726     mkUsage (mod_name, _)
 727       |  isNothing maybe_iface  -- We can't depend on it if we didn't
 728       || not (isHomeModule dflags mod)  -- even open the interface!
 729       || (null used_occs
 730           && not all_imported
 731           && not orphan_mod)
 732       = Nothing                 -- Record no usage info
 733
 734       | otherwise
 735       = Just (Usage { usg_name     = mod,
 736                       usg_mod      = mod_vers,
 737                       usg_exports  = export_vers,
 738                       usg_entities = ent_vers,
 739                       usg_rules    = rules_vers })
 740       where
 741         maybe_iface  = lookupIfaceByModule hpt pit mod_name
 742                 -- In one-shot mode, the interfaces for home-package
 743                 -- modules accumulate in the PIT not HPT.  Sigh.
 744
 745         Just iface   = maybe_iface
 746         mod          = mi_module    iface
 747         orphan_mod   = mi_orphan    iface
 748         version_env  = mi_ver_fn    iface
 749         mod_vers     = mi_mod_vers  iface
 750         rules_vers   = mi_rule_vers iface
 751         all_imported = import_all mod
 752         export_vers | all_imported = Just (mi_exp_vers iface)
 753                     | otherwise    = Nothing
 754
 755         -- The sort is to put them into canonical order
 756         used_occs = lookupModuleEnv ent_map mod `orElse` []
 757         ent_vers :: [(OccName,Version)]
 758         ent_vers = [ (occ, version_env occ `orElse` initialVersion)
 759                    | occ <- sortLe (<=) used_occs]
 760 \end{code}
 761
 762 \begin{code}
 763 mkIfaceExports :: NameSet -> [(Module, [GenAvailInfo OccName])]
 764   -- Group by module and sort by occurrence
 765   -- This keeps the list in canonical order
 766 mkIfaceExports exports
 767   = [ (mkSysModuleFS fs, eltsFM avails)
 768     | (fs, avails) <- fmToList groupFM
 769     ]
 770   where
 771     groupFM :: FiniteMap FastString (FiniteMap FastString (GenAvailInfo OccName))
 772         -- Deliberately use the FastString so we
 773         -- get a canonical ordering
 774     groupFM = foldl add emptyFM (nameSetToList exports)
 775
 776     add env name = addToFM_C add_avail env mod_fs
 777                              (unitFM avail_fs avail)
 778       where
 779         occ    = nameOccName name
 780         mod_fs = moduleFS (nameModule name)
 781         avail | Just p <- nameParent_maybe name = AvailTC (nameOccName p) [occ]
 782               | isTcOcc occ                     = AvailTC occ [occ]
 783               | otherwise                       = Avail occ
 784         avail_fs = occNameFS (availName avail)
 785         add_avail avail_fm _ = addToFM_C add_item avail_fm avail_fs avail
 786
 787         add_item (AvailTC p occs) _ = AvailTC p (List.insert occ occs)
 788         add_item (Avail n)        _ = pprPanic "MkIface.addAvail" (ppr n <+> ppr name)
 789 \end{code}
 790
 791
 792 %************************************************************************
 793 %*                                                                      *
 794         Load the old interface file for this module (unless
 795         we have it aleady), and check whether it is up to date
 796
 797 %*                                                                      *
 798 %************************************************************************
 799
 800 \begin{code}
 801 checkOldIface :: HscEnv
 802               -> Module
 803               -> FilePath               -- Where the interface file is
 804               -> Bool                   -- Source unchanged
 805               -> Maybe ModIface         -- Old interface from compilation manager, if any
 806               -> IO (RecompileRequired, Maybe ModIface)
 807
 808 checkOldIface hsc_env mod iface_path source_unchanged maybe_iface
 809   = do  { showPass (hsc_dflags hsc_env)
 810                    ("Checking old interface for " ++ moduleUserString mod) ;
 811
 812         ; initIfaceCheck hsc_env $
 813           check_old_iface mod iface_path source_unchanged maybe_iface
 814      }
 815
 816 check_old_iface this_mod iface_path source_unchanged maybe_iface
 817  =      -- CHECK WHETHER THE SOURCE HAS CHANGED
 818     ifM (not source_unchanged)
 819         (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
 820                                                 `thenM_`
 821
 822      -- If the source has changed and we're in interactive mode, avoid reading
 823      -- an interface; just return the one we might have been supplied with.
 824     getGhciMode                                 `thenM` \ ghci_mode ->
 825     if (ghci_mode == Interactive) && not source_unchanged then
 826          returnM (outOfDate, maybe_iface)
 827     else
 828
 829     case maybe_iface of {
 830        Just old_iface -> -- Use the one we already have
 831                          checkVersions source_unchanged old_iface       `thenM` \ recomp ->
 832                          returnM (recomp, Just old_iface)
 833
 834     ;  Nothing ->
 835
 836         -- Try and read the old interface for the current module
 837         -- from the .hi file left from the last time we compiled it
 838     readIface this_mod iface_path False         `thenM` \ read_result ->
 839     case read_result of {
 840        Failed err ->    -- Old interface file not found, or garbled; give up
 841                    traceIf (text "FYI: cannot read old interface file:"
 842                                  $$ nest 4 err)         `thenM_`
 843                    returnM (outOfDate, Nothing)
 844
 845     ;  Succeeded iface ->
 846
 847         -- We have got the old iface; check its versions
 848     checkVersions source_unchanged iface        `thenM` \ recomp ->
 849     returnM (recomp, Just iface)
 850     }}
 851 \end{code}
 852
 853 @recompileRequired@ is called from the HscMain.   It checks whether
 854 a recompilation is required.  It needs access to the persistent state,
 855 finder, etc, because it may have to load lots of interface files to
 856 check their versions.
 857
 858 \begin{code}
 859 type RecompileRequired = Bool
 860 upToDate  = False       -- Recompile not required
 861 outOfDate = True        -- Recompile required
 862
 863 checkVersions :: Bool           -- True <=> source unchanged
 864               -> ModIface       -- Old interface
 865               -> IfG RecompileRequired
 866 checkVersions source_unchanged iface
 867   | not source_unchanged
 868   = returnM outOfDate
 869   | otherwise
 870   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+>
 871                         ppr (mi_module iface) <> colon)
 872
 873         -- Source code unchanged and no errors yet... carry on
 874
 875         -- First put the dependent-module info, read from the old interface, into the envt,
 876         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
 877         --
 878         -- It's just temporary because either the usage check will succeed
 879         -- (in which case we are done with this module) or it'll fail (in which
 880         -- case we'll compile the module from scratch anyhow).
 881         --
 882         -- We do this regardless of compilation mode
 883         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
 884
 885         ; checkList [checkModUsage u | u <- mi_usages iface]
 886     }
 887   where
 888         -- This is a bit of a hack really
 889     mod_deps :: ModuleEnv (Module, IsBootInterface)
 890     mod_deps = mkModDeps (dep_mods (mi_deps iface))
 891
 892 checkModUsage :: Usage -> IfG RecompileRequired
 893 -- Given the usage information extracted from the old
 894 -- M.hi file for the module being compiled, figure out
 895 -- whether M needs to be recompiled.
 896
 897 checkModUsage (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
 898                        usg_rules = old_rule_vers,
 899                        usg_exports = maybe_old_export_vers,
 900                        usg_entities = old_decl_vers })
 901   =     -- Load the imported interface is possible
 902     let
 903         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 904     in
 905     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
 906
 907     loadInterface doc_str mod_name ImportBySystem       `thenM` \ mb_iface ->
 908         -- Load the interface, but don't complain on failure;
 909         -- Instead, get an Either back which we can test
 910
 911     case mb_iface of {
 912         Failed exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"),
 913                                        ppr mod_name]));
 914                 -- Couldn't find or parse a module mentioned in the
 915                 -- old interface file.  Don't complain -- it might just be that
 916                 -- the current module doesn't need that import and it's been deleted
 917
 918         Succeeded iface ->
 919     let
 920         new_mod_vers    = mi_mod_vers  iface
 921         new_decl_vers   = mi_ver_fn    iface
 922         new_export_vers = mi_exp_vers  iface
 923         new_rule_vers   = mi_rule_vers iface
 924     in
 925         -- CHECK MODULE
 926     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
 927     if not recompile then
 928         returnM upToDate
 929     else
 930
 931         -- CHECK EXPORT LIST
 932     if checkExportList maybe_old_export_vers new_export_vers then
 933         out_of_date_vers (ptext SLIT("  Export list changed"))
 934                          (fromJust maybe_old_export_vers)
 935                          new_export_vers
 936     else
 937
 938         -- CHECK RULES
 939     if old_rule_vers /= new_rule_vers then
 940         out_of_date_vers (ptext SLIT("  Rules changed"))
 941                          old_rule_vers new_rule_vers
 942     else
 943
 944         -- CHECK ITEMS ONE BY ONE
 945     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
 946     if recompile then
 947         returnM outOfDate       -- This one failed, so just bail out now
 948     else
 949         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
 950     }
 951
 952 ------------------------
 953 checkModuleVersion old_mod_vers new_mod_vers
 954   | new_mod_vers == old_mod_vers
 955   = up_to_date (ptext SLIT("Module version unchanged"))
 956
 957   | otherwise
 958   = out_of_date_vers (ptext SLIT("  Module version has changed"))
 959                      old_mod_vers new_mod_vers
 960
 961 ------------------------
 962 checkExportList Nothing  new_vers = upToDate
 963 checkExportList (Just v) new_vers = v /= new_vers
 964
 965 ------------------------
 966 checkEntityUsage new_vers (name,old_vers)
 967   = case new_vers name of
 968
 969         Nothing       ->        -- We used it before, but it ain't there now
 970                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 971
 972         Just new_vers   -- It's there, but is it up to date?
 973           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
 974                                     returnM upToDate
 975           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
 976                                                      old_vers new_vers
 977
 978 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
 979 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
 980 out_of_date_vers msg old_vers new_vers
 981   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
 982
 983 ----------------------
 984 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
 985 -- This helper is used in two places
 986 checkList []             = returnM upToDate
 987 checkList (check:checks) = check        `thenM` \ recompile ->
 988                            if recompile then
 989                                 returnM outOfDate
 990                            else
 991                                 checkList checks
 992 \end{code}
 993
 994 %************************************************************************
 995 %*                                                                      *
 996                 Printing interfaces
 997 %*                                                                      *
 998 %************************************************************************
 999
1000 \begin{code}
1001 showIface :: FilePath -> IO ()
1002 -- Raad binary interface, and print it out
1003 showIface filename = do
1004    -- skip the version check; we don't want to worry about profiled vs.
1005    -- non-profiled interfaces, for example.
1006    writeIORef v_IgnoreHiWay True
1007    iface <- Binary.getBinFileWithDict filename
1008    printDump (pprModIface iface)
1009  where
1010 \end{code}
1011
1012
1013 \begin{code}
1014 pprModIface :: ModIface -> SDoc
1015 -- Show a ModIface
1016 pprModIface iface
1017  = vcat [ ptext SLIT("interface")
1018                 <+> ppr_package (mi_package iface)
1019                 <+> ppr (mi_module iface) <+> ppr (mi_mod_vers iface)
1020                 <+> pp_sub_vers
1021                 <+> (if mi_orphan iface then ptext SLIT("[orphan module]") else empty)
1022                 <+> int opt_HiVersion
1023                 <+> ptext SLIT("where")
1024         , vcat (map pprExport (mi_exports iface))
1025         , pprDeps (mi_deps iface)
1026         , vcat (map pprUsage (mi_usages iface))
1027         , pprFixities (mi_fixities iface)
1028         , vcat (map pprIfaceDecl (mi_decls iface))
1029         , vcat (map ppr (mi_insts iface))
1030         , vcat (map ppr (mi_rules iface))
1031         , pprDeprecs (mi_deprecs iface)
1032         ]
1033   where
1034     ppr_package HomePackage = empty
1035     ppr_package (ExtPackage id) = doubleQuotes (ppr id)
1036
1037     exp_vers  = mi_exp_vers iface
1038     rule_vers = mi_rule_vers iface
1039
1040     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
1041                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
1042 \end{code}
1043
1044 When printing export lists, we print like this:
1045         Avail   f               f
1046         AvailTC C [C, x, y]     C(x,y)
1047         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
1048
1049 \begin{code}
1050 pprExport :: IfaceExport -> SDoc
1051 pprExport (mod, items)
1052  = hsep [ ptext SLIT("export"), ppr mod, hsep (map pp_avail items) ]
1053   where
1054     pp_avail :: GenAvailInfo OccName -> SDoc
1055     pp_avail (Avail occ)    = ppr occ
1056     pp_avail (AvailTC _ []) = empty
1057     pp_avail (AvailTC n (n':ns))
1058         | n==n'     = ppr n <> pp_export ns
1059         | otherwise = ppr n <> char '|' <> pp_export (n':ns)
1060
1061     pp_export []    = empty
1062     pp_export names = braces (hsep (map ppr names))
1063
1064 pprUsage :: Usage -> SDoc
1065 pprUsage usage
1066   = hsep [ptext SLIT("import"), ppr (usg_name usage),
1067           int (usg_mod usage),
1068           pp_export_version (usg_exports usage),
1069           int (usg_rules usage),
1070           pp_versions (usg_entities usage) ]
1071   where
1072     pp_versions nvs = hsep [ ppr n <+> int v | (n,v) <- nvs ]
1073     pp_export_version Nothing  = empty
1074     pp_export_version (Just v) = int v
1075
1076 pprDeps :: Dependencies -> SDoc
1077 pprDeps (Deps { dep_mods = mods, dep_pkgs = pkgs, dep_orphs = orphs})
1078   = vcat [ptext SLIT("module dependencies:") <+> fsep (map ppr_mod mods),
1079           ptext SLIT("package dependencies:") <+> fsep (map ppr pkgs),
1080           ptext SLIT("orphans:") <+> fsep (map ppr orphs)
1081         ]
1082   where
1083     ppr_mod (mod_name, boot) = ppr mod_name <+> ppr_boot boot
1084     ppr_boot True  = text "[boot]"
1085     ppr_boot False = empty
1086
1087 pprIfaceDecl :: (Version, IfaceDecl) -> SDoc
1088 pprIfaceDecl (ver, decl)
1089   = ppr_vers ver <+> ppr decl
1090   where
1091         -- Print the version for the decl
1092     ppr_vers v | v == initialVersion = empty
1093                | otherwise           = int v
1094
1095 pprFixities :: [(OccName, Fixity)] -> SDoc
1096 pprFixities []    = empty
1097 pprFixities fixes = ptext SLIT("fixities") <+> pprWithCommas pprFix fixes
1098                   where
1099                     pprFix (occ,fix) = ppr fix <+> ppr occ
1100
1101 pprDeprecs NoDeprecs        = empty
1102 pprDeprecs (DeprecAll txt)  = ptext SLIT("Deprecate all") <+> doubleQuotes (ftext txt)
1103 pprDeprecs (DeprecSome prs) = ptext SLIT("Deprecate") <+> vcat (map pprDeprec prs)
1104                             where
1105                               pprDeprec (name, txt) = ppr name <+> doubleQuotes (ftext txt)
1106 \end{code}