ghc/compiler/profiling/SCCfinal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[SCCfinal]{Modify and collect code generation for final STG program}
   5
   6 This is now a sort-of-normal STG-to-STG pass (WDP 94/06), run by stg2stg.
   7
   8 * Traverses the STG program collecting the cost centres. These are
   9   required to declare the cost centres at the start of code
  10   generation.
  11
  12   Note: because of cross-module unfolding, some of these cost centres
  13   may be from other modules.  But will still have to give them
  14   "extern" declarations.
  15
  16 * Puts on CAF cost-centres if the user has asked for individual CAF
  17   cost-centres.
  18
  19 * Ditto for individual DICT cost-centres.
  20
  21 * Boxes top-level inherited functions passed as arguments.
  22
  23 * "Distributes" given cost-centres to all as-yet-unmarked RHSs.
  24
  25 \begin{code}
  26 module SCCfinal ( stgMassageForProfiling ) where
  27
  28 #include "HsVersions.h"
  29
  30 import StgSyn
  31
  32 import DynFlags         ( DynFlags )
  33 import StaticFlags      ( opt_AutoSccsOnIndividualCafs )
  34 import CostCentre       -- lots of things
  35 import Id               ( Id )
  36 import Module           ( Module )
  37 import UniqSupply       ( uniqFromSupply, splitUniqSupply, UniqSupply )
  38 import Unique           ( Unique )
  39 import VarSet
  40 import ListSetOps       ( removeDups )
  41 import Outputable
  42
  43 infixr 9 `thenMM`, `thenMM_`
  44 \end{code}
  45
  46 \begin{code}
  47 stgMassageForProfiling
  48         :: DynFlags
  49         -> Module                       -- module name
  50         -> UniqSupply                   -- unique supply
  51         -> [StgBinding]                 -- input
  52         -> (CollectedCCs, [StgBinding])
  53
  54 stgMassageForProfiling dflags mod_name us stg_binds
  55   = let
  56         ((local_ccs, extern_ccs, cc_stacks),
  57          stg_binds2)
  58           = initMM mod_name us (do_top_bindings stg_binds)
  59
  60         (fixed_ccs, fixed_cc_stacks)
  61           = if opt_AutoSccsOnIndividualCafs
  62             then ([],[])  -- don't need "all CAFs" CC
  63                           -- (for Prelude, we use PreludeCC)
  64             else ([all_cafs_cc], [all_cafs_ccs])
  65
  66         local_ccs_no_dups  = fst (removeDups cmpCostCentre local_ccs)
  67         extern_ccs_no_dups = fst (removeDups cmpCostCentre extern_ccs)
  68     in
  69     ((fixed_ccs ++ local_ccs_no_dups,
  70       extern_ccs_no_dups,
  71       fixed_cc_stacks ++ cc_stacks), stg_binds2)
  72   where
  73
  74     all_cafs_cc  = mkAllCafsCC mod_name
  75     all_cafs_ccs = mkSingletonCCS all_cafs_cc
  76
  77     ----------
  78     do_top_bindings :: [StgBinding] -> MassageM [StgBinding]
  79
  80     do_top_bindings [] = returnMM []
  81
  82     do_top_bindings (StgNonRec b rhs : bs)
  83       = do_top_rhs b rhs                `thenMM` \ rhs' ->
  84         addTopLevelIshId b (
  85            do_top_bindings bs `thenMM` \bs' ->
  86            returnMM (StgNonRec b rhs' : bs')
  87         )
  88
  89     do_top_bindings (StgRec pairs : bs)
  90       = addTopLevelIshIds binders (
  91            mapMM do_pair pairs          `thenMM` \ pairs2 ->
  92            do_top_bindings bs `thenMM` \ bs' ->
  93            returnMM (StgRec pairs2 : bs')
  94         )
  95       where
  96         binders = map fst pairs
  97         do_pair (b, rhs)
  98            = do_top_rhs b rhs   `thenMM` \ rhs2 ->
  99              returnMM (b, rhs2)
 100
 101     ----------
 102     do_top_rhs :: Id -> StgRhs -> MassageM StgRhs
 103
 104     do_top_rhs binder (StgRhsClosure _ bi fv u srt [] (StgSCC cc (StgConApp con args)))
 105       | not (isSccCountCostCentre cc) && not (isDllConApp dflags con args)
 106         -- Trivial _scc_ around nothing but static data
 107         -- Eliminate _scc_ ... and turn into StgRhsCon
 108
 109         -- isDllConApp checks for LitLit args too
 110       = returnMM (StgRhsCon dontCareCCS con args)
 111
 112 {- Can't do this one with cost-centre stacks:  --SDM
 113     do_top_rhs binder (StgRhsClosure no_cc bi fv u [] (StgSCC ty cc expr))
 114       | (noCCSAttached no_cc || currentOrSubsumedCCS no_cc)
 115         && not (isSccCountCostCentre cc)
 116         -- Top level CAF without a cost centre attached
 117         -- Attach and collect cc of trivial _scc_ in body
 118       = collectCC cc                                    `thenMM_`
 119         set_prevailing_cc cc (do_expr expr)             `thenMM`  \ expr' ->
 120         returnMM (StgRhsClosure cc bi fv u [] expr')
 121 -}
 122
 123     do_top_rhs binder (StgRhsClosure no_cc bi fv u srt [] body)
 124       | noCCSAttached no_cc || currentOrSubsumedCCS no_cc
 125         -- Top level CAF without a cost centre attached
 126         -- Attach CAF cc (collect if individual CAF ccs)
 127       = (if opt_AutoSccsOnIndividualCafs
 128                 then let cc = mkAutoCC binder mod_name CafCC
 129                          ccs = mkSingletonCCS cc
 130                      in
 131                      collectCC  cc  `thenMM_`
 132                      collectCCS ccs `thenMM_`
 133                      returnMM ccs
 134                 else
 135                      returnMM all_cafs_ccs)             `thenMM`  \ caf_ccs ->
 136            set_prevailing_cc caf_ccs (do_expr body)     `thenMM`  \ body' ->
 137            returnMM (StgRhsClosure caf_ccs bi fv u srt [] body')
 138
 139     do_top_rhs binder (StgRhsClosure cc bi fv u srt [] body)
 140         -- Top level CAF with cost centre attached
 141         -- Should this be a CAF cc ??? Does this ever occur ???
 142       = pprPanic "SCCfinal: CAF with cc:" (ppr cc)
 143
 144     do_top_rhs binder (StgRhsClosure no_ccs bi fv u srt args body)
 145         -- Top level function, probably subsumed
 146       | noCCSAttached no_ccs
 147       = set_lambda_cc (do_expr body)    `thenMM` \ body' ->
 148         returnMM (StgRhsClosure subsumedCCS bi fv u srt args body')
 149
 150       | otherwise
 151       = pprPanic "SCCfinal: CAF with cc:" (ppr no_ccs)
 152
 153     do_top_rhs binder (StgRhsCon ccs con args)
 154         -- Top-level (static) data is not counted in heap
 155         -- profiles; nor do we set CCCS from it; so we
 156         -- just slam in dontCareCostCentre
 157       = returnMM (StgRhsCon dontCareCCS con args)
 158
 159     ------
 160     do_expr :: StgExpr -> MassageM StgExpr
 161
 162     do_expr (StgLit l) = returnMM (StgLit l)
 163
 164     do_expr (StgApp fn args)
 165       = boxHigherOrderArgs (StgApp fn) args
 166
 167     do_expr (StgConApp con args)
 168       = boxHigherOrderArgs (\args -> StgConApp con args) args
 169
 170     do_expr (StgOpApp con args res_ty)
 171       = boxHigherOrderArgs (\args -> StgOpApp con args res_ty) args
 172
 173     do_expr (StgSCC cc expr)    -- Ha, we found a cost centre!
 174       = collectCC cc            `thenMM_`
 175         do_expr expr            `thenMM` \ expr' ->
 176         returnMM (StgSCC cc expr')
 177
 178     do_expr (StgCase expr fv1 fv2 bndr srt alt_type alts)
 179       = do_expr expr            `thenMM` \ expr' ->
 180         mapMM do_alt alts       `thenMM` \ alts' ->
 181         returnMM (StgCase expr' fv1 fv2 bndr srt alt_type alts')
 182       where
 183         do_alt (id, bs, use_mask, e)
 184           = do_expr e `thenMM` \ e' ->
 185             returnMM (id, bs, use_mask, e')
 186
 187     do_expr (StgLet b e)
 188         = do_let b e `thenMM` \ (b,e) ->
 189           returnMM (StgLet b e)
 190
 191     do_expr (StgLetNoEscape lvs1 lvs2 b e)
 192         = do_let b e `thenMM` \ (b,e) ->
 193           returnMM (StgLetNoEscape lvs1 lvs2 b e)
 194
 195 #ifdef DEBUG
 196     do_expr other = pprPanic "SCCfinal.do_expr" (ppr other)
 197 #endif
 198
 199     ----------------------------------
 200
 201     do_let (StgNonRec b rhs) e
 202       = do_rhs rhs                      `thenMM` \ rhs' ->
 203         addTopLevelIshId b (
 204           do_expr e                     `thenMM` \ e' ->
 205           returnMM (StgNonRec b rhs',e')
 206         )
 207
 208     do_let (StgRec pairs) e
 209       = addTopLevelIshIds binders (
 210            mapMM do_pair pairs          `thenMM` \ pairs' ->
 211            do_expr e                    `thenMM` \ e' ->
 212            returnMM (StgRec pairs', e')
 213         )
 214       where
 215         binders = map fst pairs
 216         do_pair (b, rhs)
 217            = do_rhs rhs                 `thenMM` \ rhs2 ->
 218              returnMM (b, rhs2)
 219
 220     ----------------------------------
 221     do_rhs :: StgRhs -> MassageM StgRhs
 222         -- We play much the same game as we did in do_top_rhs above;
 223         -- but we don't have to worry about cafs etc.
 224
 225 {-
 226     do_rhs (StgRhsClosure closure_cc bi fv u [] (StgSCC ty cc (StgCon (DataCon con) args _)))
 227       | not (isSccCountCostCentre cc)
 228       = collectCC cc `thenMM_`
 229         returnMM (StgRhsCon cc con args)
 230 -}
 231
 232     do_rhs (StgRhsClosure _ bi fv u srt args expr)
 233       = slurpSCCs currentCCS expr               `thenMM` \ (expr', ccs) ->
 234         do_expr expr'                           `thenMM` \ expr'' ->
 235         returnMM (StgRhsClosure ccs bi fv u srt args expr'')
 236       where
 237         slurpSCCs ccs (StgSCC cc e)
 238              = collectCC cc                     `thenMM_`
 239                slurpSCCs ccs e                  `thenMM` \ (e', ccs')  ->
 240                returnMM (e', pushCCOnCCS cc ccs')
 241         slurpSCCs ccs e
 242              = returnMM (e, ccs)
 243
 244     do_rhs (StgRhsCon cc con args)
 245       = returnMM (StgRhsCon currentCCS con args)
 246 \end{code}
 247
 248 %************************************************************************
 249 %*                                                                      *
 250 \subsection{Boxing higher-order args}
 251 %*                                                                      *
 252 %************************************************************************
 253
 254 Boxing is *turned off* at the moment, until we can figure out how to
 255 do it properly in general.
 256
 257 \begin{code}
 258 boxHigherOrderArgs
 259     :: ([StgArg] -> StgExpr)
 260                         -- An application lacking its arguments
 261     -> [StgArg]         -- arguments which we might box
 262     -> MassageM StgExpr
 263
 264 #ifndef PROF_DO_BOXING
 265 boxHigherOrderArgs almost_expr args
 266    = returnMM (almost_expr args)
 267 #else
 268 boxHigherOrderArgs almost_expr args
 269   = getTopLevelIshIds           `thenMM` \ ids ->
 270     mapAccumMM (do_arg ids) [] args     `thenMM` \ (let_bindings, new_args) ->
 271     returnMM (foldr (mk_stg_let currentCCS) (almost_expr new_args) let_bindings)
 272   where
 273     ---------------
 274
 275     do_arg ids bindings arg@(StgVarArg old_var)
 276         |  (not (isLocalVar old_var) || elemVarSet old_var ids)
 277         && isFunTy (dropForAlls var_type)
 278       =     -- make a trivial let-binding for the top-level function
 279         getUniqueMM             `thenMM` \ uniq ->
 280         let
 281             new_var = mkSysLocal FSLIT("sf") uniq var_type
 282         in
 283         returnMM ( (new_var, old_var) : bindings, StgVarArg new_var )
 284       where
 285         var_type = idType old_var
 286
 287     do_arg ids bindings arg = returnMM (bindings, arg)
 288
 289     ---------------
 290     mk_stg_let :: CostCentreStack -> (Id, Id) -> StgExpr -> StgExpr
 291
 292     mk_stg_let cc (new_var, old_var) body
 293       = let
 294             rhs_body    = StgApp old_var [{-args-}]
 295             rhs_closure = StgRhsClosure cc stgArgOcc [{-fvs-}] ReEntrant NoSRT{-eeek!!!-} [{-args-}] rhs_body
 296         in
 297         StgLet (StgNonRec new_var rhs_closure) body
 298       where
 299         bOGUS_LVs = emptyUniqSet -- easier to print than: panic "mk_stg_let: LVs"
 300 #endif
 301 \end{code}
 302
 303 %************************************************************************
 304 %*                                                                      *
 305 \subsection{Boring monad stuff for this}
 306 %*                                                                      *
 307 %************************************************************************
 308
 309 \begin{code}
 310 type MassageM result
 311   =  Module             -- module name
 312   -> CostCentreStack    -- prevailing CostCentre
 313                         -- if none, subsumedCosts at top-level
 314                         -- currentCostCentre at nested levels
 315   -> UniqSupply
 316   -> VarSet             -- toplevel-ish Ids for boxing
 317   -> CollectedCCs
 318   -> (CollectedCCs, result)
 319
 320 -- the initMM function also returns the final CollectedCCs
 321
 322 initMM :: Module        -- module name, which we may consult
 323        -> UniqSupply
 324        -> MassageM a
 325        -> (CollectedCCs, a)
 326
 327 initMM mod_name init_us m = m mod_name noCCS init_us emptyVarSet ([],[],[])
 328
 329 thenMM  :: MassageM a -> (a -> MassageM b) -> MassageM b
 330 thenMM_ :: MassageM a -> (MassageM b) -> MassageM b
 331
 332 thenMM expr cont mod scope_cc us ids ccs
 333   = case splitUniqSupply us     of { (s1, s2) ->
 334     case (expr mod scope_cc s1 ids ccs) of { (ccs2, result) ->
 335     cont result mod scope_cc s2 ids ccs2 }}
 336
 337 thenMM_ expr cont mod scope_cc us ids ccs
 338   = case splitUniqSupply us     of { (s1, s2) ->
 339     case (expr mod scope_cc s1 ids ccs) of { (ccs2, _) ->
 340     cont mod scope_cc s2 ids ccs2 }}
 341
 342 returnMM :: a -> MassageM a
 343 returnMM result mod scope_cc us ids ccs = (ccs, result)
 344
 345 nopMM :: MassageM ()
 346 nopMM mod scope_cc us ids ccs = (ccs, ())
 347
 348 mapMM :: (a -> MassageM b) -> [a] -> MassageM [b]
 349 mapMM f [] = returnMM []
 350 mapMM f (m:ms)
 351   = f m         `thenMM` \ r  ->
 352     mapMM f ms  `thenMM` \ rs ->
 353     returnMM (r:rs)
 354
 355 mapAccumMM :: (acc -> x -> MassageM (acc, y)) -> acc -> [x] -> MassageM (acc, [y])
 356 mapAccumMM f b [] = returnMM (b, [])
 357 mapAccumMM f b (m:ms)
 358   = f b m               `thenMM` \ (b2, r)  ->
 359     mapAccumMM f b2 ms  `thenMM` \ (b3, rs) ->
 360     returnMM (b3, r:rs)
 361
 362 getUniqueMM :: MassageM Unique
 363 getUniqueMM mod scope_cc us ids ccs = (ccs, uniqFromSupply us)
 364
 365 addTopLevelIshId :: Id -> MassageM a -> MassageM a
 366 addTopLevelIshId id scope mod scope_cc us ids ccs
 367   | isCurrentCCS scope_cc = scope mod scope_cc us ids ccs
 368   | otherwise             = scope mod scope_cc us (extendVarSet ids id) ccs
 369
 370 addTopLevelIshIds :: [Id] -> MassageM a -> MassageM a
 371 addTopLevelIshIds [] cont = cont
 372 addTopLevelIshIds (id:ids) cont
 373   = addTopLevelIshId id (addTopLevelIshIds ids cont)
 374
 375 getTopLevelIshIds :: MassageM VarSet
 376 getTopLevelIshIds mod scope_cc us ids ccs = (ccs, ids)
 377 \end{code}
 378
 379 The prevailing CCS is used to tell whether we're in a top-levelish
 380 position, where top-levelish is defined as "not inside a lambda".
 381 Prevailing CCs used to be used for something much more complicated,
 382 I'm sure --SDM
 383
 384 \begin{code}
 385 set_lambda_cc :: MassageM a -> MassageM a
 386 set_lambda_cc action mod scope_cc us ids ccs
 387   = action mod currentCCS us ids ccs
 388
 389 set_prevailing_cc :: CostCentreStack -> MassageM a -> MassageM a
 390 set_prevailing_cc cc_to_set_to action mod scope_cc us ids ccs
 391   = action mod cc_to_set_to us ids ccs
 392
 393 get_prevailing_cc :: MassageM CostCentreStack
 394 get_prevailing_cc mod scope_cc us ids ccs = (ccs, scope_cc)
 395 \end{code}
 396
 397 \begin{code}
 398 collectCC :: CostCentre -> MassageM ()
 399
 400 collectCC cc mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 401   = ASSERT(not (noCCAttached cc))
 402     if (cc `ccFromThisModule` mod_name) then
 403         ((cc : local_ccs, extern_ccs, ccss), ())
 404     else -- must declare it "extern"
 405         ((local_ccs, cc : extern_ccs, ccss), ())
 406
 407 collectCCS :: CostCentreStack -> MassageM ()
 408
 409 collectCCS ccs mod_name scope_cc us ids (local_ccs, extern_ccs, ccss)
 410   = ASSERT(not (noCCSAttached ccs))
 411     ((local_ccs, extern_ccs, ccs : ccss), ())
 412 \end{code}