ghc/compiler/parser/Parser.y

   1 {-                                                              -*-haskell-*-
   2 -----------------------------------------------------------------------------
   3 $Id: Parser.y,v 1.131 2003/11/27 13:26:39 simonmar Exp $
   4
   5 Haskell grammar.
   6
   7 Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -----------------------------------------------------------------------------
   9 -}
  10
  11 {
  12 module Parser ( parseModule, parseStmt, parseIdentifier, parseIface ) where
  13
  14 #include "HsVersions.h"
  15
  16 import HsSyn
  17 import RdrHsSyn
  18 import HscTypes         ( ModIface, IsBootInterface, DeprecTxt )
  19 import Lexer
  20 import RdrName
  21 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  22                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  23 import Type             ( funTyCon )
  24 import ForeignCall      ( Safety(..), CExportSpec(..),
  25                           CCallConv(..), CCallTarget(..), defaultCCallConv
  26                         )
  27 import OccName          ( UserFS, varName, dataName, tcClsName, tvName )
  28 import DataCon          ( DataCon, dataConName )
  29 import SrcLoc           ( SrcLoc, noSrcLoc )
  30 import Module
  31 import CmdLineOpts      ( opt_SccProfilingOn )
  32 import Type             ( Kind, mkArrowKind, liftedTypeKind )
  33 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  34                           NewOrData(..), Activation(..) )
  35 import Panic
  36
  37 import GLAEXTS
  38 import CStrings         ( CLabelString )
  39 import FastString
  40 import Maybes           ( orElse )
  41 import Outputable
  42 import Char             ( ord )
  43
  44 }
  45
  46 {-
  47 -----------------------------------------------------------------------------
  48 Conflicts: 29 shift/reduce, [SDM 19/9/2002]
  49
  50 10 for abiguity in 'if x then y else z + 1'             [State 136]
  51         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  52         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
  53
  54 1 for ambiguity in 'if x then y else z with ?x=3'       [State 136]
  55         (shift parses as 'if x then y else (z with ?x=3)'
  56
  57 1 for ambiguity in 'if x then y else z :: T'            [State 136]
  58         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  59
  60 8 for ambiguity in 'e :: a `b` c'.  Does this mean      [States 160,246]
  61         (e::a) `b` c, or
  62         (e :: (a `b` c))
  63
  64 1 for ambiguity in 'let ?x ...'                         [State 268]
  65         the parser can't tell whether the ?x is the lhs of a normal binding or
  66         an implicit binding.  Fortunately resolving as shift gives it the only
  67         sensible meaning, namely the lhs of an implicit binding.
  68
  69 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 332]
  70         we don't know whether the '[' starts the activation or not: it
  71         might be the start of the declaration with the activation being
  72         empty.  --SDM 1/4/2002
  73
  74 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 394]
  75         since 'forall' is a valid variable name, we don't know whether
  76         to treat a forall on the input as the beginning of a quantifier
  77         or the beginning of the rule itself.  Resolving to shift means
  78         it's always treated as a quantifier, hence the above is disallowed.
  79         This saves explicitly defining a grammar for the rule lhs that
  80         doesn't include 'forall'.
  81
  82 6 for conflicts between `fdecl' and `fdeclDEPRECATED',  [States 384,385]
  83         which are resolved correctly, and moreover,
  84         should go away when `fdeclDEPRECATED' is removed.
  85
  86 -----------------------------------------------------------------------------
  87 -}
  88
  89 %token
  90  '_'            { T _ _ ITunderscore }          -- Haskell keywords
  91  'as'           { T _ _ ITas }
  92  'case'         { T _ _ ITcase }
  93  'class'        { T _ _ ITclass }
  94  'data'         { T _ _ ITdata }
  95  'default'      { T _ _ ITdefault }
  96  'deriving'     { T _ _ ITderiving }
  97  'do'           { T _ _ ITdo }
  98  'else'         { T _ _ ITelse }
  99  'hiding'       { T _ _ IThiding }
 100  'if'           { T _ _ ITif }
 101  'import'       { T _ _ ITimport }
 102  'in'           { T _ _ ITin }
 103  'infix'        { T _ _ ITinfix }
 104  'infixl'       { T _ _ ITinfixl }
 105  'infixr'       { T _ _ ITinfixr }
 106  'instance'     { T _ _ ITinstance }
 107  'let'          { T _ _ ITlet }
 108  'module'       { T _ _ ITmodule }
 109  'newtype'      { T _ _ ITnewtype }
 110  'of'           { T _ _ ITof }
 111  'qualified'    { T _ _ ITqualified }
 112  'then'         { T _ _ ITthen }
 113  'type'         { T _ _ ITtype }
 114  'where'        { T _ _ ITwhere }
 115  '_scc_'        { T _ _ ITscc }       -- ToDo: remove
 116
 117  'forall'       { T _ _ ITforall }                      -- GHC extension keywords
 118  'foreign'      { T _ _ ITforeign }
 119  'export'       { T _ _ ITexport }
 120  'label'        { T _ _ ITlabel }
 121  'dynamic'      { T _ _ ITdynamic }
 122  'safe'         { T _ _ ITsafe }
 123  'threadsafe'   { T _ _ ITthreadsafe }
 124  'unsafe'       { T _ _ ITunsafe }
 125  'mdo'          { T _ _ ITmdo }
 126  'stdcall'      { T _ _ ITstdcallconv }
 127  'ccall'        { T _ _ ITccallconv }
 128  'dotnet'       { T _ _ ITdotnet }
 129  'proc'         { T _ _ ITproc }                -- for arrow notation extension
 130  'rec'          { T _ _ ITrec }         -- for arrow notation extension
 131
 132  '{-# SPECIALISE'  { T _ _ ITspecialise_prag }
 133  '{-# SOURCE'      { T _ _ ITsource_prag }
 134  '{-# INLINE'      { T _ _ ITinline_prag }
 135  '{-# NOINLINE'    { T _ _ ITnoinline_prag }
 136  '{-# RULES'       { T _ _ ITrules_prag }
 137  '{-# CORE'        { T _ _ ITcore_prag }              -- hdaume: annotated core
 138  '{-# SCC'         { T _ _ ITscc_prag }
 139  '{-# DEPRECATED'  { T _ _ ITdeprecated_prag }
 140  '{-# UNPACK'      { T _ _ ITunpack_prag }
 141  '#-}'             { T _ _ ITclose_prag }
 142
 143  '..'           { T _ _ ITdotdot }                      -- reserved symbols
 144  ':'            { T _ _ ITcolon }
 145  '::'           { T _ _ ITdcolon }
 146  '='            { T _ _ ITequal }
 147  '\\'           { T _ _ ITlam }
 148  '|'            { T _ _ ITvbar }
 149  '<-'           { T _ _ ITlarrow }
 150  '->'           { T _ _ ITrarrow }
 151  '@'            { T _ _ ITat }
 152  '~'            { T _ _ ITtilde }
 153  '=>'           { T _ _ ITdarrow }
 154  '-'            { T _ _ ITminus }
 155  '!'            { T _ _ ITbang }
 156  '*'            { T _ _ ITstar }
 157  '-<'           { T _ _ ITlarrowtail }          -- for arrow notation
 158  '>-'           { T _ _ ITrarrowtail }          -- for arrow notation
 159  '-<<'          { T _ _ ITLarrowtail }          -- for arrow notation
 160  '>>-'          { T _ _ ITRarrowtail }          -- for arrow notation
 161  '.'            { T _ _ ITdot }
 162
 163  '{'            { T _ _ ITocurly }                      -- special symbols
 164  '}'            { T _ _ ITccurly }
 165  '{|'           { T _ _ ITocurlybar }
 166  '|}'           { T _ _ ITccurlybar }
 167  vocurly        { T _ _ ITvocurly } -- virtual open curly (from layout)
 168  vccurly        { T _ _ ITvccurly } -- virtual close curly (from layout)
 169  '['            { T _ _ ITobrack }
 170  ']'            { T _ _ ITcbrack }
 171  '[:'           { T _ _ ITopabrack }
 172  ':]'           { T _ _ ITcpabrack }
 173  '('            { T _ _ IToparen }
 174  ')'            { T _ _ ITcparen }
 175  '(#'           { T _ _ IToubxparen }
 176  '#)'           { T _ _ ITcubxparen }
 177  '(|'           { T _ _ IToparenbar }
 178  '|)'           { T _ _ ITcparenbar }
 179  ';'            { T _ _ ITsemi }
 180  ','            { T _ _ ITcomma }
 181  '`'            { T _ _ ITbackquote }
 182
 183  VARID          { T _ _ (ITvarid    $$) }               -- identifiers
 184  CONID          { T _ _ (ITconid    $$) }
 185  VARSYM         { T _ _ (ITvarsym   $$) }
 186  CONSYM         { T _ _ (ITconsym   $$) }
 187  QVARID         { T _ _ (ITqvarid   $$) }
 188  QCONID         { T _ _ (ITqconid   $$) }
 189  QVARSYM        { T _ _ (ITqvarsym  $$) }
 190  QCONSYM        { T _ _ (ITqconsym  $$) }
 191
 192  IPDUPVARID     { T _ _ (ITdupipvarid   $$) }           -- GHC extension
 193  IPSPLITVARID   { T _ _ (ITsplitipvarid $$) }           -- GHC extension
 194
 195  CHAR           { T _ _ (ITchar     $$) }
 196  STRING         { T _ _ (ITstring   $$) }
 197  INTEGER        { T _ _ (ITinteger  $$) }
 198  RATIONAL       { T _ _ (ITrational $$) }
 199
 200  PRIMCHAR       { T _ _ (ITprimchar   $$) }
 201  PRIMSTRING     { T _ _ (ITprimstring $$) }
 202  PRIMINTEGER    { T _ _ (ITprimint    $$) }
 203  PRIMFLOAT      { T _ _ (ITprimfloat  $$) }
 204  PRIMDOUBLE     { T _ _ (ITprimdouble $$) }
 205
 206 -- Template Haskell
 207 '[|'            { T _ _ ITopenExpQuote  }
 208 '[p|'           { T _ _ ITopenPatQuote  }
 209 '[t|'           { T _ _ ITopenTypQuote  }
 210 '[d|'           { T _ _ ITopenDecQuote  }
 211 '|]'            { T _ _ ITcloseQuote    }
 212 TH_ID_SPLICE    { T _ _ (ITidEscape $$) }     -- $x
 213 '$('            { T _ _ ITparenEscape   }     -- $( exp )
 214 TH_VAR_QUOTE    { T _ _ ITvarQuote      }     -- 'x
 215 TH_TY_QUOTE     { T _ _ ITtyQuote      }      -- ''T
 216
 217 %monad { P } { >>= } { return }
 218 %lexer { lexer } { T _ _ ITeof }
 219 %name parseModule module
 220 %name parseStmt   maybe_stmt
 221 %name parseIdentifier  identifier
 222 %name parseIface iface
 223 %tokentype { Token }
 224 %%
 225
 226 -----------------------------------------------------------------------------
 227 -- Module Header
 228
 229 -- The place for module deprecation is really too restrictive, but if it
 230 -- was allowed at its natural place just before 'module', we get an ugly
 231 -- s/r conflict with the second alternative. Another solution would be the
 232 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 233 -- either, and DEPRECATED is only expected to be used by people who really
 234 -- know what they are doing. :-)
 235
 236 module  :: { RdrNameHsModule }
 237         : srcloc 'module' modid maybemoddeprec maybeexports 'where' body
 238                 { HsModule (Just (mkHomeModule $3)) $5 (fst $7) (snd $7) $4 $1 }
 239         | srcloc missing_module_keyword top close
 240                 { HsModule Nothing Nothing (fst $3) (snd $3) Nothing $1 }
 241
 242 missing_module_keyword :: { () }
 243         : {- empty -}                           {% pushCurrentContext }
 244
 245 maybemoddeprec :: { Maybe DeprecTxt }
 246         : '{-# DEPRECATED' STRING '#-}'         { Just $2 }
 247         |  {- empty -}                          { Nothing }
 248
 249 body    :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 250         :  '{'            top '}'               { $2 }
 251         |      vocurly    top close             { $2 }
 252
 253 top     :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 254         : importdecls                           { (reverse $1,[]) }
 255         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 256         | cvtopdecls                            { ([],$1) }
 257
 258 cvtopdecls :: { [RdrNameHsDecl] }
 259         : topdecls                      { cvTopDecls $1 }
 260
 261 -----------------------------------------------------------------------------
 262 -- Interfaces (.hi-boot files)
 263
 264 iface   :: { ModIface }
 265         : 'module' modid 'where' ifacebody  { mkBootIface $2 $4 }
 266
 267 ifacebody :: { [HsDecl RdrName] }
 268         :  '{'            ifacedecls '}'                { $2 }
 269         |      vocurly    ifacedecls close              { $2 }
 270
 271 ifacedecls :: { [HsDecl RdrName] }
 272         : ifacedecl ';' ifacedecls      { $1 : $3 }
 273         | ';' ifacedecls                { $2 }
 274         | ifacedecl                     { [$1] }
 275         | {- empty -}                   { [] }
 276
 277 ifacedecl :: { HsDecl RdrName }
 278         : var '::' sigtype
 279                 { SigD (Sig $1 $3 noSrcLoc) }
 280         | 'type' syn_hdr '=' ctype
 281                 { let (tc,tvs) = $2 in TyClD (TySynonym tc tvs $4 noSrcLoc) }
 282         | new_or_data tycl_hdr
 283                 { TyClD (mkTyData $1 $2 [] Nothing noSrcLoc) }
 284         | 'class' tycl_hdr fds
 285                 { TyClD (mkClassDecl $2 $3 [] EmptyMonoBinds noSrcLoc) }
 286
 287 new_or_data :: { NewOrData }
 288         : 'data'        { DataType }
 289         | 'newtype'     { NewType }
 290
 291 -----------------------------------------------------------------------------
 292 -- The Export List
 293
 294 maybeexports :: { Maybe [RdrNameIE] }
 295         :  '(' exportlist ')'                   { Just $2 }
 296         |  {- empty -}                          { Nothing }
 297
 298 exportlist :: { [RdrNameIE] }
 299         :  exportlist ',' export                { $3 : $1 }
 300         |  exportlist ','                       { $1 }
 301         |  export                               { [$1]  }
 302         |  {- empty -}                          { [] }
 303
 304    -- No longer allow things like [] and (,,,) to be exported
 305    -- They are built in syntax, always available
 306 export  :: { RdrNameIE }
 307         :  qvar                                 { IEVar $1 }
 308         |  oqtycon                              { IEThingAbs $1 }
 309         |  oqtycon '(' '..' ')'                 { IEThingAll $1 }
 310         |  oqtycon '(' ')'                      { IEThingWith $1 [] }
 311         |  oqtycon '(' qcnames ')'              { IEThingWith $1 (reverse $3) }
 312         |  'module' modid                       { IEModuleContents $2 }
 313
 314 qcnames :: { [RdrName] }
 315         :  qcnames ',' qcname                   { $3 : $1 }
 316         |  qcname                               { [$1]  }
 317
 318 qcname  :: { RdrName }  -- Variable or data constructor
 319         :  qvar                                 { $1 }
 320         |  gcon                                 { $1 }
 321
 322 -----------------------------------------------------------------------------
 323 -- Import Declarations
 324
 325 -- import decls can be *empty*, or even just a string of semicolons
 326 -- whereas topdecls must contain at least one topdecl.
 327
 328 importdecls :: { [RdrNameImportDecl] }
 329         : importdecls ';' importdecl            { $3 : $1 }
 330         | importdecls ';'                       { $1 }
 331         | importdecl                            { [ $1 ] }
 332         | {- empty -}                           { [] }
 333
 334 importdecl :: { RdrNameImportDecl }
 335         : 'import' srcloc maybe_src optqualified modid maybeas maybeimpspec
 336                 { ImportDecl $5 $3 $4 $6 $7 $2 }
 337
 338 maybe_src :: { IsBootInterface }
 339         : '{-# SOURCE' '#-}'                    { True }
 340         | {- empty -}                           { False }
 341
 342 optqualified :: { Bool }
 343         : 'qualified'                           { True  }
 344         | {- empty -}                           { False }
 345
 346 maybeas :: { Maybe ModuleName }
 347         : 'as' modid                            { Just $2 }
 348         | {- empty -}                           { Nothing }
 349
 350 maybeimpspec :: { Maybe (Bool, [RdrNameIE]) }
 351         : impspec                               { Just $1 }
 352         | {- empty -}                           { Nothing }
 353
 354 impspec :: { (Bool, [RdrNameIE]) }
 355         :  '(' exportlist ')'                   { (False, reverse $2) }
 356         |  'hiding' '(' exportlist ')'          { (True,  reverse $3) }
 357
 358 -----------------------------------------------------------------------------
 359 -- Fixity Declarations
 360
 361 prec    :: { Int }
 362         : {- empty -}                           { 9 }
 363         | INTEGER                               {% checkPrecP (fromInteger $1) }
 364
 365 infix   :: { FixityDirection }
 366         : 'infix'                               { InfixN  }
 367         | 'infixl'                              { InfixL  }
 368         | 'infixr'                              { InfixR }
 369
 370 ops     :: { [RdrName] }
 371         : ops ',' op                            { $3 : $1 }
 372         | op                                    { [$1] }
 373
 374 -----------------------------------------------------------------------------
 375 -- Top-Level Declarations
 376
 377 topdecls :: { [RdrBinding] }    -- Reversed
 378         : topdecls ';' topdecl          { $3 : $1 }
 379         | topdecls ';'                  { $1 }
 380         | topdecl                       { [$1] }
 381
 382 topdecl :: { RdrBinding }
 383         : tycl_decl                     { RdrHsDecl (TyClD $1) }
 384         | srcloc 'instance' inst_type where
 385                 { let (binds,sigs) = cvMonoBindsAndSigs $4
 386                   in RdrHsDecl (InstD (InstDecl $3 binds sigs $1)) }
 387         | srcloc 'default' '(' comma_types0 ')'         { RdrHsDecl (DefD (DefaultDecl $4 $1)) }
 388         | 'foreign' fdecl                               { RdrHsDecl $2 }
 389         | '{-# DEPRECATED' deprecations '#-}'           { RdrBindings (reverse $2) }
 390         | '{-# RULES' rules '#-}'                       { RdrBindings (reverse $2) }
 391         | srcloc '$(' exp ')'                           { RdrHsDecl (SpliceD (SpliceDecl $3 $1)) }
 392         | decl                                          { $1 }
 393
 394 tycl_decl :: { RdrNameTyClDecl }
 395         : srcloc 'type' syn_hdr '=' ctype
 396                 -- Note ctype, not sigtype.
 397                 -- We allow an explicit for-all but we don't insert one
 398                 -- in   type Foo a = (b,b)
 399                 -- Instead we just say b is out of scope
 400                 { let (tc,tvs) = $3 in TySynonym tc tvs $5 $1 }
 401
 402         | srcloc 'data' tycl_hdr constrs deriving
 403                 { mkTyData DataType $3 (reverse $4) $5 $1 }
 404
 405         | srcloc 'newtype' tycl_hdr '=' newconstr deriving
 406                 { mkTyData NewType $3 [$5] $6 $1 }
 407
 408         | srcloc 'class' tycl_hdr fds where
 409                 { let
 410                         (binds,sigs) = cvMonoBindsAndSigs $5
 411                   in
 412                   mkClassDecl $3 $4 sigs binds $1 }
 413
 414 syn_hdr :: { (RdrName, [RdrNameHsTyVar]) }      -- We don't retain the syntax of an infix
 415                                                 -- type synonym declaration. Oh well.
 416         : tycon tv_bndrs                { ($1, $2) }
 417         | tv_bndr tyconop tv_bndr       { ($2, [$1,$3]) }
 418
 419 -- tycl_hdr parses the header of a type or class decl,
 420 -- which takes the form
 421 --      T a b
 422 --      Eq a => T a
 423 --      (Eq a, Ord b) => T a b
 424 -- Rather a lot of inlining here, else we get reduce/reduce errors
 425 tycl_hdr :: { (RdrNameContext, RdrName, [RdrNameHsTyVar]) }
 426         : context '=>' type             {% checkTyClHdr $1 $3 }
 427         | type                          {% checkTyClHdr [] $1 }
 428
 429 -----------------------------------------------------------------------------
 430 -- Nested declarations
 431
 432 decls   :: { [RdrBinding] }     -- Reversed
 433         : decls ';' decl                { $3 : $1 }
 434         | decls ';'                     { $1 }
 435         | decl                          { [$1] }
 436         | {- empty -}                   { [] }
 437
 438
 439 decllist :: { [RdrBinding] }    -- Reversed
 440         : '{'            decls '}'      { $2 }
 441         |     vocurly    decls close    { $2 }
 442
 443 where   :: { [RdrBinding] }     -- Reversed
 444                                 -- No implicit parameters
 445         : 'where' decllist              { $2 }
 446         | {- empty -}                   { [] }
 447
 448 binds   ::  { RdrNameHsBinds }  -- May have implicit parameters
 449         : decllist                      { cvBinds $1 }
 450         | '{'            dbinds '}'     { IPBinds $2 }
 451         |     vocurly    dbinds close   { IPBinds $2 }
 452
 453 wherebinds :: { RdrNameHsBinds }        -- May have implicit parameters
 454         : 'where' binds                 { $2 }
 455         | {- empty -}                   { EmptyBinds }
 456
 457
 458
 459 -----------------------------------------------------------------------------
 460 -- Transformation Rules
 461
 462 rules   :: { [RdrBinding] }     -- Reversed
 463         :  rules ';' rule                       { $3 : $1 }
 464         |  rules ';'                            { $1 }
 465         |  rule                                 { [$1] }
 466         |  {- empty -}                          { [] }
 467
 468 rule    :: { RdrBinding }
 469         : STRING activation rule_forall infixexp '=' srcloc exp
 470              { RdrHsDecl (RuleD (HsRule $1 $2 $3 $4 $7 $6)) }
 471
 472 activation :: { Activation }           -- Omitted means AlwaysActive
 473         : {- empty -}                           { AlwaysActive }
 474         | explicit_activation                   { $1 }
 475
 476 inverse_activation :: { Activation }   -- Omitted means NeverActive
 477         : {- empty -}                           { NeverActive }
 478         | explicit_activation                   { $1 }
 479
 480 explicit_activation :: { Activation }  -- In brackets
 481         : '[' INTEGER ']'                       { ActiveAfter  (fromInteger $2) }
 482         | '[' '~' INTEGER ']'                   { ActiveBefore (fromInteger $3) }
 483
 484 rule_forall :: { [RdrNameRuleBndr] }
 485         : 'forall' rule_var_list '.'            { $2 }
 486         | {- empty -}                           { [] }
 487
 488 rule_var_list :: { [RdrNameRuleBndr] }
 489         : rule_var                              { [$1] }
 490         | rule_var rule_var_list                { $1 : $2 }
 491
 492 rule_var :: { RdrNameRuleBndr }
 493         : varid                                 { RuleBndr $1 }
 494         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 495
 496 -----------------------------------------------------------------------------
 497 -- Deprecations (c.f. rules)
 498
 499 deprecations :: { [RdrBinding] }        -- Reversed
 500         : deprecations ';' deprecation          { $3 : $1 }
 501         | deprecations ';'                      { $1 }
 502         | deprecation                           { [$1] }
 503         | {- empty -}                           { [] }
 504
 505 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 506 deprecation :: { RdrBinding }
 507         : srcloc depreclist STRING
 508                 { RdrBindings
 509                         [ RdrHsDecl (DeprecD (Deprecation n $3 $1)) | n <- $2 ] }
 510
 511
 512 -----------------------------------------------------------------------------
 513 -- Foreign import and export declarations
 514
 515 -- for the time being, the following accepts foreign declarations conforming
 516 -- to the FFI Addendum, Version 1.0 as well as pre-standard declarations
 517 --
 518 -- * a flag indicates whether pre-standard declarations have been used and
 519 --   triggers a deprecation warning further down the road
 520 --
 521 -- NB: The first two rules could be combined into one by replacing `safety1'
 522 --     with `safety'.  However, the combined rule conflicts with the
 523 --     DEPRECATED rules.
 524 --
 525 fdecl :: { RdrNameHsDecl }
 526 fdecl : srcloc 'import' callconv safety1 fspec  {% mkImport $3 $4       $5 $1 }
 527       | srcloc 'import' callconv         fspec  {% mkImport $3 (PlaySafe False) $4 $1 }
 528       | srcloc 'export' callconv         fspec  {% mkExport $3          $4 $1 }
 529         -- the following syntax is DEPRECATED
 530       | srcloc fdecl1DEPRECATED                 { ForD ($2 True $1) }
 531       | srcloc fdecl2DEPRECATED                 { $2 $1 }
 532
 533 fdecl1DEPRECATED :: { Bool -> SrcLoc -> ForeignDecl RdrName }
 534 fdecl1DEPRECATED
 535   ----------- DEPRECATED label decls ------------
 536   : 'label' ext_name varid '::' sigtype
 537     { ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 538                                    (CLabel ($2 `orElse` mkExtName $3))) }
 539
 540   ----------- DEPRECATED ccall/stdcall decls ------------
 541   --
 542   -- NB: This business with the case expression below may seem overly
 543   --     complicated, but it is necessary to avoid some conflicts.
 544
 545     -- DEPRECATED variant #1: lack of a calling convention specification
 546     --                        (import)
 547   | 'import' {-no callconv-} ext_name safety varid_no_unsafe '::' sigtype
 548     { let
 549         target = StaticTarget ($2 `orElse` mkExtName $4)
 550       in
 551       ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 552                                    (CFunction target)) }
 553
 554     -- DEPRECATED variant #2: external name consists of two separate strings
 555     --                        (module name and function name) (import)
 556   | 'import' callconv STRING STRING safety varid_no_unsafe '::' sigtype
 557     {% case $2 of
 558          DNCall      -> parseError "Illegal format of .NET foreign import"
 559          CCall cconv -> return $
 560            let
 561              imp = CFunction (StaticTarget $4)
 562            in
 563            ForeignImport $6 $8 (CImport cconv $5 nilFS nilFS imp) }
 564
 565     -- DEPRECATED variant #3: `unsafe' after entity
 566   | 'import' callconv STRING 'unsafe' varid_no_unsafe '::' sigtype
 567     {% case $2 of
 568          DNCall      -> parseError "Illegal format of .NET foreign import"
 569          CCall cconv -> return $
 570            let
 571              imp = CFunction (StaticTarget $3)
 572            in
 573            ForeignImport $5 $7 (CImport cconv PlayRisky nilFS nilFS imp) }
 574
 575     -- DEPRECATED variant #4: use of the special identifier `dynamic' without
 576     --                        an explicit calling convention (import)
 577   | 'import' {-no callconv-} 'dynamic' safety varid_no_unsafe '::' sigtype
 578     { ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 579                                    (CFunction DynamicTarget)) }
 580
 581     -- DEPRECATED variant #5: use of the special identifier `dynamic' (import)
 582   | 'import' callconv 'dynamic' safety varid_no_unsafe '::' sigtype
 583     {% case $2 of
 584          DNCall      -> parseError "Illegal format of .NET foreign import"
 585          CCall cconv -> return $
 586            ForeignImport $5 $7 (CImport cconv $4 nilFS nilFS
 587                                         (CFunction DynamicTarget)) }
 588
 589     -- DEPRECATED variant #6: lack of a calling convention specification
 590     --                        (export)
 591   | 'export' {-no callconv-} ext_name varid '::' sigtype
 592     { ForeignExport $3 $5 (CExport (CExportStatic ($2 `orElse` mkExtName $3)
 593                                    defaultCCallConv)) }
 594
 595     -- DEPRECATED variant #7: external name consists of two separate strings
 596     --                        (module name and function name) (export)
 597   | 'export' callconv STRING STRING varid '::' sigtype
 598     {% case $2 of
 599          DNCall      -> parseError "Illegal format of .NET foreign import"
 600          CCall cconv -> return $
 601            ForeignExport $5 $7
 602                          (CExport (CExportStatic $4 cconv)) }
 603
 604     -- DEPRECATED variant #8: use of the special identifier `dynamic' without
 605     --                        an explicit calling convention (export)
 606   | 'export' {-no callconv-} 'dynamic' varid '::' sigtype
 607     { ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 608                                    CWrapper) }
 609
 610     -- DEPRECATED variant #9: use of the special identifier `dynamic' (export)
 611   | 'export' callconv 'dynamic' varid '::' sigtype
 612     {% case $2 of
 613          DNCall      -> parseError "Illegal format of .NET foreign import"
 614          CCall cconv -> return $
 615            ForeignImport $4 $6 (CImport cconv (PlaySafe False) nilFS nilFS CWrapper) }
 616
 617   ----------- DEPRECATED .NET decls ------------
 618   -- NB: removed the .NET call declaration, as it is entirely subsumed
 619   --     by the new standard FFI declarations
 620
 621 fdecl2DEPRECATED :: { SrcLoc -> RdrNameHsDecl }
 622 fdecl2DEPRECATED
 623   : 'import' 'dotnet' 'type' ext_name tycon
 624           { \loc -> TyClD (ForeignType $5 $4 DNType loc) }
 625     -- left this one unchanged for the moment as type imports are not
 626     -- covered currently by the FFI standard -=chak
 627
 628
 629 callconv :: { CallConv }
 630           : 'stdcall'                   { CCall  StdCallConv }
 631           | 'ccall'                     { CCall  CCallConv   }
 632           | 'dotnet'                    { DNCall             }
 633
 634 safety :: { Safety }
 635         : 'unsafe'                      { PlayRisky }
 636         | 'safe'                        { PlaySafe False }
 637         | 'threadsafe'                  { PlaySafe True  }
 638         | {- empty -}                   { PlaySafe False }
 639
 640 safety1 :: { Safety }
 641         : 'unsafe'                      { PlayRisky }
 642         | 'safe'                        { PlaySafe  False }
 643         | 'threadsafe'                  { PlaySafe  True }
 644           -- only needed to avoid conflicts with the DEPRECATED rules
 645
 646 fspec :: { (FastString, RdrName, RdrNameHsType) }
 647        : STRING var '::' sigtype      { ($1      , $2, $4) }
 648        |        var '::' sigtype      { (nilFS, $1, $3) }
 649          -- if the entity string is missing, it defaults to the empty string;
 650          -- the meaning of an empty entity string depends on the calling
 651          -- convention
 652
 653 -- DEPRECATED syntax
 654 ext_name :: { Maybe CLabelString }
 655         : STRING                { Just $1 }
 656         | STRING STRING         { Just $2 }     -- Ignore "module name" for now
 657         | {- empty -}           { Nothing }
 658
 659
 660 -----------------------------------------------------------------------------
 661 -- Type signatures
 662
 663 opt_sig :: { Maybe RdrNameHsType }
 664         : {- empty -}                   { Nothing }
 665         | '::' sigtype                  { Just $2 }
 666
 667 opt_asig :: { Maybe RdrNameHsType }
 668         : {- empty -}                   { Nothing }
 669         | '::' atype                    { Just $2 }
 670
 671 sigtypes :: { [RdrNameHsType] }
 672         : sigtype                       { [ $1 ] }
 673         | sigtypes ',' sigtype          { $3 : $1 }
 674
 675 sigtype :: { RdrNameHsType }
 676         : ctype                         { mkImplicitHsForAllTy [] $1 }
 677         -- Wrap an Implicit forall if there isn't one there already
 678
 679 sig_vars :: { [RdrName] }
 680          : sig_vars ',' var             { $3 : $1 }
 681          | var                          { [ $1 ] }
 682
 683 -----------------------------------------------------------------------------
 684 -- Types
 685
 686 -- A ctype is a for-all type
 687 ctype   :: { RdrNameHsType }
 688         : 'forall' tv_bndrs '.' ctype   { mkExplicitHsForAllTy $2 [] $4 }
 689         | context '=>' type             { mkImplicitHsForAllTy   $1 $3 }
 690         -- A type of form (context => type) is an *implicit* HsForAllTy
 691         | type                          { $1 }
 692
 693 -- We parse a context as a btype so that we don't get reduce/reduce
 694 -- errors in ctype.  The basic problem is that
 695 --      (Eq a, Ord a)
 696 -- looks so much like a tuple type.  We can't tell until we find the =>
 697 context :: { RdrNameContext }
 698         : btype                         {% checkContext $1 }
 699
 700 type :: { RdrNameHsType }
 701         : ipvar '::' gentype            { mkHsIParamTy $1 $3 }
 702         | gentype                       { $1 }
 703
 704 gentype :: { RdrNameHsType }
 705         : btype                         { $1 }
 706         | btype qtyconop gentype        { HsOpTy $1 $2 $3 }
 707         | btype  '`' tyvar '`' gentype  { HsOpTy $1 $3 $5 }
 708         | btype '->' gentype            { HsFunTy $1 $3 }
 709
 710 btype :: { RdrNameHsType }
 711         : btype atype                   { HsAppTy $1 $2 }
 712         | atype                         { $1 }
 713
 714 atype :: { RdrNameHsType }
 715         : gtycon                        { HsTyVar $1 }
 716         | tyvar                         { HsTyVar $1 }
 717         | '(' type ',' comma_types1 ')' { HsTupleTy Boxed  ($2:$4) }
 718         | '(#' comma_types1 '#)'        { HsTupleTy Unboxed $2     }
 719         | '[' type ']'                  { HsListTy  $2 }
 720         | '[:' type ':]'                { HsPArrTy  $2 }
 721         | '(' ctype ')'                 { HsParTy   $2 }
 722         | '(' ctype '::' kind ')'       { HsKindSig $2 $4 }
 723 -- Generics
 724         | INTEGER                       { HsNumTy $1 }
 725
 726 -- An inst_type is what occurs in the head of an instance decl
 727 --      e.g.  (Foo a, Gaz b) => Wibble a b
 728 -- It's kept as a single type, with a MonoDictTy at the right
 729 -- hand corner, for convenience.
 730 inst_type :: { RdrNameHsType }
 731         : ctype                         {% checkInstType $1 }
 732
 733 comma_types0  :: { [RdrNameHsType] }
 734         : comma_types1                  { $1 }
 735         | {- empty -}                   { [] }
 736
 737 comma_types1    :: { [RdrNameHsType] }
 738         : type                          { [$1] }
 739         | type  ',' comma_types1        { $1 : $3 }
 740
 741 tv_bndrs :: { [RdrNameHsTyVar] }
 742          : tv_bndr tv_bndrs             { $1 : $2 }
 743          | {- empty -}                  { [] }
 744
 745 tv_bndr :: { RdrNameHsTyVar }
 746         : tyvar                         { UserTyVar $1 }
 747         | '(' tyvar '::' kind ')'       { KindedTyVar $2 $4 }
 748
 749 fds :: { [([RdrName], [RdrName])] }
 750         : {- empty -}                   { [] }
 751         | '|' fds1                      { reverse $2 }
 752
 753 fds1 :: { [([RdrName], [RdrName])] }
 754         : fds1 ',' fd                   { $3 : $1 }
 755         | fd                            { [$1] }
 756
 757 fd :: { ([RdrName], [RdrName]) }
 758         : varids0 '->' varids0          { (reverse $1, reverse $3) }
 759
 760 varids0 :: { [RdrName] }
 761         : {- empty -}                   { [] }
 762         | varids0 tyvar                 { $2 : $1 }
 763
 764 -----------------------------------------------------------------------------
 765 -- Kinds
 766
 767 kind    :: { Kind }
 768         : akind                 { $1 }
 769         | akind '->' kind       { mkArrowKind $1 $3 }
 770
 771 akind   :: { Kind }
 772         : '*'                   { liftedTypeKind }
 773         | '(' kind ')'          { $2 }
 774
 775
 776 -----------------------------------------------------------------------------
 777 -- Datatype declarations
 778
 779 newconstr :: { RdrNameConDecl }
 780         : srcloc conid atype    { ConDecl $2 [] [] (PrefixCon [unbangedType $3]) $1 }
 781         | srcloc conid '{' var '::' ctype '}'
 782                                 { ConDecl $2 [] [] (RecCon [($4, unbangedType $6)]) $1 }
 783
 784 constrs :: { [RdrNameConDecl] }
 785         : {- empty; a GHC extension -}  { [] }
 786         | '=' constrs1                  { $2 }
 787
 788 constrs1 :: { [RdrNameConDecl] }
 789         : constrs1 '|' constr           { $3 : $1 }
 790         | constr                        { [$1] }
 791
 792 constr :: { RdrNameConDecl }
 793         : srcloc forall context '=>' constr_stuff
 794                 { ConDecl (fst $5) $2 $3 (snd $5) $1 }
 795         | srcloc forall constr_stuff
 796                 { ConDecl (fst $3) $2 [] (snd $3) $1 }
 797
 798 forall :: { [RdrNameHsTyVar] }
 799         : 'forall' tv_bndrs '.'         { $2 }
 800         | {- empty -}                   { [] }
 801
 802 constr_stuff :: { (RdrName, RdrNameConDetails) }
 803         : btype                         {% mkPrefixCon $1 [] }
 804         | btype strict_mark atype satypes {% mkPrefixCon $1 (BangType $2 $3 : $4) }
 805         | oqtycon '{' '}'               {% mkRecCon $1 [] }
 806         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 }
 807         | sbtype conop sbtype           { ($2, InfixCon $1 $3) }
 808
 809 satypes :: { [RdrNameBangType] }
 810         : atype satypes                 { unbangedType $1 : $2 }
 811         | strict_mark atype satypes     { BangType $1 $2 : $3 }
 812         | {- empty -}                   { [] }
 813
 814 sbtype :: { RdrNameBangType }
 815         : btype                         { unbangedType $1 }
 816         | strict_mark atype             { BangType $1 $2 }
 817
 818 fielddecls :: { [([RdrName],RdrNameBangType)] }
 819         : fielddecl ',' fielddecls      { $1 : $3 }
 820         | fielddecl                     { [$1] }
 821
 822 fielddecl :: { ([RdrName],RdrNameBangType) }
 823         : sig_vars '::' stype           { (reverse $1, $3) }
 824
 825 stype :: { RdrNameBangType }
 826         : ctype                         { unbangedType $1 }
 827         | strict_mark atype             { BangType $1 $2 }
 828
 829 strict_mark :: { HsBang }
 830         : '!'                           { HsStrict }
 831         | '{-# UNPACK' '#-}' '!'        { HsUnbox }
 832
 833 deriving :: { Maybe RdrNameContext }
 834         : {- empty -}                   { Nothing }
 835         | 'deriving' context            { Just $2 }
 836              -- Glasgow extension: allow partial
 837              -- applications in derivings
 838
 839 -----------------------------------------------------------------------------
 840 -- Value definitions
 841
 842 {- There's an awkward overlap with a type signature.  Consider
 843         f :: Int -> Int = ...rhs...
 844    Then we can't tell whether it's a type signature or a value
 845    definition with a result signature until we see the '='.
 846    So we have to inline enough to postpone reductions until we know.
 847 -}
 848
 849 {-
 850   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
 851   instead of qvar, we get another shift/reduce-conflict. Consider the
 852   following programs:
 853
 854      { (^^) :: Int->Int ; }          Type signature; only var allowed
 855
 856      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
 857                                      qvar allowed (because of instance decls)
 858
 859   We can't tell whether to reduce var to qvar until after we've read the signatures.
 860 -}
 861
 862 decl    :: { RdrBinding }
 863         : sigdecl                       { $1 }
 864         | infixexp srcloc opt_sig rhs   {% checkValDef $1 $3 $4 $2 }
 865
 866 rhs     :: { RdrNameGRHSs }
 867         : '=' srcloc exp wherebinds     { GRHSs (unguardedRHS $3 $2) $4 placeHolderType }
 868         | gdrhs wherebinds              { GRHSs (reverse $1)         $2 placeHolderType }
 869
 870 gdrhs :: { [RdrNameGRHS] }
 871         : gdrhs gdrh                    { $2 : $1 }
 872         | gdrh                          { [$1] }
 873
 874 gdrh :: { RdrNameGRHS }
 875         : '|' srcloc quals '=' exp      { GRHS (reverse (ResultStmt $5 $2 : $3)) $2 }
 876
 877 sigdecl :: { RdrBinding }
 878         : infixexp srcloc '::' sigtype
 879                                 {% checkValSig $1 $4 $2 }
 880                 -- See the above notes for why we need infixexp here
 881         | var ',' sig_vars srcloc '::' sigtype
 882                                 { mkSigDecls [ Sig n $6 $4 | n <- $1:$3 ] }
 883         | srcloc infix prec ops { mkSigDecls [ FixSig (FixitySig n (Fixity $3 $2) $1)
 884                                              | n <- $4 ] }
 885         | '{-# INLINE'   srcloc activation qvar '#-}'
 886                                 { RdrHsDecl (SigD (InlineSig True  $4 $3 $2)) }
 887         | '{-# NOINLINE' srcloc inverse_activation qvar '#-}'
 888                                 { RdrHsDecl (SigD (InlineSig False $4 $3 $2)) }
 889         | '{-# SPECIALISE' srcloc qvar '::' sigtypes '#-}'
 890                                 { mkSigDecls  [ SpecSig $3 t $2 | t <- $5] }
 891         | '{-# SPECIALISE' srcloc 'instance' inst_type '#-}'
 892                                 { RdrHsDecl (SigD (SpecInstSig $4 $2)) }
 893
 894 -----------------------------------------------------------------------------
 895 -- Expressions
 896
 897 exp   :: { RdrNameHsExpr }
 898         : infixexp '::' sigtype         { ExprWithTySig $1 $3 }
 899         | fexp srcloc '-<' exp          { HsArrApp $1 $4 placeHolderType HsFirstOrderApp True $2 }
 900         | fexp srcloc '>-' exp          { HsArrApp $4 $1 placeHolderType HsFirstOrderApp False $2 }
 901         | fexp srcloc '-<<' exp         { HsArrApp $1 $4 placeHolderType HsHigherOrderApp True $2 }
 902         | fexp srcloc '>>-' exp         { HsArrApp $4 $1 placeHolderType HsHigherOrderApp False $2 }
 903         | infixexp                      { $1 }
 904
 905 infixexp :: { RdrNameHsExpr }
 906         : exp10                         { $1 }
 907         | infixexp qop exp10            { (OpApp $1 (HsVar $2)
 908                                                 (panic "fixity") $3 )}
 909
 910 exp10 :: { RdrNameHsExpr }
 911         : '\\' srcloc aexp aexps opt_asig '->' srcloc exp
 912                         {% checkPatterns $2 ($3 : reverse $4) >>= \ ps ->
 913                            return (HsLam (Match ps $5
 914                                             (GRHSs (unguardedRHS $8 $7)
 915                                                    EmptyBinds placeHolderType))) }
 916         | 'let' binds 'in' exp                  { HsLet $2 $4 }
 917         | 'if' srcloc exp 'then' exp 'else' exp { HsIf $3 $5 $7 $2 }
 918         | 'case' srcloc exp 'of' altslist       { HsCase $3 $5 $2 }
 919         | '-' fexp                              { mkHsNegApp $2 }
 920         | srcloc 'do' stmtlist                  {% checkDo $3  >>= \ stmts ->
 921                                                    return (mkHsDo DoExpr stmts $1) }
 922         | srcloc 'mdo' stmtlist                 {% checkMDo $3  >>= \ stmts ->
 923                                                    return (mkHsDo MDoExpr stmts $1) }
 924
 925         | scc_annot exp                         { if opt_SccProfilingOn
 926                                                         then HsSCC $1 $2
 927                                                         else HsPar $2 }
 928
 929         | 'proc' srcloc aexp '->' srcloc exp
 930                         {% checkPattern $2 $3 >>= \ p ->
 931                            return (HsProc p (HsCmdTop $6 [] placeHolderType undefined) $5) }
 932
 933         | '{-# CORE' STRING '#-}' exp           { HsCoreAnn $2 $4 }    -- hdaume: core annotation
 934
 935         | fexp                                  { $1 }
 936
 937 scc_annot :: { FastString }
 938         : '_scc_' STRING                        { $2 }
 939         | '{-# SCC' STRING '#-}'                { $2 }
 940
 941 fexp    :: { RdrNameHsExpr }
 942         : fexp aexp                             { HsApp $1 $2 }
 943         | aexp                                  { $1 }
 944
 945 aexps   :: { [RdrNameHsExpr] }
 946         : aexps aexp                            { $2 : $1 }
 947         | {- empty -}                           { [] }
 948
 949 aexp    :: { RdrNameHsExpr }
 950         : qvar '@' aexp                 { EAsPat $1 $3 }
 951         | '~' aexp                      { ELazyPat $2 }
 952         | aexp1                         { $1 }
 953
 954 aexp1   :: { RdrNameHsExpr }
 955         : aexp1 '{' fbinds '}'          {% (mkRecConstrOrUpdate $1 (reverse $3)) }
 956         | aexp2                         { $1 }
 957
 958 -- Here was the syntax for type applications that I was planning
 959 -- but there are difficulties (e.g. what order for type args)
 960 -- so it's not enabled yet.
 961 -- But this case *is* used for the left hand side of a generic definition,
 962 -- which is parsed as an expression before being munged into a pattern
 963         | qcname '{|' gentype '|}'      { (HsApp (HsVar $1) (HsType $3)) }
 964
 965 aexp2   :: { RdrNameHsExpr }
 966         : ipvar                         { HsIPVar $1 }
 967         | qcname                        { HsVar $1 }
 968         | literal                       { HsLit $1 }
 969         | INTEGER                       { HsOverLit $! mkHsIntegral $1 }
 970         | RATIONAL                      { HsOverLit $! mkHsFractional $1 }
 971         | '(' exp ')'                   { HsPar $2 }
 972         | '(' exp ',' texps ')'         { ExplicitTuple ($2 : reverse $4) Boxed}
 973         | '(#' texps '#)'               { ExplicitTuple (reverse $2)      Unboxed }
 974         | '[' list ']'                  { $2 }
 975         | '[:' parr ':]'                { $2 }
 976         | '(' infixexp qop ')'          { (SectionL $2 (HsVar $3))  }
 977         | '(' qopm infixexp ')'         { (SectionR $2 $3) }
 978         | '_'                           { EWildPat }
 979
 980         -- MetaHaskell Extension
 981         | srcloc TH_ID_SPLICE           { mkHsSplice (HsVar (mkUnqual varName $2)) $1 }  -- $x
 982         | srcloc '$(' exp ')'           { mkHsSplice $3 $1 }                             -- $( exp )
 983         | srcloc TH_VAR_QUOTE qvar      { HsBracket (VarBr $3) $1 }
 984         | srcloc TH_VAR_QUOTE qcon      { HsBracket (VarBr $3) $1 }
 985         | srcloc TH_TY_QUOTE tyvar      { HsBracket (VarBr $3) $1 }
 986         | srcloc TH_TY_QUOTE gtycon     { HsBracket (VarBr $3) $1 }
 987         | srcloc '[|' exp '|]'          { HsBracket (ExpBr $3) $1 }
 988         | srcloc '[t|' ctype '|]'       { HsBracket (TypBr $3) $1 }
 989         | srcloc '[p|' infixexp '|]'    {% checkPattern $1 $3 >>= \p ->
 990                                            return (HsBracket (PatBr p) $1) }
 991         | srcloc '[d|' cvtopbody '|]'   { HsBracket (DecBr (mkGroup $3)) $1 }
 992
 993         -- arrow notation extension
 994         | srcloc '(|' aexp2 cmdargs '|)'
 995                                         { HsArrForm $3 Nothing (reverse $4) $1 }
 996
 997 cmdargs :: { [RdrNameHsCmdTop] }
 998         : cmdargs acmd                  { $2 : $1 }
 999         | {- empty -}                   { [] }
1000
1001 acmd    :: { RdrNameHsCmdTop }
1002         : aexp2                         { HsCmdTop $1 [] placeHolderType undefined }
1003
1004 cvtopbody :: { [RdrNameHsDecl] }
1005         :  '{'            cvtopdecls '}'                { $2 }
1006         |      vocurly    cvtopdecls close              { $2 }
1007
1008 texps :: { [RdrNameHsExpr] }
1009         : texps ',' exp                 { $3 : $1 }
1010         | exp                           { [$1] }
1011
1012
1013 -----------------------------------------------------------------------------
1014 -- List expressions
1015
1016 -- The rules below are little bit contorted to keep lexps left-recursive while
1017 -- avoiding another shift/reduce-conflict.
1018
1019 list :: { RdrNameHsExpr }
1020         : exp                           { ExplicitList placeHolderType [$1] }
1021         | lexps                         { ExplicitList placeHolderType (reverse $1) }
1022         | exp '..'                      { ArithSeqIn (From $1) }
1023         | exp ',' exp '..'              { ArithSeqIn (FromThen $1 $3) }
1024         | exp '..' exp                  { ArithSeqIn (FromTo $1 $3) }
1025         | exp ',' exp '..' exp          { ArithSeqIn (FromThenTo $1 $3 $5) }
1026         | exp srcloc pquals             { mkHsDo ListComp
1027                                                  (reverse (ResultStmt $1 $2 : $3))
1028                                                  $2
1029                                         }
1030
1031 lexps :: { [RdrNameHsExpr] }
1032         : lexps ',' exp                 { $3 : $1 }
1033         | exp ',' exp                   { [$3,$1] }
1034
1035 -----------------------------------------------------------------------------
1036 -- List Comprehensions
1037
1038 pquals :: { [RdrNameStmt] }     -- Either a singleton ParStmt, or a reversed list of Stmts
1039         : pquals1                       { case $1 of
1040                                             [qs] -> qs
1041                                             qss  -> [ParStmt stmtss]
1042                                                  where
1043                                                     stmtss = [ (reverse qs, undefined)
1044                                                              | qs <- qss ]
1045                                         }
1046
1047 pquals1 :: { [[RdrNameStmt]] }
1048         : pquals1 '|' quals             { $3 : $1 }
1049         | '|' quals                     { [$2] }
1050
1051 quals :: { [RdrNameStmt] }
1052         : quals ',' qual                { $3 : $1 }
1053         | qual                          { [$1] }
1054
1055 -----------------------------------------------------------------------------
1056 -- Parallel array expressions
1057
1058 -- The rules below are little bit contorted; see the list case for details.
1059 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1060 -- Moreover, we allow explicit arrays with no element (represented by the nil
1061 -- constructor in the list case).
1062
1063 parr :: { RdrNameHsExpr }
1064         :                               { ExplicitPArr placeHolderType [] }
1065         | exp                           { ExplicitPArr placeHolderType [$1] }
1066         | lexps                         { ExplicitPArr placeHolderType
1067                                                        (reverse $1) }
1068         | exp '..' exp                  { PArrSeqIn (FromTo $1 $3) }
1069         | exp ',' exp '..' exp          { PArrSeqIn (FromThenTo $1 $3 $5) }
1070         | exp srcloc pquals             {  mkHsDo PArrComp
1071                                                   (reverse (ResultStmt $1 $2 : $3))
1072                                                   $2
1073                                         }
1074
1075 -- We are reusing `lexps' and `pquals' from the list case.
1076
1077 -----------------------------------------------------------------------------
1078 -- Case alternatives
1079
1080 altslist :: { [RdrNameMatch] }
1081         : '{'            alts '}'       { reverse $2 }
1082         |     vocurly    alts  close    { reverse $2 }
1083
1084 alts    :: { [RdrNameMatch] }
1085         : alts1                         { $1 }
1086         | ';' alts                      { $2 }
1087
1088 alts1   :: { [RdrNameMatch] }
1089         : alts1 ';' alt                 { $3 : $1 }
1090         | alts1 ';'                     { $1 }
1091         | alt                           { [$1] }
1092
1093 alt     :: { RdrNameMatch }
1094         : srcloc infixexp opt_sig ralt wherebinds
1095                                         {% (checkPattern $1 $2 >>= \p ->
1096                                            return (Match [p] $3
1097                                                      (GRHSs $4 $5 placeHolderType))  )}
1098
1099 ralt :: { [RdrNameGRHS] }
1100         : '->' srcloc exp               { [GRHS [ResultStmt $3 $2] $2] }
1101         | gdpats                        { reverse $1 }
1102
1103 gdpats :: { [RdrNameGRHS] }
1104         : gdpats gdpat                  { $2 : $1 }
1105         | gdpat                         { [$1] }
1106
1107 gdpat   :: { RdrNameGRHS }
1108         : srcloc '|' quals '->' exp     { GRHS (reverse (ResultStmt $5 $1:$3)) $1}
1109
1110 -----------------------------------------------------------------------------
1111 -- Statement sequences
1112
1113 stmtlist :: { [RdrNameStmt] }
1114         : '{'           stmts '}'       { $2 }
1115         |     vocurly   stmts close     { $2 }
1116
1117 --      do { ;; s ; s ; ; s ;; }
1118 -- The last Stmt should be a ResultStmt, but that's hard to enforce
1119 -- here, because we need too much lookahead if we see do { e ; }
1120 -- So we use ExprStmts throughout, and switch the last one over
1121 -- in ParseUtils.checkDo instead
1122 stmts :: { [RdrNameStmt] }
1123         : stmt stmts_help               { $1 : $2 }
1124         | ';' stmts                     { $2 }
1125         | {- empty -}                   { [] }
1126
1127 stmts_help :: { [RdrNameStmt] }
1128         : ';' stmts                     { $2 }
1129         | {- empty -}                   { [] }
1130
1131 -- For typing stmts at the GHCi prompt, where
1132 -- the input may consist of just comments.
1133 maybe_stmt :: { Maybe RdrNameStmt }
1134         : stmt                          { Just $1 }
1135         | {- nothing -}                 { Nothing }
1136
1137 stmt  :: { RdrNameStmt }
1138         : qual                          { $1 }
1139         | srcloc infixexp '->' exp      {% checkPattern $1 $4 >>= \p ->
1140                                            return (BindStmt p $2 $1) }
1141         | srcloc 'rec' stmtlist         { RecStmt $3 undefined undefined undefined }
1142
1143 qual  :: { RdrNameStmt }
1144         : srcloc infixexp '<-' exp      {% checkPattern $1 $2 >>= \p ->
1145                                            return (BindStmt p $4 $1) }
1146         | srcloc exp                    { ExprStmt $2 placeHolderType $1 }
1147         | srcloc 'let' binds            { LetStmt $3 }
1148
1149 -----------------------------------------------------------------------------
1150 -- Record Field Update/Construction
1151
1152 fbinds :: { RdrNameHsRecordBinds }
1153         : fbinds1                       { $1 }
1154         | {- empty -}                   { [] }
1155
1156 fbinds1 :: { RdrNameHsRecordBinds }
1157         : fbinds1 ',' fbind             { $3 : $1 }
1158         | fbind                         { [$1] }
1159
1160 fbind   :: { (RdrName, RdrNameHsExpr) }
1161         : qvar '=' exp                  { ($1,$3) }
1162
1163 -----------------------------------------------------------------------------
1164 -- Implicit Parameter Bindings
1165
1166 dbinds  :: { [(IPName RdrName, RdrNameHsExpr)] }
1167         : dbinds ';' dbind              { $3 : $1 }
1168         | dbinds ';'                    { $1 }
1169         | dbind                         { [$1] }
1170 --      | {- empty -}                   { [] }
1171
1172 dbind   :: { (IPName RdrName, RdrNameHsExpr) }
1173 dbind   : ipvar '=' exp                 { ($1, $3) }
1174
1175 -----------------------------------------------------------------------------
1176 -- Variables, Constructors and Operators.
1177
1178 identifier :: { RdrName }
1179         : qvar                          { $1 }
1180         | gcon                          { $1 }
1181         | qop                           { $1 }
1182
1183 depreclist :: { [RdrName] }
1184 depreclist : deprec_var                 { [$1] }
1185            | deprec_var ',' depreclist  { $1 : $3 }
1186
1187 deprec_var :: { RdrName }
1188 deprec_var : var                        { $1 }
1189            | tycon                      { $1 }
1190
1191 gcon    :: { RdrName }  -- Data constructor namespace
1192         : sysdcon               { nameRdrName (dataConName $1) }
1193         | qcon                  { $1 }
1194 -- the case of '[:' ':]' is part of the production `parr'
1195
1196 sysdcon :: { DataCon }  -- Wired in data constructors
1197         : '(' ')'               { unitDataCon }
1198         | '(' commas ')'        { tupleCon Boxed $2 }
1199         | '[' ']'               { nilDataCon }
1200
1201 var     :: { RdrName }
1202         : varid                 { $1 }
1203         | '(' varsym ')'        { $2 }
1204
1205 qvar    :: { RdrName }
1206         : qvarid                { $1 }
1207         | '(' varsym ')'        { $2 }
1208         | '(' qvarsym1 ')'      { $2 }
1209 -- We've inlined qvarsym here so that the decision about
1210 -- whether it's a qvar or a var can be postponed until
1211 -- *after* we see the close paren.
1212
1213 ipvar   :: { IPName RdrName }
1214         : IPDUPVARID            { Dupable (mkUnqual varName $1) }
1215         | IPSPLITVARID          { Linear  (mkUnqual varName $1) }
1216
1217 qcon    :: { RdrName }
1218         : qconid                { $1 }
1219         | '(' qconsym ')'       { $2 }
1220
1221 varop   :: { RdrName }
1222         : varsym                { $1 }
1223         | '`' varid '`'         { $2 }
1224
1225 qvarop :: { RdrName }
1226         : qvarsym               { $1 }
1227         | '`' qvarid '`'        { $2 }
1228
1229 qvaropm :: { RdrName }
1230         : qvarsym_no_minus      { $1 }
1231         | '`' qvarid '`'        { $2 }
1232
1233 conop :: { RdrName }
1234         : consym                { $1 }
1235         | '`' conid '`'         { $2 }
1236
1237 qconop :: { RdrName }
1238         : qconsym               { $1 }
1239         | '`' qconid '`'        { $2 }
1240
1241 -----------------------------------------------------------------------------
1242 -- Type constructors
1243
1244 gtycon  :: { RdrName }  -- A "general" qualified tycon
1245         : oqtycon                       { $1 }
1246         | '(' ')'                       { getRdrName unitTyCon }
1247         | '(' commas ')'                { getRdrName (tupleTyCon Boxed $2) }
1248         | '(' '->' ')'                  { getRdrName funTyCon }
1249         | '[' ']'                       { listTyCon_RDR }
1250         | '[:' ':]'                     { parrTyCon_RDR }
1251
1252 oqtycon :: { RdrName }  -- An "ordinary" qualified tycon
1253         : qtycon                        { $1 }
1254         | '(' qtyconsym ')'             { $2 }
1255
1256 qtyconop :: { RdrName } -- Qualified or unqualified
1257         : qtyconsym                     { $1 }
1258         | '`' qtycon '`'                { $2 }
1259
1260 tyconop :: { RdrName }  -- Unqualified
1261         : tyconsym                      { $1 }
1262         | '`' tycon '`'                 { $2 }
1263
1264 qtycon :: { RdrName }   -- Qualified or unqualified
1265         : QCONID                        { mkQual tcClsName $1 }
1266         | tycon                         { $1 }
1267
1268 tycon   :: { RdrName }  -- Unqualified
1269         : CONID                         { mkUnqual tcClsName $1 }
1270
1271 qtyconsym :: { RdrName }
1272         : QCONSYM                       { mkQual tcClsName $1 }
1273         | tyconsym                      { $1 }
1274
1275 tyconsym :: { RdrName }
1276         : CONSYM                        { mkUnqual tcClsName $1 }
1277
1278 -----------------------------------------------------------------------------
1279 -- Any operator
1280
1281 op      :: { RdrName }   -- used in infix decls
1282         : varop                 { $1 }
1283         | conop                 { $1 }
1284
1285 qop     :: { RdrName {-HsExpr-} }   -- used in sections
1286         : qvarop                { $1 }
1287         | qconop                { $1 }
1288
1289 qopm    :: { RdrNameHsExpr }   -- used in sections
1290         : qvaropm               { HsVar $1 }
1291         | qconop                { HsVar $1 }
1292
1293 -----------------------------------------------------------------------------
1294 -- VarIds
1295
1296 qvarid :: { RdrName }
1297         : varid                 { $1 }
1298         | QVARID                { mkQual varName $1 }
1299
1300 varid :: { RdrName }
1301         : varid_no_unsafe       { $1 }
1302         | 'unsafe'              { mkUnqual varName FSLIT("unsafe") }
1303         | 'safe'                { mkUnqual varName FSLIT("safe") }
1304         | 'threadsafe'          { mkUnqual varName FSLIT("threadsafe") }
1305
1306 varid_no_unsafe :: { RdrName }
1307         : VARID                 { mkUnqual varName $1 }
1308         | special_id            { mkUnqual varName $1 }
1309         | 'forall'              { mkUnqual varName FSLIT("forall") }
1310
1311 tyvar   :: { RdrName }
1312         : VARID                 { mkUnqual tvName $1 }
1313         | special_id            { mkUnqual tvName $1 }
1314         | 'unsafe'              { mkUnqual tvName FSLIT("unsafe") }
1315         | 'safe'                { mkUnqual tvName FSLIT("safe") }
1316         | 'threadsafe'          { mkUnqual tvName FSLIT("threadsafe") }
1317
1318 -- These special_ids are treated as keywords in various places,
1319 -- but as ordinary ids elsewhere.   'special_id' collects all these
1320 -- except 'unsafe' and 'forall' whose treatment differs depending on context
1321 special_id :: { UserFS }
1322 special_id
1323         : 'as'                  { FSLIT("as") }
1324         | 'qualified'           { FSLIT("qualified") }
1325         | 'hiding'              { FSLIT("hiding") }
1326         | 'export'              { FSLIT("export") }
1327         | 'label'               { FSLIT("label")  }
1328         | 'dynamic'             { FSLIT("dynamic") }
1329         | 'stdcall'             { FSLIT("stdcall") }
1330         | 'ccall'               { FSLIT("ccall") }
1331
1332 -----------------------------------------------------------------------------
1333 -- Variables
1334
1335 qvarsym :: { RdrName }
1336         : varsym                { $1 }
1337         | qvarsym1              { $1 }
1338
1339 qvarsym_no_minus :: { RdrName }
1340         : varsym_no_minus       { $1 }
1341         | qvarsym1              { $1 }
1342
1343 qvarsym1 :: { RdrName }
1344 qvarsym1 : QVARSYM              { mkQual varName $1 }
1345
1346 varsym :: { RdrName }
1347         : varsym_no_minus       { $1 }
1348         | '-'                   { mkUnqual varName FSLIT("-") }
1349
1350 varsym_no_minus :: { RdrName } -- varsym not including '-'
1351         : VARSYM                { mkUnqual varName $1 }
1352         | special_sym           { mkUnqual varName $1 }
1353
1354
1355 -- See comments with special_id
1356 special_sym :: { UserFS }
1357 special_sym : '!'       { FSLIT("!") }
1358             | '.'       { FSLIT(".") }
1359             | '*'       { FSLIT("*") }
1360
1361 -----------------------------------------------------------------------------
1362 -- Data constructors
1363
1364 qconid :: { RdrName }   -- Qualified or unqualifiedb
1365         : conid                 { $1 }
1366         | QCONID                { mkQual dataName $1 }
1367
1368 conid   :: { RdrName }
1369         : CONID                 { mkUnqual dataName $1 }
1370
1371 qconsym :: { RdrName }  -- Qualified or unqualified
1372         : consym                { $1 }
1373         | QCONSYM               { mkQual dataName $1 }
1374
1375 consym :: { RdrName }
1376         : CONSYM                { mkUnqual dataName $1 }
1377
1378         -- ':' means only list cons
1379         | ':'                   { consDataCon_RDR }
1380
1381
1382 -----------------------------------------------------------------------------
1383 -- Literals
1384
1385 literal :: { HsLit }
1386         : CHAR                  { HsChar       (ord $1) } --TODO remove ord
1387         | STRING                { HsString     $1 }
1388         | PRIMINTEGER           { HsIntPrim    $1 }
1389         | PRIMCHAR              { HsCharPrim   (ord $1) } --TODO remove ord
1390         | PRIMSTRING            { HsStringPrim $1 }
1391         | PRIMFLOAT             { HsFloatPrim  $1 }
1392         | PRIMDOUBLE            { HsDoublePrim $1 }
1393
1394 srcloc :: { SrcLoc }    :       {% getSrcLoc }
1395
1396 -----------------------------------------------------------------------------
1397 -- Layout
1398
1399 close :: { () }
1400         : vccurly               { () } -- context popped in lexer.
1401         | error                 {% popContext }
1402
1403 -----------------------------------------------------------------------------
1404 -- Miscellaneous (mostly renamings)
1405
1406 modid   :: { ModuleName }
1407         : CONID                 { mkModuleNameFS $1 }
1408         | QCONID                { mkModuleNameFS
1409                                    (mkFastString
1410                                      (unpackFS (fst $1) ++
1411                                         '.':unpackFS (snd $1)))
1412                                 }
1413
1414 commas :: { Int }
1415         : commas ','                    { $1 + 1 }
1416         | ','                           { 2 }
1417
1418 -----------------------------------------------------------------------------
1419
1420 {
1421 happyError :: P a
1422 happyError = srcParseFail
1423 }