ghc/compiler/rename/ParseIface.y

   1 {
   2 module ParseIface ( parseIface, IfaceStuff(..) ) where
   3
   4 #include "HsVersions.h"
   5
   6 import HsSyn            -- quite a bit of stuff
   7 import RdrHsSyn         -- oodles of synonyms
   8 import HsTypes          ( mkHsForAllTy )
   9 import HsCore
  10 import Const            ( Literal(..), mkMachInt_safe )
  11 import BasicTypes       ( Fixity(..), FixityDirection(..),
  12                           NewOrData(..), Version
  13                         )
  14 import CostCentre       ( CostCentre(..), IsCafCC(..), IsDupdCC(..) )
  15 import HsPragmas        ( noDataPragmas, noClassPragmas )
  16 import Type             ( Kind, mkArrowKind, boxedTypeKind, openTypeKind, UsageAnn(..) )
  17 import IdInfo           ( ArityInfo, exactArity, CprInfo(..) )
  18 import Lex
  19
  20 import RnMonad          ( ImportVersion, LocalVersion, ParsedIface(..), WhatsImported(..),
  21                           RdrNamePragma, ExportItem, RdrAvailInfo, GenAvailInfo(..), WhetherHasOrphans
  22                         )
  23 import Bag              ( emptyBag, unitBag, snocBag )
  24 import FiniteMap        ( emptyFM, unitFM, addToFM, plusFM, bagToFM, FiniteMap )
  25 import RdrName          ( RdrName, mkRdrUnqual, mkSysQual, mkSysUnqual )
  26 import Name             ( OccName, Provenance )
  27 import OccName          ( mkSysOccFS,
  28                           tcName, varName, dataName, clsName, tvName,
  29                           EncodedFS
  30                         )
  31 import Module           ( ModuleName, mkSysModuleFS )
  32 import PrelMods         ( mkTupNameStr, mkUbxTupNameStr )
  33 import PrelInfo         ( mkTupConRdrName, mkUbxTupConRdrName )
  34 import SrcLoc           ( SrcLoc )
  35 import Maybes
  36 import Outputable
  37
  38 import GlaExts
  39
  40 #if __HASKELL1__ > 4
  41 import Ratio ( (%) )
  42 #endif
  43 }
  44
  45 %name       parseIface
  46 %tokentype  { IfaceToken }
  47 %monad      { IfM }{ thenIf }{ returnIf }
  48 %lexer      { lexIface } { ITeof }
  49
  50 %token
  51  'case'         { ITcase }                      -- Haskell keywords
  52  'class'        { ITclass }
  53  'data'         { ITdata }
  54  'default'      { ITdefault }
  55  'deriving'     { ITderiving }
  56  'do'           { ITdo }
  57  'else'         { ITelse }
  58  'if'           { ITif }
  59  'import'       { ITimport }
  60  'in'           { ITin }
  61  'infix'        { ITinfix }
  62  'infixl'       { ITinfixl }
  63  'infixr'       { ITinfixr }
  64  'instance'     { ITinstance }
  65  'let'          { ITlet }
  66  'module'       { ITmodule }
  67  'newtype'      { ITnewtype }
  68  'of'           { ITof }
  69  'then'         { ITthen }
  70  'type'         { ITtype }
  71  'where'        { ITwhere }
  72  'as'           { ITas }
  73  'qualified'    { ITqualified }
  74  'hiding'       { IThiding }
  75
  76  '__interface'  { ITinterface }                 -- GHC-extension keywords
  77  '__export'     { ITexport }
  78  '__depends'    { ITdepends }
  79  '__forall'     { ITforall }
  80  '__letrec'     { ITletrec }
  81  '__coerce'     { ITcoerce }
  82  '__inline_call'{ ITinlineCall }
  83  '__inline_me'  { ITinlineMe }
  84  '__DEFAULT'    { ITdefaultbranch }
  85  '__bot'        { ITbottom }
  86  '__integer'    { ITinteger_lit }
  87  '__float'      { ITfloat_lit }
  88  '__rational'   { ITrational_lit }
  89  '__addr'       { ITaddr_lit }
  90  '__litlit'     { ITlit_lit }
  91  '__string'     { ITstring_lit }
  92  '__ccall'      { ITccall $$ }
  93  '__scc'        { ITscc }
  94  '__sccC'       { ITsccAllCafs }
  95
  96  '__o'          { ITonce }
  97  '__m'          { ITmany }
  98
  99  '__A'          { ITarity }
 100  '__P'          { ITspecialise }
 101  '__C'          { ITnocaf }
 102  '__U'          { ITunfold $$ }
 103  '__S'          { ITstrict $$ }
 104  '__R'          { ITrules }
 105  '__M'          { ITcprinfo $$ }
 106
 107  '..'           { ITdotdot }                    -- reserved symbols
 108  '::'           { ITdcolon }
 109  '='            { ITequal }
 110  '\\'           { ITlam }
 111  '|'            { ITvbar }
 112  '<-'           { ITlarrow }
 113  '->'           { ITrarrow }
 114  '@'            { ITat }
 115  '~'            { ITtilde }
 116  '=>'           { ITdarrow }
 117  '-'            { ITminus }
 118  '!'            { ITbang }
 119
 120  '/\\'          { ITbiglam }                    -- GHC-extension symbols
 121
 122  '{'            { ITocurly }                    -- special symbols
 123  '}'            { ITccurly }
 124  '['            { ITobrack }
 125  ']'            { ITcbrack }
 126  '('            { IToparen }
 127  ')'            { ITcparen }
 128  '(#'           { IToubxparen }
 129  '#)'           { ITcubxparen }
 130  ';'            { ITsemi }
 131  ','            { ITcomma }
 132
 133  VARID          { ITvarid    $$ }               -- identifiers
 134  CONID          { ITconid    $$ }
 135  VARSYM         { ITvarsym   $$ }
 136  CONSYM         { ITconsym   $$ }
 137  QVARID         { ITqvarid   $$ }
 138  QCONID         { ITqconid   $$ }
 139  QVARSYM        { ITqvarsym  $$ }
 140  QCONSYM        { ITqconsym  $$ }
 141
 142  PRAGMA         { ITpragma   $$ }
 143
 144  CHAR           { ITchar     $$ }
 145  STRING         { ITstring   $$ }
 146  INTEGER        { ITinteger  $$ }
 147  RATIONAL       { ITrational $$ }
 148
 149  UNKNOWN        { ITunknown  $$ }
 150 %%
 151
 152 -- iface_stuff is the main production.
 153 -- It recognises (a) a whole interface file
 154 --               (b) a type (so that type sigs can be parsed lazily)
 155 --               (c) the IdInfo part of a signature (same reason)
 156
 157 iface_stuff :: { IfaceStuff }
 158 iface_stuff : iface             { let (nm, iff) = $1 in PIface nm iff }
 159             | type              { PType   $1 }
 160             | id_info           { PIdInfo $1 }
 161             | '__R' rules       { PRules  $2 }
 162
 163
 164 iface           :: { (ModuleName, ParsedIface) }
 165 iface           : '__interface' mod_fs INTEGER orphans checkVersion 'where'
 166                   exports_part
 167                   import_part
 168                   instance_decl_part
 169                   decls_part
 170                   rules_part
 171                   { ( $2                        -- Module name
 172                     , ParsedIface {
 173                         pi_mod = fromInteger $3,        -- Module version
 174                         pi_orphan  = $4,
 175                         pi_exports = $7,        -- Exports
 176                         pi_usages  = $8,        -- Usages
 177                         pi_insts   = $9,        -- Local instances
 178                         pi_decls   = $10,       -- Decls
 179                         pi_rules   = $11        -- Rules
 180                       } ) }
 181
 182 --------------------------------------------------------------------------
 183
 184 import_part :: { [ImportVersion OccName] }
 185 import_part :                                             { [] }
 186             |  import_part import_decl                    { $2 : $1 }
 187
 188 import_decl :: { ImportVersion OccName }
 189 import_decl : 'import' mod_fs INTEGER orphans whats_imported ';'
 190                         { (mkSysModuleFS $2, fromInteger $3, $4, $5) }
 191         -- import Foo 3 :: a 1 b 3 c 7 ;        means import a,b,c from Foo
 192         -- import Foo 3 ;                       means import all of Foo
 193         -- import Foo 3 ! :: ...stuff... ;      the ! means that Foo contains orphans
 194
 195 orphans             :: { WhetherHasOrphans }
 196 orphans             :                                           { False }
 197                     | '!'                                       { True }
 198
 199 whats_imported      :: { WhatsImported OccName }
 200 whats_imported      :                                           { Everything }
 201                     | '::' name_version_pairs                   { Specifically $2 }
 202
 203 name_version_pairs  ::  { [LocalVersion OccName] }
 204 name_version_pairs  :                                           { [] }
 205                     |  name_version_pair name_version_pairs     { $1 : $2 }
 206
 207 name_version_pair   ::  { LocalVersion OccName }
 208 name_version_pair   :  var_occ INTEGER                          { ($1, fromInteger $2) }
 209                     |  tc_occ  INTEGER                          { ($1, fromInteger $2) }
 210
 211
 212 --------------------------------------------------------------------------
 213
 214 exports_part    :: { [ExportItem] }
 215 exports_part    :                                       { [] }
 216                 | exports_part '__export'
 217                   mod_fs entities ';'                   { (mkSysModuleFS $3, $4) : $1 }
 218
 219 entities        :: { [RdrAvailInfo] }
 220 entities        :                                       { [] }
 221                 |  entity entities                      { $1 : $2 }
 222
 223 entity          :: { RdrAvailInfo }
 224 entity          :  tc_occ                               { AvailTC $1 [$1] }
 225                 |  var_occ                              { Avail $1 }
 226                 |  tc_occ stuff_inside                  { AvailTC $1 ($1:$2) }
 227                 |  tc_occ '|' stuff_inside              { AvailTC $1 $3 }
 228
 229 stuff_inside    :: { [OccName] }
 230 stuff_inside    :  '{' val_occs '}'                     { $2 }
 231
 232 val_occ         :: { OccName }
 233                 :  var_occ              { $1 }
 234                 |  data_occ             { $1 }
 235
 236 val_occs        :: { [OccName] }
 237                 :  val_occ              { [$1] }
 238                 |  val_occ val_occs     { $1 : $2 }
 239
 240
 241 --------------------------------------------------------------------------
 242
 243 fixity      :: { FixityDirection }
 244 fixity      : 'infixl'                                  { InfixL }
 245             | 'infixr'                                  { InfixR }
 246             | 'infix'                                   { InfixN }
 247
 248 mb_fix      :: { Int }
 249 mb_fix      : {-nothing-}                               { 9 }
 250             | INTEGER                                   { (fromInteger $1) }
 251
 252 -----------------------------------------------------------------------------
 253
 254 csigs           :: { [RdrNameSig] }
 255 csigs           :                               { [] }
 256                 | 'where' '{' csigs1 '}'        { $3 }
 257
 258 csigs1          :: { [RdrNameSig] }
 259 csigs1          : csig                          { [$1] }
 260                 | csig ';' csigs1               { $1 : $3 }
 261
 262 csig            :: { RdrNameSig }
 263 csig            :  src_loc var_name '::' type           { mkClassOpSig False $2 $4 $1 }
 264                 |  src_loc var_name '=' '::' type       { mkClassOpSig True  $2 $5 $1 }
 265
 266 --------------------------------------------------------------------------
 267
 268 instance_decl_part :: { [RdrNameInstDecl] }
 269 instance_decl_part : {- empty -}                       { [] }
 270                    | instance_decl_part inst_decl      { $2 : $1 }
 271
 272 inst_decl       :: { RdrNameInstDecl }
 273 inst_decl       :  src_loc 'instance' type '=' var_name ';'
 274                         { InstDecl $3
 275                                    EmptyMonoBinds       {- No bindings -}
 276                                    []                   {- No user pragmas -}
 277                                    $5                   {- Dfun id -}
 278                                    $1
 279                         }
 280
 281 --------------------------------------------------------------------------
 282
 283 decls_part :: { [(Version, RdrNameHsDecl)] }
 284 decls_part
 285         :  {- empty -}                          { [] }
 286         |  decls_part version decl ';'          { ($2,$3):$1 }
 287
 288 decl    :: { RdrNameHsDecl }
 289 decl    : src_loc var_name '::' type maybe_idinfo
 290                          { SigD (IfaceSig $2 $4 ($5 $2) $1) }
 291         | src_loc 'type' tc_name tv_bndrs '=' type
 292                         { TyClD (TySynonym $3 $4 $6 $1) }
 293         | src_loc 'data' decl_context tc_name tv_bndrs constrs
 294                         { TyClD (TyData DataType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 295         | src_loc 'newtype' decl_context tc_name tv_bndrs newtype_constr
 296                         { TyClD (TyData NewType $3 $4 $5 $6 Nothing noDataPragmas $1) }
 297         | src_loc 'class' decl_context tc_name tv_bndrs csigs
 298                         { TyClD (mkClassDecl $3 $4 $5 $6 EmptyMonoBinds
 299                                         noClassPragmas $1) }
 300         | src_loc fixity mb_fix var_or_data_name
 301                         { FixD (FixitySig $4 (Fixity $3 $2) $1) }
 302
 303 maybe_idinfo  :: { RdrName -> [HsIdInfo RdrName] }
 304 maybe_idinfo  : {- empty -}     { \_ -> [] }
 305               | src_loc PRAGMA  { \x ->
 306                                    case parseIface $2 $1 of
 307                                      Succeeded (PIdInfo id_info) -> id_info
 308                                      Failed err -> pprPanic "IdInfo parse failed"
 309                                                             (vcat [ppr x, err])
 310                                 }
 311
 312 -----------------------------------------------------------------------------
 313
 314 rules_part :: { [RdrNameRuleDecl] }
 315 rules_part : {- empty -}        { [] }
 316            | src_loc PRAGMA     { case parseIface $2 $1 of
 317                                      Succeeded (PRules rules) -> rules
 318                                      Failed err -> pprPanic "Rules parse failed" err
 319                                 }
 320
 321 rules      :: { [RdrNameRuleDecl] }
 322            : {- empty -}        { [] }
 323            | rule ';' rules     { $1:$3 }
 324
 325 rule       :: { RdrNameRuleDecl }
 326 rule       : src_loc STRING rule_forall qvar_name
 327              core_args '=' core_expr    { IfaceRuleDecl $4 (UfRuleBody $2 $3 $5 $7) $1 }
 328
 329 rule_forall     :: { [UfBinder RdrName] }
 330 rule_forall     : '__forall' '{' core_bndrs '}' { $3 }
 331
 332 -----------------------------------------------------------------------------
 333
 334 version         :: { Version }
 335 version         :  INTEGER                              { fromInteger $1 }
 336
 337 decl_context    :: { RdrNameContext }
 338 decl_context    :                                       { [] }
 339                 | '{' context_list1 '}' '=>'    { $2 }
 340
 341 ----------------------------------------------------------------
 342
 343 constrs         :: { [RdrNameConDecl] {- empty for handwritten abstract -} }
 344                 :                       { [] }
 345                 | '=' constrs1          { $2 }
 346
 347 constrs1        :: { [RdrNameConDecl] }
 348 constrs1        :  constr               { [$1] }
 349                 |  constr '|' constrs1  { $1 : $3 }
 350
 351 constr          :: { RdrNameConDecl }
 352 constr          :  src_loc ex_stuff data_name batypes           { mkConDecl $3 $2 (VanillaCon $4) $1 }
 353                 |  src_loc ex_stuff data_name '{' fields1 '}'   { mkConDecl $3 $2 (RecCon $5)     $1 }
 354                 -- We use "data_fs" so as to include ()
 355
 356 newtype_constr  :: { [RdrNameConDecl] {- Empty if handwritten abstract -} }
 357 newtype_constr  :                                       { [] }
 358                 | src_loc '=' ex_stuff data_name atype  { [mkConDecl $4 $3 (NewCon $5 Nothing) $1] }
 359                 | src_loc '=' ex_stuff data_name '{' var_name '::' atype '}'
 360                                                         { [mkConDecl $4 $3 (NewCon $8 (Just $6)) $1] }
 361
 362 ex_stuff :: { ([HsTyVar RdrName], RdrNameContext) }
 363 ex_stuff        :                                       { ([],[]) }
 364                 | '__forall' forall context '=>'            { ($2,$3) }
 365
 366 batypes         :: { [RdrNameBangType] }
 367 batypes         :                                       { [] }
 368                 |  batype batypes                       { $1 : $2 }
 369
 370 batype          :: { RdrNameBangType }
 371 batype          :  atype                                { Unbanged $1 }
 372                 |  '!' atype                            { Banged   $2 }
 373                 |  '!' '!' atype                        { Unpacked $3 }
 374
 375 fields1         :: { [([RdrName], RdrNameBangType)] }
 376 fields1         : field                                 { [$1] }
 377                 | field ',' fields1                     { $1 : $3 }
 378
 379 field           :: { ([RdrName], RdrNameBangType) }
 380 field           :  var_names1 '::' type         { ($1, Unbanged $3) }
 381                 |  var_names1 '::' '!' type     { ($1, Banged   $4) }
 382                 |  var_names1 '::' '!' '!' type { ($1, Unpacked $5) }
 383 --------------------------------------------------------------------------
 384
 385 type            :: { RdrNameHsType }
 386 type            : '__forall' forall context '=>' type
 387                                                 { mkHsForAllTy $2 $3 $5 }
 388                 | btype '->' type               { MonoFunTy $1 $3 }
 389                 | btype                         { $1 }
 390
 391 forall          :: { [HsTyVar RdrName] }
 392 forall          : '[' tv_bndrs ']'                      { $2 }
 393
 394 context         :: { RdrNameContext }
 395 context         :                                       { [] }
 396                 | '{' context_list1 '}'                 { $2 }
 397
 398 context_list1   :: { RdrNameContext }
 399 context_list1   : class                                 { [$1] }
 400                 | class ',' context_list1               { $1 : $3 }
 401
 402 class           :: { (RdrName, [RdrNameHsType]) }
 403 class           :  qcls_name atypes                     { ($1, $2) }
 404
 405 types2          :: { [RdrNameHsType]                    {- Two or more -}  }
 406 types2          :  type ',' type                        { [$1,$3] }
 407                 |  type ',' types2                      { $1 : $3 }
 408
 409 btype           :: { RdrNameHsType }
 410 btype           :  atype                                { $1 }
 411                 |  btype atype                          { MonoTyApp $1 $2 }
 412                 |  '__o' atype                          { MonoUsgTy UsOnce $2 }
 413                 |  '__m' atype                          { MonoUsgTy UsMany $2 }
 414
 415 atype           :: { RdrNameHsType }
 416 atype           :  qtc_name                             { MonoTyVar $1 }
 417                 |  tv_name                              { MonoTyVar $1 }
 418                 |  '(' types2 ')'                       { MonoTupleTy $2 True{-boxed-} }
 419                 |  '(#' type '#)'                       { MonoTupleTy [$2] False{-unboxed-} }
 420                 |  '(#' types2 '#)'                     { MonoTupleTy $2 False{-unboxed-} }
 421                 |  '[' type ']'                         { MonoListTy  $2 }
 422                 |  '{' qcls_name atypes '}'             { MonoDictTy $2 $3 }
 423                 |  '(' type ')'                         { $2 }
 424
 425 -- This one is dealt with via qtc_name
 426 --              |  '(' ')'                              { MonoTupleTy [] True }
 427
 428 atypes          :: { [RdrNameHsType]    {-  Zero or more -} }
 429 atypes          :                                       { [] }
 430                 |  atype atypes                         { $1 : $2 }
 431 ---------------------------------------------------------------------
 432 mod_fs          :: { EncodedFS }
 433                 :  CONID                { $1 }
 434
 435 mod_name        :: { ModuleName }
 436                 :  mod_fs               { mkSysModuleFS $1 }
 437
 438
 439 ---------------------------------------------------
 440 var_fs          :: { EncodedFS }
 441                 : VARID                 { $1 }
 442                 | VARSYM                { $1 }
 443                 | '-'                   { SLIT("-") }
 444                 | '!'                   { SLIT("!") }
 445
 446
 447 qvar_fs         :: { (EncodedFS, EncodedFS) }
 448                 :  QVARID               { $1 }
 449                 |  QVARSYM              { $1 }
 450
 451 var_occ         :: { OccName }
 452                 :  var_fs               { mkSysOccFS varName $1 }
 453
 454 var_name        :: { RdrName }
 455 var_name        :  var_occ              { mkRdrUnqual $1 }
 456
 457 qvar_name       :: { RdrName }
 458 qvar_name       :  var_name             { $1 }
 459                 |  qvar_fs              { mkSysQual varName $1 }
 460
 461 var_names       :: { [RdrName] }
 462 var_names       :                       { [] }
 463                 | var_name var_names    { $1 : $2 }
 464
 465 var_names1      :: { [RdrName] }
 466 var_names1      : var_name var_names    { $1 : $2 }
 467
 468 ---------------------------------------------------
 469 -- For some bizarre reason,
 470 --      (,,,)      is dealt with by the parser
 471 --      Foo.(,,,)  is dealt with by the lexer
 472 -- Sigh
 473
 474 data_fs         :: { EncodedFS }
 475                 :  CONID                { $1 }
 476                 |  CONSYM               { $1 }
 477
 478 qdata_fs        :: { (EncodedFS, EncodedFS) }
 479                 :  QCONID               { $1 }
 480                 |  QCONSYM              { $1 }
 481
 482 data_occ        :: { OccName }
 483                 :  data_fs              { mkSysOccFS dataName $1 }
 484
 485 data_name       :: { RdrName }
 486                 :  data_occ             { mkRdrUnqual $1 }
 487
 488 qdata_name      :: { RdrName }
 489 qdata_name      :  data_name            { $1 }
 490                 |  qdata_fs             { mkSysQual dataName $1 }
 491
 492 qdata_names     :: { [RdrName] }
 493 qdata_names     :                               { [] }
 494                 | qdata_name qdata_names        { $1 : $2 }
 495
 496 var_or_data_name :: { RdrName }
 497                   : var_name                    { $1 }
 498                   | data_name                   { $1 }
 499
 500 ---------------------------------------------------
 501 tc_fs           :: { EncodedFS }
 502                 :  data_fs              { $1 }
 503
 504 tc_occ          :: { OccName }
 505                 :  tc_fs                { mkSysOccFS tcName $1 }
 506
 507 tc_name         :: { RdrName }
 508                 :  tc_occ               { mkRdrUnqual $1 }
 509
 510 qtc_name        :: { RdrName }
 511                 : tc_name               { $1 }
 512                 | qdata_fs              { mkSysQual tcName $1 }
 513
 514 ---------------------------------------------------
 515 cls_name        :: { RdrName }
 516                 :  data_fs              { mkSysUnqual clsName $1 }
 517
 518 qcls_name       :: { RdrName }
 519                 : cls_name              { $1 }
 520                 | qdata_fs              { mkSysQual clsName $1 }
 521
 522 ---------------------------------------------------
 523 tv_name         :: { RdrName }
 524                 :  VARID                { mkSysUnqual tvName $1 }
 525                 |  VARSYM               { mkSysUnqual tvName $1 {- Allow t2 as a tyvar -} }
 526
 527 tv_bndr         :: { HsTyVar RdrName }
 528                 :  tv_name '::' akind   { IfaceTyVar $1 $3 }
 529                 |  tv_name              { IfaceTyVar $1 boxedTypeKind }
 530
 531 tv_bndrs        :: { [HsTyVar RdrName] }
 532                 :                       { [] }
 533                 | tv_bndr tv_bndrs      { $1 : $2 }
 534
 535 ---------------------------------------------------
 536 kind            :: { Kind }
 537                 : akind                 { $1 }
 538                 | akind '->' kind       { mkArrowKind $1 $3 }
 539
 540 akind           :: { Kind }
 541                 : VARSYM                { if $1 == SLIT("*") then
 542                                                 boxedTypeKind
 543                                           else if $1 == SLIT("?") then
 544                                                 openTypeKind
 545                                           else panic "ParseInterface: akind"
 546                                         }
 547                 | '(' kind ')'  { $2 }
 548
 549 --------------------------------------------------------------------------
 550
 551 id_info         :: { [HsIdInfo RdrName] }
 552                 :                               { [] }
 553                 | id_info_item id_info          { $1 : $2 }
 554                 | strict_info id_info           { $1 ++ $2 }
 555
 556 id_info_item    :: { HsIdInfo RdrName }
 557                 : '__A' arity_info              { HsArity $2 }
 558                 | '__U' core_expr               { HsUnfold $1 (Just $2) }
 559                 | '__U'                         { HsUnfold $1 Nothing }
 560                 | '__C'                         { HsNoCafRefs }
 561
 562 strict_info     :: { [HsIdInfo RdrName] }
 563                 : cpr worker                    { ($1:$2) }
 564                 | strict worker                 { ($1:$2) }
 565                 | cpr strict worker             { ($1:$2:$3) }
 566
 567 cpr             :: { HsIdInfo RdrName }
 568                 : '__M'                         { HsCprInfo $1 }
 569
 570 strict          :: { HsIdInfo RdrName }
 571                 : '__S'                         { HsStrictness (HsStrictnessInfo $1) }
 572
 573 worker          :: { [HsIdInfo RdrName] }
 574                 : qvar_name                     { [HsWorker $1] }
 575                 | {- nothing -}                 { [] }
 576
 577 arity_info      :: { ArityInfo }
 578                 : INTEGER                       { exactArity (fromInteger $1) }
 579
 580 -------------------------------------------------------
 581 core_expr       :: { UfExpr RdrName }
 582 core_expr       : '\\' core_bndrs '->' core_expr        { foldr UfLam $4 $2 }
 583                 | 'case' core_expr 'of' var_name
 584                   '{' core_alts '}'                     { UfCase $2 $4 $6 }
 585
 586                 | 'let' '{' core_val_bndr '=' core_expr
 587                       '}' 'in' core_expr                { UfLet (UfNonRec $3 $5) $8 }
 588                 | '__letrec' '{' rec_binds '}'
 589                   'in' core_expr                        { UfLet (UfRec $3) $6 }
 590
 591                 | con_or_primop '{' core_args '}'       { UfCon $1 $3 }
 592                 | '__litlit' STRING atype               { UfCon (UfLitLitCon $2 $3) [] }
 593
 594                 | '__inline_me' core_expr               { UfNote UfInlineMe $2 }
 595                 | '__inline_call' core_expr             { UfNote UfInlineCall $2 }
 596                 | '__coerce' atype core_expr            { UfNote (UfCoerce $2) $3 }
 597                 | scc core_expr                         { UfNote (UfSCC $1) $2  }
 598                 | fexpr                                 { $1 }
 599
 600 fexpr   :: { UfExpr RdrName }
 601 fexpr   : fexpr core_arg                                { UfApp $1 $2 }
 602         | core_aexpr                                    { $1 }
 603
 604 core_arg        :: { UfExpr RdrName }
 605                 : '@' atype                                     { UfType $2 }
 606                 | core_aexpr                                    { $1 }
 607
 608 core_args       :: { [UfExpr RdrName] }
 609                 :                                               { [] }
 610                 | core_arg core_args                            { $1 : $2 }
 611
 612 core_aexpr      :: { UfExpr RdrName }              -- Atomic expressions
 613 core_aexpr      : qvar_name                                     { UfVar $1 }
 614
 615                 | qdata_name                                    { UfVar $1 }
 616                         -- This one means that e.g. "True" will parse as
 617                         -- (UfVar True_Id) rather than (UfCon True_Con []).
 618                         -- No big deal; it'll be inlined in a jiffy.  I tried
 619                         -- parsing it to (Con con []) directly, but got bitten
 620                         -- when a real constructor Id showed up in an interface
 621                         -- file.  As usual, a hack bites you in the end.
 622                         -- If you want to get a UfCon, then use the
 623                         -- curly-bracket notation (True {}).
 624
 625                 | core_lit               { UfCon (UfLitCon $1) [] }
 626                 | '(' core_expr ')'      { $2 }
 627                 | '(' comma_exprs2 ')'   { UfTuple (mkTupConRdrName (length $2)) $2 }
 628                 | '(#' core_expr '#)'    { UfTuple (mkUbxTupConRdrName 1) [$2] }
 629                 | '(#' comma_exprs2 '#)' { UfTuple (mkUbxTupConRdrName (length $2)) $2 }
 630
 631 -- This one is dealt with by qdata_name: see above comments
 632 --              | '('  ')'               { UfTuple (mkTupConRdrName 0) [] }
 633
 634 comma_exprs2    :: { [UfExpr RdrName] } -- Two or more
 635 comma_exprs2    : core_expr ',' core_expr                       { [$1,$3] }
 636                 | core_expr ',' comma_exprs2                    { $1 : $3 }
 637
 638 con_or_primop   :: { UfCon RdrName }
 639 con_or_primop   : qdata_name                    { UfDataCon $1 }
 640                 | qvar_name                     { UfPrimOp $1 }
 641                 | '__ccall' ccall_string      { let
 642                                                 (is_dyn, is_casm, may_gc) = $1
 643                                                 in
 644                                                 UfCCallOp $2 is_dyn is_casm may_gc
 645                                                 }
 646
 647 rec_binds       :: { [(UfBinder RdrName, UfExpr RdrName)] }
 648                 :                                               { [] }
 649                 | core_val_bndr '=' core_expr ';' rec_binds     { ($1,$3) : $5 }
 650
 651 core_alts       :: { [UfAlt RdrName] }
 652                 : core_alt                                      { [$1] }
 653                 | core_alt ';' core_alts                        { $1 : $3 }
 654
 655 core_alt        :: { UfAlt RdrName }
 656 core_alt        : core_pat '->' core_expr       { (fst $1, snd $1, $3) }
 657
 658 core_pat        :: { (UfCon RdrName, [RdrName]) }
 659 core_pat        : core_lit                      { (UfLitCon  $1, []) }
 660                 | '__litlit' STRING atype       { (UfLitLitCon $2 $3, []) }
 661                 | qdata_name var_names          { (UfDataCon $1, $2) }
 662                 | '(' comma_var_names1 ')'      { (UfDataCon (mkTupConRdrName (length $2)), $2) }
 663                 | '(#' comma_var_names1 '#)'    { (UfDataCon (mkUbxTupConRdrName (length $2)), $2) }
 664                 | '__DEFAULT'                   { (UfDefault, []) }
 665                 | '(' core_pat ')'              { $2 }
 666
 667
 668 comma_var_names1 :: { [RdrName] }       -- One or more
 669 comma_var_names1 : var_name                                     { [$1] }
 670                  | var_name ',' comma_var_names1                { $1 : $3 }
 671
 672 core_lit        :: { Literal }
 673 core_lit        : INTEGER                       { mkMachInt_safe $1 }
 674                 | CHAR                          { MachChar $1 }
 675                 | STRING                        { MachStr $1 }
 676                 | '__string' STRING             { NoRepStr $2 (panic "NoRepStr type") }
 677                 | RATIONAL                      { MachDouble $1 }
 678                 | '__float' RATIONAL            { MachFloat $2 }
 679
 680                 | '__integer' INTEGER           { NoRepInteger  $2 (panic "NoRepInteger type")
 681                                                         -- The type checker will add the types
 682                                                 }
 683
 684                 | '__rational' INTEGER INTEGER  { NoRepRational ($2 % $3)
 685                                                    (panic "NoRepRational type")
 686                                                         -- The type checker will add the type
 687                                                 }
 688
 689                 | '__addr' INTEGER              { MachAddr $2 }
 690
 691 core_bndr       :: { UfBinder RdrName }
 692 core_bndr       : core_val_bndr                                 { $1 }
 693                 | core_tv_bndr                                  { $1 }
 694
 695 core_bndrs      :: { [UfBinder RdrName] }
 696 core_bndrs      :                                               { [] }
 697                 | core_bndr core_bndrs                          { $1 : $2 }
 698
 699 core_val_bndr   :: { UfBinder RdrName }
 700 core_val_bndr   : var_name '::' atype                           { UfValBinder $1 $3 }
 701
 702 core_tv_bndr    :: { UfBinder RdrName }
 703 core_tv_bndr    :  '@' tv_name '::' akind               { UfTyBinder $2 $4 }
 704                 |  '@' tv_name                          { UfTyBinder $2 boxedTypeKind }
 705
 706 ccall_string    :: { FAST_STRING }
 707                 : STRING                                        { $1 }
 708                 | VARID                                         { $1 }
 709                 | CONID                                         { $1 }
 710
 711 ------------------------------------------------------------------------
 712 scc     :: { CostCentre }
 713         :  '__sccC' '{' mod_name STRING '}'                      { AllCafsCC $3 $4 }
 714         |  '__scc' '{' cc_name mod_name STRING cc_dup cc_caf '}'
 715                              { NormalCC { cc_name = $3, cc_mod = $4, cc_grp = $5,
 716                                           cc_is_dupd = $6, cc_is_caf = $7 } }
 717
 718 cc_name :: { EncodedFS }
 719         : CONID                 { $1 }
 720         | VARID                 { $1 }
 721
 722 cc_dup  :: { IsDupdCC }
 723 cc_dup  :                       { OriginalCC }
 724         | '!'                   { DupdCC }
 725
 726 cc_caf  :: { IsCafCC }
 727         :                       { NotCafCC }
 728         | '__C'                 { CafCC }
 729
 730 -------------------------------------------------------------------
 731
 732 src_loc :: { SrcLoc }
 733 src_loc :                               {% getSrcLocIf }
 734
 735 checkVersion :: { () }
 736            : {-empty-}                  {% checkVersion Nothing }
 737            | INTEGER                    {% checkVersion (Just (fromInteger $1)) }
 738
 739 -------------------------------------------------------------------
 740
 741 --                      Haskell code
 742 {
 743
 744 data IfaceStuff = PIface        EncodedFS{-.hi module name-} ParsedIface
 745                 | PIdInfo       [HsIdInfo RdrName]
 746                 | PType         RdrNameHsType
 747                 | PRules        [RdrNameRuleDecl]
 748
 749 mkConDecl name (ex_tvs, ex_ctxt) details loc = ConDecl name ex_tvs ex_ctxt details loc
 750 }