ghc/compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         init,
  15         newSession,
  16
  17         -- * Flags and settings
  18         DynFlags(..), DynFlag(..), GhcMode(..), HscTarget(..), dopt,
  19         parseDynamicFlags,
  20         initPackages,
  21         getSessionDynFlags,
  22         setSessionDynFlags,
  23         setMsgHandler,
  24
  25         -- * Targets
  26         Target(..), TargetId(..),
  27         setTargets,
  28         getTargets,
  29         addTarget,
  30         removeTarget,
  31         guessTarget,
  32
  33         -- * Loading\/compiling the program
  34         depanal,
  35         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  36         workingDirectoryChanged,
  37         checkModule, CheckedModule(..),
  38
  39         -- * Inspecting the module structure of the program
  40         ModuleGraph, ModSummary(..),
  41         getModuleGraph,
  42         isLoaded,
  43         topSortModuleGraph,
  44
  45         -- * Inspecting modules
  46         ModuleInfo,
  47         getModuleInfo,
  48         modInfoTyThings,
  49         modInfoTopLevelScope,
  50         lookupName,
  51
  52         -- * Interactive evaluation
  53         getBindings, getPrintUnqual,
  54 #ifdef GHCI
  55         setContext, getContext,
  56         getNamesInScope,
  57         moduleIsInterpreted,
  58         getInfo, GetInfoResult,
  59         exprType,
  60         typeKind,
  61         parseName,
  62         RunResult(..),
  63         runStmt,
  64         browseModule,
  65         showModule,
  66         compileExpr, HValue,
  67 #endif
  68
  69         -- * Abstract syntax elements
  70
  71         -- ** Modules
  72         Module, mkModule, pprModule,
  73
  74         -- ** Names
  75         Name,
  76
  77         -- ** Identifiers
  78         Id, idType,
  79         isImplicitId, isDeadBinder,
  80         isSpecPragmaId, isExportedId, isLocalId, isGlobalId,
  81         isRecordSelector,
  82         isPrimOpId, isFCallId,
  83         isDataConWorkId, idDataCon,
  84         isBottomingId, isDictonaryId,
  85
  86         -- ** Type constructors
  87         TyCon,
  88         isClassTyCon, isSynTyCon, isNewTyCon,
  89
  90         -- ** Data constructors
  91         DataCon,
  92
  93         -- ** Classes
  94         Class,
  95         classSCTheta, classTvsFds,
  96
  97         -- ** Types and Kinds
  98         Type, dropForAlls,
  99         Kind,
 100
 101         -- ** Entities
 102         TyThing(..),
 103
 104         -- * Exceptions
 105         GhcException(..), showGhcException,
 106
 107         -- * Miscellaneous
 108         sessionHscEnv,
 109         cyclicModuleErr,
 110   ) where
 111
 112 {-
 113  ToDo:
 114
 115   * return error messages rather than printing them.
 116   * inline bits of HscMain here to simplify layering: hscGetInfo,
 117     hscTcExpr, hscStmt.
 118   * implement second argument to load.
 119   * we need to expose DynFlags, so should parseDynamicFlags really be
 120     part of this interface?
 121   * what StaticFlags should we expose, if any?
 122 -}
 123
 124 #include "HsVersions.h"
 125
 126 #ifdef GHCI
 127 import qualified Linker
 128 import Linker           ( HValue, extendLinkEnv )
 129 import NameEnv          ( lookupNameEnv )
 130 import TcRnDriver       ( mkExportEnv, getModuleContents, tcRnLookupRdrName )
 131 import RdrName          ( plusGlobalRdrEnv )
 132 import HscMain          ( hscGetInfo, GetInfoResult, hscParseIdentifier,
 133                           hscStmt, hscTcExpr, hscKcType )
 134 import Type             ( tidyType )
 135 import VarEnv           ( emptyTidyEnv )
 136 import GHC.Exts         ( unsafeCoerce# )
 137 import IfaceSyn         ( IfaceDecl )
 138 #endif
 139
 140 import Packages         ( initPackages )
 141 import NameSet          ( NameSet, nameSetToList )
 142 import RdrName          ( GlobalRdrEnv )
 143 import HsSyn            ( HsModule, LHsBinds )
 144 import Type             ( Kind, Type, dropForAlls )
 145 import Id               ( Id, idType, isImplicitId, isDeadBinder,
 146                           isSpecPragmaId, isExportedId, isLocalId, isGlobalId,
 147                           isRecordSelector,
 148                           isPrimOpId, isFCallId,
 149                           isDataConWorkId, idDataCon,
 150                           isBottomingId )
 151 import TyCon            ( TyCon, isClassTyCon, isSynTyCon, isNewTyCon )
 152 import Class            ( Class, classSCTheta, classTvsFds )
 153 import DataCon          ( DataCon )
 154 import Name             ( Name, getName, nameModule_maybe )
 155 import RdrName          ( RdrName, gre_name, globalRdrEnvElts )
 156 import NameEnv          ( nameEnvElts )
 157 import SrcLoc           ( Located(..) )
 158 import DriverPipeline
 159 import DriverPhases     ( Phase(..), isHaskellSrcFilename, startPhase )
 160 import GetImports       ( getImports )
 161 import Packages         ( isHomePackage )
 162 import Finder
 163 import HscMain          ( newHscEnv, hscFileCheck, HscResult(..) )
 164 import HscTypes
 165 import DynFlags
 166 import StaticFlags
 167 import SysTools         ( initSysTools, cleanTempFiles )
 168 import Module
 169 import FiniteMap
 170 import Panic
 171 import Digraph
 172 import ErrUtils         ( showPass, Messages, putMsg, debugTraceMsg )
 173 import qualified ErrUtils
 174 import Util
 175 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 176 import Outputable
 177 import SysTools         ( cleanTempFilesExcept )
 178 import BasicTypes       ( SuccessFlag(..), succeeded, failed )
 179 import Maybes           ( orElse, expectJust, mapCatMaybes )
 180 import TcType           ( tcSplitSigmaTy, isDictTy )
 181
 182 import Directory        ( getModificationTime, doesFileExist )
 183 import Maybe            ( isJust, isNothing, fromJust, fromMaybe, catMaybes )
 184 import Maybes           ( expectJust )
 185 import List             ( partition, nub )
 186 import qualified List
 187 import Monad            ( unless, when, foldM )
 188 import System           ( exitWith, ExitCode(..) )
 189 import Time             ( ClockTime )
 190 import EXCEPTION as Exception hiding (handle)
 191 import DATA_IOREF
 192 import IO
 193 import Prelude hiding (init)
 194
 195 -- -----------------------------------------------------------------------------
 196 -- Exception handlers
 197
 198 -- | Install some default exception handlers and run the inner computation.
 199 -- Unless you want to handle exceptions yourself, you should wrap this around
 200 -- the top level of your program.  The default handlers output the error
 201 -- message(s) to stderr and exit cleanly.
 202 defaultErrorHandler :: IO a -> IO a
 203 defaultErrorHandler inner =
 204   -- top-level exception handler: any unrecognised exception is a compiler bug.
 205   handle (\exception -> do
 206            hFlush stdout
 207            case exception of
 208                 -- an IO exception probably isn't our fault, so don't panic
 209                 IOException _ ->  putMsg (show exception)
 210                 AsyncException StackOverflow ->
 211                         putMsg "stack overflow: use +RTS -K<size> to increase it"
 212                 _other ->  putMsg (show (Panic (show exception)))
 213            exitWith (ExitFailure 1)
 214          ) $
 215
 216   -- all error messages are propagated as exceptions
 217   handleDyn (\dyn -> do
 218                 hFlush stdout
 219                 case dyn of
 220                      PhaseFailed _ code -> exitWith code
 221                      Interrupted -> exitWith (ExitFailure 1)
 222                      _ -> do putMsg (show (dyn :: GhcException))
 223                              exitWith (ExitFailure 1)
 224             ) $
 225   inner
 226
 227 -- | Install a default cleanup handler to remove temporary files
 228 -- deposited by a GHC run.  This is seperate from
 229 -- 'defaultErrorHandler', because you might want to override the error
 230 -- handling, but still get the ordinary cleanup behaviour.
 231 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 232 defaultCleanupHandler dflags inner =
 233    -- make sure we clean up after ourselves
 234    later (unless (dopt Opt_KeepTmpFiles dflags) $
 235             cleanTempFiles dflags)
 236         -- exceptions will be blocked while we clean the temporary files,
 237         -- so there shouldn't be any difficulty if we receive further
 238         -- signals.
 239    inner
 240
 241
 242 -- | Initialises GHC.  This must be done /once/ only.  Takes the
 243 -- command-line arguments.  All command-line arguments which aren't
 244 -- understood by GHC will be returned.
 245
 246 init :: [String] -> IO [String]
 247 init args = do
 248    -- catch ^C
 249    installSignalHandlers
 250
 251    -- Grab the -B option if there is one
 252    let (minusB_args, argv1) = partition (prefixMatch "-B") args
 253    dflags0 <- initSysTools minusB_args defaultDynFlags
 254    writeIORef v_initDynFlags dflags0
 255
 256    -- Parse the static flags
 257    argv2 <- parseStaticFlags argv1
 258    return argv2
 259
 260 GLOBAL_VAR(v_initDynFlags, error "initDynFlags", DynFlags)
 261         -- stores the DynFlags between the call to init and subsequent
 262         -- calls to newSession.
 263
 264 -- | Starts a new session.  A session consists of a set of loaded
 265 -- modules, a set of options (DynFlags), and an interactive context.
 266 -- ToDo: GhcMode should say "keep typechecked code" and\/or "keep renamed
 267 -- code".
 268 newSession :: GhcMode -> IO Session
 269 newSession mode = do
 270   dflags0 <- readIORef v_initDynFlags
 271   dflags <- initDynFlags dflags0
 272   env <- newHscEnv dflags{ ghcMode=mode }
 273   ref <- newIORef env
 274   return (Session ref)
 275
 276 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 277 -- needs to call the Finder.  ToDo: untangle this.
 278 sessionHscEnv :: Session -> IO HscEnv
 279 sessionHscEnv (Session ref) = readIORef ref
 280
 281 withSession :: Session -> (HscEnv -> IO a) -> IO a
 282 withSession (Session ref) f = do h <- readIORef ref; f h
 283
 284 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 285 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 286
 287 -- -----------------------------------------------------------------------------
 288 -- Flags & settings
 289
 290 -- | Grabs the DynFlags from the Session
 291 getSessionDynFlags :: Session -> IO DynFlags
 292 getSessionDynFlags s = withSession s (return . hsc_dflags)
 293
 294 -- | Updates the DynFlags in a Session
 295 setSessionDynFlags :: Session -> DynFlags -> IO ()
 296 setSessionDynFlags s dflags = modifySession s (\h -> h{ hsc_dflags = dflags })
 297
 298 -- | Messages during compilation (eg. warnings and progress messages)
 299 -- are reported using this callback.  By default, these messages are
 300 -- printed to stderr.
 301 setMsgHandler :: (String -> IO ()) -> IO ()
 302 setMsgHandler = ErrUtils.setMsgHandler
 303
 304 -- -----------------------------------------------------------------------------
 305 -- Targets
 306
 307 -- ToDo: think about relative vs. absolute file paths. And what
 308 -- happens when the current directory changes.
 309
 310 -- | Sets the targets for this session.  Each target may be a module name
 311 -- or a filename.  The targets correspond to the set of root modules for
 312 -- the program\/library.  Unloading the current program is achieved by
 313 -- setting the current set of targets to be empty, followed by load.
 314 setTargets :: Session -> [Target] -> IO ()
 315 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 316
 317 -- | returns the current set of targets
 318 getTargets :: Session -> IO [Target]
 319 getTargets s = withSession s (return . hsc_targets)
 320
 321 -- | Add another target
 322 addTarget :: Session -> Target -> IO ()
 323 addTarget s target
 324   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 325
 326 -- | Remove a target
 327 removeTarget :: Session -> TargetId -> IO ()
 328 removeTarget s target_id
 329   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 330   where
 331    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 332
 333 -- Attempts to guess what Target a string refers to.  This function implements
 334 -- the --make/GHCi command-line syntax for filenames:
 335 --
 336 --      - if the string looks like a Haskell source filename, then interpret
 337 --        it as such
 338 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 339 --        then use that
 340 --      - otherwise interpret the string as a module name
 341 --
 342 guessTarget :: String -> IO Target
 343 guessTarget file
 344    | isHaskellSrcFilename file
 345    = return (Target (TargetFile file) Nothing)
 346    | otherwise
 347    = do exists <- doesFileExist hs_file
 348         if exists then return (Target (TargetFile hs_file) Nothing) else do
 349         exists <- doesFileExist lhs_file
 350         if exists then return (Target (TargetFile lhs_file) Nothing) else do
 351         return (Target (TargetModule (mkModule file)) Nothing)
 352      where
 353          hs_file = file ++ ".hs"
 354          lhs_file = file ++ ".lhs"
 355
 356 -- -----------------------------------------------------------------------------
 357 -- Loading the program
 358
 359 -- Perform a dependency analysis starting from the current targets
 360 -- and update the session with the new module graph.
 361 depanal :: Session -> [Module] -> IO ()
 362 depanal (Session ref) excluded_mods = do
 363   hsc_env <- readIORef ref
 364   let
 365          dflags  = hsc_dflags hsc_env
 366          gmode   = ghcMode (hsc_dflags hsc_env)
 367          targets = hsc_targets hsc_env
 368          old_graph = hsc_mod_graph hsc_env
 369
 370   showPass dflags "Chasing dependencies"
 371   when (gmode == BatchCompile) $
 372         debugTraceMsg dflags 1 (showSDoc (hcat [
 373                      text "Chasing modules from: ",
 374                         hcat (punctuate comma (map pprTarget targets))]))
 375
 376   graph <- downsweep hsc_env old_graph excluded_mods
 377   writeIORef ref hsc_env{ hsc_mod_graph=graph }
 378
 379 {-
 380 -- | The result of load.
 381 data LoadResult
 382   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 383   | LoadFailed  Errors  -- ^ not all modules were loaded.
 384
 385 type Errors = [String]
 386
 387 data ErrMsg = ErrMsg {
 388         errMsgSeverity  :: Severity,  -- warning, error, etc.
 389         errMsgSpans     :: [SrcSpan],
 390         errMsgShortDoc  :: Doc,
 391         errMsgExtraInfo :: Doc
 392         }
 393 -}
 394
 395 data LoadHowMuch
 396    = LoadAllTargets
 397    | LoadUpTo Module
 398    | LoadDependenciesOf Module
 399
 400 -- | Try to load the program.  If a Module is supplied, then just
 401 -- attempt to load up to this target.  If no Module is supplied,
 402 -- then try to load all targets.
 403 load :: Session -> LoadHowMuch -> IO SuccessFlag
 404 load s@(Session ref) how_much
 405    = do
 406         -- Dependency analysis first.  Note that this fixes the module graph:
 407         -- even if we don't get a fully successful upsweep, the full module
 408         -- graph is still retained in the Session.  We can tell which modules
 409         -- were successfully loaded by inspecting the Session's HPT.
 410         depanal s []
 411
 412         hsc_env <- readIORef ref
 413
 414         let hpt1      = hsc_HPT hsc_env
 415         let dflags    = hsc_dflags hsc_env
 416         let mod_graph = hsc_mod_graph hsc_env
 417
 418         let ghci_mode = ghcMode (hsc_dflags hsc_env) -- this never changes
 419         let verb      = verbosity dflags
 420
 421         -- The "bad" boot modules are the ones for which we have
 422         -- B.hs-boot in the module graph, but no B.hs
 423         -- The downsweep should have ensured this does not happen
 424         -- (see msDeps)
 425         let all_home_mods = [ms_mod s | s <- mod_graph, not (isBootSummary s)]
 426             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 427                                         not (ms_mod s `elem` all_home_mods)]
 428         ASSERT( null bad_boot_mods ) return ()
 429
 430         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 431         -- graph with cycles.  Among other things, it is used for
 432         -- backing out partially complete cycles following a failed
 433         -- upsweep, and for removing from hpt all the modules
 434         -- not in strict downwards closure, during calls to compile.
 435         let mg2_with_srcimps :: [SCC ModSummary]
 436             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 437
 438             -- check the stability property for each module.
 439             stable_mods@(stable_obj,stable_bco)
 440                 | BatchCompile <- ghci_mode = ([],[])
 441                 | otherwise = checkStability hpt1 mg2_with_srcimps all_home_mods
 442
 443             -- prune bits of the HPT which are definitely redundant now,
 444             -- to save space.
 445             pruned_hpt = pruneHomePackageTable hpt1
 446                                 (flattenSCCs mg2_with_srcimps)
 447                                 stable_mods
 448
 449         evaluate pruned_hpt
 450
 451         debugTraceMsg dflags 2 (showSDoc (text "Stable obj:" <+> ppr stable_obj $$
 452                                 text "Stable BCO:" <+> ppr stable_bco))
 453
 454         -- Unload any modules which are going to be re-linked this time around.
 455         let stable_linkables = [ linkable
 456                                | m <- stable_obj++stable_bco,
 457                                  Just hmi <- [lookupModuleEnv pruned_hpt m],
 458                                  Just linkable <- [hm_linkable hmi] ]
 459         unload hsc_env stable_linkables
 460
 461         -- We could at this point detect cycles which aren't broken by
 462         -- a source-import, and complain immediately, but it seems better
 463         -- to let upsweep_mods do this, so at least some useful work gets
 464         -- done before the upsweep is abandoned.
 465         --hPutStrLn stderr "after tsort:\n"
 466         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 467
 468         -- Now do the upsweep, calling compile for each module in
 469         -- turn.  Final result is version 3 of everything.
 470
 471         -- Topologically sort the module graph, this time including hi-boot
 472         -- nodes, and possibly just including the portion of the graph
 473         -- reachable from the module specified in the 2nd argument to load.
 474         -- This graph should be cycle-free.
 475         -- If we're restricting the upsweep to a portion of the graph, we
 476         -- also want to retain everything that is still stable.
 477         let full_mg :: [SCC ModSummary]
 478             full_mg    = topSortModuleGraph False mod_graph Nothing
 479
 480             maybe_top_mod = case how_much of
 481                                 LoadUpTo m           -> Just m
 482                                 LoadDependenciesOf m -> Just m
 483                                 _                    -> Nothing
 484
 485             partial_mg0 :: [SCC ModSummary]
 486             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 487
 488             -- LoadDependenciesOf m: we want the upsweep to stop just
 489             -- short of the specified module (unless the specified module
 490             -- is stable).
 491             partial_mg
 492                 | LoadDependenciesOf mod <- how_much
 493                 = ASSERT( case last partial_mg0 of
 494                             AcyclicSCC ms -> ms_mod ms == mod; _ -> False )
 495                   List.init partial_mg0
 496                 | otherwise
 497                 = partial_mg0
 498
 499             stable_mg =
 500                 [ AcyclicSCC ms
 501                 | AcyclicSCC ms <- full_mg,
 502                   ms_mod ms `elem` stable_obj++stable_bco,
 503                   ms_mod ms `notElem` [ ms_mod ms' |
 504                                         AcyclicSCC ms' <- partial_mg ] ]
 505
 506             mg = stable_mg ++ partial_mg
 507
 508         -- clean up between compilations
 509         let cleanup = cleanTempFilesExcept dflags
 510                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 511
 512         (upsweep_ok, hsc_env1, modsUpswept)
 513            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 514                            pruned_hpt stable_mods cleanup mg
 515
 516         -- Make modsDone be the summaries for each home module now
 517         -- available; this should equal the domain of hpt3.
 518         -- Get in in a roughly top .. bottom order (hence reverse).
 519
 520         let modsDone = reverse modsUpswept
 521
 522         -- Try and do linking in some form, depending on whether the
 523         -- upsweep was completely or only partially successful.
 524
 525         if succeeded upsweep_ok
 526
 527          then
 528            -- Easy; just relink it all.
 529            do debugTraceMsg dflags 2 "Upsweep completely successful."
 530
 531               -- Clean up after ourselves
 532               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 533
 534               -- Issue a warning for the confusing case where the user
 535               -- said '-o foo' but we're not going to do any linking.
 536               -- We attempt linking if either (a) one of the modules is
 537               -- called Main, or (b) the user said -no-hs-main, indicating
 538               -- that main() is going to come from somewhere else.
 539               --
 540               let ofile = outputFile dflags
 541               let no_hs_main = dopt Opt_NoHsMain dflags
 542               let mb_main_mod = mainModIs dflags
 543               let
 544                 main_mod = mb_main_mod `orElse` "Main"
 545                 a_root_is_Main
 546                     = any ((==main_mod).moduleUserString.ms_mod)
 547                           mod_graph
 548                 do_linking = a_root_is_Main || no_hs_main
 549
 550               when (ghci_mode == BatchCompile && isJust ofile && not do_linking) $
 551                 debugTraceMsg dflags 1 ("Warning: output was redirected with -o, " ++
 552                                    "but no output will be generated\n" ++
 553                                    "because there is no " ++ main_mod ++ " module.")
 554
 555               -- link everything together
 556               linkresult <- link ghci_mode dflags do_linking (hsc_HPT hsc_env1)
 557
 558               loadFinish Succeeded linkresult ref hsc_env1
 559
 560          else
 561            -- Tricky.  We need to back out the effects of compiling any
 562            -- half-done cycles, both so as to clean up the top level envs
 563            -- and to avoid telling the interactive linker to link them.
 564            do debugTraceMsg dflags 2 "Upsweep partially successful."
 565
 566               let modsDone_names
 567                      = map ms_mod modsDone
 568               let mods_to_zap_names
 569                      = findPartiallyCompletedCycles modsDone_names
 570                           mg2_with_srcimps
 571               let mods_to_keep
 572                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 573                           modsDone
 574
 575               let hpt4 = retainInTopLevelEnvs (map ms_mod mods_to_keep)
 576                                               (hsc_HPT hsc_env1)
 577
 578               -- Clean up after ourselves
 579               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 580
 581               -- there should be no Nothings where linkables should be, now
 582               ASSERT(all (isJust.hm_linkable)
 583                         (moduleEnvElts (hsc_HPT hsc_env))) do
 584
 585               -- Link everything together
 586               linkresult <- link ghci_mode dflags False hpt4
 587
 588               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 589               loadFinish Failed linkresult ref hsc_env4
 590
 591 -- Finish up after a load.
 592
 593 -- If the link failed, unload everything and return.
 594 loadFinish all_ok Failed ref hsc_env
 595   = do unload hsc_env []
 596        writeIORef ref $! discardProg hsc_env
 597        return Failed
 598
 599 -- Empty the interactive context and set the module context to the topmost
 600 -- newly loaded module, or the Prelude if none were loaded.
 601 loadFinish all_ok Succeeded ref hsc_env
 602   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 603        return all_ok
 604
 605
 606 -- Forget the current program, but retain the persistent info in HscEnv
 607 discardProg :: HscEnv -> HscEnv
 608 discardProg hsc_env
 609   = hsc_env { hsc_mod_graph = emptyMG,
 610               hsc_IC = emptyInteractiveContext,
 611               hsc_HPT = emptyHomePackageTable }
 612
 613 -- used to fish out the preprocess output files for the purposes of
 614 -- cleaning up.  The preprocessed file *might* be the same as the
 615 -- source file, but that doesn't do any harm.
 616 ppFilesFromSummaries summaries = [ fn | Just fn <- map ms_hspp_file summaries ]
 617
 618 -- -----------------------------------------------------------------------------
 619 -- Check module
 620
 621 data CheckedModule =
 622   CheckedModule { parsedSource      :: ParsedSource,
 623                 -- ToDo: renamedSource
 624                   typecheckedSource :: Maybe TypecheckedSource,
 625                   checkedModuleInfo :: Maybe ModuleInfo
 626                 }
 627
 628 type ParsedSource  = Located (HsModule RdrName)
 629 type TypecheckedSource = LHsBinds Id
 630
 631 -- | This is the way to get access to parsed and typechecked source code
 632 -- for a module.  'checkModule' loads all the dependencies of the specified
 633 -- module in the Session, and then attempts to typecheck the module.  If
 634 -- successful, it returns the abstract syntax for the module.
 635 checkModule :: Session -> Module -> (Messages -> IO ())
 636         -> IO (Maybe CheckedModule)
 637 checkModule session@(Session ref) mod msg_act = do
 638         -- load up the dependencies first
 639    r <- load session (LoadDependenciesOf mod)
 640    if (failed r) then return Nothing else do
 641
 642         -- now parse & typecheck the module
 643    hsc_env <- readIORef ref
 644    let mg  = hsc_mod_graph hsc_env
 645    case [ ms | ms <- mg, ms_mod ms == mod ] of
 646         [] -> return Nothing
 647         (ms:_) -> do
 648            r <- hscFileCheck hsc_env msg_act ms
 649            case r of
 650                 HscFail ->
 651                    return Nothing
 652                 HscChecked parsed Nothing ->
 653                    return (Just (CheckedModule parsed Nothing Nothing))
 654                 HscChecked parsed (Just (tc_binds, rdr_env, details)) -> do
 655                    let minf = ModuleInfo {
 656                                 minf_details  = details,
 657                                 minf_rdr_env  = Just rdr_env
 658                               }
 659                    return (Just (CheckedModule {
 660                                         parsedSource = parsed,
 661                                         typecheckedSource = Just tc_binds,
 662                                         checkedModuleInfo = Just minf }))
 663
 664 -- ---------------------------------------------------------------------------
 665 -- Unloading
 666
 667 unload :: HscEnv -> [Linkable] -> IO ()
 668 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 669   = case ghcMode (hsc_dflags hsc_env) of
 670         BatchCompile  -> return ()
 671         JustTypecheck -> return ()
 672 #ifdef GHCI
 673         Interactive -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 674 #else
 675         Interactive -> panic "unload: no interpreter"
 676 #endif
 677         other -> panic "unload: strange mode"
 678
 679 -- -----------------------------------------------------------------------------
 680 -- checkStability
 681
 682 {-
 683   Stability tells us which modules definitely do not need to be recompiled.
 684   There are two main reasons for having stability:
 685
 686    - avoid doing a complete upsweep of the module graph in GHCi when
 687      modules near the bottom of the tree have not changed.
 688
 689    - to tell GHCi when it can load object code: we can only load object code
 690      for a module when we also load object code fo  all of the imports of the
 691      module.  So we need to know that we will definitely not be recompiling
 692      any of these modules, and we can use the object code.
 693
 694   NB. stability is of no importance to BatchCompile at all, only Interactive.
 695   (ToDo: what about JustTypecheck?)
 696
 697   The stability check is as follows.  Both stableObject and
 698   stableBCO are used during the upsweep phase later.
 699
 700   -------------------
 701   stable m = stableObject m || stableBCO m
 702
 703   stableObject m =
 704         all stableObject (imports m)
 705         && old linkable does not exist, or is == on-disk .o
 706         && date(on-disk .o) > date(.hs)
 707
 708   stableBCO m =
 709         all stable (imports m)
 710         && date(BCO) > date(.hs)
 711   -------------------
 712
 713   These properties embody the following ideas:
 714
 715     - if a module is stable:
 716         - if it has been compiled in a previous pass (present in HPT)
 717           then it does not need to be compiled or re-linked.
 718         - if it has not been compiled in a previous pass,
 719           then we only need to read its .hi file from disk and
 720           link it to produce a ModDetails.
 721
 722     - if a modules is not stable, we will definitely be at least
 723       re-linking, and possibly re-compiling it during the upsweep.
 724       All non-stable modules can (and should) therefore be unlinked
 725       before the upsweep.
 726
 727     - Note that objects are only considered stable if they only depend
 728       on other objects.  We can't link object code against byte code.
 729 -}
 730
 731 checkStability
 732         :: HomePackageTable             -- HPT from last compilation
 733         -> [SCC ModSummary]             -- current module graph (cyclic)
 734         -> [Module]                     -- all home modules
 735         -> ([Module],                   -- stableObject
 736             [Module])                   -- stableBCO
 737
 738 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 739   where
 740    checkSCC (stable_obj, stable_bco) scc0
 741      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 742      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 743      | otherwise     = (stable_obj, stable_bco)
 744      where
 745         scc = flattenSCC scc0
 746         scc_mods = map ms_mod scc
 747         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 748
 749         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 750             -- all imports outside the current SCC, but in the home pkg
 751
 752         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 753         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 754
 755         stableObjects =
 756            and stable_obj_imps
 757            && all object_ok scc
 758
 759         stableBCOs =
 760            and (zipWith (||) stable_obj_imps stable_bco_imps)
 761            && all bco_ok scc
 762
 763         object_ok ms
 764           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 765                                          && same_as_prev t
 766           | otherwise = False
 767           where
 768              same_as_prev t = case lookupModuleEnv hpt (ms_mod ms) of
 769                                 Nothing  -> True
 770                                 Just hmi  | Just l <- hm_linkable hmi
 771                                  -> isObjectLinkable l && t == linkableTime l
 772                 -- why '>=' rather than '>' above?  If the filesystem stores
 773                 -- times to the nearset second, we may occasionally find that
 774                 -- the object & source have the same modification time,
 775                 -- especially if the source was automatically generated
 776                 -- and compiled.  Using >= is slightly unsafe, but it matches
 777                 -- make's behaviour.
 778
 779         bco_ok ms
 780           = case lookupModuleEnv hpt (ms_mod ms) of
 781                 Nothing  -> False
 782                 Just hmi  | Just l <- hm_linkable hmi ->
 783                         not (isObjectLinkable l) &&
 784                         linkableTime l >= ms_hs_date ms
 785
 786 ms_allimps :: ModSummary -> [Module]
 787 ms_allimps ms = ms_srcimps ms ++ ms_imps ms
 788
 789 -- -----------------------------------------------------------------------------
 790 -- Prune the HomePackageTable
 791
 792 -- Before doing an upsweep, we can throw away:
 793 --
 794 --   - For non-stable modules:
 795 --      - all ModDetails, all linked code
 796 --   - all unlinked code that is out of date with respect to
 797 --     the source file
 798 --
 799 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 800 -- space at the end of the upsweep, because the topmost ModDetails of the
 801 -- old HPT holds on to the entire type environment from the previous
 802 -- compilation.
 803
 804 pruneHomePackageTable
 805    :: HomePackageTable
 806    -> [ModSummary]
 807    -> ([Module],[Module])
 808    -> HomePackageTable
 809
 810 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
 811   = mapModuleEnv prune hpt
 812   where prune hmi
 813           | is_stable modl = hmi'
 814           | otherwise      = hmi'{ hm_details = emptyModDetails }
 815           where
 816            modl = mi_module (hm_iface hmi)
 817            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
 818                 = hmi{ hm_linkable = Nothing }
 819                 | otherwise
 820                 = hmi
 821                 where ms = expectJust "prune" (lookupModuleEnv ms_map modl)
 822
 823         ms_map = mkModuleEnv [(ms_mod ms, ms) | ms <- summ]
 824
 825         is_stable m = m `elem` stable_obj || m `elem` stable_bco
 826
 827 -- -----------------------------------------------------------------------------
 828
 829 -- Return (names of) all those in modsDone who are part of a cycle
 830 -- as defined by theGraph.
 831 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 832 findPartiallyCompletedCycles modsDone theGraph
 833    = chew theGraph
 834      where
 835         chew [] = []
 836         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 837         chew ((CyclicSCC vs):rest)
 838            = let names_in_this_cycle = nub (map ms_mod vs)
 839                  mods_in_this_cycle
 840                     = nub ([done | done <- modsDone,
 841                                    done `elem` names_in_this_cycle])
 842                  chewed_rest = chew rest
 843              in
 844              if   notNull mods_in_this_cycle
 845                   && length mods_in_this_cycle < length names_in_this_cycle
 846              then mods_in_this_cycle ++ chewed_rest
 847              else chewed_rest
 848
 849 -- -----------------------------------------------------------------------------
 850 -- The upsweep
 851
 852 -- This is where we compile each module in the module graph, in a pass
 853 -- from the bottom to the top of the graph.
 854
 855 -- There better had not be any cyclic groups here -- we check for them.
 856
 857 upsweep
 858     :: HscEnv                   -- Includes initially-empty HPT
 859     -> HomePackageTable         -- HPT from last time round (pruned)
 860     -> ([Module],[Module])      -- stable modules (see checkStability)
 861     -> IO ()                    -- How to clean up unwanted tmp files
 862     -> [SCC ModSummary]         -- Mods to do (the worklist)
 863     -> IO (SuccessFlag,
 864            HscEnv,              -- With an updated HPT
 865            [ModSummary])        -- Mods which succeeded
 866
 867 upsweep hsc_env old_hpt stable_mods cleanup
 868      []
 869    = return (Succeeded, hsc_env, [])
 870
 871 upsweep hsc_env old_hpt stable_mods cleanup
 872      (CyclicSCC ms:_)
 873    = do putMsg (showSDoc (cyclicModuleErr ms))
 874         return (Failed, hsc_env, [])
 875
 876 upsweep hsc_env old_hpt stable_mods cleanup
 877      (AcyclicSCC mod:mods)
 878    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
 879         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
 880         --                     (moduleEnvElts (hsc_HPT hsc_env)))
 881
 882         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods mod
 883
 884         cleanup         -- Remove unwanted tmp files between compilations
 885
 886         case mb_mod_info of
 887             Nothing -> return (Failed, hsc_env, [])
 888             Just mod_info -> do
 889                 { let this_mod = ms_mod mod
 890
 891                         -- Add new info to hsc_env
 892                       hpt1     = extendModuleEnv (hsc_HPT hsc_env)
 893                                         this_mod mod_info
 894                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
 895
 896                         -- Space-saving: delete the old HPT entry
 897                         -- for mod BUT if mod is a hs-boot
 898                         -- node, don't delete it.  For the
 899                         -- interface, the HPT entry is probaby for the
 900                         -- main Haskell source file.  Deleting it
 901                         -- would force .. (what?? --SDM)
 902                       old_hpt1 | isBootSummary mod = old_hpt
 903                                | otherwise = delModuleEnv old_hpt this_mod
 904
 905                 ; (restOK, hsc_env2, modOKs)
 906                         <- upsweep hsc_env1 old_hpt1 stable_mods cleanup mods
 907                 ; return (restOK, hsc_env2, mod:modOKs)
 908                 }
 909
 910
 911 -- Compile a single module.  Always produce a Linkable for it if
 912 -- successful.  If no compilation happened, return the old Linkable.
 913 upsweep_mod :: HscEnv
 914             -> HomePackageTable
 915             -> ([Module],[Module])
 916             -> ModSummary
 917             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
 918
 919 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) summary
 920    = do
 921         let
 922             this_mod    = ms_mod summary
 923             mb_obj_date = ms_obj_date summary
 924             obj_fn      = ml_obj_file (ms_location summary)
 925             hs_date     = ms_hs_date summary
 926
 927             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
 928             compile_it  = upsweep_compile hsc_env old_hpt this_mod summary
 929
 930         case ghcMode (hsc_dflags hsc_env) of
 931             BatchCompile ->
 932                 case () of
 933                    -- Batch-compilating is easy: just check whether we have
 934                    -- an up-to-date object file.  If we do, then the compiler
 935                    -- needs to do a recompilation check.
 936                    _ | Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
 937                            linkable <-
 938                                 findObjectLinkable this_mod obj_fn obj_date
 939                            compile_it (Just linkable)
 940
 941                      | otherwise ->
 942                            compile_it Nothing
 943
 944             interactive ->
 945                 case () of
 946                     _ | is_stable_obj, isJust old_hmi ->
 947                            return old_hmi
 948                         -- object is stable, and we have an entry in the
 949                         -- old HPT: nothing to do
 950
 951                       | is_stable_obj, isNothing old_hmi -> do
 952                            linkable <-
 953                                 findObjectLinkable this_mod obj_fn
 954                                         (expectJust "upseep1" mb_obj_date)
 955                            compile_it (Just linkable)
 956                         -- object is stable, but we need to load the interface
 957                         -- off disk to make a HMI.
 958
 959                       | is_stable_bco ->
 960                            ASSERT(isJust old_hmi) -- must be in the old_hpt
 961                            return old_hmi
 962                         -- BCO is stable: nothing to do
 963
 964                       | Just hmi <- old_hmi,
 965                         Just l <- hm_linkable hmi, not (isObjectLinkable l),
 966                         linkableTime l >= ms_hs_date summary ->
 967                            compile_it (Just l)
 968                         -- we have an old BCO that is up to date with respect
 969                         -- to the source: do a recompilation check as normal.
 970
 971                       | otherwise ->
 972                           compile_it Nothing
 973                         -- no existing code at all: we must recompile.
 974                    where
 975                     is_stable_obj = this_mod `elem` stable_obj
 976                     is_stable_bco = this_mod `elem` stable_bco
 977
 978                     old_hmi = lookupModuleEnv old_hpt this_mod
 979
 980 -- Run hsc to compile a module
 981 upsweep_compile hsc_env old_hpt this_mod summary mb_old_linkable = do
 982   let
 983         -- The old interface is ok if it's in the old HPT
 984         --      a) we're compiling a source file, and the old HPT
 985         --      entry is for a source file
 986         --      b) we're compiling a hs-boot file
 987         -- Case (b) allows an hs-boot file to get the interface of its
 988         -- real source file on the second iteration of the compilation
 989         -- manager, but that does no harm.  Otherwise the hs-boot file
 990         -- will always be recompiled
 991
 992         mb_old_iface
 993                 = case lookupModuleEnv old_hpt this_mod of
 994                      Nothing                              -> Nothing
 995                      Just hm_info | isBootSummary summary -> Just iface
 996                                   | not (mi_boot iface)   -> Just iface
 997                                   | otherwise             -> Nothing
 998                                    where
 999                                      iface = hm_iface hm_info
1000
1001   compresult <- compile hsc_env summary mb_old_linkable mb_old_iface
1002
1003   case compresult of
1004         -- Compilation failed.  Compile may still have updated the PCS, tho.
1005         CompErrs -> return Nothing
1006
1007         -- Compilation "succeeded", and may or may not have returned a new
1008         -- linkable (depending on whether compilation was actually performed
1009         -- or not).
1010         CompOK new_details new_iface new_linkable
1011               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1012                                                  hm_details = new_details,
1013                                                  hm_linkable = new_linkable }
1014                     return (Just new_info)
1015
1016
1017 -- Filter modules in the HPT
1018 retainInTopLevelEnvs :: [Module] -> HomePackageTable -> HomePackageTable
1019 retainInTopLevelEnvs keep_these hpt
1020    = mkModuleEnv [ (mod, expectJust "retain" mb_mod_info)
1021                  | mod <- keep_these
1022                  , let mb_mod_info = lookupModuleEnv hpt mod
1023                  , isJust mb_mod_info ]
1024
1025 -- ---------------------------------------------------------------------------
1026 -- Topological sort of the module graph
1027
1028 topSortModuleGraph
1029           :: Bool               -- Drop hi-boot nodes? (see below)
1030           -> [ModSummary]
1031           -> Maybe Module
1032           -> [SCC ModSummary]
1033 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1034 -- The resulting list of strongly-connected-components is in topologically
1035 -- sorted order, starting with the module(s) at the bottom of the
1036 -- dependency graph (ie compile them first) and ending with the ones at
1037 -- the top.
1038 --
1039 -- Drop hi-boot nodes (first boolean arg)?
1040 --
1041 --   False:     treat the hi-boot summaries as nodes of the graph,
1042 --              so the graph must be acyclic
1043 --
1044 --   True:      eliminate the hi-boot nodes, and instead pretend
1045 --              the a source-import of Foo is an import of Foo
1046 --              The resulting graph has no hi-boot nodes, but can by cyclic
1047
1048 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1049   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1050 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1051   = stronglyConnComp (map vertex_fn (reachable graph root))
1052   where
1053         -- restrict the graph to just those modules reachable from
1054         -- the specified module.  We do this by building a graph with
1055         -- the full set of nodes, and determining the reachable set from
1056         -- the specified node.
1057         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1058         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1059         root
1060           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1061           | otherwise  = throwDyn (ProgramError "module does not exist")
1062
1063 moduleGraphNodes :: Bool -> [ModSummary]
1064   -> ([(ModSummary, Int, [Int])], HscSource -> Module -> Maybe Int)
1065 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1066    where
1067         -- Drop hs-boot nodes by using HsSrcFile as the key
1068         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1069                     | otherwise          = HsBootFile
1070
1071         -- We use integers as the keys for the SCC algorithm
1072         nodes :: [(ModSummary, Int, [Int])]
1073         nodes = [(s, expectJust "topSort" (lookup_key (ms_hsc_src s) (ms_mod s)),
1074                      out_edge_keys hs_boot_key (ms_srcimps s) ++
1075                      out_edge_keys HsSrcFile   (ms_imps s)    )
1076                 | s <- summaries
1077                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1078                 -- Drop the hi-boot ones if told to do so
1079
1080         key_map :: NodeMap Int
1081         key_map = listToFM ([(ms_mod s, ms_hsc_src s) | s <- summaries]
1082                            `zip` [1..])
1083
1084         lookup_key :: HscSource -> Module -> Maybe Int
1085         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1086
1087         out_edge_keys :: HscSource -> [Module] -> [Int]
1088         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1089                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1090                 -- the IsBootInterface parameter True; else False
1091
1092
1093 type NodeKey   = (Module, HscSource)      -- The nodes of the graph are
1094 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1095
1096 msKey :: ModSummary -> NodeKey
1097 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (mod,boot)
1098
1099 emptyNodeMap :: NodeMap a
1100 emptyNodeMap = emptyFM
1101
1102 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1103 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1104
1105 nodeMapElts :: NodeMap a -> [a]
1106 nodeMapElts = eltsFM
1107
1108 -- -----------------------------------------------------------------
1109 -- The unlinked image
1110 --
1111 -- The compilation manager keeps a list of compiled, but as-yet unlinked
1112 -- binaries (byte code or object code).  Even when it links bytecode
1113 -- it keeps the unlinked version so it can re-link it later without
1114 -- recompiling.
1115
1116 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
1117
1118 findModuleLinkable_maybe :: [Linkable] -> Module -> Maybe Linkable
1119 findModuleLinkable_maybe lis mod
1120    = case [LM time nm us | LM time nm us <- lis, nm == mod] of
1121         []   -> Nothing
1122         [li] -> Just li
1123         many -> pprPanic "findModuleLinkable" (ppr mod)
1124
1125 delModuleLinkable :: [Linkable] -> Module -> [Linkable]
1126 delModuleLinkable ls mod = [ l | l@(LM _ nm _) <- ls, nm /= mod ]
1127
1128 -----------------------------------------------------------------------------
1129 -- Downsweep (dependency analysis)
1130
1131 -- Chase downwards from the specified root set, returning summaries
1132 -- for all home modules encountered.  Only follow source-import
1133 -- links.
1134
1135 -- We pass in the previous collection of summaries, which is used as a
1136 -- cache to avoid recalculating a module summary if the source is
1137 -- unchanged.
1138 --
1139 -- The returned list of [ModSummary] nodes has one node for each home-package
1140 -- module, plus one for any hs-boot files.  The imports of these nodes
1141 -- are all there, including the imports of non-home-package modules.
1142
1143 downsweep :: HscEnv
1144           -> [ModSummary]       -- Old summaries
1145           -> [Module]           -- Ignore dependencies on these; treat them as
1146                                 -- if they were package modules
1147           -> IO [ModSummary]
1148 downsweep hsc_env old_summaries excl_mods
1149    = do rootSummaries <- mapM getRootSummary roots
1150         checkDuplicates rootSummaries
1151         loop (concatMap msDeps rootSummaries)
1152              (mkNodeMap rootSummaries)
1153      where
1154         roots = hsc_targets hsc_env
1155
1156         old_summary_map :: NodeMap ModSummary
1157         old_summary_map = mkNodeMap old_summaries
1158
1159         getRootSummary :: Target -> IO ModSummary
1160         getRootSummary (Target (TargetFile file) maybe_buf)
1161            = do exists <- doesFileExist file
1162                 if exists then summariseFile hsc_env file maybe_buf else do
1163                 throwDyn (CmdLineError ("can't find file: " ++ file))
1164         getRootSummary (Target (TargetModule modl) maybe_buf)
1165            = do maybe_summary <- summarise hsc_env emptyNodeMap Nothing False
1166                                            modl maybe_buf excl_mods
1167                 case maybe_summary of
1168                    Nothing -> packageModErr modl
1169                    Just s  -> return s
1170
1171         -- In a root module, the filename is allowed to diverge from the module
1172         -- name, so we have to check that there aren't multiple root files
1173         -- defining the same module (otherwise the duplicates will be silently
1174         -- ignored, leading to confusing behaviour).
1175         checkDuplicates :: [ModSummary] -> IO ()
1176         checkDuplicates summaries = mapM_ check summaries
1177           where check summ =
1178                   case dups of
1179                         []     -> return ()
1180                         [_one] -> return ()
1181                         many   -> multiRootsErr modl many
1182                    where modl = ms_mod summ
1183                          dups =
1184                            [ expectJust "checkDup" (ml_hs_file (ms_location summ'))
1185                            | summ' <- summaries, ms_mod summ' == modl ]
1186
1187         loop :: [(FilePath,Module,IsBootInterface)]
1188                         -- Work list: process these modules
1189              -> NodeMap ModSummary
1190                         -- Visited set
1191              -> IO [ModSummary]
1192                         -- The result includes the worklist, except
1193                         -- for those mentioned in the visited set
1194         loop [] done      = return (nodeMapElts done)
1195         loop ((cur_path, wanted_mod, is_boot) : ss) done
1196           | key `elemFM` done = loop ss done
1197           | otherwise         = do { mb_s <- summarise hsc_env old_summary_map
1198                                                  (Just cur_path) is_boot
1199                                                  wanted_mod Nothing excl_mods
1200                                    ; case mb_s of
1201                                         Nothing -> loop ss done
1202                                         Just s  -> loop (msDeps s ++ ss)
1203                                                         (addToFM done key s) }
1204           where
1205             key = (wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1206
1207 msDeps :: ModSummary -> [(FilePath,             -- Importing module
1208                           Module,               -- Imported module
1209                           IsBootInterface)]      -- {-# SOURCE #-} import or not
1210 -- (msDeps s) returns the dependencies of the ModSummary s.
1211 -- A wrinkle is that for a {-# SOURCE #-} import we return
1212 --      *both* the hs-boot file
1213 --      *and* the source file
1214 -- as "dependencies".  That ensures that the list of all relevant
1215 -- modules always contains B.hs if it contains B.hs-boot.
1216 -- Remember, this pass isn't doing the topological sort.  It's
1217 -- just gathering the list of all relevant ModSummaries
1218 msDeps s =  concat [ [(f, m, True), (f,m,False)] | m <- ms_srcimps s]
1219          ++ [(f,m,False) | m <- ms_imps    s]
1220         where
1221           f = msHsFilePath s    -- Keep the importing module for error reporting
1222
1223
1224 -----------------------------------------------------------------------------
1225 -- Summarising modules
1226
1227 -- We have two types of summarisation:
1228 --
1229 --    * Summarise a file.  This is used for the root module(s) passed to
1230 --      cmLoadModules.  The file is read, and used to determine the root
1231 --      module name.  The module name may differ from the filename.
1232 --
1233 --    * Summarise a module.  We are given a module name, and must provide
1234 --      a summary.  The finder is used to locate the file in which the module
1235 --      resides.
1236
1237 summariseFile :: HscEnv -> FilePath
1238    -> Maybe (StringBuffer,ClockTime)
1239    -> IO ModSummary
1240 -- Used for Haskell source only, I think
1241 -- We know the file name, and we know it exists,
1242 -- but we don't necessarily know the module name (might differ)
1243 summariseFile hsc_env file maybe_buf
1244    = do let dflags = hsc_dflags hsc_env
1245
1246         (dflags', hspp_fn, buf)
1247             <- preprocessFile dflags file maybe_buf
1248
1249         (srcimps,the_imps,mod) <- getImports dflags' buf hspp_fn
1250
1251         -- Make a ModLocation for this file
1252         location <- mkHomeModLocation dflags mod file
1253
1254         -- Tell the Finder cache where it is, so that subsequent calls
1255         -- to findModule will find it, even if it's not on any search path
1256         addHomeModuleToFinder hsc_env mod location
1257
1258         src_timestamp <- case maybe_buf of
1259                            Just (_,t) -> return t
1260                            Nothing    -> getModificationTime file
1261
1262         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1263
1264         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1265                              ms_location = location,
1266                              ms_hspp_file = Just hspp_fn,
1267                              ms_hspp_buf  = Just buf,
1268                              ms_srcimps = srcimps, ms_imps = the_imps,
1269                              ms_hs_date = src_timestamp,
1270                              ms_obj_date = obj_timestamp })
1271
1272 -- Summarise a module, and pick up source and timestamp.
1273 summarise :: HscEnv
1274           -> NodeMap ModSummary -- Map of old summaries
1275           -> Maybe FilePath     -- Importing module (for error messages)
1276           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1277           -> Module             -- Imported module to be summarised
1278           -> Maybe (StringBuffer, ClockTime)
1279           -> [Module]           -- Modules to exclude
1280           -> IO (Maybe ModSummary)      -- Its new summary
1281
1282 summarise hsc_env old_summary_map cur_mod is_boot wanted_mod maybe_buf excl_mods
1283   | wanted_mod `elem` excl_mods
1284   = return Nothing
1285
1286   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1287   = do          -- Find its new timestamp; all the
1288                 -- ModSummaries in the old map have valid ml_hs_files
1289         let location = ms_location old_summary
1290             src_fn = expectJust "summarise" (ml_hs_file location)
1291
1292                 -- return the cached summary if the source didn't change
1293         src_timestamp <- case maybe_buf of
1294                            Just (_,t) -> return t
1295                            Nothing    -> getModificationTime src_fn
1296
1297         if ms_hs_date old_summary == src_timestamp
1298            then do -- update the object-file timestamp
1299                   obj_timestamp <- getObjTimestamp location is_boot
1300                   return (Just old_summary{ ms_obj_date = obj_timestamp })
1301            else
1302                 -- source changed: re-summarise
1303                 new_summary location src_fn maybe_buf src_timestamp
1304
1305   | otherwise
1306   = do  found <- findModule hsc_env wanted_mod True {-explicit-}
1307         case found of
1308              Found location pkg
1309                 | not (isHomePackage pkg) -> return Nothing
1310                         -- Drop external-pkg
1311                 | isJust (ml_hs_file location) -> just_found location
1312                         -- Home package
1313              err -> noModError dflags cur_mod wanted_mod err
1314                         -- Not found
1315   where
1316     dflags = hsc_dflags hsc_env
1317
1318     hsc_src = if is_boot then HsBootFile else HsSrcFile
1319
1320     just_found location = do
1321                 -- Adjust location to point to the hs-boot source file,
1322                 -- hi file, object file, when is_boot says so
1323         let location' | is_boot   = addBootSuffixLocn location
1324                       | otherwise = location
1325             src_fn = expectJust "summarise2" (ml_hs_file location')
1326
1327                 -- Check that it exists
1328                 -- It might have been deleted since the Finder last found it
1329         maybe_t <- modificationTimeIfExists src_fn
1330         case maybe_t of
1331           Nothing -> noHsFileErr cur_mod src_fn
1332           Just t  -> new_summary location' src_fn Nothing t
1333
1334
1335     new_summary location src_fn maybe_bug src_timestamp
1336       = do
1337         -- Preprocess the source file and get its imports
1338         -- The dflags' contains the OPTIONS pragmas
1339         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn maybe_buf
1340         (srcimps, the_imps, mod_name) <- getImports dflags' buf hspp_fn
1341
1342         when (mod_name /= wanted_mod) $
1343                 throwDyn (ProgramError
1344                    (showSDoc (text src_fn
1345                               <>  text ": file name does not match module name"
1346                               <+> quotes (ppr mod_name))))
1347
1348                 -- Find the object timestamp, and return the summary
1349         obj_timestamp <- getObjTimestamp location is_boot
1350
1351         return (Just ( ModSummary { ms_mod       = wanted_mod,
1352                                     ms_hsc_src   = hsc_src,
1353                                     ms_location  = location,
1354                                     ms_hspp_file = Just hspp_fn,
1355                                     ms_hspp_buf  = Just buf,
1356                                     ms_srcimps   = srcimps,
1357                                     ms_imps      = the_imps,
1358                                     ms_hs_date   = src_timestamp,
1359                                     ms_obj_date  = obj_timestamp }))
1360
1361
1362 getObjTimestamp location is_boot
1363   = if is_boot then return Nothing
1364                else modificationTimeIfExists (ml_obj_file location)
1365
1366
1367 preprocessFile :: DynFlags -> FilePath -> Maybe (StringBuffer,ClockTime)
1368   -> IO (DynFlags, FilePath, StringBuffer)
1369 preprocessFile dflags src_fn Nothing
1370   = do
1371         (dflags', hspp_fn) <- preprocess dflags src_fn
1372         buf <- hGetStringBuffer hspp_fn
1373         return (dflags', hspp_fn, buf)
1374
1375 preprocessFile dflags src_fn (Just (buf, time))
1376   = do
1377         -- case we bypass the preprocessing stage?
1378         let
1379             local_opts = getOptionsFromStringBuffer buf
1380         --
1381         (dflags', errs) <- parseDynamicFlags dflags local_opts
1382
1383         let
1384             needs_preprocessing
1385                 | Unlit _ <- startPhase src_fn  = True
1386                   -- note: local_opts is only required if there's no Unlit phase
1387                 | dopt Opt_Cpp dflags'          = True
1388                 | dopt Opt_Pp  dflags'          = True
1389                 | otherwise                     = False
1390
1391         when needs_preprocessing $
1392            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1393
1394         return (dflags', "<buffer>", buf)
1395
1396
1397 -----------------------------------------------------------------------------
1398 --                      Error messages
1399 -----------------------------------------------------------------------------
1400
1401 noModError :: DynFlags -> Maybe FilePath -> Module -> FindResult -> IO ab
1402 -- ToDo: we don't have a proper line number for this error
1403 noModError dflags cur_mod wanted_mod err
1404   = throwDyn $ ProgramError $ showSDoc $
1405     vcat [cantFindError dflags wanted_mod err,
1406           nest 2 (parens (pp_where cur_mod))]
1407
1408 noHsFileErr cur_mod path
1409   = throwDyn $ CmdLineError $ showSDoc $
1410     vcat [text "Can't find" <+> text path,
1411           nest 2 (parens (pp_where cur_mod))]
1412
1413 pp_where Nothing  = text "one of the roots of the dependency analysis"
1414 pp_where (Just p) = text "imported from" <+> text p
1415
1416 packageModErr mod
1417   = throwDyn (CmdLineError (showSDoc (text "module" <+>
1418                                    quotes (ppr mod) <+>
1419                                    text "is a package module")))
1420
1421 multiRootsErr mod files
1422   = throwDyn (ProgramError (showSDoc (
1423         text "module" <+> quotes (ppr mod) <+>
1424         text "is defined in multiple files:" <+>
1425         sep (map text files))))
1426
1427 cyclicModuleErr :: [ModSummary] -> SDoc
1428 cyclicModuleErr ms
1429   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1430        2 (vcat (map show_one ms))
1431   where
1432     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1433                         nest 2 $ ptext SLIT("imports:") <+>
1434                                    (pp_imps HsBootFile (ms_srcimps ms)
1435                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1436     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1437     pp_imps src mods = fsep (map (show_mod src) mods)
1438
1439
1440 -- | Inform GHC that the working directory has changed.  GHC will flush
1441 -- its cache of module locations, since it may no longer be valid.
1442 -- Note: if you change the working directory, you should also unload
1443 -- the current program (set targets to empty, followed by load).
1444 workingDirectoryChanged :: Session -> IO ()
1445 workingDirectoryChanged s = withSession s $ \hsc_env ->
1446   flushFinderCache (hsc_FC hsc_env)
1447
1448 -- -----------------------------------------------------------------------------
1449 -- inspecting the session
1450
1451 -- | Get the module dependency graph.
1452 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1453 getModuleGraph s = withSession s (return . hsc_mod_graph)
1454
1455 isLoaded :: Session -> Module -> IO Bool
1456 isLoaded s m = withSession s $ \hsc_env ->
1457   return $! isJust (lookupModuleEnv (hsc_HPT hsc_env) m)
1458
1459 getBindings :: Session -> IO [TyThing]
1460 getBindings s = withSession s (return . nameEnvElts . ic_type_env . hsc_IC)
1461
1462 getPrintUnqual :: Session -> IO PrintUnqualified
1463 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1464
1465 #ifdef GHCI
1466 -- | Parses a string as an identifier, and returns the list of 'Name's that
1467 -- the identifier can refer to in the current interactive context.
1468 parseName :: Session -> String -> IO [Name]
1469 parseName s str = withSession s $ \hsc_env -> do
1470    maybe_rdr_name <- hscParseIdentifier (hsc_dflags hsc_env) str
1471    case maybe_rdr_name of
1472         Nothing -> return []
1473         Just (L _ rdr_name) -> do
1474             mb_names <- tcRnLookupRdrName hsc_env rdr_name
1475             case mb_names of
1476                 Nothing -> return []
1477                 Just ns -> return ns
1478                 -- ToDo: should return error messages
1479 #endif
1480
1481 -- | Returns the 'TyThing' for a 'Name'.  The 'Name' may refer to any
1482 -- entity known to GHC, including 'Name's defined using 'runStmt'.
1483 lookupName :: Session -> Name -> IO (Maybe TyThing)
1484 lookupName s name = withSession s $ \hsc_env -> do
1485   case lookupTypeEnv (ic_type_env (hsc_IC hsc_env)) name of
1486         Just tt -> return (Just tt)
1487         Nothing -> do
1488             eps <- readIORef (hsc_EPS hsc_env)
1489             return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1490
1491 -- | Container for information about a 'Module'.
1492 data ModuleInfo = ModuleInfo {
1493         minf_details  :: ModDetails,
1494         minf_rdr_env  :: Maybe GlobalRdrEnv
1495   }
1496         -- ToDo: this should really contain the ModIface too
1497         -- We don't want HomeModInfo here, because a ModuleInfo applies
1498         -- to package modules too.
1499
1500 -- | Request information about a loaded 'Module'
1501 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1502 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1503   case lookupModuleEnv (hsc_HPT hsc_env) mdl of
1504     Nothing  -> return Nothing
1505     Just hmi ->
1506         return (Just (ModuleInfo {
1507                         minf_details = hm_details hmi,
1508                         minf_rdr_env = mi_globals $! hm_iface hmi
1509                         }))
1510
1511         -- ToDo: we should be able to call getModuleInfo on a package module,
1512         -- even one that isn't loaded yet.
1513
1514 -- | The list of top-level entities defined in a module
1515 modInfoTyThings :: ModuleInfo -> [TyThing]
1516 modInfoTyThings minf = typeEnvElts (md_types (minf_details minf))
1517
1518 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1519 modInfoTopLevelScope minf
1520   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1521
1522 modInfoExports :: ModuleInfo -> [Name]
1523 modInfoExports minf = nameSetToList $! (md_exports $! minf_details minf)
1524
1525 isDictonaryId :: Id -> Bool
1526 isDictonaryId id
1527   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1528
1529 #if 0
1530
1531 data ObjectCode
1532   = ByteCode
1533   | BinaryCode FilePath
1534
1535 type TypecheckedCode = HsTypecheckedGroup
1536 type RenamedCode     = [HsGroup Name]
1537
1538 -- ToDo: typechecks abstract syntax or renamed abstract syntax.  Issues:
1539 --   - typechecked syntax includes extra dictionary translation and
1540 --     AbsBinds which need to be translated back into something closer to
1541 --     the original source.
1542 --   - renamed syntax currently doesn't exist in a single blob, since
1543 --     renaming and typechecking are interleaved at splice points.  We'd
1544 --     need a restriction that there are no splices in the source module.
1545
1546 -- ToDo:
1547 --   - Data and Typeable instances for HsSyn.
1548
1549 -- ToDo:
1550 --   - things that aren't in the output of the renamer:
1551 --     - the export list
1552 --     - the imports
1553
1554 -- ToDo:
1555 --   - things that aren't in the output of the typechecker right now:
1556 --     - the export list
1557 --     - the imports
1558 --     - type signatures
1559 --     - type/data/newtype declarations
1560 --     - class declarations
1561 --     - instances
1562 --   - extra things in the typechecker's output:
1563 --     - default methods are turned into top-level decls.
1564 --     - dictionary bindings
1565
1566 -- ToDo: check for small transformations that happen to the syntax in
1567 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1568
1569 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1570 -- to get from TyCons, Ids etc. to TH syntax (reify).
1571
1572 -- :browse will use either lm_toplev or inspect lm_interface, depending
1573 -- on whether the module is interpreted or not.
1574
1575 -- various abstract syntax types (perhaps IfaceBlah)
1576 data Type = ...
1577 data Kind = ...
1578
1579 -- This is for reconstructing refactored source code
1580 -- Calls the lexer repeatedly.
1581 -- ToDo: add comment tokens to token stream
1582 getTokenStream :: Session -> Module -> IO [Located Token]
1583 #endif
1584
1585 -- -----------------------------------------------------------------------------
1586 -- Interactive evaluation
1587
1588 #ifdef GHCI
1589
1590 -- | Set the interactive evaluation context.
1591 --
1592 -- Setting the context doesn't throw away any bindings; the bindings
1593 -- we've built up in the InteractiveContext simply move to the new
1594 -- module.  They always shadow anything in scope in the current context.
1595 setContext :: Session
1596            -> [Module]  -- entire top level scope of these modules
1597            -> [Module]  -- exports only of these modules
1598            -> IO ()
1599 setContext (Session ref) toplevs exports = do
1600   hsc_env <- readIORef ref
1601   let old_ic  = hsc_IC     hsc_env
1602       hpt     = hsc_HPT    hsc_env
1603
1604   mapM_ (checkModuleExists hsc_env hpt) exports
1605   export_env  <- mkExportEnv hsc_env exports
1606   toplev_envs <- mapM (mkTopLevEnv hpt) toplevs
1607   let all_env = foldr plusGlobalRdrEnv export_env toplev_envs
1608   writeIORef ref hsc_env{ hsc_IC = old_ic { ic_toplev_scope = toplevs,
1609                                             ic_exports      = exports,
1610                                             ic_rn_gbl_env   = all_env } }
1611
1612 checkModuleExists :: HscEnv -> HomePackageTable -> Module -> IO ()
1613 checkModuleExists hsc_env hpt mod =
1614   case lookupModuleEnv hpt mod of
1615     Just mod_info -> return ()
1616     _not_a_home_module -> do
1617           res <- findPackageModule hsc_env mod True
1618           case res of
1619             Found _ _ -> return  ()
1620             err -> let msg = cantFindError (hsc_dflags hsc_env) mod err in
1621                    throwDyn (CmdLineError (showSDoc msg))
1622
1623 mkTopLevEnv :: HomePackageTable -> Module -> IO GlobalRdrEnv
1624 mkTopLevEnv hpt modl
1625  = case lookupModuleEnv hpt modl of
1626       Nothing ->
1627          throwDyn (ProgramError ("mkTopLevEnv: not a home module "
1628                         ++ showSDoc (pprModule modl)))
1629       Just details ->
1630          case mi_globals (hm_iface details) of
1631                 Nothing  ->
1632                    throwDyn (ProgramError ("mkTopLevEnv: not interpreted "
1633                                                 ++ showSDoc (pprModule modl)))
1634                 Just env -> return env
1635
1636 -- | Get the interactive evaluation context, consisting of a pair of the
1637 -- set of modules from which we take the full top-level scope, and the set
1638 -- of modules from which we take just the exports respectively.
1639 getContext :: Session -> IO ([Module],[Module])
1640 getContext s = withSession s (\HscEnv{ hsc_IC=ic } ->
1641                                 return (ic_toplev_scope ic, ic_exports ic))
1642
1643 -- | Returns 'True' if the specified module is interpreted, and hence has
1644 -- its full top-level scope available.
1645 moduleIsInterpreted :: Session -> Module -> IO Bool
1646 moduleIsInterpreted s modl = withSession s $ \h ->
1647  case lookupModuleEnv (hsc_HPT h) modl of
1648       Just details       -> return (isJust (mi_globals (hm_iface details)))
1649       _not_a_home_module -> return False
1650
1651 -- | Looks up an identifier in the current interactive context (for :info)
1652 {-# DEPRECATED getInfo "we should be using parseName/lookupName instead" #-}
1653 getInfo :: Session -> String -> IO [GetInfoResult]
1654 getInfo s id = withSession s $ \hsc_env -> hscGetInfo hsc_env id
1655
1656 -- | Returns all names in scope in the current interactive context
1657 getNamesInScope :: Session -> IO [Name]
1658 getNamesInScope s = withSession s $ \hsc_env -> do
1659   return (map gre_name (globalRdrEnvElts (ic_rn_gbl_env (hsc_IC hsc_env))))
1660
1661 -- -----------------------------------------------------------------------------
1662 -- Getting the type of an expression
1663
1664 -- | Get the type of an expression
1665 exprType :: Session -> String -> IO (Maybe Type)
1666 exprType s expr = withSession s $ \hsc_env -> do
1667    maybe_stuff <- hscTcExpr hsc_env expr
1668    case maybe_stuff of
1669         Nothing -> return Nothing
1670         Just ty -> return (Just tidy_ty)
1671              where
1672                 tidy_ty = tidyType emptyTidyEnv ty
1673                 dflags  = hsc_dflags hsc_env
1674
1675 -- -----------------------------------------------------------------------------
1676 -- Getting the kind of a type
1677
1678 -- | Get the kind of a  type
1679 typeKind  :: Session -> String -> IO (Maybe Kind)
1680 typeKind s str = withSession s $ \hsc_env -> do
1681    maybe_stuff <- hscKcType hsc_env str
1682    case maybe_stuff of
1683         Nothing -> return Nothing
1684         Just kind -> return (Just kind)
1685
1686 -----------------------------------------------------------------------------
1687 -- cmCompileExpr: compile an expression and deliver an HValue
1688
1689 compileExpr :: Session -> String -> IO (Maybe HValue)
1690 compileExpr s expr = withSession s $ \hsc_env -> do
1691   maybe_stuff <- hscStmt hsc_env ("let __cmCompileExpr = "++expr)
1692   case maybe_stuff of
1693         Nothing -> return Nothing
1694         Just (new_ic, names, hval) -> do
1695                         -- Run it!
1696                 hvals <- (unsafeCoerce# hval) :: IO [HValue]
1697
1698                 case (names,hvals) of
1699                   ([n],[hv]) -> return (Just hv)
1700                   _          -> panic "compileExpr"
1701
1702 -- -----------------------------------------------------------------------------
1703 -- running a statement interactively
1704
1705 data RunResult
1706   = RunOk [Name]                -- ^ names bound by this evaluation
1707   | RunFailed                   -- ^ statement failed compilation
1708   | RunException Exception      -- ^ statement raised an exception
1709
1710 -- | Run a statement in the current interactive context.  Statemenet
1711 -- may bind multple values.
1712 runStmt :: Session -> String -> IO RunResult
1713 runStmt (Session ref) expr
1714    = do
1715         hsc_env <- readIORef ref
1716
1717         -- Turn off -fwarn-unused-bindings when running a statement, to hide
1718         -- warnings about the implicit bindings we introduce.
1719         let dflags'  = dopt_unset (hsc_dflags hsc_env) Opt_WarnUnusedBinds
1720             hsc_env' = hsc_env{ hsc_dflags = dflags' }
1721
1722         maybe_stuff <- hscStmt hsc_env' expr
1723
1724         case maybe_stuff of
1725            Nothing -> return RunFailed
1726            Just (new_hsc_env, names, hval) -> do
1727
1728                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
1729                 either_hvals <- sandboxIO thing_to_run
1730
1731                 case either_hvals of
1732                     Left e -> do
1733                         -- on error, keep the *old* interactive context,
1734                         -- so that 'it' is not bound to something
1735                         -- that doesn't exist.
1736                         return (RunException e)
1737
1738                     Right hvals -> do
1739                         -- Get the newly bound things, and bind them.
1740                         -- Don't need to delete any shadowed bindings;
1741                         -- the new ones override the old ones.
1742                         extendLinkEnv (zip names hvals)
1743
1744                         writeIORef ref new_hsc_env
1745                         return (RunOk names)
1746
1747
1748 -- We run the statement in a "sandbox" to protect the rest of the
1749 -- system from anything the expression might do.  For now, this
1750 -- consists of just wrapping it in an exception handler, but see below
1751 -- for another version.
1752
1753 sandboxIO :: IO a -> IO (Either Exception a)
1754 sandboxIO thing = Exception.try thing
1755
1756 {-
1757 -- This version of sandboxIO runs the expression in a completely new
1758 -- RTS main thread.  It is disabled for now because ^C exceptions
1759 -- won't be delivered to the new thread, instead they'll be delivered
1760 -- to the (blocked) GHCi main thread.
1761
1762 -- SLPJ: when re-enabling this, reflect a wrong-stat error as an exception
1763
1764 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
1765 sandboxIO thing = do
1766   st_thing <- newStablePtr (Exception.try thing)
1767   alloca $ \ p_st_result -> do
1768     stat <- rts_evalStableIO st_thing p_st_result
1769     freeStablePtr st_thing
1770     if stat == 1
1771         then do st_result <- peek p_st_result
1772                 result <- deRefStablePtr st_result
1773                 freeStablePtr st_result
1774                 return (Right result)
1775         else do
1776                 return (Left (fromIntegral stat))
1777
1778 foreign import "rts_evalStableIO"  {- safe -}
1779   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
1780   -- more informative than the C type!
1781 -}
1782
1783 -- ---------------------------------------------------------------------------
1784 -- cmBrowseModule: get all the TyThings defined in a module
1785
1786 {-# DEPRECATED browseModule "we should be using getModuleInfo instead" #-}
1787 browseModule :: Session -> Module -> Bool -> IO [IfaceDecl]
1788 browseModule s modl exports_only = withSession s $ \hsc_env -> do
1789   mb_decls <- getModuleContents hsc_env modl exports_only
1790   case mb_decls of
1791         Nothing -> return []            -- An error of some kind
1792         Just ds -> return ds
1793
1794
1795 -----------------------------------------------------------------------------
1796 -- show a module and it's source/object filenames
1797
1798 showModule :: Session -> ModSummary -> IO String
1799 showModule s mod_summary = withSession s $ \hsc_env -> do
1800   case lookupModuleEnv (hsc_HPT hsc_env) (ms_mod mod_summary) of
1801         Nothing       -> panic "missing linkable"
1802         Just mod_info -> return (showModMsg obj_linkable mod_summary)
1803                       where
1804                          obj_linkable = isObjectLinkable (fromJust (hm_linkable mod_info))
1805
1806 #endif /* GHCI */