ghc/compiler/parser/Parser.y

   1 {-
   2 -----------------------------------------------------------------------------
   3 $Id: Parser.y,v 1.43 2000/10/24 08:40:10 simonpj Exp $
   4
   5 Haskell grammar.
   6
   7 Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -----------------------------------------------------------------------------
   9 -}
  10
  11 {
  12 module Parser ( parse ) where
  13
  14 import HsSyn
  15 import HsPragmas
  16 import HsTypes          ( mkHsTupCon )
  17 import HsPat            ( InPat(..) )
  18
  19 import RdrHsSyn
  20 import Lex
  21 import ParseUtil
  22 import RdrName
  23 import PrelInfo         ( mAIN_Name )
  24 import OccName          ( UserFS, varName, ipName, tcName, dataName, tcClsName, tvName )
  25 import SrcLoc           ( SrcLoc )
  26 import Module
  27 import CallConv
  28 import CmdLineOpts      ( opt_SccProfilingOn )
  29 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), NewOrData(..) )
  30 import Panic
  31
  32 import GlaExts
  33 import FastString       ( tailFS )
  34 import Outputable
  35
  36 #include "HsVersions.h"
  37 }
  38
  39 {-
  40 -----------------------------------------------------------------------------
  41 Conflicts: 14 shift/reduce
  42         (note: it's currently 21 -- JRL, 31/1/2000)
  43
  44 8 for abiguity in 'if x then y else z + 1'
  45         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  46 1 for ambiguity in 'if x then y else z :: T'
  47         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  48 3 for ambiguity in 'case x of y :: a -> b'
  49         (don't know whether to reduce 'a' as a btype or shift the '->'.
  50          conclusion:  bogus expression anyway, doesn't matter)
  51
  52 1 for ambiguity in '{-# RULES "name" forall = ... #-}'
  53         since 'forall' is a valid variable name, we don't know whether
  54         to treat a forall on the input as the beginning of a quantifier
  55         or the beginning of the rule itself.  Resolving to shift means
  56         it's always treated as a quantifier, hence the above is disallowed.
  57         This saves explicitly defining a grammar for the rule lhs that
  58         doesn't include 'forall'.
  59
  60 1 for ambiguity in 'x @ Rec{..}'.
  61         Only sensible parse is 'x @ (Rec{..})', which is what resolving
  62         to shift gives us.
  63
  64 -----------------------------------------------------------------------------
  65 -}
  66
  67 %token
  68  '_'            { ITunderscore }                -- Haskell keywords
  69  'as'           { ITas }
  70  'case'         { ITcase }
  71  'class'        { ITclass }
  72  'data'         { ITdata }
  73  'default'      { ITdefault }
  74  'deriving'     { ITderiving }
  75  'do'           { ITdo }
  76  'else'         { ITelse }
  77  'hiding'       { IThiding }
  78  'if'           { ITif }
  79  'import'       { ITimport }
  80  'in'           { ITin }
  81  'infix'        { ITinfix }
  82  'infixl'       { ITinfixl }
  83  'infixr'       { ITinfixr }
  84  'instance'     { ITinstance }
  85  'let'          { ITlet }
  86  'module'       { ITmodule }
  87  'newtype'      { ITnewtype }
  88  'of'           { ITof }
  89  'qualified'    { ITqualified }
  90  'then'         { ITthen }
  91  'type'         { ITtype }
  92  'where'        { ITwhere }
  93  '_scc_'        { ITscc }
  94
  95  'forall'       { ITforall }                    -- GHC extension keywords
  96  'foreign'      { ITforeign }
  97  'export'       { ITexport }
  98  'label'        { ITlabel }
  99  'dynamic'      { ITdynamic }
 100  'unsafe'       { ITunsafe }
 101  'with'         { ITwith }
 102  'stdcall'      { ITstdcallconv }
 103  'ccall'        { ITccallconv }
 104  '_ccall_'      { ITccall (False, False, False) }
 105  '_ccall_GC_'   { ITccall (False, False, True)  }
 106  '_casm_'       { ITccall (False, True,  False) }
 107  '_casm_GC_'    { ITccall (False, True,  True)  }
 108
 109  '{-# SPECIALISE'  { ITspecialise_prag }
 110  '{-# SOURCE'      { ITsource_prag }
 111  '{-# INLINE'      { ITinline_prag }
 112  '{-# NOINLINE'    { ITnoinline_prag }
 113  '{-# RULES'       { ITrules_prag }
 114  '{-# DEPRECATED'  { ITdeprecated_prag }
 115  '#-}'             { ITclose_prag }
 116
 117 {-
 118  '__interface'  { ITinterface }                 -- interface keywords
 119  '__export'     { IT__export }
 120  '__instimport' { ITinstimport }
 121  '__forall'     { IT__forall }
 122  '__letrec'     { ITletrec }
 123  '__coerce'     { ITcoerce }
 124  '__depends'    { ITdepends }
 125  '__inline'     { ITinline }
 126  '__DEFAULT'    { ITdefaultbranch }
 127  '__bot'        { ITbottom }
 128  '__integer'    { ITinteger_lit }
 129  '__float'      { ITfloat_lit }
 130  '__rational'   { ITrational_lit }
 131  '__addr'       { ITaddr_lit }
 132  '__label'      { ITlabel_lit }
 133  '__litlit'     { ITlit_lit }
 134  '__string'     { ITstring_lit }
 135  '__ccall'      { ITccall $$ }
 136  '__scc'        { IT__scc }
 137  '__sccC'       { ITsccAllCafs }
 138
 139  '__A'          { ITarity }
 140  '__P'          { ITspecialise }
 141  '__C'          { ITnocaf }
 142  '__U'          { ITunfold $$ }
 143  '__S'          { ITstrict $$ }
 144  '__M'          { ITcprinfo $$ }
 145 -}
 146
 147  '..'           { ITdotdot }                    -- reserved symbols
 148  '::'           { ITdcolon }
 149  '='            { ITequal }
 150  '\\'           { ITlam }
 151  '|'            { ITvbar }
 152  '<-'           { ITlarrow }
 153  '->'           { ITrarrow }
 154  '@'            { ITat }
 155  '~'            { ITtilde }
 156  '=>'           { ITdarrow }
 157  '-'            { ITminus }
 158  '!'            { ITbang }
 159  '.'            { ITdot }
 160
 161  '{'            { ITocurly }                    -- special symbols
 162  '}'            { ITccurly }
 163  '{|'           { ITocurlybar }
 164  '|}'           { ITccurlybar }
 165  vccurly        { ITvccurly } -- virtual close curly (from layout)
 166  '['            { ITobrack }
 167  ']'            { ITcbrack }
 168  '('            { IToparen }
 169  ')'            { ITcparen }
 170  '(#'           { IToubxparen }
 171  '#)'           { ITcubxparen }
 172  ';'            { ITsemi }
 173  ','            { ITcomma }
 174  '`'            { ITbackquote }
 175
 176  VARID          { ITvarid    $$ }               -- identifiers
 177  CONID          { ITconid    $$ }
 178  VARSYM         { ITvarsym   $$ }
 179  CONSYM         { ITconsym   $$ }
 180  QVARID         { ITqvarid   $$ }
 181  QCONID         { ITqconid   $$ }
 182  QVARSYM        { ITqvarsym  $$ }
 183  QCONSYM        { ITqconsym  $$ }
 184
 185  IPVARID        { ITipvarid  $$ }               -- GHC extension
 186
 187  CHAR           { ITchar     $$ }
 188  STRING         { ITstring   $$ }
 189  INTEGER        { ITinteger  $$ }
 190  RATIONAL       { ITrational $$ }
 191
 192  PRIMCHAR       { ITprimchar   $$ }
 193  PRIMSTRING     { ITprimstring $$ }
 194  PRIMINTEGER    { ITprimint    $$ }
 195  PRIMFLOAT      { ITprimfloat  $$ }
 196  PRIMDOUBLE     { ITprimdouble $$ }
 197  CLITLIT        { ITlitlit     $$ }
 198
 199 %monad { P } { thenP } { returnP }
 200 %lexer { lexer } { ITeof }
 201 %name parse
 202 %tokentype { Token }
 203 %%
 204
 205 -----------------------------------------------------------------------------
 206 -- Module Header
 207
 208 -- The place for module deprecation is really too restrictive, but if it
 209 -- was allowed at its natural place just before 'module', we get an ugly
 210 -- s/r conflict with the second alternative. Another solution would be the
 211 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 212 -- either, and DEPRECATED is only expected to be used by people who really
 213 -- know what they are doing. :-)
 214
 215 module  :: { RdrNameHsModule }
 216         : srcloc 'module' modid maybemoddeprec maybeexports 'where' body
 217                 { HsModule $3 Nothing $5 (fst $7) (snd $7) $4 $1 }
 218         | srcloc body
 219                 { HsModule mAIN_Name Nothing Nothing (fst $2) (snd $2) Nothing $1 }
 220
 221 maybemoddeprec :: { Maybe DeprecTxt }
 222         : '{-# DEPRECATED' STRING '#-}'         { Just $2 }
 223         |  {- empty -}                          { Nothing }
 224
 225 body    :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 226         :  '{'            top '}'               { $2 }
 227         |      layout_on  top close             { $2 }
 228
 229 top     :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 230         : importdecls                           { (reverse $1,[]) }
 231         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 232         | cvtopdecls                            { ([],$1) }
 233
 234 cvtopdecls :: { [RdrNameHsDecl] }
 235         : topdecls                              { cvTopDecls (groupBindings $1)}
 236
 237 -----------------------------------------------------------------------------
 238 -- The Export List
 239
 240 maybeexports :: { Maybe [RdrNameIE] }
 241         :  '(' exportlist ')'                   { Just $2 }
 242         |  {- empty -}                          { Nothing }
 243
 244 exportlist :: { [RdrNameIE] }
 245         :  exportlist ',' export                { $3 : $1 }
 246         |  exportlist ','                       { $1 }
 247         |  export                               { [$1]  }
 248         |  {- empty -}                          { [] }
 249
 250    -- GHC extension: we allow things like [] and (,,,) to be exported
 251 export  :: { RdrNameIE }
 252         :  qvar                                 { IEVar $1 }
 253         |  gtycon                               { IEThingAbs $1 }
 254         |  gtycon '(' '..' ')'                  { IEThingAll $1 }
 255         |  gtycon '(' ')'                       { IEThingWith $1 [] }
 256         |  gtycon '(' qcnames ')'               { IEThingWith $1 (reverse $3) }
 257         |  'module' modid                       { IEModuleContents $2 }
 258
 259 qcnames :: { [RdrName] }
 260         :  qcnames ',' qcname                   { $3 : $1 }
 261         |  qcname                               { [$1]  }
 262
 263 qcname  :: { RdrName }
 264         :  qvar                                 { $1 }
 265         |  gcon                                 { $1 }
 266
 267 -----------------------------------------------------------------------------
 268 -- Import Declarations
 269
 270 -- import decls can be *empty*, or even just a string of semicolons
 271 -- whereas topdecls must contain at least one topdecl.
 272
 273 importdecls :: { [RdrNameImportDecl] }
 274         : importdecls ';' importdecl            { $3 : $1 }
 275         | importdecls ';'                       { $1 }
 276         | importdecl                            { [ $1 ] }
 277         | {- empty -}                           { [] }
 278
 279 importdecl :: { RdrNameImportDecl }
 280         : 'import' srcloc maybe_src optqualified CONID maybeas maybeimpspec
 281                 { ImportDecl (mkSrcModuleFS $5) $3 $4 $6 $7 $2 }
 282
 283 maybe_src :: { WhereFrom }
 284         : '{-# SOURCE' '#-}'                    { ImportByUserSource }
 285         | {- empty -}                           { ImportByUser }
 286
 287 optqualified :: { Bool }
 288         : 'qualified'                           { True  }
 289         | {- empty -}                           { False }
 290
 291 maybeas :: { Maybe ModuleName }
 292         : 'as' modid                            { Just $2 }
 293         | {- empty -}                           { Nothing }
 294
 295 maybeimpspec :: { Maybe (Bool, [RdrNameIE]) }
 296         : impspec                               { Just $1 }
 297         | {- empty -}                           { Nothing }
 298
 299 impspec :: { (Bool, [RdrNameIE]) }
 300         :  '(' exportlist ')'                   { (False, reverse $2) }
 301         |  'hiding' '(' exportlist ')'          { (True,  reverse $3) }
 302
 303 -----------------------------------------------------------------------------
 304 -- Fixity Declarations
 305
 306 prec    :: { Int }
 307         : {- empty -}                           { 9 }
 308         | INTEGER                               {%  checkPrec $1 `thenP_`
 309                                                     returnP (fromInteger $1) }
 310
 311 infix   :: { FixityDirection }
 312         : 'infix'                               { InfixN  }
 313         | 'infixl'                              { InfixL  }
 314         | 'infixr'                              { InfixR }
 315
 316 ops     :: { [RdrName] }
 317         : ops ',' op                            { $3 : $1 }
 318         | op                                    { [$1] }
 319
 320 -----------------------------------------------------------------------------
 321 -- Top-Level Declarations
 322
 323 topdecls :: { [RdrBinding] }
 324         : topdecls ';' topdecl          { ($3 : $1) }
 325         | topdecls ';'                  { $1 }
 326         | topdecl                       { [$1] }
 327
 328 topdecl :: { RdrBinding }
 329         : srcloc 'type' simpletype '=' sigtype
 330                 { RdrHsDecl (TyClD (TySynonym (fst $3) (snd $3) $5 $1)) }
 331
 332         | srcloc 'data' ctype '=' constrs deriving
 333                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 334                    returnP (RdrHsDecl (TyClD
 335                       (mkTyData DataType cs c ts (reverse $5) (length $5) $6 $1))) }
 336
 337         | srcloc 'newtype' ctype '=' newconstr deriving
 338                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 339                    returnP (RdrHsDecl (TyClD
 340                       (mkTyData NewType cs c ts [$5] 1 $6 $1))) }
 341
 342         | srcloc 'class' ctype fds where
 343                 {% checkDataHeader $3 `thenP` \(cs,c,ts) ->
 344                    let
 345                         (binds,sigs) = cvMonoBindsAndSigs cvClassOpSig (groupBindings $5)
 346                    in
 347                    returnP (RdrHsDecl (TyClD
 348                       (mkClassDecl cs c ts $4 sigs binds $1))) }
 349
 350         | srcloc 'instance' inst_type where
 351                 { let (binds,sigs)
 352                         = cvMonoBindsAndSigs cvInstDeclSig
 353                                 (groupBindings $4)
 354                   in RdrHsDecl (InstD (InstDecl $3 binds sigs Nothing $1)) }
 355
 356         | srcloc 'default' '(' types0 ')'
 357                 { RdrHsDecl (DefD (DefaultDecl $4 $1)) }
 358
 359         | srcloc 'foreign' 'import' callconv ext_name
 360           unsafe_flag varid_no_unsafe '::' sigtype
 361                 { RdrHsDecl (ForD (ForeignDecl $7 (FoImport $6) $9 (mkExtName $5 $7) $4 $1)) }
 362
 363         | srcloc 'foreign' 'export' callconv ext_name varid '::' sigtype
 364                 { RdrHsDecl (ForD (ForeignDecl $6 FoExport $8 (mkExtName $5 $6) $4 $1)) }
 365
 366         | srcloc 'foreign' 'label' ext_name varid '::' sigtype
 367                 { RdrHsDecl (ForD (ForeignDecl $5 FoLabel $7 (mkExtName $4 $5)
 368                                         defaultCallConv $1)) }
 369
 370         | '{-# DEPRECATED' deprecations '#-}'           { $2 }
 371         | '{-# RULES' rules '#-}'                       { $2 }
 372         | decl                                          { $1 }
 373
 374 decls   :: { [RdrBinding] }
 375         : decls ';' decl                { $3 : $1 }
 376         | decls ';'                     { $1 }
 377         | decl                          { [$1] }
 378         | {- empty -}                   { [] }
 379
 380 decl    :: { RdrBinding }
 381         : fixdecl                       { $1 }
 382         | valdef                        { $1 }
 383         | '{-# INLINE'   srcloc opt_phase qvar '#-}'    { RdrSig (InlineSig $4 $3 $2) }
 384         | '{-# NOINLINE' srcloc opt_phase qvar '#-}'    { RdrSig (NoInlineSig $4 $3 $2) }
 385         | '{-# SPECIALISE' srcloc qvar '::' sigtypes '#-}'
 386                 { foldr1 RdrAndBindings
 387                     (map (\t -> RdrSig (SpecSig $3 t $2)) $5) }
 388         | '{-# SPECIALISE' srcloc 'instance' inst_type '#-}'
 389                 { RdrSig (SpecInstSig $4 $2) }
 390
 391 opt_phase :: { Maybe Int }
 392           : INTEGER                     { Just (fromInteger $1) }
 393           | {- empty -}                 { Nothing }
 394
 395 wherebinds :: { RdrNameHsBinds }
 396         : where                 { cvBinds cvValSig (groupBindings $1) }
 397
 398 where   :: { [RdrBinding] }
 399         : 'where' decllist              { $2 }
 400         | {- empty -}                   { [] }
 401
 402 declbinds :: { RdrNameHsBinds }
 403         : decllist                      { cvBinds cvValSig (groupBindings $1) }
 404
 405 decllist :: { [RdrBinding] }
 406         : '{'            decls '}'      { $2 }
 407         |     layout_on  decls close    { $2 }
 408
 409 fixdecl :: { RdrBinding }
 410         : srcloc infix prec ops         { foldr1 RdrAndBindings
 411                                             [ RdrSig (FixSig (FixitySig n
 412                                                             (Fixity $3 $2) $1))
 413                                             | n <- $4 ] }
 414
 415 -----------------------------------------------------------------------------
 416 -- Transformation Rules
 417
 418 rules   :: { RdrBinding }
 419         :  rules ';' rule                       { $1 `RdrAndBindings` $3 }
 420         |  rules ';'                            { $1 }
 421         |  rule                                 { $1 }
 422         |  {- empty -}                          { RdrNullBind }
 423
 424 rule    :: { RdrBinding }
 425         : STRING rule_forall fexp '=' srcloc exp
 426              { RdrHsDecl (RuleD (HsRule $1 [] $2 $3 $6 $5)) }
 427
 428 rule_forall :: { [RdrNameRuleBndr] }
 429         : 'forall' rule_var_list '.'            { $2 }
 430         | {- empty -}                           { [] }
 431
 432 rule_var_list :: { [RdrNameRuleBndr] }
 433         : rule_var                              { [$1] }
 434         | rule_var rule_var_list                { $1 : $2 }
 435
 436 rule_var :: { RdrNameRuleBndr }
 437         : varid                                 { RuleBndr $1 }
 438         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 439
 440 -----------------------------------------------------------------------------
 441 -- Deprecations
 442
 443 deprecations :: { RdrBinding }
 444         : deprecations ';' deprecation          { $1 `RdrAndBindings` $3 }
 445         | deprecations ';'                      { $1 }
 446         | deprecation                           { $1 }
 447         | {- empty -}                           { RdrNullBind }
 448
 449 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 450 deprecation :: { RdrBinding }
 451         : srcloc depreclist STRING
 452                 { foldr RdrAndBindings RdrNullBind
 453                         [ RdrHsDecl (DeprecD (Deprecation n $3 $1)) | n <- $2 ] }
 454
 455 -----------------------------------------------------------------------------
 456 -- Foreign import/export
 457
 458 callconv :: { Int }
 459         : 'stdcall'             { stdCallConv }
 460         | 'ccall'               { cCallConv }
 461         | {- empty -}           { defaultCallConv }
 462
 463 unsafe_flag :: { Bool }
 464         : 'unsafe'              { True }
 465         | {- empty -}           { False }
 466
 467 ext_name :: { Maybe ExtName }
 468         : 'dynamic'             { Just Dynamic }
 469         | STRING                { Just (ExtName $1 Nothing)   }
 470         | STRING STRING         { Just (ExtName $2 (Just $1)) }
 471         | {- empty -}           { Nothing }
 472
 473
 474 -----------------------------------------------------------------------------
 475 -- Type signatures
 476
 477 opt_sig :: { Maybe RdrNameHsType }
 478         : {- empty -}                   { Nothing }
 479         | '::' sigtype                  { Just $2 }
 480
 481 opt_asig :: { Maybe RdrNameHsType }
 482         : {- empty -}                   { Nothing }
 483         | '::' atype                    { Just $2 }
 484
 485 sigtypes :: { [RdrNameHsType] }
 486         : sigtype                       { [ $1 ] }
 487         | sigtypes ',' sigtype          { $3 : $1 }
 488
 489 sigtype :: { RdrNameHsType }
 490         : ctype                         { (mkHsForAllTy Nothing [] $1) }
 491
 492 sig_vars :: { [RdrName] }
 493          : sig_vars ',' var             { $3 : $1 }
 494          | var                          { [ $1 ] }
 495
 496 -----------------------------------------------------------------------------
 497 -- Types
 498
 499 -- A ctype is a for-all type
 500 ctype   :: { RdrNameHsType }
 501         : 'forall' tyvars '.' ctype     { mkHsForAllTy (Just $2) [] $4 }
 502         | context type                  { mkHsForAllTy Nothing   $1 $2 }
 503         -- A type of form (context => type) is an *implicit* HsForAllTy
 504         | type                          { $1 }
 505
 506 type :: { RdrNameHsType }
 507         : gentype '->' type             { HsFunTy $1 $3 }
 508         | ipvar '::' type               { mkHsIParamTy $1 $3 }
 509         | gentype                       { $1 }
 510
 511 gentype :: { RdrNameHsType }
 512         : btype                         { $1 }
 513 -- Generics
 514         | atype tyconop atype           { HsOpTy $1 $2 $3 }
 515
 516 btype :: { RdrNameHsType }
 517         : btype atype                   { (HsAppTy $1 $2) }
 518         | atype                         { $1 }
 519
 520 atype :: { RdrNameHsType }
 521         : gtycon                        { HsTyVar $1 }
 522         | tyvar                         { HsTyVar $1 }
 523         | '(' type ',' types ')'        { HsTupleTy (mkHsTupCon tcName Boxed  ($2:$4)) ($2 : reverse $4) }
 524         | '(#' types '#)'               { HsTupleTy (mkHsTupCon tcName Unboxed     $2) (reverse $2)      }
 525         | '[' type ']'                  { HsListTy $2 }
 526         | '(' ctype ')'                 { $2 }
 527 -- Generics
 528         | INTEGER                       { HsNumTy $1 }
 529
 530 -- An inst_type is what occurs in the head of an instance decl
 531 --      e.g.  (Foo a, Gaz b) => Wibble a b
 532 -- It's kept as a single type, with a MonoDictTy at the right
 533 -- hand corner, for convenience.
 534 inst_type :: { RdrNameHsType }
 535         : ctype                         {% checkInstType $1 }
 536
 537 types0  :: { [RdrNameHsType] }
 538         : types                         { $1 }
 539         | {- empty -}                   { [] }
 540
 541 types   :: { [RdrNameHsType] }
 542         : type                          { [$1] }
 543         | types  ',' type               { $3 : $1 }
 544
 545 simpletype :: { (RdrName, [RdrNameHsTyVar]) }
 546         : tycon tyvars                  { ($1, reverse $2) }
 547
 548 tyvars :: { [RdrNameHsTyVar] }
 549         : tyvars tyvar                  { UserTyVar $2 : $1 }
 550         | {- empty -}                   { [] }
 551
 552 fds :: { [([RdrName], [RdrName])] }
 553         : {- empty -}                   { [] }
 554         | '|' fds1                      { reverse $2 }
 555
 556 fds1 :: { [([RdrName], [RdrName])] }
 557         : fds1 ',' fd                   { $3 : $1 }
 558         | fd                            { [$1] }
 559
 560 fd :: { ([RdrName], [RdrName]) }
 561         : varids0 '->' varids0          { (reverse $1, reverse $3) }
 562
 563 varids0 :: { [RdrName] }
 564         : {- empty -}                   { [] }
 565         | varids0 tyvar                 { $2 : $1 }
 566
 567 -----------------------------------------------------------------------------
 568 -- Datatype declarations
 569
 570 newconstr :: { RdrNameConDecl }
 571         : srcloc conid atype    { mkConDecl $2 [] [] (VanillaCon [Unbanged $3]) $1 }
 572         | srcloc conid '{' var '::' type '}'
 573                                 { mkConDecl $2 [] [] (RecCon [([$4], Unbanged $6)]) $1 }
 574
 575 constrs :: { [RdrNameConDecl] }
 576         : constrs '|' constr            { $3 : $1 }
 577         | constr                        { [$1] }
 578
 579 constr :: { RdrNameConDecl }
 580         : srcloc forall context constr_stuff
 581                 { mkConDecl (fst $4) $2 $3 (snd $4) $1 }
 582         | srcloc forall constr_stuff
 583                 { mkConDecl (fst $3) $2 [] (snd $3) $1 }
 584
 585 forall :: { [RdrNameHsTyVar] }
 586         : 'forall' tyvars '.'           { $2 }
 587         | {- empty -}                   { [] }
 588
 589 context :: { RdrNameContext }
 590         : btype '=>'                    {% checkContext $1 }
 591
 592 constr_stuff :: { (RdrName, RdrNameConDetails) }
 593         : btype                         {% mkVanillaCon $1 []               }
 594         | btype '!' atype satypes       {% mkVanillaCon $1 (Banged $3 : $4) }
 595         | gtycon '{' fielddecls '}'     {% mkRecCon $1 $3 }
 596         | sbtype conop sbtype           { ($2, InfixCon $1 $3) }
 597
 598 satypes :: { [RdrNameBangType] }
 599         : atype satypes                 { Unbanged $1 : $2 }
 600         | '!' atype satypes             { Banged   $2 : $3 }
 601         | {- empty -}                   { [] }
 602
 603 sbtype :: { RdrNameBangType }
 604         : btype                         { Unbanged $1 }
 605         | '!' atype                     { Banged   $2 }
 606
 607 fielddecls :: { [([RdrName],RdrNameBangType)] }
 608         : fielddecl ',' fielddecls      { $1 : $3 }
 609         | fielddecl                     { [$1] }
 610
 611 fielddecl :: { ([RdrName],RdrNameBangType) }
 612         : sig_vars '::' stype           { (reverse $1, $3) }
 613
 614 stype :: { RdrNameBangType }
 615         : ctype                         { Unbanged $1 }
 616         | '!' atype                     { Banged   $2 }
 617
 618 deriving :: { Maybe [RdrName] }
 619         : {- empty -}                   { Nothing }
 620         | 'deriving' qtycls             { Just [$2] }
 621         | 'deriving' '('          ')'   { Just [] }
 622         | 'deriving' '(' dclasses ')'   { Just (reverse $3) }
 623
 624 dclasses :: { [RdrName] }
 625         : dclasses ',' qtycls           { $3 : $1 }
 626         | qtycls                        { [$1] }
 627
 628 -----------------------------------------------------------------------------
 629 -- Value definitions
 630
 631 {- There's an awkward overlap with a type signature.  Consider
 632         f :: Int -> Int = ...rhs...
 633    Then we can't tell whether it's a type signature or a value
 634    definition with a result signature until we see the '='.
 635    So we have to inline enough to postpone reductions until we know.
 636 -}
 637
 638 {-
 639   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
 640   instead of qvar, we get another shift/reduce-conflict. Consider the
 641   following programs:
 642
 643      { (^^) :: Int->Int ; }          Type signature; only var allowed
 644
 645      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
 646                                      qvar allowed (because of instance decls)
 647
 648   We can't tell whether to reduce var to qvar until after we've read the signatures.
 649 -}
 650
 651 valdef :: { RdrBinding }
 652         : infixexp srcloc opt_sig rhs           {% (checkValDef $1 $3 $4 $2) }
 653         | infixexp srcloc '::' sigtype          {% (checkValSig $1 $4 $2) }
 654         | var ',' sig_vars srcloc '::' sigtype  { foldr1 RdrAndBindings
 655                                                          [ RdrSig (Sig n $6 $4) | n <- $1:$3 ]
 656                                                 }
 657
 658
 659 rhs     :: { RdrNameGRHSs }
 660         : '=' srcloc exp wherebinds     { (GRHSs (unguardedRHS $3 $2)
 661                                                                 $4 Nothing)}
 662         | gdrhs wherebinds              { GRHSs (reverse $1) $2 Nothing }
 663
 664 gdrhs :: { [RdrNameGRHS] }
 665         : gdrhs gdrh                    { $2 : $1 }
 666         | gdrh                          { [$1] }
 667
 668 gdrh :: { RdrNameGRHS }
 669         : '|' srcloc quals '=' exp      { GRHS (reverse (ExprStmt $5 $2 : $3)) $2 }
 670
 671 -----------------------------------------------------------------------------
 672 -- Expressions
 673
 674 exp   :: { RdrNameHsExpr }
 675         : infixexp '::' sigtype         { (ExprWithTySig $1 $3) }
 676         | infixexp 'with' dbinding      { HsWith $1 $3 }
 677         | infixexp                      { $1 }
 678
 679 infixexp :: { RdrNameHsExpr }
 680         : exp10                         { $1 }
 681         | infixexp qop exp10            { (OpApp $1 (HsVar $2)
 682                                                 (panic "fixity") $3 )}
 683
 684 exp10 :: { RdrNameHsExpr }
 685         : '\\' aexp aexps opt_asig '->' srcloc exp
 686                         {% checkPatterns ($2 : reverse $3) `thenP` \ ps ->
 687                            returnP (HsLam (Match [] ps $4
 688                                             (GRHSs (unguardedRHS $7 $6)
 689                                                    EmptyBinds Nothing))) }
 690         | 'let' declbinds 'in' exp              { HsLet $2 $4 }
 691         | 'if' srcloc exp 'then' exp 'else' exp { HsIf $3 $5 $7 $2 }
 692         | 'case' srcloc exp 'of' altslist       { HsCase $3 $5 $2 }
 693         | '-' fexp                              { mkHsNegApp $2 }
 694         | srcloc 'do' stmtlist                  { HsDo DoStmt $3 $1 }
 695
 696         | '_ccall_'    ccallid aexps0           { HsCCall $2 $3 False False cbot }
 697         | '_ccall_GC_' ccallid aexps0           { HsCCall $2 $3 True  False cbot }
 698         | '_casm_'     CLITLIT aexps0           { HsCCall $2 $3 False True  cbot }
 699         | '_casm_GC_'  CLITLIT aexps0           { HsCCall $2 $3 True  True  cbot }
 700
 701         | '_scc_' STRING exp                    { if opt_SccProfilingOn
 702                                                         then HsSCC $2 $3
 703                                                         else HsPar $3 }
 704
 705         | fexp                                  { $1 }
 706
 707 ccallid :: { FAST_STRING }
 708         :  VARID                                { $1 }
 709         |  CONID                                { $1 }
 710
 711 fexp    :: { RdrNameHsExpr }
 712         : fexp aexp                             { (HsApp $1 $2) }
 713         | aexp                                  { $1 }
 714
 715 aexps0  :: { [RdrNameHsExpr] }
 716         : aexps                                 { (reverse $1) }
 717
 718 aexps   :: { [RdrNameHsExpr] }
 719         : aexps aexp                            { $2 : $1 }
 720         | {- empty -}                           { [] }
 721
 722 aexp    :: { RdrNameHsExpr }
 723         : var_or_con '{|' gentype '|}'          { (HsApp $1 (HsType $3)) }
 724         | aexp '{' fbinds '}'                   {% (mkRecConstrOrUpdate $1
 725                                                         (reverse $3)) }
 726         | aexp1                                 { $1 }
 727
 728 var_or_con :: { RdrNameHsExpr }
 729         : qvar                          { HsVar $1 }
 730         | gcon                          { HsVar $1 }
 731
 732 aexp1   :: { RdrNameHsExpr }
 733         : ipvar                         { HsIPVar $1 }
 734         | var_or_con                    { $1 }
 735         | literal                       { HsLit $1 }
 736         | INTEGER                       { HsOverLit (mkHsIntegralLit $1) }
 737         | RATIONAL                      { HsOverLit (mkHsFractionalLit $1) }
 738         | '(' exp ')'                   { HsPar $2 }
 739         | '(' exp ',' texps ')'         { ExplicitTuple ($2 : reverse $4) Boxed}
 740         | '(#' texps '#)'               { ExplicitTuple (reverse $2)      Unboxed }
 741         | '[' list ']'                  { $2 }
 742         | '(' infixexp qop ')'          { (SectionL $2 (HsVar $3))  }
 743         | '(' qopm infixexp ')'         { (SectionR $2 $3) }
 744         | qvar '@' aexp                 { EAsPat $1 $3 }
 745         | '_'                           { EWildPat }
 746         | '~' aexp1                     { ELazyPat $2 }
 747
 748 texps :: { [RdrNameHsExpr] }
 749         : texps ',' exp                 { $3 : $1 }
 750         | exp                           { [$1] }
 751
 752
 753 -----------------------------------------------------------------------------
 754 -- List expressions
 755
 756 -- The rules below are little bit contorted to keep lexps left-recursive while
 757 -- avoiding another shift/reduce-conflict.
 758
 759 list :: { RdrNameHsExpr }
 760         : exp                           { ExplicitList [$1] }
 761         | lexps                         { ExplicitList (reverse $1) }
 762         | exp '..'                      { ArithSeqIn (From $1) }
 763         | exp ',' exp '..'              { ArithSeqIn (FromThen $1 $3) }
 764         | exp '..' exp                  { ArithSeqIn (FromTo $1 $3) }
 765         | exp ',' exp '..' exp          { ArithSeqIn (FromThenTo $1 $3 $5) }
 766         | exp srcloc '|' quals                  { HsDo ListComp (reverse
 767                                                 (ReturnStmt $1 : $4)) $2 }
 768
 769 lexps :: { [RdrNameHsExpr] }
 770         : lexps ',' exp                 { $3 : $1 }
 771         | exp ',' exp                   { [$3,$1] }
 772
 773 -----------------------------------------------------------------------------
 774 -- List Comprehensions
 775
 776 quals :: { [RdrNameStmt] }
 777         : quals ',' qual                { $3 : $1 }
 778         | qual                          { [$1] }
 779
 780 qual  :: { RdrNameStmt }
 781         : srcloc infixexp '<-' exp      {% checkPattern $2 `thenP` \p ->
 782                                            returnP (BindStmt p $4 $1) }
 783         | srcloc exp                    { GuardStmt $2 $1 }
 784         | srcloc 'let' declbinds        { LetStmt $3 }
 785
 786 -----------------------------------------------------------------------------
 787 -- Case alternatives
 788
 789 altslist :: { [RdrNameMatch] }
 790         : '{'            alts '}'       { reverse $2 }
 791         |     layout_on  alts  close    { reverse $2 }
 792
 793 alts    :: { [RdrNameMatch] }
 794         : alts1                         { $1 }
 795         | ';' alts                      { $2 }
 796
 797 alts1   :: { [RdrNameMatch] }
 798         : alts1 ';' alt                 { $3 : $1 }
 799         | alts1 ';'                     { $1 }
 800         | alt                           { [$1] }
 801
 802 alt     :: { RdrNameMatch }
 803         : infixexp opt_sig ralt wherebinds
 804                                         {% (checkPattern $1 `thenP` \p ->
 805                                            returnP (Match [] [p] $2
 806                                                      (GRHSs $3 $4 Nothing))  )}
 807
 808 ralt :: { [RdrNameGRHS] }
 809         : '->' srcloc exp               { [GRHS [ExprStmt $3 $2] $2] }
 810         | gdpats                        { (reverse $1) }
 811
 812 gdpats :: { [RdrNameGRHS] }
 813         : gdpats gdpat                  { $2 : $1 }
 814         | gdpat                         { [$1] }
 815
 816 gdpat   :: { RdrNameGRHS }
 817         : srcloc '|' quals '->' exp     { GRHS (reverse (ExprStmt $5 $1:$3)) $1}
 818
 819 -----------------------------------------------------------------------------
 820 -- Statement sequences
 821
 822 stmtlist :: { [RdrNameStmt] }
 823         : '{'                   stmts '}'       { reverse $2 }
 824         |     layout_on_for_do  stmts close     { reverse $2 }
 825
 826 -- Stmt list should really end in an expression, but it's not
 827 -- convenient to enforce this here, so we throw out erroneous
 828 -- statement sequences in the renamer instead.
 829
 830 stmts :: { [RdrNameStmt] }
 831         : ';' stmts1                    { $2 }
 832         | stmts1                        { $1 }
 833
 834 stmts1 :: { [RdrNameStmt] }
 835         : stmts1 ';' stmt               { $3 : $1 }
 836         | stmts1 ';'                    { $1 }
 837         | stmt                          { [$1] }
 838
 839 stmt  :: { RdrNameStmt }
 840         : srcloc infixexp '<-' exp      {% checkPattern $2 `thenP` \p ->
 841                                            returnP (BindStmt p $4 $1) }
 842         | srcloc exp                    { ExprStmt $2 $1 }
 843         | srcloc 'let' declbinds        { LetStmt $3 }
 844
 845 -----------------------------------------------------------------------------
 846 -- Record Field Update/Construction
 847
 848 fbinds  :: { RdrNameHsRecordBinds }
 849         : fbinds ',' fbind              { $3 : $1 }
 850         | fbinds ','                    { $1 }
 851         | fbind                         { [$1] }
 852         | {- empty -}                   { [] }
 853
 854 fbind   :: { (RdrName, RdrNameHsExpr, Bool) }
 855         : qvar '=' exp                  { ($1,$3,False) }
 856
 857 -----------------------------------------------------------------------------
 858 -- Implicit Parameter Bindings
 859
 860 dbinding :: { [(RdrName, RdrNameHsExpr)] }
 861         : '{' dbinds '}'                { $2 }
 862         | layout_on dbinds close        { $2 }
 863
 864 dbinds  :: { [(RdrName, RdrNameHsExpr)] }
 865         : dbinds ';' dbind              { $3 : $1 }
 866         | dbinds ';'                    { $1 }
 867         | dbind                         { [$1] }
 868         | {- empty -}                   { [] }
 869
 870 dbind   :: { (RdrName, RdrNameHsExpr) }
 871 dbind   : ipvar '=' exp                 { ($1, $3) }
 872
 873 -----------------------------------------------------------------------------
 874 -- Variables, Constructors and Operators.
 875
 876 depreclist :: { [RdrName] }
 877 depreclist : deprec_var                 { [$1] }
 878            | deprec_var ',' depreclist  { $1 : $2 }
 879
 880 deprec_var :: { RdrName }
 881 deprec_var : var                        { $1 }
 882            | tycon                      { $1 }
 883
 884 gtycon  :: { RdrName }
 885         : qtycon                        { $1 }
 886         | '(' qtyconop ')'              { $2 }
 887         | '(' ')'                       { unitTyCon_RDR }
 888         | '(' '->' ')'                  { funTyCon_RDR }
 889         | '[' ']'                       { listTyCon_RDR }
 890         | '(' commas ')'                { tupleTyCon_RDR $2 }
 891
 892 gcon    :: { RdrName }
 893         : '(' ')'               { unitCon_RDR }
 894         | '[' ']'               { nilCon_RDR }
 895         | '(' commas ')'        { tupleCon_RDR $2 }
 896         | qcon                  { $1 }
 897
 898 var     :: { RdrName }
 899         : varid                 { $1 }
 900         | '(' varsym ')'        { $2 }
 901
 902 qvar    :: { RdrName }
 903         : qvarid                { $1 }
 904         | '(' varsym ')'        { $2 }
 905         | '(' qvarsym1 ')'      { $2 }
 906 -- We've inlined qvarsym here so that the decision about
 907 -- whether it's a qvar or a var can be postponed until
 908 -- *after* we see the close paren.
 909
 910 ipvar   :: { RdrName }
 911         : IPVARID               { (mkUnqual ipName (tailFS $1)) }
 912
 913 qcon    :: { RdrName }
 914         : qconid                { $1 }
 915         | '(' qconsym ')'       { $2 }
 916
 917 varop   :: { RdrName }
 918         : varsym                { $1 }
 919         | '`' varid '`'         { $2 }
 920
 921 qvarop :: { RdrName }
 922         : qvarsym               { $1 }
 923         | '`' qvarid '`'        { $2 }
 924
 925 qvaropm :: { RdrName }
 926         : qvarsym_no_minus      { $1 }
 927         | '`' qvarid '`'        { $2 }
 928
 929 conop :: { RdrName }
 930         : consym                { $1 }
 931         | '`' conid '`'         { $2 }
 932
 933 qconop :: { RdrName }
 934         : qconsym               { $1 }
 935         | '`' qconid '`'        { $2 }
 936
 937 -----------------------------------------------------------------------------
 938 -- Any operator
 939
 940 op      :: { RdrName }   -- used in infix decls
 941         : varop                 { $1 }
 942         | conop                 { $1 }
 943
 944 qop     :: { RdrName {-HsExpr-} }   -- used in sections
 945         : qvarop                { $1 }
 946         | qconop                { $1 }
 947
 948 qopm    :: { RdrNameHsExpr }   -- used in sections
 949         : qvaropm               { HsVar $1 }
 950         | qconop                { HsVar $1 }
 951
 952 -----------------------------------------------------------------------------
 953 -- VarIds
 954
 955 qvarid :: { RdrName }
 956         : varid                 { $1 }
 957         | QVARID                { mkQual varName $1 }
 958
 959 varid :: { RdrName }
 960         : varid_no_unsafe       { $1 }
 961         | 'unsafe'              { mkUnqual varName SLIT("unsafe") }
 962
 963 varid_no_unsafe :: { RdrName }
 964         : VARID                 { mkUnqual varName $1 }
 965         | special_id            { mkUnqual varName $1 }
 966         | 'forall'              { mkUnqual varName SLIT("forall") }
 967
 968 tyvar   :: { RdrName }
 969         : VARID                 { mkUnqual tvName $1 }
 970         | special_id            { mkUnqual tvName $1 }
 971         | 'unsafe'              { mkUnqual tvName SLIT("unsafe") }
 972
 973 -- These special_ids are treated as keywords in various places,
 974 -- but as ordinary ids elsewhere.   A special_id collects all thsee
 975 -- except 'unsafe' and 'forall' whose treatment differs depending on context
 976 special_id :: { UserFS }
 977 special_id
 978         : 'as'                  { SLIT("as") }
 979         | 'qualified'           { SLIT("qualified") }
 980         | 'hiding'              { SLIT("hiding") }
 981         | 'export'              { SLIT("export") }
 982         | 'label'               { SLIT("label")  }
 983         | 'dynamic'             { SLIT("dynamic") }
 984         | 'stdcall'             { SLIT("stdcall") }
 985         | 'ccall'               { SLIT("ccall") }
 986
 987 -----------------------------------------------------------------------------
 988 -- ConIds
 989
 990 qconid :: { RdrName }
 991         : conid                 { $1 }
 992         | QCONID                { mkQual dataName $1 }
 993
 994 conid   :: { RdrName }
 995         : CONID                 { mkUnqual dataName $1 }
 996
 997 -----------------------------------------------------------------------------
 998 -- ConSyms
 999
1000 qconsym :: { RdrName }
1001         : consym                { $1 }
1002         | QCONSYM               { mkQual dataName $1 }
1003
1004 consym :: { RdrName }
1005         : CONSYM                { mkUnqual dataName $1 }
1006
1007 -----------------------------------------------------------------------------
1008 -- VarSyms
1009
1010 qvarsym :: { RdrName }
1011         : varsym                { $1 }
1012         | qvarsym1              { $1 }
1013
1014 qvarsym_no_minus :: { RdrName }
1015         : varsym_no_minus       { $1 }
1016         | qvarsym1              { $1 }
1017
1018 qvarsym1 :: { RdrName }
1019 qvarsym1 : QVARSYM              { mkQual varName $1 }
1020
1021 varsym :: { RdrName }
1022         : varsym_no_minus       { $1 }
1023         | '-'                   { mkUnqual varName SLIT("-") }
1024
1025 varsym_no_minus :: { RdrName } -- varsym not including '-'
1026         : VARSYM                { mkUnqual varName $1 }
1027         | special_sym           { mkUnqual varName $1 }
1028
1029
1030 -- See comments with special_id
1031 special_sym :: { UserFS }
1032 special_sym : '!'       { SLIT("!") }
1033             | '.'       { SLIT(".") }
1034
1035 -----------------------------------------------------------------------------
1036 -- Literals
1037
1038 literal :: { HsLit }
1039         : CHAR                  { HsChar       $1 }
1040         | STRING                { HsString     $1 }
1041         | PRIMINTEGER           { HsIntPrim    $1 }
1042         | PRIMCHAR              { HsCharPrim   $1 }
1043         | PRIMSTRING            { HsStringPrim $1 }
1044         | PRIMFLOAT             { HsFloatPrim  $1 }
1045         | PRIMDOUBLE            { HsDoublePrim $1 }
1046         | CLITLIT               { HsLitLit     $1 (error "Parser.y: CLITLIT") }
1047
1048 srcloc :: { SrcLoc }    :       {% getSrcLocP }
1049
1050 -----------------------------------------------------------------------------
1051 -- Layout
1052
1053 close :: { () }
1054         : vccurly               { () } -- context popped in lexer.
1055         | error                 {% popContext }
1056
1057 layout_on         :: { () }     : {% layoutOn True{-strict-} }
1058 layout_on_for_do  :: { () }     : {% layoutOn False }
1059
1060 -----------------------------------------------------------------------------
1061 -- Miscellaneous (mostly renamings)
1062
1063 modid   :: { ModuleName }
1064         : CONID                 { mkSrcModuleFS $1 }
1065
1066 tycon   :: { RdrName }
1067         : CONID                 { mkUnqual tcClsName $1 }
1068
1069 tyconop :: { RdrName }
1070         : CONSYM                { mkUnqual tcClsName $1 }
1071
1072 qtycon :: { RdrName }
1073         : tycon                 { $1 }
1074         | QCONID                { mkQual tcClsName $1 }
1075
1076 qtyconop :: { RdrName }
1077           : tyconop             { $1 }
1078           | QCONSYM             { mkQual tcClsName $1 }
1079
1080 qtycls  :: { RdrName }
1081         : qtycon                { $1 }
1082
1083 commas :: { Int }
1084         : commas ','                    { $1 + 1 }
1085         | ','                           { 2 }
1086
1087 -----------------------------------------------------------------------------
1088
1089 {
1090 happyError :: P a
1091 happyError buf PState{ loc = loc } = PFailed (srcParseErr buf loc)
1092 }