ghc/compiler/main/SysTools.lhs

   1 -----------------------------------------------------------------------------
   2 -- Access to system tools: gcc, cp, rm etc
   3 --
   4 -- (c) The University of Glasgow 2000
   5 --
   6 -----------------------------------------------------------------------------
   7
   8 \begin{code}
   9 module SysTools (
  10         -- Initialisation
  11         initSysTools,
  12         setPgm,                 -- String -> IO ()
  13                                 -- Command-line override
  14         setDryRun,
  15
  16         packageConfigPath,      -- IO String
  17                                 -- Where package.conf is
  18
  19         -- Interface to system tools
  20         runUnlit, runCpp, runCc, -- [String] -> IO ()
  21         runMangle, runSplit,     -- [String] -> IO ()
  22         runAs, runLink,          -- [String] -> IO ()
  23         runMkDLL,
  24
  25         touch,                  -- String -> String -> IO ()
  26         copy,                   -- String -> String -> String -> IO ()
  27
  28         -- Temporary-file management
  29         setTmpDir,
  30         newTempName,
  31         cleanTempFiles, cleanTempFilesExcept, removeTmpFiles,
  32         addFilesToClean,
  33
  34         -- System interface
  35         getProcessID,           -- IO Int
  36         system,                 -- String -> IO Int
  37
  38         -- Misc
  39         showGhcUsage,           -- IO ()        Shows usage message and exits
  40         getSysMan,              -- IO String    Parallel system only
  41
  42         runSomething    -- ToDo: make private
  43  ) where
  44
  45 import DriverUtil
  46 import Config
  47 import Outputable
  48 import Panic            ( progName, GhcException(..) )
  49 import Util             ( global )
  50 import CmdLineOpts      ( dynFlag, verbosity )
  51
  52 import Exception        ( throwDyn, catchAllIO )
  53 import IO
  54 import Directory        ( doesFileExist, removeFile )
  55 import IOExts           ( IORef, readIORef, writeIORef )
  56 import Monad            ( when, unless )
  57 import System           ( system, ExitCode(..), exitWith )
  58 import CString
  59 import Int
  60
  61 #if __GLASGOW_HASKELL__ < 500
  62 import Storable
  63 #else
  64 import MarshalArray
  65 #endif
  66
  67 #include "../includes/config.h"
  68
  69 #if !defined(mingw32_TARGET_OS)
  70 import qualified Posix
  71 #else
  72 import Addr
  73 import List             ( isPrefixOf )
  74 #endif
  75
  76 import List             ( isSuffixOf )
  77
  78 #include "HsVersions.h"
  79
  80 {-# DEPRECATED runSomething "runSomething should be private to SysTools" #-}
  81
  82 \end{code}
  83
  84
  85                 The configuration story
  86                 ~~~~~~~~~~~~~~~~~~~~~~~
  87
  88 GHC needs various support files (library packages, RTS etc), plus
  89 various auxiliary programs (cp, gcc, etc).  It finds these in one
  90 of two places:
  91
  92 * When running as an *installed program*, GHC finds most of this support
  93   stuff in the installed library tree.  The path to this tree is passed
  94   to GHC via the -B flag, and given to initSysTools .
  95
  96 * When running *in-place* in a build tree, GHC finds most of this support
  97   stuff in the build tree.  The path to the build tree is, again passed
  98   to GHC via -B.
  99
 100 GHC tells which of the two is the case by seeing whether package.conf
 101 is in TopDir [installed] or in TopDir/ghc/driver [inplace] (what a hack).
 102
 103
 104 SysTools.initSysProgs figures out exactly where all the auxiliary programs
 105 are, and initialises mutable variables to make it easy to call them.
 106 To to this, it makes use of definitions in Config.hs, which is a Haskell
 107 file containing variables whose value is figured out by the build system.
 108
 109 Config.hs contains two sorts of things
 110
 111   cGCC,         The *names* of the programs
 112   cCPP            e.g.  cGCC = gcc
 113   cUNLIT                cCPP = gcc -E
 114   etc           They do *not* include paths
 115
 116
 117   cUNLIT_DIR    The *path* to the directory containing unlit, split etc
 118   cSPLIT_DIR    *relative* to the root of the build tree,
 119                 for use when running *in-place* in a build tree (only)
 120
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125 \subsection{Global variables to contain system programs}
 126 %*                                                                      *
 127 %************************************************************************
 128
 129 All these pathnames are maintained IN THE NATIVE FORMAT OF THE HOST MACHINE.
 130 (See remarks under pathnames below)
 131
 132 \begin{code}
 133 GLOBAL_VAR(v_Pgm_L,     error "pgm_L",   String)        -- unlit
 134 GLOBAL_VAR(v_Pgm_P,     error "pgm_P",   String)        -- cpp
 135 GLOBAL_VAR(v_Pgm_c,     error "pgm_c",   String)        -- gcc
 136 GLOBAL_VAR(v_Pgm_m,     error "pgm_m",   String)        -- asm code mangler
 137 GLOBAL_VAR(v_Pgm_s,     error "pgm_s",   String)        -- asm code splitter
 138 GLOBAL_VAR(v_Pgm_a,     error "pgm_a",   String)        -- as
 139 GLOBAL_VAR(v_Pgm_l,     error "pgm_l",   String)        -- ld
 140 GLOBAL_VAR(v_Pgm_MkDLL, error "pgm_dll", String)        -- mkdll
 141
 142 GLOBAL_VAR(v_Pgm_T,    error "pgm_T",    String)        -- touch
 143 GLOBAL_VAR(v_Pgm_CP,   error "pgm_CP",   String)        -- cp
 144
 145 GLOBAL_VAR(v_Path_package_config, error "path_package_config", String)
 146 GLOBAL_VAR(v_Path_usage,          error "ghc_usage.txt",       String)
 147
 148 -- Parallel system only
 149 GLOBAL_VAR(v_Pgm_sysman, error "pgm_sysman", String)    -- system manager
 150 \end{code}
 151
 152
 153 %************************************************************************
 154 %*                                                                      *
 155 \subsection{Initialisation}
 156 %*                                                                      *
 157 %************************************************************************
 158
 159 \begin{code}
 160 initSysTools :: [String]        -- Command-line arguments starting "-B"
 161
 162              -> IO String       -- Set all the mutable variables above, holding
 163                                 --      (a) the system programs
 164                                 --      (b) the package-config file
 165                                 --      (c) the GHC usage message
 166                                 -- Return TopDir
 167
 168
 169 initSysTools minusB_args
 170   = do  { (am_installed, top_dir) <- getTopDir minusB_args
 171                 -- top_dir
 172                 --      for "installed" this is the root of GHC's support files
 173                 --      for "in-place" it is the root of the build tree
 174                 -- NB: top_dir is assumed to be in standard Unix format '/' separated
 175
 176         ; let installed_bin pgm   =  pgmPath (top_dir `slash` "bin") pgm
 177               installed     file  =  pgmPath top_dir file
 178               inplace dir   pgm   =  pgmPath (top_dir `slash` dir) pgm
 179
 180         ; let pkgconfig_path
 181                 | am_installed = installed "package.conf"
 182                 | otherwise    = inplace cGHC_DRIVER_DIR "package.conf.inplace"
 183
 184               ghc_usage_msg_path
 185                 | am_installed = installed "ghc-usage.txt"
 186                 | otherwise    = inplace cGHC_DRIVER_DIR "ghc-usage.txt"
 187
 188                 -- For all systems, unlit, split, mangle are GHC utilities
 189                 -- architecture-specific stuff is done when building Config.hs
 190               unlit_path
 191                 | am_installed = installed_bin cGHC_UNLIT
 192                 | otherwise    = inplace cGHC_UNLIT_DIR cGHC_UNLIT
 193
 194                 -- split and mangle are Perl scripts
 195               split_script
 196                 | am_installed = installed_bin cGHC_SPLIT
 197                 | otherwise    = inplace cGHC_SPLIT_DIR cGHC_SPLIT
 198
 199               mangle_script
 200                 | am_installed = installed_bin cGHC_MANGLER
 201                 | otherwise    = inplace cGHC_MANGLER_DIR cGHC_MANGLER
 202
 203         -- Check that the package config exists
 204         ; config_exists <- doesFileExist pkgconfig_path
 205         ; when (not config_exists) $
 206              throwDyn (InstallationError
 207                          ("Can't find package.conf as " ++ pkgconfig_path))
 208
 209 #if defined(mingw32_TARGET_OS)
 210         --              WINDOWS-SPECIFIC STUFF
 211         -- On Windows, gcc and friends are distributed with GHC,
 212         --      so when "installed" we look in TopDir/bin
 213         -- When "in-place" we look wherever the build-time configure
 214         --      script found them
 215         ; let cpp_path  | am_installed = installed cRAWCPP
 216                         | otherwise    = cRAWCPP
 217               gcc_path  | am_installed = installed cGCC
 218                         | otherwise    = cGCC
 219               perl_path | am_installed = installed cGHC_PERL
 220                         | otherwise    = cGHC_PERL
 221
 222         -- 'touch' is a GHC util for Windows, and similarly unlit, mangle
 223         ; let touch_path  | am_installed = installed cGHC_TOUCHY
 224                           | otherwise    = inplace cGHC_TOUCHY_DIR cGHC_TOUCHY
 225
 226         -- On Win32 we don't want to rely on #!/bin/perl, so we prepend
 227         -- a call to Perl to get the invocation of split and mangle
 228         ; let split_path  = perl_path ++ " " ++ split_script
 229               mangle_path = perl_path ++ " " ++ mangle_script
 230
 231         ; let mkdll_path = cMKDLL
 232 #else
 233         --              UNIX-SPECIFIC STUFF
 234         -- On Unix, the "standard" tools are assumed to be
 235         -- in the same place whether we are running "in-place" or "installed"
 236         -- That place is wherever the build-time configure script found them.
 237         ; let   cpp_path   = cRAWCPP
 238                 gcc_path   = cGCC
 239                 touch_path = cGHC_TOUCHY
 240                 mkdll_path = panic "Can't build DLLs on a non-Win32 system"
 241
 242         -- On Unix, scripts are invoked using the '#!' method.  Binary
 243         -- installations of GHC on Unix place the correct line on the front
 244         -- of the script at installation time, so we don't want to wire-in
 245         -- our knowledge of $(PERL) on the host system here.
 246         ; let split_path  = split_script
 247               mangle_path = mangle_script
 248
 249 #endif
 250
 251         -- For all systems, copy and remove are provided by the host
 252         -- system; architecture-specific stuff is done when building Config.hs
 253         ; let   cp_path = cGHC_CP
 254
 255         -- Other things being equal, as and ld are simply gcc
 256         ; let   as_path  = gcc_path
 257                 ld_path  = gcc_path
 258
 259
 260         -- Initialise the global vars
 261         ; writeIORef v_Path_package_config pkgconfig_path
 262         ; writeIORef v_Path_usage          ghc_usage_msg_path
 263
 264         ; writeIORef v_Pgm_sysman          (top_dir ++ "/ghc/rts/parallel/SysMan")
 265                 -- Hans: this isn't right in general, but you can
 266                 -- elaborate it in the same way as the others
 267
 268         ; writeIORef v_Pgm_L               unlit_path
 269         ; writeIORef v_Pgm_P               cpp_path
 270         ; writeIORef v_Pgm_c               gcc_path
 271         ; writeIORef v_Pgm_m               mangle_path
 272         ; writeIORef v_Pgm_s               split_path
 273         ; writeIORef v_Pgm_a               as_path
 274         ; writeIORef v_Pgm_l               ld_path
 275         ; writeIORef v_Pgm_MkDLL           mkdll_path
 276         ; writeIORef v_Pgm_T               touch_path
 277         ; writeIORef v_Pgm_CP              cp_path
 278
 279         ; return top_dir
 280         }
 281 \end{code}
 282
 283 setPgm is called when a command-line option like
 284         -pgmLld
 285 is used to override a particular program with a new onw
 286
 287 \begin{code}
 288 setPgm :: String -> IO ()
 289 -- The string is the flag, minus the '-pgm' prefix
 290 -- So the first character says which program to override
 291
 292 setPgm ('P' : pgm) = writeIORef v_Pgm_P pgm
 293 setPgm ('c' : pgm) = writeIORef v_Pgm_c pgm
 294 setPgm ('m' : pgm) = writeIORef v_Pgm_m pgm
 295 setPgm ('s' : pgm) = writeIORef v_Pgm_s pgm
 296 setPgm ('a' : pgm) = writeIORef v_Pgm_a pgm
 297 setPgm ('l' : pgm) = writeIORef v_Pgm_l pgm
 298 setPgm pgm         = unknownFlagErr ("-pgm" ++ pgm)
 299 \end{code}
 300
 301
 302 \begin{code}
 303 -- Find TopDir
 304 --      for "installed" this is the root of GHC's support files
 305 --      for "in-place" it is the root of the build tree
 306 --
 307 -- Plan of action:
 308 -- 1. Set proto_top_dir
 309 --      a) look for (the last) -B flag, and use it
 310 --      b) if there are no -B flags, get the directory
 311 --         where GHC is running
 312 --
 313 -- 2. If package.conf exists in proto_top_dir, we are running
 314 --      installed; and TopDir = proto_top_dir
 315 --
 316 -- 3. Otherwise we are running in-place, so
 317 --      proto_top_dir will be /...stuff.../ghc/compiler
 318 --      Set TopDir to /...stuff..., which is the root of the build tree
 319 --
 320 -- This is very gruesome indeed
 321
 322 getTopDir :: [String]
 323           -> IO (Bool,          -- True <=> am installed, False <=> in-place
 324                  String)        -- TopDir (in Unix format '/' separated)
 325
 326 getTopDir minusbs
 327   = do { top_dir1 <- get_proto
 328        ; let top_dir2 = unDosifyPath top_dir1   -- Convert to standard internal form
 329
 330         -- Discover whether we're running in a build tree or in an installation,
 331         -- by looking for the package configuration file.
 332        ; am_installed <- doesFileExist (top_dir2 `slash` "package.conf")
 333
 334        ; return (am_installed, top_dir2)
 335        }
 336   where
 337     get_proto | not (null minusbs)
 338               = return (drop 2 (last minusbs))  -- 2 for "-B"
 339               | otherwise
 340               = do { maybe_exec_dir <- getExecDir -- Get directory of executable
 341                    ; case maybe_exec_dir of       -- (only works on Windows;
 342                                                   --  returns Nothing on Unix)
 343                         Nothing  -> throwDyn (InstallationError "missing -B<dir> option")
 344                         Just dir -> return (remove_suffix dir)
 345                    }
 346
 347     -- In an installed tree, the ghc binary lives in $libexecdir, which
 348     -- is normally $libdir/bin.  So we strip off a /bin suffix here.
 349     -- In a build tree, the ghc binary lives in $fptools/ghc/compiler,
 350     -- so we strip off the /ghc/compiler suffix here too, leaving a
 351     -- standard TOPDIR.
 352     remove_suffix ghc_bin_dir   -- ghc_bin_dir is in standard Unix format
 353         | "/ghc/compiler" `isSuffixOf` ghc_bin_dir      = back_two
 354         | "/bin" `isSuffixOf` ghc_bin_dir               = back_one
 355         | otherwise                                     = ghc_bin_dir
 356         where
 357          p1      = dropWhile (not . isSlash) (reverse ghc_bin_dir)
 358          p2      = dropWhile (not . isSlash) (tail p1)  -- head is '/'
 359          back_two = reverse (tail p2)                   -- head is '/'
 360          back_one = reverse (tail p1)
 361 \end{code}
 362
 363
 364 %************************************************************************
 365 %*                                                                      *
 366 \subsection{Running an external program}
 367 n%*                                                                     *
 368 %************************************************************************
 369
 370
 371 \begin{code}
 372 runUnlit :: [String] -> IO ()
 373 runUnlit args = do p <- readIORef v_Pgm_L
 374                    runSomething "Literate pre-processor" p args
 375
 376 runCpp :: [String] -> IO ()
 377 runCpp args =   do p <- readIORef v_Pgm_P
 378                    runSomething "C pre-processor" p args
 379
 380 runCc :: [String] -> IO ()
 381 runCc args =   do p <- readIORef v_Pgm_c
 382                   runSomething "C Compiler" p args
 383
 384 runMangle :: [String] -> IO ()
 385 runMangle args = do p <- readIORef v_Pgm_m
 386                     runSomething "Mangler" p args
 387
 388 runSplit :: [String] -> IO ()
 389 runSplit args = do p <- readIORef v_Pgm_s
 390                    runSomething "Splitter" p args
 391
 392 runAs :: [String] -> IO ()
 393 runAs args = do p <- readIORef v_Pgm_a
 394                 runSomething "Assembler" p args
 395
 396 runLink :: [String] -> IO ()
 397 runLink args = do p <- readIORef v_Pgm_l
 398                   runSomething "Linker" p args
 399
 400 runMkDLL :: [String] -> IO ()
 401 runMkDLL args = do p <- readIORef v_Pgm_MkDLL
 402                    runSomething "Make DLL" p args
 403
 404 touch :: String -> String -> IO ()
 405 touch purpose arg =  do p <- readIORef v_Pgm_T
 406                         runSomething purpose p [arg]
 407
 408 copy :: String -> String -> String -> IO ()
 409 copy purpose from to =
 410     (do
 411       h <- openFile to WriteMode
 412       ls <- readFile from -- inefficient, but it'll do for now.
 413                               -- ToDo: speed up via slurping.
 414       hPutStrLn h ls
 415       hClose h) `catchAllIO`
 416                  (\_ -> throwDyn (PhaseFailed purpose (ExitFailure 1)))
 417 \end{code}
 418
 419 \begin{code}
 420 getSysMan :: IO String  -- How to invoke the system manager
 421                         -- (parallel system only)
 422 getSysMan = readIORef v_Pgm_sysman
 423 \end{code}
 424
 425 %************************************************************************
 426 %*                                                                      *
 427 \subsection{GHC Usage message}
 428 %*                                                                      *
 429 %************************************************************************
 430
 431 Show the usage message and exit
 432
 433 \begin{code}
 434 showGhcUsage = do { usage_path <- readIORef v_Path_usage
 435                   ; usage      <- readFile usage_path
 436                   ; dump usage
 437                   ; exitWith ExitSuccess }
 438   where
 439      dump ""          = return ()
 440      dump ('$':'$':s) = hPutStr stderr progName >> dump s
 441      dump (c:s)       = hPutChar stderr c >> dump s
 442
 443 packageConfigPath = readIORef v_Path_package_config
 444 \end{code}
 445
 446
 447 %************************************************************************
 448 %*                                                                      *
 449 \subsection{Managing temporary files
 450 %*                                                                      *
 451 %************************************************************************
 452
 453 \begin{code}
 454 GLOBAL_VAR(v_FilesToClean, [],               [String] )
 455 GLOBAL_VAR(v_TmpDir,       cDEFAULT_TMPDIR,  String   )
 456         -- v_TmpDir has no closing '/'
 457 \end{code}
 458
 459 \begin{code}
 460 setTmpDir dir = writeIORef v_TmpDir dir
 461
 462 cleanTempFiles :: Int -> IO ()
 463 cleanTempFiles verb = do fs <- readIORef v_FilesToClean
 464                          removeTmpFiles verb fs
 465
 466 cleanTempFilesExcept :: Int -> [FilePath] -> IO ()
 467 cleanTempFilesExcept verb dont_delete
 468   = do fs <- readIORef v_FilesToClean
 469        let leftovers = filter (`notElem` dont_delete) fs
 470        removeTmpFiles verb leftovers
 471        writeIORef v_FilesToClean dont_delete
 472
 473
 474 -- find a temporary name that doesn't already exist.
 475 newTempName :: Suffix -> IO FilePath
 476 newTempName extn
 477   = do x <- getProcessID
 478        tmp_dir <- readIORef v_TmpDir
 479        findTempName tmp_dir x
 480   where
 481     findTempName tmp_dir x
 482       = do let filename = tmp_dir ++ "/ghc" ++ show x ++ '.':extn
 483            b  <- doesFileExist filename
 484            if b then findTempName tmp_dir (x+1)
 485                 else do add v_FilesToClean filename -- clean it up later
 486                         return filename
 487
 488 addFilesToClean :: [FilePath] -> IO ()
 489 -- May include wildcards [used by DriverPipeline.run_phase SplitMangle]
 490 addFilesToClean files = mapM_ (add v_FilesToClean) files
 491
 492 removeTmpFiles :: Int -> [FilePath] -> IO ()
 493 removeTmpFiles verb fs
 494   = traceCmd "Deleting temp files"
 495              ("Deleting: " ++ unwords fs)
 496              (mapM_ rm fs)
 497   where
 498     rm f = removeFile f `catchAllIO`
 499                 (\exn -> hPutStrLn stderr ("Warning: deleting non-existent " ++ f) >>
 500                          return ())
 501
 502 \end{code}
 503
 504
 505 %************************************************************************
 506 %*                                                                      *
 507 \subsection{Running a program}
 508 %*                                                                      *
 509 %************************************************************************
 510
 511 \begin{code}
 512 GLOBAL_VAR(v_Dry_run, False, Bool)
 513
 514 setDryRun :: IO ()
 515 setDryRun = writeIORef v_Dry_run True
 516
 517 -----------------------------------------------------------------------------
 518 -- Running an external program
 519
 520 runSomething :: String          -- For -v message
 521              -> String          -- Command name (possibly a full path)
 522                                 --      assumed already dos-ified
 523              -> [String]        -- Arguments
 524                                 --      runSomething will dos-ify them
 525              -> IO ()
 526
 527 runSomething phase_name pgm args
 528  = traceCmd phase_name cmd_line $
 529    do   { exit_code <- system cmd_line
 530         ; if exit_code /= ExitSuccess
 531           then throwDyn (PhaseFailed phase_name exit_code)
 532           else return ()
 533         }
 534   where
 535     cmd_line = unwords (pgm : dosifyPaths args)
 536         -- The pgm is already in native format (appropriate dir separators)
 537
 538 traceCmd :: String -> String -> IO () -> IO ()
 539 -- a) trace the command (at two levels of verbosity)
 540 -- b) don't do it at all if dry-run is set
 541 traceCmd phase_name cmd_line action
 542  = do   { verb <- dynFlag verbosity
 543         ; when (verb >= 2) $ hPutStrLn stderr ("*** " ++ phase_name)
 544         ; when (verb >= 3) $ hPutStrLn stderr cmd_line
 545         ; hFlush stderr
 546
 547            -- Test for -n flag
 548         ; n <- readIORef v_Dry_run
 549         ; unless n $ do {
 550
 551            -- And run it!
 552         ; action `catchAllIO` handle_exn verb
 553         }}
 554   where
 555     handle_exn verb exn = do { when (verb >= 2) (hPutStr   stderr "\n")
 556                              ; when (verb >= 3) (hPutStrLn stderr ("Failed: " ++ cmd_line))
 557                              ; throwDyn (PhaseFailed phase_name (ExitFailure 1)) }
 558 \end{code}
 559
 560
 561 %************************************************************************
 562 %*                                                                      *
 563 \subsection{Path names}
 564 %*                                                                      *
 565 %************************************************************************
 566
 567 We maintain path names in Unix form ('/'-separated) right until
 568 the last moment.  On Windows we dos-ify them just before passing them
 569 to the Windows command.
 570
 571 The alternative, of using '/' consistently on Unix and '\' on Windows,
 572 proved quite awkward.  There were a lot more calls to dosifyPath,
 573 and even on Windows we might invoke a unix-like utility (eg 'sh'), which
 574 interpreted a command line 'foo\baz' as 'foobaz'.
 575
 576 \begin{code}
 577 -----------------------------------------------------------------------------
 578 -- Convert filepath into MSDOS form.
 579
 580 dosifyPaths :: [String] -> [String]
 581 -- dosifyPaths does two things
 582 -- a) change '/' to '\'
 583 -- b) remove initial '/cygdrive/'
 584
 585 unDosifyPath :: String -> String
 586 -- Just change '\' to '/'
 587
 588 pgmPath :: String               -- Directory string in Unix format
 589         -> String               -- Program name with no directory separators
 590                                 --      (e.g. copy /y)
 591         -> String               -- Program invocation string in native format
 592
 593
 594
 595 #if defined(mingw32_TARGET_OS)
 596
 597 --------------------- Windows version ------------------
 598 unDosifyPath xs = xs
 599
 600 dosifyPaths xs = map dosifyPath xs
 601
 602 pgmPath dir pgm = dosifyPath dir ++ '\\' : pgm
 603
 604 dosifyPath stuff
 605   = subst '/' '\\' real_stuff
 606  where
 607    -- fully convince myself that /cygdrive/ prefixes cannot
 608    -- really appear here.
 609   cygdrive_prefix = "/cygdrive/"
 610
 611   real_stuff
 612     | cygdrive_prefix `isPrefixOf` stuff = drop (length cygdrive_prefix) stuff
 613     | otherwise = stuff
 614
 615 #else
 616
 617 --------------------- Unix version ---------------------
 618 dosifyPaths  ps = ps
 619 unDosifyPath xs = subst '\\' '/' xs
 620 pgmPath dir pgm = dir ++ '/' : pgm
 621 --------------------------------------------------------
 622 #endif
 623
 624 subst a b ls = map (\ x -> if x == a then b else x) ls
 625 \end{code}
 626
 627
 628 -----------------------------------------------------------------------------
 629    Path name construction
 630
 631 \begin{code}
 632 slash            :: String -> String -> String
 633 absPath, relPath :: [String] -> String
 634
 635 isSlash '/'   = True
 636 isSlash other = False
 637
 638 relPath [] = ""
 639 relPath xs = foldr1 slash xs
 640
 641 absPath xs = "" `slash` relPath xs
 642
 643 slash s1 s2 = s1 ++ ('/' : s2)
 644 \end{code}
 645
 646
 647 %************************************************************************
 648 %*                                                                      *
 649 \subsection{Support code}
 650 %*                                                                      *
 651 %************************************************************************
 652
 653 \begin{code}
 654 -----------------------------------------------------------------------------
 655 -- Define       myGetProcessId :: IO Int
 656 --              getExecDir     :: IO (Maybe String)
 657
 658 #ifdef mingw32_TARGET_OS
 659 foreign import "_getpid" getProcessID :: IO Int -- relies on Int == Int32 on Windows
 660
 661 #if __GLASGOW_HASKELL__ >= 500
 662 foreign import stdcall "GetCurrentDirectoryA" getCurrentDirectory :: Int32 -> CString -> IO Int32
 663 foreign import stdcall "GetCurrentDirectoryA" getCurrentDirectoryLen :: Int32 -> Addr -> IO Int32
 664 getExecDir :: IO (Maybe String)
 665 getExecDir = do len <- getCurrentDirectoryLen 0 nullAddr
 666                 buf <- mallocArray (fromIntegral len)
 667                 ret <- getCurrentDirectory len buf
 668                 if ret == 0 then return Nothing
 669                             else do s <- peekCString buf
 670                                     destructArray (fromIntegral len) buf
 671                                     return (Just s)
 672 #else
 673 foreign import stdcall "GetCurrentDirectoryA" getCurrentDirectory :: Int32 -> Addr -> IO Int32
 674 getExecDir :: IO (Maybe String)
 675 getExecDir = do len <- getCurrentDirectory 0 nullAddr
 676                 buf <- malloc (fromIntegral len)
 677                 ret <- getCurrentDirectory len buf
 678                 if ret == 0 then return Nothing
 679                             else do s <- unpackCStringIO buf
 680                                     free buf
 681                                     return (Just s)
 682 #endif
 683 #else
 684 getProcessID :: IO Int
 685 getProcessID = Posix.getProcessID
 686 getExecDir :: IO (Maybe String) = do return Nothing
 687 #endif
 688 \end{code}