ghc/compiler/rename/ParseIface.y

   1 {
   2 module ParseIface ( parseIface, IfaceStuff(..) ) where
   3
   4 #include "HsVersions.h"
   5
   6 import HsSyn            -- quite a bit of stuff
   7 import RdrHsSyn         -- oodles of synonyms
   8 import HsDecls          ( HsIdInfo(..), HsStrictnessInfo(..) )
   9 import HsTypes          ( mkHsForAllTy )
  10 import HsCore
  11 import Const            ( Literal(..), mkMachInt_safe )
  12 import BasicTypes       ( Fixity(..), FixityDirection(..),
  13                           NewOrData(..), Version
  14                         )
  15 import CostCentre       ( CostCentre(..), IsCafCC(..), IsDupdCC(..) )
  16 import HsPragmas        ( noDataPragmas, noClassPragmas )
  17 import Type             ( Kind, mkArrowKind, boxedTypeKind, openTypeKind )
  18 import IdInfo           ( ArityInfo, exactArity )
  19 import Lex
  20
  21 import RnMonad          ( ImportVersion, LocalVersion, ParsedIface(..), WhatsImported(..),
  22                           RdrNamePragma, ExportItem, RdrAvailInfo, GenAvailInfo(..)
  23                         )
  24 import Bag              ( emptyBag, unitBag, snocBag )
  25 import FiniteMap        ( emptyFM, unitFM, addToFM, plusFM, bagToFM, FiniteMap )
  26 import RdrName          ( RdrName, mkRdrUnqual, mkSysQual, mkSysUnqual )
  27 import Name             ( OccName, Provenance )
  28 import OccName          ( mkSysOccFS,
  29                           tcName, varName, dataName, clsName, tvName,
  30                           EncodedFS
  31                         )
  32 import Module           ( Module, mkSysModuleFS, IfaceFlavour, hiFile, hiBootFile )
  33 import PrelMods         ( mkTupNameStr, mkUbxTupNameStr )
  34 import PrelInfo         ( mkTupConRdrName, mkUbxTupConRdrName )
  35 import SrcLoc           ( SrcLoc )
  36 import Maybes
  37 import Outputable
  38
  39 import GlaExts
  40
  41 #if __HASKELL1__ > 4
  42 import Ratio ( (%) )
  43 #endif
  44 }
  45
  46 %name       parseIface
  47 %tokentype  { IfaceToken }
  48 %monad      { IfM }{ thenIf }{ returnIf }
  49 %lexer      { lexIface } { ITeof }
  50
  51 %token
  52  'case'         { ITcase }                      -- Haskell keywords
  53  'class'        { ITclass }
  54  'data'         { ITdata }
  55  'default'      { ITdefault }
  56  'deriving'     { ITderiving }
  57  'do'           { ITdo }
  58  'else'         { ITelse }
  59  'if'           { ITif }
  60  'import'       { ITimport }
  61  'in'           { ITin }
  62  'infix'        { ITinfix }
  63  'infixl'       { ITinfixl }
  64  'infixr'       { ITinfixr }
  65  'instance'     { ITinstance }
  66  'let'          { ITlet }
  67  'module'       { ITmodule }
  68  'newtype'      { ITnewtype }
  69  'of'           { ITof }
  70  'then'         { ITthen }
  71  'type'         { ITtype }
  72  'where'        { ITwhere }
  73  'as'           { ITas }
  74  'qualified'    { ITqualified }
  75  'hiding'       { IThiding }
  76
  77  '__interface'  { ITinterface }                 -- GHC-extension keywords
  78  '__export'     { ITexport }
  79  '__instimport' { ITinstimport }
  80  '__forall'     { ITforall }
  81  '__letrec'     { ITletrec }
  82  '__coerce'     { ITcoerce }
  83  '__inline'     { ITinline }
  84  '__DEFAULT'    { ITdefaultbranch }
  85  '__bot'        { ITbottom }
  86  '__integer'    { ITinteger_lit }
  87  '__float'      { ITfloat_lit }
  88  '__rational'   { ITrational_lit }
  89  '__addr'       { ITaddr_lit }
  90  '__litlit'     { ITlit_lit }
  91  '__string'     { ITstring_lit }
  92  '__ccall'      { ITccall $$ }
  93  '__scc'        { ITscc }
  94  '__sccC'       { ITsccAllCafs }
  95
  96  '__A'          { ITarity }
  97  '__P'          { ITspecialise }
  98  '__C'          { ITnocaf }
  99  '__U'          { ITunfold $$ }
 100  '__S'          { ITstrict $$ }
 101
 102  '..'           { ITdotdot }                    -- reserved symbols
 103  '::'           { ITdcolon }
 104  '='            { ITequal }
 105  '\\'           { ITlam }
 106  '|'            { ITvbar }
 107  '<-'           { ITlarrow }
 108  '->'           { ITrarrow }
 109  '@'            { ITat }
 110  '~'            { ITtilde }
 111  '=>'           { ITdarrow }
 112  '-'            { ITminus }
 113  '!'            { ITbang }
 114
 115  '/\\'          { ITbiglam }                    -- GHC-extension symbols
 116
 117  '{'            { ITocurly }                    -- special symbols
 118  '}'            { ITccurly }
 119  '['            { ITobrack }
 120  ']'            { ITcbrack }
 121  '('            { IToparen }
 122  ')'            { ITcparen }
 123  '(#'           { IToubxparen }
 124  '#)'           { ITcubxparen }
 125  ';'            { ITsemi }
 126  ','            { ITcomma }
 127
 128  VARID          { ITvarid    $$ }               -- identifiers
 129  CONID          { ITconid    $$ }
 130  VARSYM         { ITvarsym   $$ }
 131  CONSYM         { ITconsym   $$ }
 132  QVARID         { ITqvarid   $$ }
 133  QCONID         { ITqconid   $$ }
 134  QVARSYM        { ITqvarsym  $$ }
 135  QCONSYM        { ITqconsym  $$ }
 136
 137  PRAGMA         { ITpragma   $$ }
 138
 139  CHAR           { ITchar     $$ }
 140  STRING         { ITstring   $$ }
 141  INTEGER        { ITinteger  $$ }
 142  RATIONAL       { ITrational $$ }
 143
 144  UNKNOWN        { ITunknown  $$ }
 145 %%
 146
 147 -- iface_stuff is the main production.
 148 -- It recognises (a) a whole interface file
 149 --               (b) a type (so that type sigs can be parsed lazily)
 150 --               (c) the IdInfo part of a signature (same reason)
 151
 152 iface_stuff :: { IfaceStuff }
 153 iface_stuff : iface             { let (nm, iff) = $1 in PIface nm iff }
 154             | type              { PType   $1 }
 155             | id_info           { PIdInfo $1 }
 156
 157
 158 iface           :: { (EncodedFS, ParsedIface) }
 159 iface           : '__interface' mod_fs INTEGER checkVersion 'where'
 160                   import_part
 161                   instance_import_part
 162                   exports_part
 163                   instance_decl_part
 164                   decls_part
 165                   { ( $2                        -- Module name
 166                     , ParsedIface
 167                         (fromInteger $3)        -- Module version
 168                         (reverse $6)            -- Usages
 169                         (reverse $8)            -- Exports
 170                         (reverse $7)            -- Instance import modules
 171                         (reverse $10)           -- Decls
 172                         (reverse $9)            -- Local instances
 173                     )
 174                   }
 175
 176 --------------------------------------------------------------------------
 177
 178 import_part :: { [ImportVersion OccName] }
 179 import_part :                                             { [] }
 180             |  import_part import_decl                    { $2 : $1 }
 181
 182 import_decl :: { ImportVersion OccName }
 183 import_decl : 'import' mod_fs opt_bang INTEGER '::' whats_imported ';'
 184                         { (mkSysModuleFS $2 $3, fromInteger $4, $6) }
 185
 186 whats_imported      :: { WhatsImported OccName }
 187 whats_imported      :                                           { Everything }
 188                     | name_version_pair name_version_pairs      { Specifically ($1:$2) }
 189
 190 name_version_pairs  ::  { [LocalVersion OccName] }
 191 name_version_pairs  :                                           { [] }
 192                     |  name_version_pair name_version_pairs     { $1 : $2 }
 193
 194 name_version_pair   ::  { LocalVersion OccName }
 195 name_version_pair   :  var_occ INTEGER                          { ($1, fromInteger $2) }
 196                     |  tc_occ  INTEGER                          { ($1, fromInteger $2) }
 197
 198 instance_import_part :: { [Module] }
 199 instance_import_part :                                          {   []    }
 200                      | instance_import_part '__instimport' mod_name ';'
 201                                                                 { $3 : $1 }
 202
 203 --------------------------------------------------------------------------
 204
 205 exports_part    :: { [ExportItem] }
 206 exports_part    :                                       { [] }
 207                 | exports_part '__export' opt_bang mod_fs entities ';'
 208                                                 { (mkSysModuleFS $4 $3,$5) : $1 }
 209
 210 opt_bang        :: { IfaceFlavour }
 211 opt_bang        :                                       { hiFile }
 212                 | '!'                                   { hiBootFile }
 213
 214 entities        :: { [RdrAvailInfo] }
 215 entities        :                                       { [] }
 216                 |  entity entities                      { $1 : $2 }
 217
 218 entity          :: { RdrAvailInfo }
 219 entity          :  tc_occ                               { AvailTC $1 [$1] }
 220                 |  var_occ                              { Avail $1 }
 221                 |  tc_occ stuff_inside                  { AvailTC $1 ($1:$2) }
 222                 |  tc_occ '|' stuff_inside              { AvailTC $1 $3 }
 223
 224 stuff_inside    :: { [OccName] }
 225 stuff_inside    :  '{' val_occs '}'                     { $2 }
 226
 227 val_occ         :: { OccName }
 228                 :  var_occ              { $1 }
 229                 |  data_occ             { $1 }
 230
 231 val_occs        :: { [OccName] }
 232                 :  val_occ              { [$1] }
 233                 |  val_occ val_occs     { $1 : $2 }
 234
 235
 236 --------------------------------------------------------------------------
 237
 238 fixity      :: { FixityDirection }
 239 fixity      : 'infixl'                                  { InfixL }
 240             | 'infixr'                                  { InfixR }
 241             | 'infix'                                   { InfixN }
 242
 243 mb_fix      :: { Int }
 244 mb_fix      : {-nothing-}                               { 9 }
 245             | INTEGER                                   { (fromInteger $1) }
 246
 247 -----------------------------------------------------------------------------
 248
 249 csigs           :: { [RdrNameSig] }
 250 csigs           :                               { [] }
 251                 | 'where' '{' csigs1 '}'        { $3 }
 252
 253 csigs1          :: { [RdrNameSig] }
 254 csigs1          : csig                          { [$1] }
 255                 | csig ';' csigs1               { $1 : $3 }
 256
 257 csig            :: { RdrNameSig }
 258 csig            :  src_loc var_name '::' type { ClassOpSig $2 Nothing $4 $1 }
 259                 |  src_loc var_name '=' '::' type
 260                         { ClassOpSig $2
 261                             (Just (error "Un-filled-in default method"))
 262                             $5 $1 }
 263
 264 --------------------------------------------------------------------------
 265
 266 instance_decl_part :: { [RdrNameInstDecl] }
 267 instance_decl_part : {- empty -}                       { [] }
 268                    | instance_decl_part inst_decl      { $2 : $1 }
 269
 270 inst_decl       :: { RdrNameInstDecl }
 271 inst_decl       :  src_loc 'instance' type '=' var_name ';'
 272                         { InstDecl $3
 273                                    EmptyMonoBinds       {- No bindings -}
 274                                    []                   {- No user pragmas -}
 275                                    (Just $5)            {- Dfun id -}
 276                                    $1
 277                         }
 278
 279 --------------------------------------------------------------------------
 280
 281 decls_part :: { [(Version, RdrNameHsDecl)] }
 282 decls_part
 283         :  {- empty -}                          { [] }
 284         |  decls_part version decl ';'          { ($2,$3):$1 }
 285
 286 decl    :: { RdrNameHsDecl }
 287 decl    : src_loc var_name '::' type maybe_idinfo
 288                          { SigD (IfaceSig $2 $4 ($5 $2) $1) }
 289         | src_loc 'type' tc_name tv_bndrs '=' type
 290                         { TyClD (TySynonym $3 $4 $6 $1) }
 291         | src_loc 'data' decl_context tc_name tv_bndrs constrs
 292                         { TyClD (TyData DataType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 293         | src_loc 'newtype' decl_context tc_name tv_bndrs newtype_constr
 294                         { TyClD (TyData NewType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 295         | src_loc 'class' decl_context tc_name tv_bndrs csigs
 296                         { TyClD (mkClassDecl $3 $4 $5 $6 EmptyMonoBinds
 297                                         noClassPragmas $1) }
 298         | src_loc fixity mb_fix var_or_data_name
 299                         { FixD (FixitySig $4 (Fixity $3 $2) $1) }
 300
 301 maybe_idinfo  :: { RdrName -> [HsIdInfo RdrName] }
 302 maybe_idinfo  : {- empty -}     { \_ -> [] }
 303               | src_loc PRAGMA  { \x ->
 304                                    case parseIface $2 $1 of
 305                                      Succeeded (PIdInfo id_info) -> id_info
 306                                      Failed err -> pprPanic "IdInfo parse failed"
 307                                                             (vcat [ppr x, err])
 308                                 }
 309
 310 -----------------------------------------------------------------------------
 311
 312 version         :: { Version }
 313 version         :  INTEGER                              { fromInteger $1 }
 314
 315 decl_context    :: { RdrNameContext }
 316 decl_context    :                                       { [] }
 317                 | '{' context_list1 '}' '=>'    { $2 }
 318
 319 ----------------------------------------------------------------
 320
 321 constrs         :: { [RdrNameConDecl] {- empty for handwritten abstract -} }
 322                 :                       { [] }
 323                 | '=' constrs1          { $2 }
 324
 325 constrs1        :: { [RdrNameConDecl] }
 326 constrs1        :  constr               { [$1] }
 327                 |  constr '|' constrs1  { $1 : $3 }
 328
 329 constr          :: { RdrNameConDecl }
 330 constr          :  src_loc ex_stuff data_name batypes           { mkConDecl $3 $2 (VanillaCon $4) $1 }
 331                 |  src_loc ex_stuff data_name '{' fields1 '}'   { mkConDecl $3 $2 (RecCon $5)     $1 }
 332                 -- We use "data_fs" so as to include ()
 333
 334 newtype_constr  :: { [RdrNameConDecl] {- Empty if handwritten abstract -} }
 335 newtype_constr  :                                       { [] }
 336                 | src_loc '=' ex_stuff data_name atype  { [mkConDecl $4 $3 (NewCon $5 Nothing) $1] }
 337                 | src_loc '=' ex_stuff data_name '{' var_name '::' atype '}'
 338                                                         { [mkConDecl $4 $3 (NewCon $8 (Just $6)) $1] }
 339
 340 ex_stuff :: { ([HsTyVar RdrName], RdrNameContext) }
 341 ex_stuff        :                                       { ([],[]) }
 342                 | '__forall' forall context '=>'            { ($2,$3) }
 343
 344 batypes         :: { [RdrNameBangType] }
 345 batypes         :                                       { [] }
 346                 |  batype batypes                       { $1 : $2 }
 347
 348 batype          :: { RdrNameBangType }
 349 batype          :  atype                                { Unbanged $1 }
 350                 |  '!' atype                            { Banged   $2 }
 351
 352 fields1         :: { [([RdrName], RdrNameBangType)] }
 353 fields1         : field                                 { [$1] }
 354                 | field ',' fields1                     { $1 : $3 }
 355
 356 field           :: { ([RdrName], RdrNameBangType) }
 357 field           :  var_names1 '::' type         { ($1, Unbanged $3) }
 358                 |  var_names1 '::' '!' type     { ($1, Banged   $4) }
 359 --------------------------------------------------------------------------
 360
 361 type            :: { RdrNameHsType }
 362 type            : '__forall' forall context '=>' type
 363                                                 { mkHsForAllTy $2 $3 $5 }
 364                 | btype '->' type               { MonoFunTy $1 $3 }
 365                 | btype                         { $1 }
 366
 367 forall          :: { [HsTyVar RdrName] }
 368 forall          : '[' tv_bndrs ']'                      { $2 }
 369
 370 context         :: { RdrNameContext }
 371 context         :                                       { [] }
 372                 | '{' context_list1 '}'                 { $2 }
 373
 374 context_list1   :: { RdrNameContext }
 375 context_list1   : class                                 { [$1] }
 376                 | class ',' context_list1               { $1 : $3 }
 377
 378 class           :: { (RdrName, [RdrNameHsType]) }
 379 class           :  qcls_name atypes                     { ($1, $2) }
 380
 381 types2          :: { [RdrNameHsType]                    {- Two or more -}  }
 382 types2          :  type ',' type                        { [$1,$3] }
 383                 |  type ',' types2                      { $1 : $3 }
 384
 385 btype           :: { RdrNameHsType }
 386 btype           :  atype                                { $1 }
 387                 |  btype atype                          { MonoTyApp $1 $2 }
 388
 389 atype           :: { RdrNameHsType }
 390 atype           :  qtc_name                             { MonoTyVar $1 }
 391                 |  tv_name                              { MonoTyVar $1 }
 392                 |  '(' types2 ')'                       { MonoTupleTy $2 True{-boxed-} }
 393                 |  '(#' type '#)'                       { MonoTupleTy [$2] False{-unboxed-} }
 394                 |  '(#' types2 '#)'                     { MonoTupleTy $2 False{-unboxed-} }
 395                 |  '[' type ']'                         { MonoListTy  $2 }
 396                 |  '{' qcls_name atypes '}'             { MonoDictTy $2 $3 }
 397                 |  '(' type ')'                         { $2 }
 398
 399 -- This one is dealt with via qtc_name
 400 --              |  '(' ')'                              { MonoTupleTy [] True }
 401
 402 atypes          :: { [RdrNameHsType]    {-  Zero or more -} }
 403 atypes          :                                       { [] }
 404                 |  atype atypes                         { $1 : $2 }
 405 ---------------------------------------------------------------------
 406 mod_fs          :: { EncodedFS }
 407                 :  CONID                { $1 }
 408
 409 mod_name        :: { Module }
 410                 :  mod_fs               { mkSysModuleFS $1 hiFile }
 411
 412
 413 ---------------------------------------------------
 414 var_fs          :: { EncodedFS }
 415                 : VARID                 { $1 }
 416                 | VARSYM                { $1 }
 417                 | '-'                   { SLIT("-") }
 418                 | '!'                   { SLIT("!") }
 419
 420
 421 qvar_fs         :: { (EncodedFS, EncodedFS, IfaceFlavour) }
 422                 :  QVARID               { $1 }
 423                 |  QVARSYM              { $1 }
 424
 425 var_occ         :: { OccName }
 426                 :  var_fs               { mkSysOccFS varName $1 }
 427
 428 var_name        :: { RdrName }
 429 var_name        :  var_occ              { mkRdrUnqual $1 }
 430
 431 qvar_name       :: { RdrName }
 432 qvar_name       :  var_name             { $1 }
 433                 |  qvar_fs              { mkSysQual varName $1 }
 434
 435 var_names       :: { [RdrName] }
 436 var_names       :                       { [] }
 437                 | var_name var_names    { $1 : $2 }
 438
 439 var_names1      :: { [RdrName] }
 440 var_names1      : var_name var_names    { $1 : $2 }
 441
 442 ---------------------------------------------------
 443 -- For some bizarre reason,
 444 --      (,,,)      is dealt with by the parser
 445 --      Foo.(,,,)  is dealt with by the lexer
 446 -- Sigh
 447
 448 data_fs         :: { EncodedFS }
 449                 :  CONID                { $1 }
 450                 |  CONSYM               { $1 }
 451
 452 qdata_fs        :: { (EncodedFS, EncodedFS, IfaceFlavour) }
 453                 :  QCONID               { $1 }
 454                 |  QCONSYM              { $1 }
 455
 456 data_occ        :: { OccName }
 457                 :  data_fs              { mkSysOccFS dataName $1 }
 458
 459 data_name       :: { RdrName }
 460                 :  data_occ             { mkRdrUnqual $1 }
 461
 462 qdata_name      :: { RdrName }
 463 qdata_name      :  data_name            { $1 }
 464                 |  qdata_fs             { mkSysQual dataName $1 }
 465
 466 qdata_names     :: { [RdrName] }
 467 qdata_names     :                               { [] }
 468                 | qdata_name qdata_names        { $1 : $2 }
 469
 470 var_or_data_name :: { RdrName }
 471                   : var_name                    { $1 }
 472                   | data_name                   { $1 }
 473
 474 ---------------------------------------------------
 475 tc_fs           :: { EncodedFS }
 476                 :  data_fs              { $1 }
 477
 478 tc_occ          :: { OccName }
 479                 :  tc_fs                { mkSysOccFS tcName $1 }
 480
 481 tc_name         :: { RdrName }
 482                 :  tc_occ               { mkRdrUnqual $1 }
 483
 484 qtc_name        :: { RdrName }
 485                 : tc_name               { $1 }
 486                 | qdata_fs              { mkSysQual tcName $1 }
 487
 488 ---------------------------------------------------
 489 cls_name        :: { RdrName }
 490                 :  data_fs              { mkSysUnqual clsName $1 }
 491
 492 qcls_name       :: { RdrName }
 493                 : cls_name              { $1 }
 494                 | qdata_fs              { mkSysQual clsName $1 }
 495
 496 ---------------------------------------------------
 497 tv_name         :: { RdrName }
 498                 :  VARID                { mkSysUnqual tvName $1 }
 499                 |  VARSYM               { mkSysUnqual tvName $1 {- Allow t2 as a tyvar -} }
 500
 501 tv_bndr         :: { HsTyVar RdrName }
 502                 :  tv_name '::' akind   { IfaceTyVar $1 $3 }
 503                 |  tv_name              { IfaceTyVar $1 boxedTypeKind }
 504
 505 tv_bndrs        :: { [HsTyVar RdrName] }
 506                 :                       { [] }
 507                 | tv_bndr tv_bndrs      { $1 : $2 }
 508
 509 ---------------------------------------------------
 510 kind            :: { Kind }
 511                 : akind                 { $1 }
 512                 | akind '->' kind       { mkArrowKind $1 $3 }
 513
 514 akind           :: { Kind }
 515                 : VARSYM                { if $1 == SLIT("*") then
 516                                                 boxedTypeKind
 517                                           else if $1 == SLIT("?") then
 518                                                 openTypeKind
 519                                           else panic "ParseInterface: akind"
 520                                         }
 521                 | '(' kind ')'  { $2 }
 522
 523 --------------------------------------------------------------------------
 524
 525 id_info         :: { [HsIdInfo RdrName] }
 526 id_info         :                               { [] }
 527                 | id_info_item id_info          { $1 : $2 }
 528
 529 id_info_item    :: { HsIdInfo RdrName }
 530 id_info_item    : '__A' arity_info              { HsArity $2 }
 531                 | strict_info                   { HsStrictness $1 }
 532                 | '__U' core_expr               { HsUnfold $1 (Just $2) }
 533                 | '__U'                         { HsUnfold $1 Nothing }
 534                 | '__P' spec_tvs
 535                      atypes '=' core_expr       { HsSpecialise $2 $3 $5 }
 536                 | '__C'                         { HsNoCafRefs }
 537
 538
 539 spec_tvs        :: { [HsTyVar RdrName] }
 540 spec_tvs        : '[' tv_bndrs ']'              { $2 }
 541
 542
 543 arity_info      :: { ArityInfo }
 544 arity_info      : INTEGER                       { exactArity (fromInteger $1) }
 545
 546 strict_info     :: { HsStrictnessInfo RdrName }
 547 strict_info     : '__S' qvar_name '{' qdata_names '}'
 548                                         { HsStrictnessInfo $1 (Just ($2,$4)) }
 549                 | '__S' qvar_name       { HsStrictnessInfo $1 (Just ($2,[])) }
 550                 | '__S'                 { HsStrictnessInfo $1 Nothing }
 551
 552 -------------------------------------------------------
 553 core_expr       :: { UfExpr RdrName }
 554 core_expr       : '\\' core_bndrs '->' core_expr        { foldr UfLam $4 $2 }
 555                 | 'case' core_expr 'of' var_name
 556                   '{' core_alts '}'                     { UfCase $2 $4 $6 }
 557
 558                 | 'let' '{' core_val_bndr '=' core_expr
 559                       '}' 'in' core_expr                { UfLet (UfNonRec $3 $5) $8 }
 560                 | '__letrec' '{' rec_binds '}'
 561                   'in' core_expr                        { UfLet (UfRec $3) $6 }
 562
 563                 | con_or_primop '{' core_args '}'       { UfCon $1 $3 }
 564                 | '__litlit' STRING atype               { UfCon (UfLitLitCon $2 $3) [] }
 565
 566                 | '__inline' core_expr                  { UfNote UfInlineCall $2 }
 567                 | '__coerce' atype core_expr            { UfNote (UfCoerce $2) $3 }
 568                 | scc core_expr                         { UfNote (UfSCC $1) $2  }
 569                 | fexpr                                 { $1 }
 570
 571 fexpr   :: { UfExpr RdrName }
 572 fexpr   : fexpr core_arg                                { UfApp $1 $2 }
 573         | core_aexpr                                    { $1 }
 574
 575 core_arg        :: { UfExpr RdrName }
 576                 : '@' atype                                     { UfType $2 }
 577                 | core_aexpr                                    { $1 }
 578
 579 core_args       :: { [UfExpr RdrName] }
 580                 :                                               { [] }
 581                 | core_arg core_args                            { $1 : $2 }
 582
 583 core_aexpr      :: { UfExpr RdrName }              -- Atomic expressions
 584 core_aexpr      : qvar_name                                     { UfVar $1 }
 585
 586                 | qdata_name                                    { UfVar $1 }
 587                         -- This one means that e.g. "True" will parse as
 588                         -- (UfVar True_Id) rather than (UfCon True_Con []).
 589                         -- No big deal; it'll be inlined in a jiffy.  I tried
 590                         -- parsing it to (Con con []) directly, but got bitten
 591                         -- when a real constructor Id showed up in an interface
 592                         -- file.  As usual, a hack bites you in the end.
 593                         -- If you want to get a UfCon, then use the
 594                         -- curly-bracket notation (True {}).
 595
 596                 | core_lit               { UfCon (UfLitCon $1) [] }
 597                 | '(' core_expr ')'      { $2 }
 598                 | '(' comma_exprs2 ')'   { UfTuple (mkTupConRdrName (length $2)) $2 }
 599                 | '(#' core_expr '#)'    { UfTuple (mkUbxTupConRdrName 1) [$2] }
 600                 | '(#' comma_exprs2 '#)' { UfTuple (mkUbxTupConRdrName (length $2)) $2 }
 601
 602 -- This one is dealt with by qdata_name: see above comments
 603 --              | '('  ')'               { UfTuple (mkTupConRdrName 0) [] }
 604
 605 comma_exprs2    :: { [UfExpr RdrName] } -- Two or more
 606 comma_exprs2    : core_expr ',' core_expr                       { [$1,$3] }
 607                 | core_expr ',' comma_exprs2                    { $1 : $3 }
 608
 609 con_or_primop   :: { UfCon RdrName }
 610 con_or_primop   : qdata_name                    { UfDataCon $1 }
 611                 | qvar_name                     { UfPrimOp $1 }
 612                 | '__ccall' ccall_string      { let
 613                                                 (is_dyn, is_casm, may_gc) = $1
 614                                                 in
 615                                                 UfCCallOp $2 is_dyn is_casm may_gc
 616                                                 }
 617
 618 rec_binds       :: { [(UfBinder RdrName, UfExpr RdrName)] }
 619                 :                                               { [] }
 620                 | core_val_bndr '=' core_expr ';' rec_binds     { ($1,$3) : $5 }
 621
 622 core_alts       :: { [UfAlt RdrName] }
 623                 : core_alt                                      { [$1] }
 624                 | core_alt ';' core_alts                        { $1 : $3 }
 625
 626 core_alt        :: { UfAlt RdrName }
 627 core_alt        : core_pat '->' core_expr       { (fst $1, snd $1, $3) }
 628
 629 core_pat        :: { (UfCon RdrName, [RdrName]) }
 630 core_pat        : core_lit                      { (UfLitCon  $1, []) }
 631                 | '__litlit' STRING atype       { (UfLitLitCon $2 $3, []) }
 632                 | qdata_name var_names          { (UfDataCon $1, $2) }
 633                 | '(' comma_var_names1 ')'      { (UfDataCon (mkTupConRdrName (length $2)), $2) }
 634                 | '(#' comma_var_names1 '#)'    { (UfDataCon (mkUbxTupConRdrName (length $2)), $2) }
 635                 | '__DEFAULT'                   { (UfDefault, []) }
 636                 | '(' core_pat ')'              { $2 }
 637
 638
 639 comma_var_names1 :: { [RdrName] }       -- One or more
 640 comma_var_names1 : var_name                                     { [$1] }
 641                  | var_name ',' comma_var_names1                { $1 : $3 }
 642
 643 core_lit        :: { Literal }
 644 core_lit        : INTEGER                       { mkMachInt_safe $1 }
 645                 | CHAR                          { MachChar $1 }
 646                 | STRING                        { MachStr $1 }
 647                 | '__string' STRING             { NoRepStr $2 (panic "NoRepStr type") }
 648                 | RATIONAL                      { MachDouble $1 }
 649                 | '__float' RATIONAL            { MachFloat $2 }
 650
 651                 | '__integer' INTEGER           { NoRepInteger  $2 (panic "NoRepInteger type")
 652                                                         -- The type checker will add the types
 653                                                 }
 654
 655                 | '__rational' INTEGER INTEGER  { NoRepRational ($2 % $3)
 656                                                    (panic "NoRepRational type")
 657                                                         -- The type checker will add the type
 658                                                 }
 659
 660                 | '__addr' INTEGER              { MachAddr $2 }
 661
 662 core_bndr       :: { UfBinder RdrName }
 663 core_bndr       : core_val_bndr                                 { $1 }
 664                 | core_tv_bndr                                  { $1 }
 665
 666 core_bndrs      :: { [UfBinder RdrName] }
 667 core_bndrs      :                                               { [] }
 668                 | core_bndr core_bndrs                          { $1 : $2 }
 669
 670 core_val_bndr   :: { UfBinder RdrName }
 671 core_val_bndr   : var_name '::' atype                           { UfValBinder $1 $3 }
 672
 673 core_tv_bndr    :: { UfBinder RdrName }
 674 core_tv_bndr    :  '@' tv_name '::' akind               { UfTyBinder $2 $4 }
 675                 |  '@' tv_name                          { UfTyBinder $2 boxedTypeKind }
 676
 677 ccall_string    :: { FAST_STRING }
 678                 : STRING                                        { $1 }
 679                 | VARID                                         { $1 }
 680                 | CONID                                         { $1 }
 681
 682 ------------------------------------------------------------------------
 683 scc     :: { CostCentre }
 684         :  '__sccC' '{' mod_name STRING '}'                      { AllCafsCC $3 $4 }
 685         |  '__scc' '(' cc_name mod_name STRING cc_dup cc_caf '}'
 686                              { NormalCC { cc_name = $3, cc_mod = $4, cc_grp = $5,
 687                                           cc_is_dupd = $6, cc_is_caf = $7 } }
 688
 689 cc_name :: { EncodedFS }
 690         : CONID                 { $1 }
 691         | VARID                 { $1 }
 692
 693 cc_dup  :: { IsDupdCC }
 694 cc_dup  :                       { OriginalCC }
 695         | '!'                   { DupdCC }
 696
 697 cc_caf  :: { IsCafCC }
 698         :                       { NotCafCC }
 699         | '__C'                 { CafCC }
 700
 701 -------------------------------------------------------------------
 702
 703 src_loc :: { SrcLoc }
 704 src_loc :                               {% getSrcLocIf }
 705
 706 checkVersion :: { () }
 707            : {-empty-}                  {% checkVersion Nothing }
 708            | INTEGER                    {% checkVersion (Just (fromInteger $1)) }
 709
 710 -------------------------------------------------------------------
 711
 712 --                      Haskell code
 713 {
 714
 715 data IfaceStuff = PIface        EncodedFS{-.hi module name-} ParsedIface
 716                 | PIdInfo       [HsIdInfo RdrName]
 717                 | PType         RdrNameHsType
 718
 719 mkConDecl name (ex_tvs, ex_ctxt) details loc = ConDecl name ex_tvs ex_ctxt details loc
 720 }