ghc/compiler/parser/Parser.y

   1 {-                                                              -*-haskell-*-
   2 -----------------------------------------------------------------------------
   3 $Id: Parser.y,v 1.110 2002/10/11 14:46:04 simonpj Exp $
   4
   5 Haskell grammar.
   6
   7 Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -----------------------------------------------------------------------------
   9 -}
  10
  11 {
  12 module Parser ( parseModule, parseStmt, parseIdentifier, parseIface ) where
  13
  14 #include "HsVersions.h"
  15
  16 import HsSyn
  17 import HsTypes          ( mkHsTupCon )
  18
  19 import RdrHsSyn
  20 import HscTypes         ( ParsedIface(..), IsBootInterface )
  21 import Lex
  22 import RdrName
  23 import PrelNames        ( mAIN_Name, funTyConName, listTyConName,
  24                           parrTyConName, consDataConName, nilDataConName )
  25 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon )
  26 import ForeignCall      ( Safety(..), CExportSpec(..),
  27                           CCallConv(..), CCallTarget(..), defaultCCallConv,
  28                         )
  29 import OccName          ( UserFS, varName, tcName, dataName, tcClsName, tvName )
  30 import TyCon            ( DataConDetails(..) )
  31 import SrcLoc           ( SrcLoc )
  32 import Module
  33 import CmdLineOpts      ( opt_SccProfilingOn, opt_InPackage )
  34 import Type             ( Kind, mkArrowKind, liftedTypeKind )
  35 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  36                           NewOrData(..), StrictnessMark(..), Activation(..),
  37                           FixitySig(..) )
  38 import Panic
  39
  40 import GLAEXTS
  41 import CStrings         ( CLabelString )
  42 import FastString
  43 import Maybes           ( orElse )
  44 import Outputable
  45
  46 }
  47
  48 {-
  49 -----------------------------------------------------------------------------
  50 Conflicts: 29 shift/reduce, [SDM 19/9/2002]
  51
  52 10 for abiguity in 'if x then y else z + 1'             [State 136]
  53         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  54         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
  55
  56 1 for ambiguity in 'if x then y else z with ?x=3'       [State 136]
  57         (shift parses as 'if x then y else (z with ?x=3)'
  58
  59 1 for ambiguity in 'if x then y else z :: T'            [State 136]
  60         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  61
  62 8 for ambiguity in 'e :: a `b` c'.  Does this mean      [States 160,246]
  63         (e::a) `b` c, or
  64         (e :: (a `b` c))
  65
  66 1 for ambiguity in 'let ?x ...'                         [State 268]
  67         the parser can't tell whether the ?x is the lhs of a normal binding or
  68         an implicit binding.  Fortunately resolving as shift gives it the only
  69         sensible meaning, namely the lhs of an implicit binding.
  70
  71 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 332]
  72         we don't know whether the '[' starts the activation or not: it
  73         might be the start of the declaration with the activation being
  74         empty.  --SDM 1/4/2002
  75
  76 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 394]
  77         since 'forall' is a valid variable name, we don't know whether
  78         to treat a forall on the input as the beginning of a quantifier
  79         or the beginning of the rule itself.  Resolving to shift means
  80         it's always treated as a quantifier, hence the above is disallowed.
  81         This saves explicitly defining a grammar for the rule lhs that
  82         doesn't include 'forall'.
  83
  84 6 for conflicts between `fdecl' and `fdeclDEPRECATED',  [States 384,385]
  85         which are resolved correctly, and moreover,
  86         should go away when `fdeclDEPRECATED' is removed.
  87
  88 -----------------------------------------------------------------------------
  89 -}
  90
  91 %token
  92  '_'            { ITunderscore }                -- Haskell keywords
  93  'as'           { ITas }
  94  'case'         { ITcase }
  95  'class'        { ITclass }
  96  'data'         { ITdata }
  97  'default'      { ITdefault }
  98  'deriving'     { ITderiving }
  99  'do'           { ITdo }
 100  'else'         { ITelse }
 101  'hiding'       { IThiding }
 102  'if'           { ITif }
 103  'import'       { ITimport }
 104  'in'           { ITin }
 105  'infix'        { ITinfix }
 106  'infixl'       { ITinfixl }
 107  'infixr'       { ITinfixr }
 108  'instance'     { ITinstance }
 109  'let'          { ITlet }
 110  'module'       { ITmodule }
 111  'newtype'      { ITnewtype }
 112  'of'           { ITof }
 113  'qualified'    { ITqualified }
 114  'then'         { ITthen }
 115  'type'         { ITtype }
 116  'where'        { ITwhere }
 117  '_scc_'        { ITscc }             -- ToDo: remove
 118
 119  'forall'       { ITforall }                    -- GHC extension keywords
 120  'foreign'      { ITforeign }
 121  'export'       { ITexport }
 122  'label'        { ITlabel }
 123  'dynamic'      { ITdynamic }
 124  'safe'         { ITsafe }
 125  'threadsafe'   { ITthreadsafe }
 126  'unsafe'       { ITunsafe }
 127  'with'         { ITwith }
 128  'mdo'          { ITmdo }
 129  'stdcall'      { ITstdcallconv }
 130  'ccall'        { ITccallconv }
 131  'dotnet'       { ITdotnet }
 132  '_ccall_'      { ITccall (False, False, PlayRisky) }
 133  '_ccall_GC_'   { ITccall (False, False, PlaySafe False) }
 134  '_casm_'       { ITccall (False, True,  PlayRisky) }
 135  '_casm_GC_'    { ITccall (False, True,  PlaySafe False) }
 136
 137  '{-# SPECIALISE'  { ITspecialise_prag }
 138  '{-# SOURCE'      { ITsource_prag }
 139  '{-# INLINE'      { ITinline_prag }
 140  '{-# NOINLINE'    { ITnoinline_prag }
 141  '{-# RULES'       { ITrules_prag }
 142  '{-# SCC'         { ITscc_prag }
 143  '{-# DEPRECATED'  { ITdeprecated_prag }
 144  '#-}'             { ITclose_prag }
 145
 146 {-
 147  '__interface'  { ITinterface }                 -- interface keywords
 148  '__export'     { IT__export }
 149  '__instimport' { ITinstimport }
 150  '__forall'     { IT__forall }
 151  '__letrec'     { ITletrec }
 152  '__coerce'     { ITcoerce }
 153  '__depends'    { ITdepends }
 154  '__inline'     { ITinline }
 155  '__DEFAULT'    { ITdefaultbranch }
 156  '__bot'        { ITbottom }
 157  '__integer'    { ITinteger_lit }
 158  '__float'      { ITfloat_lit }
 159  '__rational'   { ITrational_lit }
 160  '__addr'       { ITaddr_lit }
 161  '__label'      { ITlabel_lit }
 162  '__litlit'     { ITlit_lit }
 163  '__string'     { ITstring_lit }
 164  '__ccall'      { ITccall $$ }
 165  '__scc'        { IT__scc }
 166  '__sccC'       { ITsccAllCafs }
 167
 168  '__A'          { ITarity }
 169  '__P'          { ITspecialise }
 170  '__C'          { ITnocaf }
 171  '__U'          { ITunfold }
 172  '__S'          { ITstrict $$ }
 173  '__M'          { ITcprinfo $$ }
 174 -}
 175
 176  '..'           { ITdotdot }                    -- reserved symbols
 177  ':'            { ITcolon }
 178  '::'           { ITdcolon }
 179  '='            { ITequal }
 180  '\\'           { ITlam }
 181  '|'            { ITvbar }
 182  '<-'           { ITlarrow }
 183  '->'           { ITrarrow }
 184  '@'            { ITat }
 185  '~'            { ITtilde }
 186  '=>'           { ITdarrow }
 187  '-'            { ITminus }
 188  '!'            { ITbang }
 189  '*'            { ITstar }
 190  '.'            { ITdot }
 191
 192  '{'            { ITocurly }                    -- special symbols
 193  '}'            { ITccurly }
 194  '{|'           { ITocurlybar }
 195  '|}'           { ITccurlybar }
 196  vccurly        { ITvccurly } -- virtual close curly (from layout)
 197  '['            { ITobrack }
 198  ']'            { ITcbrack }
 199  '[:'           { ITopabrack }
 200  ':]'           { ITcpabrack }
 201  '('            { IToparen }
 202  ')'            { ITcparen }
 203  '(#'           { IToubxparen }
 204  '#)'           { ITcubxparen }
 205  ';'            { ITsemi }
 206  ','            { ITcomma }
 207  '`'            { ITbackquote }
 208
 209  VARID          { ITvarid    $$ }               -- identifiers
 210  CONID          { ITconid    $$ }
 211  VARSYM         { ITvarsym   $$ }
 212  CONSYM         { ITconsym   $$ }
 213  QVARID         { ITqvarid   $$ }
 214  QCONID         { ITqconid   $$ }
 215  QVARSYM        { ITqvarsym  $$ }
 216  QCONSYM        { ITqconsym  $$ }
 217
 218  IPDUPVARID     { ITdupipvarid   $$ }           -- GHC extension
 219  IPSPLITVARID   { ITsplitipvarid $$ }           -- GHC extension
 220
 221  CHAR           { ITchar     $$ }
 222  STRING         { ITstring   $$ }
 223  INTEGER        { ITinteger  $$ }
 224  RATIONAL       { ITrational $$ }
 225
 226  PRIMCHAR       { ITprimchar   $$ }
 227  PRIMSTRING     { ITprimstring $$ }
 228  PRIMINTEGER    { ITprimint    $$ }
 229  PRIMFLOAT      { ITprimfloat  $$ }
 230  PRIMDOUBLE     { ITprimdouble $$ }
 231  CLITLIT        { ITlitlit     $$ }
 232
 233 -- Template Haskell
 234 '[|'            { ITopenExpQuote  }
 235 '[p|'           { ITopenPatQuote  }
 236 '[t|'           { ITopenTypQuote  }
 237 '[d|'           { ITopenDecQuote  }
 238 '|]'            { ITcloseQuote    }
 239 ID_SPLICE       { ITidEscape $$   }     -- $x
 240 '$('            { ITparenEscape   }     -- $( exp )
 241 REIFY_TYPE      { ITreifyType }
 242 REIFY_DECL      { ITreifyDecl }
 243 REIFY_FIXITY    { ITreifyFixity }
 244
 245 %monad { P } { thenP } { returnP }
 246 %lexer { lexer } { ITeof }
 247 %name parseModule module
 248 %name parseStmt   maybe_stmt
 249 %name parseIdentifier  identifier
 250 %name parseIface iface
 251 %tokentype { Token }
 252 %%
 253
 254 -----------------------------------------------------------------------------
 255 -- Module Header
 256
 257 -- The place for module deprecation is really too restrictive, but if it
 258 -- was allowed at its natural place just before 'module', we get an ugly
 259 -- s/r conflict with the second alternative. Another solution would be the
 260 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 261 -- either, and DEPRECATED is only expected to be used by people who really
 262 -- know what they are doing. :-)
 263
 264 module  :: { RdrNameHsModule }
 265         : srcloc 'module' modid maybemoddeprec maybeexports 'where' body
 266                 { HsModule (mkHomeModule $3) Nothing $5 (fst $7) (snd $7) $4 $1 }
 267         | srcloc body
 268                 { HsModule (mkHomeModule mAIN_Name) Nothing Nothing
 269                            (fst $2) (snd $2) Nothing $1 }
 270
 271 maybemoddeprec :: { Maybe DeprecTxt }
 272         : '{-# DEPRECATED' STRING '#-}'         { Just $2 }
 273         |  {- empty -}                          { Nothing }
 274
 275 body    :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 276         :  '{'            top '}'               { $2 }
 277         |      layout_on  top close             { $2 }
 278
 279 top     :: { ([RdrNameImportDecl], [RdrNameHsDecl]) }
 280         : importdecls                           { (reverse $1,[]) }
 281         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 282         | cvtopdecls                            { ([],$1) }
 283
 284 cvtopdecls :: { [RdrNameHsDecl] }
 285         : topdecls                      { cvTopDecls $1 }
 286
 287 -----------------------------------------------------------------------------
 288 -- Interfaces (.hi-boot files)
 289
 290 iface   :: { ParsedIface }
 291         : 'module' modid 'where' ifacebody
 292           {         ParsedIface {
 293                         pi_mod     = $2,
 294                         pi_pkg     = opt_InPackage,
 295                         pi_vers    = 1,                 -- Module version
 296                         pi_orphan  = False,
 297                         pi_exports = (1,[($2,mkIfaceExports $4)]),
 298                         pi_usages  = [],
 299                         pi_fixity  = [],
 300                         pi_insts   = [],
 301                         pi_decls   = map (\x -> (1,x)) $4,
 302                         pi_rules   = (1,[]),
 303                         pi_deprecs = Nothing
 304                     }
 305            }
 306
 307 ifacebody :: { [RdrNameTyClDecl] }
 308         :  '{'            ifacedecls '}'                { $2 }
 309         |      layout_on  ifacedecls close              { $2 }
 310
 311 ifacedecls :: { [RdrNameTyClDecl] }
 312         : ifacedecl ';' ifacedecls      { $1 : $3 }
 313         | ';' ifacedecls                { $2 }
 314         | ifacedecl                     { [$1] }
 315         | {- empty -}                   { [] }
 316
 317 ifacedecl :: { RdrNameTyClDecl }
 318         : tycl_decl                     { $1 }
 319         | srcloc var '::' sigtype       { IfaceSig $2 $4 [] $1 }
 320
 321 -----------------------------------------------------------------------------
 322 -- The Export List
 323
 324 maybeexports :: { Maybe [RdrNameIE] }
 325         :  '(' exportlist ')'                   { Just $2 }
 326         |  {- empty -}                          { Nothing }
 327
 328 exportlist :: { [RdrNameIE] }
 329         :  exportlist ',' export                { $3 : $1 }
 330         |  exportlist ','                       { $1 }
 331         |  export                               { [$1]  }
 332         |  {- empty -}                          { [] }
 333
 334    -- No longer allow things like [] and (,,,) to be exported
 335    -- They are built in syntax, always available
 336 export  :: { RdrNameIE }
 337         :  qvar                                 { IEVar $1 }
 338         |  oqtycon                              { IEThingAbs $1 }
 339         |  oqtycon '(' '..' ')'                 { IEThingAll $1 }
 340         |  oqtycon '(' ')'                      { IEThingWith $1 [] }
 341         |  oqtycon '(' qcnames ')'              { IEThingWith $1 (reverse $3) }
 342         |  'module' modid                       { IEModuleContents $2 }
 343
 344 qcnames :: { [RdrName] }
 345         :  qcnames ',' qcname                   { $3 : $1 }
 346         |  qcname                               { [$1]  }
 347
 348 qcname  :: { RdrName }  -- Variable or data constructor
 349         :  qvar                                 { $1 }
 350         |  gcon                                 { $1 }
 351
 352 -----------------------------------------------------------------------------
 353 -- Import Declarations
 354
 355 -- import decls can be *empty*, or even just a string of semicolons
 356 -- whereas topdecls must contain at least one topdecl.
 357
 358 importdecls :: { [RdrNameImportDecl] }
 359         : importdecls ';' importdecl            { $3 : $1 }
 360         | importdecls ';'                       { $1 }
 361         | importdecl                            { [ $1 ] }
 362         | {- empty -}                           { [] }
 363
 364 importdecl :: { RdrNameImportDecl }
 365         : 'import' srcloc maybe_src optqualified modid maybeas maybeimpspec
 366                 { ImportDecl $5 $3 $4 $6 $7 $2 }
 367
 368 maybe_src :: { IsBootInterface }
 369         : '{-# SOURCE' '#-}'                    { True }
 370         | {- empty -}                           { False }
 371
 372 optqualified :: { Bool }
 373         : 'qualified'                           { True  }
 374         | {- empty -}                           { False }
 375
 376 maybeas :: { Maybe ModuleName }
 377         : 'as' modid                            { Just $2 }
 378         | {- empty -}                           { Nothing }
 379
 380 maybeimpspec :: { Maybe (Bool, [RdrNameIE]) }
 381         : impspec                               { Just $1 }
 382         | {- empty -}                           { Nothing }
 383
 384 impspec :: { (Bool, [RdrNameIE]) }
 385         :  '(' exportlist ')'                   { (False, reverse $2) }
 386         |  'hiding' '(' exportlist ')'          { (True,  reverse $3) }
 387
 388 -----------------------------------------------------------------------------
 389 -- Fixity Declarations
 390
 391 prec    :: { Int }
 392         : {- empty -}                           { 9 }
 393         | INTEGER                               {% checkPrecP (fromInteger $1) }
 394
 395 infix   :: { FixityDirection }
 396         : 'infix'                               { InfixN  }
 397         | 'infixl'                              { InfixL  }
 398         | 'infixr'                              { InfixR }
 399
 400 ops     :: { [RdrName] }
 401         : ops ',' op                            { $3 : $1 }
 402         | op                                    { [$1] }
 403
 404 -----------------------------------------------------------------------------
 405 -- Top-Level Declarations
 406
 407 topdecls :: { [RdrBinding] }    -- Reversed
 408         : topdecls ';' topdecl          { $3 : $1 }
 409         | topdecls ';'                  { $1 }
 410         | topdecl                       { [$1] }
 411
 412 topdecl :: { RdrBinding }
 413         : tycl_decl                     { RdrHsDecl (TyClD $1) }
 414         | srcloc 'instance' inst_type where
 415                 { let (binds,sigs) = cvMonoBindsAndSigs $4
 416                   in RdrHsDecl (InstD (InstDecl $3 binds sigs Nothing $1)) }
 417         | srcloc 'default' '(' comma_types0 ')'         { RdrHsDecl (DefD (DefaultDecl $4 $1)) }
 418         | 'foreign' fdecl                               { RdrHsDecl $2 }
 419         | '{-# DEPRECATED' deprecations '#-}'           { RdrBindings (reverse $2) }
 420         | '{-# RULES' rules '#-}'                       { RdrBindings (reverse $2) }
 421         | srcloc '$(' exp ')'                           { RdrHsDecl (SpliceD (SpliceDecl $3 $1)) }
 422         | decl                                          { $1 }
 423
 424 tycl_decl :: { RdrNameTyClDecl }
 425         : srcloc 'type' syn_hdr '=' ctype
 426                 -- Note ctype, not sigtype.
 427                 -- We allow an explicit for-all but we don't insert one
 428                 -- in   type Foo a = (b,b)
 429                 -- Instead we just say b is out of scope
 430                 { let (tc,tvs) = $3 in TySynonym tc tvs $5 $1 }
 431
 432
 433         | srcloc 'data' tycl_hdr constrs deriving
 434                 { mkTyData DataType $3 (DataCons (reverse $4)) $5 $1 }
 435
 436         | srcloc 'newtype' tycl_hdr '=' newconstr deriving
 437                 { mkTyData NewType $3 (DataCons [$5]) $6 $1 }
 438
 439         | srcloc 'class' tycl_hdr fds where
 440                 { let
 441                         (binds,sigs) = cvMonoBindsAndSigs $5
 442                   in
 443                   mkClassDecl $3 $4 (map cvClassOpSig sigs) (Just binds) $1 }
 444
 445 syn_hdr :: { (RdrName, [RdrNameHsTyVar]) }      -- We don't retain the syntax of an infix
 446                                                 -- type synonym declaration. Oh well.
 447         : tycon tv_bndrs                { ($1, $2) }
 448         | tv_bndr tyconop tv_bndr       { ($2, [$1,$3]) }
 449
 450 -- tycl_hdr parses the header of a type or class decl,
 451 -- which takes the form
 452 --      T a b
 453 --      Eq a => T a
 454 --      (Eq a, Ord b) => T a b
 455 -- Rather a lot of inlining here, else we get reduce/reduce errors
 456 tycl_hdr :: { (RdrNameContext, RdrName, [RdrNameHsTyVar]) }
 457         : context '=>' type             {% checkTyClHdr $3      `thenP` \ (tc,tvs) ->
 458                                            returnP ($1, tc, tvs) }
 459         | type                          {% checkTyClHdr $1      `thenP` \ (tc,tvs) ->
 460                                            returnP ([], tc, tvs) }
 461
 462 -----------------------------------------------------------------------------
 463 -- Nested declarations
 464
 465 decls   :: { [RdrBinding] }     -- Reversed
 466         : decls ';' decl                { $3 : $1 }
 467         | decls ';'                     { $1 }
 468         | decl                          { [$1] }
 469         | {- empty -}                   { [] }
 470
 471
 472 wherebinds :: { RdrNameHsBinds }
 473         : where                         { cvBinds $1 }
 474
 475 where   :: { [RdrBinding] }     -- Reversed
 476         : 'where' decllist              { $2 }
 477         | {- empty -}                   { [] }
 478
 479 decllist :: { [RdrBinding] }    -- Reversed
 480         : '{'            decls '}'      { $2 }
 481         |     layout_on  decls close    { $2 }
 482
 483 letbinds :: { RdrNameHsExpr -> RdrNameHsExpr }
 484         : decllist                      { HsLet (cvBinds $1) }
 485         | '{'            dbinds '}'     { \e -> HsWith e $2 False{-not with-} }
 486         |     layout_on  dbinds close   { \e -> HsWith e $2 False{-not with-} }
 487
 488
 489
 490 -----------------------------------------------------------------------------
 491 -- Transformation Rules
 492
 493 rules   :: { [RdrBinding] }     -- Reversed
 494         :  rules ';' rule                       { $3 : $1 }
 495         |  rules ';'                            { $1 }
 496         |  rule                                 { [$1] }
 497         |  {- empty -}                          { [] }
 498
 499 rule    :: { RdrBinding }
 500         : STRING activation rule_forall infixexp '=' srcloc exp
 501              { RdrHsDecl (RuleD (HsRule $1 $2 $3 $4 $7 $6)) }
 502
 503 activation :: { Activation }           -- Omitted means AlwaysActive
 504         : {- empty -}                           { AlwaysActive }
 505         | explicit_activation                   { $1 }
 506
 507 inverse_activation :: { Activation }   -- Omitted means NeverActive
 508         : {- empty -}                           { NeverActive }
 509         | explicit_activation                   { $1 }
 510
 511 explicit_activation :: { Activation }  -- In brackets
 512         : '[' INTEGER ']'                       { ActiveAfter  (fromInteger $2) }
 513         | '[' '~' INTEGER ']'                   { ActiveBefore (fromInteger $3) }
 514
 515 rule_forall :: { [RdrNameRuleBndr] }
 516         : 'forall' rule_var_list '.'            { $2 }
 517         | {- empty -}                           { [] }
 518
 519 rule_var_list :: { [RdrNameRuleBndr] }
 520         : rule_var                              { [$1] }
 521         | rule_var rule_var_list                { $1 : $2 }
 522
 523 rule_var :: { RdrNameRuleBndr }
 524         : varid                                 { RuleBndr $1 }
 525         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 526
 527 -----------------------------------------------------------------------------
 528 -- Deprecations (c.f. rules)
 529
 530 deprecations :: { [RdrBinding] }        -- Reversed
 531         : deprecations ';' deprecation          { $3 : $1 }
 532         | deprecations ';'                      { $1 }
 533         | deprecation                           { [$1] }
 534         | {- empty -}                           { [] }
 535
 536 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 537 deprecation :: { RdrBinding }
 538         : srcloc depreclist STRING
 539                 { RdrBindings
 540                         [ RdrHsDecl (DeprecD (Deprecation n $3 $1)) | n <- $2 ] }
 541
 542
 543 -----------------------------------------------------------------------------
 544 -- Foreign import and export declarations
 545
 546 -- for the time being, the following accepts foreign declarations conforming
 547 -- to the FFI Addendum, Version 1.0 as well as pre-standard declarations
 548 --
 549 -- * a flag indicates whether pre-standard declarations have been used and
 550 --   triggers a deprecation warning further down the road
 551 --
 552 -- NB: The first two rules could be combined into one by replacing `safety1'
 553 --     with `safety'.  However, the combined rule conflicts with the
 554 --     DEPRECATED rules.
 555 --
 556 fdecl :: { RdrNameHsDecl }
 557 fdecl : srcloc 'import' callconv safety1 fspec  {% mkImport $3 $4       $5 $1 }
 558       | srcloc 'import' callconv         fspec  {% mkImport $3 (PlaySafe False) $4 $1 }
 559       | srcloc 'export' callconv         fspec  {% mkExport $3          $4 $1 }
 560         -- the following syntax is DEPRECATED
 561       | srcloc fdecl1DEPRECATED                 { ForD ($2 True $1) }
 562       | srcloc fdecl2DEPRECATED                 { $2 $1 }
 563
 564 fdecl1DEPRECATED :: { Bool -> SrcLoc -> ForeignDecl RdrName }
 565 fdecl1DEPRECATED
 566   ----------- DEPRECATED label decls ------------
 567   : 'label' ext_name varid '::' sigtype
 568     { ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 569                                    (CLabel ($2 `orElse` mkExtName $3))) }
 570
 571   ----------- DEPRECATED ccall/stdcall decls ------------
 572   --
 573   -- NB: This business with the case expression below may seem overly
 574   --     complicated, but it is necessary to avoid some conflicts.
 575
 576     -- DEPRECATED variant #1: lack of a calling convention specification
 577     --                        (import)
 578   | 'import' {-no callconv-} ext_name safety varid_no_unsafe '::' sigtype
 579     { let
 580         target = StaticTarget ($2 `orElse` mkExtName $4)
 581       in
 582       ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 583                                    (CFunction target)) }
 584
 585     -- DEPRECATED variant #2: external name consists of two separate strings
 586     --                        (module name and function name) (import)
 587   | 'import' callconv STRING STRING safety varid_no_unsafe '::' sigtype
 588     {% case $2 of
 589          DNCall      -> parseError "Illegal format of .NET foreign import"
 590          CCall cconv -> returnP $
 591            let
 592              imp = CFunction (StaticTarget $4)
 593            in
 594            ForeignImport $6 $8 (CImport cconv $5 nilFS nilFS imp) }
 595
 596     -- DEPRECATED variant #3: `unsafe' after entity
 597   | 'import' callconv STRING 'unsafe' varid_no_unsafe '::' sigtype
 598     {% case $2 of
 599          DNCall      -> parseError "Illegal format of .NET foreign import"
 600          CCall cconv -> returnP $
 601            let
 602              imp = CFunction (StaticTarget $3)
 603            in
 604            ForeignImport $5 $7 (CImport cconv PlayRisky nilFS nilFS imp) }
 605
 606     -- DEPRECATED variant #4: use of the special identifier `dynamic' without
 607     --                        an explicit calling convention (import)
 608   | 'import' {-no callconv-} 'dynamic' safety varid_no_unsafe '::' sigtype
 609     { ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 610                                    (CFunction DynamicTarget)) }
 611
 612     -- DEPRECATED variant #5: use of the special identifier `dynamic' (import)
 613   | 'import' callconv 'dynamic' safety varid_no_unsafe '::' sigtype
 614     {% case $2 of
 615          DNCall      -> parseError "Illegal format of .NET foreign import"
 616          CCall cconv -> returnP $
 617            ForeignImport $5 $7 (CImport cconv $4 nilFS nilFS
 618                                         (CFunction DynamicTarget)) }
 619
 620     -- DEPRECATED variant #6: lack of a calling convention specification
 621     --                        (export)
 622   | 'export' {-no callconv-} ext_name varid '::' sigtype
 623     { ForeignExport $3 $5 (CExport (CExportStatic ($2 `orElse` mkExtName $3)
 624                                    defaultCCallConv)) }
 625
 626     -- DEPRECATED variant #7: external name consists of two separate strings
 627     --                        (module name and function name) (export)
 628   | 'export' callconv STRING STRING varid '::' sigtype
 629     {% case $2 of
 630          DNCall      -> parseError "Illegal format of .NET foreign import"
 631          CCall cconv -> returnP $
 632            ForeignExport $5 $7
 633                          (CExport (CExportStatic $4 cconv)) }
 634
 635     -- DEPRECATED variant #8: use of the special identifier `dynamic' without
 636     --                        an explicit calling convention (export)
 637   | 'export' {-no callconv-} 'dynamic' varid '::' sigtype
 638     { ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 639                                    CWrapper) }
 640
 641     -- DEPRECATED variant #9: use of the special identifier `dynamic' (export)
 642   | 'export' callconv 'dynamic' varid '::' sigtype
 643     {% case $2 of
 644          DNCall      -> parseError "Illegal format of .NET foreign import"
 645          CCall cconv -> returnP $
 646            ForeignImport $4 $6 (CImport cconv (PlaySafe False) nilFS nilFS CWrapper) }
 647
 648   ----------- DEPRECATED .NET decls ------------
 649   -- NB: removed the .NET call declaration, as it is entirely subsumed
 650   --     by the new standard FFI declarations
 651
 652 fdecl2DEPRECATED :: { SrcLoc -> RdrNameHsDecl }
 653 fdecl2DEPRECATED
 654   : 'import' 'dotnet' 'type' ext_name tycon
 655           { \loc -> TyClD (ForeignType $5 $4 DNType loc) }
 656     -- left this one unchanged for the moment as type imports are not
 657     -- covered currently by the FFI standard -=chak
 658
 659
 660 callconv :: { CallConv }
 661           : 'stdcall'                   { CCall  StdCallConv }
 662           | 'ccall'                     { CCall  CCallConv   }
 663           | 'dotnet'                    { DNCall             }
 664
 665 safety :: { Safety }
 666         : 'unsafe'                      { PlayRisky }
 667         | 'safe'                        { PlaySafe False }
 668         | 'threadsafe'                  { PlaySafe True  }
 669         | {- empty -}                   { PlaySafe False }
 670
 671 safety1 :: { Safety }
 672         : 'unsafe'                      { PlayRisky }
 673         | 'safe'                        { PlaySafe  False }
 674         | 'threadsafe'                  { PlaySafe  True }
 675           -- only needed to avoid conflicts with the DEPRECATED rules
 676
 677 fspec :: { (FastString, RdrName, RdrNameHsType) }
 678        : STRING var '::' sigtype      { ($1      , $2, $4) }
 679        |        var '::' sigtype      { (nilFS, $1, $3) }
 680          -- if the entity string is missing, it defaults to the empty string;
 681          -- the meaning of an empty entity string depends on the calling
 682          -- convention
 683
 684 -- DEPRECATED syntax
 685 ext_name :: { Maybe CLabelString }
 686         : STRING                { Just $1 }
 687         | STRING STRING         { Just $2 }     -- Ignore "module name" for now
 688         | {- empty -}           { Nothing }
 689
 690
 691 -----------------------------------------------------------------------------
 692 -- Type signatures
 693
 694 opt_sig :: { Maybe RdrNameHsType }
 695         : {- empty -}                   { Nothing }
 696         | '::' sigtype                  { Just $2 }
 697
 698 opt_asig :: { Maybe RdrNameHsType }
 699         : {- empty -}                   { Nothing }
 700         | '::' atype                    { Just $2 }
 701
 702 sigtypes :: { [RdrNameHsType] }
 703         : sigtype                       { [ $1 ] }
 704         | sigtypes ',' sigtype          { $3 : $1 }
 705
 706 sigtype :: { RdrNameHsType }
 707         : ctype                         { mkHsForAllTy Nothing [] $1 }
 708
 709 sig_vars :: { [RdrName] }
 710          : sig_vars ',' var             { $3 : $1 }
 711          | var                          { [ $1 ] }
 712
 713 -----------------------------------------------------------------------------
 714 -- Types
 715
 716 -- A ctype is a for-all type
 717 ctype   :: { RdrNameHsType }
 718         : 'forall' tv_bndrs '.' ctype   { mkHsForAllTy (Just $2) [] $4 }
 719         | context '=>' type             { mkHsForAllTy Nothing   $1 $3 }
 720         -- A type of form (context => type) is an *implicit* HsForAllTy
 721         | type                          { $1 }
 722
 723 -- We parse a context as a btype so that we don't get reduce/reduce
 724 -- errors in ctype.  The basic problem is that
 725 --      (Eq a, Ord a)
 726 -- looks so much like a tuple type.  We can't tell until we find the =>
 727 context :: { RdrNameContext }
 728         : btype                         {% checkContext $1 }
 729
 730 type :: { RdrNameHsType }
 731         : ipvar '::' gentype            { mkHsIParamTy $1 $3 }
 732         | gentype                       { $1 }
 733
 734 gentype :: { RdrNameHsType }
 735         : btype                         { $1 }
 736         | btype qtyconop gentype        { HsOpTy $1 (HsTyOp $2) $3 }
 737         | btype  '`' tyvar '`' gentype  { HsOpTy $1 (HsTyOp $3) $5 }
 738         | btype '->' gentype            { HsOpTy $1 HsArrow $3 }
 739
 740 btype :: { RdrNameHsType }
 741         : btype atype                   { HsAppTy $1 $2 }
 742         | atype                         { $1 }
 743
 744 atype :: { RdrNameHsType }
 745         : gtycon                        { HsTyVar $1 }
 746         | tyvar                         { HsTyVar $1 }
 747         | '(' type ',' comma_types1 ')' { HsTupleTy (mkHsTupCon tcName Boxed  ($2:$4)) ($2:$4) }
 748         | '(#' comma_types1 '#)'        { HsTupleTy (mkHsTupCon tcName Unboxed     $2) $2      }
 749         | '[' type ']'                  { HsListTy  $2 }
 750         | '[:' type ':]'                { HsPArrTy  $2 }
 751         | '(' ctype ')'                 { HsParTy   $2 }
 752         | '(' ctype '::' kind ')'       { HsKindSig $2 $4 }
 753 -- Generics
 754         | INTEGER                       { HsNumTy $1 }
 755
 756 -- An inst_type is what occurs in the head of an instance decl
 757 --      e.g.  (Foo a, Gaz b) => Wibble a b
 758 -- It's kept as a single type, with a MonoDictTy at the right
 759 -- hand corner, for convenience.
 760 inst_type :: { RdrNameHsType }
 761         : ctype                         {% checkInstType $1 }
 762
 763 comma_types0  :: { [RdrNameHsType] }
 764         : comma_types1                  { $1 }
 765         | {- empty -}                   { [] }
 766
 767 comma_types1    :: { [RdrNameHsType] }
 768         : type                          { [$1] }
 769         | type  ',' comma_types1        { $1 : $3 }
 770
 771 tv_bndrs :: { [RdrNameHsTyVar] }
 772          : tv_bndr tv_bndrs             { $1 : $2 }
 773          | {- empty -}                  { [] }
 774
 775 tv_bndr :: { RdrNameHsTyVar }
 776         : tyvar                         { UserTyVar $1 }
 777         | '(' tyvar '::' kind ')'       { IfaceTyVar $2 $4 }
 778
 779 fds :: { [([RdrName], [RdrName])] }
 780         : {- empty -}                   { [] }
 781         | '|' fds1                      { reverse $2 }
 782
 783 fds1 :: { [([RdrName], [RdrName])] }
 784         : fds1 ',' fd                   { $3 : $1 }
 785         | fd                            { [$1] }
 786
 787 fd :: { ([RdrName], [RdrName]) }
 788         : varids0 '->' varids0          { (reverse $1, reverse $3) }
 789
 790 varids0 :: { [RdrName] }
 791         : {- empty -}                   { [] }
 792         | varids0 tyvar                 { $2 : $1 }
 793
 794 -----------------------------------------------------------------------------
 795 -- Kinds
 796
 797 kind    :: { Kind }
 798         : akind                 { $1 }
 799         | akind '->' kind       { mkArrowKind $1 $3 }
 800
 801 akind   :: { Kind }
 802         : '*'                   { liftedTypeKind }
 803         | '(' kind ')'          { $2 }
 804
 805
 806 -----------------------------------------------------------------------------
 807 -- Datatype declarations
 808
 809 newconstr :: { RdrNameConDecl }
 810         : srcloc conid atype    { ConDecl $2 [] [] (PrefixCon [unbangedType $3]) $1 }
 811         | srcloc conid '{' var '::' ctype '}'
 812                                 { ConDecl $2 [] [] (RecCon [($4, unbangedType $6)]) $1 }
 813
 814 constrs :: { [RdrNameConDecl] }
 815         : {- empty; a GHC extension -}  { [] }
 816         | '=' constrs1                  { $2 }
 817
 818 constrs1 :: { [RdrNameConDecl] }
 819         : constrs1 '|' constr           { $3 : $1 }
 820         | constr                        { [$1] }
 821
 822 constr :: { RdrNameConDecl }
 823         : srcloc forall context '=>' constr_stuff
 824                 { ConDecl (fst $5) $2 $3 (snd $5) $1 }
 825         | srcloc forall constr_stuff
 826                 { ConDecl (fst $3) $2 [] (snd $3) $1 }
 827
 828 forall :: { [RdrNameHsTyVar] }
 829         : 'forall' tv_bndrs '.'         { $2 }
 830         | {- empty -}                   { [] }
 831
 832 constr_stuff :: { (RdrName, RdrNameConDetails) }
 833         : btype                         {% mkPrefixCon $1 [] }
 834         | btype '!' atype satypes       {% mkPrefixCon $1 (BangType MarkedUserStrict $3 : $4) }
 835         | oqtycon '{' '}'               {% mkRecCon $1 [] }
 836         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 }
 837         | sbtype conop sbtype           { ($2, InfixCon $1 $3) }
 838
 839 satypes :: { [RdrNameBangType] }
 840         : atype satypes                 { unbangedType $1 : $2 }
 841         | '!' atype satypes             { BangType MarkedUserStrict $2 : $3 }
 842         | {- empty -}                   { [] }
 843
 844 sbtype :: { RdrNameBangType }
 845         : btype                         { unbangedType $1 }
 846         | '!' atype                     { BangType MarkedUserStrict $2 }
 847
 848 fielddecls :: { [([RdrName],RdrNameBangType)] }
 849         : fielddecl ',' fielddecls      { $1 : $3 }
 850         | fielddecl                     { [$1] }
 851
 852 fielddecl :: { ([RdrName],RdrNameBangType) }
 853         : sig_vars '::' stype           { (reverse $1, $3) }
 854
 855 stype :: { RdrNameBangType }
 856         : ctype                         { unbangedType $1 }
 857         | '!' atype                     { BangType MarkedUserStrict $2 }
 858
 859 deriving :: { Maybe RdrNameContext }
 860         : {- empty -}                   { Nothing }
 861         | 'deriving' context            { Just $2 }
 862              -- Glasgow extension: allow partial
 863              -- applications in derivings
 864
 865 -----------------------------------------------------------------------------
 866 -- Value definitions
 867
 868 {- There's an awkward overlap with a type signature.  Consider
 869         f :: Int -> Int = ...rhs...
 870    Then we can't tell whether it's a type signature or a value
 871    definition with a result signature until we see the '='.
 872    So we have to inline enough to postpone reductions until we know.
 873 -}
 874
 875 {-
 876   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
 877   instead of qvar, we get another shift/reduce-conflict. Consider the
 878   following programs:
 879
 880      { (^^) :: Int->Int ; }          Type signature; only var allowed
 881
 882      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
 883                                      qvar allowed (because of instance decls)
 884
 885   We can't tell whether to reduce var to qvar until after we've read the signatures.
 886 -}
 887
 888 decl    :: { RdrBinding }
 889         : sigdecl                       { $1 }
 890         | infixexp srcloc opt_sig rhs   {% checkValDef $1 $3 $4 $2 }
 891
 892 rhs     :: { RdrNameGRHSs }
 893         : '=' srcloc exp wherebinds     { GRHSs (unguardedRHS $3 $2) $4 placeHolderType }
 894         | gdrhs wherebinds              { GRHSs (reverse $1)         $2 placeHolderType }
 895
 896 gdrhs :: { [RdrNameGRHS] }
 897         : gdrhs gdrh                    { $2 : $1 }
 898         | gdrh                          { [$1] }
 899
 900 gdrh :: { RdrNameGRHS }
 901         : '|' srcloc quals '=' exp      { GRHS (reverse (ResultStmt $5 $2 : $3)) $2 }
 902
 903 sigdecl :: { RdrBinding }
 904         : infixexp srcloc '::' sigtype
 905                                 {% checkValSig $1 $4 $2 }
 906                 -- See the above notes for why we need infixexp here
 907         | var ',' sig_vars srcloc '::' sigtype
 908                                 { mkSigDecls [ Sig n $6 $4 | n <- $1:$3 ] }
 909         | srcloc infix prec ops { mkSigDecls [ FixSig (FixitySig n (Fixity $3 $2) $1)
 910                                              | n <- $4 ] }
 911         | '{-# INLINE'   srcloc activation qvar '#-}'
 912                                 { RdrHsDecl (SigD (InlineSig True  $4 $3 $2)) }
 913         | '{-# NOINLINE' srcloc inverse_activation qvar '#-}'
 914                                 { RdrHsDecl (SigD (InlineSig False $4 $3 $2)) }
 915         | '{-# SPECIALISE' srcloc qvar '::' sigtypes '#-}'
 916                                 { mkSigDecls  [ SpecSig $3 t $2 | t <- $5] }
 917         | '{-# SPECIALISE' srcloc 'instance' inst_type '#-}'
 918                                 { RdrHsDecl (SigD (SpecInstSig $4 $2)) }
 919
 920 -----------------------------------------------------------------------------
 921 -- Expressions
 922
 923 exp   :: { RdrNameHsExpr }
 924         : infixexp '::' sigtype         { ExprWithTySig $1 $3 }
 925         | infixexp 'with' dbinding      { HsWith $1 $3 True{-not a let-} }
 926         | infixexp                      { $1 }
 927
 928 infixexp :: { RdrNameHsExpr }
 929         : exp10                         { $1 }
 930         | infixexp qop exp10            { (OpApp $1 (HsVar $2)
 931                                                 (panic "fixity") $3 )}
 932
 933 exp10 :: { RdrNameHsExpr }
 934         : '\\' srcloc aexp aexps opt_asig '->' srcloc exp
 935                         {% checkPatterns $2 ($3 : reverse $4) `thenP` \ ps ->
 936                            returnP (HsLam (Match ps $5
 937                                             (GRHSs (unguardedRHS $8 $7)
 938                                                    EmptyBinds placeHolderType))) }
 939         | 'let' letbinds 'in' exp               { $2 $4 }
 940         | 'if' srcloc exp 'then' exp 'else' exp { HsIf $3 $5 $7 $2 }
 941         | 'case' srcloc exp 'of' altslist       { HsCase $3 $5 $2 }
 942         | '-' fexp                              { mkHsNegApp $2 }
 943         | srcloc 'do' stmtlist                  {% checkDo $3  `thenP` \ stmts ->
 944                                                    returnP (mkHsDo DoExpr stmts $1) }
 945         | srcloc 'mdo' stmtlist                 {% checkMDo $3  `thenP` \ stmts ->
 946                                                    returnP (mkHsDo MDoExpr stmts $1) }
 947
 948         | '_ccall_'    ccallid aexps0           { HsCCall $2 $3 PlayRisky False placeHolderType }
 949         | '_ccall_GC_' ccallid aexps0           { HsCCall $2 $3 (PlaySafe False) False placeHolderType }
 950         | '_casm_'     CLITLIT aexps0           { HsCCall $2 $3 PlayRisky True  placeHolderType }
 951         | '_casm_GC_'  CLITLIT aexps0           { HsCCall $2 $3 (PlaySafe False) True  placeHolderType }
 952
 953         | scc_annot exp                         { if opt_SccProfilingOn
 954                                                         then HsSCC $1 $2
 955                                                         else HsPar $2 }
 956
 957         | reifyexp                              { HsReify $1 }
 958         | fexp                                  { $1 }
 959
 960 scc_annot :: { FastString }
 961         : '_scc_' STRING                        { $2 }
 962         | '{-# SCC' STRING '#-}'                { $2 }
 963
 964 ccallid :: { FastString }
 965         :  VARID                                { $1 }
 966         |  CONID                                { $1 }
 967
 968 fexp    :: { RdrNameHsExpr }
 969         : fexp aexp                             { (HsApp $1 $2) }
 970         | aexp                                  { $1 }
 971
 972 reifyexp :: { HsReify RdrName }
 973         : REIFY_DECL gtycon                     { Reify ReifyDecl $2 }
 974         | REIFY_DECL qvar                       { Reify ReifyDecl $2 }
 975         | REIFY_TYPE qcname                     { Reify ReifyType $2 }
 976         | REIFY_FIXITY qcname                   { Reify ReifyFixity $2 }
 977
 978 aexps0  :: { [RdrNameHsExpr] }
 979         : aexps                                 { reverse $1 }
 980
 981 aexps   :: { [RdrNameHsExpr] }
 982         : aexps aexp                            { $2 : $1 }
 983         | {- empty -}                           { [] }
 984
 985 aexp    :: { RdrNameHsExpr }
 986         : qvar '@' aexp                 { EAsPat $1 $3 }
 987         | '~' aexp                      { ELazyPat $2 }
 988         | aexp1                         { $1 }
 989
 990 aexp1   :: { RdrNameHsExpr }
 991         : aexp1 '{' fbinds '}'          {% (mkRecConstrOrUpdate $1 (reverse $3)) }
 992         | aexp2                         { $1 }
 993
 994 -- Here was the syntax for type applications that I was planning
 995 -- but there are difficulties (e.g. what order for type args)
 996 -- so it's not enabled yet.
 997         | qcname '{|' gentype '|}'          { (HsApp (HsVar $1) (HsType $3)) }
 998
 999 aexp2   :: { RdrNameHsExpr }
1000         : ipvar                         { HsIPVar $1 }
1001         | qcname                        { HsVar $1 }
1002         | literal                       { HsLit $1 }
1003         | INTEGER                       { HsOverLit (mkHsIntegral   $1) }
1004         | RATIONAL                      { HsOverLit (mkHsFractional $1) }
1005         | '(' exp ')'                   { HsPar $2 }
1006         | '(' exp ',' texps ')'         { ExplicitTuple ($2 : reverse $4) Boxed}
1007         | '(#' texps '#)'               { ExplicitTuple (reverse $2)      Unboxed }
1008         | '[' list ']'                  { $2 }
1009         | '[:' parr ':]'                { $2 }
1010         | '(' infixexp qop ')'          { (SectionL $2 (HsVar $3))  }
1011         | '(' qopm infixexp ')'         { (SectionR $2 $3) }
1012         | '_'                           { EWildPat }
1013
1014         -- MetaHaskell Extension
1015         | srcloc ID_SPLICE              { mkHsSplice (HsVar (mkUnqual varName $2)) $1 }  -- $x
1016         | srcloc '$(' exp ')'           { mkHsSplice $3 $1 }                             -- $( exp )
1017         | srcloc '[|' exp '|]'          { HsBracket (ExpBr $3) $1 }
1018         | srcloc '[t|' ctype '|]'       { HsBracket (TypBr $3) $1 }
1019         | srcloc '[p|' infixexp '|]'    {% checkPattern $1 $3 `thenP` \p ->
1020                                            returnP (HsBracket (PatBr p) $1) }
1021         | srcloc '[d|' cvtopdecls '|]'  { HsBracket (DecBr (mkGroup $3)) $1 }
1022
1023
1024 texps :: { [RdrNameHsExpr] }
1025         : texps ',' exp                 { $3 : $1 }
1026         | exp                           { [$1] }
1027
1028
1029 -----------------------------------------------------------------------------
1030 -- List expressions
1031
1032 -- The rules below are little bit contorted to keep lexps left-recursive while
1033 -- avoiding another shift/reduce-conflict.
1034
1035 list :: { RdrNameHsExpr }
1036         : exp                           { ExplicitList placeHolderType [$1] }
1037         | lexps                         { ExplicitList placeHolderType (reverse $1) }
1038         | exp '..'                      { ArithSeqIn (From $1) }
1039         | exp ',' exp '..'              { ArithSeqIn (FromThen $1 $3) }
1040         | exp '..' exp                  { ArithSeqIn (FromTo $1 $3) }
1041         | exp ',' exp '..' exp          { ArithSeqIn (FromThenTo $1 $3 $5) }
1042         | exp srcloc pquals             {% let { body [qs] = qs;
1043                                                  body  qss = [ParStmt (map reverse qss)] }
1044                                            in
1045                                            returnP ( mkHsDo ListComp
1046                                                             (reverse (ResultStmt $1 $2 : body $3))
1047                                                             $2
1048                                                   )
1049                                         }
1050
1051 lexps :: { [RdrNameHsExpr] }
1052         : lexps ',' exp                 { $3 : $1 }
1053         | exp ',' exp                   { [$3,$1] }
1054
1055 -----------------------------------------------------------------------------
1056 -- List Comprehensions
1057
1058 pquals :: { [[RdrNameStmt]] }
1059         : pquals '|' quals              { $3 : $1 }
1060         | '|' quals                     { [$2] }
1061
1062 quals :: { [RdrNameStmt] }
1063         : quals ',' stmt                { $3 : $1 }
1064         | stmt                          { [$1] }
1065
1066 -----------------------------------------------------------------------------
1067 -- Parallel array expressions
1068
1069 -- The rules below are little bit contorted; see the list case for details.
1070 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1071 -- Moreover, we allow explicit arrays with no element (represented by the nil
1072 -- constructor in the list case).
1073
1074 parr :: { RdrNameHsExpr }
1075         :                               { ExplicitPArr placeHolderType [] }
1076         | exp                           { ExplicitPArr placeHolderType [$1] }
1077         | lexps                         { ExplicitPArr placeHolderType
1078                                                        (reverse $1) }
1079         | exp '..' exp                  { PArrSeqIn (FromTo $1 $3) }
1080         | exp ',' exp '..' exp          { PArrSeqIn (FromThenTo $1 $3 $5) }
1081         | exp srcloc pquals             {% let {
1082                                              body [qs] = qs;
1083                                              body  qss = [ParStmt
1084                                                            (map reverse qss)]}
1085                                            in
1086                                            returnP $
1087                                              mkHsDo PArrComp
1088                                                     (reverse (ResultStmt $1 $2
1089                                                              : body $3))
1090                                                     $2
1091                                         }
1092
1093 -- We are reusing `lexps' and `pquals' from the list case.
1094
1095 -----------------------------------------------------------------------------
1096 -- Case alternatives
1097
1098 altslist :: { [RdrNameMatch] }
1099         : '{'            alts '}'       { reverse $2 }
1100         |     layout_on  alts  close    { reverse $2 }
1101
1102 alts    :: { [RdrNameMatch] }
1103         : alts1                         { $1 }
1104         | ';' alts                      { $2 }
1105
1106 alts1   :: { [RdrNameMatch] }
1107         : alts1 ';' alt                 { $3 : $1 }
1108         | alts1 ';'                     { $1 }
1109         | alt                           { [$1] }
1110
1111 alt     :: { RdrNameMatch }
1112         : srcloc infixexp opt_sig ralt wherebinds
1113                                         {% (checkPattern $1 $2 `thenP` \p ->
1114                                            returnP (Match [p] $3
1115                                                      (GRHSs $4 $5 placeHolderType))  )}
1116
1117 ralt :: { [RdrNameGRHS] }
1118         : '->' srcloc exp               { [GRHS [ResultStmt $3 $2] $2] }
1119         | gdpats                        { reverse $1 }
1120
1121 gdpats :: { [RdrNameGRHS] }
1122         : gdpats gdpat                  { $2 : $1 }
1123         | gdpat                         { [$1] }
1124
1125 gdpat   :: { RdrNameGRHS }
1126         : srcloc '|' quals '->' exp     { GRHS (reverse (ResultStmt $5 $1:$3)) $1}
1127
1128 -----------------------------------------------------------------------------
1129 -- Statement sequences
1130
1131 stmtlist :: { [RdrNameStmt] }
1132         : '{'                   stmts '}'       { $2 }
1133         |     layout_on_for_do  stmts close     { $2 }
1134
1135 --      do { ;; s ; s ; ; s ;; }
1136 -- The last Stmt should be a ResultStmt, but that's hard to enforce
1137 -- here, because we need too much lookahead if we see do { e ; }
1138 -- So we use ExprStmts throughout, and switch the last one over
1139 -- in ParseUtils.checkDo instead
1140 stmts :: { [RdrNameStmt] }
1141         : stmt stmts_help               { $1 : $2 }
1142         | ';' stmts                     { $2 }
1143         | {- empty -}                   { [] }
1144
1145 stmts_help :: { [RdrNameStmt] }
1146         : ';' stmts                     { $2 }
1147         | {- empty -}                   { [] }
1148
1149 -- For typing stmts at the GHCi prompt, where
1150 -- the input may consist of just comments.
1151 maybe_stmt :: { Maybe RdrNameStmt }
1152         : stmt                          { Just $1 }
1153         | {- nothing -}                 { Nothing }
1154
1155 stmt  :: { RdrNameStmt }
1156         : srcloc infixexp '<-' exp      {% checkPattern $1 $2 `thenP` \p ->
1157                                            returnP (BindStmt p $4 $1) }
1158         | srcloc exp                    { ExprStmt $2 placeHolderType $1 }
1159         | srcloc 'let' decllist         { LetStmt (cvBinds $3) }
1160
1161 -----------------------------------------------------------------------------
1162 -- Record Field Update/Construction
1163
1164 fbinds  :: { RdrNameHsRecordBinds }
1165         : fbinds ',' fbind              { $3 : $1 }
1166         | fbinds ','                    { $1 }
1167         | fbind                         { [$1] }
1168         | {- empty -}                   { [] }
1169
1170 fbind   :: { (RdrName, RdrNameHsExpr) }
1171         : qvar '=' exp                  { ($1,$3) }
1172
1173 -----------------------------------------------------------------------------
1174 -- Implicit Parameter Bindings
1175
1176 dbinding :: { [(IPName RdrName, RdrNameHsExpr)] }
1177         : '{' dbinds '}'                { $2 }
1178         | layout_on dbinds close        { $2 }
1179
1180 dbinds  :: { [(IPName RdrName, RdrNameHsExpr)] }
1181         : dbinds ';' dbind              { $3 : $1 }
1182         | dbinds ';'                    { $1 }
1183         | dbind                         { [$1] }
1184 --      | {- empty -}                   { [] }
1185
1186 dbind   :: { (IPName RdrName, RdrNameHsExpr) }
1187 dbind   : ipvar '=' exp                 { ($1, $3) }
1188
1189 -----------------------------------------------------------------------------
1190 -- Variables, Constructors and Operators.
1191
1192 identifier :: { RdrName }
1193         : qvar                          { $1 }
1194         | gcon                          { $1 }
1195         | qop                           { $1 }
1196
1197 depreclist :: { [RdrName] }
1198 depreclist : deprec_var                 { [$1] }
1199            | deprec_var ',' depreclist  { $1 : $3 }
1200
1201 deprec_var :: { RdrName }
1202 deprec_var : var                        { $1 }
1203            | tycon                      { $1 }
1204
1205 gcon    :: { RdrName }  -- Data constructor namespace
1206         : sysdcon               { $1 }
1207         | qcon                  { $1 }
1208 -- the case of '[:' ':]' is part of the production `parr'
1209
1210 sysdcon :: { RdrName }  -- Data constructor namespace
1211         : '(' ')'               { getRdrName unitDataCon }
1212         | '(' commas ')'        { getRdrName (tupleCon Boxed $2) }
1213         | '[' ']'               { nameRdrName nilDataConName }
1214
1215 var     :: { RdrName }
1216         : varid                 { $1 }
1217         | '(' varsym ')'        { $2 }
1218
1219 qvar    :: { RdrName }
1220         : qvarid                { $1 }
1221         | '(' varsym ')'        { $2 }
1222         | '(' qvarsym1 ')'      { $2 }
1223 -- We've inlined qvarsym here so that the decision about
1224 -- whether it's a qvar or a var can be postponed until
1225 -- *after* we see the close paren.
1226
1227 ipvar   :: { IPName RdrName }
1228         : IPDUPVARID            { Dupable (mkUnqual varName $1) }
1229         | IPSPLITVARID          { Linear  (mkUnqual varName $1) }
1230
1231 qcon    :: { RdrName }
1232         : qconid                { $1 }
1233         | '(' qconsym ')'       { $2 }
1234
1235 varop   :: { RdrName }
1236         : varsym                { $1 }
1237         | '`' varid '`'         { $2 }
1238
1239 qvarop :: { RdrName }
1240         : qvarsym               { $1 }
1241         | '`' qvarid '`'        { $2 }
1242
1243 qvaropm :: { RdrName }
1244         : qvarsym_no_minus      { $1 }
1245         | '`' qvarid '`'        { $2 }
1246
1247 conop :: { RdrName }
1248         : consym                { $1 }
1249         | '`' conid '`'         { $2 }
1250
1251 qconop :: { RdrName }
1252         : qconsym               { $1 }
1253         | '`' qconid '`'        { $2 }
1254
1255 -----------------------------------------------------------------------------
1256 -- Type constructors
1257
1258 gtycon  :: { RdrName }  -- A "general" qualified tycon
1259         : oqtycon                       { $1 }
1260         | '(' ')'                       { getRdrName unitTyCon }
1261         | '(' commas ')'                { getRdrName (tupleTyCon Boxed $2) }
1262         | '(' '->' ')'                  { nameRdrName funTyConName }
1263         | '[' ']'                       { nameRdrName listTyConName }
1264         | '[:' ':]'                     { nameRdrName parrTyConName }
1265
1266 oqtycon :: { RdrName }  -- An "ordinary" qualified tycon
1267         : qtycon                        { $1 }
1268         | '(' qtyconsym ')'             { $2 }
1269
1270 qtyconop :: { RdrName } -- Qualified or unqualified
1271         : qtyconsym                     { $1 }
1272         | '`' qtycon '`'                { $2 }
1273
1274 tyconop :: { RdrName }  -- Unqualified
1275         : tyconsym                      { $1 }
1276         | '`' tycon '`'                 { $2 }
1277
1278 qtycon :: { RdrName }   -- Qualified or unqualified
1279         : QCONID                        { mkQual tcClsName $1 }
1280         | tycon                         { $1 }
1281
1282 tycon   :: { RdrName }  -- Unqualified
1283         : CONID                         { mkUnqual tcClsName $1 }
1284
1285 qtyconsym :: { RdrName }
1286         : QCONSYM                       { mkQual tcClsName $1 }
1287         | tyconsym                      { $1 }
1288
1289 tyconsym :: { RdrName }
1290         : CONSYM                        { mkUnqual tcClsName $1 }
1291
1292 -----------------------------------------------------------------------------
1293 -- Any operator
1294
1295 op      :: { RdrName }   -- used in infix decls
1296         : varop                 { $1 }
1297         | conop                 { $1 }
1298
1299 qop     :: { RdrName {-HsExpr-} }   -- used in sections
1300         : qvarop                { $1 }
1301         | qconop                { $1 }
1302
1303 qopm    :: { RdrNameHsExpr }   -- used in sections
1304         : qvaropm               { HsVar $1 }
1305         | qconop                { HsVar $1 }
1306
1307 -----------------------------------------------------------------------------
1308 -- VarIds
1309
1310 qvarid :: { RdrName }
1311         : varid                 { $1 }
1312         | QVARID                { mkQual varName $1 }
1313
1314 varid :: { RdrName }
1315         : varid_no_unsafe       { $1 }
1316         | 'unsafe'              { mkUnqual varName FSLIT("unsafe") }
1317         | 'safe'                { mkUnqual varName FSLIT("safe") }
1318         | 'threadsafe'          { mkUnqual varName FSLIT("threadsafe") }
1319
1320 varid_no_unsafe :: { RdrName }
1321         : VARID                 { mkUnqual varName $1 }
1322         | special_id            { mkUnqual varName $1 }
1323         | 'forall'              { mkUnqual varName FSLIT("forall") }
1324
1325 tyvar   :: { RdrName }
1326         : VARID                 { mkUnqual tvName $1 }
1327         | special_id            { mkUnqual tvName $1 }
1328         | 'unsafe'              { mkUnqual tvName FSLIT("unsafe") }
1329         | 'safe'                { mkUnqual tvName FSLIT("safe") }
1330         | 'threadsafe'          { mkUnqual tvName FSLIT("threadsafe") }
1331
1332 -- These special_ids are treated as keywords in various places,
1333 -- but as ordinary ids elsewhere.   'special_id' collects all these
1334 -- except 'unsafe' and 'forall' whose treatment differs depending on context
1335 special_id :: { UserFS }
1336 special_id
1337         : 'as'                  { FSLIT("as") }
1338         | 'qualified'           { FSLIT("qualified") }
1339         | 'hiding'              { FSLIT("hiding") }
1340         | 'export'              { FSLIT("export") }
1341         | 'label'               { FSLIT("label")  }
1342         | 'dynamic'             { FSLIT("dynamic") }
1343         | 'stdcall'             { FSLIT("stdcall") }
1344         | 'ccall'               { FSLIT("ccall") }
1345
1346 -----------------------------------------------------------------------------
1347 -- Variables
1348
1349 qvarsym :: { RdrName }
1350         : varsym                { $1 }
1351         | qvarsym1              { $1 }
1352
1353 qvarsym_no_minus :: { RdrName }
1354         : varsym_no_minus       { $1 }
1355         | qvarsym1              { $1 }
1356
1357 qvarsym1 :: { RdrName }
1358 qvarsym1 : QVARSYM              { mkQual varName $1 }
1359
1360 varsym :: { RdrName }
1361         : varsym_no_minus       { $1 }
1362         | '-'                   { mkUnqual varName FSLIT("-") }
1363
1364 varsym_no_minus :: { RdrName } -- varsym not including '-'
1365         : VARSYM                { mkUnqual varName $1 }
1366         | special_sym           { mkUnqual varName $1 }
1367
1368
1369 -- See comments with special_id
1370 special_sym :: { UserFS }
1371 special_sym : '!'       { FSLIT("!") }
1372             | '.'       { FSLIT(".") }
1373             | '*'       { FSLIT("*") }
1374
1375 -----------------------------------------------------------------------------
1376 -- Data constructors
1377
1378 qconid :: { RdrName }   -- Qualified or unqualifiedb
1379         : conid                 { $1 }
1380         | QCONID                { mkQual dataName $1 }
1381
1382 conid   :: { RdrName }
1383         : CONID                 { mkUnqual dataName $1 }
1384
1385 qconsym :: { RdrName }  -- Qualified or unqualified
1386         : consym                { $1 }
1387         | QCONSYM               { mkQual dataName $1 }
1388
1389 consym :: { RdrName }
1390         : CONSYM                { mkUnqual dataName $1 }
1391         | ':'                   { nameRdrName consDataConName }
1392         -- ':' means only list cons
1393
1394
1395 -----------------------------------------------------------------------------
1396 -- Literals
1397
1398 literal :: { HsLit }
1399         : CHAR                  { HsChar       $1 }
1400         | STRING                { HsString     $1 }
1401         | PRIMINTEGER           { HsIntPrim    $1 }
1402         | PRIMCHAR              { HsCharPrim   $1 }
1403         | PRIMSTRING            { HsStringPrim $1 }
1404         | PRIMFLOAT             { HsFloatPrim  $1 }
1405         | PRIMDOUBLE            { HsDoublePrim $1 }
1406         | CLITLIT               { HsLitLit     $1 placeHolderType }
1407
1408 srcloc :: { SrcLoc }    :       {% getSrcLocP }
1409
1410 -----------------------------------------------------------------------------
1411 -- Layout
1412
1413 close :: { () }
1414         : vccurly               { () } -- context popped in lexer.
1415         | error                 {% popContext }
1416
1417 layout_on         :: { () }     : {% layoutOn True{-strict-} }
1418 layout_on_for_do  :: { () }     : {% layoutOn False }
1419
1420 -----------------------------------------------------------------------------
1421 -- Miscellaneous (mostly renamings)
1422
1423 modid   :: { ModuleName }
1424         : CONID                 { mkModuleNameFS $1 }
1425         | QCONID                { mkModuleNameFS
1426                                    (mkFastString
1427                                      (unpackFS (fst $1) ++
1428                                         '.':unpackFS (snd $1)))
1429                                 }
1430
1431 commas :: { Int }
1432         : commas ','                    { $1 + 1 }
1433         | ','                           { 2 }
1434
1435 -----------------------------------------------------------------------------
1436
1437 {
1438 happyError :: P a
1439 happyError buf PState{ loc = loc } = PFailed (srcParseErr buf loc)
1440 }