ghc/compiler/main/GHC.hs

   1 -- -----------------------------------------------------------------------------
   2 --
   3 -- (c) The University of Glasgow, 2005
   4 --
   5 -- The GHC API
   6 --
   7 -- -----------------------------------------------------------------------------
   8
   9 module GHC (
  10         -- * Initialisation
  11         Session,
  12         defaultErrorHandler,
  13         defaultCleanupHandler,
  14         init,
  15         newSession,
  16
  17         -- * Flags and settings
  18         DynFlags(..), DynFlag(..), GhcMode(..), HscTarget(..), dopt,
  19         parseDynamicFlags,
  20         initPackages,
  21         getSessionDynFlags,
  22         setSessionDynFlags,
  23         setMsgHandler,
  24
  25         -- * Targets
  26         Target(..), TargetId(..), Phase,
  27         setTargets,
  28         getTargets,
  29         addTarget,
  30         removeTarget,
  31         guessTarget,
  32
  33         -- * Loading\/compiling the program
  34         depanal,
  35         load, LoadHowMuch(..), SuccessFlag(..), -- also does depanal
  36         loadMsgs,
  37         workingDirectoryChanged,
  38         checkModule, CheckedModule(..),
  39         TypecheckedSource, ParsedSource, RenamedSource,
  40
  41         -- * Inspecting the module structure of the program
  42         ModuleGraph, ModSummary(..),
  43         getModuleGraph,
  44         isLoaded,
  45         topSortModuleGraph,
  46
  47         -- * Inspecting modules
  48         ModuleInfo,
  49         getModuleInfo,
  50         modInfoTyThings,
  51         modInfoTopLevelScope,
  52         modInfoPrintUnqualified,
  53         modInfoExports,
  54         modInfoInstances,
  55         modInfoIsExportedName,
  56         modInfoLookupName,
  57         lookupGlobalName,
  58
  59         -- * Interactive evaluation
  60         getBindings, getPrintUnqual,
  61 #ifdef GHCI
  62         setContext, getContext,
  63         getNamesInScope,
  64         moduleIsInterpreted,
  65         getInfo, GetInfoResult,
  66         exprType,
  67         typeKind,
  68         parseName,
  69         RunResult(..),
  70         runStmt,
  71         browseModule,
  72         showModule,
  73         compileExpr, HValue,
  74         lookupName,
  75 #endif
  76
  77         -- * Abstract syntax elements
  78
  79         -- ** Modules
  80         Module, mkModule, pprModule,
  81
  82         -- ** Names
  83         Name, nameModule,
  84
  85         -- ** Identifiers
  86         Id, idType,
  87         isImplicitId, isDeadBinder,
  88         isSpecPragmaId, isExportedId, isLocalId, isGlobalId,
  89         isRecordSelector,
  90         isPrimOpId, isFCallId,
  91         isDataConWorkId, idDataCon,
  92         isBottomingId, isDictonaryId,
  93
  94         -- ** Type constructors
  95         TyCon,
  96         isClassTyCon, isSynTyCon, isNewTyCon,
  97
  98         -- ** Data constructors
  99         DataCon,
 100
 101         -- ** Classes
 102         Class,
 103         classSCTheta, classTvsFds,
 104
 105         -- ** Instances
 106         Instance,
 107
 108         -- ** Types and Kinds
 109         Type, dropForAlls,
 110         Kind,
 111
 112         -- ** Entities
 113         TyThing(..),
 114
 115         -- ** Syntax
 116         module HsSyn, -- ToDo: remove extraneous bits
 117
 118         -- * Exceptions
 119         GhcException(..), showGhcException,
 120
 121         -- * Miscellaneous
 122         sessionHscEnv,
 123         cyclicModuleErr,
 124   ) where
 125
 126 {-
 127  ToDo:
 128
 129   * inline bits of HscMain here to simplify layering: hscGetInfo,
 130     hscTcExpr, hscStmt.
 131   * we need to expose DynFlags, so should parseDynamicFlags really be
 132     part of this interface?
 133   * what StaticFlags should we expose, if any?
 134 -}
 135
 136 #include "HsVersions.h"
 137
 138 #ifdef GHCI
 139 import qualified Linker
 140 import Linker           ( HValue, extendLinkEnv )
 141 import TcRnDriver       ( getModuleContents, tcRnLookupRdrName,
 142                           getModuleExports )
 143 import RdrName          ( plusGlobalRdrEnv, Provenance(..),
 144                           ImportSpec(..), ImpDeclSpec(..), ImpItemSpec(..),
 145                           emptyGlobalRdrEnv, mkGlobalRdrEnv )
 146 import HscMain          ( hscGetInfo, GetInfoResult, hscParseIdentifier,
 147                           hscStmt, hscTcExpr, hscKcType )
 148 import Type             ( tidyType )
 149 import VarEnv           ( emptyTidyEnv )
 150 import GHC.Exts         ( unsafeCoerce# )
 151 import IfaceSyn         ( IfaceDecl )
 152 #endif
 153
 154 import Packages         ( initPackages, isHomeModule )
 155 import NameSet          ( NameSet, nameSetToList, elemNameSet )
 156 import RdrName          ( GlobalRdrEnv, GlobalRdrElt(..), RdrName,
 157                           globalRdrEnvElts )
 158 import HsSyn
 159 import Type             ( Kind, Type, dropForAlls )
 160 import Id               ( Id, idType, isImplicitId, isDeadBinder,
 161                           isSpecPragmaId, isExportedId, isLocalId, isGlobalId,
 162                           isRecordSelector,
 163                           isPrimOpId, isFCallId,
 164                           isDataConWorkId, idDataCon,
 165                           isBottomingId )
 166 import TyCon            ( TyCon, isClassTyCon, isSynTyCon, isNewTyCon )
 167 import Class            ( Class, classSCTheta, classTvsFds )
 168 import DataCon          ( DataCon )
 169 import Name             ( Name, nameModule )
 170 import NameEnv          ( nameEnvElts )
 171 import InstEnv          ( Instance )
 172 import SrcLoc
 173 import DriverPipeline
 174 import DriverPhases     ( Phase(..), isHaskellSrcFilename, startPhase )
 175 import GetImports       ( getImports )
 176 import Packages         ( isHomePackage )
 177 import Finder
 178 import HscMain          ( newHscEnv, hscFileCheck, HscResult(..) )
 179 import HscTypes
 180 import DynFlags
 181 import StaticFlags
 182 import SysTools         ( initSysTools, cleanTempFiles )
 183 import Module
 184 import FiniteMap
 185 import Panic
 186 import Digraph
 187 import Bag              ( unitBag, emptyBag )
 188 import ErrUtils         ( showPass, Messages, putMsg, debugTraceMsg,
 189                           mkPlainErrMsg, pprBagOfErrors )
 190 import qualified ErrUtils
 191 import Util
 192 import StringBuffer     ( StringBuffer, hGetStringBuffer )
 193 import Outputable
 194 import SysTools         ( cleanTempFilesExcept )
 195 import BasicTypes       ( SuccessFlag(..), succeeded, failed )
 196 import TcType           ( tcSplitSigmaTy, isDictTy )
 197 import FastString       ( mkFastString )
 198
 199 import Directory        ( getModificationTime, doesFileExist )
 200 import Maybe            ( isJust, isNothing, fromJust )
 201 import Maybes           ( orElse, expectJust, mapCatMaybes )
 202 import List             ( partition, nub )
 203 import qualified List
 204 import Monad            ( unless, when )
 205 import System           ( exitWith, ExitCode(..) )
 206 import Time             ( ClockTime )
 207 import EXCEPTION as Exception hiding (handle)
 208 import DATA_IOREF
 209 import IO
 210 import Prelude hiding (init)
 211
 212 -- -----------------------------------------------------------------------------
 213 -- Exception handlers
 214
 215 -- | Install some default exception handlers and run the inner computation.
 216 -- Unless you want to handle exceptions yourself, you should wrap this around
 217 -- the top level of your program.  The default handlers output the error
 218 -- message(s) to stderr and exit cleanly.
 219 defaultErrorHandler :: IO a -> IO a
 220 defaultErrorHandler inner =
 221   -- top-level exception handler: any unrecognised exception is a compiler bug.
 222   handle (\exception -> do
 223            hFlush stdout
 224            case exception of
 225                 -- an IO exception probably isn't our fault, so don't panic
 226                 IOException _ ->  putMsg (show exception)
 227                 AsyncException StackOverflow ->
 228                         putMsg "stack overflow: use +RTS -K<size> to increase it"
 229                 _other ->  putMsg (show (Panic (show exception)))
 230            exitWith (ExitFailure 1)
 231          ) $
 232
 233   -- program errors: messages with locations attached.  Sometimes it is
 234   -- convenient to just throw these as exceptions.
 235   handleDyn (\dyn -> do printErrs (pprBagOfErrors (unitBag dyn))
 236                         exitWith (ExitFailure 1)) $
 237
 238   -- error messages propagated as exceptions
 239   handleDyn (\dyn -> do
 240                 hFlush stdout
 241                 case dyn of
 242                      PhaseFailed _ code -> exitWith code
 243                      Interrupted -> exitWith (ExitFailure 1)
 244                      _ -> do putMsg (show (dyn :: GhcException))
 245                              exitWith (ExitFailure 1)
 246             ) $
 247   inner
 248
 249 -- | Install a default cleanup handler to remove temporary files
 250 -- deposited by a GHC run.  This is seperate from
 251 -- 'defaultErrorHandler', because you might want to override the error
 252 -- handling, but still get the ordinary cleanup behaviour.
 253 defaultCleanupHandler :: DynFlags -> IO a -> IO a
 254 defaultCleanupHandler dflags inner =
 255    -- make sure we clean up after ourselves
 256    later (unless (dopt Opt_KeepTmpFiles dflags) $
 257             cleanTempFiles dflags)
 258         -- exceptions will be blocked while we clean the temporary files,
 259         -- so there shouldn't be any difficulty if we receive further
 260         -- signals.
 261    inner
 262
 263
 264 -- | Initialises GHC.  This must be done /once/ only.  Takes the
 265 -- command-line arguments.  All command-line arguments which aren't
 266 -- understood by GHC will be returned.
 267
 268 init :: [String] -> IO [String]
 269 init args = do
 270    -- catch ^C
 271    installSignalHandlers
 272
 273    -- Grab the -B option if there is one
 274    let (minusB_args, argv1) = partition (prefixMatch "-B") args
 275    dflags0 <- initSysTools minusB_args defaultDynFlags
 276    writeIORef v_initDynFlags dflags0
 277
 278    -- Parse the static flags
 279    argv2 <- parseStaticFlags argv1
 280    return argv2
 281
 282 GLOBAL_VAR(v_initDynFlags, error "initDynFlags", DynFlags)
 283         -- stores the DynFlags between the call to init and subsequent
 284         -- calls to newSession.
 285
 286 -- | Starts a new session.  A session consists of a set of loaded
 287 -- modules, a set of options (DynFlags), and an interactive context.
 288 -- ToDo: GhcMode should say "keep typechecked code" and\/or "keep renamed
 289 -- code".
 290 newSession :: GhcMode -> IO Session
 291 newSession mode = do
 292   dflags0 <- readIORef v_initDynFlags
 293   dflags <- initDynFlags dflags0
 294   env <- newHscEnv dflags{ ghcMode=mode }
 295   ref <- newIORef env
 296   return (Session ref)
 297
 298 -- tmp: this breaks the abstraction, but required because DriverMkDepend
 299 -- needs to call the Finder.  ToDo: untangle this.
 300 sessionHscEnv :: Session -> IO HscEnv
 301 sessionHscEnv (Session ref) = readIORef ref
 302
 303 withSession :: Session -> (HscEnv -> IO a) -> IO a
 304 withSession (Session ref) f = do h <- readIORef ref; f h
 305
 306 modifySession :: Session -> (HscEnv -> HscEnv) -> IO ()
 307 modifySession (Session ref) f = do h <- readIORef ref; writeIORef ref $! f h
 308
 309 -- -----------------------------------------------------------------------------
 310 -- Flags & settings
 311
 312 -- | Grabs the DynFlags from the Session
 313 getSessionDynFlags :: Session -> IO DynFlags
 314 getSessionDynFlags s = withSession s (return . hsc_dflags)
 315
 316 -- | Updates the DynFlags in a Session
 317 setSessionDynFlags :: Session -> DynFlags -> IO ()
 318 setSessionDynFlags s dflags = modifySession s (\h -> h{ hsc_dflags = dflags })
 319
 320 -- | Messages during compilation (eg. warnings and progress messages)
 321 -- are reported using this callback.  By default, these messages are
 322 -- printed to stderr.
 323 setMsgHandler :: (String -> IO ()) -> IO ()
 324 setMsgHandler = ErrUtils.setMsgHandler
 325
 326 -- -----------------------------------------------------------------------------
 327 -- Targets
 328
 329 -- ToDo: think about relative vs. absolute file paths. And what
 330 -- happens when the current directory changes.
 331
 332 -- | Sets the targets for this session.  Each target may be a module name
 333 -- or a filename.  The targets correspond to the set of root modules for
 334 -- the program\/library.  Unloading the current program is achieved by
 335 -- setting the current set of targets to be empty, followed by load.
 336 setTargets :: Session -> [Target] -> IO ()
 337 setTargets s targets = modifySession s (\h -> h{ hsc_targets = targets })
 338
 339 -- | returns the current set of targets
 340 getTargets :: Session -> IO [Target]
 341 getTargets s = withSession s (return . hsc_targets)
 342
 343 -- | Add another target
 344 addTarget :: Session -> Target -> IO ()
 345 addTarget s target
 346   = modifySession s (\h -> h{ hsc_targets = target : hsc_targets h })
 347
 348 -- | Remove a target
 349 removeTarget :: Session -> TargetId -> IO ()
 350 removeTarget s target_id
 351   = modifySession s (\h -> h{ hsc_targets = filter (hsc_targets h) })
 352   where
 353    filter targets = [ t | t@(Target id _) <- targets, id /= target_id ]
 354
 355 -- Attempts to guess what Target a string refers to.  This function implements
 356 -- the --make/GHCi command-line syntax for filenames:
 357 --
 358 --      - if the string looks like a Haskell source filename, then interpret
 359 --        it as such
 360 --      - if adding a .hs or .lhs suffix yields the name of an existing file,
 361 --        then use that
 362 --      - otherwise interpret the string as a module name
 363 --
 364 guessTarget :: String -> Maybe Phase -> IO Target
 365 guessTarget file (Just phase)
 366    = return (Target (TargetFile file (Just phase)) Nothing)
 367 guessTarget file Nothing
 368    | isHaskellSrcFilename file
 369    = return (Target (TargetFile file Nothing) Nothing)
 370    | otherwise
 371    = do exists <- doesFileExist hs_file
 372         if exists
 373            then return (Target (TargetFile hs_file Nothing) Nothing)
 374            else do
 375         exists <- doesFileExist lhs_file
 376         if exists
 377            then return (Target (TargetFile lhs_file Nothing) Nothing)
 378            else do
 379         return (Target (TargetModule (mkModule file)) Nothing)
 380      where
 381          hs_file  = file `joinFileExt` "hs"
 382          lhs_file = file `joinFileExt` "lhs"
 383
 384 -- -----------------------------------------------------------------------------
 385 -- Loading the program
 386
 387 -- Perform a dependency analysis starting from the current targets
 388 -- and update the session with the new module graph.
 389 depanal :: Session -> [Module] -> IO (Either Messages ModuleGraph)
 390 depanal (Session ref) excluded_mods = do
 391   hsc_env <- readIORef ref
 392   let
 393          dflags  = hsc_dflags hsc_env
 394          gmode   = ghcMode (hsc_dflags hsc_env)
 395          targets = hsc_targets hsc_env
 396          old_graph = hsc_mod_graph hsc_env
 397
 398   showPass dflags "Chasing dependencies"
 399   when (gmode == BatchCompile) $
 400         debugTraceMsg dflags 1 (showSDoc (hcat [
 401                      text "Chasing modules from: ",
 402                         hcat (punctuate comma (map pprTarget targets))]))
 403
 404   r <- downsweep hsc_env old_graph excluded_mods
 405   case r of
 406     Right mod_graph -> writeIORef ref hsc_env{ hsc_mod_graph = mod_graph }
 407     _ -> return ()
 408   return r
 409
 410 {-
 411 -- | The result of load.
 412 data LoadResult
 413   = LoadOk      Errors  -- ^ all specified targets were loaded successfully.
 414   | LoadFailed  Errors  -- ^ not all modules were loaded.
 415
 416 type Errors = [String]
 417
 418 data ErrMsg = ErrMsg {
 419         errMsgSeverity  :: Severity,  -- warning, error, etc.
 420         errMsgSpans     :: [SrcSpan],
 421         errMsgShortDoc  :: Doc,
 422         errMsgExtraInfo :: Doc
 423         }
 424 -}
 425
 426 data LoadHowMuch
 427    = LoadAllTargets
 428    | LoadUpTo Module
 429    | LoadDependenciesOf Module
 430
 431 -- | Try to load the program.  If a Module is supplied, then just
 432 -- attempt to load up to this target.  If no Module is supplied,
 433 -- then try to load all targets.
 434 load :: Session -> LoadHowMuch -> IO SuccessFlag
 435 load session how_much =
 436    loadMsgs session how_much ErrUtils.printErrorsAndWarnings
 437
 438 -- | Version of 'load' that takes a callback function to be invoked
 439 -- on compiler errors and warnings as they occur during compilation.
 440 loadMsgs :: Session -> LoadHowMuch -> (Messages-> IO ()) -> IO SuccessFlag
 441 loadMsgs s@(Session ref) how_much msg_act
 442    = do
 443         -- Dependency analysis first.  Note that this fixes the module graph:
 444         -- even if we don't get a fully successful upsweep, the full module
 445         -- graph is still retained in the Session.  We can tell which modules
 446         -- were successfully loaded by inspecting the Session's HPT.
 447         mb_graph <- depanal s []
 448         case mb_graph of
 449            Left msgs       -> do msg_act msgs; return Failed
 450            Right mod_graph -> loadMsgs2 s how_much msg_act mod_graph
 451
 452 loadMsgs2 s@(Session ref) how_much msg_act mod_graph = do
 453         hsc_env <- readIORef ref
 454
 455         let hpt1      = hsc_HPT hsc_env
 456         let dflags    = hsc_dflags hsc_env
 457         let ghci_mode = ghcMode dflags -- this never changes
 458         let verb      = verbosity dflags
 459
 460         -- The "bad" boot modules are the ones for which we have
 461         -- B.hs-boot in the module graph, but no B.hs
 462         -- The downsweep should have ensured this does not happen
 463         -- (see msDeps)
 464         let all_home_mods = [ms_mod s | s <- mod_graph, not (isBootSummary s)]
 465             bad_boot_mods = [s        | s <- mod_graph, isBootSummary s,
 466                                         not (ms_mod s `elem` all_home_mods)]
 467         ASSERT( null bad_boot_mods ) return ()
 468
 469         -- mg2_with_srcimps drops the hi-boot nodes, returning a
 470         -- graph with cycles.  Among other things, it is used for
 471         -- backing out partially complete cycles following a failed
 472         -- upsweep, and for removing from hpt all the modules
 473         -- not in strict downwards closure, during calls to compile.
 474         let mg2_with_srcimps :: [SCC ModSummary]
 475             mg2_with_srcimps = topSortModuleGraph True mod_graph Nothing
 476
 477             -- check the stability property for each module.
 478             stable_mods@(stable_obj,stable_bco)
 479                 | BatchCompile <- ghci_mode = ([],[])
 480                 | otherwise = checkStability hpt1 mg2_with_srcimps all_home_mods
 481
 482             -- prune bits of the HPT which are definitely redundant now,
 483             -- to save space.
 484             pruned_hpt = pruneHomePackageTable hpt1
 485                                 (flattenSCCs mg2_with_srcimps)
 486                                 stable_mods
 487
 488         evaluate pruned_hpt
 489
 490         debugTraceMsg dflags 2 (showSDoc (text "Stable obj:" <+> ppr stable_obj $$
 491                                 text "Stable BCO:" <+> ppr stable_bco))
 492
 493         -- Unload any modules which are going to be re-linked this time around.
 494         let stable_linkables = [ linkable
 495                                | m <- stable_obj++stable_bco,
 496                                  Just hmi <- [lookupModuleEnv pruned_hpt m],
 497                                  Just linkable <- [hm_linkable hmi] ]
 498         unload hsc_env stable_linkables
 499
 500         -- We could at this point detect cycles which aren't broken by
 501         -- a source-import, and complain immediately, but it seems better
 502         -- to let upsweep_mods do this, so at least some useful work gets
 503         -- done before the upsweep is abandoned.
 504         --hPutStrLn stderr "after tsort:\n"
 505         --hPutStrLn stderr (showSDoc (vcat (map ppr mg2)))
 506
 507         -- Now do the upsweep, calling compile for each module in
 508         -- turn.  Final result is version 3 of everything.
 509
 510         -- Topologically sort the module graph, this time including hi-boot
 511         -- nodes, and possibly just including the portion of the graph
 512         -- reachable from the module specified in the 2nd argument to load.
 513         -- This graph should be cycle-free.
 514         -- If we're restricting the upsweep to a portion of the graph, we
 515         -- also want to retain everything that is still stable.
 516         let full_mg :: [SCC ModSummary]
 517             full_mg    = topSortModuleGraph False mod_graph Nothing
 518
 519             maybe_top_mod = case how_much of
 520                                 LoadUpTo m           -> Just m
 521                                 LoadDependenciesOf m -> Just m
 522                                 _                    -> Nothing
 523
 524             partial_mg0 :: [SCC ModSummary]
 525             partial_mg0 = topSortModuleGraph False mod_graph maybe_top_mod
 526
 527             -- LoadDependenciesOf m: we want the upsweep to stop just
 528             -- short of the specified module (unless the specified module
 529             -- is stable).
 530             partial_mg
 531                 | LoadDependenciesOf mod <- how_much
 532                 = ASSERT( case last partial_mg0 of
 533                             AcyclicSCC ms -> ms_mod ms == mod; _ -> False )
 534                   List.init partial_mg0
 535                 | otherwise
 536                 = partial_mg0
 537
 538             stable_mg =
 539                 [ AcyclicSCC ms
 540                 | AcyclicSCC ms <- full_mg,
 541                   ms_mod ms `elem` stable_obj++stable_bco,
 542                   ms_mod ms `notElem` [ ms_mod ms' |
 543                                         AcyclicSCC ms' <- partial_mg ] ]
 544
 545             mg = stable_mg ++ partial_mg
 546
 547         -- clean up between compilations
 548         let cleanup = cleanTempFilesExcept dflags
 549                           (ppFilesFromSummaries (flattenSCCs mg2_with_srcimps))
 550
 551         (upsweep_ok, hsc_env1, modsUpswept)
 552            <- upsweep (hsc_env { hsc_HPT = emptyHomePackageTable })
 553                            pruned_hpt stable_mods cleanup msg_act mg
 554
 555         -- Make modsDone be the summaries for each home module now
 556         -- available; this should equal the domain of hpt3.
 557         -- Get in in a roughly top .. bottom order (hence reverse).
 558
 559         let modsDone = reverse modsUpswept
 560
 561         -- Try and do linking in some form, depending on whether the
 562         -- upsweep was completely or only partially successful.
 563
 564         if succeeded upsweep_ok
 565
 566          then
 567            -- Easy; just relink it all.
 568            do debugTraceMsg dflags 2 "Upsweep completely successful."
 569
 570               -- Clean up after ourselves
 571               cleanTempFilesExcept dflags (ppFilesFromSummaries modsDone)
 572
 573               -- Issue a warning for the confusing case where the user
 574               -- said '-o foo' but we're not going to do any linking.
 575               -- We attempt linking if either (a) one of the modules is
 576               -- called Main, or (b) the user said -no-hs-main, indicating
 577               -- that main() is going to come from somewhere else.
 578               --
 579               let ofile = outputFile dflags
 580               let no_hs_main = dopt Opt_NoHsMain dflags
 581               let mb_main_mod = mainModIs dflags
 582               let
 583                 main_mod = mb_main_mod `orElse` "Main"
 584                 a_root_is_Main
 585                     = any ((==main_mod).moduleUserString.ms_mod)
 586                           mod_graph
 587                 do_linking = a_root_is_Main || no_hs_main
 588
 589               when (ghci_mode == BatchCompile && isJust ofile && not do_linking) $
 590                 debugTraceMsg dflags 1 ("Warning: output was redirected with -o, " ++
 591                                    "but no output will be generated\n" ++
 592                                    "because there is no " ++ main_mod ++ " module.")
 593
 594               -- link everything together
 595               linkresult <- link ghci_mode dflags do_linking (hsc_HPT hsc_env1)
 596
 597               loadFinish Succeeded linkresult ref hsc_env1
 598
 599          else
 600            -- Tricky.  We need to back out the effects of compiling any
 601            -- half-done cycles, both so as to clean up the top level envs
 602            -- and to avoid telling the interactive linker to link them.
 603            do debugTraceMsg dflags 2 "Upsweep partially successful."
 604
 605               let modsDone_names
 606                      = map ms_mod modsDone
 607               let mods_to_zap_names
 608                      = findPartiallyCompletedCycles modsDone_names
 609                           mg2_with_srcimps
 610               let mods_to_keep
 611                      = filter ((`notElem` mods_to_zap_names).ms_mod)
 612                           modsDone
 613
 614               let hpt4 = retainInTopLevelEnvs (map ms_mod mods_to_keep)
 615                                               (hsc_HPT hsc_env1)
 616
 617               -- Clean up after ourselves
 618               cleanTempFilesExcept dflags (ppFilesFromSummaries mods_to_keep)
 619
 620               -- there should be no Nothings where linkables should be, now
 621               ASSERT(all (isJust.hm_linkable)
 622                         (moduleEnvElts (hsc_HPT hsc_env))) do
 623
 624               -- Link everything together
 625               linkresult <- link ghci_mode dflags False hpt4
 626
 627               let hsc_env4 = hsc_env1{ hsc_HPT = hpt4 }
 628               loadFinish Failed linkresult ref hsc_env4
 629
 630 -- Finish up after a load.
 631
 632 -- If the link failed, unload everything and return.
 633 loadFinish all_ok Failed ref hsc_env
 634   = do unload hsc_env []
 635        writeIORef ref $! discardProg hsc_env
 636        return Failed
 637
 638 -- Empty the interactive context and set the module context to the topmost
 639 -- newly loaded module, or the Prelude if none were loaded.
 640 loadFinish all_ok Succeeded ref hsc_env
 641   = do writeIORef ref $! hsc_env{ hsc_IC = emptyInteractiveContext }
 642        return all_ok
 643
 644
 645 -- Forget the current program, but retain the persistent info in HscEnv
 646 discardProg :: HscEnv -> HscEnv
 647 discardProg hsc_env
 648   = hsc_env { hsc_mod_graph = emptyMG,
 649               hsc_IC = emptyInteractiveContext,
 650               hsc_HPT = emptyHomePackageTable }
 651
 652 -- used to fish out the preprocess output files for the purposes of
 653 -- cleaning up.  The preprocessed file *might* be the same as the
 654 -- source file, but that doesn't do any harm.
 655 ppFilesFromSummaries summaries = [ fn | Just fn <- map ms_hspp_file summaries ]
 656
 657 -- -----------------------------------------------------------------------------
 658 -- Check module
 659
 660 data CheckedModule =
 661   CheckedModule { parsedSource      :: ParsedSource,
 662                   renamedSource     :: Maybe RenamedSource,
 663                   typecheckedSource :: Maybe TypecheckedSource,
 664                   checkedModuleInfo :: Maybe ModuleInfo
 665                 }
 666         -- ToDo: improvements that could be made here:
 667         --  if the module succeeded renaming but not typechecking,
 668         --  we can still get back the GlobalRdrEnv and exports, so
 669         --  perhaps the ModuleInfo should be split up into separate
 670         --  fields within CheckedModule.
 671
 672 type ParsedSource      = Located (HsModule RdrName)
 673 type RenamedSource     = HsGroup Name
 674 type TypecheckedSource = LHsBinds Id
 675
 676 -- | This is the way to get access to parsed and typechecked source code
 677 -- for a module.  'checkModule' loads all the dependencies of the specified
 678 -- module in the Session, and then attempts to typecheck the module.  If
 679 -- successful, it returns the abstract syntax for the module.
 680 checkModule :: Session -> Module -> (Messages -> IO ())
 681         -> IO (Maybe CheckedModule)
 682 checkModule session@(Session ref) mod msg_act = do
 683         -- load up the dependencies first
 684    r <- loadMsgs session (LoadDependenciesOf mod) msg_act
 685    if (failed r) then return Nothing else do
 686
 687         -- now parse & typecheck the module
 688    hsc_env <- readIORef ref
 689    let mg  = hsc_mod_graph hsc_env
 690    case [ ms | ms <- mg, ms_mod ms == mod ] of
 691         [] -> return Nothing
 692         (ms:_) -> do
 693            -- Add in the OPTIONS from the source file This is nasty:
 694            -- we've done this once already, in the compilation manager
 695            -- It might be better to cache the flags in the
 696            -- ml_hspp_file field, say
 697            let dflags0 = hsc_dflags hsc_env
 698                hspp_buf = expectJust "GHC.checkModule" (ms_hspp_buf ms)
 699                opts = getOptionsFromStringBuffer hspp_buf
 700            (dflags1,leftovers) <- parseDynamicFlags dflags0 (map snd opts)
 701            if (not (null leftovers))
 702                 then do let filename = fromJust (ml_hs_file (ms_location ms))
 703                         msg_act (optionsErrorMsgs leftovers opts filename)
 704                         return Nothing
 705                 else do
 706
 707            r <- hscFileCheck hsc_env{hsc_dflags=dflags1} msg_act ms
 708            case r of
 709                 HscFail ->
 710                    return Nothing
 711                 HscChecked parsed renamed Nothing ->
 712                    return (Just (CheckedModule {
 713                                         parsedSource = parsed,
 714                                         renamedSource = renamed,
 715                                         typecheckedSource = Nothing,
 716                                         checkedModuleInfo = Nothing }))
 717                 HscChecked parsed renamed
 718                            (Just (tc_binds, rdr_env, details)) -> do
 719                    let minf = ModuleInfo {
 720                                 minf_type_env  = md_types details,
 721                                 minf_exports   = md_exports details,
 722                                 minf_rdr_env   = Just rdr_env,
 723                                 minf_instances = md_insts details
 724                               }
 725                    return (Just (CheckedModule {
 726                                         parsedSource = parsed,
 727                                         renamedSource = renamed,
 728                                         typecheckedSource = Just tc_binds,
 729                                         checkedModuleInfo = Just minf }))
 730
 731 -- ---------------------------------------------------------------------------
 732 -- Unloading
 733
 734 unload :: HscEnv -> [Linkable] -> IO ()
 735 unload hsc_env stable_linkables -- Unload everthing *except* 'stable_linkables'
 736   = case ghcMode (hsc_dflags hsc_env) of
 737         BatchCompile  -> return ()
 738         JustTypecheck -> return ()
 739 #ifdef GHCI
 740         Interactive -> Linker.unload (hsc_dflags hsc_env) stable_linkables
 741 #else
 742         Interactive -> panic "unload: no interpreter"
 743 #endif
 744         other -> panic "unload: strange mode"
 745
 746 -- -----------------------------------------------------------------------------
 747 -- checkStability
 748
 749 {-
 750   Stability tells us which modules definitely do not need to be recompiled.
 751   There are two main reasons for having stability:
 752
 753    - avoid doing a complete upsweep of the module graph in GHCi when
 754      modules near the bottom of the tree have not changed.
 755
 756    - to tell GHCi when it can load object code: we can only load object code
 757      for a module when we also load object code fo  all of the imports of the
 758      module.  So we need to know that we will definitely not be recompiling
 759      any of these modules, and we can use the object code.
 760
 761   NB. stability is of no importance to BatchCompile at all, only Interactive.
 762   (ToDo: what about JustTypecheck?)
 763
 764   The stability check is as follows.  Both stableObject and
 765   stableBCO are used during the upsweep phase later.
 766
 767   -------------------
 768   stable m = stableObject m || stableBCO m
 769
 770   stableObject m =
 771         all stableObject (imports m)
 772         && old linkable does not exist, or is == on-disk .o
 773         && date(on-disk .o) > date(.hs)
 774
 775   stableBCO m =
 776         all stable (imports m)
 777         && date(BCO) > date(.hs)
 778   -------------------
 779
 780   These properties embody the following ideas:
 781
 782     - if a module is stable:
 783         - if it has been compiled in a previous pass (present in HPT)
 784           then it does not need to be compiled or re-linked.
 785         - if it has not been compiled in a previous pass,
 786           then we only need to read its .hi file from disk and
 787           link it to produce a ModDetails.
 788
 789     - if a modules is not stable, we will definitely be at least
 790       re-linking, and possibly re-compiling it during the upsweep.
 791       All non-stable modules can (and should) therefore be unlinked
 792       before the upsweep.
 793
 794     - Note that objects are only considered stable if they only depend
 795       on other objects.  We can't link object code against byte code.
 796 -}
 797
 798 checkStability
 799         :: HomePackageTable             -- HPT from last compilation
 800         -> [SCC ModSummary]             -- current module graph (cyclic)
 801         -> [Module]                     -- all home modules
 802         -> ([Module],                   -- stableObject
 803             [Module])                   -- stableBCO
 804
 805 checkStability hpt sccs all_home_mods = foldl checkSCC ([],[]) sccs
 806   where
 807    checkSCC (stable_obj, stable_bco) scc0
 808      | stableObjects = (scc_mods ++ stable_obj, stable_bco)
 809      | stableBCOs    = (stable_obj, scc_mods ++ stable_bco)
 810      | otherwise     = (stable_obj, stable_bco)
 811      where
 812         scc = flattenSCC scc0
 813         scc_mods = map ms_mod scc
 814         home_module m   = m `elem` all_home_mods && m `notElem` scc_mods
 815
 816         scc_allimps = nub (filter home_module (concatMap ms_allimps scc))
 817             -- all imports outside the current SCC, but in the home pkg
 818
 819         stable_obj_imps = map (`elem` stable_obj) scc_allimps
 820         stable_bco_imps = map (`elem` stable_bco) scc_allimps
 821
 822         stableObjects =
 823            and stable_obj_imps
 824            && all object_ok scc
 825
 826         stableBCOs =
 827            and (zipWith (||) stable_obj_imps stable_bco_imps)
 828            && all bco_ok scc
 829
 830         object_ok ms
 831           | Just t <- ms_obj_date ms  =  t >= ms_hs_date ms
 832                                          && same_as_prev t
 833           | otherwise = False
 834           where
 835              same_as_prev t = case lookupModuleEnv hpt (ms_mod ms) of
 836                                 Nothing  -> True
 837                                 Just hmi  | Just l <- hm_linkable hmi
 838                                  -> isObjectLinkable l && t == linkableTime l
 839                 -- why '>=' rather than '>' above?  If the filesystem stores
 840                 -- times to the nearset second, we may occasionally find that
 841                 -- the object & source have the same modification time,
 842                 -- especially if the source was automatically generated
 843                 -- and compiled.  Using >= is slightly unsafe, but it matches
 844                 -- make's behaviour.
 845
 846         bco_ok ms
 847           = case lookupModuleEnv hpt (ms_mod ms) of
 848                 Nothing  -> False
 849                 Just hmi  | Just l <- hm_linkable hmi ->
 850                         not (isObjectLinkable l) &&
 851                         linkableTime l >= ms_hs_date ms
 852
 853 ms_allimps :: ModSummary -> [Module]
 854 ms_allimps ms = map unLoc (ms_srcimps ms ++ ms_imps ms)
 855
 856 -- -----------------------------------------------------------------------------
 857 -- Prune the HomePackageTable
 858
 859 -- Before doing an upsweep, we can throw away:
 860 --
 861 --   - For non-stable modules:
 862 --      - all ModDetails, all linked code
 863 --   - all unlinked code that is out of date with respect to
 864 --     the source file
 865 --
 866 -- This is VERY IMPORTANT otherwise we'll end up requiring 2x the
 867 -- space at the end of the upsweep, because the topmost ModDetails of the
 868 -- old HPT holds on to the entire type environment from the previous
 869 -- compilation.
 870
 871 pruneHomePackageTable
 872    :: HomePackageTable
 873    -> [ModSummary]
 874    -> ([Module],[Module])
 875    -> HomePackageTable
 876
 877 pruneHomePackageTable hpt summ (stable_obj, stable_bco)
 878   = mapModuleEnv prune hpt
 879   where prune hmi
 880           | is_stable modl = hmi'
 881           | otherwise      = hmi'{ hm_details = emptyModDetails }
 882           where
 883            modl = mi_module (hm_iface hmi)
 884            hmi' | Just l <- hm_linkable hmi, linkableTime l < ms_hs_date ms
 885                 = hmi{ hm_linkable = Nothing }
 886                 | otherwise
 887                 = hmi
 888                 where ms = expectJust "prune" (lookupModuleEnv ms_map modl)
 889
 890         ms_map = mkModuleEnv [(ms_mod ms, ms) | ms <- summ]
 891
 892         is_stable m = m `elem` stable_obj || m `elem` stable_bco
 893
 894 -- -----------------------------------------------------------------------------
 895
 896 -- Return (names of) all those in modsDone who are part of a cycle
 897 -- as defined by theGraph.
 898 findPartiallyCompletedCycles :: [Module] -> [SCC ModSummary] -> [Module]
 899 findPartiallyCompletedCycles modsDone theGraph
 900    = chew theGraph
 901      where
 902         chew [] = []
 903         chew ((AcyclicSCC v):rest) = chew rest    -- acyclic?  not interesting.
 904         chew ((CyclicSCC vs):rest)
 905            = let names_in_this_cycle = nub (map ms_mod vs)
 906                  mods_in_this_cycle
 907                     = nub ([done | done <- modsDone,
 908                                    done `elem` names_in_this_cycle])
 909                  chewed_rest = chew rest
 910              in
 911              if   notNull mods_in_this_cycle
 912                   && length mods_in_this_cycle < length names_in_this_cycle
 913              then mods_in_this_cycle ++ chewed_rest
 914              else chewed_rest
 915
 916 -- -----------------------------------------------------------------------------
 917 -- The upsweep
 918
 919 -- This is where we compile each module in the module graph, in a pass
 920 -- from the bottom to the top of the graph.
 921
 922 -- There better had not be any cyclic groups here -- we check for them.
 923
 924 upsweep
 925     :: HscEnv                   -- Includes initially-empty HPT
 926     -> HomePackageTable         -- HPT from last time round (pruned)
 927     -> ([Module],[Module])      -- stable modules (see checkStability)
 928     -> IO ()                    -- How to clean up unwanted tmp files
 929     -> (Messages -> IO ())      -- Compiler error message callback
 930     -> [SCC ModSummary]         -- Mods to do (the worklist)
 931     -> IO (SuccessFlag,
 932            HscEnv,              -- With an updated HPT
 933            [ModSummary])        -- Mods which succeeded
 934
 935 upsweep hsc_env old_hpt stable_mods cleanup msg_act mods
 936    = upsweep' hsc_env old_hpt stable_mods cleanup msg_act mods 1 (length mods)
 937
 938 upsweep' hsc_env old_hpt stable_mods cleanup msg_act
 939      [] _ _
 940    = return (Succeeded, hsc_env, [])
 941
 942 upsweep' hsc_env old_hpt stable_mods cleanup msg_act
 943      (CyclicSCC ms:_) _ _
 944    = do putMsg (showSDoc (cyclicModuleErr ms))
 945         return (Failed, hsc_env, [])
 946
 947 upsweep' hsc_env old_hpt stable_mods cleanup msg_act
 948      (AcyclicSCC mod:mods) mod_index nmods
 949    = do -- putStrLn ("UPSWEEP_MOD: hpt = " ++
 950         --           show (map (moduleUserString.moduleName.mi_module.hm_iface)
 951         --                     (moduleEnvElts (hsc_HPT hsc_env)))
 952
 953         mb_mod_info <- upsweep_mod hsc_env old_hpt stable_mods msg_act mod
 954                        mod_index nmods
 955
 956         cleanup         -- Remove unwanted tmp files between compilations
 957
 958         case mb_mod_info of
 959             Nothing -> return (Failed, hsc_env, [])
 960             Just mod_info -> do
 961                 { let this_mod = ms_mod mod
 962
 963                         -- Add new info to hsc_env
 964                       hpt1     = extendModuleEnv (hsc_HPT hsc_env)
 965                                         this_mod mod_info
 966                       hsc_env1 = hsc_env { hsc_HPT = hpt1 }
 967
 968                         -- Space-saving: delete the old HPT entry
 969                         -- for mod BUT if mod is a hs-boot
 970                         -- node, don't delete it.  For the
 971                         -- interface, the HPT entry is probaby for the
 972                         -- main Haskell source file.  Deleting it
 973                         -- would force .. (what?? --SDM)
 974                       old_hpt1 | isBootSummary mod = old_hpt
 975                                | otherwise = delModuleEnv old_hpt this_mod
 976
 977                 ; (restOK, hsc_env2, modOKs)
 978                         <- upsweep' hsc_env1 old_hpt1 stable_mods cleanup
 979                                 msg_act mods (mod_index+1) nmods
 980                 ; return (restOK, hsc_env2, mod:modOKs)
 981                 }
 982
 983
 984 -- Compile a single module.  Always produce a Linkable for it if
 985 -- successful.  If no compilation happened, return the old Linkable.
 986 upsweep_mod :: HscEnv
 987             -> HomePackageTable
 988             -> ([Module],[Module])
 989             -> (Messages -> IO ())
 990             -> ModSummary
 991             -> Int  -- index of module
 992             -> Int  -- total number of modules
 993             -> IO (Maybe HomeModInfo)   -- Nothing => Failed
 994
 995 upsweep_mod hsc_env old_hpt (stable_obj, stable_bco) msg_act summary mod_index nmods
 996    = do
 997         let
 998             this_mod    = ms_mod summary
 999             mb_obj_date = ms_obj_date summary
1000             obj_fn      = ml_obj_file (ms_location summary)
1001             hs_date     = ms_hs_date summary
1002
1003             compile_it :: Maybe Linkable -> IO (Maybe HomeModInfo)
1004             compile_it  = upsweep_compile hsc_env old_hpt this_mod
1005                                 msg_act summary mod_index nmods
1006
1007         case ghcMode (hsc_dflags hsc_env) of
1008             BatchCompile ->
1009                 case () of
1010                    -- Batch-compilating is easy: just check whether we have
1011                    -- an up-to-date object file.  If we do, then the compiler
1012                    -- needs to do a recompilation check.
1013                    _ | Just obj_date <- mb_obj_date, obj_date >= hs_date -> do
1014                            linkable <-
1015                                 findObjectLinkable this_mod obj_fn obj_date
1016                            compile_it (Just linkable)
1017
1018                      | otherwise ->
1019                            compile_it Nothing
1020
1021             interactive ->
1022                 case () of
1023                     _ | is_stable_obj, isJust old_hmi ->
1024                            return old_hmi
1025                         -- object is stable, and we have an entry in the
1026                         -- old HPT: nothing to do
1027
1028                       | is_stable_obj, isNothing old_hmi -> do
1029                            linkable <-
1030                                 findObjectLinkable this_mod obj_fn
1031                                         (expectJust "upseep1" mb_obj_date)
1032                            compile_it (Just linkable)
1033                         -- object is stable, but we need to load the interface
1034                         -- off disk to make a HMI.
1035
1036                       | is_stable_bco ->
1037                            ASSERT(isJust old_hmi) -- must be in the old_hpt
1038                            return old_hmi
1039                         -- BCO is stable: nothing to do
1040
1041                       | Just hmi <- old_hmi,
1042                         Just l <- hm_linkable hmi, not (isObjectLinkable l),
1043                         linkableTime l >= ms_hs_date summary ->
1044                            compile_it (Just l)
1045                         -- we have an old BCO that is up to date with respect
1046                         -- to the source: do a recompilation check as normal.
1047
1048                       | otherwise ->
1049                           compile_it Nothing
1050                         -- no existing code at all: we must recompile.
1051                    where
1052                     is_stable_obj = this_mod `elem` stable_obj
1053                     is_stable_bco = this_mod `elem` stable_bco
1054
1055                     old_hmi = lookupModuleEnv old_hpt this_mod
1056
1057 -- Run hsc to compile a module
1058 upsweep_compile hsc_env old_hpt this_mod msg_act summary
1059                 mod_index nmods
1060                 mb_old_linkable = do
1061   let
1062         -- The old interface is ok if it's in the old HPT
1063         --      a) we're compiling a source file, and the old HPT
1064         --         entry is for a source file
1065         --      b) we're compiling a hs-boot file
1066         -- Case (b) allows an hs-boot file to get the interface of its
1067         -- real source file on the second iteration of the compilation
1068         -- manager, but that does no harm.  Otherwise the hs-boot file
1069         -- will always be recompiled
1070
1071         mb_old_iface
1072                 = case lookupModuleEnv old_hpt this_mod of
1073                      Nothing                              -> Nothing
1074                      Just hm_info | isBootSummary summary -> Just iface
1075                                   | not (mi_boot iface)   -> Just iface
1076                                   | otherwise             -> Nothing
1077                                    where
1078                                      iface = hm_iface hm_info
1079
1080   compresult <- compile hsc_env msg_act summary mb_old_linkable mb_old_iface
1081                         mod_index nmods
1082
1083   case compresult of
1084         -- Compilation failed.  Compile may still have updated the PCS, tho.
1085         CompErrs -> return Nothing
1086
1087         -- Compilation "succeeded", and may or may not have returned a new
1088         -- linkable (depending on whether compilation was actually performed
1089         -- or not).
1090         CompOK new_details new_iface new_linkable
1091               -> do let new_info = HomeModInfo { hm_iface = new_iface,
1092                                                  hm_details = new_details,
1093                                                  hm_linkable = new_linkable }
1094                     return (Just new_info)
1095
1096
1097 -- Filter modules in the HPT
1098 retainInTopLevelEnvs :: [Module] -> HomePackageTable -> HomePackageTable
1099 retainInTopLevelEnvs keep_these hpt
1100    = mkModuleEnv [ (mod, expectJust "retain" mb_mod_info)
1101                  | mod <- keep_these
1102                  , let mb_mod_info = lookupModuleEnv hpt mod
1103                  , isJust mb_mod_info ]
1104
1105 -- ---------------------------------------------------------------------------
1106 -- Topological sort of the module graph
1107
1108 topSortModuleGraph
1109           :: Bool               -- Drop hi-boot nodes? (see below)
1110           -> [ModSummary]
1111           -> Maybe Module
1112           -> [SCC ModSummary]
1113 -- Calculate SCCs of the module graph, possibly dropping the hi-boot nodes
1114 -- The resulting list of strongly-connected-components is in topologically
1115 -- sorted order, starting with the module(s) at the bottom of the
1116 -- dependency graph (ie compile them first) and ending with the ones at
1117 -- the top.
1118 --
1119 -- Drop hi-boot nodes (first boolean arg)?
1120 --
1121 --   False:     treat the hi-boot summaries as nodes of the graph,
1122 --              so the graph must be acyclic
1123 --
1124 --   True:      eliminate the hi-boot nodes, and instead pretend
1125 --              the a source-import of Foo is an import of Foo
1126 --              The resulting graph has no hi-boot nodes, but can by cyclic
1127
1128 topSortModuleGraph drop_hs_boot_nodes summaries Nothing
1129   = stronglyConnComp (fst (moduleGraphNodes drop_hs_boot_nodes summaries))
1130 topSortModuleGraph drop_hs_boot_nodes summaries (Just mod)
1131   = stronglyConnComp (map vertex_fn (reachable graph root))
1132   where
1133         -- restrict the graph to just those modules reachable from
1134         -- the specified module.  We do this by building a graph with
1135         -- the full set of nodes, and determining the reachable set from
1136         -- the specified node.
1137         (nodes, lookup_key) = moduleGraphNodes drop_hs_boot_nodes summaries
1138         (graph, vertex_fn, key_fn) = graphFromEdges' nodes
1139         root
1140           | Just key <- lookup_key HsSrcFile mod, Just v <- key_fn key = v
1141           | otherwise  = throwDyn (ProgramError "module does not exist")
1142
1143 moduleGraphNodes :: Bool -> [ModSummary]
1144   -> ([(ModSummary, Int, [Int])], HscSource -> Module -> Maybe Int)
1145 moduleGraphNodes drop_hs_boot_nodes summaries = (nodes, lookup_key)
1146    where
1147         -- Drop hs-boot nodes by using HsSrcFile as the key
1148         hs_boot_key | drop_hs_boot_nodes = HsSrcFile
1149                     | otherwise          = HsBootFile
1150
1151         -- We use integers as the keys for the SCC algorithm
1152         nodes :: [(ModSummary, Int, [Int])]
1153         nodes = [(s, expectJust "topSort" (lookup_key (ms_hsc_src s) (ms_mod s)),
1154                      out_edge_keys hs_boot_key (map unLoc (ms_srcimps s)) ++
1155                      out_edge_keys HsSrcFile   (map unLoc (ms_imps s))    )
1156                 | s <- summaries
1157                 , not (isBootSummary s && drop_hs_boot_nodes) ]
1158                 -- Drop the hi-boot ones if told to do so
1159
1160         key_map :: NodeMap Int
1161         key_map = listToFM ([(ms_mod s, ms_hsc_src s) | s <- summaries]
1162                            `zip` [1..])
1163
1164         lookup_key :: HscSource -> Module -> Maybe Int
1165         lookup_key hs_src mod = lookupFM key_map (mod, hs_src)
1166
1167         out_edge_keys :: HscSource -> [Module] -> [Int]
1168         out_edge_keys hi_boot ms = mapCatMaybes (lookup_key hi_boot) ms
1169                 -- If we want keep_hi_boot_nodes, then we do lookup_key with
1170                 -- the IsBootInterface parameter True; else False
1171
1172
1173 type NodeKey   = (Module, HscSource)      -- The nodes of the graph are
1174 type NodeMap a = FiniteMap NodeKey a      -- keyed by (mod, src_file_type) pairs
1175
1176 msKey :: ModSummary -> NodeKey
1177 msKey (ModSummary { ms_mod = mod, ms_hsc_src = boot }) = (mod,boot)
1178
1179 emptyNodeMap :: NodeMap a
1180 emptyNodeMap = emptyFM
1181
1182 mkNodeMap :: [ModSummary] -> NodeMap ModSummary
1183 mkNodeMap summaries = listToFM [ (msKey s, s) | s <- summaries]
1184
1185 nodeMapElts :: NodeMap a -> [a]
1186 nodeMapElts = eltsFM
1187
1188 -- -----------------------------------------------------------------
1189 -- The unlinked image
1190 --
1191 -- The compilation manager keeps a list of compiled, but as-yet unlinked
1192 -- binaries (byte code or object code).  Even when it links bytecode
1193 -- it keeps the unlinked version so it can re-link it later without
1194 -- recompiling.
1195
1196 type UnlinkedImage = [Linkable] -- the unlinked images (should be a set, really)
1197
1198 findModuleLinkable_maybe :: [Linkable] -> Module -> Maybe Linkable
1199 findModuleLinkable_maybe lis mod
1200    = case [LM time nm us | LM time nm us <- lis, nm == mod] of
1201         []   -> Nothing
1202         [li] -> Just li
1203         many -> pprPanic "findModuleLinkable" (ppr mod)
1204
1205 delModuleLinkable :: [Linkable] -> Module -> [Linkable]
1206 delModuleLinkable ls mod = [ l | l@(LM _ nm _) <- ls, nm /= mod ]
1207
1208 -----------------------------------------------------------------------------
1209 -- Downsweep (dependency analysis)
1210
1211 -- Chase downwards from the specified root set, returning summaries
1212 -- for all home modules encountered.  Only follow source-import
1213 -- links.
1214
1215 -- We pass in the previous collection of summaries, which is used as a
1216 -- cache to avoid recalculating a module summary if the source is
1217 -- unchanged.
1218 --
1219 -- The returned list of [ModSummary] nodes has one node for each home-package
1220 -- module, plus one for any hs-boot files.  The imports of these nodes
1221 -- are all there, including the imports of non-home-package modules.
1222
1223 downsweep :: HscEnv
1224           -> [ModSummary]       -- Old summaries
1225           -> [Module]           -- Ignore dependencies on these; treat them as
1226                                 -- if they were package modules
1227           -> IO (Either Messages [ModSummary])
1228 downsweep hsc_env old_summaries excl_mods
1229    = -- catch error messages and return them
1230      handleDyn (\err_msg -> return (Left (emptyBag, unitBag err_msg))) $ do
1231        rootSummaries <- mapM getRootSummary roots
1232        checkDuplicates rootSummaries
1233        summs <- loop (concatMap msDeps rootSummaries) (mkNodeMap rootSummaries)
1234        return (Right summs)
1235      where
1236         roots = hsc_targets hsc_env
1237
1238         old_summary_map :: NodeMap ModSummary
1239         old_summary_map = mkNodeMap old_summaries
1240
1241         getRootSummary :: Target -> IO ModSummary
1242         getRootSummary (Target (TargetFile file mb_phase) maybe_buf)
1243            = do exists <- doesFileExist file
1244                 if exists
1245                     then summariseFile hsc_env old_summaries file mb_phase maybe_buf
1246                     else throwDyn $ mkPlainErrMsg noSrcSpan $
1247                            text "can't find file:" <+> text file
1248         getRootSummary (Target (TargetModule modl) maybe_buf)
1249            = do maybe_summary <- summariseModule hsc_env old_summary_map False
1250                                            (L rootLoc modl) maybe_buf excl_mods
1251                 case maybe_summary of
1252                    Nothing -> packageModErr modl
1253                    Just s  -> return s
1254
1255         rootLoc = mkGeneralSrcSpan FSLIT("<command line>")
1256
1257         -- In a root module, the filename is allowed to diverge from the module
1258         -- name, so we have to check that there aren't multiple root files
1259         -- defining the same module (otherwise the duplicates will be silently
1260         -- ignored, leading to confusing behaviour).
1261         checkDuplicates :: [ModSummary] -> IO ()
1262         checkDuplicates summaries = mapM_ check summaries
1263           where check summ =
1264                   case dups of
1265                         []     -> return ()
1266                         [_one] -> return ()
1267                         many   -> multiRootsErr modl many
1268                    where modl = ms_mod summ
1269                          dups =
1270                            [ expectJust "checkDup" (ml_hs_file (ms_location summ'))
1271                            | summ' <- summaries, ms_mod summ' == modl ]
1272
1273         loop :: [(Located Module,IsBootInterface)]
1274                         -- Work list: process these modules
1275              -> NodeMap ModSummary
1276                         -- Visited set
1277              -> IO [ModSummary]
1278                         -- The result includes the worklist, except
1279                         -- for those mentioned in the visited set
1280         loop [] done      = return (nodeMapElts done)
1281         loop ((wanted_mod, is_boot) : ss) done
1282           | key `elemFM` done = loop ss done
1283           | otherwise         = do { mb_s <- summariseModule hsc_env old_summary_map
1284                                                  is_boot wanted_mod Nothing excl_mods
1285                                    ; case mb_s of
1286                                         Nothing -> loop ss done
1287                                         Just s  -> loop (msDeps s ++ ss)
1288                                                         (addToFM done key s) }
1289           where
1290             key = (unLoc wanted_mod, if is_boot then HsBootFile else HsSrcFile)
1291
1292 msDeps :: ModSummary -> [(Located Module, IsBootInterface)]
1293 -- (msDeps s) returns the dependencies of the ModSummary s.
1294 -- A wrinkle is that for a {-# SOURCE #-} import we return
1295 --      *both* the hs-boot file
1296 --      *and* the source file
1297 -- as "dependencies".  That ensures that the list of all relevant
1298 -- modules always contains B.hs if it contains B.hs-boot.
1299 -- Remember, this pass isn't doing the topological sort.  It's
1300 -- just gathering the list of all relevant ModSummaries
1301 msDeps s =
1302     concat [ [(m,True), (m,False)] | m <- ms_srcimps s ]
1303          ++ [ (m,False) | m <- ms_imps s ]
1304
1305 -----------------------------------------------------------------------------
1306 -- Summarising modules
1307
1308 -- We have two types of summarisation:
1309 --
1310 --    * Summarise a file.  This is used for the root module(s) passed to
1311 --      cmLoadModules.  The file is read, and used to determine the root
1312 --      module name.  The module name may differ from the filename.
1313 --
1314 --    * Summarise a module.  We are given a module name, and must provide
1315 --      a summary.  The finder is used to locate the file in which the module
1316 --      resides.
1317
1318 summariseFile
1319         :: HscEnv
1320         -> [ModSummary]                 -- old summaries
1321         -> FilePath                     -- source file name
1322         -> Maybe Phase                  -- start phase
1323         -> Maybe (StringBuffer,ClockTime)
1324         -> IO ModSummary
1325
1326 summariseFile hsc_env old_summaries file mb_phase maybe_buf
1327         -- we can use a cached summary if one is available and the
1328         -- source file hasn't changed,  But we have to look up the summary
1329         -- by source file, rather than module name as we do in summarise.
1330    | Just old_summary <- findSummaryBySourceFile old_summaries file
1331    = do
1332         let location = ms_location old_summary
1333
1334                 -- return the cached summary if the source didn't change
1335         src_timestamp <- case maybe_buf of
1336                            Just (_,t) -> return t
1337                            Nothing    -> getModificationTime file
1338
1339         if ms_hs_date old_summary == src_timestamp
1340            then do -- update the object-file timestamp
1341                   obj_timestamp <- getObjTimestamp location False
1342                   return old_summary{ ms_obj_date = obj_timestamp }
1343            else
1344                 new_summary
1345
1346    | otherwise
1347    = new_summary
1348   where
1349     new_summary = do
1350         let dflags = hsc_dflags hsc_env
1351
1352         (dflags', hspp_fn, buf)
1353             <- preprocessFile dflags file mb_phase maybe_buf
1354
1355         (srcimps,the_imps, L _ mod) <- getImports dflags' buf hspp_fn
1356
1357         -- Make a ModLocation for this file
1358         location <- mkHomeModLocation dflags mod file
1359
1360         -- Tell the Finder cache where it is, so that subsequent calls
1361         -- to findModule will find it, even if it's not on any search path
1362         addHomeModuleToFinder hsc_env mod location
1363
1364         src_timestamp <- case maybe_buf of
1365                            Just (_,t) -> return t
1366                            Nothing    -> getModificationTime file
1367
1368         obj_timestamp <- modificationTimeIfExists (ml_obj_file location)
1369
1370         return (ModSummary { ms_mod = mod, ms_hsc_src = HsSrcFile,
1371                              ms_location = location,
1372                              ms_hspp_file = Just hspp_fn,
1373                              ms_hspp_buf  = Just buf,
1374                              ms_srcimps = srcimps, ms_imps = the_imps,
1375                              ms_hs_date = src_timestamp,
1376                              ms_obj_date = obj_timestamp })
1377
1378 findSummaryBySourceFile :: [ModSummary] -> FilePath -> Maybe ModSummary
1379 findSummaryBySourceFile summaries file
1380   = case [ ms | ms <- summaries, HsSrcFile <- [ms_hsc_src ms],
1381                                  fromJust (ml_hs_file (ms_location ms)) == file ] of
1382         [] -> Nothing
1383         (x:xs) -> Just x
1384
1385 -- Summarise a module, and pick up source and timestamp.
1386 summariseModule
1387           :: HscEnv
1388           -> NodeMap ModSummary -- Map of old summaries
1389           -> IsBootInterface    -- True <=> a {-# SOURCE #-} import
1390           -> Located Module     -- Imported module to be summarised
1391           -> Maybe (StringBuffer, ClockTime)
1392           -> [Module]           -- Modules to exclude
1393           -> IO (Maybe ModSummary)      -- Its new summary
1394
1395 summariseModule hsc_env old_summary_map is_boot (L loc wanted_mod) maybe_buf excl_mods
1396   | wanted_mod `elem` excl_mods
1397   = return Nothing
1398
1399   | Just old_summary <- lookupFM old_summary_map (wanted_mod, hsc_src)
1400   = do          -- Find its new timestamp; all the
1401                 -- ModSummaries in the old map have valid ml_hs_files
1402         let location = ms_location old_summary
1403             src_fn = expectJust "summariseModule" (ml_hs_file location)
1404
1405                 -- return the cached summary if the source didn't change
1406         src_timestamp <- case maybe_buf of
1407                            Just (_,t) -> return t
1408                            Nothing    -> getModificationTime src_fn
1409
1410         if ms_hs_date old_summary == src_timestamp
1411            then do -- update the object-file timestamp
1412                   obj_timestamp <- getObjTimestamp location is_boot
1413                   return (Just old_summary{ ms_obj_date = obj_timestamp })
1414            else
1415                 -- source changed: re-summarise
1416                 new_summary location src_fn maybe_buf src_timestamp
1417
1418   | otherwise
1419   = do  found <- findModule hsc_env wanted_mod True {-explicit-}
1420         case found of
1421              Found location pkg
1422                 | not (isHomePackage pkg) -> return Nothing
1423                         -- Drop external-pkg
1424                 | isJust (ml_hs_file location) -> just_found location
1425                         -- Home package
1426              err -> noModError dflags loc wanted_mod err
1427                         -- Not found
1428   where
1429     dflags = hsc_dflags hsc_env
1430
1431     hsc_src = if is_boot then HsBootFile else HsSrcFile
1432
1433     just_found location = do
1434                 -- Adjust location to point to the hs-boot source file,
1435                 -- hi file, object file, when is_boot says so
1436         let location' | is_boot   = addBootSuffixLocn location
1437                       | otherwise = location
1438             src_fn = expectJust "summarise2" (ml_hs_file location')
1439
1440                 -- Check that it exists
1441                 -- It might have been deleted since the Finder last found it
1442         maybe_t <- modificationTimeIfExists src_fn
1443         case maybe_t of
1444           Nothing -> noHsFileErr loc src_fn
1445           Just t  -> new_summary location' src_fn Nothing t
1446
1447
1448     new_summary location src_fn maybe_bug src_timestamp
1449       = do
1450         -- Preprocess the source file and get its imports
1451         -- The dflags' contains the OPTIONS pragmas
1452         (dflags', hspp_fn, buf) <- preprocessFile dflags src_fn Nothing maybe_buf
1453         (srcimps, the_imps, L mod_loc mod_name) <- getImports dflags' buf hspp_fn
1454
1455         when (mod_name /= wanted_mod) $
1456                 throwDyn $ mkPlainErrMsg mod_loc $
1457                               text "file name does not match module name"
1458                               <+> quotes (ppr mod_name)
1459
1460                 -- Find the object timestamp, and return the summary
1461         obj_timestamp <- getObjTimestamp location is_boot
1462
1463         return (Just ( ModSummary { ms_mod       = wanted_mod,
1464                                     ms_hsc_src   = hsc_src,
1465                                     ms_location  = location,
1466                                     ms_hspp_file = Just hspp_fn,
1467                                     ms_hspp_buf  = Just buf,
1468                                     ms_srcimps   = srcimps,
1469                                     ms_imps      = the_imps,
1470                                     ms_hs_date   = src_timestamp,
1471                                     ms_obj_date  = obj_timestamp }))
1472
1473
1474 getObjTimestamp location is_boot
1475   = if is_boot then return Nothing
1476                else modificationTimeIfExists (ml_obj_file location)
1477
1478
1479 preprocessFile :: DynFlags -> FilePath -> Maybe Phase -> Maybe (StringBuffer,ClockTime)
1480   -> IO (DynFlags, FilePath, StringBuffer)
1481 preprocessFile dflags src_fn mb_phase Nothing
1482   = do
1483         (dflags', hspp_fn) <- preprocess dflags (src_fn, mb_phase)
1484         buf <- hGetStringBuffer hspp_fn
1485         return (dflags', hspp_fn, buf)
1486
1487 preprocessFile dflags src_fn mb_phase (Just (buf, time))
1488   = do
1489         -- case we bypass the preprocessing stage?
1490         let
1491             local_opts = getOptionsFromStringBuffer buf
1492         --
1493         (dflags', errs) <- parseDynamicFlags dflags (map snd local_opts)
1494
1495         let
1496             needs_preprocessing
1497                 | Just (Unlit _) <- mb_phase    = True
1498                 | Nothing <- mb_phase, Unlit _ <- startPhase src_fn  = True
1499                   -- note: local_opts is only required if there's no Unlit phase
1500                 | dopt Opt_Cpp dflags'          = True
1501                 | dopt Opt_Pp  dflags'          = True
1502                 | otherwise                     = False
1503
1504         when needs_preprocessing $
1505            ghcError (ProgramError "buffer needs preprocesing; interactive check disabled")
1506
1507         return (dflags', src_fn, buf)
1508
1509
1510 -----------------------------------------------------------------------------
1511 --                      Error messages
1512 -----------------------------------------------------------------------------
1513
1514 noModError :: DynFlags -> SrcSpan -> Module -> FindResult -> IO ab
1515 -- ToDo: we don't have a proper line number for this error
1516 noModError dflags loc wanted_mod err
1517   = throwDyn $ mkPlainErrMsg loc $ cantFindError dflags wanted_mod err
1518
1519 noHsFileErr loc path
1520   = throwDyn $ mkPlainErrMsg loc $ text "Can't find" <+> text path
1521
1522 packageModErr mod
1523   = throwDyn $ mkPlainErrMsg noSrcSpan $
1524         text "module" <+> quotes (ppr mod) <+> text "is a package module"
1525
1526 multiRootsErr mod files
1527   = throwDyn $ mkPlainErrMsg noSrcSpan $
1528         text "module" <+> quotes (ppr mod) <+>
1529         text "is defined in multiple files:" <+>
1530         sep (map text files)
1531
1532 cyclicModuleErr :: [ModSummary] -> SDoc
1533 cyclicModuleErr ms
1534   = hang (ptext SLIT("Module imports form a cycle for modules:"))
1535        2 (vcat (map show_one ms))
1536   where
1537     show_one ms = sep [ show_mod (ms_hsc_src ms) (ms_mod ms),
1538                         nest 2 $ ptext SLIT("imports:") <+>
1539                                    (pp_imps HsBootFile (ms_srcimps ms)
1540                                    $$ pp_imps HsSrcFile  (ms_imps ms))]
1541     show_mod hsc_src mod = ppr mod <> text (hscSourceString hsc_src)
1542     pp_imps src mods = fsep (map (show_mod src) mods)
1543
1544
1545 -- | Inform GHC that the working directory has changed.  GHC will flush
1546 -- its cache of module locations, since it may no longer be valid.
1547 -- Note: if you change the working directory, you should also unload
1548 -- the current program (set targets to empty, followed by load).
1549 workingDirectoryChanged :: Session -> IO ()
1550 workingDirectoryChanged s = withSession s $ \hsc_env ->
1551   flushFinderCache (hsc_FC hsc_env)
1552
1553 -- -----------------------------------------------------------------------------
1554 -- inspecting the session
1555
1556 -- | Get the module dependency graph.
1557 getModuleGraph :: Session -> IO ModuleGraph -- ToDo: DiGraph ModSummary
1558 getModuleGraph s = withSession s (return . hsc_mod_graph)
1559
1560 isLoaded :: Session -> Module -> IO Bool
1561 isLoaded s m = withSession s $ \hsc_env ->
1562   return $! isJust (lookupModuleEnv (hsc_HPT hsc_env) m)
1563
1564 getBindings :: Session -> IO [TyThing]
1565 getBindings s = withSession s (return . nameEnvElts . ic_type_env . hsc_IC)
1566
1567 getPrintUnqual :: Session -> IO PrintUnqualified
1568 getPrintUnqual s = withSession s (return . icPrintUnqual . hsc_IC)
1569
1570 -- | Container for information about a 'Module'.
1571 data ModuleInfo = ModuleInfo {
1572         minf_type_env  :: TypeEnv,
1573         minf_exports   :: NameSet,
1574         minf_rdr_env   :: Maybe GlobalRdrEnv,   -- Nothing for a compiled/package mod
1575         minf_instances :: [Instance]
1576         -- ToDo: this should really contain the ModIface too
1577   }
1578         -- We don't want HomeModInfo here, because a ModuleInfo applies
1579         -- to package modules too.
1580
1581 -- | Request information about a loaded 'Module'
1582 getModuleInfo :: Session -> Module -> IO (Maybe ModuleInfo)
1583 getModuleInfo s mdl = withSession s $ \hsc_env -> do
1584   let mg = hsc_mod_graph hsc_env
1585   if mdl `elem` map ms_mod mg
1586         then getHomeModuleInfo hsc_env mdl
1587         else do
1588   if isHomeModule (hsc_dflags hsc_env) mdl
1589         then return Nothing
1590         else getPackageModuleInfo hsc_env mdl
1591    -- getPackageModuleInfo will attempt to find the interface, so
1592    -- we don't want to call it for a home module, just in case there
1593    -- was a problem loading the module and the interface doesn't
1594    -- exist... hence the isHomeModule test here.
1595
1596 getPackageModuleInfo :: HscEnv -> Module -> IO (Maybe ModuleInfo)
1597 getPackageModuleInfo hsc_env mdl = do
1598 #ifdef GHCI
1599   (_msgs, mb_names) <- getModuleExports hsc_env mdl
1600   case mb_names of
1601     Nothing -> return Nothing
1602     Just names -> do
1603         eps <- readIORef (hsc_EPS hsc_env)
1604         let
1605             pte    = eps_PTE eps
1606             n_list = nameSetToList names
1607             tys    = [ ty | name <- n_list,
1608                             Just ty <- [lookupTypeEnv pte name] ]
1609         --
1610         return (Just (ModuleInfo {
1611                         minf_type_env  = mkTypeEnv tys,
1612                         minf_exports   = names,
1613                         minf_rdr_env   = Just $! nameSetToGlobalRdrEnv names mdl,
1614                         minf_instances = error "getModuleInfo: instances for package module unimplemented"
1615                 }))
1616 #else
1617   -- bogusly different for non-GHCI (ToDo)
1618   return Nothing
1619 #endif
1620
1621 getHomeModuleInfo hsc_env mdl =
1622   case lookupModuleEnv (hsc_HPT hsc_env) mdl of
1623     Nothing  -> return Nothing
1624     Just hmi -> do
1625       let details = hm_details hmi
1626       return (Just (ModuleInfo {
1627                         minf_type_env  = md_types details,
1628                         minf_exports   = md_exports details,
1629                         minf_rdr_env   = mi_globals $! hm_iface hmi,
1630                         minf_instances = md_insts details
1631                         }))
1632
1633 -- | The list of top-level entities defined in a module
1634 modInfoTyThings :: ModuleInfo -> [TyThing]
1635 modInfoTyThings minf = typeEnvElts (minf_type_env minf)
1636
1637 modInfoTopLevelScope :: ModuleInfo -> Maybe [Name]
1638 modInfoTopLevelScope minf
1639   = fmap (map gre_name . globalRdrEnvElts) (minf_rdr_env minf)
1640
1641 modInfoExports :: ModuleInfo -> [Name]
1642 modInfoExports minf = nameSetToList $! minf_exports minf
1643
1644 -- | Returns the instances defined by the specified module.
1645 -- Warning: currently unimplemented for package modules.
1646 modInfoInstances :: ModuleInfo -> [Instance]
1647 modInfoInstances = minf_instances
1648
1649 modInfoIsExportedName :: ModuleInfo -> Name -> Bool
1650 modInfoIsExportedName minf name = elemNameSet name (minf_exports minf)
1651
1652 modInfoPrintUnqualified :: ModuleInfo -> Maybe PrintUnqualified
1653 modInfoPrintUnqualified minf = fmap unQualInScope (minf_rdr_env minf)
1654
1655 modInfoLookupName :: Session -> ModuleInfo -> Name -> IO (Maybe TyThing)
1656 modInfoLookupName s minf name = withSession s $ \hsc_env -> do
1657    case lookupTypeEnv (minf_type_env minf) name of
1658      Just tyThing -> return (Just tyThing)
1659      Nothing      -> do
1660        eps <- readIORef (hsc_EPS hsc_env)
1661        return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1662
1663 isDictonaryId :: Id -> Bool
1664 isDictonaryId id
1665   = case tcSplitSigmaTy (idType id) of { (tvs, theta, tau) -> isDictTy tau }
1666
1667 -- | Looks up a global name: that is, any top-level name in any
1668 -- visible module.  Unlike 'lookupName', lookupGlobalName does not use
1669 -- the interactive context, and therefore does not require a preceding
1670 -- 'setContext'.
1671 lookupGlobalName :: Session -> Name -> IO (Maybe TyThing)
1672 lookupGlobalName s name = withSession s $ \hsc_env -> do
1673    eps <- readIORef (hsc_EPS hsc_env)
1674    return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1675
1676 #if 0
1677
1678 data ObjectCode
1679   = ByteCode
1680   | BinaryCode FilePath
1681
1682 -- ToDo: typechecks abstract syntax or renamed abstract syntax.  Issues:
1683 --   - typechecked syntax includes extra dictionary translation and
1684 --     AbsBinds which need to be translated back into something closer to
1685 --     the original source.
1686
1687 -- ToDo:
1688 --   - Data and Typeable instances for HsSyn.
1689
1690 -- ToDo:
1691 --   - things that aren't in the output of the renamer:
1692 --     - the export list
1693 --     - the imports
1694
1695 -- ToDo:
1696 --   - things that aren't in the output of the typechecker right now:
1697 --     - the export list
1698 --     - the imports
1699 --     - type signatures
1700 --     - type/data/newtype declarations
1701 --     - class declarations
1702 --     - instances
1703 --   - extra things in the typechecker's output:
1704 --     - default methods are turned into top-level decls.
1705 --     - dictionary bindings
1706
1707 -- ToDo: check for small transformations that happen to the syntax in
1708 -- the typechecker (eg. -e ==> negate e, perhaps for fromIntegral)
1709
1710 -- ToDo: maybe use TH syntax instead of IfaceSyn?  There's already a way
1711 -- to get from TyCons, Ids etc. to TH syntax (reify).
1712
1713 -- :browse will use either lm_toplev or inspect lm_interface, depending
1714 -- on whether the module is interpreted or not.
1715
1716 -- This is for reconstructing refactored source code
1717 -- Calls the lexer repeatedly.
1718 -- ToDo: add comment tokens to token stream
1719 getTokenStream :: Session -> Module -> IO [Located Token]
1720 #endif
1721
1722 -- -----------------------------------------------------------------------------
1723 -- Interactive evaluation
1724
1725 #ifdef GHCI
1726
1727 -- | Set the interactive evaluation context.
1728 --
1729 -- Setting the context doesn't throw away any bindings; the bindings
1730 -- we've built up in the InteractiveContext simply move to the new
1731 -- module.  They always shadow anything in scope in the current context.
1732 setContext :: Session
1733            -> [Module]  -- entire top level scope of these modules
1734            -> [Module]  -- exports only of these modules
1735            -> IO ()
1736 setContext (Session ref) toplevs exports = do
1737   hsc_env <- readIORef ref
1738   let old_ic  = hsc_IC     hsc_env
1739       hpt     = hsc_HPT    hsc_env
1740
1741   mapM_ (checkModuleExists hsc_env hpt) exports
1742   export_env  <- mkExportEnv hsc_env exports
1743   toplev_envs <- mapM (mkTopLevEnv hpt) toplevs
1744   let all_env = foldr plusGlobalRdrEnv export_env toplev_envs
1745   writeIORef ref hsc_env{ hsc_IC = old_ic { ic_toplev_scope = toplevs,
1746                                             ic_exports      = exports,
1747                                             ic_rn_gbl_env   = all_env } }
1748
1749 -- Make a GlobalRdrEnv based on the exports of the modules only.
1750 mkExportEnv :: HscEnv -> [Module] -> IO GlobalRdrEnv
1751 mkExportEnv hsc_env mods = do
1752   stuff <- mapM (getModuleExports hsc_env) mods
1753   let
1754         (_msgs, mb_name_sets) = unzip stuff
1755         gres = [ nameSetToGlobalRdrEnv name_set mod
1756                | (Just name_set, mod) <- zip mb_name_sets mods ]
1757   --
1758   return $! foldr plusGlobalRdrEnv emptyGlobalRdrEnv gres
1759
1760 nameSetToGlobalRdrEnv :: NameSet -> Module -> GlobalRdrEnv
1761 nameSetToGlobalRdrEnv names mod =
1762   mkGlobalRdrEnv [ GRE  { gre_name = name, gre_prov = vanillaProv mod }
1763                  | name <- nameSetToList names ]
1764
1765 vanillaProv :: Module -> Provenance
1766 -- We're building a GlobalRdrEnv as if the user imported
1767 -- all the specified modules into the global interactive module
1768 vanillaProv mod = Imported [ImpSpec { is_decl = decl, is_item = ImpAll}]
1769   where
1770     decl = ImpDeclSpec { is_mod = mod, is_as = mod,
1771                          is_qual = False,
1772                          is_dloc = srcLocSpan interactiveSrcLoc }
1773
1774 checkModuleExists :: HscEnv -> HomePackageTable -> Module -> IO ()
1775 checkModuleExists hsc_env hpt mod =
1776   case lookupModuleEnv hpt mod of
1777     Just mod_info -> return ()
1778     _not_a_home_module -> do
1779           res <- findPackageModule hsc_env mod True
1780           case res of
1781             Found _ _ -> return  ()
1782             err -> let msg = cantFindError (hsc_dflags hsc_env) mod err in
1783                    throwDyn (CmdLineError (showSDoc msg))
1784
1785 mkTopLevEnv :: HomePackageTable -> Module -> IO GlobalRdrEnv
1786 mkTopLevEnv hpt modl
1787  = case lookupModuleEnv hpt modl of
1788       Nothing ->
1789          throwDyn (ProgramError ("mkTopLevEnv: not a home module "
1790                         ++ showSDoc (pprModule modl)))
1791       Just details ->
1792          case mi_globals (hm_iface details) of
1793                 Nothing  ->
1794                    throwDyn (ProgramError ("mkTopLevEnv: not interpreted "
1795                                                 ++ showSDoc (pprModule modl)))
1796                 Just env -> return env
1797
1798 -- | Get the interactive evaluation context, consisting of a pair of the
1799 -- set of modules from which we take the full top-level scope, and the set
1800 -- of modules from which we take just the exports respectively.
1801 getContext :: Session -> IO ([Module],[Module])
1802 getContext s = withSession s (\HscEnv{ hsc_IC=ic } ->
1803                                 return (ic_toplev_scope ic, ic_exports ic))
1804
1805 -- | Returns 'True' if the specified module is interpreted, and hence has
1806 -- its full top-level scope available.
1807 moduleIsInterpreted :: Session -> Module -> IO Bool
1808 moduleIsInterpreted s modl = withSession s $ \h ->
1809  case lookupModuleEnv (hsc_HPT h) modl of
1810       Just details       -> return (isJust (mi_globals (hm_iface details)))
1811       _not_a_home_module -> return False
1812
1813 -- | Looks up an identifier in the current interactive context (for :info)
1814 {-# DEPRECATED getInfo "we should be using parseName/lookupName instead" #-}
1815 getInfo :: Session -> String -> IO [GetInfoResult]
1816 getInfo s id = withSession s $ \hsc_env -> hscGetInfo hsc_env id
1817
1818 -- | Returns all names in scope in the current interactive context
1819 getNamesInScope :: Session -> IO [Name]
1820 getNamesInScope s = withSession s $ \hsc_env -> do
1821   return (map gre_name (globalRdrEnvElts (ic_rn_gbl_env (hsc_IC hsc_env))))
1822
1823 -- | Parses a string as an identifier, and returns the list of 'Name's that
1824 -- the identifier can refer to in the current interactive context.
1825 parseName :: Session -> String -> IO [Name]
1826 parseName s str = withSession s $ \hsc_env -> do
1827    maybe_rdr_name <- hscParseIdentifier (hsc_dflags hsc_env) str
1828    case maybe_rdr_name of
1829         Nothing -> return []
1830         Just (L _ rdr_name) -> do
1831             mb_names <- tcRnLookupRdrName hsc_env rdr_name
1832             case mb_names of
1833                 Nothing -> return []
1834                 Just ns -> return ns
1835                 -- ToDo: should return error messages
1836
1837 -- | Returns the 'TyThing' for a 'Name'.  The 'Name' may refer to any
1838 -- entity known to GHC, including 'Name's defined using 'runStmt'.
1839 lookupName :: Session -> Name -> IO (Maybe TyThing)
1840 lookupName s name = withSession s $ \hsc_env -> do
1841   case lookupTypeEnv (ic_type_env (hsc_IC hsc_env)) name of
1842         Just tt -> return (Just tt)
1843         Nothing -> do
1844             eps <- readIORef (hsc_EPS hsc_env)
1845             return $! lookupType (hsc_HPT hsc_env) (eps_PTE eps) name
1846
1847 -- -----------------------------------------------------------------------------
1848 -- Getting the type of an expression
1849
1850 -- | Get the type of an expression
1851 exprType :: Session -> String -> IO (Maybe Type)
1852 exprType s expr = withSession s $ \hsc_env -> do
1853    maybe_stuff <- hscTcExpr hsc_env expr
1854    case maybe_stuff of
1855         Nothing -> return Nothing
1856         Just ty -> return (Just tidy_ty)
1857              where
1858                 tidy_ty = tidyType emptyTidyEnv ty
1859                 dflags  = hsc_dflags hsc_env
1860
1861 -- -----------------------------------------------------------------------------
1862 -- Getting the kind of a type
1863
1864 -- | Get the kind of a  type
1865 typeKind  :: Session -> String -> IO (Maybe Kind)
1866 typeKind s str = withSession s $ \hsc_env -> do
1867    maybe_stuff <- hscKcType hsc_env str
1868    case maybe_stuff of
1869         Nothing -> return Nothing
1870         Just kind -> return (Just kind)
1871
1872 -----------------------------------------------------------------------------
1873 -- cmCompileExpr: compile an expression and deliver an HValue
1874
1875 compileExpr :: Session -> String -> IO (Maybe HValue)
1876 compileExpr s expr = withSession s $ \hsc_env -> do
1877   maybe_stuff <- hscStmt hsc_env ("let __cmCompileExpr = "++expr)
1878   case maybe_stuff of
1879         Nothing -> return Nothing
1880         Just (new_ic, names, hval) -> do
1881                         -- Run it!
1882                 hvals <- (unsafeCoerce# hval) :: IO [HValue]
1883
1884                 case (names,hvals) of
1885                   ([n],[hv]) -> return (Just hv)
1886                   _          -> panic "compileExpr"
1887
1888 -- -----------------------------------------------------------------------------
1889 -- running a statement interactively
1890
1891 data RunResult
1892   = RunOk [Name]                -- ^ names bound by this evaluation
1893   | RunFailed                   -- ^ statement failed compilation
1894   | RunException Exception      -- ^ statement raised an exception
1895
1896 -- | Run a statement in the current interactive context.  Statemenet
1897 -- may bind multple values.
1898 runStmt :: Session -> String -> IO RunResult
1899 runStmt (Session ref) expr
1900    = do
1901         hsc_env <- readIORef ref
1902
1903         -- Turn off -fwarn-unused-bindings when running a statement, to hide
1904         -- warnings about the implicit bindings we introduce.
1905         let dflags'  = dopt_unset (hsc_dflags hsc_env) Opt_WarnUnusedBinds
1906             hsc_env' = hsc_env{ hsc_dflags = dflags' }
1907
1908         maybe_stuff <- hscStmt hsc_env' expr
1909
1910         case maybe_stuff of
1911            Nothing -> return RunFailed
1912            Just (new_hsc_env, names, hval) -> do
1913
1914                 let thing_to_run = unsafeCoerce# hval :: IO [HValue]
1915                 either_hvals <- sandboxIO thing_to_run
1916
1917                 case either_hvals of
1918                     Left e -> do
1919                         -- on error, keep the *old* interactive context,
1920                         -- so that 'it' is not bound to something
1921                         -- that doesn't exist.
1922                         return (RunException e)
1923
1924                     Right hvals -> do
1925                         -- Get the newly bound things, and bind them.
1926                         -- Don't need to delete any shadowed bindings;
1927                         -- the new ones override the old ones.
1928                         extendLinkEnv (zip names hvals)
1929
1930                         writeIORef ref new_hsc_env
1931                         return (RunOk names)
1932
1933
1934 -- We run the statement in a "sandbox" to protect the rest of the
1935 -- system from anything the expression might do.  For now, this
1936 -- consists of just wrapping it in an exception handler, but see below
1937 -- for another version.
1938
1939 sandboxIO :: IO a -> IO (Either Exception a)
1940 sandboxIO thing = Exception.try thing
1941
1942 {-
1943 -- This version of sandboxIO runs the expression in a completely new
1944 -- RTS main thread.  It is disabled for now because ^C exceptions
1945 -- won't be delivered to the new thread, instead they'll be delivered
1946 -- to the (blocked) GHCi main thread.
1947
1948 -- SLPJ: when re-enabling this, reflect a wrong-stat error as an exception
1949
1950 sandboxIO :: IO a -> IO (Either Int (Either Exception a))
1951 sandboxIO thing = do
1952   st_thing <- newStablePtr (Exception.try thing)
1953   alloca $ \ p_st_result -> do
1954     stat <- rts_evalStableIO st_thing p_st_result
1955     freeStablePtr st_thing
1956     if stat == 1
1957         then do st_result <- peek p_st_result
1958                 result <- deRefStablePtr st_result
1959                 freeStablePtr st_result
1960                 return (Right result)
1961         else do
1962                 return (Left (fromIntegral stat))
1963
1964 foreign import "rts_evalStableIO"  {- safe -}
1965   rts_evalStableIO :: StablePtr (IO a) -> Ptr (StablePtr a) -> IO CInt
1966   -- more informative than the C type!
1967 -}
1968
1969 -- ---------------------------------------------------------------------------
1970 -- cmBrowseModule: get all the TyThings defined in a module
1971
1972 {-# DEPRECATED browseModule "we should be using getModuleInfo instead" #-}
1973 browseModule :: Session -> Module -> Bool -> IO [IfaceDecl]
1974 browseModule s modl exports_only = withSession s $ \hsc_env -> do
1975   mb_decls <- getModuleContents hsc_env modl exports_only
1976   case mb_decls of
1977         Nothing -> return []            -- An error of some kind
1978         Just ds -> return ds
1979
1980
1981 -----------------------------------------------------------------------------
1982 -- show a module and it's source/object filenames
1983
1984 showModule :: Session -> ModSummary -> IO String
1985 showModule s mod_summary = withSession s $ \hsc_env -> do
1986   case lookupModuleEnv (hsc_HPT hsc_env) (ms_mod mod_summary) of
1987         Nothing       -> panic "missing linkable"
1988         Just mod_info -> return (showModMsg obj_linkable mod_summary)
1989                       where
1990                          obj_linkable = isObjectLinkable (fromJust (hm_linkable mod_info))
1991
1992 #endif /* GHCI */