ghc/compiler/main/MkIface.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[MkIface]{Print an interface for a module}
   5
   6 \begin{code}
   7 module MkIface (
   8         startIface, endIface, ifaceDecls
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import IO               ( Handle, hPutStr, openFile,
  14                           hClose, hPutStrLn, IOMode(..) )
  15
  16 import HsSyn
  17 import BasicTypes       ( Fixity(..), FixityDirection(..), NewOrData(..) )
  18 import RnMonad
  19 import RnEnv            ( availName )
  20
  21 import TcInstUtil       ( InstInfo(..) )
  22
  23 import CmdLineOpts
  24 import Id               ( Id, idType, idInfo, omitIfaceSigForId, isUserExportedId,
  25                           getIdSpecialisation
  26                         )
  27 import Var              ( isId )
  28 import VarSet
  29 import DataCon          ( StrictnessMark(..), dataConSig, dataConFieldLabels, dataConStrictMarks )
  30 import IdInfo           ( IdInfo, StrictnessInfo, ArityInfo, InlinePragInfo(..), inlinePragInfo,
  31                           arityInfo, ppArityInfo,
  32                           strictnessInfo, ppStrictnessInfo, isBottomingStrictness,
  33                           cafInfo, ppCafInfo, specInfo,
  34                           cprInfo, ppCprInfo,
  35                           workerExists, workerInfo, ppWorkerInfo
  36                         )
  37 import CoreSyn          ( CoreExpr, CoreBind, Bind(..), rulesRules, rulesRhsFreeVars )
  38 import CoreFVs          ( exprSomeFreeVars, ruleSomeLhsFreeVars, ruleSomeFreeVars )
  39 import CoreUnfold       ( calcUnfoldingGuidance, okToUnfoldInHiFile, couldBeSmallEnoughToInline )
  40 import Module           ( moduleString, pprModule, pprModuleName )
  41 import Name             ( isLocallyDefined, isWiredInName, nameRdrName, nameModule,
  42                           Name, NamedThing(..)
  43                         )
  44 import OccName          ( OccName, pprOccName )
  45 import TyCon            ( TyCon, getSynTyConDefn, isSynTyCon, isNewTyCon, isAlgTyCon,
  46                           tyConTheta, tyConTyVars, tyConDataCons
  47                         )
  48 import Class            ( Class, classBigSig )
  49 import FieldLabel       ( fieldLabelName, fieldLabelType )
  50 import Type             ( mkSigmaTy, splitSigmaTy, mkDictTy, tidyTopType, deNoteType,
  51                           Type, ThetaType
  52                         )
  53
  54 import PprType
  55 import PprCore          ( pprIfaceUnfolding, pprCoreRule )
  56 import Rules            ( pprProtoCoreRule, ProtoCoreRule(..) )
  57
  58 import Bag              ( bagToList, isEmptyBag )
  59 import Maybes           ( catMaybes, maybeToBool )
  60 import FiniteMap        ( emptyFM, addToFM, addToFM_C, fmToList, FiniteMap )
  61 import UniqFM           ( lookupUFM, listToUFM )
  62 import UniqSet          ( uniqSetToList )
  63 import Util             ( sortLt, mapAccumL )
  64 import Bag
  65 import Outputable
  66 \end{code}
  67
  68 We have a function @startIface@ to open the output file and put
  69 (something like) ``interface Foo'' in it.  It gives back a handle
  70 for subsequent additions to the interface file.
  71
  72 We then have one-function-per-block-of-interface-stuff, e.g.,
  73 @ifaceExportList@ produces the @__exports__@ section; it appends
  74 to the handle provided by @startIface@.
  75
  76 \begin{code}
  77 startIface  :: Module -> InterfaceDetails
  78             -> IO (Maybe Handle) -- Nothing <=> don't do an interface
  79
  80 ifaceDecls :: Maybe Handle
  81            -> [TyCon] -> [Class]
  82            -> Bag InstInfo
  83            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
  84            -> [CoreBind]        -- In dependency order, later depend on earlier
  85            -> [ProtoCoreRule]   -- Rules
  86            -> IO ()
  87
  88 endIface    :: Maybe Handle -> IO ()
  89 \end{code}
  90
  91 \begin{code}
  92 startIface mod (has_orphans, import_usages, ExportEnv avails fixities)
  93   = case opt_ProduceHi of
  94       Nothing -> return Nothing ; -- not producing any .hi file
  95
  96       Just fn -> do
  97         if_hdl <- openFile fn WriteMode
  98         hPutStr         if_hdl ("__interface " ++ moduleString mod)
  99         hPutStr         if_hdl (' ' : show (opt_HiVersion :: Int) ++ orphan_indicator)
 100         hPutStrLn       if_hdl " where"
 101         ifaceExports    if_hdl avails
 102         ifaceImports    if_hdl import_usages
 103         ifaceFixities   if_hdl fixities
 104         return (Just if_hdl)
 105   where
 106     orphan_indicator | has_orphans = " !"
 107                      | otherwise   = ""
 108
 109 endIface Nothing        = return ()
 110 endIface (Just if_hdl)  = hPutStr if_hdl "\n" >> hClose if_hdl
 111 \end{code}
 112
 113
 114 \begin{code}
 115 ifaceDecls Nothing tycons classes inst_info final_ids simplified rules = return ()
 116 ifaceDecls (Just hdl)
 117            tycons classes
 118            inst_infos
 119            final_ids binds
 120            orphan_rules         -- Rules defined locally for an Id that is *not* defined locally
 121   | null_decls = return ()
 122         --  You could have a module with just (re-)exports/instances in it
 123   | otherwise
 124   = ifaceClasses hdl classes                    >>
 125     ifaceInstances hdl inst_infos               >>= \ inst_ids ->
 126     ifaceTyCons hdl tycons                      >>
 127     ifaceBinds hdl (inst_ids `unionVarSet` orphan_rule_ids)
 128                final_ids binds                  >>= \ emitted_ids ->
 129     ifaceRules hdl orphan_rules emitted_ids     >>
 130     return ()
 131   where
 132      orphan_rule_ids = unionVarSets [ ruleSomeFreeVars interestingId rule
 133                                     | ProtoCoreRule _ _ rule <- orphan_rules]
 134
 135      null_decls = null binds      &&
 136                   null tycons     &&
 137                   null classes    &&
 138                   isEmptyBag inst_infos &&
 139                   null orphan_rules
 140 \end{code}
 141
 142 \begin{code}
 143 ifaceImports if_hdl import_usages
 144   = hPutCol if_hdl upp_uses (sortLt lt_imp_vers import_usages)
 145   where
 146     upp_uses (m, mv, has_orphans, whats_imported)
 147       = hsep [ptext SLIT("import"), pprModuleName m,
 148               int mv, pp_orphan,
 149               upp_import_versions whats_imported
 150         ] <> semi
 151       where
 152         pp_orphan | has_orphans = ptext SLIT("!")
 153                   | otherwise   = empty
 154
 155         -- Importing the whole module is indicated by an empty list
 156     upp_import_versions Everything = empty
 157
 158         -- For imported versions we do print the version number
 159     upp_import_versions (Specifically nvs)
 160       = dcolon <+> hsep [ hsep [ppr_unqual_name n, int v] | (n,v) <- sort_versions nvs ]
 161
 162 ifaceModuleDeps if_hdl [] = return ()
 163 ifaceModuleDeps if_hdl mod_deps
 164   = let
 165         lines = map ppr_mod_dep mod_deps
 166         ppr_mod_dep (mod, contains_orphans)
 167            | contains_orphans = pprModuleName mod <+> ptext SLIT("!")
 168            | otherwise        = pprModuleName mod
 169     in
 170     printForIface if_hdl (ptext SLIT("__depends") <+> vcat lines <> ptext SLIT(" ;")) >>
 171     hPutStr if_hdl "\n"
 172
 173 ifaceExports if_hdl [] = return ()
 174 ifaceExports if_hdl avails
 175   = hPutCol if_hdl do_one_module (fmToList export_fm)
 176   where
 177         -- Sort them into groups by module
 178     export_fm :: FiniteMap Module [AvailInfo]
 179     export_fm = foldr insert emptyFM avails
 180
 181     insert avail efm = addToFM_C (++) efm mod [avail]
 182                      where
 183                        mod = nameModule (availName avail)
 184
 185         -- Print one module's worth of stuff
 186     do_one_module :: (Module, [AvailInfo]) -> SDoc
 187     do_one_module (mod_name, avails@(avail1:_))
 188         = ptext SLIT("__export ") <>
 189           hsep [pprModule mod_name,
 190                 hsep (map upp_avail (sortLt lt_avail avails))
 191           ] <> semi
 192
 193 ifaceFixities if_hdl [] = return ()
 194 ifaceFixities if_hdl fixities
 195   = hPutCol if_hdl upp_fixity fixities
 196
 197 ifaceRules if_hdl rules emitted
 198   | null orphan_rule_pretties && null local_id_pretties
 199   = return ()
 200   | otherwise
 201   = do  printForIface if_hdl (vcat [
 202                 ptext SLIT("{-## __R"),
 203
 204                 vcat orphan_rule_pretties,
 205
 206                 vcat local_id_pretties,
 207
 208                 ptext SLIT("##-}")
 209           ])
 210
 211         return ()
 212   where
 213     orphan_rule_pretties =  [ pprCoreRule (Just fn) rule <+> semi
 214                             | ProtoCoreRule _ fn rule <- rules
 215                             ]
 216     local_id_pretties = [ pprCoreRule (Just fn) rule <+> semi
 217                         | fn <- varSetElems emitted,
 218                           rule <- rulesRules (getIdSpecialisation fn),
 219                           all (`elemVarSet` emitted) (varSetElems (ruleSomeLhsFreeVars interestingId rule))
 220                                 -- Spit out a rule only if all its lhs free vars are eemitted
 221                         ]
 222 \end{code}
 223
 224 %************************************************************************
 225 %*                                                                      *
 226 \subsection{Instance declarations}
 227 %*                                                                      *
 228 %************************************************************************
 229
 230
 231 \begin{code}
 232 ifaceInstances :: Handle -> Bag InstInfo -> IO IdSet            -- The IdSet is the needed dfuns
 233 ifaceInstances if_hdl inst_infos
 234   | null togo_insts = return emptyVarSet
 235   | otherwise       = hPutCol if_hdl pp_inst (sortLt lt_inst togo_insts) >>
 236                       return needed_ids
 237   where
 238     togo_insts  = filter is_togo_inst (bagToList inst_infos)
 239     needed_ids  = mkVarSet [dfun_id | InstInfo _ _ _ _ dfun_id _ _ _ <- togo_insts]
 240     is_togo_inst (InstInfo _ _ _ _ dfun_id _ _ _) = isLocallyDefined dfun_id
 241
 242     -------
 243     lt_inst (InstInfo _ _ _ _ dfun_id1 _ _ _)
 244             (InstInfo _ _ _ _ dfun_id2 _ _ _)
 245       = getOccName dfun_id1 < getOccName dfun_id2
 246         -- The dfuns are assigned names df1, df2, etc, in order of original textual
 247         -- occurrence, and this makes as good a sort order as any
 248
 249     -------
 250     pp_inst (InstInfo clas tvs tys theta dfun_id _ _ _)
 251       = let
 252                 -- The deNoteType is very important.   It removes all type
 253                 -- synonyms from the instance type in interface files.
 254                 -- That in turn makes sure that when reading in instance decls
 255                 -- from interface files that the 'gating' mechanism works properly.
 256                 -- Otherwise you could have
 257                 --      type Tibble = T Int
 258                 --      instance Foo Tibble where ...
 259                 -- and this instance decl wouldn't get imported into a module
 260                 -- that mentioned T but not Tibble.
 261             forall_ty     = mkSigmaTy tvs theta (deNoteType (mkDictTy clas tys))
 262             renumbered_ty = tidyTopType forall_ty
 263         in
 264         hcat [ptext SLIT("instance "), pprType renumbered_ty,
 265                     ptext SLIT(" = "), ppr_unqual_name dfun_id, semi]
 266 \end{code}
 267
 268
 269 %************************************************************************
 270 %*                                                                      *
 271 \subsection{Printing values}
 272 %*                                                                      *
 273 %************************************************************************
 274
 275 \begin{code}
 276 ifaceId :: (Id -> IdInfo)               -- This function "knows" the extra info added
 277                                         -- by the STG passes.  Sigh
 278
 279             -> IdSet                    -- Set of Ids that are needed by earlier interface
 280                                         -- file emissions.  If the Id isn't in this set, and isn't
 281                                         -- exported, there's no need to emit anything
 282             -> Bool                     -- True <=> recursive, so don't print unfolding
 283             -> Id
 284             -> CoreExpr                 -- The Id's right hand side
 285             -> Maybe (SDoc, IdSet)      -- The emitted stuff, plus any *extra* needed Ids
 286
 287 ifaceId get_idinfo needed_ids is_rec id rhs
 288   | not (id `elemVarSet` needed_ids ||          -- Needed [no id in needed_ids has omitIfaceSigForId]
 289          (isUserExportedId id && not (omitIfaceSigForId id)))   -- or exported and not to be omitted
 290   = Nothing             -- Well, that was easy!
 291
 292 ifaceId get_idinfo needed_ids is_rec id rhs
 293   = Just (hsep [sig_pretty, prag_pretty, char ';'], new_needed_ids)
 294   where
 295     idinfo         = get_idinfo id
 296
 297     ty_pretty  = pprType (idType id)
 298     sig_pretty = hsep [ppr (getOccName id), dcolon, ty_pretty]
 299
 300     prag_pretty
 301      | opt_OmitInterfacePragmas = empty
 302      | otherwise                = hsep [ptext SLIT("{-##"),
 303                                         arity_pretty,
 304                                         caf_pretty,
 305                                         cpr_pretty,
 306                                         strict_pretty,
 307                                         wrkr_pretty,
 308                                         unfold_pretty,
 309                                         ptext SLIT("##-}")]
 310
 311     ------------  Arity  --------------
 312     arity_pretty  = ppArityInfo (arityInfo idinfo)
 313
 314     ------------ Caf Info --------------
 315     caf_pretty = ppCafInfo (cafInfo idinfo)
 316
 317     ------------ CPR Info --------------
 318     cpr_pretty = ppCprInfo (cprInfo idinfo)
 319
 320     ------------  Strictness  --------------
 321     strict_info   = strictnessInfo idinfo
 322     bottoming_fn  = isBottomingStrictness strict_info
 323     strict_pretty = ppStrictnessInfo strict_info
 324
 325     ------------  Worker  --------------
 326     work_info     = workerInfo idinfo
 327     has_worker    = workerExists work_info
 328     wrkr_pretty   = ppWorkerInfo work_info
 329     Just work_id  = work_info
 330
 331
 332     ------------  Unfolding  --------------
 333     inline_pragma  = inlinePragInfo idinfo
 334     dont_inline    = case inline_pragma of
 335                         IMustNotBeINLINEd -> True
 336                         IAmALoopBreaker   -> True
 337                         other             -> False
 338
 339     unfold_pretty | show_unfold = ptext SLIT("__u") <+> pprIfaceUnfolding rhs
 340                   | otherwise   = empty
 341
 342     show_unfold = not has_worker         &&     -- Not unnecessary
 343                   not bottoming_fn       &&     -- Not necessary
 344                   not dont_inline        &&
 345                   rhs_is_small           &&     -- Small enough
 346                   okToUnfoldInHiFile rhs        -- No casms etc
 347
 348     rhs_is_small = couldBeSmallEnoughToInline (calcUnfoldingGuidance opt_UF_HiFileThreshold rhs)
 349
 350     ------------  Specialisations --------------
 351     spec_info   = specInfo idinfo
 352
 353     ------------  Extra free Ids  --------------
 354     new_needed_ids | opt_OmitInterfacePragmas = emptyVarSet
 355                    | otherwise                = worker_ids      `unionVarSet`
 356                                                 unfold_ids      `unionVarSet`
 357                                                 spec_ids
 358
 359     worker_ids | has_worker && interestingId work_id = unitVarSet work_id
 360                         -- Conceivably, the worker might come from
 361                         -- another module
 362                | otherwise                         = emptyVarSet
 363
 364     spec_ids = filterVarSet interestingId (rulesRhsFreeVars spec_info)
 365
 366     unfold_ids | show_unfold = find_fvs rhs
 367                | otherwise   = emptyVarSet
 368
 369     find_fvs expr = exprSomeFreeVars interestingId expr
 370
 371 interestingId id = isId id && isLocallyDefined id &&
 372                    not (omitIfaceSigForId id)
 373 \end{code}
 374
 375 \begin{code}
 376 ifaceBinds :: Handle
 377            -> IdSet             -- These Ids are needed already
 378            -> [Id]              -- Ids used at code-gen time; they have better pragma info!
 379            -> [CoreBind]        -- In dependency order, later depend on earlier
 380            -> IO IdSet          -- Set of Ids actually spat out
 381
 382 ifaceBinds hdl needed_ids final_ids binds
 383   = mapIO (printForIface hdl) (bagToList pretties)      >>
 384     hPutStr hdl "\n"                                    >>
 385     return emitted
 386   where
 387     final_id_map  = listToUFM [(id,id) | id <- final_ids]
 388     get_idinfo id = case lookupUFM final_id_map id of
 389                         Just id' -> idInfo id'
 390                         Nothing  -> pprTrace "ifaceBinds not found:" (ppr id) $
 391                                     idInfo id
 392
 393     (pretties, emitted) = go needed_ids (reverse binds) emptyBag emptyVarSet
 394                         -- Reverse so that later things will
 395                         -- provoke earlier ones to be emitted
 396     go needed [] pretties emitted
 397         | not (isEmptyVarSet needed) = pprTrace "ifaceBinds: free vars:"
 398                                           (sep (map ppr (varSetElems needed)))
 399                                        (pretties, emitted)
 400         | otherwise                  = (pretties, emitted)
 401
 402     go needed (NonRec id rhs : binds) pretties emitted
 403         = case ifaceId get_idinfo needed False id rhs of
 404                 Nothing               -> go needed binds pretties emitted
 405                 Just (pretty, extras) -> let
 406                         needed' = (needed `unionVarSet` extras) `delVarSet` id
 407                         -- 'extras' can include the Id itself via a rule
 408                         emitted' = emitted `extendVarSet` id
 409                         in
 410                         go needed' binds (pretty `consBag` pretties) emitted'
 411
 412         -- Recursive groups are a bit more of a pain.  We may only need one to
 413         -- start with, but it may call out the next one, and so on.  So we
 414         -- have to look for a fixed point.
 415     go needed (Rec pairs : binds) pretties emitted
 416         = go needed' binds pretties' emitted'
 417         where
 418           (new_pretties, new_emitted, extras) = go_rec needed pairs
 419           pretties' = new_pretties `unionBags` pretties
 420           needed'   = (needed `unionVarSet` extras) `minusVarSet` mkVarSet (map fst pairs)
 421           emitted'  = emitted `unionVarSet` new_emitted
 422
 423     go_rec :: IdSet -> [(Id,CoreExpr)] -> (Bag SDoc, IdSet, IdSet)
 424     go_rec needed pairs
 425         | null pretties = (emptyBag, emptyVarSet, emptyVarSet)
 426         | otherwise     = (more_pretties `unionBags`   listToBag pretties,
 427                            more_emitted  `unionVarSet` mkVarSet emitted,
 428                            more_extras   `unionVarSet` extras)
 429         where
 430           maybes               = map do_one pairs
 431           emitted              = [id   | ((id,_), Just _)  <- pairs `zip` maybes]
 432           reduced_pairs        = [pair | (pair,   Nothing) <- pairs `zip` maybes]
 433           (pretties, extras_s) = unzip (catMaybes maybes)
 434           extras               = unionVarSets extras_s
 435           (more_pretties, more_emitted, more_extras) = go_rec extras reduced_pairs
 436
 437           do_one (id,rhs) = ifaceId get_idinfo needed True id rhs
 438 \end{code}
 439
 440
 441 %************************************************************************
 442 %*                                                                      *
 443 \subsection{Random small things}
 444 %*                                                                      *
 445 %************************************************************************
 446
 447 \begin{code}
 448 ifaceTyCons hdl tycons   = hPutCol hdl upp_tycon (sortLt (<) (filter (for_iface_name . getName) tycons ))
 449 ifaceClasses hdl classes = hPutCol hdl upp_class (sortLt (<) (filter (for_iface_name . getName) classes))
 450
 451 for_iface_name name = isLocallyDefined name &&
 452                       not (isWiredInName name)
 453
 454 upp_tycon tycon = ifaceTyCon tycon
 455 upp_class clas  = ifaceClass clas
 456 \end{code}
 457
 458
 459 \begin{code}
 460 ifaceTyCon :: TyCon -> SDoc
 461 ifaceTyCon tycon
 462   | isSynTyCon tycon
 463   = hsep [ ptext SLIT("type"),
 464            ppr (getName tycon),
 465            pprTyVarBndrs tyvars,
 466            ptext SLIT("="),
 467            ppr ty,
 468            semi
 469     ]
 470   where
 471     (tyvars, ty) = getSynTyConDefn tycon
 472
 473 ifaceTyCon tycon
 474   | isAlgTyCon tycon
 475   = hsep [ ptext keyword,
 476            ppr_decl_context (tyConTheta tycon),
 477            ppr (getName tycon),
 478            pprTyVarBndrs (tyConTyVars tycon),
 479            ptext SLIT("="),
 480            hsep (punctuate (ptext SLIT(" | ")) (map ppr_con (tyConDataCons tycon))),
 481            semi
 482     ]
 483   where
 484     keyword | isNewTyCon tycon = SLIT("newtype")
 485             | otherwise        = SLIT("data")
 486
 487     tyvars = tyConTyVars tycon
 488
 489     ppr_con data_con
 490         | null field_labels
 491         = ASSERT( tycon == tycon1 && tyvars == tyvars1 )
 492           hsep [  ppr_ex ex_tyvars ex_theta,
 493                   ppr name,
 494                   hsep (map ppr_arg_ty (strict_marks `zip` arg_tys))
 495                 ]
 496
 497         | otherwise
 498         = hsep [  ppr_ex ex_tyvars ex_theta,
 499                   ppr name,
 500                   braces $ hsep $ punctuate comma (map ppr_field (strict_marks `zip` field_labels))
 501                 ]
 502           where
 503            (tyvars1, theta1, ex_tyvars, ex_theta, arg_tys, tycon1) = dataConSig data_con
 504            field_labels   = dataConFieldLabels data_con
 505            strict_marks   = dataConStrictMarks data_con
 506            name           = getName            data_con
 507
 508     ppr_ex [] ex_theta = ASSERT( null ex_theta ) empty
 509     ppr_ex ex_tvs ex_theta = ptext SLIT("__forall") <+> brackets (pprTyVarBndrs ex_tvs)
 510                              <+> pprIfaceTheta ex_theta <+> ptext SLIT("=>")
 511
 512     ppr_arg_ty (strict_mark, ty) = ppr_strict_mark strict_mark <> pprParendType ty
 513
 514     ppr_strict_mark NotMarkedStrict        = empty
 515     ppr_strict_mark (MarkedUnboxed _ _)    = ptext SLIT("! ! ")
 516     ppr_strict_mark MarkedStrict           = ptext SLIT("! ")
 517
 518     ppr_field (strict_mark, field_label)
 519         = hsep [ ppr (fieldLabelName field_label),
 520                   dcolon,
 521                   ppr_strict_mark strict_mark <> pprParendType (fieldLabelType field_label)
 522                 ]
 523
 524 ifaceTyCon tycon
 525   = pprPanic "pprIfaceTyDecl" (ppr tycon)
 526
 527 ifaceClass clas
 528   = hsep [ptext SLIT("class"),
 529            ppr_decl_context sc_theta,
 530            ppr clas,                    -- Print the name
 531            pprTyVarBndrs clas_tyvars,
 532            pp_ops,
 533            semi
 534           ]
 535    where
 536      (clas_tyvars, sc_theta, _, sel_ids, defms) = classBigSig clas
 537
 538      pp_ops | null sel_ids  = empty
 539             | otherwise = hsep [ptext SLIT("where"),
 540                                  braces (hsep (punctuate semi (zipWith ppr_classop sel_ids defms)))
 541                           ]
 542
 543      ppr_classop sel_id maybe_defm
 544         = ASSERT( sel_tyvars == clas_tyvars)
 545           hsep [ppr (getOccName sel_id),
 546                 if maybeToBool maybe_defm then equals else empty,
 547                 dcolon,
 548                 ppr op_ty
 549           ]
 550         where
 551           (sel_tyvars, _, op_ty) = splitSigmaTy (idType sel_id)
 552
 553 ppr_decl_context :: ThetaType -> SDoc
 554 ppr_decl_context []    = empty
 555 ppr_decl_context theta = pprIfaceTheta theta <+> ptext SLIT(" =>")
 556
 557 pprIfaceTheta :: ThetaType -> SDoc      -- Use braces rather than parens in interface files
 558 pprIfaceTheta []    = empty
 559 pprIfaceTheta theta = braces (hsep (punctuate comma [pprConstraint c tys | (c,tys) <- theta]))
 560 \end{code}
 561
 562 %************************************************************************
 563 %*                                                                      *
 564 \subsection{Random small things}
 565 %*                                                                      *
 566 %************************************************************************
 567
 568 When printing export lists, we print like this:
 569         Avail   f               f
 570         AvailTC C [C, x, y]     C(x,y)
 571         AvailTC C [x, y]        C!(x,y)         -- Exporting x, y but not C
 572
 573 \begin{code}
 574 upp_avail :: AvailInfo -> SDoc
 575 upp_avail (Avail name)      = pprOccName (getOccName name)
 576 upp_avail (AvailTC name []) = empty
 577 upp_avail (AvailTC name ns) = hcat [pprOccName (getOccName name), bang, upp_export ns']
 578                             where
 579                               bang | name `elem` ns = empty
 580                                    | otherwise      = char '|'
 581                               ns' = filter (/= name) ns
 582
 583 upp_export :: [Name] -> SDoc
 584 upp_export []    = empty
 585 upp_export names = braces (hsep (map (pprOccName . getOccName) names))
 586
 587 upp_fixity :: (Name, Fixity) -> SDoc
 588 upp_fixity (name, fixity) = hsep [ptext SLIT("0"), ppr fixity, ppr name, semi]
 589         -- Dummy version number!
 590
 591 ppr_unqual_name :: NamedThing a => a -> SDoc            -- Just its occurrence name
 592 ppr_unqual_name name = pprOccName (getOccName name)
 593 \end{code}
 594
 595
 596 %************************************************************************
 597 %*                                                                      *
 598 \subsection{Comparisons}
 599 %*                                                                      *
 600 %************************************************************************
 601
 602
 603 The various sorts above simply prevent unnecessary "wobbling" when
 604 things change that don't have to.  We therefore compare lexically, not
 605 by unique
 606
 607 \begin{code}
 608 lt_avail :: AvailInfo -> AvailInfo -> Bool
 609
 610 a1 `lt_avail` a2 = availName a1 `lt_name` availName a2
 611
 612 lt_name :: Name -> Name -> Bool
 613 n1 `lt_name` n2 = nameRdrName n1 < nameRdrName n2
 614
 615 lt_lexical :: NamedThing a => a -> a -> Bool
 616 lt_lexical a1 a2 = getName a1 `lt_name` getName a2
 617
 618 lt_imp_vers :: ImportVersion a -> ImportVersion a -> Bool
 619 lt_imp_vers (m1,_,_,_) (m2,_,_,_) = m1 < m2
 620
 621 sort_versions vs = sortLt lt_vers vs
 622
 623 lt_vers :: LocalVersion Name -> LocalVersion Name -> Bool
 624 lt_vers (n1,v1) (n2,v2) = n1 `lt_name` n2
 625 \end{code}
 626
 627
 628 \begin{code}
 629 hPutCol :: Handle
 630         -> (a -> SDoc)
 631         -> [a]
 632         -> IO ()
 633 hPutCol hdl fmt xs = mapIO (printForIface hdl . fmt) xs
 634
 635 mapIO :: (a -> IO b) -> [a] -> IO ()
 636 mapIO f []     = return ()
 637 mapIO f (x:xs) = f x >> mapIO f xs
 638 \end{code}