ghc/compiler/main/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1996
   3 %
   4 \section[MkIface]{Print an interface for a module}
   5
   6 \begin{code}
   7 module MkIface (
   8         startIface, endIface,
   9         ifaceMain,
  10         ifaceDecls
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import IO               ( Handle, hPutStr, openFile,
  16                           hClose, hPutStrLn, IOMode(..) )
  17
  18 import HsSyn
  19 import RdrHsSyn         ( RdrName(..) )
  20 import RnHsSyn          ( RenamedHsModule )
  21 import BasicTypes       ( Fixity(..), FixityDirection(..), NewOrData(..), IfaceFlavour(..),
  22                           pprModule
  23                         )
  24 import RnMonad
  25 import RnEnv            ( availName, ifaceFlavour )
  26
  27 import TcInstUtil       ( InstInfo(..) )
  28 import WorkWrap         ( getWorkerIdAndCons )
  29
  30 import CmdLineOpts
  31 import Id               ( idType, dataConRawArgTys, dataConFieldLabels,
  32                           idInfo, omitIfaceSigForId,
  33                           dataConStrictMarks, StrictnessMark(..),
  34                           IdSet, idSetToList, unionIdSets, unitIdSet, minusIdSet,
  35                           isEmptyIdSet, elementOfIdSet, emptyIdSet, mkIdSet,
  36                           pprId, getIdSpecialisation,
  37                           Id
  38                         )
  39 import IdInfo           ( IdInfo, StrictnessInfo, ArityInfo, InlinePragInfo(..), inlinePragInfo,
  40                           arityInfo, ppArityInfo, strictnessInfo, ppStrictnessInfo,
  41                           bottomIsGuaranteed, workerExists,
  42                         )
  43 import CoreSyn          ( CoreExpr, CoreBinding, GenCoreExpr, GenCoreBinding(..) )
  44 import CoreUnfold       ( calcUnfoldingGuidance, UnfoldingGuidance(..), Unfolding )
  45 import FreeVars         ( addExprFVs )
  46 import Name             ( isLocallyDefined, isWiredInName, modAndOcc, nameModule, pprOccName,
  47                           OccName, occNameString, nameOccName, nameString, isExported,
  48                           Name {-instance NamedThing-}, Provenance, NamedThing(..)
  49                         )
  50 import TyCon            ( TyCon, getSynTyConDefn, isSynTyCon, isNewTyCon, isAlgTyCon,
  51                           tyConTheta, tyConTyVars, tyConDataCons
  52                         )
  53 import Class            ( Class, classBigSig )
  54 import SpecEnv          ( specEnvToList )
  55 import FieldLabel       ( fieldLabelName, fieldLabelType )
  56 import Type             ( mkSigmaTy, splitSigmaTy, mkDictTy,
  57                           mkTyVarTys, Type, ThetaType
  58                         )
  59
  60 import PprEnv           -- not sure how much...
  61 import PprType
  62 import PprCore          ( pprIfaceUnfolding )
  63
  64 import Bag              ( bagToList, isEmptyBag )
  65 import Maybes           ( catMaybes, maybeToBool )
  66 import FiniteMap        ( emptyFM, addToFM, addToFM_C, lookupFM, fmToList, eltsFM, FiniteMap )
  67 import UniqFM           ( UniqFM, lookupUFM, listToUFM )
  68 import Util             ( sortLt, zipWithEqual, zipWith3Equal, mapAccumL )
  69 import Outputable
  70 \end{code}
  71
  72 We have a function @startIface@ to open the output file and put
  73 (something like) ``interface Foo'' in it.  It gives back a handle
  74 for subsequent additions to the interface file.
  75
  76 We then have one-function-per-block-of-interface-stuff, e.g.,
  77 @ifaceExportList@ produces the @__exports__@ section; it appends
  78 to the handle provided by @startIface@.
  79
  80 \begin{code}
  81 startIface  :: Module
  82             -> IO (Maybe Handle) -- Nothing <=> don't do an interface
  83
  84 ifaceMain   :: Maybe Handle
  85             -> InterfaceDetails
  86             -> IO ()
  87
  88
  89 ifaceDecls :: Maybe Handle
  90            -> [TyCon] -> [Class]
  91            -> Bag InstInfo
  92            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
  93            -> [CoreBinding]     -- In dependency order, later depend on earlier
  94            -> IO ()
  95
  96 endIface    :: Maybe Handle -> IO ()
  97 \end{code}
  98
  99 \begin{code}
 100 startIface mod
 101   = case opt_ProduceHi of
 102       Nothing -> return Nothing -- not producing any .hi file
 103       Just fn -> do
 104         if_hdl <- openFile fn WriteMode
 105         hPutStrLn if_hdl ("_interface_ "++ _UNPK_ mod ++ ' ':show (PROJECTVERSION :: Int))
 106         return (Just if_hdl)
 107
 108 endIface Nothing        = return ()
 109 endIface (Just if_hdl)  = hPutStr if_hdl "\n" >> hClose if_hdl
 110 \end{code}
 111
 112
 113 \begin{code}
 114 ifaceMain Nothing iface_stuff = return ()
 115 ifaceMain (Just if_hdl)
 116           (import_usages, ExportEnv avails fixities, instance_modules)
 117   =
 118     ifaceInstanceModules        if_hdl instance_modules         >>
 119     ifaceUsages                 if_hdl import_usages            >>
 120     ifaceExports                if_hdl avails                   >>
 121     ifaceFixities               if_hdl fixities                 >>
 122     return ()
 123
 124 ifaceDecls Nothing tycons classes inst_info final_ids simplified = return ()
 125 ifaceDecls (Just hdl)
 126            tycons classes
 127            inst_infos
 128            final_ids binds
 129   | null_decls = return ()
 130         --  You could have a module with just (re-)exports/instances in it
 131   | otherwise
 132   = ifaceInstances hdl inst_infos               >>= \ needed_ids ->
 133     hPutStr hdl "_declarations_\n"              >>
 134     ifaceClasses hdl classes                    >>
 135     ifaceTyCons hdl tycons                      >>
 136     ifaceBinds hdl needed_ids final_ids binds   >>
 137     return ()
 138   where
 139      null_decls = null binds      &&
 140                   null tycons     &&
 141                   null classes    &&
 142                   isEmptyBag inst_infos
 143 \end{code}
 144
 145 \begin{code}
 146 ifaceUsages if_hdl import_usages
 147   = hPutStr if_hdl "_usages_\n"   >>
 148     hPutCol if_hdl upp_uses (sortLt lt_imp_vers import_usages)
 149   where
 150     upp_uses (m, hif, mv, whats_imported)
 151       = hsep [pprModule m, pp_hif hif, int mv, ptext SLIT("::"),
 152               upp_import_versions whats_imported
 153         ] <> semi
 154
 155         -- Importing the whole module is indicated by an empty list
 156     upp_import_versions Everything = empty
 157
 158         -- For imported versions we do print the version number
 159     upp_import_versions (Specifically nvs)
 160       = hsep [ hsep [ppr_unqual_name n, int v] | (n,v) <- sort_versions nvs ]
 161
 162 ifaceInstanceModules if_hdl [] = return ()
 163 ifaceInstanceModules if_hdl imods
 164   = hPutStr if_hdl "_instance_modules_\n" >>
 165     printForIface if_hdl (hsep (map ptext (sortLt (<) imods))) >>
 166     hPutStr if_hdl "\n"
 167
 168 ifaceExports if_hdl [] = return ()
 169 ifaceExports if_hdl avails
 170   = hPutStr if_hdl "_exports_\n"                        >>
 171     hPutCol if_hdl do_one_module (fmToList export_fm)
 172   where
 173         -- Sort them into groups by module
 174     export_fm :: FiniteMap Module [AvailInfo]
 175     export_fm = foldr insert emptyFM avails
 176
 177     insert NotAvailable efm = efm
 178     insert avail efm = addToFM_C (++) efm mod [avail]
 179                      where
 180                        mod = nameModule (availName avail)
 181
 182         -- Print one module's worth of stuff
 183     do_one_module (mod_name, avails@(avail1:_))
 184         = hsep [pp_hif (ifaceFlavour (availName avail1)),
 185                 pprModule mod_name,
 186                 hsep (map upp_avail (sortLt lt_avail avails))
 187           ] <> semi
 188
 189 -- The "!" indicates that the exported things came from a hi-boot interface
 190 pp_hif HiFile     = empty
 191 pp_hif HiBootFile = char '!'
 192
 193 ifaceFixities if_hdl [] = return ()
 194 ifaceFixities if_hdl fixities
 195   = hPutStr if_hdl "_fixities_\n"               >>
 196     hPutCol if_hdl upp_fixity fixities
 197 \end{code}
 198
 199 %************************************************************************
 200 %*                                                                      *
 201 \subsection{Instance declarations}
 202 %*                                                                      *
 203 %************************************************************************
 204
 205
 206 \begin{code}
 207 ifaceInstances :: Handle -> Bag InstInfo -> IO IdSet            -- The IdSet is the needed dfuns
 208 ifaceInstances if_hdl inst_infos
 209   | null togo_insts = return emptyIdSet
 210   | otherwise       = hPutStr if_hdl "_instances_\n" >>
 211                       hPutCol if_hdl pp_inst (sortLt lt_inst togo_insts) >>
 212                       return needed_ids
 213   where
 214     togo_insts  = filter is_togo_inst (bagToList inst_infos)
 215     needed_ids  = mkIdSet [dfun_id | InstInfo _ _ _ _ _ dfun_id _ _ _ <- togo_insts]
 216     is_togo_inst (InstInfo _ _ _ _ _ dfun_id _ _ _) = isLocallyDefined dfun_id
 217
 218     -------
 219     lt_inst (InstInfo _ _ _ _ _ dfun_id1 _ _ _)
 220             (InstInfo _ _ _ _ _ dfun_id2 _ _ _)
 221       = getOccName dfun_id1 < getOccName dfun_id2
 222         -- The dfuns are assigned names df1, df2, etc, in order of original textual
 223         -- occurrence, and this makes as good a sort order as any
 224
 225     -------
 226     pp_inst (InstInfo clas tvs tys theta _ dfun_id _ _ _)
 227       = let
 228             forall_ty     = mkSigmaTy tvs theta (mkDictTy clas tys)
 229             renumbered_ty = nmbrGlobalType forall_ty
 230         in
 231         hcat [ptext SLIT("instance "), pprType renumbered_ty,
 232                     ptext SLIT(" = "), ppr_unqual_name dfun_id, semi]
 233 \end{code}
 234
 235
 236 %************************************************************************
 237 %*                                                                      *
 238 \subsection{Printing values}
 239 %*                                                                      *
 240 %************************************************************************
 241
 242 \begin{code}
 243 ifaceId :: (Id -> IdInfo)               -- This function "knows" the extra info added
 244                                         -- by the STG passes.  Sigh
 245
 246             -> IdSet                    -- Set of Ids that are needed by earlier interface
 247                                         -- file emissions.  If the Id isn't in this set, and isn't
 248                                         -- exported, there's no need to emit anything
 249             -> Bool                     -- True <=> recursive, so don't print unfolding
 250             -> Id
 251             -> CoreExpr                 -- The Id's right hand side
 252             -> Maybe (SDoc, IdSet)      -- The emitted stuff, plus a possibly-augmented set of needed Ids
 253
 254 ifaceId get_idinfo needed_ids is_rec id rhs
 255   | not (id `elementOfIdSet` needed_ids ||              -- Needed [no id in needed_ids has omitIfaceSigForId]
 256          (isExported id && not (omitIfaceSigForId id))) -- or exported and not to be omitted
 257   = Nothing             -- Well, that was easy!
 258
 259 ifaceId get_idinfo needed_ids is_rec id rhs
 260   = Just (hsep [sig_pretty, pp_double_semi, prag_pretty], new_needed_ids)
 261   where
 262     pp_double_semi = ptext SLIT(";;")
 263     idinfo         = get_idinfo id
 264     inline_pragma  = inlinePragInfo idinfo
 265
 266     ty_pretty  = pprType (nmbrGlobalType (idType id))
 267     sig_pretty = hcat [ppr (getOccName id), ptext SLIT(" _:_ "), ty_pretty]
 268
 269     prag_pretty
 270      | opt_OmitInterfacePragmas = empty
 271      | otherwise                = hsep [arity_pretty, strict_pretty, unfold_pretty, spec_pretty, pp_double_semi]
 272
 273     ------------  Arity  --------------
 274     arity_pretty  = ppArityInfo (arityInfo idinfo)
 275
 276     ------------  Strictness  --------------
 277     strict_info   = strictnessInfo idinfo
 278     has_worker    = workerExists strict_info
 279     strict_pretty = ppStrictnessInfo strict_info <+> wrkr_pretty
 280
 281     wrkr_pretty | not has_worker = empty
 282                 | null con_list  = pprId work_id
 283                 | otherwise      = pprId work_id <+>
 284                                    braces (hsep (map (pprId) con_list))
 285
 286     (work_id, wrapper_cons) = getWorkerIdAndCons id rhs
 287     con_list               = idSetToList wrapper_cons
 288
 289     ------------  Unfolding  --------------
 290     unfold_pretty | show_unfold = hsep [ptext unfold_herald, pprIfaceUnfolding rhs]
 291                   | otherwise   = empty
 292
 293     unfold_herald = case inline_pragma of
 294                         IMustBeINLINEd   -> SLIT("_U_")
 295                         IWantToBeINLINEd -> SLIT("_U_")
 296                         other            -> SLIT("_u_")
 297
 298     show_unfold = not implicit_unfolding &&     -- Not unnecessary
 299                   unfolding_is_ok               -- Not dangerous
 300
 301     implicit_unfolding = has_worker ||
 302                          bottomIsGuaranteed strict_info
 303
 304     unfolding_is_ok
 305         = case inline_pragma of
 306             IMustBeINLINEd    -> True
 307             IWantToBeINLINEd  -> True
 308             IMustNotBeINLINEd -> False
 309             NoPragmaInfo      -> case guidance of
 310                                         UnfoldNever -> False    -- Too big
 311                                         other       -> True
 312
 313     guidance = calcUnfoldingGuidance opt_InterfaceUnfoldThreshold rhs
 314
 315     ------------  Specialisations --------------
 316     spec_pretty = hsep (map pp_spec (specEnvToList (getIdSpecialisation id)))
 317     pp_spec (tyvars, tys, rhs) = hsep [ptext SLIT("_P_"),
 318                                        brackets (interpp'SP tyvars),
 319                                        hsep (map pprParendType tys),
 320                                        ptext SLIT("="),
 321                                        ppr rhs
 322                                  ]
 323
 324     ------------  Extra free Ids  --------------
 325     new_needed_ids = (needed_ids `minusIdSet` unitIdSet id)     `unionIdSets`
 326                      extra_ids
 327
 328     extra_ids | opt_OmitInterfacePragmas = emptyIdSet
 329               | otherwise                = worker_ids   `unionIdSets`
 330                                            unfold_ids
 331
 332     worker_ids | has_worker = unitIdSet work_id
 333                | otherwise  = emptyIdSet
 334
 335     unfold_ids | show_unfold = free_vars
 336                | otherwise   = emptyIdSet
 337                              where
 338                                (_,free_vars) = addExprFVs interesting emptyIdSet rhs
 339                                interesting bound id = isLocallyDefined id &&
 340                                                       not (id `elementOfIdSet` bound) &&
 341                                                       not (omitIfaceSigForId id)
 342 \end{code}
 343
 344 \begin{code}
 345 ifaceBinds :: Handle
 346            -> IdSet             -- These Ids are needed already
 347            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
 348            -> [CoreBinding]     -- In dependency order, later depend on earlier
 349            -> IO ()
 350
 351 ifaceBinds hdl needed_ids final_ids binds
 352   = mapIO (printForIface hdl) pretties >>
 353     hPutStr hdl "\n"
 354   where
 355     final_id_map  = listToUFM [(id,id) | id <- final_ids]
 356     get_idinfo id = case lookupUFM final_id_map id of
 357                         Just id' -> idInfo id'
 358                         Nothing  -> pprTrace "ifaceBinds not found:" (ppr id) $
 359                                     idInfo id
 360
 361     pretties = go needed_ids (reverse binds)    -- Reverse so that later things will
 362                                                 -- provoke earlier ones to be emitted
 363     go needed [] = if not (isEmptyIdSet needed) then
 364                         pprTrace "ifaceBinds: free vars:"
 365                                   (sep (map ppr (idSetToList needed))) $
 366                         []
 367                    else
 368                         []
 369
 370     go needed (NonRec id rhs : binds)
 371         = case ifaceId get_idinfo needed False id rhs of
 372                 Nothing                -> go needed binds
 373                 Just (pretty, needed') -> pretty : go needed' binds
 374
 375         -- Recursive groups are a bit more of a pain.  We may only need one to
 376         -- start with, but it may call out the next one, and so on.  So we
 377         -- have to look for a fixed point.
 378     go needed (Rec pairs : binds)
 379         = pretties ++ go needed'' binds
 380         where
 381           (needed', pretties) = go_rec needed pairs
 382           needed'' = needed' `minusIdSet` mkIdSet (map fst pairs)
 383                 -- Later ones may spuriously cause earlier ones to be "needed" again
 384
 385     go_rec :: IdSet -> [(Id,CoreExpr)] -> (IdSet, [SDoc])
 386     go_rec needed pairs
 387         | null pretties = (needed, [])
 388         | otherwise     = (final_needed, more_pretties ++ pretties)
 389         where
 390           reduced_pairs                 = [pair | (pair,Nothing) <- pairs `zip` maybes]
 391           pretties                      = catMaybes maybes
 392           (needed', maybes)             = mapAccumL do_one needed pairs
 393           (final_needed, more_pretties) = go_rec needed' reduced_pairs
 394
 395           do_one needed (id,rhs) = case ifaceId get_idinfo needed True id rhs of
 396                                         Nothing                -> (needed,  Nothing)
 397                                         Just (pretty, needed') -> (needed', Just pretty)
 398 \end{code}
 399
 400
 401 %************************************************************************
 402 %*                                                                      *
 403 \subsection{Random small things}
 404 %*                                                                      *
 405 %************************************************************************
 406
 407 \begin{code}
 408 ifaceTyCons hdl tycons   = hPutCol hdl upp_tycon (sortLt (<) (filter (for_iface_name . getName) tycons ))
 409 ifaceClasses hdl classes = hPutCol hdl upp_class (sortLt (<) (filter (for_iface_name . getName) classes))
 410
 411 for_iface_name name = isLocallyDefined name &&
 412                       not (isWiredInName name)
 413
 414 upp_tycon tycon = ifaceTyCon tycon
 415 upp_class clas  = ifaceClass clas
 416 \end{code}
 417
 418
 419 \begin{code}
 420 ifaceTyCon :: TyCon -> SDoc
 421 ifaceTyCon tycon
 422   | isSynTyCon tycon
 423   = hsep [ ptext SLIT("type"),
 424            ppr (getName tycon),
 425            pprTyVarBndrs tyvars,
 426            ptext SLIT("="),
 427            ppr ty,
 428            semi
 429     ]
 430   where
 431     (tyvars, ty) = getSynTyConDefn tycon
 432
 433 ifaceTyCon tycon
 434   | isAlgTyCon tycon
 435   = hsep [ ptext keyword,
 436            ppr_decl_context (tyConTheta tycon),
 437            ppr (getName tycon),
 438            pprTyVarBndrs (tyConTyVars tycon),
 439            ptext SLIT("="),
 440            hsep (punctuate (ptext SLIT(" | ")) (map ppr_con (tyConDataCons tycon))),
 441            semi
 442     ]
 443   where
 444     keyword | isNewTyCon tycon = SLIT("newtype")
 445             | otherwise        = SLIT("data")
 446
 447     ppr_con data_con
 448         | null field_labels
 449         = hsep [ ppr name,
 450                   hsep (map ppr_arg_ty (strict_marks `zip` arg_tys))
 451                 ]
 452
 453         | otherwise
 454         = hsep [ ppr name,
 455                   braces $ hsep $ punctuate comma (map ppr_field (strict_marks `zip` field_labels))
 456                 ]
 457           where
 458            field_labels   = dataConFieldLabels data_con
 459            arg_tys        = dataConRawArgTys   data_con
 460            strict_marks   = dataConStrictMarks data_con
 461            name           = getName            data_con
 462
 463     ppr_arg_ty (strict_mark, ty) = ppr_strict_mark strict_mark <> pprParendType ty
 464
 465     ppr_strict_mark NotMarkedStrict = empty
 466     ppr_strict_mark MarkedStrict    = ptext SLIT("! ")
 467                                 -- The extra space helps the lexical analyser that lexes
 468                                 -- interface files; it doesn't make the rigid operator/identifier
 469                                 -- distinction, so "!a" is a valid identifier so far as it is concerned
 470
 471     ppr_field (strict_mark, field_label)
 472         = hsep [ ppr (fieldLabelName field_label),
 473                   ptext SLIT("::"),
 474                   ppr_strict_mark strict_mark <> pprParendType (fieldLabelType field_label)
 475                 ]
 476
 477 ifaceTyCon tycon
 478   = pprPanic "pprIfaceTyDecl" (ppr tycon)
 479
 480 ifaceClass clas
 481   = hsep [ptext SLIT("class"),
 482            ppr_decl_context sc_theta,
 483            ppr clas,                    -- Print the name
 484            pprTyVarBndrs clas_tyvars,
 485            pp_ops,
 486            semi
 487           ]
 488    where
 489      (clas_tyvars, sc_theta, _, sel_ids, defms) = classBigSig clas
 490
 491      pp_ops | null sel_ids  = empty
 492             | otherwise = hsep [ptext SLIT("where"),
 493                                  braces (hsep (punctuate semi (zipWith ppr_classop sel_ids defms)))
 494                           ]
 495
 496      ppr_classop sel_id maybe_defm
 497         = ASSERT( sel_tyvars == clas_tyvars)
 498           hsep [ppr (getOccName sel_id),
 499                 if maybeToBool maybe_defm then equals else empty,
 500                 ptext SLIT("::"),
 501                 ppr op_ty
 502           ]
 503         where
 504           (sel_tyvars, _, op_ty) = splitSigmaTy (idType sel_id)
 505
 506 ppr_decl_context :: ThetaType -> SDoc
 507 ppr_decl_context [] = empty
 508 ppr_decl_context theta
 509   = braces (hsep (punctuate comma (map (ppr_dict) theta)))
 510     <>
 511     ptext SLIT(" =>")
 512   where
 513     ppr_dict (clas,tys) = ppr clas <+> hsep (map pprParendType tys)
 514 \end{code}
 515
 516 %************************************************************************
 517 %*                                                                      *
 518 \subsection{Random small things}
 519 %*                                                                      *
 520 %************************************************************************
 521
 522 When printing export lists, we print like this:
 523         Avail   f               f
 524         AvailTC C [C, x, y]     C(x,y)
 525         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 526
 527 \begin{code}
 528 upp_avail NotAvailable      = empty
 529 upp_avail (Avail name)      = upp_occname (getOccName name)
 530 upp_avail (AvailTC name []) = empty
 531 upp_avail (AvailTC name ns) = hcat [upp_occname (getOccName name), bang, upp_export ns']
 532                             where
 533                               bang | name `elem` ns = empty
 534                                    | otherwise      = char '|'
 535                               ns' = filter (/= name) ns
 536
 537 upp_export []    = empty
 538 upp_export names = parens (hsep (map (upp_occname . getOccName) names))
 539
 540 upp_fixity (occ, fixity) = hcat [ppr fixity, space, upp_occname occ, semi]
 541
 542 ppr_unqual_name :: NamedThing a => a -> SDoc            -- Just its occurrence name
 543 ppr_unqual_name name = upp_occname (getOccName name)
 544
 545 upp_occname :: OccName -> SDoc
 546 upp_occname occ = ptext (occNameString occ)
 547 \end{code}
 548
 549
 550 %************************************************************************
 551 %*                                                                      *
 552 \subsection{Comparisons
 553 %*                                                                      *
 554 %************************************************************************
 555
 556
 557 The various sorts above simply prevent unnecessary "wobbling" when
 558 things change that don't have to.  We therefore compare lexically, not
 559 by unique
 560
 561 \begin{code}
 562 lt_avail :: AvailInfo -> AvailInfo -> Bool
 563
 564 a1 `lt_avail` a2 = availName a1 `lt_name` availName a2
 565
 566 lt_name :: Name -> Name -> Bool
 567 n1 `lt_name` n2 = modAndOcc n1 < modAndOcc n2
 568
 569 lt_lexical :: NamedThing a => a -> a -> Bool
 570 lt_lexical a1 a2 = getName a1 `lt_name` getName a2
 571
 572 lt_imp_vers :: ImportVersion a -> ImportVersion a -> Bool
 573 lt_imp_vers (m1,_,_,_) (m2,_,_,_) = m1 < m2
 574
 575 sort_versions vs = sortLt lt_vers vs
 576
 577 lt_vers :: LocalVersion Name -> LocalVersion Name -> Bool
 578 lt_vers (n1,v1) (n2,v2) = n1 `lt_name` n2
 579 \end{code}
 580
 581
 582 \begin{code}
 583 hPutCol :: Handle
 584         -> (a -> SDoc)
 585         -> [a]
 586         -> IO ()
 587 hPutCol hdl fmt xs = mapIO (printForIface hdl . fmt) xs
 588
 589 mapIO :: (a -> IO b) -> [a] -> IO ()
 590 mapIO f []     = return ()
 591 mapIO f (x:xs) = f x >> mapIO f xs
 592 \end{code}