ghc/compiler/parser/Parser.y

   1 {-
   2 -----------------------------------------------------------------------------
   3 $Id: Parser.y,v 1.37 2000/10/03 08:43:02 simonpj Exp $
   4
   5 Haskell grammar.
   6
   7 Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -----------------------------------------------------------------------------
   9 -}
  10
  11 {
  12 module Parser ( parse ) where
  13
  14 import HsSyn
  15 import HsPragmas
  16 import HsTypes          ( mkHsTupCon )
  17 import HsPat            ( InPat(..) )
  18
  19 import RdrHsSyn
  20 import Lex
  21 import ParseUtil
  22 import RdrName
  23 import PrelInfo         ( mAIN_Name )
  24 import OccName          ( UserFS, varName, ipName, tcName, dataName, tcClsName, tvName )
  25 import SrcLoc           ( SrcLoc )
  26 import Module
  27 import CallConv
  28 import CmdLineOpts      ( opt_SccProfilingOn )
  29 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), NewOrData(..) )
  30 import Panic
  31
  32 import GlaExts
  33 import FastString       ( tailFS )
  34 import Outputable
  35
  36 #include "HsVersions.h"
  37 }
  38
  39 {-
  40 -----------------------------------------------------------------------------
  41 Conflicts: 14 shift/reduce
  42         (note: it's currently 21 -- JRL, 31/1/2000)
  43
  44 8 for abiguity in 'if x then y else z + 1'
  45         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  46 1 for ambiguity in 'if x then y else z :: T'
  47         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  48 3 for ambiguity in 'case x of y :: a -> b'
  49         (don't know whether to reduce 'a' as a btype or shift the '->'.
  50          conclusion:  bogus expression anyway, doesn't matter)
  51
  52 1 for ambiguity in '{-# RULES "name" forall = ... #-}'
  53         since 'forall' is a valid variable name, we don't know whether
  54         to treat a forall on the input as the beginning of a quantifier
  55         or the beginning of the rule itself.  Resolving to shift means
  56         it's always treated as a quantifier, hence the above is disallowed.
  57         This saves explicitly defining a grammar for the rule lhs that
  58         doesn't include 'forall'.
  59
  60 1 for ambiguity in 'x @ Rec{..}'.
  61         Only sensible parse is 'x @ (Rec{..})', which is what resolving
  62         to shift gives us.
  63
  64 -----------------------------------------------------------------------------
  65 -}
  66
  67 %token
  68  '_'            { ITunderscore }                -- Haskell keywords
  69  'as'           { ITas }
  70  'case'         { ITcase }
  71  'class'        { ITclass }
  72  'data'         { ITdata }
  73  'default'      { ITdefault }
  74  'deriving'     { ITderiving }
  75  'do'           { ITdo }
  76  'else'         { ITelse }
  77  'hiding'       { IThiding }
  78  'if'           { ITif }
  79  'import'       { ITimport }
  80  'in'           { ITin }
  81  'infix'        { ITinfix }
  82  'infixl'       { ITinfixl }
  83  'infixr'       { ITinfixr }
  84  'instance'     { ITinstance }
  85  'let'          { ITlet }
  86  'module'       { ITmodule }
  87  'newtype'      { ITnewtype }
  88  'of'           { ITof }
  89  'qualified'    { ITqualified }
  90  'then'         { ITthen }
  91  'type'         { ITtype }
  92  'where'        { ITwhere }
  93  '_scc_'        { ITscc }
  94
  95  'forall'       { ITforall }                    -- GHC extension keywords
  96  'foreign'      { ITforeign }
  97  'export'       { ITexport }
  98  'label'        { ITlabel }
  99  'dynamic'      { ITdynamic }
 100  'unsafe'       { ITunsafe }
 101  'with'         { ITwith }
 102  'stdcall'      { ITstdcallconv }
 103  'ccall'        { ITccallconv }
 104  '_ccall_'      { ITccall (False, False, False) }
 105  '_ccall_GC_'   { ITccall (False, False, True)  }
 106  '_casm_'       { ITccall (False, True,  False) }
 107  '_casm_GC_'    { ITccall (False, True,  True)  }
 108
 109  '{-# SPECIALISE'  { ITspecialise_prag }
 110  '{-# SOURCE'      { ITsource_prag }
 111  '{-# INLINE'      { ITinline_prag }
 112  '{-# NOINLINE'    { ITnoinline_prag }
 113  '{-# RULES'       { ITrules_prag }
 114  '{-# DEPRECATED'  { ITdeprecated_prag }
 115  '#-}'             { ITclose_prag }
 116
 117 {-
 118  '__interface'  { ITinterface }                 -- interface keywords
 119  '__export'     { IT__export }
 120  '__instimport' { ITinstimport }
 121  '__forall'     { IT__forall }
 122  '__letrec'     { ITletrec }
 123  '__coerce'     { ITcoerce }
 124  '__depends'    { ITdepends }
 125  '__inline'     { ITinline }
 126  '__DEFAULT'    { ITdefaultbranch }
 127  '__bot'        { ITbottom }
 128  '__integer'    { ITinteger_lit }
 129  '__float'      { ITfloat_lit }
 130  '__rational'   { ITrational_lit }
 131  '__addr'       { ITaddr_lit }
 132  '__label'      { ITlabel_lit }
 133  '__litlit'     { ITlit_lit }
 134  '__string'     { ITstring_lit }
 135  '__ccall'      { ITccall $$ }
 136  '__scc'        { IT__scc }
 137  '__sccC'       { ITsccAllCafs }
 138
 139  '__A'          { ITarity }
 140  '__P'          { ITspecialise }
 141  '__C'          { ITnocaf }
 142  '__U'          { ITunfold $$ }
 143  '__S'          { ITstrict $$ }
 144  '__M'          { ITcprinfo $$ }
 145 -}
 146
 147  '..'           { ITdotdot }                    -- reserved symbols
 148  '::'           { ITdcolon }
 149  '='            { ITequal }
 150  '\\'           { ITlam }
 151  '|'            { ITvbar }
 152  '<-'           { ITlarrow }
 153  '->'           { ITrarrow }
 154  '@'            { ITat }
 155  '~'            { ITtilde }
 156  '=>'           { ITdarrow }
 157  '-'            { ITminus }
 158  '!'            { ITbang }
 159  '.'            { ITdot }
 160
 161  '{'            { ITocurly }                    -- special symbols
 162  '}'            { ITccurly }
 163  '{|'           { ITocurlybar }
 164  '|}'           { ITccurlybar }
 165  vccurly        { ITvccurly } -- virtual close curly (from layout)
 166  '['            { ITobrack }
 167  ']'            { ITcbrack }
 168  '('            { IToparen }
 169  ')'            { ITcparen }
 170  '(#'           { IToubxparen }
 171  '#)'           { ITcubxparen }
 172  ';'            { ITsemi }
 173  ','            { ITcomma }
 174  '`'            { ITbackquote }
 175
 176  VARID          { ITvarid    $$ }               -- identifiers
 177  CONID          { ITconid    $$ }
 178  VARSYM         { ITvarsym   $$ }
 179  CONSYM         { ITconsym   $$ }
 180  QVARID         { ITqvarid   $$ }
 181  QCONID         { ITqconid   $$ }
 182  QVARSYM        { ITqvarsym  $$ }
 183  QCONSYM        { ITqconsym  $$ }
 184
 185  IPVARID        { ITipvarid  $$ }               -- GHC extension
 186
 187  CHAR           { ITchar     $$ }
 188  STRING         { ITstring   $$ }
 189  INTEGER        { ITinteger  $$ }
 190  RATIONAL       { ITrational $$ }
 191
 192  PRIMCHAR       { ITprimchar   $$ }
 193  PRIMSTRING     { ITprimstring $$ }
 194  PRIMINTEGER    { ITprimint    $$ }
 195  PRIMFLOAT      { ITprimfloat  $$ }
 196  PRIMDOUBLE     { ITprimdouble $$ }
 197  CLITLIT        { ITlitlit     $$ }
 198
 199 %monad { P } { thenP } { returnP }
 200 %lexer { lexer } { ITeof }
 201 %name parse
 202 %tokentype { Token }
 203 %%
 204
 205 -----------------------------------------------------------------------------
 206 -- Module Header
 207
 208 -- The place for module deprecation is really too restrictive, but if it
 209 -- was allowed at its natural place just before 'module', we get an ugly
 210 -- s/r conflict with the second alternative. Another solution would be the
 211 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 212 -- either, and DEPRECATED is only expected to be used by people who really
 213 -- know what they are doing. :-)
 214
 215 module  :: { RdrNameHsModule }
 216         : srcloc 'module' modid maybemoddeprec maybeexports 'where' body
 217                 { HsModule $3 Nothing $5 (fst $7) (snd $7) $4 $1 }
 218         | srcloc body
 219                 { HsModule mAIN_Name Nothing Nothing (fst $2) (snd $2) Nothing $1 }
 220
 221 maybemoddeprec :: { Maybe DeprecTxt }
 222         : '{-# DEPRECATED' STRING '#-}'         { Just $2 }
 223         |  {- empty -}                          { Nothing }
 224
 225 body    :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 226         :  '{'            top '}'               { $2 }
 227         |      layout_on  top close             { $2 }
 228
 229 top     :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 230         : importdecls                           { (reverse $1,[]) }
 231         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 232         | cvtopdecls                            { ([],$1) }
 233
 234 cvtopdecls :: { [RdrNameHsDecl] }
 235         : topdecls                              { cvTopDecls (groupBindings $1)}
 236
 237 -----------------------------------------------------------------------------
 238 -- The Export List
 239
 240 maybeexports :: { Maybe [RdrNameIE] }
 241         :  '(' exportlist ')'                   { Just $2 }
 242         |  {- empty -}                          { Nothing }
 243
 244 exportlist :: { [RdrNameIE] }
 245         :  exportlist ',' export                { $3 : $1 }
 246         |  exportlist ','                       { $1 }
 247         |  export                               { [$1]  }
 248         |  {- empty -}                          { [] }
 249
 250    -- GHC extension: we allow things like [] and (,,,) to be exported
 251 export  :: { RdrNameIE }
 252         :  qvar                                 { IEVar $1 }
 253         |  gtycon                               { IEThingAbs $1 }
 254         |  gtycon '(' '..' ')'                  { IEThingAll $1 }
 255         |  gtycon '(' ')'                       { IEThingWith $1 [] }
 256         |  gtycon '(' qcnames ')'               { IEThingWith $1 (reverse $3) }
 257         |  'module' modid                       { IEModuleContents $2 }
 258
 259 qcnames :: { [RdrName] }
 260         :  qcnames ',' qcname                   { $3 : $1 }
 261         |  qcname                               { [$1]  }
 262
 263 qcname  :: { RdrName }
 264         :  qvar                                 { $1 }
 265         |  gcon                                 { $1 }
 266
 267 -----------------------------------------------------------------------------
 268 -- Import Declarations
 269
 270 -- import decls can be *empty*, or even just a string of semicolons
 271 -- whereas topdecls must contain at least one topdecl.
 272
 273 importdecls :: { [RdrNameImportDecl] }
 274         : importdecls ';' importdecl            { $3 : $1 }
 275         | importdecls ';'                       { $1 }
 276         | importdecl                            { [ $1 ] }
 277         | {- empty -}                           { [] }
 278
 279 importdecl :: { RdrNameImportDecl }
 280         : 'import' srcloc maybe_src optqualified CONID maybeas maybeimpspec
 281                 { ImportDecl (mkSrcModuleFS $5) $3 $4 $6 $7 $2 }
 282
 283 maybe_src :: { WhereFrom }
 284         : '{-# SOURCE' '#-}'                    { ImportByUserSource }
 285         | {- empty -}                           { ImportByUser }
 286
 287 optqualified :: { Bool }
 288         : 'qualified'                           { True  }
 289         | {- empty -}                           { False }
 290
 291 maybeas :: { Maybe ModuleName }
 292         : 'as' modid                            { Just $2 }
 293         | {- empty -}                           { Nothing }
 294
 295 maybeimpspec :: { Maybe (Bool, [RdrNameIE]) }
 296         : impspec                               { Just $1 }
 297         | {- empty -}                           { Nothing }
 298
 299 impspec :: { (Bool, [RdrNameIE]) }
 300         :  '(' exportlist ')'                   { (False, reverse $2) }
 301         |  'hiding' '(' exportlist ')'          { (True,  reverse $3) }
 302
 303 -----------------------------------------------------------------------------
 304 -- Fixity Declarations
 305
 306 prec    :: { Int }
 307         : {- empty -}                           { 9 }
 308         | INTEGER                               {%  checkPrec $1 `thenP_`
 309                                                     returnP (fromInteger $1) }
 310
 311 infix   :: { FixityDirection }
 312         : 'infix'                               { InfixN  }
 313         | 'infixl'                              { InfixL  }
 314         | 'infixr'                              { InfixR }
 315
 316 ops     :: { [RdrName] }
 317         : ops ',' op                            { $3 : $1 }
 318         | op                                    { [$1] }
 319
 320 -----------------------------------------------------------------------------
 321 -- Top-Level Declarations
 322
 323 topdecls :: { [RdrBinding] }
 324         : topdecls ';' topdecl          { ($3 : $1) }
 325         | topdecls ';'                  { $1 }
 326         | topdecl                       { [$1] }
 327
 328 topdecl :: { RdrBinding }
 329         : srcloc 'type' simpletype '=' sigtype
 330                 { RdrHsDecl (TyClD (TySynonym (fst $3) (snd $3) $5 $1)) }
 331
 332         | srcloc 'data' ctype '=' constrs deriving
 333                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 334                    returnP (RdrHsDecl (TyClD
 335                       (mkTyData DataType cs c ts (reverse $5) (length $5) $6
 336                         NoDataPragmas $1))) }
 337
 338         | srcloc 'newtype' ctype '=' newconstr deriving
 339                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 340                    returnP (RdrHsDecl (TyClD
 341                       (mkTyData NewType cs c ts [$5] 1 $6
 342                         NoDataPragmas $1))) }
 343
 344         | srcloc 'class' ctype fds where
 345                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 346                    let
 347                         (binds,sigs) = cvMonoBindsAndSigs cvClassOpSig (groupBindings $5)
 348                    in
 349                    returnP (RdrHsDecl (TyClD
 350                       (mkClassDecl cs c ts $4 sigs binds
 351                         NoClassPragmas $1))) }
 352
 353         | srcloc 'instance' inst_type where
 354                 { let (binds,sigs)
 355                         = cvMonoBindsAndSigs cvInstDeclSig
 356                                 (groupBindings $4)
 357                   in RdrHsDecl (InstD (InstDecl $3 binds sigs Nothing $1)) }
 358
 359         | srcloc 'default' '(' types0 ')'
 360                 { RdrHsDecl (DefD (DefaultDecl $4 $1)) }
 361
 362         | srcloc 'foreign' 'import' callconv ext_name
 363           unsafe_flag varid_no_unsafe '::' sigtype
 364                 { RdrHsDecl (ForD (ForeignDecl $7 (FoImport $6) $9 (mkExtName $5 $7) $4 $1)) }
 365
 366         | srcloc 'foreign' 'export' callconv ext_name varid '::' sigtype
 367                 { RdrHsDecl (ForD (ForeignDecl $6 FoExport $8 (mkExtName $5 $6) $4 $1)) }
 368
 369         | srcloc 'foreign' 'label' ext_name varid '::' sigtype
 370                 { RdrHsDecl (ForD (ForeignDecl $5 FoLabel $7 (mkExtName $4 $5)
 371                                         defaultCallConv $1)) }
 372
 373         | '{-# DEPRECATED' deprecations '#-}'           { $2 }
 374         | '{-# RULES' rules '#-}'                       { $2 }
 375         | decl                                          { $1 }
 376
 377 decls   :: { [RdrBinding] }
 378         : decls ';' decl                { $3 : $1 }
 379         | decls ';'                     { $1 }
 380         | decl                          { [$1] }
 381         | {- empty -}                   { [] }
 382
 383 decl    :: { RdrBinding }
 384         : fixdecl                       { $1 }
 385         | valdef                        { $1 }
 386         | '{-# INLINE'   srcloc opt_phase qvar '#-}'    { RdrSig (InlineSig $4 $3 $2) }
 387         | '{-# NOINLINE' srcloc opt_phase qvar '#-}'    { RdrSig (NoInlineSig $4 $3 $2) }
 388         | '{-# SPECIALISE' srcloc qvar '::' sigtypes '#-}'
 389                 { foldr1 RdrAndBindings
 390                     (map (\t -> RdrSig (SpecSig $3 t $2)) $5) }
 391         | '{-# SPECIALISE' srcloc 'instance' inst_type '#-}'
 392                 { RdrSig (SpecInstSig $4 $2) }
 393
 394 opt_phase :: { Maybe Int }
 395           : INTEGER                     { Just (fromInteger $1) }
 396           | {- empty -}                 { Nothing }
 397
 398 wherebinds :: { RdrNameHsBinds }
 399         : where                 { cvBinds cvValSig (groupBindings $1) }
 400
 401 where   :: { [RdrBinding] }
 402         : 'where' decllist              { $2 }
 403         | {- empty -}                   { [] }
 404
 405 declbinds :: { RdrNameHsBinds }
 406         : decllist                      { cvBinds cvValSig (groupBindings $1) }
 407
 408 decllist :: { [RdrBinding] }
 409         : '{'            decls '}'      { $2 }
 410         |     layout_on  decls close    { $2 }
 411
 412 fixdecl :: { RdrBinding }
 413         : srcloc infix prec ops         { foldr1 RdrAndBindings
 414                                             [ RdrSig (FixSig (FixitySig n
 415                                                             (Fixity $3 $2) $1))
 416                                             | n <- $4 ] }
 417
 418 -----------------------------------------------------------------------------
 419 -- Transformation Rules
 420
 421 rules   :: { RdrBinding }
 422         :  rules ';' rule                       { $1 `RdrAndBindings` $3 }
 423         |  rules ';'                            { $1 }
 424         |  rule                                 { $1 }
 425         |  {- empty -}                          { RdrNullBind }
 426
 427 rule    :: { RdrBinding }
 428         : STRING rule_forall fexp '=' srcloc exp
 429              { RdrHsDecl (RuleD (HsRule $1 [] $2 $3 $6 $5)) }
 430
 431 rule_forall :: { [RdrNameRuleBndr] }
 432         : 'forall' rule_var_list '.'            { $2 }
 433         | {- empty -}                           { [] }
 434
 435 rule_var_list :: { [RdrNameRuleBndr] }
 436         : rule_var                              { [$1] }
 437         | rule_var rule_var_list                { $1 : $2 }
 438
 439 rule_var :: { RdrNameRuleBndr }
 440         : varid                                 { RuleBndr $1 }
 441         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 442
 443 -----------------------------------------------------------------------------
 444 -- Deprecations
 445
 446 deprecations :: { RdrBinding }
 447         : deprecations ';' deprecation          { $1 `RdrAndBindings` $3 }
 448         | deprecations ';'                      { $1 }
 449         | deprecation                           { $1 }
 450         | {- empty -}                           { RdrNullBind }
 451
 452 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 453 deprecation :: { RdrBinding }
 454         : srcloc exportlist STRING
 455                 { foldr RdrAndBindings RdrNullBind
 456                         [ RdrHsDecl (DeprecD (Deprecation n $3 $1)) | n <- $2 ] }
 457
 458 -----------------------------------------------------------------------------
 459 -- Foreign import/export
 460
 461 callconv :: { Int }
 462         : 'stdcall'             { stdCallConv }
 463         | 'ccall'               { cCallConv }
 464         | {- empty -}           { defaultCallConv }
 465
 466 unsafe_flag :: { Bool }
 467         : 'unsafe'              { True }
 468         | {- empty -}           { False }
 469
 470 ext_name :: { Maybe ExtName }
 471         : 'dynamic'             { Just Dynamic }
 472         | STRING                { Just (ExtName $1 Nothing)   }
 473         | STRING STRING         { Just (ExtName $2 (Just $1)) }
 474         | {- empty -}           { Nothing }
 475
 476
 477 -----------------------------------------------------------------------------
 478 -- Type signatures
 479
 480 opt_sig :: { Maybe RdrNameHsType }
 481         : {- empty -}                   { Nothing }
 482         | '::' sigtype                  { Just $2 }
 483
 484 opt_asig :: { Maybe RdrNameHsType }
 485         : {- empty -}                   { Nothing }
 486         | '::' atype                    { Just $2 }
 487
 488 sigtypes :: { [RdrNameHsType] }
 489         : sigtype                       { [ $1 ] }
 490         | sigtypes ',' sigtype          { $3 : $1 }
 491
 492 sigtype :: { RdrNameHsType }
 493         : ctype                         { (mkHsForAllTy Nothing [] $1) }
 494
 495 sig_vars :: { [RdrName] }
 496          : sig_vars ',' var             { $3 : $1 }
 497          | var                          { [ $1 ] }
 498
 499 -----------------------------------------------------------------------------
 500 -- Types
 501
 502 -- A ctype is a for-all type
 503 ctype   :: { RdrNameHsType }
 504         : 'forall' tyvars '.' ctype     { mkHsForAllTy (Just $2) [] $4 }
 505         | context type                  { mkHsForAllTy Nothing   $1 $2 }
 506         -- A type of form (context => type) is an *implicit* HsForAllTy
 507         | type                          { $1 }
 508
 509 type :: { RdrNameHsType }
 510         : gentype '->' type             { HsFunTy $1 $3 }
 511         | ipvar '::' type               { mkHsIParamTy $1 $3 }
 512         | gentype                       { $1 }
 513
 514 gentype :: { RdrNameHsType }
 515         : btype                         { $1 }
 516 -- Generics
 517         | atype tyconop atype           { HsOpTy $1 $2 $3 }
 518
 519 btype :: { RdrNameHsType }
 520         : btype atype                   { (HsAppTy $1 $2) }
 521         | atype                         { $1 }
 522
 523 atype :: { RdrNameHsType }
 524         : gtycon                        { HsTyVar $1 }
 525         | tyvar                         { HsTyVar $1 }
 526         | '(' type ',' types ')'        { HsTupleTy (mkHsTupCon tcName Boxed  ($2:$4)) ($2 : reverse $4) }
 527         | '(#' types '#)'               { HsTupleTy (mkHsTupCon tcName Unboxed     $2) (reverse $2)      }
 528         | '[' type ']'                  { HsListTy $2 }
 529         | '(' ctype ')'                 { $2 }
 530 -- Generics
 531         | INTEGER                       { HsNumTy $1 }
 532
 533 -- An inst_type is what occurs in the head of an instance decl
 534 --      e.g.  (Foo a, Gaz b) => Wibble a b
 535 -- It's kept as a single type, with a MonoDictTy at the right
 536 -- hand corner, for convenience.
 537 inst_type :: { RdrNameHsType }
 538         : ctype                         {% checkInstType $1 }
 539
 540 types0  :: { [RdrNameHsType] }
 541         : types                         { $1 }
 542         | {- empty -}                   { [] }
 543
 544 types   :: { [RdrNameHsType] }
 545         : type                          { [$1] }
 546         | types  ',' type               { $3 : $1 }
 547
 548 simpletype :: { (RdrName, [RdrNameHsTyVar]) }
 549         : tycon tyvars                  { ($1, reverse $2) }
 550
 551 tyvars :: { [RdrNameHsTyVar] }
 552         : tyvars tyvar                  { UserTyVar $2 : $1 }
 553         | {- empty -}                   { [] }
 554
 555 fds :: { [([RdrName], [RdrName])] }
 556         : {- empty -}                   { [] }
 557         | '|' fds1                      { reverse $2 }
 558
 559 fds1 :: { [([RdrName], [RdrName])] }
 560         : fds1 ',' fd                   { $3 : $1 }
 561         | fd                            { [$1] }
 562
 563 fd :: { ([RdrName], [RdrName]) }
 564         : varids0 '->' varids0          { (reverse $1, reverse $3) }
 565
 566 varids0 :: { [RdrName] }
 567         : {- empty -}                   { [] }
 568         | varids0 tyvar                 { $2 : $1 }
 569
 570 -----------------------------------------------------------------------------
 571 -- Datatype declarations
 572
 573 constrs :: { [RdrNameConDecl] }
 574         : constrs '|' constr            { $3 : $1 }
 575         | constr                        { [$1] }
 576
 577 constr :: { RdrNameConDecl }
 578         : srcloc forall context constr_stuff
 579                 { mkConDecl (fst $4) $2 $3 (snd $4) $1 }
 580         | srcloc forall constr_stuff
 581                 { mkConDecl (fst $3) $2 [] (snd $3) $1 }
 582
 583 forall :: { [RdrNameHsTyVar] }
 584         : 'forall' tyvars '.'           { $2 }
 585         | {- empty -}                   { [] }
 586
 587 context :: { RdrNameContext }
 588         : btype '=>'                    {% checkContext $1 }
 589
 590 constr_stuff :: { (RdrName, RdrNameConDetails) }
 591         : scontype                      { (fst $1, VanillaCon (snd $1)) }
 592         | sbtype conop sbtype           { ($2, InfixCon $1 $3) }
 593         | con '{' fielddecls '}'        { ($1, RecCon (reverse $3)) }
 594
 595 newconstr :: { RdrNameConDecl }
 596         : srcloc conid atype    { mkConDecl $2 [] [] (VanillaCon [Unbanged $3]) $1 }
 597         | srcloc conid '{' var '::' type '}'
 598                                 { mkConDecl $2 [] [] (RecCon [([$4], Unbanged $6)]) $1 }
 599
 600 scontype :: { (RdrName, [RdrNameBangType]) }
 601         : btype                         {% splitForConApp $1 [] }
 602         | scontype1                     { $1 }
 603
 604 scontype1 :: { (RdrName, [RdrNameBangType]) }
 605         : btype '!' atype               {% splitForConApp $1 [Banged $3] }
 606         | scontype1 satype              { (fst $1, snd $1 ++ [$2] ) }
 607         | '(' consym ')'                { ($2,[]) }
 608
 609 satype :: { RdrNameBangType }
 610         : atype                         { Unbanged $1 }
 611         | '!' atype                     { Banged   $2 }
 612
 613 sbtype :: { RdrNameBangType }
 614         : btype                         { Unbanged $1 }
 615         | '!' atype                     { Banged   $2 }
 616
 617 fielddecls :: { [([RdrName],RdrNameBangType)] }
 618         : fielddecls ',' fielddecl      { $3 : $1 }
 619         | fielddecl                     { [$1] }
 620
 621 fielddecl :: { ([RdrName],RdrNameBangType) }
 622         : sig_vars '::' stype           { (reverse $1, $3) }
 623
 624 stype :: { RdrNameBangType }
 625         : ctype                         { Unbanged $1 }
 626         | '!' atype                     { Banged   $2 }
 627
 628 deriving :: { Maybe [RdrName] }
 629         : {- empty -}                   { Nothing }
 630         | 'deriving' qtycls             { Just [$2] }
 631         | 'deriving' '('          ')'   { Just [] }
 632         | 'deriving' '(' dclasses ')'   { Just (reverse $3) }
 633
 634 dclasses :: { [RdrName] }
 635         : dclasses ',' qtycls           { $3 : $1 }
 636         | qtycls                        { [$1] }
 637
 638 -----------------------------------------------------------------------------
 639 -- Value definitions
 640
 641 {- There's an awkward overlap with a type signature.  Consider
 642         f :: Int -> Int = ...rhs...
 643    Then we can't tell whether it's a type signature or a value
 644    definition with a result signature until we see the '='.
 645    So we have to inline enough to postpone reductions until we know.
 646 -}
 647
 648 {-
 649   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
 650   instead of qvar, we get another shift/reduce-conflict. Consider the
 651   following programs:
 652
 653      { (^^) :: Int->Int ; }          Type signature; only var allowed
 654
 655      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
 656                                      qvar allowed (because of instance decls)
 657
 658   We can't tell whether to reduce var to qvar until after we've read the signatures.
 659 -}
 660
 661 valdef :: { RdrBinding }
 662         : infixexp srcloc opt_sig rhs           {% (checkValDef $1 $3 $4 $2) }
 663         | infixexp srcloc '::' sigtype          {% (checkValSig $1 $4 $2) }
 664         | var ',' sig_vars srcloc '::' sigtype  { foldr1 RdrAndBindings
 665                                                          [ RdrSig (Sig n $6 $4) | n <- $1:$3 ]
 666                                                 }
 667
 668
 669 rhs     :: { RdrNameGRHSs }
 670         : '=' srcloc exp wherebinds     { (GRHSs (unguardedRHS $3 $2)
 671                                                                 $4 Nothing)}
 672         | gdrhs wherebinds              { GRHSs (reverse $1) $2 Nothing }
 673
 674 gdrhs :: { [RdrNameGRHS] }
 675         : gdrhs gdrh                    { $2 : $1 }
 676         | gdrh                          { [$1] }
 677
 678 gdrh :: { RdrNameGRHS }
 679         : '|' srcloc quals '=' exp      { GRHS (reverse (ExprStmt $5 $2 : $3)) $2 }
 680
 681 -----------------------------------------------------------------------------
 682 -- Expressions
 683
 684 exp   :: { RdrNameHsExpr }
 685         : infixexp '::' sigtype         { (ExprWithTySig $1 $3) }
 686         | infixexp 'with' dbinding      { HsWith $1 $3 }
 687         | infixexp                      { $1 }
 688
 689 infixexp :: { RdrNameHsExpr }
 690         : exp10                         { $1 }
 691         | infixexp qop exp10            { (OpApp $1 (HsVar $2)
 692                                                 (panic "fixity") $3 )}
 693
 694 exp10 :: { RdrNameHsExpr }
 695         : '\\' aexp aexps opt_asig '->' srcloc exp
 696                         {% checkPatterns ($2 : reverse $3) `thenP` \ ps ->
 697                            returnP (HsLam (Match [] ps $4
 698                                             (GRHSs (unguardedRHS $7 $6)
 699                                                    EmptyBinds Nothing))) }
 700         | 'let' declbinds 'in' exp              { HsLet $2 $4 }
 701         | 'if' srcloc exp 'then' exp 'else' exp { HsIf $3 $5 $7 $2 }
 702         | 'case' srcloc exp 'of' altslist       { HsCase $3 $5 $2 }
 703         | '-' fexp                              { mkHsNegApp $2 }
 704         | srcloc 'do' stmtlist                  { HsDo DoStmt $3 $1 }
 705
 706         | '_ccall_'    ccallid aexps0           { HsCCall $2 $3 False False cbot }
 707         | '_ccall_GC_' ccallid aexps0           { HsCCall $2 $3 True  False cbot }
 708         | '_casm_'     CLITLIT aexps0           { HsCCall $2 $3 False True  cbot }
 709         | '_casm_GC_'  CLITLIT aexps0           { HsCCall $2 $3 True  True  cbot }
 710
 711         | '_scc_' STRING exp                    { if opt_SccProfilingOn
 712                                                         then HsSCC $2 $3
 713                                                         else HsPar $3 }
 714
 715         | fexp                                  { $1 }
 716
 717 ccallid :: { FAST_STRING }
 718         :  VARID                                { $1 }
 719         |  CONID                                { $1 }
 720
 721 fexp    :: { RdrNameHsExpr }
 722         : fexp aexp                             { (HsApp $1 $2) }
 723         | aexp                                  { $1 }
 724
 725 aexps0  :: { [RdrNameHsExpr] }
 726         : aexps                                 { (reverse $1) }
 727
 728 aexps   :: { [RdrNameHsExpr] }
 729         : aexps aexp                            { $2 : $1 }
 730         | {- empty -}                           { [] }
 731
 732 aexp    :: { RdrNameHsExpr }
 733         : var_or_con '{|' gentype '|}'          { (HsApp $1 (HsType $3)) }
 734         | aexp '{' fbinds '}'                   {% (mkRecConstrOrUpdate $1
 735                                                         (reverse $3)) }
 736         | aexp1                                 { $1 }
 737
 738 var_or_con :: { RdrNameHsExpr }
 739         : qvar                          { HsVar $1 }
 740         | gcon                          { HsVar $1 }
 741
 742 aexp1   :: { RdrNameHsExpr }
 743         : ipvar                         { HsIPVar $1 }
 744         | var_or_con                    { $1 }
 745         | literal                       { HsLit $1 }
 746         | INTEGER                       { HsOverLit (mkHsIntegralLit $1) }
 747         | RATIONAL                      { HsOverLit (mkHsFractionalLit $1) }
 748         | '(' exp ')'                   { HsPar $2 }
 749         | '(' exp ',' texps ')'         { ExplicitTuple ($2 : reverse $4) Boxed}
 750         | '(#' texps '#)'               { ExplicitTuple (reverse $2)      Unboxed }
 751         | '[' list ']'                  { $2 }
 752         | '(' infixexp qop ')'          { (SectionL $2 (HsVar $3))  }
 753         | '(' qopm infixexp ')'         { (SectionR $2 $3) }
 754         | qvar '@' aexp                 { EAsPat $1 $3 }
 755         | '_'                           { EWildPat }
 756         | '~' aexp1                     { ELazyPat $2 }
 757
 758 texps :: { [RdrNameHsExpr] }
 759         : texps ',' exp                 { $3 : $1 }
 760         | exp                           { [$1] }
 761
 762
 763 -----------------------------------------------------------------------------
 764 -- List expressions
 765
 766 -- The rules below are little bit contorted to keep lexps left-recursive while
 767 -- avoiding another shift/reduce-conflict.
 768
 769 list :: { RdrNameHsExpr }
 770         : exp                           { ExplicitList [$1] }
 771         | lexps                         { ExplicitList (reverse $1) }
 772         | exp '..'                      { ArithSeqIn (From $1) }
 773         | exp ',' exp '..'              { ArithSeqIn (FromThen $1 $3) }
 774         | exp '..' exp                  { ArithSeqIn (FromTo $1 $3) }
 775         | exp ',' exp '..' exp          { ArithSeqIn (FromThenTo $1 $3 $5) }
 776         | exp srcloc '|' quals                  { HsDo ListComp (reverse
 777                                                 (ReturnStmt $1 : $4)) $2 }
 778
 779 lexps :: { [RdrNameHsExpr] }
 780         : lexps ',' exp                 { $3 : $1 }
 781         | exp ',' exp                   { [$3,$1] }
 782
 783 -----------------------------------------------------------------------------
 784 -- List Comprehensions
 785
 786 quals :: { [RdrNameStmt] }
 787         : quals ',' qual                { $3 : $1 }
 788         | qual                          { [$1] }
 789
 790 qual  :: { RdrNameStmt }
 791         : srcloc infixexp '<-' exp      {% checkPattern $2 `thenP` \p ->
 792                                            returnP (BindStmt p $4 $1) }
 793         | srcloc exp                    { GuardStmt $2 $1 }
 794         | srcloc 'let' declbinds        { LetStmt $3 }
 795
 796 -----------------------------------------------------------------------------
 797 -- Case alternatives
 798
 799 altslist :: { [RdrNameMatch] }
 800         : '{'            alts '}'       { reverse $2 }
 801         |     layout_on  alts  close    { reverse $2 }
 802
 803 alts    :: { [RdrNameMatch] }
 804         : alts1                         { $1 }
 805         | ';' alts                      { $2 }
 806
 807 alts1   :: { [RdrNameMatch] }
 808         : alts1 ';' alt                 { $3 : $1 }
 809         | alts1 ';'                     { $1 }
 810         | alt                           { [$1] }
 811
 812 alt     :: { RdrNameMatch }
 813         : infixexp opt_sig ralt wherebinds
 814                                         {% (checkPattern $1 `thenP` \p ->
 815                                            returnP (Match [] [p] $2
 816                                                      (GRHSs $3 $4 Nothing))  )}
 817
 818 ralt :: { [RdrNameGRHS] }
 819         : '->' srcloc exp               { [GRHS [ExprStmt $3 $2] $2] }
 820         | gdpats                        { (reverse $1) }
 821
 822 gdpats :: { [RdrNameGRHS] }
 823         : gdpats gdpat                  { $2 : $1 }
 824         | gdpat                         { [$1] }
 825
 826 gdpat   :: { RdrNameGRHS }
 827         : srcloc '|' quals '->' exp     { GRHS (reverse (ExprStmt $5 $1:$3)) $1}
 828
 829 -----------------------------------------------------------------------------
 830 -- Statement sequences
 831
 832 stmtlist :: { [RdrNameStmt] }
 833         : '{'                   stmts '}'       { reverse $2 }
 834         |     layout_on_for_do  stmts close     { reverse $2 }
 835
 836 -- Stmt list should really end in an expression, but it's not
 837 -- convenient to enforce this here, so we throw out erroneous
 838 -- statement sequences in the renamer instead.
 839
 840 stmts :: { [RdrNameStmt] }
 841         : ';' stmts1                    { $2 }
 842         | stmts1                        { $1 }
 843
 844 stmts1 :: { [RdrNameStmt] }
 845         : stmts1 ';' stmt               { $3 : $1 }
 846         | stmts1 ';'                    { $1 }
 847         | stmt                          { [$1] }
 848
 849 stmt  :: { RdrNameStmt }
 850         : srcloc infixexp '<-' exp      {% checkPattern $2 `thenP` \p ->
 851                                            returnP (BindStmt p $4 $1) }
 852         | srcloc exp                    { ExprStmt $2 $1 }
 853         | srcloc 'let' declbinds        { LetStmt $3 }
 854
 855 -----------------------------------------------------------------------------
 856 -- Record Field Update/Construction
 857
 858 fbinds  :: { RdrNameHsRecordBinds }
 859         : fbinds ',' fbind              { $3 : $1 }
 860         | fbinds ','                    { $1 }
 861         | fbind                         { [$1] }
 862         | {- empty -}                   { [] }
 863
 864 fbind   :: { (RdrName, RdrNameHsExpr, Bool) }
 865         : qvar '=' exp                  { ($1,$3,False) }
 866
 867 -----------------------------------------------------------------------------
 868 -- Implicit Parameter Bindings
 869
 870 dbinding :: { [(RdrName, RdrNameHsExpr)] }
 871         : '{' dbinds '}'                { $2 }
 872         | layout_on dbinds close        { $2 }
 873
 874 dbinds  :: { [(RdrName, RdrNameHsExpr)] }
 875         : dbinds ';' dbind              { $3 : $1 }
 876         | dbinds ';'                    { $1 }
 877         | dbind                         { [$1] }
 878         | {- empty -}                   { [] }
 879
 880 dbind   :: { (RdrName, RdrNameHsExpr) }
 881 dbind   : ipvar '=' exp                 { ($1, $3) }
 882
 883 -----------------------------------------------------------------------------
 884 -- Variables, Constructors and Operators.
 885
 886 gtycon  :: { RdrName }
 887         : qtycon                        { $1 }
 888         | '(' ')'                       { unitTyCon_RDR }
 889         | '(' '->' ')'                  { funTyCon_RDR }
 890         | '[' ']'                       { listTyCon_RDR }
 891         | '(' commas ')'                { tupleTyCon_RDR $2 }
 892
 893 gcon    :: { RdrName }
 894         : '(' ')'               { unitCon_RDR }
 895         | '[' ']'               { nilCon_RDR }
 896         | '(' commas ')'        { tupleCon_RDR $2 }
 897         | qcon                  { $1 }
 898
 899 var     :: { RdrName }
 900         : varid                 { $1 }
 901         | '(' varsym ')'        { $2 }
 902
 903 qvar    :: { RdrName }
 904         : qvarid                { $1 }
 905         | '(' varsym ')'        { $2 }
 906         | '(' qvarsym1 ')'      { $2 }
 907 -- We've inlined qvarsym here so that the decision about
 908 -- whether it's a qvar or a var can be postponed until
 909 -- *after* we see the close paren.
 910
 911 ipvar   :: { RdrName }
 912         : IPVARID               { (mkSrcUnqual ipName (tailFS $1)) }
 913
 914 con     :: { RdrName }
 915         : conid                 { $1 }
 916         | '(' consym ')'        { $2 }
 917
 918 qcon    :: { RdrName }
 919         : qconid                { $1 }
 920         | '(' qconsym ')'       { $2 }
 921
 922 varop   :: { RdrName }
 923         : varsym                { $1 }
 924         | '`' varid '`'         { $2 }
 925
 926 qvarop :: { RdrName }
 927         : qvarsym               { $1 }
 928         | '`' qvarid '`'        { $2 }
 929
 930 qvaropm :: { RdrName }
 931         : qvarsym_no_minus      { $1 }
 932         | '`' qvarid '`'        { $2 }
 933
 934 conop :: { RdrName }
 935         : consym                { $1 }
 936         | '`' conid '`'         { $2 }
 937
 938 qconop :: { RdrName }
 939         : qconsym               { $1 }
 940         | '`' qconid '`'        { $2 }
 941
 942 -----------------------------------------------------------------------------
 943 -- Any operator
 944
 945 op      :: { RdrName }   -- used in infix decls
 946         : varop                 { $1 }
 947         | conop                 { $1 }
 948
 949 qop     :: { RdrName {-HsExpr-} }   -- used in sections
 950         : qvarop                { $1 }
 951         | qconop                { $1 }
 952
 953 qopm    :: { RdrNameHsExpr }   -- used in sections
 954         : qvaropm               { HsVar $1 }
 955         | qconop                { HsVar $1 }
 956
 957 -----------------------------------------------------------------------------
 958 -- VarIds
 959
 960 qvarid :: { RdrName }
 961         : varid                 { $1 }
 962         | QVARID                { mkSrcQual varName $1 }
 963
 964 varid :: { RdrName }
 965         : varid_no_unsafe       { $1 }
 966         | 'unsafe'              { mkSrcUnqual varName SLIT("unsafe") }
 967
 968 varid_no_unsafe :: { RdrName }
 969         : VARID                 { mkSrcUnqual varName $1 }
 970         | special_id            { mkSrcUnqual varName $1 }
 971         | 'forall'              { mkSrcUnqual varName SLIT("forall") }
 972
 973 tyvar   :: { RdrName }
 974         : VARID                 { mkSrcUnqual tvName $1 }
 975         | special_id            { mkSrcUnqual tvName $1 }
 976         | 'unsafe'              { mkSrcUnqual tvName SLIT("unsafe") }
 977
 978 -- These special_ids are treated as keywords in various places,
 979 -- but as ordinary ids elsewhere.   A special_id collects all thsee
 980 -- except 'unsafe' and 'forall' whose treatment differs depending on context
 981 special_id :: { UserFS }
 982 special_id
 983         : 'as'                  { SLIT("as") }
 984         | 'qualified'           { SLIT("qualified") }
 985         | 'hiding'              { SLIT("hiding") }
 986         | 'export'              { SLIT("export") }
 987         | 'label'               { SLIT("label")  }
 988         | 'dynamic'             { SLIT("dynamic") }
 989         | 'stdcall'             { SLIT("stdcall") }
 990         | 'ccall'               { SLIT("ccall") }
 991
 992 -----------------------------------------------------------------------------
 993 -- ConIds
 994
 995 qconid :: { RdrName }
 996         : conid                 { $1 }
 997         | QCONID                { mkSrcQual dataName $1 }
 998
 999 conid   :: { RdrName }
1000         : CONID                 { mkSrcUnqual dataName $1 }
1001
1002 -----------------------------------------------------------------------------
1003 -- ConSyms
1004
1005 qconsym :: { RdrName }
1006         : consym                { $1 }
1007         | QCONSYM               { mkSrcQual dataName $1 }
1008
1009 consym :: { RdrName }
1010         : CONSYM                { mkSrcUnqual dataName $1 }
1011
1012 -----------------------------------------------------------------------------
1013 -- VarSyms
1014
1015 qvarsym :: { RdrName }
1016         : varsym                { $1 }
1017         | qvarsym1              { $1 }
1018
1019 qvarsym_no_minus :: { RdrName }
1020         : varsym_no_minus       { $1 }
1021         | qvarsym1              { $1 }
1022
1023 qvarsym1 :: { RdrName }
1024 qvarsym1 : QVARSYM              { mkSrcQual varName $1 }
1025
1026 varsym :: { RdrName }
1027         : varsym_no_minus       { $1 }
1028         | '-'                   { mkSrcUnqual varName SLIT("-") }
1029
1030 varsym_no_minus :: { RdrName } -- varsym not including '-'
1031         : VARSYM                { mkSrcUnqual varName $1 }
1032         | special_sym           { mkSrcUnqual varName $1 }
1033
1034
1035 -- See comments with special_id
1036 special_sym :: { UserFS }
1037 special_sym : '!'       { SLIT("!") }
1038             | '.'       { SLIT(".") }
1039
1040 -----------------------------------------------------------------------------
1041 -- Literals
1042
1043 literal :: { HsLit }
1044         : CHAR                  { HsChar       $1 }
1045         | STRING                { HsString     $1 }
1046         | PRIMINTEGER           { HsIntPrim    $1 }
1047         | PRIMCHAR              { HsCharPrim   $1 }
1048         | PRIMSTRING            { HsStringPrim $1 }
1049         | PRIMFLOAT             { HsFloatPrim  $1 }
1050         | PRIMDOUBLE            { HsDoublePrim $1 }
1051         | CLITLIT               { HsLitLit     $1 (error "Parser.y: CLITLIT") }
1052
1053 srcloc :: { SrcLoc }    :       {% getSrcLocP }
1054
1055 -----------------------------------------------------------------------------
1056 -- Layout
1057
1058 close :: { () }
1059         : vccurly               { () } -- context popped in lexer.
1060         | error                 {% popContext }
1061
1062 layout_on         :: { () }     : {% layoutOn True{-strict-} }
1063 layout_on_for_do  :: { () }     : {% layoutOn False }
1064
1065 -----------------------------------------------------------------------------
1066 -- Miscellaneous (mostly renamings)
1067
1068 modid   :: { ModuleName }
1069         : CONID                 { mkSrcModuleFS $1 }
1070
1071 tycon   :: { RdrName }
1072         : CONID                 { mkSrcUnqual tcClsName $1 }
1073
1074 tyconop :: { RdrName }
1075         : CONSYM                { mkSrcUnqual tcClsName $1 }
1076
1077 qtycon :: { RdrName }
1078         : tycon                 { $1 }
1079         | QCONID                { mkSrcQual tcClsName $1 }
1080
1081 qtycls  :: { RdrName }
1082         : qtycon                { $1 }
1083
1084 commas :: { Int }
1085         : commas ','                    { $1 + 1 }
1086         | ','                           { 2 }
1087
1088 -----------------------------------------------------------------------------
1089
1090 {
1091 happyError :: P a
1092 happyError buf PState{ loc = loc } = PFailed (srcParseErr buf loc)
1093 }