ghc/compiler/main/CodeOutput.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section{Code output phase}
   5
   6 \begin{code}
   7 module CodeOutput( codeOutput ) where
   8
   9 #include "HsVersions.h"
  10
  11 #ifndef OMIT_NATIVE_CODEGEN
  12 import AsmCodeGen       ( nativeCodeGen )
  13 #endif
  14
  15 #ifdef ILX
  16 import IlxGen           ( ilxGen )
  17 #endif
  18
  19 import JavaGen          ( javaGen )
  20 import qualified PrintJava
  21
  22 import TyCon            ( TyCon )
  23 import Id               ( Id )
  24 import CoreSyn          ( CoreBind )
  25 import StgSyn           ( StgBinding )
  26 import AbsCSyn          ( AbstractC )
  27 import PprAbsC          ( dumpRealC, writeRealC )
  28 import Module           ( Module )
  29 import CmdLineOpts
  30 import ErrUtils         ( dumpIfSet_dyn )
  31 import Outputable
  32 import CmdLineOpts      ( DynFlags, HscLang(..), dopt_OutName )
  33 import TmpFiles         ( newTempName )
  34 import UniqSupply       ( mkSplitUniqSupply )
  35
  36 import IO               ( IOMode(..), hClose, openFile, Handle )
  37 \end{code}
  38
  39
  40 %************************************************************************
  41 %*                                                                      *
  42 \subsection{Steering}
  43 %*                                                                      *
  44 %************************************************************************
  45
  46 \begin{code}
  47 codeOutput :: DynFlags
  48            -> Module
  49            -> [TyCon]                   -- Local tycons
  50            -> [CoreBind]                -- Core bindings
  51            -> [(StgBinding,[Id])]       -- The STG program with SRTs
  52            -> SDoc              -- C stubs for foreign exported functions
  53            -> SDoc              -- Header file prototype for foreign exported functions
  54            -> AbstractC         -- Compiled abstract C
  55            -> IO (Maybe FilePath, Maybe FilePath)
  56 codeOutput dflags mod_name tycons core_binds stg_binds
  57            c_code h_code flat_abstractC
  58   = -- You can have C (c_output) or assembly-language (ncg_output),
  59     -- but not both.  [Allowing for both gives a space leak on
  60     -- flat_abstractC.  WDP 94/10]
  61
  62     -- Dunno if the above comment is still meaningful now.  JRS 001024.
  63
  64     do let filenm = dopt_OutName dflags
  65        stub_names <- outputForeignStubs dflags c_code h_code
  66        case dopt_HscLang dflags of
  67           HscInterpreted -> return stub_names
  68           HscAsm         -> outputAsm dflags filenm flat_abstractC
  69                             >> return stub_names
  70           HscC           -> outputC dflags filenm flat_abstractC
  71                             >> return stub_names
  72           HscJava        -> outputJava dflags filenm mod_name tycons core_binds
  73                             >> return stub_names
  74
  75 doOutput :: String -> (Handle -> IO ()) -> IO ()
  76 doOutput filenm io_action
  77   = (do handle <- openFile filenm WriteMode
  78         io_action handle
  79         hClose handle)
  80     `catch` (\err -> pprPanic "Failed to open or write code output file"
  81                               (text filenm))
  82 \end{code}
  83
  84
  85 %************************************************************************
  86 %*                                                                      *
  87 \subsection{C}
  88 %*                                                                      *
  89 %************************************************************************
  90
  91 \begin{code}
  92 outputC dflags filenm flat_absC
  93   = do dumpIfSet_dyn dflags Opt_D_dump_realC "Real C" (dumpRealC flat_absC)
  94        doOutput filenm (\ h -> writeRealC h flat_absC)
  95 \end{code}
  96
  97
  98 %************************************************************************
  99 %*                                                                      *
 100 \subsection{Assembler}
 101 %*                                                                      *
 102 %************************************************************************
 103
 104 \begin{code}
 105 outputAsm dflags filenm flat_absC
 106
 107 #ifndef OMIT_NATIVE_CODEGEN
 108
 109   = do ncg_uniqs <- mkSplitUniqSupply 'n'
 110        let (stix_final, ncg_output_d) = nativeCodeGen flat_absC ncg_uniqs
 111        dumpIfSet_dyn dflags Opt_D_dump_stix "Final stix code" stix_final
 112        dumpIfSet_dyn dflags Opt_D_dump_asm "Asm code" ncg_output_d
 113        doOutput filenm ( \f -> printForAsm f ncg_output_d)
 114   where
 115
 116 #else /* OMIT_NATIVE_CODEGEN */
 117
 118   = pprPanic "This compiler was built without a native code generator"
 119              (text "Use -fvia-C instead")
 120
 121 #endif
 122 \end{code}
 123
 124
 125 %************************************************************************
 126 %*                                                                      *
 127 \subsection{Java}
 128 %*                                                                      *
 129 %************************************************************************
 130
 131 \begin{code}
 132 outputJava dflags filenm mod tycons core_binds
 133   = doOutput filenm (\ f -> printForUser f pp_java)
 134         -- User style printing for now to keep indentation
 135   where
 136     java_code = javaGen mod [{- Should be imports-}] tycons core_binds
 137     pp_java   = PrintJava.compilationUnit java_code
 138 \end{code}
 139
 140
 141 %************************************************************************
 142 %*                                                                      *
 143 \subsection{Foreign import/export}
 144 %*                                                                      *
 145 %************************************************************************
 146
 147 \begin{code}
 148 outputForeignStubs dflags c_code h_code
 149   = do
 150         dumpIfSet_dyn dflags Opt_D_dump_foreign
 151                       "Foreign export header file" stub_h_output_d
 152
 153         maybe_stub_h_file
 154            <- outputForeignStubs_help True{-.h output-} stub_h_output_w
 155
 156         dumpIfSet_dyn dflags Opt_D_dump_foreign
 157                       "Foreign export stubs" stub_c_output_d
 158
 159         maybe_stub_c_file
 160            <- outputForeignStubs_help False{-not .h-} stub_c_output_w
 161
 162         return (maybe_stub_h_file, maybe_stub_c_file)
 163   where
 164     -- C stubs for "foreign export"ed functions.
 165     stub_c_output_d = pprCode CStyle c_code
 166     stub_c_output_w = showSDoc stub_c_output_d
 167
 168     -- Header file protos for "foreign export"ed functions.
 169     stub_h_output_d = pprCode CStyle h_code
 170     stub_h_output_w = showSDoc stub_h_output_d
 171
 172
 173 -- Don't use doOutput for dumping the f. export stubs
 174 -- since it is more than likely that the stubs file will
 175 -- turn out to be empty, in which case no file should be created.
 176 outputForeignStubs_help is_header ""      = return Nothing
 177 outputForeignStubs_help is_header doc_str
 178    = newTempName suffix >>= \ fname ->
 179      writeFile fname (include_prefix ++ doc_str) >>
 180      return (Just suffix)
 181   where
 182     suffix
 183        | is_header   = "h_stub"
 184        | otherwise   = "c_stub"
 185     include_prefix
 186        | is_header   = "#include \"HsFFI.h\"\n"
 187        | otherwise   = "#include \"RtsAPI.h\"\n"
 188 \end{code}
 189