ghc/compiler/parser/Parser.y.pp

   1 --                                                              -*-haskell-*-
   2 -- ---------------------------------------------------------------------------
   3 -- (c) The University of Glasgow 1997-2003
   4 ---
   5 -- The GHC grammar.
   6 --
   7 -- Author(s): Simon Marlow, Sven Panne 1997, 1998, 1999
   8 -- ---------------------------------------------------------------------------
   9
  10 {
  11 module Parser ( parseModule, parseStmt, parseIdentifier, parseType,
  12                 parseHeader ) where
  13
  14 #define INCLUDE #include
  15 INCLUDE "HsVersions.h"
  16
  17 import HsSyn
  18 import RdrHsSyn
  19 import HscTypes         ( IsBootInterface, DeprecTxt )
  20 import Lexer
  21 import RdrName
  22 import TysWiredIn       ( unitTyCon, unitDataCon, tupleTyCon, tupleCon, nilDataCon,
  23                           listTyCon_RDR, parrTyCon_RDR, consDataCon_RDR )
  24 import Type             ( funTyCon )
  25 import ForeignCall      ( Safety(..), CExportSpec(..), CLabelString,
  26                           CCallConv(..), CCallTarget(..), defaultCCallConv
  27                         )
  28 import OccName          ( UserFS, varName, dataName, tcClsName, tvName )
  29 import DataCon          ( DataCon, dataConName )
  30 import SrcLoc           ( Located(..), unLoc, getLoc, noLoc, combineSrcSpans,
  31                           SrcSpan, combineLocs, srcLocFile,
  32                           mkSrcLoc, mkSrcSpan )
  33 import Module
  34 import StaticFlags      ( opt_SccProfilingOn )
  35 import Type             ( Kind, mkArrowKind, liftedTypeKind )
  36 import BasicTypes       ( Boxity(..), Fixity(..), FixityDirection(..), IPName(..),
  37                           Activation(..), InlineSpec(..), defaultInlineSpec )
  38 import OrdList
  39 import Panic
  40
  41 import FastString
  42 import Maybes           ( orElse )
  43 import Outputable
  44 import GLAEXTS
  45 }
  46
  47 {-
  48 -----------------------------------------------------------------------------
  49 Conflicts: 36 shift/reduce (1.25)
  50
  51 10 for abiguity in 'if x then y else z + 1'             [State 178]
  52         (shift parses as 'if x then y else (z + 1)', as per longest-parse rule)
  53         10 because op might be: : - ! * . `x` VARSYM CONSYM QVARSYM QCONSYM
  54
  55 1 for ambiguity in 'if x then y else z :: T'            [State 178]
  56         (shift parses as 'if x then y else (z :: T)', as per longest-parse rule)
  57
  58 4 for ambiguity in 'if x then y else z -< e'            [State 178]
  59         (shift parses as 'if x then y else (z -< T)', as per longest-parse rule)
  60         There are four such operators: -<, >-, -<<, >>-
  61
  62
  63 2 for ambiguity in 'case v of { x :: T -> T ... } '     [States 11, 253]
  64         Which of these two is intended?
  65           case v of
  66             (x::T) -> T         -- Rhs is T
  67     or
  68           case v of
  69             (x::T -> T) -> ..   -- Rhs is ...
  70
  71 10 for ambiguity in 'e :: a `b` c'.  Does this mean     [States 11, 253]
  72         (e::a) `b` c, or
  73         (e :: (a `b` c))
  74     As well as `b` we can have !, VARSYM, QCONSYM, and CONSYM, hence 5 cases
  75     Same duplication between states 11 and 253 as the previous case
  76
  77 1 for ambiguity in 'let ?x ...'                         [State 329]
  78         the parser can't tell whether the ?x is the lhs of a normal binding or
  79         an implicit binding.  Fortunately resolving as shift gives it the only
  80         sensible meaning, namely the lhs of an implicit binding.
  81
  82 1 for ambiguity in '{-# RULES "name" [ ... #-}          [State 382]
  83         we don't know whether the '[' starts the activation or not: it
  84         might be the start of the declaration with the activation being
  85         empty.  --SDM 1/4/2002
  86
  87 6 for conflicts between `fdecl' and `fdeclDEPRECATED',  [States 393,394]
  88         which are resolved correctly, and moreover,
  89         should go away when `fdeclDEPRECATED' is removed.
  90
  91 1 for ambiguity in '{-# RULES "name" forall = ... #-}'  [State 474]
  92         since 'forall' is a valid variable name, we don't know whether
  93         to treat a forall on the input as the beginning of a quantifier
  94         or the beginning of the rule itself.  Resolving to shift means
  95         it's always treated as a quantifier, hence the above is disallowed.
  96         This saves explicitly defining a grammar for the rule lhs that
  97         doesn't include 'forall'.
  98
  99 -- ---------------------------------------------------------------------------
 100 -- Adding location info
 101
 102 This is done in a stylised way using the three macros below, L0, L1
 103 and LL.  Each of these macros can be thought of as having type
 104
 105    L0, L1, LL :: a -> Located a
 106
 107 They each add a SrcSpan to their argument.
 108
 109    L0   adds 'noSrcSpan', used for empty productions
 110
 111    L1   for a production with a single token on the lhs.  Grabs the SrcSpan
 112         from that token.
 113
 114    LL   for a production with >1 token on the lhs.  Makes up a SrcSpan from
 115         the first and last tokens.
 116
 117 These suffice for the majority of cases.  However, we must be
 118 especially careful with empty productions: LL won't work if the first
 119 or last token on the lhs can represent an empty span.  In these cases,
 120 we have to calculate the span using more of the tokens from the lhs, eg.
 121
 122         | 'newtype' tycl_hdr '=' newconstr deriving
 123                 { L (comb3 $1 $4 $5)
 124                     (mkTyData NewType (unLoc $2) [$4] (unLoc $5)) }
 125
 126 We provide comb3 and comb4 functions which are useful in such cases.
 127
 128 Be careful: there's no checking that you actually got this right, the
 129 only symptom will be that the SrcSpans of your syntax will be
 130 incorrect.
 131
 132 /*
 133  * We must expand these macros *before* running Happy, which is why this file is
 134  * Parser.y.pp rather than just Parser.y - we run the C pre-processor first.
 135  */
 136 #define L0   L noSrcSpan
 137 #define L1   sL (getLoc $1)
 138 #define LL   sL (comb2 $1 $>)
 139
 140 -- -----------------------------------------------------------------------------
 141
 142 -}
 143
 144 %token
 145  '_'            { L _ ITunderscore }            -- Haskell keywords
 146  'as'           { L _ ITas }
 147  'case'         { L _ ITcase }
 148  'class'        { L _ ITclass }
 149  'data'         { L _ ITdata }
 150  'default'      { L _ ITdefault }
 151  'deriving'     { L _ ITderiving }
 152  'do'           { L _ ITdo }
 153  'else'         { L _ ITelse }
 154  'hiding'       { L _ IThiding }
 155  'if'           { L _ ITif }
 156  'import'       { L _ ITimport }
 157  'in'           { L _ ITin }
 158  'infix'        { L _ ITinfix }
 159  'infixl'       { L _ ITinfixl }
 160  'infixr'       { L _ ITinfixr }
 161  'instance'     { L _ ITinstance }
 162  'let'          { L _ ITlet }
 163  'module'       { L _ ITmodule }
 164  'newtype'      { L _ ITnewtype }
 165  'of'           { L _ ITof }
 166  'qualified'    { L _ ITqualified }
 167  'then'         { L _ ITthen }
 168  'type'         { L _ ITtype }
 169  'where'        { L _ ITwhere }
 170  '_scc_'        { L _ ITscc }         -- ToDo: remove
 171
 172  'forall'       { L _ ITforall }                        -- GHC extension keywords
 173  'foreign'      { L _ ITforeign }
 174  'export'       { L _ ITexport }
 175  'label'        { L _ ITlabel }
 176  'dynamic'      { L _ ITdynamic }
 177  'safe'         { L _ ITsafe }
 178  'threadsafe'   { L _ ITthreadsafe }
 179  'unsafe'       { L _ ITunsafe }
 180  'mdo'          { L _ ITmdo }
 181  'stdcall'      { L _ ITstdcallconv }
 182  'ccall'        { L _ ITccallconv }
 183  'dotnet'       { L _ ITdotnet }
 184  'proc'         { L _ ITproc }          -- for arrow notation extension
 185  'rec'          { L _ ITrec }           -- for arrow notation extension
 186
 187  '{-# INLINE'             { L _ (ITinline_prag _) }
 188  '{-# SPECIALISE'         { L _ ITspec_prag }
 189  '{-# SPECIALISE_INLINE'  { L _ (ITspec_inline_prag _) }
 190  '{-# SOURCE'      { L _ ITsource_prag }
 191  '{-# RULES'       { L _ ITrules_prag }
 192  '{-# CORE'        { L _ ITcore_prag }              -- hdaume: annotated core
 193  '{-# SCC'         { L _ ITscc_prag }
 194  '{-# DEPRECATED'  { L _ ITdeprecated_prag }
 195  '{-# UNPACK'      { L _ ITunpack_prag }
 196  '#-}'             { L _ ITclose_prag }
 197
 198  '..'           { L _ ITdotdot }                        -- reserved symbols
 199  ':'            { L _ ITcolon }
 200  '::'           { L _ ITdcolon }
 201  '='            { L _ ITequal }
 202  '\\'           { L _ ITlam }
 203  '|'            { L _ ITvbar }
 204  '<-'           { L _ ITlarrow }
 205  '->'           { L _ ITrarrow }
 206  '@'            { L _ ITat }
 207  '~'            { L _ ITtilde }
 208  '=>'           { L _ ITdarrow }
 209  '-'            { L _ ITminus }
 210  '!'            { L _ ITbang }
 211  '*'            { L _ ITstar }
 212  '-<'           { L _ ITlarrowtail }            -- for arrow notation
 213  '>-'           { L _ ITrarrowtail }            -- for arrow notation
 214  '-<<'          { L _ ITLarrowtail }            -- for arrow notation
 215  '>>-'          { L _ ITRarrowtail }            -- for arrow notation
 216  '.'            { L _ ITdot }
 217
 218  '{'            { L _ ITocurly }                        -- special symbols
 219  '}'            { L _ ITccurly }
 220  '{|'           { L _ ITocurlybar }
 221  '|}'           { L _ ITccurlybar }
 222  vocurly        { L _ ITvocurly } -- virtual open curly (from layout)
 223  vccurly        { L _ ITvccurly } -- virtual close curly (from layout)
 224  '['            { L _ ITobrack }
 225  ']'            { L _ ITcbrack }
 226  '[:'           { L _ ITopabrack }
 227  ':]'           { L _ ITcpabrack }
 228  '('            { L _ IToparen }
 229  ')'            { L _ ITcparen }
 230  '(#'           { L _ IToubxparen }
 231  '#)'           { L _ ITcubxparen }
 232  '(|'           { L _ IToparenbar }
 233  '|)'           { L _ ITcparenbar }
 234  ';'            { L _ ITsemi }
 235  ','            { L _ ITcomma }
 236  '`'            { L _ ITbackquote }
 237
 238  VARID          { L _ (ITvarid    _) }          -- identifiers
 239  CONID          { L _ (ITconid    _) }
 240  VARSYM         { L _ (ITvarsym   _) }
 241  CONSYM         { L _ (ITconsym   _) }
 242  QVARID         { L _ (ITqvarid   _) }
 243  QCONID         { L _ (ITqconid   _) }
 244  QVARSYM        { L _ (ITqvarsym  _) }
 245  QCONSYM        { L _ (ITqconsym  _) }
 246
 247  IPDUPVARID     { L _ (ITdupipvarid   _) }              -- GHC extension
 248  IPSPLITVARID   { L _ (ITsplitipvarid _) }              -- GHC extension
 249
 250  CHAR           { L _ (ITchar     _) }
 251  STRING         { L _ (ITstring   _) }
 252  INTEGER        { L _ (ITinteger  _) }
 253  RATIONAL       { L _ (ITrational _) }
 254
 255  PRIMCHAR       { L _ (ITprimchar   _) }
 256  PRIMSTRING     { L _ (ITprimstring _) }
 257  PRIMINTEGER    { L _ (ITprimint    _) }
 258  PRIMFLOAT      { L _ (ITprimfloat  _) }
 259  PRIMDOUBLE     { L _ (ITprimdouble _) }
 260
 261 -- Template Haskell
 262 '[|'            { L _ ITopenExpQuote  }
 263 '[p|'           { L _ ITopenPatQuote  }
 264 '[t|'           { L _ ITopenTypQuote  }
 265 '[d|'           { L _ ITopenDecQuote  }
 266 '|]'            { L _ ITcloseQuote    }
 267 TH_ID_SPLICE    { L _ (ITidEscape _)  }     -- $x
 268 '$('            { L _ ITparenEscape   }     -- $( exp )
 269 TH_VAR_QUOTE    { L _ ITvarQuote      }     -- 'x
 270 TH_TY_QUOTE     { L _ ITtyQuote       }      -- ''T
 271
 272 %monad { P } { >>= } { return }
 273 %lexer { lexer } { L _ ITeof }
 274 %name parseModule module
 275 %name parseStmt   maybe_stmt
 276 %name parseIdentifier  identifier
 277 %name parseType ctype
 278 %partial parseHeader header
 279 %tokentype { Located Token }
 280 %%
 281
 282 -----------------------------------------------------------------------------
 283 -- Identifiers; one of the entry points
 284 identifier :: { Located RdrName }
 285         : qvar                          { $1 }
 286         | qcon                          { $1 }
 287         | qvarop                        { $1 }
 288         | qconop                        { $1 }
 289
 290 -----------------------------------------------------------------------------
 291 -- Module Header
 292
 293 -- The place for module deprecation is really too restrictive, but if it
 294 -- was allowed at its natural place just before 'module', we get an ugly
 295 -- s/r conflict with the second alternative. Another solution would be the
 296 -- introduction of a new pragma DEPRECATED_MODULE, but this is not very nice,
 297 -- either, and DEPRECATED is only expected to be used by people who really
 298 -- know what they are doing. :-)
 299
 300 module  :: { Located (HsModule RdrName) }
 301         : 'module' modid maybemoddeprec maybeexports 'where' body
 302                 {% fileSrcSpan >>= \ loc ->
 303                    return (L loc (HsModule (Just $2) $4 (fst $6) (snd $6) $3)) }
 304         | missing_module_keyword top close
 305                 {% fileSrcSpan >>= \ loc ->
 306                    return (L loc (HsModule Nothing Nothing
 307                                 (fst $2) (snd $2) Nothing)) }
 308
 309 missing_module_keyword :: { () }
 310         : {- empty -}                           {% pushCurrentContext }
 311
 312 maybemoddeprec :: { Maybe DeprecTxt }
 313         : '{-# DEPRECATED' STRING '#-}'         { Just (getSTRING $2) }
 314         |  {- empty -}                          { Nothing }
 315
 316 body    :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 317         :  '{'            top '}'               { $2 }
 318         |      vocurly    top close             { $2 }
 319
 320 top     :: { ([LImportDecl RdrName], [LHsDecl RdrName]) }
 321         : importdecls                           { (reverse $1,[]) }
 322         | importdecls ';' cvtopdecls            { (reverse $1,$3) }
 323         | cvtopdecls                            { ([],$1) }
 324
 325 cvtopdecls :: { [LHsDecl RdrName] }
 326         : topdecls                              { cvTopDecls $1 }
 327
 328 -----------------------------------------------------------------------------
 329 -- Module declaration & imports only
 330
 331 header  :: { Located (HsModule RdrName) }
 332         : 'module' modid maybemoddeprec maybeexports 'where' header_body
 333                 {% fileSrcSpan >>= \ loc ->
 334                    return (L loc (HsModule (Just $2) $4 $6 [] $3)) }
 335         | missing_module_keyword importdecls
 336                 {% fileSrcSpan >>= \ loc ->
 337                    return (L loc (HsModule Nothing Nothing $2 [] Nothing)) }
 338
 339 header_body :: { [LImportDecl RdrName] }
 340         :  '{'            importdecls           { $2 }
 341         |      vocurly    importdecls           { $2 }
 342
 343 -----------------------------------------------------------------------------
 344 -- The Export List
 345
 346 maybeexports :: { Maybe [LIE RdrName] }
 347         :  '(' exportlist ')'                   { Just $2 }
 348         |  {- empty -}                          { Nothing }
 349
 350 exportlist :: { [LIE RdrName] }
 351         :  exportlist ',' export                { $3 : $1 }
 352         |  exportlist ','                       { $1 }
 353         |  export                               { [$1]  }
 354         |  {- empty -}                          { [] }
 355
 356    -- No longer allow things like [] and (,,,) to be exported
 357    -- They are built in syntax, always available
 358 export  :: { LIE RdrName }
 359         :  qvar                         { L1 (IEVar (unLoc $1)) }
 360         |  oqtycon                      { L1 (IEThingAbs (unLoc $1)) }
 361         |  oqtycon '(' '..' ')'         { LL (IEThingAll (unLoc $1)) }
 362         |  oqtycon '(' ')'              { LL (IEThingWith (unLoc $1) []) }
 363         |  oqtycon '(' qcnames ')'      { LL (IEThingWith (unLoc $1) (reverse $3)) }
 364         |  'module' modid               { LL (IEModuleContents (unLoc $2)) }
 365
 366 qcnames :: { [RdrName] }
 367         :  qcnames ',' qcname                   { unLoc $3 : $1 }
 368         |  qcname                               { [unLoc $1]  }
 369
 370 qcname  :: { Located RdrName }  -- Variable or data constructor
 371         :  qvar                                 { $1 }
 372         |  qcon                                 { $1 }
 373
 374 -----------------------------------------------------------------------------
 375 -- Import Declarations
 376
 377 -- import decls can be *empty*, or even just a string of semicolons
 378 -- whereas topdecls must contain at least one topdecl.
 379
 380 importdecls :: { [LImportDecl RdrName] }
 381         : importdecls ';' importdecl            { $3 : $1 }
 382         | importdecls ';'                       { $1 }
 383         | importdecl                            { [ $1 ] }
 384         | {- empty -}                           { [] }
 385
 386 importdecl :: { LImportDecl RdrName }
 387         : 'import' maybe_src optqualified modid maybeas maybeimpspec
 388                 { L (comb4 $1 $4 $5 $6) (ImportDecl $4 $2 $3 (unLoc $5) (unLoc $6)) }
 389
 390 maybe_src :: { IsBootInterface }
 391         : '{-# SOURCE' '#-}'                    { True }
 392         | {- empty -}                           { False }
 393
 394 optqualified :: { Bool }
 395         : 'qualified'                           { True  }
 396         | {- empty -}                           { False }
 397
 398 maybeas :: { Located (Maybe Module) }
 399         : 'as' modid                            { LL (Just (unLoc $2)) }
 400         | {- empty -}                           { noLoc Nothing }
 401
 402 maybeimpspec :: { Located (Maybe (Bool, [LIE RdrName])) }
 403         : impspec                               { L1 (Just (unLoc $1)) }
 404         | {- empty -}                           { noLoc Nothing }
 405
 406 impspec :: { Located (Bool, [LIE RdrName]) }
 407         :  '(' exportlist ')'                   { LL (False, reverse $2) }
 408         |  'hiding' '(' exportlist ')'          { LL (True,  reverse $3) }
 409
 410 -----------------------------------------------------------------------------
 411 -- Fixity Declarations
 412
 413 prec    :: { Int }
 414         : {- empty -}           { 9 }
 415         | INTEGER               {% checkPrecP (L1 (fromInteger (getINTEGER $1))) }
 416
 417 infix   :: { Located FixityDirection }
 418         : 'infix'                               { L1 InfixN  }
 419         | 'infixl'                              { L1 InfixL  }
 420         | 'infixr'                              { L1 InfixR }
 421
 422 ops     :: { Located [Located RdrName] }
 423         : ops ',' op                            { LL ($3 : unLoc $1) }
 424         | op                                    { L1 [$1] }
 425
 426 -----------------------------------------------------------------------------
 427 -- Top-Level Declarations
 428
 429 topdecls :: { OrdList (LHsDecl RdrName) }       -- Reversed
 430         : topdecls ';' topdecl          { $1 `appOL` $3 }
 431         | topdecls ';'                  { $1 }
 432         | topdecl                       { $1 }
 433
 434 topdecl :: { OrdList (LHsDecl RdrName) }
 435         : tycl_decl                     { unitOL (L1 (TyClD (unLoc $1))) }
 436         | 'instance' inst_type where
 437                 { let (binds,sigs) = cvBindsAndSigs (unLoc $3)
 438                   in unitOL (L (comb3 $1 $2 $3) (InstD (InstDecl $2 binds sigs))) }
 439         | 'default' '(' comma_types0 ')'        { unitOL (LL $ DefD (DefaultDecl $3)) }
 440         | 'foreign' fdecl                       { unitOL (LL (unLoc $2)) }
 441         | '{-# DEPRECATED' deprecations '#-}'   { $2 }
 442         | '{-# RULES' rules '#-}'               { $2 }
 443         | '$(' exp ')'                          { unitOL (LL $ SpliceD (SpliceDecl $2)) }
 444         | decl                                  { unLoc $1 }
 445
 446 tycl_decl :: { LTyClDecl RdrName }
 447         : 'type' type '=' ctype
 448                 -- Note type on the left of the '='; this allows
 449                 -- infix type constructors to be declared
 450                 --
 451                 -- Note ctype, not sigtype, on the right
 452                 -- We allow an explicit for-all but we don't insert one
 453                 -- in   type Foo a = (b,b)
 454                 -- Instead we just say b is out of scope
 455                 {% do { (tc,tvs) <- checkSynHdr $2
 456                       ; return (LL (TySynonym tc tvs $4)) } }
 457
 458         | 'data' tycl_hdr constrs deriving
 459                 { L (comb4 $1 $2 $3 $4) -- We need the location on tycl_hdr
 460                                         -- in case constrs and deriving are both empty
 461                     (mkTyData DataType $2 Nothing (reverse (unLoc $3)) (unLoc $4)) }
 462
 463         | 'data' tycl_hdr opt_kind_sig
 464                  'where' gadt_constrlist
 465                  deriving
 466                 { L (comb4 $1 $2 $4 $5)
 467                     (mkTyData DataType $2 $3 (reverse (unLoc $5)) (unLoc $6)) }
 468
 469         | 'newtype' tycl_hdr '=' newconstr deriving
 470                 { L (comb3 $1 $4 $5)
 471                     (mkTyData NewType $2 Nothing [$4] (unLoc $5)) }
 472
 473         | 'class' tycl_hdr fds where
 474                 { let
 475                         (binds,sigs) = cvBindsAndSigs (unLoc $4)
 476                   in
 477                   L (comb4 $1 $2 $3 $4) (mkClassDecl (unLoc $2) (unLoc $3) sigs
 478                                           binds) }
 479
 480 opt_kind_sig :: { Maybe Kind }
 481         :                               { Nothing }
 482         | '::' kind                     { Just $2 }
 483
 484 -- tycl_hdr parses the header of a type or class decl,
 485 -- which takes the form
 486 --      T a b
 487 --      Eq a => T a
 488 --      (Eq a, Ord b) => T a b
 489 -- Rather a lot of inlining here, else we get reduce/reduce errors
 490 tycl_hdr :: { Located (LHsContext RdrName, Located RdrName, [LHsTyVarBndr RdrName]) }
 491         : context '=>' type             {% checkTyClHdr $1         $3 >>= return.LL }
 492         | type                          {% checkTyClHdr (noLoc []) $1 >>= return.L1 }
 493
 494 -----------------------------------------------------------------------------
 495 -- Nested declarations
 496
 497 decls   :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 498         : decls ';' decl                { LL (unLoc $1 `appOL` unLoc $3) }
 499         | decls ';'                     { LL (unLoc $1) }
 500         | decl                          { $1 }
 501         | {- empty -}                   { noLoc nilOL }
 502
 503
 504 decllist :: { Located (OrdList (LHsDecl RdrName)) }     -- Reversed
 505         : '{'            decls '}'      { LL (unLoc $2) }
 506         |     vocurly    decls close    { $2 }
 507
 508 where   :: { Located (OrdList (LHsDecl RdrName)) }      -- Reversed
 509                                 -- No implicit parameters
 510         : 'where' decllist              { LL (unLoc $2) }
 511         | {- empty -}                   { noLoc nilOL }
 512
 513 binds   ::  { Located (HsLocalBinds RdrName) }          -- May have implicit parameters
 514         : decllist                      { L1 (HsValBinds (cvBindGroup (unLoc $1))) }
 515         | '{'            dbinds '}'     { LL (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 516         |     vocurly    dbinds close   { L (getLoc $2) (HsIPBinds (IPBinds (unLoc $2) emptyLHsBinds)) }
 517
 518 wherebinds :: { Located (HsLocalBinds RdrName) }        -- May have implicit parameters
 519         : 'where' binds                 { LL (unLoc $2) }
 520         | {- empty -}                   { noLoc emptyLocalBinds }
 521
 522
 523 -----------------------------------------------------------------------------
 524 -- Transformation Rules
 525
 526 rules   :: { OrdList (LHsDecl RdrName) }        -- Reversed
 527         :  rules ';' rule                       { $1 `snocOL` $3 }
 528         |  rules ';'                            { $1 }
 529         |  rule                                 { unitOL $1 }
 530         |  {- empty -}                          { nilOL }
 531
 532 rule    :: { LHsDecl RdrName }
 533         : STRING activation rule_forall infixexp '=' exp
 534              { LL $ RuleD (HsRule (getSTRING $1) $2 $3 $4 $6) }
 535
 536 activation :: { Activation }           -- Omitted means AlwaysActive
 537         : {- empty -}                           { AlwaysActive }
 538         | explicit_activation                   { $1 }
 539
 540 explicit_activation :: { Activation }  -- In brackets
 541         : '[' INTEGER ']'               { ActiveAfter  (fromInteger (getINTEGER $2)) }
 542         | '[' '~' INTEGER ']'           { ActiveBefore (fromInteger (getINTEGER $3)) }
 543
 544 rule_forall :: { [RuleBndr RdrName] }
 545         : 'forall' rule_var_list '.'            { $2 }
 546         | {- empty -}                           { [] }
 547
 548 rule_var_list :: { [RuleBndr RdrName] }
 549         : rule_var                              { [$1] }
 550         | rule_var rule_var_list                { $1 : $2 }
 551
 552 rule_var :: { RuleBndr RdrName }
 553         : varid                                 { RuleBndr $1 }
 554         | '(' varid '::' ctype ')'              { RuleBndrSig $2 $4 }
 555
 556 -----------------------------------------------------------------------------
 557 -- Deprecations (c.f. rules)
 558
 559 deprecations :: { OrdList (LHsDecl RdrName) }   -- Reversed
 560         : deprecations ';' deprecation          { $1 `appOL` $3 }
 561         | deprecations ';'                      { $1 }
 562         | deprecation                           { $1 }
 563         | {- empty -}                           { nilOL }
 564
 565 -- SUP: TEMPORARY HACK, not checking for `module Foo'
 566 deprecation :: { OrdList (LHsDecl RdrName) }
 567         : depreclist STRING
 568                 { toOL [ LL $ DeprecD (Deprecation n (getSTRING $2))
 569                        | n <- unLoc $1 ] }
 570
 571
 572 -----------------------------------------------------------------------------
 573 -- Foreign import and export declarations
 574
 575 -- for the time being, the following accepts foreign declarations conforming
 576 -- to the FFI Addendum, Version 1.0 as well as pre-standard declarations
 577 --
 578 -- * a flag indicates whether pre-standard declarations have been used and
 579 --   triggers a deprecation warning further down the road
 580 --
 581 -- NB: The first two rules could be combined into one by replacing `safety1'
 582 --     with `safety'.  However, the combined rule conflicts with the
 583 --     DEPRECATED rules.
 584 --
 585 fdecl :: { LHsDecl RdrName }
 586 fdecl : 'import' callconv safety1 fspec
 587                 {% mkImport $2 $3 (unLoc $4) >>= return.LL }
 588       | 'import' callconv         fspec
 589                 {% do { d <- mkImport $2 (PlaySafe False) (unLoc $3);
 590                         return (LL d) } }
 591       | 'export' callconv fspec
 592                 {% mkExport $2 (unLoc $3) >>= return.LL }
 593         -- the following syntax is DEPRECATED
 594       | fdecl1DEPRECATED                        { L1 (ForD (unLoc $1)) }
 595       | fdecl2DEPRECATED                        { L1 (unLoc $1) }
 596
 597 fdecl1DEPRECATED :: { LForeignDecl RdrName }
 598 fdecl1DEPRECATED
 599   ----------- DEPRECATED label decls ------------
 600   : 'label' ext_name varid '::' sigtype
 601     { LL $ ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 602                                    (CLabel ($2 `orElse` mkExtName (unLoc $3)))) True }
 603
 604   ----------- DEPRECATED ccall/stdcall decls ------------
 605   --
 606   -- NB: This business with the case expression below may seem overly
 607   --     complicated, but it is necessary to avoid some conflicts.
 608
 609     -- DEPRECATED variant #1: lack of a calling convention specification
 610     --                        (import)
 611   | 'import' {-no callconv-} ext_name safety varid_no_unsafe '::' sigtype
 612     { let
 613         target = StaticTarget ($2 `orElse` mkExtName (unLoc $4))
 614       in
 615       LL $ ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 616                                    (CFunction target)) True }
 617
 618     -- DEPRECATED variant #2: external name consists of two separate strings
 619     --                        (module name and function name) (import)
 620   | 'import' callconv STRING STRING safety varid_no_unsafe '::' sigtype
 621     {% case $2 of
 622          DNCall      -> parseError (comb2 $1 $>) "Illegal format of .NET foreign import"
 623          CCall cconv -> return $
 624            let
 625              imp = CFunction (StaticTarget (getSTRING $4))
 626            in
 627            LL $ ForeignImport $6 $8 (CImport cconv $5 nilFS nilFS imp) True }
 628
 629     -- DEPRECATED variant #3: `unsafe' after entity
 630   | 'import' callconv STRING 'unsafe' varid_no_unsafe '::' sigtype
 631     {% case $2 of
 632          DNCall      -> parseError (comb2 $1 $>) "Illegal format of .NET foreign import"
 633          CCall cconv -> return $
 634            let
 635              imp = CFunction (StaticTarget (getSTRING $3))
 636            in
 637            LL $ ForeignImport $5 $7 (CImport cconv PlayRisky nilFS nilFS imp) True }
 638
 639     -- DEPRECATED variant #4: use of the special identifier `dynamic' without
 640     --                        an explicit calling convention (import)
 641   | 'import' {-no callconv-} 'dynamic' safety varid_no_unsafe '::' sigtype
 642     { LL $ ForeignImport $4 $6 (CImport defaultCCallConv $3 nilFS nilFS
 643                                    (CFunction DynamicTarget)) True }
 644
 645     -- DEPRECATED variant #5: use of the special identifier `dynamic' (import)
 646   | 'import' callconv 'dynamic' safety varid_no_unsafe '::' sigtype
 647     {% case $2 of
 648          DNCall      -> parseError (comb2 $1 $>) "Illegal format of .NET foreign import"
 649          CCall cconv -> return $
 650            LL $ ForeignImport $5 $7 (CImport cconv $4 nilFS nilFS
 651                                         (CFunction DynamicTarget)) True }
 652
 653     -- DEPRECATED variant #6: lack of a calling convention specification
 654     --                        (export)
 655   | 'export' {-no callconv-} ext_name varid '::' sigtype
 656     { LL $ ForeignExport $3 $5 (CExport (CExportStatic ($2 `orElse` mkExtName (unLoc $3))
 657                                    defaultCCallConv)) True }
 658
 659     -- DEPRECATED variant #7: external name consists of two separate strings
 660     --                        (module name and function name) (export)
 661   | 'export' callconv STRING STRING varid '::' sigtype
 662     {% case $2 of
 663          DNCall      -> parseError (comb2 $1 $>) "Illegal format of .NET foreign import"
 664          CCall cconv -> return $
 665            LL $ ForeignExport $5 $7
 666                          (CExport (CExportStatic (getSTRING $4) cconv)) True }
 667
 668     -- DEPRECATED variant #8: use of the special identifier `dynamic' without
 669     --                        an explicit calling convention (export)
 670   | 'export' {-no callconv-} 'dynamic' varid '::' sigtype
 671     { LL $ ForeignImport $3 $5 (CImport defaultCCallConv (PlaySafe False) nilFS nilFS
 672                                    CWrapper) True }
 673
 674     -- DEPRECATED variant #9: use of the special identifier `dynamic' (export)
 675   | 'export' callconv 'dynamic' varid '::' sigtype
 676     {% case $2 of
 677          DNCall      -> parseError (comb2 $1 $>) "Illegal format of .NET foreign import"
 678          CCall cconv -> return $
 679            LL $ ForeignImport $4 $6
 680                  (CImport cconv (PlaySafe False) nilFS nilFS CWrapper) True }
 681
 682   ----------- DEPRECATED .NET decls ------------
 683   -- NB: removed the .NET call declaration, as it is entirely subsumed
 684   --     by the new standard FFI declarations
 685
 686 fdecl2DEPRECATED :: { LHsDecl RdrName }
 687 fdecl2DEPRECATED
 688   : 'import' 'dotnet' 'type' ext_name tycon { LL $ TyClD (ForeignType $5 $4 DNType) }
 689     -- left this one unchanged for the moment as type imports are not
 690     -- covered currently by the FFI standard -=chak
 691
 692
 693 callconv :: { CallConv }
 694           : 'stdcall'                   { CCall  StdCallConv }
 695           | 'ccall'                     { CCall  CCallConv   }
 696           | 'dotnet'                    { DNCall             }
 697
 698 safety :: { Safety }
 699         : 'unsafe'                      { PlayRisky }
 700         | 'safe'                        { PlaySafe False }
 701         | 'threadsafe'                  { PlaySafe True  }
 702         | {- empty -}                   { PlaySafe False }
 703
 704 safety1 :: { Safety }
 705         : 'unsafe'                      { PlayRisky }
 706         | 'safe'                        { PlaySafe  False }
 707         | 'threadsafe'                  { PlaySafe  True }
 708           -- only needed to avoid conflicts with the DEPRECATED rules
 709
 710 fspec :: { Located (Located FastString, Located RdrName, LHsType RdrName) }
 711        : STRING var '::' sigtype      { LL (L (getLoc $1) (getSTRING $1), $2, $4) }
 712        |        var '::' sigtype      { LL (noLoc nilFS, $1, $3) }
 713          -- if the entity string is missing, it defaults to the empty string;
 714          -- the meaning of an empty entity string depends on the calling
 715          -- convention
 716
 717 -- DEPRECATED syntax
 718 ext_name :: { Maybe CLabelString }
 719         : STRING                { Just (getSTRING $1) }
 720         | STRING STRING         { Just (getSTRING $2) } -- Ignore "module name" for now
 721         | {- empty -}           { Nothing }
 722
 723
 724 -----------------------------------------------------------------------------
 725 -- Type signatures
 726
 727 opt_sig :: { Maybe (LHsType RdrName) }
 728         : {- empty -}                   { Nothing }
 729         | '::' sigtype                  { Just $2 }
 730
 731 opt_asig :: { Maybe (LHsType RdrName) }
 732         : {- empty -}                   { Nothing }
 733         | '::' atype                    { Just $2 }
 734
 735 sigtypes1 :: { [LHsType RdrName] }
 736         : sigtype                       { [ $1 ] }
 737         | sigtype ',' sigtypes1         { $1 : $3 }
 738
 739 sigtype :: { LHsType RdrName }
 740         : ctype                         { L1 (mkImplicitHsForAllTy (noLoc []) $1) }
 741         -- Wrap an Implicit forall if there isn't one there already
 742
 743 sig_vars :: { Located [Located RdrName] }
 744          : sig_vars ',' var             { LL ($3 : unLoc $1) }
 745          | var                          { L1 [$1] }
 746
 747 -----------------------------------------------------------------------------
 748 -- Types
 749
 750 strict_mark :: { Located HsBang }
 751         : '!'                           { L1 HsStrict }
 752         | '{-# UNPACK' '#-}' '!'        { LL HsUnbox }
 753
 754 -- A ctype is a for-all type
 755 ctype   :: { LHsType RdrName }
 756         : 'forall' tv_bndrs '.' ctype   { LL $ mkExplicitHsForAllTy $2 (noLoc []) $4 }
 757         | context '=>' type             { LL $ mkImplicitHsForAllTy   $1 $3 }
 758         -- A type of form (context => type) is an *implicit* HsForAllTy
 759         | type                          { $1 }
 760
 761 -- We parse a context as a btype so that we don't get reduce/reduce
 762 -- errors in ctype.  The basic problem is that
 763 --      (Eq a, Ord a)
 764 -- looks so much like a tuple type.  We can't tell until we find the =>
 765 context :: { LHsContext RdrName }
 766         : btype                         {% checkContext $1 }
 767
 768 type :: { LHsType RdrName }
 769         : ipvar '::' gentype            { LL (HsPredTy (HsIParam (unLoc $1) $3)) }
 770         | gentype                       { $1 }
 771
 772 gentype :: { LHsType RdrName }
 773         : btype                         { $1 }
 774         | btype qtyconop gentype        { LL $ HsOpTy $1 $2 $3 }
 775         | btype tyvarop  gentype        { LL $ HsOpTy $1 $2 $3 }
 776         | btype '->' gentype            { LL $ HsFunTy $1 $3 }
 777
 778 btype :: { LHsType RdrName }
 779         : btype atype                   { LL $ HsAppTy $1 $2 }
 780         | atype                         { $1 }
 781
 782 atype :: { LHsType RdrName }
 783         : gtycon                        { L1 (HsTyVar (unLoc $1)) }
 784         | tyvar                         { L1 (HsTyVar (unLoc $1)) }
 785         | strict_mark atype             { LL (HsBangTy (unLoc $1) $2) }
 786         | '(' type ',' comma_types1 ')' { LL $ HsTupleTy Boxed  ($2:$4) }
 787         | '(#' comma_types1 '#)'        { LL $ HsTupleTy Unboxed $2     }
 788         | '[' type ']'                  { LL $ HsListTy  $2 }
 789         | '[:' type ':]'                { LL $ HsPArrTy  $2 }
 790         | '(' ctype ')'                 { LL $ HsParTy   $2 }
 791         | '(' ctype '::' kind ')'       { LL $ HsKindSig $2 $4 }
 792 -- Generics
 793         | INTEGER                       { L1 (HsNumTy (getINTEGER $1)) }
 794
 795 -- An inst_type is what occurs in the head of an instance decl
 796 --      e.g.  (Foo a, Gaz b) => Wibble a b
 797 -- It's kept as a single type, with a MonoDictTy at the right
 798 -- hand corner, for convenience.
 799 inst_type :: { LHsType RdrName }
 800         : sigtype                       {% checkInstType $1 }
 801
 802 inst_types1 :: { [LHsType RdrName] }
 803         : inst_type                     { [$1] }
 804         | inst_type ',' inst_types1     { $1 : $3 }
 805
 806 comma_types0  :: { [LHsType RdrName] }
 807         : comma_types1                  { $1 }
 808         | {- empty -}                   { [] }
 809
 810 comma_types1    :: { [LHsType RdrName] }
 811         : type                          { [$1] }
 812         | type  ',' comma_types1        { $1 : $3 }
 813
 814 tv_bndrs :: { [LHsTyVarBndr RdrName] }
 815          : tv_bndr tv_bndrs             { $1 : $2 }
 816          | {- empty -}                  { [] }
 817
 818 tv_bndr :: { LHsTyVarBndr RdrName }
 819         : tyvar                         { L1 (UserTyVar (unLoc $1)) }
 820         | '(' tyvar '::' kind ')'       { LL (KindedTyVar (unLoc $2) $4) }
 821
 822 fds :: { Located [Located ([RdrName], [RdrName])] }
 823         : {- empty -}                   { noLoc [] }
 824         | '|' fds1                      { LL (reverse (unLoc $2)) }
 825
 826 fds1 :: { Located [Located ([RdrName], [RdrName])] }
 827         : fds1 ',' fd                   { LL ($3 : unLoc $1) }
 828         | fd                            { L1 [$1] }
 829
 830 fd :: { Located ([RdrName], [RdrName]) }
 831         : varids0 '->' varids0          { L (comb3 $1 $2 $3)
 832                                            (reverse (unLoc $1), reverse (unLoc $3)) }
 833
 834 varids0 :: { Located [RdrName] }
 835         : {- empty -}                   { noLoc [] }
 836         | varids0 tyvar                 { LL (unLoc $2 : unLoc $1) }
 837
 838 -----------------------------------------------------------------------------
 839 -- Kinds
 840
 841 kind    :: { Kind }
 842         : akind                 { $1 }
 843         | akind '->' kind       { mkArrowKind $1 $3 }
 844
 845 akind   :: { Kind }
 846         : '*'                   { liftedTypeKind }
 847         | '(' kind ')'          { $2 }
 848
 849
 850 -----------------------------------------------------------------------------
 851 -- Datatype declarations
 852
 853 newconstr :: { LConDecl RdrName }
 854         : conid atype   { LL $ ConDecl $1 Explicit [] (noLoc []) (PrefixCon [$2]) ResTyH98 }
 855         | conid '{' var '::' ctype '}'
 856                         { LL $ ConDecl $1 Explicit [] (noLoc []) (RecCon [($3, $5)]) ResTyH98 }
 857
 858 gadt_constrlist :: { Located [LConDecl RdrName] }
 859         : '{'            gadt_constrs '}'       { LL (unLoc $2) }
 860         |     vocurly    gadt_constrs close     { $2 }
 861
 862 gadt_constrs :: { Located [LConDecl RdrName] }
 863         : gadt_constrs ';' gadt_constr  { LL ($3 : unLoc $1) }
 864         | gadt_constrs ';'              { $1 }
 865         | gadt_constr                   { L1 [$1] }
 866
 867 -- We allow the following forms:
 868 --      C :: Eq a => a -> T a
 869 --      C :: forall a. Eq a => !a -> T a
 870 --      D { x,y :: a } :: T a
 871 --      forall a. Eq a => D { x,y :: a } :: T a
 872
 873 gadt_constr :: { LConDecl RdrName }
 874         : con '::' sigtype
 875               { LL (mkGadtDecl $1 $3) }
 876         -- Syntax: Maybe merge the record stuff with the single-case above?
 877         --         (to kill the mostly harmless reduce/reduce error)
 878         -- XXX revisit autrijus
 879         | constr_stuff_record '::' sigtype
 880                 { let (con,details) = unLoc $1 in
 881                   LL (ConDecl con Implicit [] (noLoc []) details (ResTyGADT $3)) }
 882 {-
 883         | forall context '=>' constr_stuff_record '::' sigtype
 884                 { let (con,details) = unLoc $4 in
 885                   LL (ConDecl con Implicit (unLoc $1) $2 details (ResTyGADT $6)) }
 886         | forall constr_stuff_record '::' sigtype
 887                 { let (con,details) = unLoc $2 in
 888                   LL (ConDecl con Implicit (unLoc $1) (noLoc []) details (ResTyGADT $4)) }
 889 -}
 890
 891
 892 constrs :: { Located [LConDecl RdrName] }
 893         : {- empty; a GHC extension -}  { noLoc [] }
 894         | '=' constrs1                  { LL (unLoc $2) }
 895
 896 constrs1 :: { Located [LConDecl RdrName] }
 897         : constrs1 '|' constr           { LL ($3 : unLoc $1) }
 898         | constr                        { L1 [$1] }
 899
 900 constr :: { LConDecl RdrName }
 901         : forall context '=>' constr_stuff
 902                 { let (con,details) = unLoc $4 in
 903                   LL (ConDecl con Explicit (unLoc $1) $2 details ResTyH98) }
 904         | forall constr_stuff
 905                 { let (con,details) = unLoc $2 in
 906                   LL (ConDecl con Explicit (unLoc $1) (noLoc []) details ResTyH98) }
 907
 908 forall :: { Located [LHsTyVarBndr RdrName] }
 909         : 'forall' tv_bndrs '.'         { LL $2 }
 910         | {- empty -}                   { noLoc [] }
 911
 912 constr_stuff :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
 913 -- We parse the constructor declaration
 914 --      C t1 t2
 915 -- as a btype (treating C as a type constructor) and then convert C to be
 916 -- a data constructor.  Reason: it might continue like this:
 917 --      C t1 t2 %: D Int
 918 -- in which case C really would be a type constructor.  We can't resolve this
 919 -- ambiguity till we come across the constructor oprerator :% (or not, more usually)
 920         : btype                         {% mkPrefixCon $1 [] >>= return.LL }
 921         | oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.LL }
 922         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.LL }
 923         | btype conop btype             { LL ($2, InfixCon $1 $3) }
 924
 925 constr_stuff_record :: { Located (Located RdrName, HsConDetails RdrName (LBangType RdrName)) }
 926         : oqtycon '{' '}'               {% mkRecCon $1 [] >>= return.sL (comb2 $1 $>) }
 927         | oqtycon '{' fielddecls '}'    {% mkRecCon $1 $3 >>= return.sL (comb2 $1 $>) }
 928
 929 fielddecls :: { [([Located RdrName], LBangType RdrName)] }
 930         : fielddecl ',' fielddecls      { unLoc $1 : $3 }
 931         | fielddecl                     { [unLoc $1] }
 932
 933 fielddecl :: { Located ([Located RdrName], LBangType RdrName) }
 934         : sig_vars '::' ctype           { LL (reverse (unLoc $1), $3) }
 935
 936 -- We allow the odd-looking 'inst_type' in a deriving clause, so that
 937 -- we can do deriving( forall a. C [a] ) in a newtype (GHC extension).
 938 -- The 'C [a]' part is converted to an HsPredTy by checkInstType
 939 -- We don't allow a context, but that's sorted out by the type checker.
 940 deriving :: { Located (Maybe [LHsType RdrName]) }
 941         : {- empty -}                           { noLoc Nothing }
 942         | 'deriving' qtycon     {% do { let { L loc tv = $2 }
 943                                       ; p <- checkInstType (L loc (HsTyVar tv))
 944                                       ; return (LL (Just [p])) } }
 945         | 'deriving' '(' ')'                    { LL (Just []) }
 946         | 'deriving' '(' inst_types1 ')'        { LL (Just $3) }
 947              -- Glasgow extension: allow partial
 948              -- applications in derivings
 949
 950 -----------------------------------------------------------------------------
 951 -- Value definitions
 952
 953 {- There's an awkward overlap with a type signature.  Consider
 954         f :: Int -> Int = ...rhs...
 955    Then we can't tell whether it's a type signature or a value
 956    definition with a result signature until we see the '='.
 957    So we have to inline enough to postpone reductions until we know.
 958 -}
 959
 960 {-
 961   ATTENTION: Dirty Hackery Ahead! If the second alternative of vars is var
 962   instead of qvar, we get another shift/reduce-conflict. Consider the
 963   following programs:
 964
 965      { (^^) :: Int->Int ; }          Type signature; only var allowed
 966
 967      { (^^) :: Int->Int = ... ; }    Value defn with result signature;
 968                                      qvar allowed (because of instance decls)
 969
 970   We can't tell whether to reduce var to qvar until after we've read the signatures.
 971 -}
 972
 973 decl    :: { Located (OrdList (LHsDecl RdrName)) }
 974         : sigdecl                       { $1 }
 975         | infixexp opt_sig rhs          {% do { r <- checkValDef $1 $2 $3;
 976                                                 return (LL $ unitOL (LL $ ValD r)) } }
 977
 978 rhs     :: { Located (GRHSs RdrName) }
 979         : '=' exp wherebinds    { L (comb3 $1 $2 $3) $ GRHSs (unguardedRHS $2) (unLoc $3) }
 980         | gdrhs wherebinds      { LL $ GRHSs (reverse (unLoc $1)) (unLoc $2) }
 981
 982 gdrhs :: { Located [LGRHS RdrName] }
 983         : gdrhs gdrh            { LL ($2 : unLoc $1) }
 984         | gdrh                  { L1 [$1] }
 985
 986 gdrh :: { LGRHS RdrName }
 987         : '|' quals '=' exp     { sL (comb2 $1 $>) $ GRHS (reverse (unLoc $2)) $4 }
 988
 989 sigdecl :: { Located (OrdList (LHsDecl RdrName)) }
 990         : infixexp '::' sigtype
 991                                 {% do s <- checkValSig $1 $3;
 992                                       return (LL $ unitOL (LL $ SigD s)) }
 993                 -- See the above notes for why we need infixexp here
 994         | var ',' sig_vars '::' sigtype
 995                                 { LL $ toOL [ LL $ SigD (TypeSig n $5) | n <- $1 : unLoc $3 ] }
 996         | infix prec ops        { LL $ toOL [ LL $ SigD (FixSig (FixitySig n (Fixity $2 (unLoc $1))))
 997                                              | n <- unLoc $3 ] }
 998         | '{-# INLINE'   activation qvar '#-}'
 999                                 { LL $ unitOL (LL $ SigD (InlineSig $3 (Inline $2 (getINLINE $1)))) }
1000         | '{-# SPECIALISE' qvar '::' sigtypes1 '#-}'
1001                                 { LL $ toOL [ LL $ SigD (SpecSig $2 t defaultInlineSpec)
1002                                             | t <- $4] }
1003         | '{-# SPECIALISE_INLINE' activation qvar '::' sigtypes1 '#-}'
1004                                 { LL $ toOL [ LL $ SigD (SpecSig $3 t (Inline $2 (getSPEC_INLINE $1)))
1005                                             | t <- $5] }
1006         | '{-# SPECIALISE' 'instance' inst_type '#-}'
1007                                 { LL $ unitOL (LL $ SigD (SpecInstSig $3)) }
1008
1009 -----------------------------------------------------------------------------
1010 -- Expressions
1011
1012 exp   :: { LHsExpr RdrName }
1013         : infixexp '::' sigtype         { LL $ ExprWithTySig $1 $3 }
1014         | infixexp '-<' exp             { LL $ HsArrApp $1 $3 placeHolderType HsFirstOrderApp True }
1015         | infixexp '>-' exp             { LL $ HsArrApp $3 $1 placeHolderType HsFirstOrderApp False }
1016         | infixexp '-<<' exp            { LL $ HsArrApp $1 $3 placeHolderType HsHigherOrderApp True }
1017         | infixexp '>>-' exp            { LL $ HsArrApp $3 $1 placeHolderType HsHigherOrderApp False}
1018         | infixexp                      { $1 }
1019
1020 infixexp :: { LHsExpr RdrName }
1021         : exp10                         { $1 }
1022         | infixexp qop exp10            { LL (OpApp $1 $2 (panic "fixity") $3) }
1023
1024 exp10 :: { LHsExpr RdrName }
1025         : '\\' aexp aexps opt_asig '->' exp
1026                         {% checkPatterns ($2 : reverse $3) >>= \ ps ->
1027                            return (LL $ HsLam (mkMatchGroup [LL $ Match ps $4
1028                                             (GRHSs (unguardedRHS $6) emptyLocalBinds
1029                                                         )])) }
1030         | 'let' binds 'in' exp                  { LL $ HsLet (unLoc $2) $4 }
1031         | 'if' exp 'then' exp 'else' exp        { LL $ HsIf $2 $4 $6 }
1032         | 'case' exp 'of' altslist              { LL $ HsCase $2 (mkMatchGroup (unLoc $4)) }
1033         | '-' fexp                              { LL $ mkHsNegApp $2 }
1034
1035         | 'do' stmtlist                 {% let loc = comb2 $1 $2 in
1036                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1037                                            return (L loc (mkHsDo DoExpr stmts body)) }
1038         | 'mdo' stmtlist                {% let loc = comb2 $1 $2 in
1039                                            checkDo loc (unLoc $2)  >>= \ (stmts,body) ->
1040                                            return (L loc (mkHsDo (MDoExpr noPostTcTable) stmts body)) }
1041         | scc_annot exp                         { LL $ if opt_SccProfilingOn
1042                                                         then HsSCC (unLoc $1) $2
1043                                                         else HsPar $2 }
1044
1045         | 'proc' aexp '->' exp
1046                         {% checkPattern $2 >>= \ p ->
1047                            return (LL $ HsProc p (LL $ HsCmdTop $4 []
1048                                                    placeHolderType undefined)) }
1049                                                 -- TODO: is LL right here?
1050
1051         | '{-# CORE' STRING '#-}' exp           { LL $ HsCoreAnn (getSTRING $2) $4 }
1052                                                     -- hdaume: core annotation
1053         | fexp                                  { $1 }
1054
1055 scc_annot :: { Located FastString }
1056         : '_scc_' STRING                        { LL $ getSTRING $2 }
1057         | '{-# SCC' STRING '#-}'                { LL $ getSTRING $2 }
1058
1059 fexp    :: { LHsExpr RdrName }
1060         : fexp aexp                             { LL $ HsApp $1 $2 }
1061         | aexp                                  { $1 }
1062
1063 aexps   :: { [LHsExpr RdrName] }
1064         : aexps aexp                            { $2 : $1 }
1065         | {- empty -}                           { [] }
1066
1067 aexp    :: { LHsExpr RdrName }
1068         : qvar '@' aexp                 { LL $ EAsPat $1 $3 }
1069         | '~' aexp                      { LL $ ELazyPat $2 }
1070         | aexp1                         { $1 }
1071
1072 aexp1   :: { LHsExpr RdrName }
1073         : aexp1 '{' fbinds '}'  {% do { r <- mkRecConstrOrUpdate $1 (comb2 $2 $4)
1074                                                         (reverse $3);
1075                                         return (LL r) }}
1076         | aexp2                 { $1 }
1077
1078 -- Here was the syntax for type applications that I was planning
1079 -- but there are difficulties (e.g. what order for type args)
1080 -- so it's not enabled yet.
1081 -- But this case *is* used for the left hand side of a generic definition,
1082 -- which is parsed as an expression before being munged into a pattern
1083         | qcname '{|' gentype '|}'      { LL $ HsApp (sL (getLoc $1) (HsVar (unLoc $1)))
1084                                                      (sL (getLoc $3) (HsType $3)) }
1085
1086 aexp2   :: { LHsExpr RdrName }
1087         : ipvar                         { L1 (HsIPVar $! unLoc $1) }
1088         | qcname                        { L1 (HsVar   $! unLoc $1) }
1089         | literal                       { L1 (HsLit   $! unLoc $1) }
1090         | INTEGER                       { L1 (HsOverLit $! mkHsIntegral (getINTEGER $1)) }
1091         | RATIONAL                      { L1 (HsOverLit $! mkHsFractional (getRATIONAL $1)) }
1092         | '(' exp ')'                   { LL (HsPar $2) }
1093         | '(' exp ',' texps ')'         { LL $ ExplicitTuple ($2 : reverse $4) Boxed }
1094         | '(#' texps '#)'               { LL $ ExplicitTuple (reverse $2)      Unboxed }
1095         | '[' list ']'                  { LL (unLoc $2) }
1096         | '[:' parr ':]'                { LL (unLoc $2) }
1097         | '(' infixexp qop ')'          { LL $ SectionL $2 $3 }
1098         | '(' qopm infixexp ')'         { LL $ SectionR $2 $3 }
1099         | '_'                           { L1 EWildPat }
1100
1101         -- MetaHaskell Extension
1102         | TH_ID_SPLICE          { L1 $ HsSpliceE (mkHsSplice
1103                                         (L1 $ HsVar (mkUnqual varName
1104                                                         (getTH_ID_SPLICE $1)))) } -- $x
1105         | '$(' exp ')'          { LL $ HsSpliceE (mkHsSplice $2) }               -- $( exp )
1106
1107         | TH_VAR_QUOTE qvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1108         | TH_VAR_QUOTE qcon     { LL $ HsBracket (VarBr (unLoc $2)) }
1109         | TH_TY_QUOTE tyvar     { LL $ HsBracket (VarBr (unLoc $2)) }
1110         | TH_TY_QUOTE gtycon    { LL $ HsBracket (VarBr (unLoc $2)) }
1111         | '[|' exp '|]'         { LL $ HsBracket (ExpBr $2) }
1112         | '[t|' ctype '|]'      { LL $ HsBracket (TypBr $2) }
1113         | '[p|' infixexp '|]'   {% checkPattern $2 >>= \p ->
1114                                            return (LL $ HsBracket (PatBr p)) }
1115         | '[d|' cvtopbody '|]'  { LL $ HsBracket (DecBr (mkGroup $2)) }
1116
1117         -- arrow notation extension
1118         | '(|' aexp2 cmdargs '|)'       { LL $ HsArrForm $2 Nothing (reverse $3) }
1119
1120 cmdargs :: { [LHsCmdTop RdrName] }
1121         : cmdargs acmd                  { $2 : $1 }
1122         | {- empty -}                   { [] }
1123
1124 acmd    :: { LHsCmdTop RdrName }
1125         : aexp2                 { L1 $ HsCmdTop $1 [] placeHolderType undefined }
1126
1127 cvtopbody :: { [LHsDecl RdrName] }
1128         :  '{'            cvtopdecls0 '}'               { $2 }
1129         |      vocurly    cvtopdecls0 close             { $2 }
1130
1131 cvtopdecls0 :: { [LHsDecl RdrName] }
1132         : {- empty -}           { [] }
1133         | cvtopdecls            { $1 }
1134
1135 texps :: { [LHsExpr RdrName] }
1136         : texps ',' exp                 { $3 : $1 }
1137         | exp                           { [$1] }
1138
1139
1140 -----------------------------------------------------------------------------
1141 -- List expressions
1142
1143 -- The rules below are little bit contorted to keep lexps left-recursive while
1144 -- avoiding another shift/reduce-conflict.
1145
1146 list :: { LHsExpr RdrName }
1147         : exp                   { L1 $ ExplicitList placeHolderType [$1] }
1148         | lexps                 { L1 $ ExplicitList placeHolderType (reverse (unLoc $1)) }
1149         | exp '..'              { LL $ ArithSeq noPostTcExpr (From $1) }
1150         | exp ',' exp '..'      { LL $ ArithSeq noPostTcExpr (FromThen $1 $3) }
1151         | exp '..' exp          { LL $ ArithSeq noPostTcExpr (FromTo $1 $3) }
1152         | exp ',' exp '..' exp  { LL $ ArithSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1153         | exp pquals            { sL (comb2 $1 $>) $ mkHsDo ListComp (reverse (unLoc $2)) $1 }
1154
1155 lexps :: { Located [LHsExpr RdrName] }
1156         : lexps ',' exp                 { LL ($3 : unLoc $1) }
1157         | exp ',' exp                   { LL [$3,$1] }
1158
1159 -----------------------------------------------------------------------------
1160 -- List Comprehensions
1161
1162 pquals :: { Located [LStmt RdrName] }   -- Either a singleton ParStmt,
1163                                         -- or a reversed list of Stmts
1164         : pquals1                       { case unLoc $1 of
1165                                             [qs] -> L1 qs
1166                                             qss  -> L1 [L1 (ParStmt stmtss)]
1167                                                  where
1168                                                     stmtss = [ (reverse qs, undefined)
1169                                                              | qs <- qss ]
1170                                         }
1171
1172 pquals1 :: { Located [[LStmt RdrName]] }
1173         : pquals1 '|' quals             { LL (unLoc $3 : unLoc $1) }
1174         | '|' quals                     { L (getLoc $2) [unLoc $2] }
1175
1176 quals :: { Located [LStmt RdrName] }
1177         : quals ',' qual                { LL ($3 : unLoc $1) }
1178         | qual                          { L1 [$1] }
1179
1180 -----------------------------------------------------------------------------
1181 -- Parallel array expressions
1182
1183 -- The rules below are little bit contorted; see the list case for details.
1184 -- Note that, in contrast to lists, we only have finite arithmetic sequences.
1185 -- Moreover, we allow explicit arrays with no element (represented by the nil
1186 -- constructor in the list case).
1187
1188 parr :: { LHsExpr RdrName }
1189         :                               { noLoc (ExplicitPArr placeHolderType []) }
1190         | exp                           { L1 $ ExplicitPArr placeHolderType [$1] }
1191         | lexps                         { L1 $ ExplicitPArr placeHolderType
1192                                                        (reverse (unLoc $1)) }
1193         | exp '..' exp                  { LL $ PArrSeq noPostTcExpr (FromTo $1 $3) }
1194         | exp ',' exp '..' exp          { LL $ PArrSeq noPostTcExpr (FromThenTo $1 $3 $5) }
1195         | exp pquals                    { sL (comb2 $1 $>) $ mkHsDo PArrComp (reverse (unLoc $2)) $1 }
1196
1197 -- We are reusing `lexps' and `pquals' from the list case.
1198
1199 -----------------------------------------------------------------------------
1200 -- Case alternatives
1201
1202 altslist :: { Located [LMatch RdrName] }
1203         : '{'            alts '}'       { LL (reverse (unLoc $2)) }
1204         |     vocurly    alts  close    { L (getLoc $2) (reverse (unLoc $2)) }
1205
1206 alts    :: { Located [LMatch RdrName] }
1207         : alts1                         { L1 (unLoc $1) }
1208         | ';' alts                      { LL (unLoc $2) }
1209
1210 alts1   :: { Located [LMatch RdrName] }
1211         : alts1 ';' alt                 { LL ($3 : unLoc $1) }
1212         | alts1 ';'                     { LL (unLoc $1) }
1213         | alt                           { L1 [$1] }
1214
1215 alt     :: { LMatch RdrName }
1216         : infixexp opt_sig alt_rhs      {%  checkPattern $1 >>= \p ->
1217                                             return (LL (Match [p] $2 (unLoc $3))) }
1218
1219 alt_rhs :: { Located (GRHSs RdrName) }
1220         : ralt wherebinds               { LL (GRHSs (unLoc $1) (unLoc $2)) }
1221
1222 ralt :: { Located [LGRHS RdrName] }
1223         : '->' exp                      { LL (unguardedRHS $2) }
1224         | gdpats                        { L1 (reverse (unLoc $1)) }
1225
1226 gdpats :: { Located [LGRHS RdrName] }
1227         : gdpats gdpat                  { LL ($2 : unLoc $1) }
1228         | gdpat                         { L1 [$1] }
1229
1230 gdpat   :: { LGRHS RdrName }
1231         : '|' quals '->' exp            { sL (comb2 $1 $>) $ GRHS (reverse (unLoc $2)) $4 }
1232
1233 -----------------------------------------------------------------------------
1234 -- Statement sequences
1235
1236 stmtlist :: { Located [LStmt RdrName] }
1237         : '{'           stmts '}'       { LL (unLoc $2) }
1238         |     vocurly   stmts close     { $2 }
1239
1240 --      do { ;; s ; s ; ; s ;; }
1241 -- The last Stmt should be an expression, but that's hard to enforce
1242 -- here, because we need too much lookahead if we see do { e ; }
1243 -- So we use ExprStmts throughout, and switch the last one over
1244 -- in ParseUtils.checkDo instead
1245 stmts :: { Located [LStmt RdrName] }
1246         : stmt stmts_help               { LL ($1 : unLoc $2) }
1247         | ';' stmts                     { LL (unLoc $2) }
1248         | {- empty -}                   { noLoc [] }
1249
1250 stmts_help :: { Located [LStmt RdrName] } -- might be empty
1251         : ';' stmts                     { LL (unLoc $2) }
1252         | {- empty -}                   { noLoc [] }
1253
1254 -- For typing stmts at the GHCi prompt, where
1255 -- the input may consist of just comments.
1256 maybe_stmt :: { Maybe (LStmt RdrName) }
1257         : stmt                          { Just $1 }
1258         | {- nothing -}                 { Nothing }
1259
1260 stmt  :: { LStmt RdrName }
1261         : qual                          { $1 }
1262         | infixexp '->' exp             {% checkPattern $3 >>= \p ->
1263                                            return (LL $ mkBindStmt p $1) }
1264         | 'rec' stmtlist                { LL $ mkRecStmt (unLoc $2) }
1265
1266 qual  :: { LStmt RdrName }
1267         : infixexp '<-' exp             {% checkPattern $1 >>= \p ->
1268                                            return (LL $ mkBindStmt p $3) }
1269         | exp                           { L1 $ mkExprStmt $1 }
1270         | 'let' binds                   { LL $ LetStmt (unLoc $2) }
1271
1272 -----------------------------------------------------------------------------
1273 -- Record Field Update/Construction
1274
1275 fbinds  :: { HsRecordBinds RdrName }
1276         : fbinds1                       { $1 }
1277         | {- empty -}                   { [] }
1278
1279 fbinds1 :: { HsRecordBinds RdrName }
1280         : fbinds1 ',' fbind             { $3 : $1 }
1281         | fbind                         { [$1] }
1282
1283 fbind   :: { (Located RdrName, LHsExpr RdrName) }
1284         : qvar '=' exp                  { ($1,$3) }
1285
1286 -----------------------------------------------------------------------------
1287 -- Implicit Parameter Bindings
1288
1289 dbinds  :: { Located [LIPBind RdrName] }
1290         : dbinds ';' dbind              { LL ($3 : unLoc $1) }
1291         | dbinds ';'                    { LL (unLoc $1) }
1292         | dbind                         { L1 [$1] }
1293 --      | {- empty -}                   { [] }
1294
1295 dbind   :: { LIPBind RdrName }
1296 dbind   : ipvar '=' exp                 { LL (IPBind (unLoc $1) $3) }
1297
1298 ipvar   :: { Located (IPName RdrName) }
1299         : IPDUPVARID            { L1 (Dupable (mkUnqual varName (getIPDUPVARID $1))) }
1300         | IPSPLITVARID          { L1 (Linear  (mkUnqual varName (getIPSPLITVARID $1))) }
1301
1302 -----------------------------------------------------------------------------
1303 -- Deprecations
1304
1305 depreclist :: { Located [RdrName] }
1306 depreclist : deprec_var                 { L1 [unLoc $1] }
1307            | deprec_var ',' depreclist  { LL (unLoc $1 : unLoc $3) }
1308
1309 deprec_var :: { Located RdrName }
1310 deprec_var : var                        { $1 }
1311            | con                        { $1 }
1312
1313 -----------------------------------------
1314 -- Data constructors
1315 qcon    :: { Located RdrName }
1316         : qconid                { $1 }
1317         | '(' qconsym ')'       { LL (unLoc $2) }
1318         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1319 -- The case of '[:' ':]' is part of the production `parr'
1320
1321 con     :: { Located RdrName }
1322         : conid                 { $1 }
1323         | '(' consym ')'        { LL (unLoc $2) }
1324         | sysdcon               { L1 $ nameRdrName (dataConName (unLoc $1)) }
1325
1326 sysdcon :: { Located DataCon }  -- Wired in data constructors
1327         : '(' ')'               { LL unitDataCon }
1328         | '(' commas ')'        { LL $ tupleCon Boxed $2 }
1329         | '[' ']'               { LL nilDataCon }
1330
1331 conop :: { Located RdrName }
1332         : consym                { $1 }
1333         | '`' conid '`'         { LL (unLoc $2) }
1334
1335 qconop :: { Located RdrName }
1336         : qconsym               { $1 }
1337         | '`' qconid '`'        { LL (unLoc $2) }
1338
1339 -----------------------------------------------------------------------------
1340 -- Type constructors
1341
1342 gtycon  :: { Located RdrName }  -- A "general" qualified tycon
1343         : oqtycon                       { $1 }
1344         | '(' ')'                       { LL $ getRdrName unitTyCon }
1345         | '(' commas ')'                { LL $ getRdrName (tupleTyCon Boxed $2) }
1346         | '(' '->' ')'                  { LL $ getRdrName funTyCon }
1347         | '[' ']'                       { LL $ listTyCon_RDR }
1348         | '[:' ':]'                     { LL $ parrTyCon_RDR }
1349
1350 oqtycon :: { Located RdrName }  -- An "ordinary" qualified tycon
1351         : qtycon                        { $1 }
1352         | '(' qtyconsym ')'             { LL (unLoc $2) }
1353
1354 qtyconop :: { Located RdrName } -- Qualified or unqualified
1355         : qtyconsym                     { $1 }
1356         | '`' qtycon '`'                { LL (unLoc $2) }
1357
1358 qtycon :: { Located RdrName }   -- Qualified or unqualified
1359         : QCONID                        { L1 $! mkQual tcClsName (getQCONID $1) }
1360         | tycon                         { $1 }
1361
1362 tycon   :: { Located RdrName }  -- Unqualified
1363         : CONID                         { L1 $! mkUnqual tcClsName (getCONID $1) }
1364
1365 qtyconsym :: { Located RdrName }
1366         : QCONSYM                       { L1 $! mkQual tcClsName (getQCONSYM $1) }
1367         | tyconsym                      { $1 }
1368
1369 tyconsym :: { Located RdrName }
1370         : CONSYM                        { L1 $! mkUnqual tcClsName (getCONSYM $1) }
1371
1372 -----------------------------------------------------------------------------
1373 -- Operators
1374
1375 op      :: { Located RdrName }   -- used in infix decls
1376         : varop                 { $1 }
1377         | conop                 { $1 }
1378
1379 varop   :: { Located RdrName }
1380         : varsym                { $1 }
1381         | '`' varid '`'         { LL (unLoc $2) }
1382
1383 qop     :: { LHsExpr RdrName }   -- used in sections
1384         : qvarop                { L1 $ HsVar (unLoc $1) }
1385         | qconop                { L1 $ HsVar (unLoc $1) }
1386
1387 qopm    :: { LHsExpr RdrName }   -- used in sections
1388         : qvaropm               { L1 $ HsVar (unLoc $1) }
1389         | qconop                { L1 $ HsVar (unLoc $1) }
1390
1391 qvarop :: { Located RdrName }
1392         : qvarsym               { $1 }
1393         | '`' qvarid '`'        { LL (unLoc $2) }
1394
1395 qvaropm :: { Located RdrName }
1396         : qvarsym_no_minus      { $1 }
1397         | '`' qvarid '`'        { LL (unLoc $2) }
1398
1399 -----------------------------------------------------------------------------
1400 -- Type variables
1401
1402 tyvar   :: { Located RdrName }
1403 tyvar   : tyvarid               { $1 }
1404         | '(' tyvarsym ')'      { LL (unLoc $2) }
1405
1406 tyvarop :: { Located RdrName }
1407 tyvarop : '`' tyvarid '`'       { LL (unLoc $2) }
1408         | tyvarsym              { $1 }
1409
1410 tyvarid :: { Located RdrName }
1411         : VARID                 { L1 $! mkUnqual tvName (getVARID $1) }
1412         | special_id            { L1 $! mkUnqual tvName (unLoc $1) }
1413         | 'unsafe'              { L1 $! mkUnqual tvName FSLIT("unsafe") }
1414         | 'safe'                { L1 $! mkUnqual tvName FSLIT("safe") }
1415         | 'threadsafe'          { L1 $! mkUnqual tvName FSLIT("threadsafe") }
1416
1417 tyvarsym :: { Located RdrName }
1418 -- Does not include "!", because that is used for strictness marks
1419 --               or ".", because that separates the quantified type vars from the rest
1420 --               or "*", because that's used for kinds
1421 tyvarsym : VARSYM               { L1 $! mkUnqual tvName (getVARSYM $1) }
1422
1423 -----------------------------------------------------------------------------
1424 -- Variables
1425
1426 var     :: { Located RdrName }
1427         : varid                 { $1 }
1428         | '(' varsym ')'        { LL (unLoc $2) }
1429
1430 qvar    :: { Located RdrName }
1431         : qvarid                { $1 }
1432         | '(' varsym ')'        { LL (unLoc $2) }
1433         | '(' qvarsym1 ')'      { LL (unLoc $2) }
1434 -- We've inlined qvarsym here so that the decision about
1435 -- whether it's a qvar or a var can be postponed until
1436 -- *after* we see the close paren.
1437
1438 qvarid :: { Located RdrName }
1439         : varid                 { $1 }
1440         | QVARID                { L1 $ mkQual varName (getQVARID $1) }
1441
1442 varid :: { Located RdrName }
1443         : varid_no_unsafe       { $1 }
1444         | 'unsafe'              { L1 $! mkUnqual varName FSLIT("unsafe") }
1445         | 'safe'                { L1 $! mkUnqual varName FSLIT("safe") }
1446         | 'threadsafe'          { L1 $! mkUnqual varName FSLIT("threadsafe") }
1447
1448 varid_no_unsafe :: { Located RdrName }
1449         : VARID                 { L1 $! mkUnqual varName (getVARID $1) }
1450         | special_id            { L1 $! mkUnqual varName (unLoc $1) }
1451         | 'forall'              { L1 $! mkUnqual varName FSLIT("forall") }
1452
1453 qvarsym :: { Located RdrName }
1454         : varsym                { $1 }
1455         | qvarsym1              { $1 }
1456
1457 qvarsym_no_minus :: { Located RdrName }
1458         : varsym_no_minus       { $1 }
1459         | qvarsym1              { $1 }
1460
1461 qvarsym1 :: { Located RdrName }
1462 qvarsym1 : QVARSYM              { L1 $ mkQual varName (getQVARSYM $1) }
1463
1464 varsym :: { Located RdrName }
1465         : varsym_no_minus       { $1 }
1466         | '-'                   { L1 $ mkUnqual varName FSLIT("-") }
1467
1468 varsym_no_minus :: { Located RdrName } -- varsym not including '-'
1469         : VARSYM                { L1 $ mkUnqual varName (getVARSYM $1) }
1470         | special_sym           { L1 $ mkUnqual varName (unLoc $1) }
1471
1472
1473 -- These special_ids are treated as keywords in various places,
1474 -- but as ordinary ids elsewhere.   'special_id' collects all these
1475 -- except 'unsafe' and 'forall' whose treatment differs depending on context
1476 special_id :: { Located UserFS }
1477 special_id
1478         : 'as'                  { L1 FSLIT("as") }
1479         | 'qualified'           { L1 FSLIT("qualified") }
1480         | 'hiding'              { L1 FSLIT("hiding") }
1481         | 'export'              { L1 FSLIT("export") }
1482         | 'label'               { L1 FSLIT("label")  }
1483         | 'dynamic'             { L1 FSLIT("dynamic") }
1484         | 'stdcall'             { L1 FSLIT("stdcall") }
1485         | 'ccall'               { L1 FSLIT("ccall") }
1486
1487 special_sym :: { Located UserFS }
1488 special_sym : '!'       { L1 FSLIT("!") }
1489             | '.'       { L1 FSLIT(".") }
1490             | '*'       { L1 FSLIT("*") }
1491
1492 -----------------------------------------------------------------------------
1493 -- Data constructors
1494
1495 qconid :: { Located RdrName }   -- Qualified or unqualified
1496         : conid                 { $1 }
1497         | QCONID                { L1 $ mkQual dataName (getQCONID $1) }
1498
1499 conid   :: { Located RdrName }
1500         : CONID                 { L1 $ mkUnqual dataName (getCONID $1) }
1501
1502 qconsym :: { Located RdrName }  -- Qualified or unqualified
1503         : consym                { $1 }
1504         | QCONSYM               { L1 $ mkQual dataName (getQCONSYM $1) }
1505
1506 consym :: { Located RdrName }
1507         : CONSYM                { L1 $ mkUnqual dataName (getCONSYM $1) }
1508
1509         -- ':' means only list cons
1510         | ':'                   { L1 $ consDataCon_RDR }
1511
1512
1513 -----------------------------------------------------------------------------
1514 -- Literals
1515
1516 literal :: { Located HsLit }
1517         : CHAR                  { L1 $ HsChar       $ getCHAR $1 }
1518         | STRING                { L1 $ HsString     $ getSTRING $1 }
1519         | PRIMINTEGER           { L1 $ HsIntPrim    $ getPRIMINTEGER $1 }
1520         | PRIMCHAR              { L1 $ HsCharPrim   $ getPRIMCHAR $1 }
1521         | PRIMSTRING            { L1 $ HsStringPrim $ getPRIMSTRING $1 }
1522         | PRIMFLOAT             { L1 $ HsFloatPrim  $ getPRIMFLOAT $1 }
1523         | PRIMDOUBLE            { L1 $ HsDoublePrim $ getPRIMDOUBLE $1 }
1524
1525 -----------------------------------------------------------------------------
1526 -- Layout
1527
1528 close :: { () }
1529         : vccurly               { () } -- context popped in lexer.
1530         | error                 {% popContext }
1531
1532 -----------------------------------------------------------------------------
1533 -- Miscellaneous (mostly renamings)
1534
1535 modid   :: { Located Module }
1536         : CONID                 { L1 $ mkModuleFS (getCONID $1) }
1537         | QCONID                { L1 $ let (mod,c) = getQCONID $1 in
1538                                   mkModuleFS
1539                                    (mkFastString
1540                                      (unpackFS mod ++ '.':unpackFS c))
1541                                 }
1542
1543 commas :: { Int }
1544         : commas ','                    { $1 + 1 }
1545         | ','                           { 2 }
1546
1547 -----------------------------------------------------------------------------
1548
1549 {
1550 happyError :: P a
1551 happyError = srcParseFail
1552
1553 getVARID        (L _ (ITvarid    x)) = x
1554 getCONID        (L _ (ITconid    x)) = x
1555 getVARSYM       (L _ (ITvarsym   x)) = x
1556 getCONSYM       (L _ (ITconsym   x)) = x
1557 getQVARID       (L _ (ITqvarid   x)) = x
1558 getQCONID       (L _ (ITqconid   x)) = x
1559 getQVARSYM      (L _ (ITqvarsym  x)) = x
1560 getQCONSYM      (L _ (ITqconsym  x)) = x
1561 getIPDUPVARID   (L _ (ITdupipvarid   x)) = x
1562 getIPSPLITVARID (L _ (ITsplitipvarid x)) = x
1563 getCHAR         (L _ (ITchar     x)) = x
1564 getSTRING       (L _ (ITstring   x)) = x
1565 getINTEGER      (L _ (ITinteger  x)) = x
1566 getRATIONAL     (L _ (ITrational x)) = x
1567 getPRIMCHAR     (L _ (ITprimchar   x)) = x
1568 getPRIMSTRING   (L _ (ITprimstring x)) = x
1569 getPRIMINTEGER  (L _ (ITprimint    x)) = x
1570 getPRIMFLOAT    (L _ (ITprimfloat  x)) = x
1571 getPRIMDOUBLE   (L _ (ITprimdouble x)) = x
1572 getTH_ID_SPLICE (L _ (ITidEscape x)) = x
1573 getINLINE       (L _ (ITinline_prag b)) = b
1574 getSPEC_INLINE  (L _ (ITspec_inline_prag b)) = b
1575
1576 -- Utilities for combining source spans
1577 comb2 :: Located a -> Located b -> SrcSpan
1578 comb2 = combineLocs
1579
1580 comb3 :: Located a -> Located b -> Located c -> SrcSpan
1581 comb3 a b c = combineSrcSpans (getLoc a) (combineSrcSpans (getLoc b) (getLoc c))
1582
1583 comb4 :: Located a -> Located b -> Located c -> Located d -> SrcSpan
1584 comb4 a b c d = combineSrcSpans (getLoc a) $ combineSrcSpans (getLoc b) $
1585                 combineSrcSpans (getLoc c) (getLoc d)
1586
1587 -- strict constructor version:
1588 {-# INLINE sL #-}
1589 sL :: SrcSpan -> a -> Located a
1590 sL span a = span `seq` L span a
1591
1592 -- Make a source location for the file.  We're a bit lazy here and just
1593 -- make a point SrcSpan at line 1, column 0.  Strictly speaking we should
1594 -- try to find the span of the whole file (ToDo).
1595 fileSrcSpan :: P SrcSpan
1596 fileSrcSpan = do
1597   l <- getSrcLoc;
1598   let loc = mkSrcLoc (srcLocFile l) 1 0;
1599   return (mkSrcSpan loc loc)
1600 }