ghc/compiler/main/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1996
   3 %
   4 \section[MkIface]{Print an interface for a module}
   5
   6 \begin{code}
   7 module MkIface (
   8         startIface, endIface,
   9         ifaceMain,
  10         ifaceDecls
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import IO               ( Handle, hPutStr, openFile,
  16                           hClose, hPutStrLn, IOMode(..) )
  17
  18 import HsSyn
  19 import RdrHsSyn         ( RdrName(..) )
  20 import RnHsSyn          ( RenamedHsModule )
  21 import BasicTypes       ( Fixity(..), FixityDirection(..), NewOrData(..), IfaceFlavour(..),
  22                           pprModule
  23                         )
  24 import RnMonad
  25 import RnEnv            ( availName, ifaceFlavour )
  26
  27 import TcInstUtil       ( InstInfo(..) )
  28 import WorkWrap         ( getWorkerIdAndCons )
  29
  30 import CmdLineOpts
  31 import Id               ( idType, dataConRawArgTys, dataConFieldLabels,
  32                           idInfo, omitIfaceSigForId,
  33                           dataConStrictMarks, StrictnessMark(..),
  34                           IdSet, idSetToList, unionIdSets, unitIdSet, minusIdSet,
  35                           isEmptyIdSet, elementOfIdSet, emptyIdSet, mkIdSet,
  36                           pprId, getIdSpecialisation,
  37                           Id
  38                         )
  39 import IdInfo           ( IdInfo, StrictnessInfo, ArityInfo, InlinePragInfo(..), inlinePragInfo,
  40                           arityInfo, ppArityInfo, strictnessInfo, ppStrictnessInfo,
  41                           bottomIsGuaranteed, workerExists,
  42                         )
  43 import CoreSyn          ( CoreExpr, CoreBinding, GenCoreExpr, GenCoreBinding(..) )
  44 import CoreUnfold       ( calcUnfoldingGuidance, UnfoldingGuidance(..), Unfolding,
  45                           okToUnfoldInHiFile
  46                         )
  47 import FreeVars         ( exprFreeVars )
  48 import Name             ( isLocallyDefined, isWiredInName, modAndOcc, nameModule, pprOccName,
  49                           OccName, occNameString, nameOccName, nameString, isExported,
  50                           Name {-instance NamedThing-}, Provenance, NamedThing(..)
  51                         )
  52 import TyCon            ( TyCon, getSynTyConDefn, isSynTyCon, isNewTyCon, isAlgTyCon,
  53                           tyConTheta, tyConTyVars, tyConDataCons
  54                         )
  55 import Class            ( Class, classBigSig )
  56 import SpecEnv          ( specEnvToList )
  57 import FieldLabel       ( fieldLabelName, fieldLabelType )
  58 import Type             ( mkSigmaTy, splitSigmaTy, mkDictTy,
  59                           mkTyVarTys, Type, ThetaType
  60                         )
  61
  62 import PprEnv           -- not sure how much...
  63 import PprType
  64 import PprCore          ( pprIfaceUnfolding )
  65
  66 import Bag              ( bagToList, isEmptyBag )
  67 import Maybes           ( catMaybes, maybeToBool )
  68 import FiniteMap        ( emptyFM, addToFM, addToFM_C, lookupFM, fmToList, eltsFM, FiniteMap )
  69 import UniqFM           ( UniqFM, lookupUFM, listToUFM )
  70 import Util             ( sortLt, zipWithEqual, zipWith3Equal, mapAccumL )
  71 import Outputable
  72 \end{code}
  73
  74 We have a function @startIface@ to open the output file and put
  75 (something like) ``interface Foo'' in it.  It gives back a handle
  76 for subsequent additions to the interface file.
  77
  78 We then have one-function-per-block-of-interface-stuff, e.g.,
  79 @ifaceExportList@ produces the @__exports__@ section; it appends
  80 to the handle provided by @startIface@.
  81
  82 \begin{code}
  83 startIface  :: Module
  84             -> IO (Maybe Handle) -- Nothing <=> don't do an interface
  85
  86 ifaceMain   :: Maybe Handle
  87             -> InterfaceDetails
  88             -> IO ()
  89
  90
  91 ifaceDecls :: Maybe Handle
  92            -> [TyCon] -> [Class]
  93            -> Bag InstInfo
  94            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
  95            -> [CoreBinding]     -- In dependency order, later depend on earlier
  96            -> IO ()
  97
  98 endIface    :: Maybe Handle -> IO ()
  99 \end{code}
 100
 101 \begin{code}
 102 startIface mod
 103   = case opt_ProduceHi of
 104       Nothing -> return Nothing -- not producing any .hi file
 105       Just fn -> do
 106         if_hdl <- openFile fn WriteMode
 107         hPutStrLn if_hdl ("_interface_ "++ _UNPK_ mod ++ ' ':show (PROJECTVERSION :: Int))
 108         return (Just if_hdl)
 109
 110 endIface Nothing        = return ()
 111 endIface (Just if_hdl)  = hPutStr if_hdl "\n" >> hClose if_hdl
 112 \end{code}
 113
 114
 115 \begin{code}
 116 ifaceMain Nothing iface_stuff = return ()
 117 ifaceMain (Just if_hdl)
 118           (import_usages, ExportEnv avails fixities, instance_modules)
 119   =
 120     ifaceInstanceModules        if_hdl instance_modules         >>
 121     ifaceUsages                 if_hdl import_usages            >>
 122     ifaceExports                if_hdl avails                   >>
 123     ifaceFixities               if_hdl fixities                 >>
 124     return ()
 125
 126 ifaceDecls Nothing tycons classes inst_info final_ids simplified = return ()
 127 ifaceDecls (Just hdl)
 128            tycons classes
 129            inst_infos
 130            final_ids binds
 131   | null_decls = return ()
 132         --  You could have a module with just (re-)exports/instances in it
 133   | otherwise
 134   = ifaceInstances hdl inst_infos               >>= \ needed_ids ->
 135     hPutStr hdl "_declarations_\n"              >>
 136     ifaceClasses hdl classes                    >>
 137     ifaceTyCons hdl tycons                      >>
 138     ifaceBinds hdl needed_ids final_ids binds   >>
 139     return ()
 140   where
 141      null_decls = null binds      &&
 142                   null tycons     &&
 143                   null classes    &&
 144                   isEmptyBag inst_infos
 145 \end{code}
 146
 147 \begin{code}
 148 ifaceUsages if_hdl import_usages
 149   = hPutStr if_hdl "_usages_\n"   >>
 150     hPutCol if_hdl upp_uses (sortLt lt_imp_vers import_usages)
 151   where
 152     upp_uses (m, hif, mv, whats_imported)
 153       = hsep [pprModule m, pp_hif hif, int mv, ptext SLIT("::"),
 154               upp_import_versions whats_imported
 155         ] <> semi
 156
 157         -- Importing the whole module is indicated by an empty list
 158     upp_import_versions Everything = empty
 159
 160         -- For imported versions we do print the version number
 161     upp_import_versions (Specifically nvs)
 162       = hsep [ hsep [ppr_unqual_name n, int v] | (n,v) <- sort_versions nvs ]
 163
 164 ifaceInstanceModules if_hdl [] = return ()
 165 ifaceInstanceModules if_hdl imods
 166   = hPutStr if_hdl "_instance_modules_\n" >>
 167     printForIface if_hdl (hsep (map ptext (sortLt (<) imods))) >>
 168     hPutStr if_hdl "\n"
 169
 170 ifaceExports if_hdl [] = return ()
 171 ifaceExports if_hdl avails
 172   = hPutStr if_hdl "_exports_\n"                        >>
 173     hPutCol if_hdl do_one_module (fmToList export_fm)
 174   where
 175         -- Sort them into groups by module
 176     export_fm :: FiniteMap Module [AvailInfo]
 177     export_fm = foldr insert emptyFM avails
 178
 179     insert NotAvailable efm = efm
 180     insert avail efm = addToFM_C (++) efm mod [avail]
 181                      where
 182                        mod = nameModule (availName avail)
 183
 184         -- Print one module's worth of stuff
 185     do_one_module (mod_name, avails@(avail1:_))
 186         = hsep [pp_hif (ifaceFlavour (availName avail1)),
 187                 pprModule mod_name,
 188                 hsep (map upp_avail (sortLt lt_avail avails))
 189           ] <> semi
 190
 191 -- The "!" indicates that the exported things came from a hi-boot interface
 192 pp_hif HiFile     = empty
 193 pp_hif HiBootFile = char '!'
 194
 195 ifaceFixities if_hdl [] = return ()
 196 ifaceFixities if_hdl fixities
 197   = hPutStr if_hdl "_fixities_\n"               >>
 198     hPutCol if_hdl upp_fixity fixities
 199 \end{code}
 200
 201 %************************************************************************
 202 %*                                                                      *
 203 \subsection{Instance declarations}
 204 %*                                                                      *
 205 %************************************************************************
 206
 207
 208 \begin{code}
 209 ifaceInstances :: Handle -> Bag InstInfo -> IO IdSet            -- The IdSet is the needed dfuns
 210 ifaceInstances if_hdl inst_infos
 211   | null togo_insts = return emptyIdSet
 212   | otherwise       = hPutStr if_hdl "_instances_\n" >>
 213                       hPutCol if_hdl pp_inst (sortLt lt_inst togo_insts) >>
 214                       return needed_ids
 215   where
 216     togo_insts  = filter is_togo_inst (bagToList inst_infos)
 217     needed_ids  = mkIdSet [dfun_id | InstInfo _ _ _ _ _ dfun_id _ _ _ <- togo_insts]
 218     is_togo_inst (InstInfo _ _ _ _ _ dfun_id _ _ _) = isLocallyDefined dfun_id
 219
 220     -------
 221     lt_inst (InstInfo _ _ _ _ _ dfun_id1 _ _ _)
 222             (InstInfo _ _ _ _ _ dfun_id2 _ _ _)
 223       = getOccName dfun_id1 < getOccName dfun_id2
 224         -- The dfuns are assigned names df1, df2, etc, in order of original textual
 225         -- occurrence, and this makes as good a sort order as any
 226
 227     -------
 228     pp_inst (InstInfo clas tvs tys theta _ dfun_id _ _ _)
 229       = let
 230             forall_ty     = mkSigmaTy tvs theta (mkDictTy clas tys)
 231             renumbered_ty = nmbrGlobalType forall_ty
 232         in
 233         hcat [ptext SLIT("instance "), pprType renumbered_ty,
 234                     ptext SLIT(" = "), ppr_unqual_name dfun_id, semi]
 235 \end{code}
 236
 237
 238 %************************************************************************
 239 %*                                                                      *
 240 \subsection{Printing values}
 241 %*                                                                      *
 242 %************************************************************************
 243
 244 \begin{code}
 245 ifaceId :: (Id -> IdInfo)               -- This function "knows" the extra info added
 246                                         -- by the STG passes.  Sigh
 247
 248             -> IdSet                    -- Set of Ids that are needed by earlier interface
 249                                         -- file emissions.  If the Id isn't in this set, and isn't
 250                                         -- exported, there's no need to emit anything
 251             -> Bool                     -- True <=> recursive, so don't print unfolding
 252             -> Id
 253             -> CoreExpr                 -- The Id's right hand side
 254             -> Maybe (SDoc, IdSet)      -- The emitted stuff, plus a possibly-augmented set of needed Ids
 255
 256 ifaceId get_idinfo needed_ids is_rec id rhs
 257   | not (id `elementOfIdSet` needed_ids ||              -- Needed [no id in needed_ids has omitIfaceSigForId]
 258          (isExported id && not (omitIfaceSigForId id))) -- or exported and not to be omitted
 259   = Nothing             -- Well, that was easy!
 260
 261 ifaceId get_idinfo needed_ids is_rec id rhs
 262   = Just (hsep [sig_pretty, pp_double_semi, prag_pretty], new_needed_ids)
 263   where
 264     pp_double_semi = ptext SLIT(";;")
 265     idinfo         = get_idinfo id
 266     inline_pragma  = inlinePragInfo idinfo
 267
 268     ty_pretty  = pprType (nmbrGlobalType (idType id))
 269     sig_pretty = hcat [ppr (getOccName id), ptext SLIT(" _:_ "), ty_pretty]
 270
 271     prag_pretty
 272      | opt_OmitInterfacePragmas = empty
 273      | otherwise                = hsep [arity_pretty, strict_pretty, unfold_pretty,
 274                                         spec_pretty, pp_double_semi]
 275
 276     ------------  Arity  --------------
 277     arity_pretty  = ppArityInfo (arityInfo idinfo)
 278
 279     ------------  Strictness  --------------
 280     strict_info   = strictnessInfo idinfo
 281     has_worker    = workerExists strict_info
 282     strict_pretty = ppStrictnessInfo strict_info <+> wrkr_pretty
 283
 284     wrkr_pretty | not has_worker = empty
 285                 | null con_list  = pprId work_id
 286                 | otherwise      = pprId work_id <+>
 287                                    braces (hsep (map (pprId) con_list))
 288
 289     (work_id, wrapper_cons) = getWorkerIdAndCons id rhs
 290     con_list               = idSetToList wrapper_cons
 291
 292     ------------  Unfolding  --------------
 293     unfold_pretty | show_unfold = hsep [ptext unfold_herald, pprIfaceUnfolding rhs]
 294                   | otherwise   = empty
 295
 296     unfold_herald = case inline_pragma of
 297                         IMustBeINLINEd   -> SLIT("_U_")
 298                         IWantToBeINLINEd -> SLIT("_U_")
 299                         other            -> SLIT("_u_")
 300
 301     show_unfold = not implicit_unfolding &&     -- Not unnecessary
 302                   unfolding_is_ok               -- Not dangerous
 303
 304     implicit_unfolding = has_worker ||
 305                          bottomIsGuaranteed strict_info
 306
 307     unfolding_is_ok
 308         = case inline_pragma of
 309             IMustBeINLINEd       -> definitely_ok_to_unfold
 310             IWantToBeINLINEd     -> definitely_ok_to_unfold
 311             IDontWantToBeINLINEd -> False
 312             IMustNotBeINLINEd    -> False
 313             NoPragmaInfo         -> case guidance of
 314                                         UnfoldNever -> False    -- Too big
 315                                         other       -> definitely_ok_to_unfold
 316
 317     definitely_ok_to_unfold =  okToUnfoldInHiFile rhs
 318     guidance = calcUnfoldingGuidance opt_InterfaceUnfoldThreshold rhs
 319
 320     ------------  Specialisations --------------
 321     spec_list = specEnvToList (getIdSpecialisation id)
 322     spec_pretty = hsep (map pp_spec spec_list)
 323     pp_spec (tyvars, tys, rhs) = hsep [ptext SLIT("_P_"),
 324                                        if null tyvars then ptext SLIT("[ ]")
 325                                                       else brackets (interppSP tyvars),
 326                                         -- The lexer interprets "[]" as a CONID.  Sigh.
 327                                        hsep (map pprParendType tys),
 328                                        ptext SLIT("="),
 329                                        pprIfaceUnfolding rhs
 330                                  ]
 331
 332     ------------  Extra free Ids  --------------
 333     new_needed_ids = (needed_ids `minusIdSet` unitIdSet id)     `unionIdSets`
 334                      extra_ids
 335
 336     extra_ids | opt_OmitInterfacePragmas = emptyIdSet
 337               | otherwise                = worker_ids   `unionIdSets`
 338                                            unfold_ids   `unionIdSets`
 339                                            spec_ids
 340
 341     worker_ids | has_worker = unitIdSet work_id
 342                | otherwise  = emptyIdSet
 343
 344     spec_ids = foldr add emptyIdSet spec_list
 345              where
 346                add (_, _, rhs) = unionIdSets (find_fvs rhs)
 347
 348     unfold_ids | show_unfold = find_fvs rhs
 349                | otherwise   = emptyIdSet
 350
 351     find_fvs expr = free_vars
 352                   where
 353                     free_vars = exprFreeVars interesting expr
 354                     interesting id = isLocallyDefined id &&
 355                                      not (omitIfaceSigForId id)
 356 \end{code}
 357
 358 \begin{code}
 359 ifaceBinds :: Handle
 360            -> IdSet             -- These Ids are needed already
 361            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
 362            -> [CoreBinding]     -- In dependency order, later depend on earlier
 363            -> IO ()
 364
 365 ifaceBinds hdl needed_ids final_ids binds
 366   = mapIO (printForIface hdl) pretties >>
 367     hPutStr hdl "\n"
 368   where
 369     final_id_map  = listToUFM [(id,id) | id <- final_ids]
 370     get_idinfo id = case lookupUFM final_id_map id of
 371                         Just id' -> idInfo id'
 372                         Nothing  -> pprTrace "ifaceBinds not found:" (ppr id) $
 373                                     idInfo id
 374
 375     pretties = go needed_ids (reverse binds)    -- Reverse so that later things will
 376                                                 -- provoke earlier ones to be emitted
 377     go needed [] = if not (isEmptyIdSet needed) then
 378                         pprTrace "ifaceBinds: free vars:"
 379                                   (sep (map ppr (idSetToList needed))) $
 380                         []
 381                    else
 382                         []
 383
 384     go needed (NonRec id rhs : binds)
 385         = case ifaceId get_idinfo needed False id rhs of
 386                 Nothing                -> go needed binds
 387                 Just (pretty, needed') -> pretty : go needed' binds
 388
 389         -- Recursive groups are a bit more of a pain.  We may only need one to
 390         -- start with, but it may call out the next one, and so on.  So we
 391         -- have to look for a fixed point.
 392     go needed (Rec pairs : binds)
 393         = pretties ++ go needed'' binds
 394         where
 395           (needed', pretties) = go_rec needed pairs
 396           needed'' = needed' `minusIdSet` mkIdSet (map fst pairs)
 397                 -- Later ones may spuriously cause earlier ones to be "needed" again
 398
 399     go_rec :: IdSet -> [(Id,CoreExpr)] -> (IdSet, [SDoc])
 400     go_rec needed pairs
 401         | null pretties = (needed, [])
 402         | otherwise     = (final_needed, more_pretties ++ pretties)
 403         where
 404           reduced_pairs                 = [pair | (pair,Nothing) <- pairs `zip` maybes]
 405           pretties                      = catMaybes maybes
 406           (needed', maybes)             = mapAccumL do_one needed pairs
 407           (final_needed, more_pretties) = go_rec needed' reduced_pairs
 408
 409           do_one needed (id,rhs) = case ifaceId get_idinfo needed True id rhs of
 410                                         Nothing                -> (needed,  Nothing)
 411                                         Just (pretty, needed') -> (needed', Just pretty)
 412 \end{code}
 413
 414
 415 %************************************************************************
 416 %*                                                                      *
 417 \subsection{Random small things}
 418 %*                                                                      *
 419 %************************************************************************
 420
 421 \begin{code}
 422 ifaceTyCons hdl tycons   = hPutCol hdl upp_tycon (sortLt (<) (filter (for_iface_name . getName) tycons ))
 423 ifaceClasses hdl classes = hPutCol hdl upp_class (sortLt (<) (filter (for_iface_name . getName) classes))
 424
 425 for_iface_name name = isLocallyDefined name &&
 426                       not (isWiredInName name)
 427
 428 upp_tycon tycon = ifaceTyCon tycon
 429 upp_class clas  = ifaceClass clas
 430 \end{code}
 431
 432
 433 \begin{code}
 434 ifaceTyCon :: TyCon -> SDoc
 435 ifaceTyCon tycon
 436   | isSynTyCon tycon
 437   = hsep [ ptext SLIT("type"),
 438            ppr (getName tycon),
 439            pprTyVarBndrs tyvars,
 440            ptext SLIT("="),
 441            ppr ty,
 442            semi
 443     ]
 444   where
 445     (tyvars, ty) = getSynTyConDefn tycon
 446
 447 ifaceTyCon tycon
 448   | isAlgTyCon tycon
 449   = hsep [ ptext keyword,
 450            ppr_decl_context (tyConTheta tycon),
 451            ppr (getName tycon),
 452            pprTyVarBndrs (tyConTyVars tycon),
 453            ptext SLIT("="),
 454            hsep (punctuate (ptext SLIT(" | ")) (map ppr_con (tyConDataCons tycon))),
 455            semi
 456     ]
 457   where
 458     keyword | isNewTyCon tycon = SLIT("newtype")
 459             | otherwise        = SLIT("data")
 460
 461     ppr_con data_con
 462         | null field_labels
 463         = hsep [ ppr name,
 464                   hsep (map ppr_arg_ty (strict_marks `zip` arg_tys))
 465                 ]
 466
 467         | otherwise
 468         = hsep [ ppr name,
 469                   braces $ hsep $ punctuate comma (map ppr_field (strict_marks `zip` field_labels))
 470                 ]
 471           where
 472            field_labels   = dataConFieldLabels data_con
 473            arg_tys        = dataConRawArgTys   data_con
 474            strict_marks   = dataConStrictMarks data_con
 475            name           = getName            data_con
 476
 477     ppr_arg_ty (strict_mark, ty) = ppr_strict_mark strict_mark <> pprParendType ty
 478
 479     ppr_strict_mark NotMarkedStrict = empty
 480     ppr_strict_mark MarkedStrict    = ptext SLIT("! ")
 481                                 -- The extra space helps the lexical analyser that lexes
 482                                 -- interface files; it doesn't make the rigid operator/identifier
 483                                 -- distinction, so "!a" is a valid identifier so far as it is concerned
 484
 485     ppr_field (strict_mark, field_label)
 486         = hsep [ ppr (fieldLabelName field_label),
 487                   ptext SLIT("::"),
 488                   ppr_strict_mark strict_mark <> pprParendType (fieldLabelType field_label)
 489                 ]
 490
 491 ifaceTyCon tycon
 492   = pprPanic "pprIfaceTyDecl" (ppr tycon)
 493
 494 ifaceClass clas
 495   = hsep [ptext SLIT("class"),
 496            ppr_decl_context sc_theta,
 497            ppr clas,                    -- Print the name
 498            pprTyVarBndrs clas_tyvars,
 499            pp_ops,
 500            semi
 501           ]
 502    where
 503      (clas_tyvars, sc_theta, _, sel_ids, defms) = classBigSig clas
 504
 505      pp_ops | null sel_ids  = empty
 506             | otherwise = hsep [ptext SLIT("where"),
 507                                  braces (hsep (punctuate semi (zipWith ppr_classop sel_ids defms)))
 508                           ]
 509
 510      ppr_classop sel_id maybe_defm
 511         = ASSERT( sel_tyvars == clas_tyvars)
 512           hsep [ppr (getOccName sel_id),
 513                 if maybeToBool maybe_defm then equals else empty,
 514                 ptext SLIT("::"),
 515                 ppr op_ty
 516           ]
 517         where
 518           (sel_tyvars, _, op_ty) = splitSigmaTy (idType sel_id)
 519
 520 ppr_decl_context :: ThetaType -> SDoc
 521 ppr_decl_context [] = empty
 522 ppr_decl_context theta
 523   = braces (hsep (punctuate comma (map (ppr_dict) theta)))
 524     <>
 525     ptext SLIT(" =>")
 526   where
 527     ppr_dict (clas,tys) = ppr clas <+> hsep (map pprParendType tys)
 528 \end{code}
 529
 530 %************************************************************************
 531 %*                                                                      *
 532 \subsection{Random small things}
 533 %*                                                                      *
 534 %************************************************************************
 535
 536 When printing export lists, we print like this:
 537         Avail   f               f
 538         AvailTC C [C, x, y]     C(x,y)
 539         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 540
 541 \begin{code}
 542 upp_avail NotAvailable      = empty
 543 upp_avail (Avail name)      = upp_occname (getOccName name)
 544 upp_avail (AvailTC name []) = empty
 545 upp_avail (AvailTC name ns) = hcat [upp_occname (getOccName name), bang, upp_export ns']
 546                             where
 547                               bang | name `elem` ns = empty
 548                                    | otherwise      = char '|'
 549                               ns' = filter (/= name) ns
 550
 551 upp_export []    = empty
 552 upp_export names = parens (hsep (map (upp_occname . getOccName) names))
 553
 554 upp_fixity (occ, fixity) = hcat [ppr fixity, space, upp_occname occ, semi]
 555
 556 ppr_unqual_name :: NamedThing a => a -> SDoc            -- Just its occurrence name
 557 ppr_unqual_name name = upp_occname (getOccName name)
 558
 559 upp_occname :: OccName -> SDoc
 560 upp_occname occ = ptext (occNameString occ)
 561 \end{code}
 562
 563
 564 %************************************************************************
 565 %*                                                                      *
 566 \subsection{Comparisons
 567 %*                                                                      *
 568 %************************************************************************
 569
 570
 571 The various sorts above simply prevent unnecessary "wobbling" when
 572 things change that don't have to.  We therefore compare lexically, not
 573 by unique
 574
 575 \begin{code}
 576 lt_avail :: AvailInfo -> AvailInfo -> Bool
 577
 578 a1 `lt_avail` a2 = availName a1 `lt_name` availName a2
 579
 580 lt_name :: Name -> Name -> Bool
 581 n1 `lt_name` n2 = modAndOcc n1 < modAndOcc n2
 582
 583 lt_lexical :: NamedThing a => a -> a -> Bool
 584 lt_lexical a1 a2 = getName a1 `lt_name` getName a2
 585
 586 lt_imp_vers :: ImportVersion a -> ImportVersion a -> Bool
 587 lt_imp_vers (m1,_,_,_) (m2,_,_,_) = m1 < m2
 588
 589 sort_versions vs = sortLt lt_vers vs
 590
 591 lt_vers :: LocalVersion Name -> LocalVersion Name -> Bool
 592 lt_vers (n1,v1) (n2,v2) = n1 `lt_name` n2
 593 \end{code}
 594
 595
 596 \begin{code}
 597 hPutCol :: Handle
 598         -> (a -> SDoc)
 599         -> [a]
 600         -> IO ()
 601 hPutCol hdl fmt xs = mapIO (printForIface hdl . fmt) xs
 602
 603 mapIO :: (a -> IO b) -> [a] -> IO ()
 604 mapIO f []     = return ()
 605 mapIO f (x:xs) = f x >> mapIO f xs
 606 \end{code}