ghc/compiler/main/Packages.lhs

   1 %
   2 % (c) The University of Glasgow, 2000
   3 %
   4 \section{Package manipulation}
   5
   6 \begin{code}
   7 module Packages (
   8         module PackageConfig,
   9
  10         -- * The PackageConfigMap
  11         PackageConfigMap, emptyPackageConfigMap, lookupPackage,
  12         extendPackageConfigMap, dumpPackages,
  13
  14         -- * Reading the package config, and processing cmdline args
  15         PackageIdH(..), isHomePackage,
  16         PackageState(..),
  17         initPackages,
  18         moduleToPackageConfig,
  19         getPackageDetails,
  20         isHomeModule,
  21
  22         -- * Inspecting the set of packages in scope
  23         getPackageIncludePath,
  24         getPackageCIncludes,
  25         getPackageLibraryPath,
  26         getPackageLinkOpts,
  27         getPackageExtraCcOpts,
  28         getPackageFrameworkPath,
  29         getPackageFrameworks,
  30         getExplicitPackagesAnd,
  31
  32         -- * Utils
  33         isDllName
  34     )
  35 where
  36
  37 #include "HsVersions.h"
  38
  39 import PackageConfig
  40 import SysTools         ( getTopDir, getPackageConfigPath )
  41 import ParsePkgConf     ( loadPackageConfig )
  42 import DynFlags         ( dopt, DynFlag(..), DynFlags(..), PackageFlag(..) )
  43 import StaticFlags      ( opt_Static )
  44 import Config           ( cProjectVersion )
  45 import Name             ( Name, nameModule_maybe )
  46 import Module           ( Module, mkModule )
  47 import UniqFM
  48 import UniqSet
  49 import Util
  50 import Maybes           ( expectJust )
  51 import Panic
  52 import Outputable
  53
  54 #if __GLASGOW_HASKELL__ >= 603
  55 import System.Directory ( getAppUserDataDirectory )
  56 #else
  57 import Compat.Directory ( getAppUserDataDirectory )
  58 #endif
  59
  60 import Distribution.InstalledPackageInfo
  61 import Distribution.Package
  62 import Distribution.Version
  63 import Data.Maybe       ( isNothing )
  64 import System.Directory ( doesFileExist )
  65 import Control.Monad    ( when, foldM )
  66 import Data.List        ( nub, partition )
  67
  68 #ifdef mingw32_TARGET_OS
  69 import Data.List        ( isPrefixOf )
  70 #endif
  71
  72 import FastString
  73 import DATA_IOREF
  74 import EXCEPTION        ( throwDyn )
  75 import ErrUtils         ( debugTraceMsg, putMsg )
  76
  77 -- ---------------------------------------------------------------------------
  78 -- The Package state
  79
  80 -- Package state is all stored in DynFlags, including the details of
  81 -- all packages, which packages are exposed, and which modules they
  82 -- provide.
  83
  84 -- The package state is computed by initPackages, and kept in DynFlags.
  85 --
  86 --   * -package <pkg> causes <pkg> to become exposed, and all other packages
  87 --      with the same name to become hidden.
  88 --
  89 --   * -hide-package <pkg> causes <pkg> to become hidden.
  90 --
  91 --   * Let exposedPackages be the set of packages thus exposed.
  92 --     Let depExposedPackages be the transitive closure from exposedPackages of
  93 --     their dependencies.
  94 --
  95 --   * It is an error for any two packages in depExposedPackages to provide the
  96 --     same module.
  97 --
  98 --   * When searching for a module from an explicit import declaration,
  99 --     only the exposed modules in exposedPackages are valid.
 100 --
 101 --   * When searching for a module from an implicit import, all modules
 102 --     from depExposedPackages are valid.
 103 --
 104 --   * When linking in a comp manager mode, we link in packages the
 105 --     program depends on (the compiler knows this list by the
 106 --     time it gets to the link step).  Also, we link in all packages
 107 --     which were mentioned with explicit -package flags on the command-line,
 108 --     or are a transitive dependency of same, or are "base"/"rts".
 109 --     The reason for (b) is that we might need packages which don't
 110 --     contain any Haskell modules, and therefore won't be discovered
 111 --     by the normal mechanism of dependency tracking.
 112
 113
 114 -- One important thing that the package state provides is a way to
 115 -- tell, for a given module, whether it is part of the current package
 116 -- or not.  We need to know this for two reasons:
 117 --
 118 --  * generating cross-DLL calls is different from intra-DLL calls
 119 --    (see below).
 120 --  * we don't record version information in interface files for entities
 121 --    in a different package.
 122 --
 123 -- Notes on DLLs
 124 -- ~~~~~~~~~~~~~
 125 -- When compiling module A, which imports module B, we need to
 126 -- know whether B will be in the same DLL as A.
 127 --      If it's in the same DLL, we refer to B_f_closure
 128 --      If it isn't, we refer to _imp__B_f_closure
 129 -- When compiling A, we record in B's Module value whether it's
 130 -- in a different DLL, by setting the DLL flag.
 131
 132 data PackageState = PackageState {
 133
 134   explicitPackages      :: [PackageId],
 135         -- The packages we're going to link in eagerly.  This list
 136         -- should be in reverse dependency order; that is, a package
 137         -- is always mentioned before the packages it depends on.
 138
 139   pkgIdMap              :: PackageConfigMap, -- PackageId   -> PackageConfig
 140         -- mapping derived from the package databases and
 141         -- command-line package flags.
 142
 143   moduleToPkgConf       :: UniqFM (PackageConfig,Bool),
 144         -- Maps Module to (pkgconf,exposed), where pkgconf is the
 145         -- PackageConfig for the package containing the module, and
 146         -- exposed is True if the package exposes that module.
 147
 148   -- The PackageIds of some known packages
 149   basePackageId         :: PackageIdH,
 150   rtsPackageId          :: PackageIdH,
 151   haskell98PackageId    :: PackageIdH,
 152   thPackageId           :: PackageIdH
 153   }
 154
 155 data PackageIdH
 156    = HomePackage                -- The "home" package is the package curently
 157                                 -- being compiled
 158    | ExtPackage PackageId       -- An "external" package is any other package
 159
 160
 161 isHomePackage :: PackageIdH -> Bool
 162 isHomePackage HomePackage    = True
 163 isHomePackage (ExtPackage _) = False
 164
 165 -- A PackageConfigMap maps a PackageId to a PackageConfig
 166 type PackageConfigMap = UniqFM PackageConfig
 167
 168 emptyPackageConfigMap :: PackageConfigMap
 169 emptyPackageConfigMap = emptyUFM
 170
 171 lookupPackage :: PackageConfigMap -> PackageId -> Maybe PackageConfig
 172 lookupPackage = lookupUFM
 173
 174 extendPackageConfigMap
 175    :: PackageConfigMap -> [PackageConfig] -> PackageConfigMap
 176 extendPackageConfigMap pkg_map new_pkgs
 177   = foldl add pkg_map new_pkgs
 178   where add pkg_map p = addToUFM pkg_map (packageConfigId p) p
 179
 180 getPackageDetails :: PackageState -> PackageId -> PackageConfig
 181 getPackageDetails dflags ps = expectJust "getPackageDetails" (lookupPackage (pkgIdMap dflags) ps)
 182
 183 -- ----------------------------------------------------------------------------
 184 -- Loading the package config files and building up the package state
 185
 186 initPackages :: DynFlags -> IO DynFlags
 187 initPackages dflags = do
 188   pkg_map <- readPackageConfigs dflags;
 189   state <- mkPackageState dflags pkg_map
 190   return dflags{ pkgState = state }
 191
 192 -- -----------------------------------------------------------------------------
 193 -- Reading the package database(s)
 194
 195 readPackageConfigs :: DynFlags -> IO PackageConfigMap
 196 readPackageConfigs dflags = do
 197         -- System one always comes first
 198    system_pkgconf <- getPackageConfigPath
 199    pkg_map1 <- readPackageConfig dflags emptyPackageConfigMap system_pkgconf
 200
 201         -- Read user's package conf (eg. ~/.ghc/i386-linux-6.3/package.conf)
 202         -- unless the -no-user-package-conf flag was given.
 203         -- We only do this when getAppUserDataDirectory is available
 204         -- (GHC >= 6.3).
 205    (exists, pkgconf) <- catch (do
 206       appdir <- getAppUserDataDirectory "ghc"
 207       let
 208          pkgconf = appdir ++ '/':TARGET_ARCH ++ '-':TARGET_OS
 209                         ++ '-':cProjectVersion ++ "/package.conf"
 210       flg <- doesFileExist pkgconf
 211       return (flg, pkgconf))
 212        -- gobble them all up and turn into False.
 213       (\ _ -> return (False, ""))
 214    pkg_map2 <- if (dopt Opt_ReadUserPackageConf dflags && exists)
 215                   then readPackageConfig dflags pkg_map1 pkgconf
 216                   else return pkg_map1
 217
 218         -- Read all the ones mentioned in -package-conf flags
 219    pkg_map <- foldM (readPackageConfig dflags) pkg_map2
 220                  (extraPkgConfs dflags)
 221
 222    return pkg_map
 223
 224
 225 readPackageConfig
 226    :: DynFlags -> PackageConfigMap -> FilePath -> IO PackageConfigMap
 227 readPackageConfig dflags pkg_map conf_file = do
 228   debugTraceMsg dflags 2 ("Using package config file: " ++ conf_file)
 229   proto_pkg_configs <- loadPackageConfig conf_file
 230   top_dir           <- getTopDir
 231   let pkg_configs = mungePackagePaths top_dir proto_pkg_configs
 232   return (extendPackageConfigMap pkg_map pkg_configs)
 233
 234
 235 mungePackagePaths :: String -> [PackageConfig] -> [PackageConfig]
 236 -- Replace the string "$topdir" at the beginning of a path
 237 -- with the current topdir (obtained from the -B option).
 238 mungePackagePaths top_dir ps = map munge_pkg ps
 239  where
 240   munge_pkg p = p{ importDirs  = munge_paths (importDirs p),
 241                    includeDirs = munge_paths (includeDirs p),
 242                    libraryDirs = munge_paths (libraryDirs p),
 243                    frameworkDirs = munge_paths (frameworkDirs p) }
 244
 245   munge_paths = map munge_path
 246
 247   munge_path p
 248           | Just p' <- maybePrefixMatch "$topdir" p = top_dir ++ p'
 249           | otherwise                               = p
 250
 251
 252 -- -----------------------------------------------------------------------------
 253 -- When all the command-line options are in, we can process our package
 254 -- settings and populate the package state.
 255
 256 mkPackageState :: DynFlags -> PackageConfigMap -> IO PackageState
 257 mkPackageState dflags pkg_db = do
 258   --
 259   -- Modify the package database according to the command-line flags
 260   -- (-package, -hide-package, -ignore-package).
 261   --
 262   -- Also, here we build up a set of the packages mentioned in -package
 263   -- flags on the command line; these are called the "explicit" packages.
 264   -- we link these packages in eagerly.  The explicit set should contain
 265   -- at least rts & base, which is why we pretend that the command line
 266   -- contains -package rts & -package base.
 267   --
 268   let
 269         flags = reverse (packageFlags dflags)
 270
 271         procflags pkgs expl [] = return (pkgs,expl)
 272         procflags pkgs expl (ExposePackage str : flags) = do
 273            case partition (matches str) pkgs of
 274                 ([],_)   -> missingPackageErr str
 275                 ([p],ps) -> procflags (p':ps) (addOneToUniqSet expl pkgid) flags
 276                   where pkgid = packageConfigId p
 277                         p' = p {exposed=True}
 278                 (ps,_)   -> multiplePackagesErr str ps
 279         procflags pkgs expl (HidePackage str : flags) = do
 280            case partition (matches str) pkgs of
 281                 ([],_)   -> missingPackageErr str
 282                 ([p],ps) -> procflags (p':ps) expl flags
 283                   where p' = p {exposed=False}
 284                 (ps,_)   -> multiplePackagesErr str ps
 285         procflags pkgs expl (IgnorePackage str : flags) = do
 286            case partition (matches str) pkgs of
 287                 (ps,qs) -> procflags qs expl flags
 288                 -- missing package is not an error for -ignore-package,
 289                 -- because a common usage is to -ignore-package P as
 290                 -- a preventative measure just in case P exists.
 291
 292         -- A package named on the command line can either include the
 293         -- version, or just the name if it is unambiguous.
 294         matches str p
 295                 =  str == showPackageId (package p)
 296                 || str == pkgName (package p)
 297   --
 298   (pkgs1,explicit) <- procflags (eltsUFM pkg_db) emptyUniqSet flags
 299   --
 300   let
 301         elimDanglingDeps pkgs =
 302            case partition (hasDanglingDeps pkgs) pkgs of
 303               ([],ps) -> ps
 304               (ps,qs) -> elimDanglingDeps qs
 305
 306         hasDanglingDeps pkgs p = any dangling (depends p)
 307           where dangling pid = pid `notElem` all_pids
 308                 all_pids = map package pkgs
 309   --
 310   -- Eliminate any packages which have dangling dependencies (perhaps
 311   -- because the package was removed by -ignore-package).
 312   --
 313   let pkgs = elimDanglingDeps pkgs1
 314       pkg_db = extendPackageConfigMap emptyPackageConfigMap pkgs
 315   --
 316   -- Find the transitive closure of dependencies of exposed
 317   --
 318   let exposed_pkgids = [ packageConfigId p | p <- pkgs, exposed p ]
 319   dep_exposed <- closeDeps pkg_db exposed_pkgids
 320   --
 321   -- Look up some known PackageIds
 322   --
 323   let
 324         lookupPackageByName :: FastString -> PackageIdH
 325         lookupPackageByName nm =
 326           case [ conf | p <- dep_exposed,
 327                         Just conf <- [lookupPackage pkg_db p],
 328                         nm == mkFastString (pkgName (package conf)) ] of
 329                 []     -> HomePackage
 330                 (p:ps) -> ExtPackage (mkPackageId (package p))
 331
 332         -- Get the PackageIds for some known packages (we know the names,
 333         -- but we don't know the versions).  Some of these packages might
 334         -- not exist in the database, so they are Maybes.
 335         basePackageId           = lookupPackageByName basePackageName
 336         rtsPackageId            = lookupPackageByName rtsPackageName
 337         haskell98PackageId      = lookupPackageByName haskell98PackageName
 338         thPackageId             = lookupPackageByName thPackageName
 339
 340         -- add base & rts to the explicit packages
 341         basicLinkedPackages = [basePackageId,rtsPackageId]
 342         explicit' = addListToUniqSet explicit
 343                         [ p | ExtPackage p <- basicLinkedPackages ]
 344   --
 345   -- Close the explicit packages with their dependencies
 346   --
 347   dep_explicit <- closeDeps pkg_db (uniqSetToList explicit')
 348   --
 349   -- Build up a mapping from Module -> PackageConfig for all modules.
 350   -- Discover any conflicts at the same time, and factor in the new exposed
 351   -- status of each package.
 352   --
 353   let
 354         extend_modmap modmap pkgname = do
 355           let
 356                 pkg = expectJust "mkPackageState" (lookupPackage pkg_db pkgname)
 357                 exposed_mods = map mkModule (exposedModules pkg)
 358                 hidden_mods  = map mkModule (hiddenModules pkg)
 359                 all_mods = exposed_mods ++ hidden_mods
 360           --
 361           -- check for overlaps
 362           --
 363           let
 364                 overlaps = [ (m,pkg) | m <- all_mods,
 365                                        Just (pkg,_) <- [lookupUFM modmap m] ]
 366           --
 367           when (not (null overlaps)) $ overlappingError pkg overlaps
 368           --
 369           return (addListToUFM modmap
 370                     [(m, (pkg, m `elem` exposed_mods))
 371                     | m <- all_mods])
 372   --
 373   mod_map <- foldM extend_modmap emptyUFM dep_exposed
 374
 375   return PackageState{ explicitPackages    = dep_explicit,
 376                        pkgIdMap            = pkg_db,
 377                        moduleToPkgConf     = mod_map,
 378                        basePackageId       = basePackageId,
 379                        rtsPackageId        = rtsPackageId,
 380                        haskell98PackageId  = haskell98PackageId,
 381                        thPackageId         = thPackageId
 382                      }
 383   -- done!
 384
 385 basePackageName      = FSLIT("base")
 386 rtsPackageName       = FSLIT("rts")
 387 haskell98PackageName = FSLIT("haskell98")
 388 thPackageName        = FSLIT("template-haskell")
 389                                 -- Template Haskell libraries in here
 390
 391 overlappingError pkg overlaps
 392   = throwDyn (CmdLineError (showSDoc (vcat (map msg overlaps))))
 393   where
 394         this_pkg = text (showPackageId (package pkg))
 395         msg (mod,other_pkg) =
 396            text "Error: module '" <> ppr mod
 397                  <> text "' is exposed by package "
 398                  <> this_pkg <> text " and package "
 399                  <> text (showPackageId (package other_pkg))
 400
 401 multiplePackagesErr str ps =
 402   throwDyn (CmdLineError (showSDoc (
 403                    text "Error; multiple packages match" <+>
 404                         text str <> colon <+>
 405                     sep (punctuate comma (map (text.showPackageId.package) ps))
 406                 )))
 407
 408 -- -----------------------------------------------------------------------------
 409 -- Extracting information from the packages in scope
 410
 411 -- Many of these functions take a list of packages: in those cases,
 412 -- the list is expected to contain the "dependent packages",
 413 -- i.e. those packages that were found to be depended on by the
 414 -- current module/program.  These can be auto or non-auto packages, it
 415 -- doesn't really matter.  The list is always combined with the list
 416 -- of explicit (command-line) packages to determine which packages to
 417 -- use.
 418
 419 getPackageIncludePath :: DynFlags -> [PackageId] -> IO [String]
 420 getPackageIncludePath dflags pkgs = do
 421   ps <- getExplicitPackagesAnd dflags pkgs
 422   return (nub (filter notNull (concatMap includeDirs ps)))
 423
 424         -- includes are in reverse dependency order (i.e. rts first)
 425 getPackageCIncludes :: [PackageConfig] -> IO [String]
 426 getPackageCIncludes pkg_configs = do
 427   return (reverse (nub (filter notNull (concatMap includes pkg_configs))))
 428
 429 getPackageLibraryPath :: DynFlags -> [PackageId] -> IO [String]
 430 getPackageLibraryPath dflags pkgs = do
 431   ps <- getExplicitPackagesAnd dflags pkgs
 432   return (nub (filter notNull (concatMap libraryDirs ps)))
 433
 434 getPackageLinkOpts :: DynFlags -> [PackageId] -> IO [String]
 435 getPackageLinkOpts dflags pkgs = do
 436   ps <- getExplicitPackagesAnd dflags pkgs
 437   let tag = buildTag dflags
 438       rts_tag = rtsBuildTag dflags
 439   let
 440         imp        = if opt_Static then "" else "_dyn"
 441         libs p     = map ((++imp) . addSuffix) (hACK (hsLibraries p)) ++ extraLibraries p
 442         all_opts p = map ("-l" ++) (libs p) ++ ldOptions p
 443
 444         suffix     = if null tag then "" else  '_':tag
 445         rts_suffix = if null rts_tag then "" else  '_':rts_tag
 446
 447         addSuffix rts@"HSrts"    = rts       ++ rts_suffix
 448         addSuffix other_lib      = other_lib ++ suffix
 449
 450   return (concat (map all_opts ps))
 451   where
 452
 453      -- This is a totally horrible (temporary) hack, for Win32.  Problem is
 454      -- that package.conf for Win32 says that the main prelude lib is
 455      -- split into HSbase1, HSbase2 and HSbase3, which is needed due to a bug
 456      -- in the GNU linker (PEi386 backend). However, we still only
 457      -- have HSbase.a for static linking, not HSbase{1,2,3}.a
 458      -- getPackageLibraries is called to find the .a's to add to the static
 459      -- link line.  On Win32, this hACK detects HSbase{1,2,3} and
 460      -- replaces them with HSbase, so static linking still works.
 461      -- Libraries needed for dynamic (GHCi) linking are discovered via
 462      -- different route (in InteractiveUI.linkPackage).
 463      -- See driver/PackageSrc.hs for the HSbase1/HSbase2 split definition.
 464      -- THIS IS A STRICTLY TEMPORARY HACK (famous last words ...)
 465      -- JRS 04 Sept 01: Same appalling hack for HSwin32[1,2]
 466      -- KAA 29 Mar  02: Same appalling hack for HSobjectio[1,2,3,4]
 467      --
 468      -- [sof 03/05: Renamed the (moribund) HSwin32 to HSwin_32 so as to
 469      --  avoid filename conflicts with the 'Win32' package on a case-insensitive filesystem]
 470      hACK libs
 471 #      if !defined(mingw32_TARGET_OS) && !defined(cygwin32_TARGET_OS)
 472        = libs
 473 #      else
 474        = if   "HSbase1" `elem` libs && "HSbase2" `elem` libs && "HSbase3" `elem` libs
 475          then "HSbase" : filter (not.(isPrefixOf "HSbase")) libs
 476          else
 477          if   "HSwin_321" `elem` libs && "HSwin_322" `elem` libs
 478          then "HSwin_32" : filter (not.(isPrefixOf "HSwin_32")) libs
 479          else
 480          if   "HSobjectio1" `elem` libs && "HSobjectio2" `elem` libs && "HSobjectio3" `elem` libs && "HSobjectio4" `elem` libs
 481          then "HSobjectio" : filter (not.(isPrefixOf "HSobjectio")) libs
 482          else
 483          libs
 484 #      endif
 485
 486 getPackageExtraCcOpts :: DynFlags -> [PackageId] -> IO [String]
 487 getPackageExtraCcOpts dflags pkgs = do
 488   ps <- getExplicitPackagesAnd dflags pkgs
 489   return (concatMap ccOptions ps)
 490
 491 getPackageFrameworkPath  :: DynFlags -> [PackageId] -> IO [String]
 492 getPackageFrameworkPath dflags pkgs = do
 493   ps <- getExplicitPackagesAnd dflags pkgs
 494   return (nub (filter notNull (concatMap frameworkDirs ps)))
 495
 496 getPackageFrameworks  :: DynFlags -> [PackageId] -> IO [String]
 497 getPackageFrameworks dflags pkgs = do
 498   ps <- getExplicitPackagesAnd dflags pkgs
 499   return (concatMap frameworks ps)
 500
 501 -- -----------------------------------------------------------------------------
 502 -- Package Utils
 503
 504 -- Takes a Module, and if the module is in a package returns
 505 -- (pkgconf,exposed) where pkgconf is the PackageConfig for that package,
 506 -- and exposed is True if the package exposes the module.
 507 moduleToPackageConfig :: DynFlags -> Module -> Maybe (PackageConfig,Bool)
 508 moduleToPackageConfig dflags m =
 509   lookupUFM (moduleToPkgConf (pkgState dflags)) m
 510
 511 isHomeModule :: DynFlags -> Module -> Bool
 512 isHomeModule dflags mod = isNothing (moduleToPackageConfig dflags mod)
 513
 514 getExplicitPackagesAnd :: DynFlags -> [PackageId] -> IO [PackageConfig]
 515 getExplicitPackagesAnd dflags pkgids =
 516   let
 517       state   = pkgState dflags
 518       pkg_map = pkgIdMap state
 519       expl    = explicitPackages state
 520   in do
 521   all_pkgs <- foldM (add_package pkg_map) expl pkgids
 522   return (map (getPackageDetails state) all_pkgs)
 523
 524 -- Takes a list of packages, and returns the list with dependencies included,
 525 -- in reverse dependency order (a package appears before those it depends on).
 526 closeDeps :: PackageConfigMap -> [PackageId] -> IO [PackageId]
 527 closeDeps pkg_map ps = foldM (add_package pkg_map) [] ps
 528
 529 -- internal helper
 530 add_package :: PackageConfigMap -> [PackageId] -> PackageId -> IO [PackageId]
 531 add_package pkg_db ps p
 532   | p `elem` ps = return ps     -- Check if we've already added this package
 533   | otherwise =
 534       case lookupPackage pkg_db p of
 535         Nothing -> missingPackageErr (packageIdString p)
 536         Just pkg -> do
 537            -- Add the package's dependents also
 538            let deps = map mkPackageId (depends pkg)
 539            ps' <- foldM (add_package pkg_db) ps deps
 540            return (p : ps')
 541
 542 missingPackageErr p =  throwDyn (CmdLineError ("unknown package: " ++ p))
 543
 544 -- -----------------------------------------------------------------------------
 545 -- Determining whether a Name refers to something in another package or not.
 546 -- Cross-package references need to be handled differently when dynamically-
 547 -- linked libraries are involved.
 548
 549 isDllName :: DynFlags -> Name -> Bool
 550 isDllName dflags name
 551   | opt_Static = False
 552   | otherwise =
 553     case nameModule_maybe name of
 554         Nothing -> False  -- no, it is not even an external name
 555         Just mod ->
 556             case lookupUFM (moduleToPkgConf (pkgState dflags)) mod of
 557                 Just _  -> True   -- yes, its a package module
 558                 Nothing -> False  -- no, must be a home module
 559
 560 -- -----------------------------------------------------------------------------
 561 -- Displaying packages
 562
 563 dumpPackages :: DynFlags -> IO ()
 564 -- Show package info on console, if verbosity is >= 3
 565 dumpPackages dflags
 566   = do  let pkg_map = pkgIdMap (pkgState dflags)
 567         putMsg $ showSDoc $
 568               vcat (map (text.showInstalledPackageInfo) (eltsUFM pkg_map))
 569 \end{code}