ghc/compiler/main/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[MkIface]{Print an interface for a module}
   5
   6 \begin{code}
   7 module MkIface (
   8         mkModDetails, mkModDetailsFromIface, completeIface,
   9         writeIface, pprIface
  10   ) where
  11
  12 #include "HsVersions.h"
  13
  14 import HsSyn
  15 import HsCore           ( HsIdInfo(..), UfExpr(..), toUfExpr, toUfBndr )
  16 import HsTypes          ( toHsTyVars )
  17 import BasicTypes       ( Fixity(..), NewOrData(..),
  18                           Version, initialVersion, bumpVersion, isLoopBreaker
  19                         )
  20 import RnMonad
  21 import RnHsSyn          ( RenamedInstDecl, RenamedTyClDecl )
  22 import TcHsSyn          ( TypecheckedRuleDecl )
  23 import HscTypes         ( VersionInfo(..), IfaceDecls(..), ModIface(..), ModDetails(..),
  24                           TyThing(..), DFunId, TypeEnv, isTyClThing, Avails,
  25                           WhatsImported(..), GenAvailInfo(..),
  26                           ImportVersion, AvailInfo, Deprecations(..),
  27                           Finder, ModuleLocation(..)
  28                         )
  29
  30 import CmdLineOpts
  31 import Id               ( Id, idType, idInfo, omitIfaceSigForId, isUserExportedId, hasNoBinding,
  32                           idSpecialisation, idName, setIdInfo
  33                         )
  34 import Var              ( isId )
  35 import VarSet
  36 import DataCon          ( StrictnessMark(..), dataConSig, dataConFieldLabels, dataConStrictMarks )
  37 import IdInfo           -- Lots
  38 import CoreSyn          ( CoreExpr, CoreBind, Bind(..), CoreRule(..), IdCoreRule,
  39                           isBuiltinRule, rulesRules, rulesRhsFreeVars, emptyCoreRules,
  40                           bindersOfBinds
  41                         )
  42 import CoreFVs          ( exprSomeFreeVars, ruleSomeLhsFreeVars, ruleSomeFreeVars )
  43 import CoreUnfold       ( okToUnfoldInHiFile, mkTopUnfolding, neverUnfold, unfoldingTemplate, noUnfolding )
  44 import Name             ( isLocallyDefined, getName,
  45                           Name, NamedThing(..),
  46                           plusNameEnv, lookupNameEnv, emptyNameEnv, mkNameEnv,
  47                           extendNameEnv, lookupNameEnv_NF, nameEnvElts
  48                         )
  49 import OccName          ( pprOccName )
  50 import TyCon            ( TyCon, getSynTyConDefn, isSynTyCon, isNewTyCon, isAlgTyCon,
  51                           tyConTheta, tyConTyVars, tyConDataCons, tyConFamilySize
  52                         )
  53 import Class            ( classExtraBigSig, DefMeth(..) )
  54 import FieldLabel       ( fieldLabelType )
  55 import Type             ( splitSigmaTy, tidyTopType, deNoteType )
  56 import SrcLoc           ( noSrcLoc )
  57 import Outputable
  58 import Module           ( ModuleName, moduleName )
  59
  60 import List             ( partition )
  61 import IO               ( IOMode(..), openFile, hClose )
  62 \end{code}
  63
  64
  65 %************************************************************************
  66 %*                                                                      *
  67 \subsection{Write a new interface file}
  68 %*                                                                      *
  69 %************************************************************************
  70
  71 \begin{code}
  72 mkModDetails :: TypeEnv -> [DFunId]     -- From typechecker
  73              -> [CoreBind] -> [Id]      -- Final bindings, plus the top-level Ids from the
  74                                         -- code generator; they have authoritative arity info
  75              -> [IdCoreRule]            -- Tidy orphan rules
  76              -> ModDetails
  77 mkModDetails type_env dfun_ids tidy_binds stg_ids orphan_rules
  78   = ModDetails { md_types = new_type_env,
  79                  md_rules = rule_dcls,
  80                  md_insts = dfun_ids }
  81   where
  82         -- The competed type environment is gotten from
  83         --      a) keeping the types and classes
  84         --      b) removing all Ids, and Ids with correct IdInfo
  85         --              gotten from the bindings
  86     new_type_env = mkNameEnv [(getName tycl, tycl) | tycl <- orig_type_env, isTyClThing tycl]
  87                         `plusNameEnv`
  88                    mkNameEnv [(idName id, AnId id) | id <- final_ids]
  89
  90     orig_type_env = nameEnvElts type_env
  91
  92     final_ids = bindsToIds (mkVarSet dfun_ids `unionVarSet` orphan_rule_ids)
  93                            (mkVarSet stg_ids)
  94                            tidy_binds
  95
  96         -- The complete rules are gotten by combining
  97         --      a) the orphan rules
  98         --      b) rules embedded in the top-level Ids
  99     rule_dcls | opt_OmitInterfacePragmas = []
 100               | otherwise                 = getRules orphan_rules tidy_binds (mkVarSet final_ids)
 101
 102     orphan_rule_ids = unionVarSets [ ruleSomeFreeVars interestingId rule
 103                                    | (_, rule) <- orphan_rules]
 104
 105
 106 -- This version is used when we are re-linking a module
 107 -- so we've only run the type checker on its previous interface
 108 mkModDetailsFromIface :: TypeEnv -> [DFunId]    -- From typechecker
 109                       -> [TypecheckedRuleDecl]
 110                       -> ModDetails
 111 mkModDetailsFromIface type_env dfun_ids rules
 112   = ModDetails { md_types = type_env,
 113                  md_rules = rule_dcls,
 114                  md_insts = dfun_ids }
 115   where
 116     rule_dcls = [(id,rule) | IfaceRuleOut id rule <- rules]
 117         -- All the rules from an interface are of the IfaceRuleOut form
 118
 119
 120 completeIface :: Maybe ModIface         -- The old interface, if we have it
 121               -> ModIface               -- The new one, minus the decls and versions
 122               -> ModDetails             -- The ModDetails for this module
 123               -> Maybe (ModIface, SDoc) -- The new one, complete with decls and versions
 124                                         -- The SDoc is a debug document giving differences
 125                                         -- Nothing => no change
 126
 127         -- NB: 'Nothing' means that even the usages havn't changed, so there's no
 128         --     need to write a new interface file.  But even if the usages have
 129         --     changed, the module version may not have.
 130         --
 131         -- The IO in the type is solely for debug output
 132         -- In particular, dumping a record of what has changed
 133 completeIface maybe_old_iface new_iface mod_details
 134   = addVersionInfo maybe_old_iface (new_iface { mi_decls = new_decls })
 135   where
 136      new_decls = IfaceDecls { dcl_tycl  = ty_cls_dcls,
 137                               dcl_insts = inst_dcls,
 138                               dcl_rules = rule_dcls }
 139
 140      inst_dcls   = map ifaceInstance (md_insts mod_details)
 141      ty_cls_dcls = map ifaceTyCls (nameEnvElts (md_types mod_details))
 142      rule_dcls   = map ifaceRule (md_rules mod_details)
 143 \end{code}
 144
 145
 146 %************************************************************************
 147 %*                                                                      *
 148 \subsection{Types and classes}
 149 %*                                                                      *
 150 %************************************************************************
 151
 152 \begin{code}
 153 ifaceTyCls :: TyThing -> RenamedTyClDecl
 154 ifaceTyCls (AClass clas)
 155   = ClassDecl (toHsContext sc_theta)
 156               (getName clas)
 157               (toHsTyVars clas_tyvars)
 158               (toHsFDs clas_fds)
 159               (map toClassOpSig op_stuff)
 160               EmptyMonoBinds
 161               [] noSrcLoc
 162   where
 163      (clas_tyvars, clas_fds, sc_theta, _, op_stuff) = classExtraBigSig clas
 164
 165      toClassOpSig (sel_id, def_meth)
 166         = ASSERT(sel_tyvars == clas_tyvars)
 167           ClassOpSig (getName sel_id) (Just def_meth') (toHsType op_ty) noSrcLoc
 168         where
 169           (sel_tyvars, _, op_ty) = splitSigmaTy (idType sel_id)
 170           def_meth' = case def_meth of
 171                          NoDefMeth  -> NoDefMeth
 172                          GenDefMeth -> GenDefMeth
 173                          DefMeth id -> DefMeth (getName id)
 174
 175 ifaceTyCls (ATyCon tycon)
 176   | isSynTyCon tycon
 177   = TySynonym (getName tycon)(toHsTyVars tyvars) (toHsType ty) noSrcLoc
 178   where
 179     (tyvars, ty) = getSynTyConDefn tycon
 180
 181 ifaceTyCls (ATyCon tycon)
 182   | isAlgTyCon tycon
 183   = TyData new_or_data (toHsContext (tyConTheta tycon))
 184            (getName tycon)
 185            (toHsTyVars tyvars)
 186            (map ifaceConDecl (tyConDataCons tycon))
 187            (tyConFamilySize tycon)
 188            Nothing noSrcLoc (panic "gen1") (panic "gen2")
 189   where
 190     tyvars = tyConTyVars tycon
 191     new_or_data | isNewTyCon tycon = NewType
 192                 | otherwise        = DataType
 193
 194     ifaceConDecl data_con
 195         = ConDecl (getName data_con) (error "ifaceConDecl")
 196                   (toHsTyVars ex_tyvars)
 197                   (toHsContext ex_theta)
 198                   details noSrcLoc
 199         where
 200           (tyvars1, _, ex_tyvars, ex_theta, arg_tys, tycon1) = dataConSig data_con
 201           field_labels   = dataConFieldLabels data_con
 202           strict_marks   = dataConStrictMarks data_con
 203           details | null field_labels
 204                   = ASSERT( tycon == tycon1 && tyvars == tyvars1 )
 205                     VanillaCon (zipWith mk_bang_ty strict_marks arg_tys)
 206
 207                   | otherwise
 208                   = RecCon (zipWith mk_field strict_marks field_labels)
 209
 210     mk_bang_ty NotMarkedStrict     ty = Unbanged (toHsType ty)
 211     mk_bang_ty (MarkedUnboxed _ _) ty = Unpacked (toHsType ty)
 212     mk_bang_ty MarkedStrict        ty = Banged   (toHsType ty)
 213
 214     mk_field strict_mark field_label
 215         = ([getName field_label], mk_bang_ty strict_mark (fieldLabelType field_label))
 216
 217 ifaceTyCls (ATyCon tycon) = pprPanic "ifaceTyCls" (ppr tycon)
 218
 219 ifaceTyCls (AnId id)
 220   = IfaceSig (getName id) (toHsType id_type) hs_idinfo noSrcLoc
 221   where
 222     id_type = idType id
 223     id_info = idInfo id
 224
 225     hs_idinfo | opt_OmitInterfacePragmas = []
 226               | otherwise                = arity_hsinfo  ++ caf_hsinfo  ++ cpr_hsinfo ++
 227                                            strict_hsinfo ++ wrkr_hsinfo ++ unfold_hsinfo
 228
 229     ------------  Arity  --------------
 230     arity_hsinfo = case arityInfo id_info of
 231                         a@(ArityExactly n) -> [HsArity a]
 232                         other              -> []
 233
 234     ------------ Caf Info --------------
 235     caf_hsinfo = case cafInfo id_info of
 236                    NoCafRefs -> [HsNoCafRefs]
 237                    otherwise -> []
 238
 239     ------------ CPR Info --------------
 240     cpr_hsinfo = case cprInfo id_info of
 241                    ReturnsCPR -> [HsCprInfo]
 242                    NoCPRInfo  -> []
 243
 244     ------------  Strictness  --------------
 245     strict_hsinfo = case strictnessInfo id_info of
 246                         NoStrictnessInfo -> []
 247                         info             -> [HsStrictness info]
 248
 249
 250     ------------  Worker  --------------
 251     wrkr_hsinfo = case workerInfo id_info of
 252                     HasWorker work_id wrap_arity -> [HsWorker (getName work_id)]
 253                     NoWorker                     -> []
 254
 255     ------------  Unfolding  --------------
 256     unfold_info = unfoldingInfo id_info
 257     inline_prag = inlinePragInfo id_info
 258     rhs         = unfoldingTemplate unfold_info
 259     unfold_hsinfo | neverUnfold unfold_info = []
 260                   | otherwise               = [HsUnfold inline_prag (toUfExpr rhs)]
 261 \end{code}
 262
 263
 264 %************************************************************************
 265 %*                                                                      *
 266 \subsection{Instances and rules}
 267 %*                                                                      *
 268 %************************************************************************
 269
 270 \begin{code}
 271 ifaceInstance :: DFunId -> RenamedInstDecl
 272 ifaceInstance dfun_id
 273   = InstDecl (toHsType tidy_ty) EmptyMonoBinds [] (Just (getName dfun_id)) noSrcLoc
 274   where
 275     tidy_ty = tidyTopType (deNoteType (idType dfun_id))
 276                 -- The deNoteType is very important.   It removes all type
 277                 -- synonyms from the instance type in interface files.
 278                 -- That in turn makes sure that when reading in instance decls
 279                 -- from interface files that the 'gating' mechanism works properly.
 280                 -- Otherwise you could have
 281                 --      type Tibble = T Int
 282                 --      instance Foo Tibble where ...
 283                 -- and this instance decl wouldn't get imported into a module
 284                 -- that mentioned T but not Tibble.
 285
 286 ifaceRule (id, BuiltinRule _)
 287   = pprTrace "toHsRule: builtin" (ppr id) (bogusIfaceRule id)
 288
 289 ifaceRule (id, Rule name bndrs args rhs)
 290   = IfaceRule name (map toUfBndr bndrs) (getName id)
 291               (map toUfExpr args) (toUfExpr rhs) noSrcLoc
 292
 293 bogusIfaceRule id
 294   = IfaceRule SLIT("bogus") [] (getName id) [] (UfVar (getName id)) noSrcLoc
 295 \end{code}
 296
 297
 298 %************************************************************************
 299 %*                                                                      *
 300 \subsection{Compute final Ids}
 301 %*                                                                      *
 302 %************************************************************************
 303
 304 A "final Id" has exactly the IdInfo for going into an interface file, or
 305 exporting to another module.
 306
 307 \begin{code}
 308 bindsToIds :: IdSet             -- These Ids are needed already
 309            -> IdSet             -- Ids used at code-gen time; they have better pragma info!
 310            -> [CoreBind]        -- In dependency order, later depend on earlier
 311            -> [Id]              -- Set of Ids actually spat out, complete with exactly the IdInfo
 312                                 -- they need for exporting to another module
 313
 314 bindsToIds needed_ids codegen_ids binds
 315   = go needed_ids (reverse binds) []
 316                 -- Reverse so that later things will
 317                 -- provoke earlier ones to be emitted
 318   where
 319         -- The 'needed' set contains the Ids that are needed by earlier
 320         -- interface file emissions.  If the Id isn't in this set, and isn't
 321         -- exported, there's no need to emit anything
 322     need_id needed_set id = id `elemVarSet` needed_set || isUserExportedId id
 323
 324     go needed [] emitted
 325         | not (isEmptyVarSet needed) = pprTrace "ifaceBinds: free vars:"
 326                                           (sep (map ppr (varSetElems needed)))
 327                                        emitted
 328         | otherwise                  = emitted
 329
 330     go needed (NonRec id rhs : binds) emitted
 331         | need_id needed id
 332         = if omitIfaceSigForId id then
 333             go (needed `delVarSet` id) binds (id:emitted)
 334           else
 335             go ((needed `unionVarSet` extras) `delVarSet` id)
 336                binds
 337                (new_id:emitted)
 338         | otherwise
 339         = go needed binds emitted
 340         where
 341           (new_id, extras) = mkFinalId codegen_ids False id rhs
 342
 343         -- Recursive groups are a bit more of a pain.  We may only need one to
 344         -- start with, but it may call out the next one, and so on.  So we
 345         -- have to look for a fixed point.  We don't want necessarily them all,
 346         -- because without -O we may only need the first one (if we don't emit
 347         -- its unfolding)
 348     go needed (Rec pairs : binds) emitted
 349         = go needed' binds emitted'
 350         where
 351           (new_emitted, extras) = go_rec needed pairs
 352           needed'  = (needed `unionVarSet` extras) `minusVarSet` mkVarSet (map fst pairs)
 353           emitted' = new_emitted ++ emitted
 354
 355     go_rec :: IdSet -> [(Id,CoreExpr)] -> ([Id], IdSet)
 356     go_rec needed pairs
 357         | null needed_prs = ([], emptyVarSet)
 358         | otherwise       = (emitted ++           more_emitted,
 359                              extras `unionVarSet` more_extras)
 360         where
 361           (needed_prs,leftover_prs)   = partition is_needed pairs
 362           (emitted, extras_s)         = unzip [ mkFinalId codegen_ids True id rhs
 363                                               | (id,rhs) <- needed_prs, not (omitIfaceSigForId id)]
 364           extras                      = unionVarSets extras_s
 365           (more_emitted, more_extras) = go_rec extras leftover_prs
 366
 367           is_needed (id,_) = need_id needed id
 368 \end{code}
 369
 370
 371
 372 \begin{code}
 373 mkFinalId :: IdSet              -- The Ids with arity info from the code generator
 374           -> Bool                       -- True <=> recursive, so don't include unfolding
 375           -> Id
 376           -> CoreExpr           -- The Id's right hand side
 377           -> (Id, IdSet)                -- The emitted id, plus any *extra* needed Ids
 378
 379 mkFinalId codegen_ids is_rec id rhs
 380   = (id `setIdInfo` new_idinfo, new_needed_ids)
 381   where
 382     core_idinfo = idInfo id
 383     stg_idinfo  = case lookupVarSet codegen_ids id of
 384                         Just id' -> idInfo id'
 385                         Nothing  -> pprTrace "ifaceBinds not found:" (ppr id) $
 386                                     idInfo id
 387
 388     new_idinfo | opt_OmitInterfacePragmas
 389                = vanillaIdInfo
 390                | otherwise
 391                = core_idinfo `setArityInfo`      arity_info
 392                              `setCafInfo`        cafInfo stg_idinfo
 393                              `setUnfoldingInfo`  unfold_info
 394                              `setWorkerInfo`     worker_info
 395                              `setSpecInfo`       emptyCoreRules
 396         -- We zap the specialisations because they are
 397         -- passed on separately through the modules IdCoreRules
 398
 399     ------------  Arity  --------------
 400     arity_info = arityInfo stg_idinfo
 401     stg_arity  = arityLowerBound arity_info
 402
 403     ------------  Worker  --------------
 404         -- We only treat a function as having a worker if
 405         -- the exported arity (which is now the number of visible lambdas)
 406         -- is the same as the arity at the moment of the w/w split
 407         -- If so, we can safely omit the unfolding inside the wrapper, and
 408         -- instead re-generate it from the type/arity/strictness info
 409         -- But if the arity has changed, we just take the simple path and
 410         -- put the unfolding into the interface file, forgetting the fact
 411         -- that it's a wrapper.
 412         --
 413         -- How can this happen?  Sometimes we get
 414         --      f = coerce t (\x y -> $wf x y)
 415         -- at the moment of w/w split; but the eta reducer turns it into
 416         --      f = coerce t $wf
 417         -- which is perfectly fine except that the exposed arity so far as
 418         -- the code generator is concerned (zero) differs from the arity
 419         -- when we did the split (2).
 420         --
 421         -- All this arises because we use 'arity' to mean "exactly how many
 422         -- top level lambdas are there" in interface files; but during the
 423         -- compilation of this module it means "how many things can I apply
 424         -- this to".
 425     worker_info = case workerInfo core_idinfo of
 426                      info@(HasWorker work_id wrap_arity)
 427                         | wrap_arity == stg_arity -> info
 428                         | otherwise               -> pprTrace "ifaceId: arity change:" (ppr id)
 429                                                      NoWorker
 430                      NoWorker                     -> NoWorker
 431
 432     has_worker = case worker_info of
 433                    HasWorker _ _ -> True
 434                    other         -> False
 435
 436     HasWorker work_id _ = worker_info
 437
 438     ------------  Unfolding  --------------
 439     inline_pragma  = inlinePragInfo core_idinfo
 440     dont_inline    = isNeverInlinePrag inline_pragma
 441     loop_breaker   = isLoopBreaker (occInfo core_idinfo)
 442     bottoming_fn   = isBottomingStrictness (strictnessInfo core_idinfo)
 443
 444     unfolding    = mkTopUnfolding rhs
 445     rhs_is_small = neverUnfold unfolding
 446
 447     unfold_info | show_unfold = unfolding
 448                 | otherwise   = noUnfolding
 449
 450     show_unfold = not has_worker         &&     -- Not unnecessary
 451                   not bottoming_fn       &&     -- Not necessary
 452                   not dont_inline        &&
 453                   not loop_breaker       &&
 454                   rhs_is_small           &&     -- Small enough
 455                   okToUnfoldInHiFile rhs        -- No casms etc
 456
 457
 458     ------------  Extra free Ids  --------------
 459     new_needed_ids | opt_OmitInterfacePragmas = emptyVarSet
 460                    | otherwise                = worker_ids      `unionVarSet`
 461                                                 unfold_ids      `unionVarSet`
 462                                                 spec_ids
 463
 464     spec_ids = filterVarSet interestingId (rulesRhsFreeVars (specInfo core_idinfo))
 465
 466     worker_ids | has_worker && interestingId work_id = unitVarSet work_id
 467                         -- Conceivably, the worker might come from
 468                         -- another module
 469                | otherwise = emptyVarSet
 470
 471     unfold_ids | show_unfold = find_fvs rhs
 472                | otherwise   = emptyVarSet
 473
 474     find_fvs expr = exprSomeFreeVars interestingId expr
 475
 476 interestingId id = isId id && isLocallyDefined id && not (hasNoBinding id)
 477 \end{code}
 478
 479
 480 \begin{code}
 481 getRules :: [IdCoreRule]        -- Orphan rules
 482          -> [CoreBind]          -- Bindings, with rules in the top-level Ids
 483          -> IdSet               -- Ids that are exported, so we need their rules
 484          -> [IdCoreRule]
 485 getRules orphan_rules binds emitted
 486   = orphan_rules ++ local_rules
 487   where
 488     local_rules  = [ (fn, rule)
 489                    | fn <- bindersOfBinds binds,
 490                      fn `elemVarSet` emitted,
 491                      rule <- rulesRules (idSpecialisation fn),
 492                      not (isBuiltinRule rule),
 493                                 -- We can't print builtin rules in interface files
 494                                 -- Since they are built in, an importing module
 495                                 -- will have access to them anyway
 496
 497                         -- Sept 00: I've disabled this test.  It doesn't stop many, if any, rules
 498                         -- from coming out, and to make it work properly we need to add ????
 499                         --      (put it back in for now)
 500                      all (`elemVarSet` emitted) (varSetElems (ruleSomeLhsFreeVars interestingId rule))
 501                                 -- Spit out a rule only if all its lhs free vars are emitted
 502                                 -- This is a good reason not to do it when we emit the Id itself
 503                    ]
 504 \end{code}
 505
 506
 507 %************************************************************************
 508 %*                                                                      *
 509 \subsection{Checking if the new interface is up to date
 510 %*                                                                      *
 511 %************************************************************************
 512
 513 \begin{code}
 514 addVersionInfo :: Maybe ModIface                -- The old interface, read from M.hi
 515                -> ModIface                      -- The new interface decls
 516                -> Maybe (ModIface, SDoc)        -- Nothing => no change; no need to write new Iface
 517                                                 -- Just mi => Here is the new interface to write
 518                                                 --            with correct version numbers
 519
 520 -- NB: the fixities, declarations, rules are all assumed
 521 -- to be sorted by increasing order of hsDeclName, so that
 522 -- we can compare for equality
 523
 524 addVersionInfo Nothing new_iface
 525 -- No old interface, so definitely write a new one!
 526   = Just (new_iface, text "No old interface available")
 527
 528 addVersionInfo (Just old_iface@(ModIface { mi_version = old_version,
 529                                            mi_decls   = old_decls,
 530                                            mi_fixities = old_fixities }))
 531                new_iface@(ModIface { mi_decls = new_decls,
 532                                      mi_fixities = new_fixities })
 533
 534   | no_output_change && no_usage_change
 535   = Nothing
 536
 537   | otherwise           -- Add updated version numbers
 538   = Just (final_iface, pp_tc_diffs)
 539
 540   where
 541     final_iface = new_iface { mi_version = new_version }
 542     new_version = VersionInfo { vers_module  = bumpVersion no_output_change (vers_module  old_version),
 543                                 vers_exports = bumpVersion no_export_change (vers_exports old_version),
 544                                 vers_rules   = bumpVersion no_rule_change   (vers_rules   old_version),
 545                                 vers_decls   = tc_vers }
 546
 547     no_output_change = no_tc_change && no_rule_change && no_export_change
 548     no_usage_change  = mi_usages old_iface == mi_usages new_iface
 549
 550     no_export_change = mi_exports old_iface == mi_exports new_iface             -- Kept sorted
 551     no_rule_change   = dcl_rules old_decls  == dcl_rules  new_decls             -- Ditto
 552
 553         -- Fill in the version number on the new declarations by looking at the old declarations.
 554         -- Set the flag if anything changes.
 555         -- Assumes that the decls are sorted by hsDeclName.
 556     old_vers_decls = vers_decls old_version
 557     (no_tc_change,  pp_tc_diffs,  tc_vers) = diffDecls old_vers_decls old_fixities new_fixities
 558                                                        (dcl_tycl old_decls) (dcl_tycl new_decls)
 559
 560
 561
 562 diffDecls :: NameEnv Version                            -- Old version map
 563           -> NameEnv Fixity -> NameEnv Fixity           -- Old and new fixities
 564           -> [RenamedTyClDecl] -> [RenamedTyClDecl]     -- Old and new decls
 565           -> (Bool,             -- True <=> no change
 566               SDoc,             -- Record of differences
 567               NameEnv Version)  -- New version
 568
 569 diffDecls old_vers old_fixities new_fixities old new
 570   = diff True empty emptyNameEnv old new
 571   where
 572         -- When seeing if two decls are the same,
 573         -- remember to check whether any relevant fixity has changed
 574     eq_tc  d1 d2 = d1 == d2 && all (same_fixity . fst) (tyClDeclNames d1)
 575     same_fixity n = lookupNameEnv old_fixities n == lookupNameEnv new_fixities n
 576
 577     diff ok_so_far pp new_vers []  []      = (ok_so_far, pp, new_vers)
 578     diff ok_so_far pp new_vers old []      = (False,     pp, new_vers)
 579     diff ok_so_far pp new_vers [] (nd:nds) = diff False (pp $$ only_new nd) new_vers [] nds
 580     diff ok_so_far pp new_vers (od:ods) (nd:nds)
 581         = case od_name `compare` nd_name of
 582                 LT -> diff False (pp $$ only_old od) new_vers ods      (nd:nds)
 583                 GT -> diff False (pp $$ only_new nd) new_vers (od:ods) nds
 584                 EQ | od `eq_tc` nd -> diff ok_so_far pp                    new_vers  ods nds
 585                    | otherwise     -> diff False     (pp $$ changed od nd) new_vers' ods nds
 586         where
 587           od_name = tyClDeclName od
 588           nd_name = tyClDeclName nd
 589           new_vers' = extendNameEnv new_vers nd_name
 590                                     (bumpVersion True (lookupNameEnv_NF old_vers od_name))
 591
 592     only_old d   = ptext SLIT("Only in old iface:") <+> ppr d
 593     only_new d   = ptext SLIT("Only in new iface:") <+> ppr d
 594     changed d nd = ptext SLIT("Changed in iface: ") <+> ((ptext SLIT("Old:") <+> ppr d) $$
 595                                                          (ptext SLIT("New:") <+> ppr nd))
 596 \end{code}
 597
 598
 599
 600 %************************************************************************
 601 %*                                                                      *
 602 \subsection{Writing an interface file}
 603 %*                                                                      *
 604 %************************************************************************
 605
 606 \begin{code}
 607 writeIface :: Finder -> Maybe ModIface -> IO ()
 608 writeIface finder Nothing
 609   = return ()
 610
 611 writeIface finder (Just mod_iface)
 612   = do  { maybe_found <- finder mod_name ;
 613         ; case maybe_found of {
 614             Nothing -> printErrs (text "Can't write interface file for" <+> ppr mod_name) ;
 615             Just (_, locn) ->
 616
 617     do  { let filename = hi_file locn
 618         ; if_hdl <- openFile filename WriteMode
 619         ; printForIface if_hdl (pprIface mod_iface)
 620         ; hClose if_hdl
 621         }}}
 622   where
 623     mod_name = moduleName (mi_module mod_iface)
 624
 625 pprIface :: ModIface -> SDoc
 626 pprIface iface
 627  = vcat [ ptext SLIT("__interface")
 628                 <+> doubleQuotes (ptext opt_InPackage)
 629                 <+> ppr (mi_module iface) <+> ppr (vers_module version_info)
 630                 <+> pp_sub_vers
 631                 <+> (if mi_orphan iface then char '!' else empty)
 632                 <+> int opt_HiVersion
 633                 <+> ptext SLIT("where")
 634
 635         , vcat (map pprExport (mi_exports iface))
 636         , vcat (map pprUsage (mi_usages iface))
 637
 638         , pprIfaceDecls (vers_decls version_info)
 639                         (mi_fixities iface)
 640                         (mi_decls iface)
 641
 642         , pprDeprecs (mi_deprecs iface)
 643         ]
 644   where
 645     version_info = mi_version iface
 646     exp_vers     = vers_exports version_info
 647     rule_vers    = vers_rules version_info
 648
 649     pp_sub_vers | exp_vers == initialVersion && rule_vers == initialVersion = empty
 650                 | otherwise = brackets (ppr exp_vers <+> ppr rule_vers)
 651 \end{code}
 652
 653 When printing export lists, we print like this:
 654         Avail   f               f
 655         AvailTC C [C, x, y]     C(x,y)
 656         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 657
 658 \begin{code}
 659 pprExport :: (ModuleName, Avails) -> SDoc
 660 pprExport (mod, items)
 661  = hsep [ ptext SLIT("__export "), ppr mod, hsep (map pp_avail items) ] <> semi
 662   where
 663     ppr_name :: Name -> SDoc    -- Print the occurrence name only
 664     ppr_name n = ppr (nameOccName n)
 665
 666     pp_avail :: AvailInfo -> SDoc
 667     pp_avail (Avail name)      = ppr_name name
 668     pp_avail (AvailTC name []) = empty
 669     pp_avail (AvailTC name ns) = hcat [ppr_name name, bang, pp_export ns']
 670                                 where
 671                                   bang | name `elem` ns = empty
 672                                        | otherwise      = char '|'
 673                                   ns' = filter (/= name) ns
 674
 675     pp_export []    = empty
 676     pp_export names = braces (hsep (map ppr_name names))
 677 \end{code}
 678
 679
 680 \begin{code}
 681 pprUsage :: ImportVersion Name -> SDoc
 682 pprUsage (m, has_orphans, is_boot, whats_imported)
 683   = hsep [ptext SLIT("import"), ppr m,
 684           pp_orphan, pp_boot,
 685           pp_versions whats_imported
 686     ] <> semi
 687   where
 688     pp_orphan | has_orphans = char '!'
 689               | otherwise   = empty
 690     pp_boot   | is_boot     = char '@'
 691               | otherwise   = empty
 692
 693         -- Importing the whole module is indicated by an empty list
 694     pp_versions NothingAtAll                = empty
 695     pp_versions (Everything v)              = dcolon <+> int v
 696     pp_versions (Specifically vm ve nvs vr) = dcolon <+> int vm <+> pp_export_version ve <+> int vr
 697                                               <+> hsep [ ppr n <+> int v | (n,v) <- nvs ]
 698
 699         -- HACK for the moment: print the export-list version even if
 700         -- we don't use it, so that syntax of interface files doesn't change
 701     pp_export_version Nothing  = int 1
 702     pp_export_version (Just v) = int v
 703 \end{code}
 704
 705 \begin{code}
 706 pprIfaceDecls version_map fixity_map decls
 707   = vcat [ vcat [ppr i <+> semi | i <- dcl_insts decls]
 708          , vcat (map ppr_decl (dcl_tycl decls))
 709          , pprRules (dcl_rules decls)
 710          ]
 711   where
 712     ppr_decl d  = (ppr_vers d <+> ppr d <> semi) $$ ppr_fixes d
 713
 714         -- Print the version for the decl
 715     ppr_vers d = case lookupNameEnv version_map (tyClDeclName d) of
 716                    Nothing -> empty
 717                    Just v  -> int v
 718
 719         -- Print fixities relevant to the decl
 720     ppr_fixes d = vcat [ ppr fix <+> ppr n <> semi
 721                        | (n,_) <- tyClDeclNames d,
 722                          Just fix <- [lookupNameEnv fixity_map n]
 723                        ]
 724 \end{code}
 725
 726 \begin{code}
 727 pprRules []    = empty
 728 pprRules rules = hsep [ptext SLIT("{-## __R"), vcat (map ppr rules), ptext SLIT("##-}")]
 729
 730 pprDeprecs NoDeprecs = empty
 731 pprDeprecs deprecs   = ptext SLIT("{-## __D") <+> guts <+> ptext SLIT("##-}")
 732                      where
 733                        guts = case deprecs of
 734                                 DeprecAll txt  -> ptext txt
 735                                 DeprecSome env -> pp_deprecs env
 736
 737 pp_deprecs env = vcat (punctuate semi (map pp_deprec (nameEnvElts env)))
 738                where
 739                  pp_deprec (name, txt) = pprOccName (nameOccName name) <+> ptext txt
 740 \end{code}