ghc/compiler/main/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[MkIface]{Print an interface for a module}
   5
   6 \begin{code}
   7 module MkIface (
   8         mkModDetails, mkModDetailsFromIface, completeIface,
   9         writeIface, pprIface
  10   ) where
  11
  12 #include "HsVersions.h"
  13
  14 import HsSyn
  15 import HsCore           ( HsIdInfo(..), UfExpr(..), toUfExpr, toUfBndr )
  16 import HsTypes          ( toHsTyVars )
  17 import BasicTypes       ( Fixity(..), NewOrData(..),
  18                           Version, initialVersion, bumpVersion, isLoopBreaker
  19                         )
  20 import RnMonad
  21 import RnHsSyn          ( RenamedInstDecl, RenamedTyClDecl )
  22 import TcHsSyn          ( TypecheckedRuleDecl )
  23 import HscTypes         ( VersionInfo(..), ModIface(..), ModDetails(..),
  24                           IfaceDecls, mkIfaceDecls, dcl_tycl, dcl_rules, dcl_insts,
  25                           TyThing(..), DFunId, TypeEnv, isTyClThing, Avails,
  26                           WhatsImported(..), GenAvailInfo(..),
  27                           ImportVersion, AvailInfo, Deprecations(..)
  28                         )
  29
  30 import CmdLineOpts
  31 import Id               ( Id, idType, idInfo, omitIfaceSigForId, isExportedId, hasNoBinding,
  32                           idSpecialisation, idName, setIdInfo
  33                         )
  34 import Var              ( isId )
  35 import VarSet
  36 import DataCon          ( StrictnessMark(..), dataConSig, dataConFieldLabels, dataConStrictMarks )
  37 import IdInfo           -- Lots
  38 import CoreSyn          ( CoreExpr, CoreBind, Bind(..), CoreRule(..), IdCoreRule,
  39                           isBuiltinRule, rulesRules, rulesRhsFreeVars, emptyCoreRules,
  40                           bindersOfBinds, mustHaveLocalBinding
  41                         )
  42 import CoreFVs          ( exprSomeFreeVars, ruleSomeLhsFreeVars, ruleSomeFreeVars )
  43 import CoreUnfold       ( okToUnfoldInHiFile, mkTopUnfolding, neverUnfold, unfoldingTemplate, noUnfolding )
  44 import Name             ( getName, nameModule, Name, NamedThing(..) )
  45 import Name     -- Env
  46 import OccName          ( pprOccName )
  47 import TyCon            ( TyCon, getSynTyConDefn, isSynTyCon, isNewTyCon, isAlgTyCon,
  48                           tyConTheta, tyConTyVars, tyConDataCons, tyConFamilySize, isClassTyCon
  49                         )
  50 import Class            ( classExtraBigSig, DefMeth(..) )
  51 import FieldLabel       ( fieldLabelType )
  52 import Type             ( splitSigmaTy, tidyTopType, deNoteType )
  53 import SrcLoc           ( noSrcLoc )
  54 import Outputable
  55 import Module           ( ModuleName )
  56
  57 import List             ( partition )
  58 import IO               ( IOMode(..), openFile, hClose )
  59 \end{code}
  60
  61
  62 %************************************************************************
  63 %*                                                                      *
  64 \subsection{Write a new interface file}
  65 %*                                                                      *
  66 %************************************************************************
  67
  68 \begin{code}
  69 mkModDetails :: TypeEnv -> [DFunId]     -- From typechecker
  70              -> [CoreBind] -> [Id]      -- Final bindings, plus the top-level Ids from the
  71                                         -- code generator; they have authoritative arity info
  72              -> [IdCoreRule]            -- Tidy orphan rules
  73              -> ModDetails
  74 mkModDetails type_env dfun_ids tidy_binds stg_ids orphan_rules
  75   = ModDetails { md_types = new_type_env,
  76                  md_rules = rule_dcls,
  77                  md_insts = dfun_ids }
  78   where
  79         -- The competed type environment is gotten from
  80         --      a) keeping the types and classes
  81         --      b) removing all Ids,
  82         --      c) adding Ids with correct IdInfo, including unfoldings,
  83         --              gotten from the bindings
  84         -- From (c) we keep only those Ids with Global names, plus Ids
  85         --          accessible from them (notably via unfoldings)
  86         -- This truncates the type environment to include only the
  87         -- exported Ids and things needed from them, which saves space
  88         --
  89         -- However, we do keep things like constructors, which should not appear
  90         -- in interface files, because they are needed by importing modules when
  91         -- using the compilation manager
  92     new_type_env = mkNameEnv [(getName tycl, tycl) | tycl <- orig_type_env, isTyClThing tycl]
  93                         `plusNameEnv`
  94                    mkNameEnv [(idName id, AnId id) | id <- final_ids]
  95
  96     orig_type_env = nameEnvElts type_env
  97
  98     final_ids = bindsToIds (mkVarSet dfun_ids `unionVarSet` orphan_rule_ids)
  99                            (mkVarSet stg_ids)
 100                            tidy_binds
 101
 102         -- The complete rules are gotten by combining
 103         --      a) the orphan rules
 104         --      b) rules embedded in the top-level Ids
 105     rule_dcls | opt_OmitInterfacePragmas = []
 106               | otherwise                 = getRules orphan_rules tidy_binds (mkVarSet final_ids)
 107
 108     orphan_rule_ids = unionVarSets [ ruleSomeFreeVars interestingId rule
 109                                    | (_, rule) <- orphan_rules]
 110
 111
 112 -- This version is used when we are re-linking a module
 113 -- so we've only run the type checker on its previous interface
 114 mkModDetailsFromIface :: TypeEnv -> [DFunId]    -- From typechecker
 115                       -> [TypecheckedRuleDecl]
 116                       -> ModDetails
 117 mkModDetailsFromIface type_env dfun_ids rules
 118   = ModDetails { md_types = type_env,
 119                  md_rules = rule_dcls,
 120                  md_insts = dfun_ids }
 121   where
 122     rule_dcls = [(id,rule) | IfaceRuleOut id rule <- rules]
 123         -- All the rules from an interface are of the IfaceRuleOut form
 124
 125
 126 completeIface :: Maybe ModIface         -- The old interface, if we have it
 127               -> ModIface               -- The new one, minus the decls and versions
 128               -> ModDetails             -- The ModDetails for this module
 129               -> (ModIface, Maybe SDoc) -- The new one, complete with decls and versions
 130                                         -- The SDoc is a debug document giving differences
 131                                         -- Nothing => no change
 132
 133         -- NB: 'Nothing' means that even the usages havn't changed, so there's no
 134         --     need to write a new interface file.  But even if the usages have
 135         --     changed, the module version may not have.
 136 completeIface maybe_old_iface new_iface mod_details
 137   = addVersionInfo maybe_old_iface (new_iface { mi_decls = new_decls })
 138   where
 139      new_decls   = mkIfaceDecls ty_cls_dcls rule_dcls inst_dcls
 140      inst_dcls   = map ifaceInstance (md_insts mod_details)
 141      ty_cls_dcls = foldNameEnv ifaceTyCls [] (md_types mod_details)
 142      rule_dcls   = map ifaceRule (md_rules mod_details)
 143 \end{code}
 144
 145
 146 %************************************************************************
 147 %*                                                                      *
 148 \subsection{Types and classes}
 149 %*                                                                      *
 150 %************************************************************************
 151
 152 \begin{code}
 153 ifaceTyCls :: TyThing -> [RenamedTyClDecl] -> [RenamedTyClDecl]
 154 ifaceTyCls (AClass clas) so_far
 155   = cls_decl : so_far
 156   where
 157     cls_decl = ClassDecl (toHsContext sc_theta)
 158                          (getName clas)
 159                          (toHsTyVars clas_tyvars)
 160                          (toHsFDs clas_fds)
 161                          (map toClassOpSig op_stuff)
 162                          EmptyMonoBinds
 163                          [] noSrcLoc
 164
 165     (clas_tyvars, clas_fds, sc_theta, _, op_stuff) = classExtraBigSig clas
 166
 167     toClassOpSig (sel_id, def_meth)
 168         = ASSERT(sel_tyvars == clas_tyvars)
 169           ClassOpSig (getName sel_id) (Just def_meth') (toHsType op_ty) noSrcLoc
 170         where
 171           (sel_tyvars, _, op_ty) = splitSigmaTy (idType sel_id)
 172           def_meth' = case def_meth of
 173                          NoDefMeth  -> NoDefMeth
 174                          GenDefMeth -> GenDefMeth
 175                          DefMeth id -> DefMeth (getName id)
 176
 177 ifaceTyCls (ATyCon tycon) so_far
 178   | isClassTyCon tycon = so_far
 179   | otherwise          = ty_decl : so_far
 180   where
 181     ty_decl | isSynTyCon tycon
 182             = TySynonym (getName tycon)(toHsTyVars tyvars)
 183                         (toHsType syn_ty) noSrcLoc
 184
 185             | isAlgTyCon tycon
 186             = TyData new_or_data (toHsContext (tyConTheta tycon))
 187                      (getName tycon)
 188                      (toHsTyVars tyvars)
 189                      (map ifaceConDecl (tyConDataCons tycon))
 190                      (tyConFamilySize tycon)
 191                      Nothing noSrcLoc (panic "gen1") (panic "gen2")
 192
 193             | otherwise = pprPanic "ifaceTyCls" (ppr tycon)
 194
 195     tyvars      = tyConTyVars tycon
 196     (_, syn_ty) = getSynTyConDefn tycon
 197     new_or_data | isNewTyCon tycon = NewType
 198                 | otherwise        = DataType
 199
 200     ifaceConDecl data_con
 201         = ConDecl (getName data_con) (error "ifaceConDecl")
 202                   (toHsTyVars ex_tyvars)
 203                   (toHsContext ex_theta)
 204                   details noSrcLoc
 205         where
 206           (tyvars1, _, ex_tyvars, ex_theta, arg_tys, tycon1) = dataConSig data_con
 207           field_labels   = dataConFieldLabels data_con
 208           strict_marks   = dataConStrictMarks data_con
 209           details | null field_labels
 210                   = ASSERT( tycon == tycon1 && tyvars == tyvars1 )
 211                     VanillaCon (zipWith mk_bang_ty strict_marks arg_tys)
 212
 213                   | otherwise
 214                   = RecCon (zipWith mk_field strict_marks field_labels)
 215
 216     mk_bang_ty NotMarkedStrict     ty = Unbanged (toHsType ty)
 217     mk_bang_ty (MarkedUnboxed _ _) ty = Unpacked (toHsType ty)
 218     mk_bang_ty MarkedStrict        ty = Banged   (toHsType ty)
 219
 220     mk_field strict_mark field_label
 221         = ([getName field_label], mk_bang_ty strict_mark (fieldLabelType field_label))
 222
 223 ifaceTyCls (AnId id) so_far
 224   | omitIfaceSigForId id = so_far
 225   | otherwise            = iface_sig : so_far
 226   where
 227     iface_sig = IfaceSig (getName id) (toHsType id_type) hs_idinfo noSrcLoc
 228
 229     id_type = idType id
 230     id_info = idInfo id
 231
 232     hs_idinfo | opt_OmitInterfacePragmas = []
 233               | otherwise                = arity_hsinfo  ++ caf_hsinfo  ++ cpr_hsinfo ++
 234                                            strict_hsinfo ++ wrkr_hsinfo ++ unfold_hsinfo
 235
 236     ------------  Arity  --------------
 237     arity_hsinfo = case arityInfo id_info of
 238                         a@(ArityExactly n) -> [HsArity a]
 239                         other              -> []
 240
 241     ------------ Caf Info --------------
 242     caf_hsinfo = case cafInfo id_info of
 243                    NoCafRefs -> [HsNoCafRefs]
 244                    otherwise -> []
 245
 246     ------------ CPR Info --------------
 247     cpr_hsinfo = case cprInfo id_info of
 248                    ReturnsCPR -> [HsCprInfo]
 249                    NoCPRInfo  -> []
 250
 251     ------------  Strictness  --------------
 252     strict_hsinfo = case strictnessInfo id_info of
 253                         NoStrictnessInfo -> []
 254                         info             -> [HsStrictness info]
 255
 256
 257     ------------  Worker  --------------
 258     wrkr_hsinfo = case workerInfo id_info of
 259                     HasWorker work_id wrap_arity -> [HsWorker (getName work_id)]
 260                     NoWorker                     -> []
 261
 262     ------------  Unfolding  --------------
 263     unfold_info = unfoldingInfo id_info
 264     inline_prag = inlinePragInfo id_info
 265     rhs         = unfoldingTemplate unfold_info
 266     unfold_hsinfo | neverUnfold unfold_info = []
 267                   | otherwise               = [HsUnfold inline_prag (toUfExpr rhs)]
 268 \end{code}
 269
 270
 271 %************************************************************************
 272 %*                                                                      *
 273 \subsection{Instances and rules}
 274 %*                                                                      *
 275 %************************************************************************
 276
 277 \begin{code}
 278 ifaceInstance :: DFunId -> RenamedInstDecl
 279 ifaceInstance dfun_id
 280   = InstDecl (toHsType tidy_ty) EmptyMonoBinds [] (Just (getName dfun_id)) noSrcLoc
 281   where
 282     tidy_ty = tidyTopType (deNoteType (idType dfun_id))
 283                 -- The deNoteType is very important.   It removes all type
 284                 -- synonyms from the instance type in interface files.
 285                 -- That in turn makes sure that when reading in instance decls
 286                 -- from interface files that the 'gating' mechanism works properly.
 287                 -- Otherwise you could have
 288                 --      type Tibble = T Int
 289                 --      instance Foo Tibble where ...
 290                 -- and this instance decl wouldn't get imported into a module
 291                 -- that mentioned T but not Tibble.
 292
 293 ifaceRule (id, BuiltinRule _)
 294   = pprTrace "toHsRule: builtin" (ppr id) (bogusIfaceRule id)
 295
 296 ifaceRule (id, Rule name bndrs args rhs)
 297   = IfaceRule name (map toUfBndr bndrs) (getName id)
 298               (map toUfExpr args) (toUfExpr rhs) noSrcLoc
 299
 300 bogusIfaceRule id
 301   = IfaceRule SLIT("bogus") [] (getName id) [] (UfVar (getName id)) noSrcLoc
 302 \end{code}
 303
 304
 305 %************************************************************************
 306 %*                                                                      *
 307 \subsection{Compute final Ids}
 308 %*                                                                      *
 309 %************************************************************************
 310
 311 A "final Id" has exactly the IdInfo for going into an interface file, or
 312 exporting to another module.
 313
 314 \begin{code}
 315 bindsToIds :: IdSet             -- These Ids are needed already
 316            -> IdSet             -- Ids used at code-gen time; they have better pragma info!
 317            -> [CoreBind]        -- In dependency order, later depend on earlier
 318            -> [Id]              -- Set of Ids actually spat out, complete with exactly the IdInfo
 319                                 -- they need for exporting to another module
 320
 321 bindsToIds needed_ids codegen_ids binds
 322   = go needed_ids (reverse binds) []
 323                 -- Reverse so that later things will
 324                 -- provoke earlier ones to be emitted
 325   where
 326         -- The 'needed' set contains the Ids that are needed by earlier
 327         -- interface file emissions.  If the Id isn't in this set, and isn't
 328         -- exported, there's no need to emit anything
 329     need_id needed_set id = id `elemVarSet` needed_set || isExportedId id
 330
 331     go needed [] emitted
 332         | not (isEmptyVarSet needed) = pprTrace "ifaceBinds: free vars:"
 333                                           (sep (map ppr (varSetElems needed)))
 334                                        emitted
 335         | otherwise                  = emitted
 336
 337     go needed (NonRec id rhs : binds) emitted
 338         | need_id needed id = go new_needed binds (new_id:emitted)
 339         | otherwise         = go needed     binds emitted
 340         where
 341           (new_id, extras) = mkFinalId codegen_ids False id rhs
 342           new_needed       = (needed `unionVarSet` extras) `delVarSet` id
 343
 344         -- Recursive groups are a bit more of a pain.  We may only need one to
 345         -- start with, but it may call out the next one, and so on.  So we
 346         -- have to look for a fixed point.  We don't want necessarily them all,
 347         -- because without -O we may only need the first one (if we don't emit
 348         -- its unfolding)
 349     go needed (Rec pairs : binds) emitted
 350         = go needed' binds emitted'
 351         where
 352           (new_emitted, extras) = go_rec needed pairs
 353           needed'  = (needed `unionVarSet` extras) `minusVarSet` mkVarSet (map fst pairs)
 354           emitted' = new_emitted ++ emitted
 355
 356     go_rec :: IdSet -> [(Id,CoreExpr)] -> ([Id], IdSet)
 357     go_rec needed pairs
 358         | null needed_prs = ([], emptyVarSet)
 359         | otherwise       = (emitted ++           more_emitted,
 360                              extras `unionVarSet` more_extras)
 361         where
 362           (needed_prs,leftover_prs)   = partition is_needed pairs
 363           (emitted, extras_s)         = unzip [ mkFinalId codegen_ids True id rhs
 364                                               | (id,rhs) <- needed_prs, not (omitIfaceSigForId id)]
 365           extras                      = unionVarSets extras_s
 366           (more_emitted, more_extras) = go_rec extras leftover_prs
 367
 368           is_needed (id,_) = need_id needed id
 369 \end{code}
 370
 371
 372
 373 \begin{code}
 374 mkFinalId :: IdSet              -- The Ids with arity info from the code generator
 375           -> Bool               -- True <=> recursive, so don't include unfolding
 376           -> Id
 377           -> CoreExpr           -- The Id's right hand side
 378           -> (Id, IdSet)        -- The emitted id, plus any *extra* needed Ids
 379
 380 mkFinalId codegen_ids is_rec id rhs
 381   | omitIfaceSigForId id
 382   = (id, emptyVarSet)           -- An optimisation for top-level constructors and suchlike
 383   | otherwise
 384   = (id `setIdInfo` new_idinfo, new_needed_ids)
 385   where
 386     core_idinfo = idInfo id
 387     stg_idinfo  = case lookupVarSet codegen_ids id of
 388                         Just id' -> idInfo id'
 389                         Nothing  -> pprTrace "ifaceBinds not found:" (ppr id) $
 390                                     idInfo id
 391
 392     new_idinfo | opt_OmitInterfacePragmas
 393                = vanillaIdInfo
 394                | otherwise
 395                = core_idinfo `setArityInfo`      arity_info
 396                              `setCafInfo`        cafInfo stg_idinfo
 397                              `setUnfoldingInfo`  unfold_info
 398                              `setWorkerInfo`     worker_info
 399                              `setSpecInfo`       emptyCoreRules
 400         -- We zap the specialisations because they are
 401         -- passed on separately through the modules IdCoreRules
 402
 403     ------------  Arity  --------------
 404     arity_info = arityInfo stg_idinfo
 405     stg_arity  = arityLowerBound arity_info
 406
 407     ------------  Worker  --------------
 408         -- We only treat a function as having a worker if
 409         -- the exported arity (which is now the number of visible lambdas)
 410         -- is the same as the arity at the moment of the w/w split
 411         -- If so, we can safely omit the unfolding inside the wrapper, and
 412         -- instead re-generate it from the type/arity/strictness info
 413         -- But if the arity has changed, we just take the simple path and
 414         -- put the unfolding into the interface file, forgetting the fact
 415         -- that it's a wrapper.
 416         --
 417         -- How can this happen?  Sometimes we get
 418         --      f = coerce t (\x y -> $wf x y)
 419         -- at the moment of w/w split; but the eta reducer turns it into
 420         --      f = coerce t $wf
 421         -- which is perfectly fine except that the exposed arity so far as
 422         -- the code generator is concerned (zero) differs from the arity
 423         -- when we did the split (2).
 424         --
 425         -- All this arises because we use 'arity' to mean "exactly how many
 426         -- top level lambdas are there" in interface files; but during the
 427         -- compilation of this module it means "how many things can I apply
 428         -- this to".
 429     worker_info = case workerInfo core_idinfo of
 430                      info@(HasWorker work_id wrap_arity)
 431                         | wrap_arity == stg_arity -> info
 432                         | otherwise               -> pprTrace "ifaceId: arity change:" (ppr id)
 433                                                      NoWorker
 434                      NoWorker                     -> NoWorker
 435
 436     has_worker = case worker_info of
 437                    HasWorker _ _ -> True
 438                    other         -> False
 439
 440     HasWorker work_id _ = worker_info
 441
 442     ------------  Unfolding  --------------
 443     inline_pragma  = inlinePragInfo core_idinfo
 444     dont_inline    = isNeverInlinePrag inline_pragma
 445     loop_breaker   = isLoopBreaker (occInfo core_idinfo)
 446     bottoming_fn   = isBottomingStrictness (strictnessInfo core_idinfo)
 447
 448     unfolding    = mkTopUnfolding rhs
 449     rhs_is_small = not (neverUnfold unfolding)
 450
 451     unfold_info | show_unfold = unfolding
 452                 | otherwise   = noUnfolding
 453
 454     show_unfold = not has_worker         &&     -- Not unnecessary
 455                   not bottoming_fn       &&     -- Not necessary
 456                   not dont_inline        &&
 457                   not loop_breaker       &&
 458                   rhs_is_small           &&     -- Small enough
 459                   okToUnfoldInHiFile rhs        -- No casms etc
 460
 461
 462     ------------  Extra free Ids  --------------
 463     new_needed_ids | opt_OmitInterfacePragmas = emptyVarSet
 464                    | otherwise                = worker_ids      `unionVarSet`
 465                                                 unfold_ids      `unionVarSet`
 466                                                 spec_ids
 467
 468     spec_ids = filterVarSet interestingId (rulesRhsFreeVars (specInfo core_idinfo))
 469
 470     worker_ids | has_worker && interestingId work_id = unitVarSet work_id
 471                         -- Conceivably, the worker might come from
 472                         -- another module
 473                | otherwise = emptyVarSet
 474
 475     unfold_ids | show_unfold = find_fvs rhs
 476                | otherwise   = emptyVarSet
 477
 478     find_fvs expr = exprSomeFreeVars interestingId expr
 479
 480 interestingId id = isId id && mustHaveLocalBinding id
 481 \end{code}
 482
 483
 484 \begin{code}
 485 getRules :: [IdCoreRule]        -- Orphan rules
 486          -> [CoreBind]          -- Bindings, with rules in the top-level Ids
 487          -> IdSet               -- Ids that are exported, so we need their rules
 488          -> [IdCoreRule]
 489 getRules orphan_rules binds emitted
 490   = orphan_rules ++ local_rules
 491   where
 492     local_rules  = [ (fn, rule)
 493                    | fn <- bindersOfBinds binds,
 494                      fn `elemVarSet` emitted,
 495                      rule <- rulesRules (idSpecialisation fn),
 496                      not (isBuiltinRule rule),
 497                                 -- We can't print builtin rules in interface files
 498                                 -- Since they are built in, an importing module
 499                                 -- will have access to them anyway
 500
 501                         -- Sept 00: I've disabled this test.  It doesn't stop many, if any, rules
 502                         -- from coming out, and to make it work properly we need to add ????
 503                         --      (put it back in for now)
 504                      all (`elemVarSet` emitted) (varSetElems (ruleSomeLhsFreeVars interestingId rule))
 505                                 -- Spit out a rule only if all its lhs free vars are emitted
 506                                 -- This is a good reason not to do it when we emit the Id itself
 507                    ]
 508 \end{code}
 509
 510
 511 %************************************************************************
 512 %*                                                                      *
 513 \subsection{Checking if the new interface is up to date
 514 %*                                                                      *
 515 %************************************************************************
 516
 517 \begin{code}
 518 addVersionInfo :: Maybe ModIface                -- The old interface, read from M.hi
 519                -> ModIface                      -- The new interface decls
 520                -> (ModIface, Maybe SDoc)        -- Nothing => no change; no need to write new Iface
 521                                                 -- Just mi => Here is the new interface to write
 522                                                 --            with correct version numbers
 523
 524 -- NB: the fixities, declarations, rules are all assumed
 525 -- to be sorted by increasing order of hsDeclName, so that
 526 -- we can compare for equality
 527
 528 addVersionInfo Nothing new_iface
 529 -- No old interface, so definitely write a new one!
 530   = (new_iface, Just (text "No old interface available"))
 531
 532 addVersionInfo (Just old_iface@(ModIface { mi_version = old_version,
 533                                            mi_decls   = old_decls,
 534                                            mi_fixities = old_fixities }))
 535                new_iface@(ModIface { mi_decls = new_decls,
 536                                      mi_fixities = new_fixities })
 537
 538   | no_output_change && no_usage_change
 539   = (old_iface, Nothing)
 540
 541   | otherwise           -- Add updated version numbers
 542   = (final_iface, Just pp_tc_diffs)
 543
 544   where
 545     final_iface = new_iface { mi_version = new_version }
 546     new_version = VersionInfo { vers_module  = bumpVersion no_output_change (vers_module  old_version),
 547                                 vers_exports = bumpVersion no_export_change (vers_exports old_version),
 548                                 vers_rules   = bumpVersion no_rule_change   (vers_rules   old_version),
 549                                 vers_decls   = tc_vers }
 550
 551     no_output_change = no_tc_change && no_rule_change && no_export_change
 552     no_usage_change  = mi_usages old_iface == mi_usages new_iface
 553
 554     no_export_change = mi_exports old_iface == mi_exports new_iface             -- Kept sorted
 555     no_rule_change   = dcl_rules old_decls  == dcl_rules  new_decls             -- Ditto
 556
 557         -- Fill in the version number on the new declarations by looking at the old declarations.
 558         -- Set the flag if anything changes.
 559         -- Assumes that the decls are sorted by hsDeclName.
 560     old_vers_decls = vers_decls old_version
 561     (no_tc_change,  pp_tc_diffs,  tc_vers) = diffDecls old_vers_decls old_fixities new_fixities
 562                                                        (dcl_tycl old_decls) (dcl_tycl new_decls)
 563
 564
 565
 566 diffDecls :: NameEnv Version                            -- Old version map
 567           -> NameEnv Fixity -> NameEnv Fixity           -- Old and new fixities
 568           -> [RenamedTyClDecl] -> [RenamedTyClDecl]     -- Old and new decls
 569           -> (Bool,             -- True <=> no change
 570               SDoc,             -- Record of differences
 571               NameEnv Version)  -- New version
 572
 573 diffDecls old_vers old_fixities new_fixities old new
 574   = diff True empty emptyNameEnv old new
 575   where
 576         -- When seeing if two decls are the same,
 577         -- remember to check whether any relevant fixity has changed
 578     eq_tc  d1 d2 = d1 == d2 && all (same_fixity . fst) (tyClDeclNames d1)
 579     same_fixity n = lookupNameEnv old_fixities n == lookupNameEnv new_fixities n
 580
 581     diff ok_so_far pp new_vers []  []      = (ok_so_far, pp, new_vers)
 582     diff ok_so_far pp new_vers old []      = (False,     pp, new_vers)
 583     diff ok_so_far pp new_vers [] (nd:nds) = diff False (pp $$ only_new nd) new_vers [] nds
 584     diff ok_so_far pp new_vers (od:ods) (nd:nds)
 585         = case nameOccName od_name `compare` nameOccName nd_name of
 586                 LT -> diff False (pp $$ only_old od) new_vers ods      (nd:nds)
 587                 GT -> diff False (pp $$ only_new nd) new_vers (od:ods) nds
 588                 EQ | od `eq_tc` nd -> diff ok_so_far pp                    new_vers  ods nds
 589                    | otherwise     -> diff False     (pp $$ changed od nd) new_vers' ods nds
 590         where
 591           od_name = tyClDeclName od
 592           nd_name = tyClDeclName nd
 593           new_vers' = extendNameEnv new_vers nd_name
 594                                     (bumpVersion True (lookupNameEnv_NF old_vers od_name))
 595
 596     only_old d   = ptext SLIT("Only in old iface:") <+> ppr d
 597     only_new d   = ptext SLIT("Only in new iface:") <+> ppr d
 598     changed d nd = ptext SLIT("Changed in iface: ") <+> ((ptext SLIT("Old:") <+> ppr d) $$
 599                                                          (ptext SLIT("New:") <+> ppr nd))
 600 \end{code}
 601
 602
 603
 604 %************************************************************************
 605 %*                                                                      *
 606 \subsection{Writing an interface file}
 607 %*                                                                      *
 608 %************************************************************************
 609
 610 \begin{code}
 611 writeIface :: FilePath -> ModIface -> IO ()
 612 writeIface hi_path mod_iface
 613   = do  { if_hdl <- openFile hi_path WriteMode
 614         ; printForIface if_hdl from_this_mod (pprIface mod_iface)
 615         ; hClose if_hdl
 616         }
 617   where
 618         -- Print names unqualified if they are from this module
 619     from_this_mod n = nameModule n == this_mod
 620     this_mod = mi_module mod_iface
 621
 622 pprIface :: ModIface -> SDoc
 623 pprIface iface
 624  = vcat [ ptext SLIT("__interface")
 625                 <+> doubleQuotes (ptext opt_InPackage)
 626                 <+> ppr (mi_module iface) <+> ppr (vers_module version_info)
 627                 <+> pp_sub_vers
 628                 <+> (if mi_orphan iface then char '!' else empty)
 629                 <+> int opt_HiVersion
 630                 <+> ptext SLIT("where")
 631
 632         , vcat (map pprExport (mi_exports iface))
 633         , vcat (map pprUsage (mi_usages iface))
 634
 635         , pprFixities (mi_fixities iface) (dcl_tycl decls)
 636         , pprIfaceDecls (vers_decls version_info) decls
 637         , pprDeprecs (mi_deprecs iface)
 638         ]
 639   where
 640     version_info = mi_version iface
 641     decls        = mi_decls iface
 642     exp_vers     = vers_exports version_info
 643     rule_vers    = vers_rules version_info
 644
 645     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
 646                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
 647 \end{code}
 648
 649 When printing export lists, we print like this:
 650         Avail   f               f
 651         AvailTC C [C, x, y]     C(x,y)
 652         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 653
 654 \begin{code}
 655 pprExport :: (ModuleName, Avails) -> SDoc
 656 pprExport (mod, items)
 657  = hsep [ ptext SLIT("__export "), ppr mod, hsep (map pp_avail items) ] <> semi
 658   where
 659     pp_avail :: AvailInfo -> SDoc
 660     pp_avail (Avail name)                    = pprOcc name
 661     pp_avail (AvailTC n [])                  = empty
 662     pp_avail (AvailTC n (n':ns)) | n==n'     = pprOcc n             <> pp_export ns
 663                                  | otherwise = pprOcc n <> char '|' <> pp_export (n':ns)
 664
 665     pp_export []    = empty
 666     pp_export names = braces (hsep (map pprOcc names))
 667
 668 pprOcc :: Name -> SDoc  -- Print the occurrence name only
 669 pprOcc n = pprOccName (nameOccName n)
 670 \end{code}
 671
 672
 673 \begin{code}
 674 pprUsage :: ImportVersion Name -> SDoc
 675 pprUsage (m, has_orphans, is_boot, whats_imported)
 676   = hsep [ptext SLIT("import"), ppr m,
 677           pp_orphan, pp_boot,
 678           pp_versions whats_imported
 679     ] <> semi
 680   where
 681     pp_orphan | has_orphans = char '!'
 682               | otherwise   = empty
 683     pp_boot   | is_boot     = char '@'
 684               | otherwise   = empty
 685
 686         -- Importing the whole module is indicated by an empty list
 687     pp_versions NothingAtAll                = empty
 688     pp_versions (Everything v)              = dcolon <+> int v
 689     pp_versions (Specifically vm ve nvs vr) = dcolon <+> int vm <+> pp_export_version ve <+> int vr
 690                                               <+> hsep [ pprOcc n <+> int v | (n,v) <- nvs ]
 691
 692         -- HACK for the moment: print the export-list version even if
 693         -- we don't use it, so that syntax of interface files doesn't change
 694     pp_export_version Nothing  = int 1
 695     pp_export_version (Just v) = int v
 696 \end{code}
 697
 698 \begin{code}
 699 pprIfaceDecls version_map decls
 700   = vcat [ vcat [ppr i <+> semi | i <- dcl_insts decls]
 701          , vcat (map ppr_decl (dcl_tycl decls))
 702          , pprRules (dcl_rules decls)
 703          ]
 704   where
 705     ppr_decl d  = ppr_vers d <+> ppr d <> semi
 706
 707         -- Print the version for the decl
 708     ppr_vers d = case lookupNameEnv version_map (tyClDeclName d) of
 709                    Nothing -> empty
 710                    Just v  -> int v
 711 \end{code}
 712
 713 \begin{code}
 714 pprFixities fixity_map decls
 715   = hsep [ ppr fix <+> ppr n
 716          | d <- decls,
 717            (n,_) <- tyClDeclNames d,
 718            Just fix <- [lookupNameEnv fixity_map n]] <> semi
 719
 720 pprRules []    = empty
 721 pprRules rules = hsep [ptext SLIT("{-## __R"), vcat (map ppr rules), ptext SLIT("##-}")]
 722
 723 pprDeprecs NoDeprecs = empty
 724 pprDeprecs deprecs   = ptext SLIT("{-## __D") <+> guts <+> ptext SLIT("##-}")
 725                      where
 726                        guts = case deprecs of
 727                                 DeprecAll txt  -> doubleQuotes (ptext txt)
 728                                 DeprecSome env -> pp_deprecs env
 729
 730 pp_deprecs env = vcat (punctuate semi (map pp_deprec (nameEnvElts env)))
 731                where
 732                  pp_deprec (name, txt) = pprOcc name <+> doubleQuotes (ptext txt)
 733 \end{code}