ghc/compiler/rename/RnEnv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnEnv]{Environment manipulation for the renamer monad}
   5
   6 \begin{code}
   7 module RnEnv where              -- Export everything
   8
   9 #include "HsVersions.h"
  10
  11 import {-# SOURCE #-} RnHiFiles
  12
  13 import HsSyn
  14 import RdrHsSyn         ( RdrNameIE, RdrNameHsType, extractHsTyRdrTyVars )
  15 import RdrName          ( RdrName, rdrNameModule, rdrNameOcc, isQual, isUnqual, isOrig,
  16                           mkRdrUnqual, mkRdrQual,
  17                           lookupRdrEnv, foldRdrEnv, rdrEnvToList, elemRdrEnv,
  18                           unqualifyRdrName
  19                         )
  20 import HsTypes          ( hsTyVarName, replaceTyVarName )
  21 import HscTypes         ( Provenance(..), pprNameProvenance, hasBetterProv,
  22                           ImportReason(..), GlobalRdrEnv, GlobalRdrElt(..), AvailEnv,
  23                           AvailInfo, Avails, GenAvailInfo(..), NameSupply(..),
  24                           ModIface(..),
  25                           Deprecations(..), lookupDeprec,
  26                           extendLocalRdrEnv
  27                         )
  28 import RnMonad
  29 import Name             ( Name,
  30                           getSrcLoc, nameIsLocalOrFrom,
  31                           mkLocalName, mkGlobalName, nameModule,
  32                           mkIPName, nameOccName, nameModule_maybe,
  33                           setNameModuleAndLoc
  34                         )
  35 import NameEnv
  36 import NameSet
  37 import OccName          ( OccName, occNameUserString, occNameFlavour )
  38 import Module           ( ModuleName, moduleName, mkVanillaModule,
  39                           mkSysModuleNameFS, moduleNameFS, WhereFrom(..) )
  40 import PrelNames        ( mkUnboundName,
  41                           derivingOccurrences,
  42                           mAIN_Name, pREL_MAIN_Name,
  43                           ioTyConName, intTyConName,
  44                           boolTyConName, funTyConName,
  45                           unpackCStringName, unpackCStringFoldrName, unpackCStringUtf8Name,
  46                           eqStringName, printName,
  47                           bindIOName, returnIOName, failIOName
  48                         )
  49 import TysWiredIn       ( unitTyCon )   -- A little odd
  50 import FiniteMap
  51 import UniqSupply
  52 import SrcLoc           ( SrcLoc, noSrcLoc )
  53 import Outputable
  54 import ListSetOps       ( removeDups, equivClasses )
  55 import Util             ( sortLt )
  56 import BasicTypes       ( mapIPName )
  57 import List             ( nub )
  58 import UniqFM           ( lookupWithDefaultUFM )
  59 import Maybe            ( mapMaybe )
  60 import CmdLineOpts
  61 import FastString       ( FastString )
  62 \end{code}
  63
  64 %*********************************************************
  65 %*                                                      *
  66 \subsection{Making new names}
  67 %*                                                      *
  68 %*********************************************************
  69
  70 \begin{code}
  71 newTopBinder :: Module -> RdrName -> SrcLoc -> RnM d Name
  72         -- newTopBinder puts into the cache the binder with the
  73         -- module information set correctly.  When the decl is later renamed,
  74         -- the binding site will thereby get the correct module.
  75         -- There maybe occurrences that don't have the correct Module, but
  76         -- by the typechecker will propagate the binding definition to all
  77         -- the occurrences, so that doesn't matter
  78
  79 newTopBinder mod rdr_name loc
  80   =     -- First check the cache
  81
  82         -- There should never be a qualified name in a binding position (except in instance decls)
  83         -- The parser doesn't check this because the same parser parses instance decls
  84     (if isQual rdr_name then
  85         qualNameErr (text "In its declaration") (rdr_name,loc)
  86      else
  87         returnRn ()
  88     )                           `thenRn_`
  89
  90     getNameSupplyRn             `thenRn` \ name_supply ->
  91     let
  92         occ = rdrNameOcc rdr_name
  93         key = (moduleName mod, occ)
  94         cache = nsNames name_supply
  95     in
  96     case lookupFM cache key of
  97
  98         -- A hit in the cache!  We are at the binding site of the name, and
  99         -- this is the moment when we know all about
 100         --      a) the Name's host Module (in particular, which
 101         --         package it comes from)
 102         --      b) its defining SrcLoc
 103         -- So we update this info
 104
 105         Just name -> let
 106                         new_name  = setNameModuleAndLoc name mod loc
 107                         new_cache = addToFM cache key new_name
 108                      in
 109                      setNameSupplyRn (name_supply {nsNames = new_cache})        `thenRn_`
 110 --                   traceRn (text "newTopBinder: overwrite" <+> ppr new_name) `thenRn_`
 111                      returnRn new_name
 112
 113         -- Miss in the cache!
 114         -- Build a completely new Name, and put it in the cache
 115         -- Even for locally-defined names we use implicitImportProvenance;
 116         -- updateProvenances will set it to rights
 117         Nothing -> let
 118                         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 119                         uniq       = uniqFromSupply us1
 120                         new_name   = mkGlobalName uniq mod occ loc
 121                         new_cache  = addToFM cache key new_name
 122                    in
 123                    setNameSupplyRn (name_supply {nsUniqs = us', nsNames = new_cache})   `thenRn_`
 124 --                 traceRn (text "newTopBinder: new" <+> ppr new_name) `thenRn_`
 125                    returnRn new_name
 126
 127
 128 newGlobalName :: ModuleName -> OccName -> RnM d Name
 129   -- Used for *occurrences*.  We make a place-holder Name, really just
 130   -- to agree on its unique, which gets overwritten when we read in
 131   -- the binding occurence later (newTopBinder)
 132   -- The place-holder Name doesn't have the right SrcLoc, and its
 133   -- Module won't have the right Package either.
 134   --
 135   -- (We have to pass a ModuleName, not a Module, because we may be
 136   -- simply looking at an occurrence M.x in an interface file.)
 137   --
 138   -- This means that a renamed program may have incorrect info
 139   -- on implicitly-imported occurrences, but the correct info on the
 140   -- *binding* declaration. It's the type checker that propagates the
 141   -- correct information to all the occurrences.
 142   -- Since implicitly-imported names never occur in error messages,
 143   -- it doesn't matter that we get the correct info in place till later,
 144   -- (but since it affects DLL-ery it does matter that we get it right
 145   --  in the end).
 146 newGlobalName mod_name occ
 147   = getNameSupplyRn             `thenRn` \ name_supply ->
 148     let
 149         key = (mod_name, occ)
 150         cache = nsNames name_supply
 151     in
 152     case lookupFM cache key of
 153         Just name -> -- traceRn (text "newGlobalName: hit" <+> ppr name) `thenRn_`
 154                      returnRn name
 155
 156         Nothing   -> setNameSupplyRn (name_supply {nsUniqs = us', nsNames = new_cache})  `thenRn_`
 157                      -- traceRn (text "newGlobalName: new" <+> ppr name)                  `thenRn_`
 158                      returnRn name
 159                   where
 160                      (us', us1) = splitUniqSupply (nsUniqs name_supply)
 161                      uniq       = uniqFromSupply us1
 162                      mod        = mkVanillaModule mod_name
 163                      name       = mkGlobalName uniq mod occ noSrcLoc
 164                      new_cache  = addToFM cache key name
 165
 166 newIPName rdr_name_ip
 167   = getNameSupplyRn             `thenRn` \ name_supply ->
 168     let
 169         ipcache = nsIPs name_supply
 170     in
 171     case lookupFM ipcache key of
 172         Just name_ip -> returnRn name_ip
 173         Nothing      -> setNameSupplyRn new_ns  `thenRn_`
 174                         returnRn name_ip
 175                   where
 176                      (us', us1)  = splitUniqSupply (nsUniqs name_supply)
 177                      uniq        = uniqFromSupply us1
 178                      name_ip     = mapIPName mk_name rdr_name_ip
 179                      mk_name rdr_name = mkIPName uniq (rdrNameOcc rdr_name)
 180                      new_ipcache = addToFM ipcache key name_ip
 181                      new_ns      = name_supply {nsUniqs = us', nsIPs = new_ipcache}
 182     where
 183         key = rdr_name_ip       -- Ensures that ?x and %x get distinct Names
 184 \end{code}
 185
 186 %*********************************************************
 187 %*                                                      *
 188 \subsection{Looking up names}
 189 %*                                                      *
 190 %*********************************************************
 191
 192 Looking up a name in the RnEnv.
 193
 194 \begin{code}
 195 lookupBndrRn rdr_name
 196   = getLocalNameEnv             `thenRn` \ local_env ->
 197     case lookupRdrEnv local_env rdr_name of
 198           Just name -> returnRn name
 199           Nothing   -> lookupTopBndrRn rdr_name
 200
 201 lookupTopBndrRn rdr_name
 202 -- Look up a top-level local binder.   We may be looking up an unqualified 'f',
 203 -- and there may be several imported 'f's too, which must not confuse us.
 204 -- So we have to filter out the non-local ones.
 205 -- A separate function (importsFromLocalDecls) reports duplicate top level
 206 -- decls, so here it's safe just to choose an arbitrary one.
 207
 208   | isOrig rdr_name
 209         -- This is here just to catch the PrelBase defn of (say) [] and similar
 210         -- The parser reads the special syntax and returns an Orig RdrName
 211         -- But the global_env contains only Qual RdrNames, so we won't
 212         -- find it there; instead just get the name via the Orig route
 213   = lookupOrigName rdr_name
 214
 215   | otherwise
 216   = getModeRn   `thenRn` \ mode ->
 217     if isInterfaceMode mode
 218         then lookupIfaceName rdr_name
 219     else
 220     getModuleRn         `thenRn` \ mod ->
 221     getGlobalNameEnv    `thenRn` \ global_env ->
 222     case lookup_local mod global_env rdr_name of
 223         Just name -> returnRn name
 224         Nothing   -> failWithRn (mkUnboundName rdr_name)
 225                                 (unknownNameErr rdr_name)
 226   where
 227     lookup_local mod global_env rdr_name
 228       = case lookupRdrEnv global_env rdr_name of
 229           Nothing   -> Nothing
 230           Just gres -> case [n | GRE n _ _ <- gres, nameIsLocalOrFrom mod n] of
 231                          []     -> Nothing
 232                          (n:ns) -> Just n
 233
 234
 235 -- lookupSigOccRn is used for type signatures and pragmas
 236 -- Is this valid?
 237 --   module A
 238 --      import M( f )
 239 --      f :: Int -> Int
 240 --      f x = x
 241 -- It's clear that the 'f' in the signature must refer to A.f
 242 -- The Haskell98 report does not stipulate this, but it will!
 243 -- So we must treat the 'f' in the signature in the same way
 244 -- as the binding occurrence of 'f', using lookupBndrRn
 245 lookupSigOccRn :: RdrName -> RnMS Name
 246 lookupSigOccRn = lookupBndrRn
 247
 248 -- lookupInstDeclBndr is used for the binders in an
 249 -- instance declaration.   Here we use the class name to
 250 -- disambiguate.
 251
 252 lookupInstDeclBndr :: Name -> RdrName -> RnMS Name
 253         -- We use the selector name as the binder
 254 lookupInstDeclBndr cls_name rdr_name
 255   | isOrig rdr_name     -- Occurs in derived instances, where we just
 256                         -- refer diectly to the right method
 257   = lookupOrigName rdr_name
 258
 259   | otherwise
 260   = getGlobalAvails     `thenRn` \ avail_env ->
 261     case lookupNameEnv avail_env cls_name of
 262           -- The class itself isn't in scope, so cls_name is unboundName
 263           -- e.g.   import Prelude hiding( Ord )
 264           --        instance Ord T where ...
 265           -- The program is wrong, but that should not cause a crash.
 266         Nothing -> returnRn (mkUnboundName rdr_name)
 267         Just (AvailTC _ ns) -> case [n | n <- ns, nameOccName n == occ] of
 268                                 (n:ns)-> ASSERT( null ns ) returnRn n
 269                                 []    -> failWithRn (mkUnboundName rdr_name)
 270                                                     (unknownNameErr rdr_name)
 271         other               -> pprPanic "lookupInstDeclBndr" (ppr cls_name)
 272   where
 273     occ = rdrNameOcc rdr_name
 274
 275 -- lookupOccRn looks up an occurrence of a RdrName
 276 lookupOccRn :: RdrName -> RnMS Name
 277 lookupOccRn rdr_name
 278   = getLocalNameEnv                     `thenRn` \ local_env ->
 279     case lookupRdrEnv local_env rdr_name of
 280           Just name -> returnRn name
 281           Nothing   -> lookupGlobalOccRn rdr_name
 282
 283 -- lookupGlobalOccRn is like lookupOccRn, except that it looks in the global
 284 -- environment.  It's used only for
 285 --      record field names
 286 --      class op names in class and instance decls
 287
 288 lookupGlobalOccRn rdr_name
 289   = getModeRn           `thenRn` \ mode ->
 290     if (isInterfaceMode mode)
 291         then lookupIfaceName rdr_name
 292         else
 293
 294     getGlobalNameEnv    `thenRn` \ global_env ->
 295     case mode of
 296         SourceMode -> lookupSrcName global_env rdr_name
 297
 298         CmdLineMode
 299          | not (isQual rdr_name) ->
 300                 lookupSrcName global_env rdr_name
 301
 302                 -- We allow qualified names on the command line to refer to
 303                 -- *any* name exported by any module in scope, just as if
 304                 -- there was an "import qualified M" declaration for every
 305                 -- module.
 306                 --
 307                 -- First look up the name in the normal environment.  If
 308                 -- it isn't there, we manufacture a new occurrence of an
 309                 -- original name.
 310          | otherwise ->
 311                 case lookupRdrEnv global_env rdr_name of
 312                        Just _  -> lookupSrcName global_env rdr_name
 313                        Nothing -> lookupQualifiedName rdr_name
 314
 315 -- a qualified name on the command line can refer to any module at all: we
 316 -- try to load the interface if we don't already have it.
 317 lookupQualifiedName :: RdrName -> RnM d Name
 318 lookupQualifiedName rdr_name
 319  = let
 320        mod = rdrNameModule rdr_name
 321        occ = rdrNameOcc rdr_name
 322    in
 323    loadInterface (ppr rdr_name) mod ImportByUser `thenRn` \ iface ->
 324    case  [ name | (_,avails) <- mi_exports iface,
 325            avail             <- avails,
 326            name              <- availNames avail,
 327            nameOccName name == occ ] of
 328       (n:ns) -> ASSERT (null ns) returnRn n
 329       _      -> failWithRn (mkUnboundName rdr_name) (unknownNameErr rdr_name)
 330
 331 lookupSrcName :: GlobalRdrEnv -> RdrName -> RnM d Name
 332 -- NB: passed GlobalEnv explicitly, not necessarily in RnMS monad
 333 lookupSrcName global_env rdr_name
 334   | isOrig rdr_name     -- Can occur in source code too
 335   = lookupOrigName rdr_name
 336
 337   | otherwise
 338   = case lookupRdrEnv global_env rdr_name of
 339         Just [GRE name _ Nothing]       -> returnRn name
 340         Just [GRE name _ (Just deprec)] -> warnDeprec name deprec       `thenRn_`
 341                                            returnRn name
 342         Just stuff@(GRE name _ _ : _)   -> addNameClashErrRn rdr_name stuff     `thenRn_`
 343                                            returnRn name
 344         Nothing                         -> failWithRn (mkUnboundName rdr_name)
 345                                                       (unknownNameErr rdr_name)
 346
 347 lookupOrigName :: RdrName -> RnM d Name
 348 lookupOrigName rdr_name
 349   = ASSERT( isOrig rdr_name )
 350     newGlobalName (rdrNameModule rdr_name) (rdrNameOcc rdr_name)
 351
 352 lookupIfaceUnqual :: RdrName -> RnM d Name
 353 lookupIfaceUnqual rdr_name
 354   = ASSERT( isUnqual rdr_name )
 355         -- An Unqual is allowed; interface files contain
 356         -- unqualified names for locally-defined things, such as
 357         -- constructors of a data type.
 358     getModuleRn                         `thenRn ` \ mod ->
 359     newGlobalName (moduleName mod) (rdrNameOcc rdr_name)
 360
 361 lookupIfaceName :: RdrName -> RnM d Name
 362 lookupIfaceName rdr_name
 363   | isUnqual rdr_name = lookupIfaceUnqual rdr_name
 364   | otherwise         = lookupOrigName rdr_name
 365 \end{code}
 366
 367 @lookupOrigName@ takes an RdrName representing an {\em original}
 368 name, and adds it to the occurrence pool so that it'll be loaded
 369 later.  This is used when language constructs (such as monad
 370 comprehensions, overloaded literals, or deriving clauses) require some
 371 stuff to be loaded that isn't explicitly mentioned in the code.
 372
 373 This doesn't apply in interface mode, where everything is explicit,
 374 but we don't check for this case: it does no harm to record an
 375 ``extra'' occurrence and @lookupOrigNames@ isn't used much in
 376 interface mode (it's only the @Nothing@ clause of @rnDerivs@ that
 377 calls it at all I think).
 378
 379   \fbox{{\em Jan 98: this comment is wrong: @rnHsType@ uses it quite a bit.}}
 380
 381 \begin{code}
 382 lookupOrigNames :: [RdrName] -> RnM d NameSet
 383 lookupOrigNames rdr_names
 384   = mapRn lookupOrigName rdr_names      `thenRn` \ names ->
 385     returnRn (mkNameSet names)
 386 \end{code}
 387
 388 lookupSysBinder is used for the "system binders" of a type, class, or
 389 instance decl.  It ensures that the module is set correctly in the
 390 name cache, and sets the provenance on the returned name too.  The
 391 returned name will end up actually in the type, class, or instance.
 392
 393 \begin{code}
 394 lookupSysBinder rdr_name
 395   = ASSERT( isUnqual rdr_name )
 396     getModuleRn                         `thenRn` \ mod ->
 397     getSrcLocRn                         `thenRn` \ loc ->
 398     newTopBinder mod rdr_name loc
 399 \end{code}
 400
 401
 402 %*********************************************************
 403 %*                                                      *
 404 \subsection{Implicit free vars and sugar names}
 405 %*                                                      *
 406 %*********************************************************
 407
 408 @getXImplicitFVs@ forces the renamer to slurp in some things which aren't
 409 mentioned explicitly, but which might be needed by the type checker.
 410
 411 \begin{code}
 412 getImplicitStmtFVs      -- Compiling a statement
 413   = returnRn (mkFVs [printName, bindIOName, returnIOName, failIOName]
 414               `plusFV` ubiquitousNames)
 415                 -- These are all needed implicitly when compiling a statement
 416                 -- See TcModule.tc_stmts
 417
 418 getImplicitModuleFVs mod_name decls     -- Compiling a module
 419   = lookupOrigNames deriv_occs          `thenRn` \ deriving_names ->
 420     returnRn (deriving_names `plusFV` implicit_main `plusFV` ubiquitousNames)
 421   where
 422         -- Add occurrences for IO or PrimIO
 423         implicit_main |  mod_name == mAIN_Name
 424                       || mod_name == pREL_MAIN_Name = unitFV ioTyConName
 425                       |  otherwise                  = emptyFVs
 426
 427         deriv_occs = [occ | TyClD (TyData {tcdDerivs = Just deriv_classes}) <- decls,
 428                             cls <- deriv_classes,
 429                             occ <- lookupWithDefaultUFM derivingOccurrences [] cls ]
 430
 431 -- ubiquitous_names are loaded regardless, because
 432 -- they are needed in virtually every program
 433 ubiquitousNames
 434   = mkFVs [unpackCStringName, unpackCStringFoldrName,
 435            unpackCStringUtf8Name, eqStringName]
 436         -- Virtually every program has error messages in it somewhere
 437
 438   `plusFV`
 439     mkFVs [getName unitTyCon, funTyConName, boolTyConName, intTyConName]
 440         -- Add occurrences for very frequently used types.
 441         --       (e.g. we don't want to be bothered with making funTyCon a
 442         --        free var at every function application!)
 443 \end{code}
 444
 445 %************************************************************************
 446 %*                                                                      *
 447 \subsection{Re-bindable desugaring names}
 448 %*                                                                      *
 449 %************************************************************************
 450
 451 Haskell 98 says that when you say "3" you get the "fromInteger" from the
 452 Standard Prelude, regardless of what is in scope.   However, to experiment
 453 with having a language that is less coupled to the standard prelude, we're
 454 trying a non-standard extension that instead gives you whatever "Prelude.fromInteger"
 455 happens to be in scope.  Then you can
 456         import Prelude ()
 457         import MyPrelude as Prelude
 458 to get the desired effect.
 459
 460 At the moment this just happens for
 461   * fromInteger, fromRational on literals (in expressions and patterns)
 462   * negate (in expressions)
 463   * minus  (arising from n+k patterns)
 464
 465 We store the relevant Name in the HsSyn tree, in
 466   * HsIntegral/HsFractional
 467   * NegApp
 468   * NPlusKPatIn
 469 respectively.  Initially, we just store the "standard" name (PrelNames.fromIntegralName,
 470 fromRationalName etc), but the renamer changes this to the appropriate user
 471 name if Opt_NoImplicitPrelude is on.  That is what lookupSyntaxName does.
 472
 473 \begin{code}
 474 lookupSyntaxName :: Name        -- The standard name
 475                  -> RnMS Name   -- Possibly a non-standard name
 476 lookupSyntaxName std_name
 477   = doptRn Opt_NoImplicitPrelude        `thenRn` \ no_prelude ->
 478     if not no_prelude then
 479         returnRn std_name       -- Normal case
 480     else
 481     let
 482         rdr_name = mkRdrUnqual (nameOccName std_name)
 483         -- Get the similarly named thing from the local environment
 484     in
 485     lookupOccRn rdr_name
 486 \end{code}
 487
 488
 489 %*********************************************************
 490 %*                                                      *
 491 \subsection{Binding}
 492 %*                                                      *
 493 %*********************************************************
 494
 495 \begin{code}
 496 newLocalsRn :: [(RdrName,SrcLoc)]
 497             -> RnMS [Name]
 498 newLocalsRn rdr_names_w_loc
 499  =  getNameSupplyRn             `thenRn` \ name_supply ->
 500     let
 501         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 502         uniqs      = uniqsFromSupply us1
 503         names      = [ mkLocalName uniq (rdrNameOcc rdr_name) loc
 504                      | ((rdr_name,loc), uniq) <- rdr_names_w_loc `zip` uniqs
 505                      ]
 506     in
 507     setNameSupplyRn (name_supply {nsUniqs = us'})       `thenRn_`
 508     returnRn names
 509
 510
 511 bindLocatedLocalsRn :: SDoc     -- Documentation string for error message
 512                     -> [(RdrName,SrcLoc)]
 513                     -> ([Name] -> RnMS a)
 514                     -> RnMS a
 515 bindLocatedLocalsRn doc_str rdr_names_w_loc enclosed_scope
 516   = getModeRn                           `thenRn` \ mode ->
 517     getLocalNameEnv                     `thenRn` \ local_env ->
 518     getGlobalNameEnv                    `thenRn` \ global_env ->
 519
 520         -- Check for duplicate names
 521     checkDupOrQualNames doc_str rdr_names_w_loc `thenRn_`
 522
 523         -- Warn about shadowing, but only in source modules
 524     let
 525       check_shadow (rdr_name,loc)
 526         |  rdr_name `elemRdrEnv` local_env
 527         || rdr_name `elemRdrEnv` global_env
 528         = pushSrcLocRn loc $ addWarnRn (shadowedNameWarn rdr_name)
 529         | otherwise
 530         = returnRn ()
 531     in
 532
 533     (case mode of
 534         SourceMode -> ifOptRn Opt_WarnNameShadowing     $
 535                       mapRn_ check_shadow rdr_names_w_loc
 536         other      -> returnRn ()
 537     )                                   `thenRn_`
 538
 539     newLocalsRn rdr_names_w_loc         `thenRn` \ names ->
 540     let
 541         new_local_env = addListToRdrEnv local_env (map fst rdr_names_w_loc `zip` names)
 542     in
 543     setLocalNameEnv new_local_env (enclosed_scope names)
 544
 545 bindCoreLocalRn :: RdrName -> (Name -> RnMS a) -> RnMS a
 546   -- A specialised variant when renaming stuff from interface
 547   -- files (of which there is a lot)
 548   --    * one at a time
 549   --    * no checks for shadowing
 550   --    * always imported
 551   --    * deal with free vars
 552 bindCoreLocalRn rdr_name enclosed_scope
 553   = getSrcLocRn                 `thenRn` \ loc ->
 554     getLocalNameEnv             `thenRn` \ name_env ->
 555     getNameSupplyRn             `thenRn` \ name_supply ->
 556     let
 557         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 558         uniq       = uniqFromSupply us1
 559         name       = mkLocalName uniq (rdrNameOcc rdr_name) loc
 560     in
 561     setNameSupplyRn (name_supply {nsUniqs = us'})       `thenRn_`
 562     let
 563         new_name_env = extendRdrEnv name_env rdr_name name
 564     in
 565     setLocalNameEnv new_name_env (enclosed_scope name)
 566
 567 bindCoreLocalsRn []     thing_inside = thing_inside []
 568 bindCoreLocalsRn (b:bs) thing_inside = bindCoreLocalRn b        $ \ name' ->
 569                                        bindCoreLocalsRn bs      $ \ names' ->
 570                                        thing_inside (name':names')
 571
 572 bindLocalNames names enclosed_scope
 573   = getLocalNameEnv             `thenRn` \ name_env ->
 574     setLocalNameEnv (extendLocalRdrEnv name_env names)
 575                     enclosed_scope
 576
 577 bindLocalNamesFV names enclosed_scope
 578   = bindLocalNames names $
 579     enclosed_scope `thenRn` \ (thing, fvs) ->
 580     returnRn (thing, delListFromNameSet fvs names)
 581
 582
 583 -------------------------------------
 584 bindLocalRn doc rdr_name enclosed_scope
 585   = getSrcLocRn                                 `thenRn` \ loc ->
 586     bindLocatedLocalsRn doc [(rdr_name,loc)]    $ \ (n:ns) ->
 587     ASSERT( null ns )
 588     enclosed_scope n
 589
 590 bindLocalsRn doc rdr_names enclosed_scope
 591   = getSrcLocRn         `thenRn` \ loc ->
 592     bindLocatedLocalsRn doc
 593                         (rdr_names `zip` repeat loc)
 594                         enclosed_scope
 595
 596         -- binLocalsFVRn is the same as bindLocalsRn
 597         -- except that it deals with free vars
 598 bindLocalsFVRn doc rdr_names enclosed_scope
 599   = bindLocalsRn doc rdr_names          $ \ names ->
 600     enclosed_scope names                `thenRn` \ (thing, fvs) ->
 601     returnRn (thing, delListFromNameSet fvs names)
 602
 603 -------------------------------------
 604 extendTyVarEnvFVRn :: [Name] -> RnMS (a, FreeVars) -> RnMS (a, FreeVars)
 605         -- This tiresome function is used only in rnSourceDecl on InstDecl
 606 extendTyVarEnvFVRn tyvars enclosed_scope
 607   = bindLocalNames tyvars enclosed_scope        `thenRn` \ (thing, fvs) ->
 608     returnRn (thing, delListFromNameSet fvs tyvars)
 609
 610 bindTyVarsRn :: SDoc -> [HsTyVarBndr RdrName]
 611               -> ([HsTyVarBndr Name] -> RnMS a)
 612               -> RnMS a
 613 bindTyVarsRn doc_str tyvar_names enclosed_scope
 614   = getSrcLocRn                                 `thenRn` \ loc ->
 615     let
 616         located_tyvars = [(hsTyVarName tv, loc) | tv <- tyvar_names]
 617     in
 618     bindLocatedLocalsRn doc_str located_tyvars  $ \ names ->
 619     enclosed_scope (zipWith replaceTyVarName tyvar_names names)
 620
 621 bindPatSigTyVars :: [RdrNameHsType]
 622                  -> RnMS (a, FreeVars)
 623                  -> RnMS (a, FreeVars)
 624   -- Find the type variables in the pattern type
 625   -- signatures that must be brought into scope
 626
 627 bindPatSigTyVars tys enclosed_scope
 628   = getLocalNameEnv                     `thenRn` \ name_env ->
 629     getSrcLocRn                         `thenRn` \ loc ->
 630     let
 631         forall_tyvars  = nub [ tv | ty <- tys,
 632                                     tv <- extractHsTyRdrTyVars ty,
 633                                     not (tv `elemFM` name_env)
 634                          ]
 635                 -- The 'nub' is important.  For example:
 636                 --      f (x :: t) (y :: t) = ....
 637                 -- We don't want to complain about binding t twice!
 638
 639         located_tyvars = [(tv, loc) | tv <- forall_tyvars]
 640         doc_sig        = text "In a pattern type-signature"
 641     in
 642     bindLocatedLocalsRn doc_sig located_tyvars  $ \ names ->
 643     enclosed_scope                              `thenRn` \ (thing, fvs) ->
 644     returnRn (thing, delListFromNameSet fvs names)
 645
 646
 647 -------------------------------------
 648 checkDupOrQualNames, checkDupNames :: SDoc
 649                                    -> [(RdrName, SrcLoc)]
 650                                    -> RnM d ()
 651         -- Works in any variant of the renamer monad
 652
 653 checkDupOrQualNames doc_str rdr_names_w_loc
 654   =     -- Check for use of qualified names
 655     mapRn_ (qualNameErr doc_str) quals  `thenRn_`
 656     checkDupNames doc_str rdr_names_w_loc
 657   where
 658     quals = filter (isQual . fst) rdr_names_w_loc
 659
 660 checkDupNames doc_str rdr_names_w_loc
 661   =     -- Check for duplicated names in a binding group
 662     mapRn_ (dupNamesErr doc_str) dups
 663   where
 664     (_, dups) = removeDups (\(n1,l1) (n2,l2) -> n1 `compare` n2) rdr_names_w_loc
 665 \end{code}
 666
 667
 668 %************************************************************************
 669 %*                                                                      *
 670 \subsection{GlobalRdrEnv}
 671 %*                                                                      *
 672 %************************************************************************
 673
 674 \begin{code}
 675 mkGlobalRdrEnv :: ModuleName            -- Imported module (after doing the "as M" name change)
 676                -> Bool                  -- True <=> want unqualified import
 677                -> (Name -> Provenance)
 678                -> Avails                -- Whats imported
 679                -> Deprecations
 680                -> GlobalRdrEnv
 681
 682 mkGlobalRdrEnv this_mod unqual_imp mk_provenance avails deprecs
 683   = gbl_env2
 684   where
 685         -- Make the name environment.  We're talking about a
 686         -- single module here, so there must be no name clashes.
 687         -- In practice there only ever will be if it's the module
 688         -- being compiled.
 689
 690         -- Add qualified names for the things that are available
 691         -- (Qualified names are always imported)
 692     gbl_env1 = foldl add_avail emptyRdrEnv avails
 693
 694         -- Add unqualified names
 695     gbl_env2 | unqual_imp = foldl add_unqual gbl_env1 (rdrEnvToList gbl_env1)
 696              | otherwise  = gbl_env1
 697
 698     add_unqual env (qual_name, elts)
 699         = foldl add_one env elts
 700         where
 701           add_one env elt = addOneToGlobalRdrEnv env unqual_name elt
 702           unqual_name     = unqualifyRdrName qual_name
 703         -- The qualified import should only have added one
 704         -- binding for each qualified name!  But if there's an error in
 705         -- the module (multiple bindings for the same name) we may get
 706         -- duplicates.  So the simple thing is to do the fold.
 707
 708     add_avail :: GlobalRdrEnv -> AvailInfo -> GlobalRdrEnv
 709     add_avail env avail = foldl add_name env (availNames avail)
 710
 711     add_name env name   -- Add qualified name only
 712         = addOneToGlobalRdrEnv env  (mkRdrQual this_mod occ) elt
 713         where
 714           occ  = nameOccName name
 715           elt  = GRE name (mk_provenance name) (lookupDeprec deprecs name)
 716
 717 mkIfaceGlobalRdrEnv :: [(ModuleName,Avails)] -> GlobalRdrEnv
 718 -- Used to construct a GlobalRdrEnv for an interface that we've
 719 -- read from a .hi file.  We can't construct the original top-level
 720 -- environment because we don't have enough info, but we compromise
 721 -- by making an environment from its exports
 722 mkIfaceGlobalRdrEnv m_avails
 723   = foldl add emptyRdrEnv m_avails
 724   where
 725     add env (mod,avails) = plusGlobalRdrEnv env (mkGlobalRdrEnv mod True
 726                                                                 (\n -> LocalDef) avails NoDeprecs)
 727                 -- The NoDeprecs is a bit of a hack I suppose
 728 \end{code}
 729
 730 \begin{code}
 731 plusGlobalRdrEnv :: GlobalRdrEnv -> GlobalRdrEnv -> GlobalRdrEnv
 732 plusGlobalRdrEnv env1 env2 = plusFM_C combine_globals env1 env2
 733
 734 addOneToGlobalRdrEnv :: GlobalRdrEnv -> RdrName -> GlobalRdrElt -> GlobalRdrEnv
 735 addOneToGlobalRdrEnv env rdr_name name = addToFM_C combine_globals env rdr_name [name]
 736
 737 delOneFromGlobalRdrEnv :: GlobalRdrEnv -> RdrName -> GlobalRdrEnv
 738 delOneFromGlobalRdrEnv env rdr_name = delFromFM env rdr_name
 739
 740 combine_globals :: [GlobalRdrElt]       -- Old
 741                 -> [GlobalRdrElt]       -- New
 742                 -> [GlobalRdrElt]
 743 combine_globals ns_old ns_new   -- ns_new is often short
 744   = foldr add ns_old ns_new
 745   where
 746     add n ns | any (is_duplicate n) ns_old = map (choose n) ns  -- Eliminate duplicates
 747              | otherwise                   = n:ns
 748
 749     choose n m | n `beats` m = n
 750                | otherwise   = m
 751
 752     (GRE n pn _) `beats` (GRE m pm _) = n==m && pn `hasBetterProv` pm
 753
 754     is_duplicate :: GlobalRdrElt -> GlobalRdrElt -> Bool
 755     is_duplicate (GRE n1 LocalDef _) (GRE n2 LocalDef _) = False
 756     is_duplicate (GRE n1 _        _) (GRE n2 _        _) = n1 == n2
 757 \end{code}
 758
 759 We treat two bindings of a locally-defined name as a duplicate,
 760 because they might be two separate, local defns and we want to report
 761 and error for that, {\em not} eliminate a duplicate.
 762
 763 On the other hand, if you import the same name from two different
 764 import statements, we {\em do} want to eliminate the duplicate, not report
 765 an error.
 766
 767 If a module imports itself then there might be a local defn and an imported
 768 defn of the same name; in this case the names will compare as equal, but
 769 will still have different provenances.
 770
 771
 772 @unQualInScope@ returns a function that takes a @Name@ and tells whether
 773 its unqualified name is in scope.  This is put as a boolean flag in
 774 the @Name@'s provenance to guide whether or not to print the name qualified
 775 in error messages.
 776
 777 \begin{code}
 778 unQualInScope :: GlobalRdrEnv -> Name -> Bool
 779 -- True if 'f' is in scope, and has only one binding,
 780 -- and the thing it is bound to is the name we are looking for
 781 -- (i.e. false if A.f and B.f are both in scope as unqualified 'f')
 782 --
 783 -- This fn is only efficient if the shared
 784 -- partial application is used a lot.
 785 unQualInScope env
 786   = (`elemNameSet` unqual_names)
 787   where
 788     unqual_names :: NameSet
 789     unqual_names = foldRdrEnv add emptyNameSet env
 790     add rdr_name [GRE name _ _] unquals | isUnqual rdr_name = addOneToNameSet unquals name
 791     add _        _              unquals                     = unquals
 792 \end{code}
 793
 794
 795 %************************************************************************
 796 %*                                                                      *
 797 \subsection{Avails}
 798 %*                                                                      *
 799 %************************************************************************
 800
 801 \begin{code}
 802 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 803 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (nub (ns1 ++ ns2))
 804 -- Added SOF 4/97
 805 #ifdef DEBUG
 806 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 807 #endif
 808
 809 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 810 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 811
 812 unitAvailEnv :: AvailInfo -> AvailEnv
 813 unitAvailEnv a = unitNameEnv (availName a) a
 814
 815 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 816 plusAvailEnv = plusNameEnv_C plusAvail
 817
 818 availEnvElts = nameEnvElts
 819
 820 addAvailToNameSet :: NameSet -> AvailInfo -> NameSet
 821 addAvailToNameSet names avail = addListToNameSet names (availNames avail)
 822
 823 availsToNameSet :: [AvailInfo] -> NameSet
 824 availsToNameSet avails = foldl addAvailToNameSet emptyNameSet avails
 825
 826 availName :: GenAvailInfo name -> name
 827 availName (Avail n)     = n
 828 availName (AvailTC n _) = n
 829
 830 availNames :: GenAvailInfo name -> [name]
 831 availNames (Avail n)      = [n]
 832 availNames (AvailTC n ns) = ns
 833
 834 -------------------------------------
 835 filterAvail :: RdrNameIE        -- Wanted
 836             -> AvailInfo        -- Available
 837             -> Maybe AvailInfo  -- Resulting available;
 838                                 -- Nothing if (any of the) wanted stuff isn't there
 839
 840 filterAvail ie@(IEThingWith want wants) avail@(AvailTC n ns)
 841   | sub_names_ok = Just (AvailTC n (filter is_wanted ns))
 842   | otherwise    = Nothing
 843   where
 844     is_wanted name = nameOccName name `elem` wanted_occs
 845     sub_names_ok   = all (`elem` avail_occs) wanted_occs
 846     avail_occs     = map nameOccName ns
 847     wanted_occs    = map rdrNameOcc (want:wants)
 848
 849 filterAvail (IEThingAbs _) (AvailTC n ns)       = ASSERT( n `elem` ns )
 850                                                   Just (AvailTC n [n])
 851
 852 filterAvail (IEThingAbs _) avail@(Avail n)      = Just avail            -- Type synonyms
 853
 854 filterAvail (IEVar _)      avail@(Avail n)      = Just avail
 855 filterAvail (IEVar v)      avail@(AvailTC n ns) = Just (AvailTC n (filter wanted ns))
 856                                                 where
 857                                                   wanted n = nameOccName n == occ
 858                                                   occ      = rdrNameOcc v
 859         -- The second equation happens if we import a class op, thus
 860         --      import A( op )
 861         -- where op is a class operation
 862
 863 filterAvail (IEThingAll _) avail@(AvailTC _ _)   = Just avail
 864         -- We don't complain even if the IE says T(..), but
 865         -- no constrs/class ops of T are available
 866         -- Instead that's caught with a warning by the caller
 867
 868 filterAvail ie avail = Nothing
 869
 870 -------------------------------------
 871 groupAvails :: Module -> Avails -> [(ModuleName, Avails)]
 872   -- Group by module and sort by occurrence
 873   -- This keeps the list in canonical order
 874 groupAvails this_mod avails
 875   = [ (mkSysModuleNameFS fs, sortLt lt avails)
 876     | (fs,avails) <- fmToList groupFM
 877     ]
 878   where
 879     groupFM :: FiniteMap FastString Avails
 880         -- Deliberately use the FastString so we
 881         -- get a canonical ordering
 882     groupFM = foldl add emptyFM avails
 883
 884     add env avail = addToFM_C combine env mod_fs [avail']
 885                   where
 886                     mod_fs = moduleNameFS (moduleName avail_mod)
 887                     avail_mod = case nameModule_maybe (availName avail) of
 888                                           Just m  -> m
 889                                           Nothing -> this_mod
 890                     combine old _ = avail':old
 891                     avail'        = sortAvail avail
 892
 893     a1 `lt` a2 = occ1 < occ2
 894                where
 895                  occ1  = nameOccName (availName a1)
 896                  occ2  = nameOccName (availName a2)
 897
 898 sortAvail :: AvailInfo -> AvailInfo
 899 -- Sort the sub-names into canonical order.
 900 -- The canonical order has the "main name" at the beginning
 901 -- (if it's there at all)
 902 sortAvail (Avail n) = Avail n
 903 sortAvail (AvailTC n ns) | n `elem` ns = AvailTC n (n : sortLt lt (filter (/= n) ns))
 904                          | otherwise   = AvailTC n (    sortLt lt ns)
 905                          where
 906                            n1 `lt` n2 = nameOccName n1 < nameOccName n2
 907 \end{code}
 908
 909 \begin{code}
 910 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 911             -> [AvailInfo]
 912             -> [AvailInfo]
 913 pruneAvails keep avails
 914   = mapMaybe del avails
 915   where
 916     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 917     del (Avail n) | keep n    = Just (Avail n)
 918                   | otherwise = Nothing
 919     del (AvailTC n ns) | null ns'  = Nothing
 920                        | otherwise = Just (AvailTC n ns')
 921                        where
 922                          ns' = filter keep ns
 923 \end{code}
 924
 925 %************************************************************************
 926 %*                                                                      *
 927 \subsection{Free variable manipulation}
 928 %*                                                                      *
 929 %************************************************************************
 930
 931 \begin{code}
 932 -- A useful utility
 933 mapFvRn f xs = mapRn f xs       `thenRn` \ stuff ->
 934                let
 935                   (ys, fvs_s) = unzip stuff
 936                in
 937                returnRn (ys, plusFVs fvs_s)
 938 \end{code}
 939
 940
 941 %************************************************************************
 942 %*                                                                      *
 943 \subsection{Envt utility functions}
 944 %*                                                                      *
 945 %************************************************************************
 946
 947 \begin{code}
 948 warnUnusedModules :: [ModuleName] -> RnM d ()
 949 warnUnusedModules mods
 950   = ifOptRn Opt_WarnUnusedImports (mapRn_ (addWarnRn . unused_mod) mods)
 951   where
 952     unused_mod m = vcat [ptext SLIT("Module") <+> quotes (ppr m) <+>
 953                            text "is imported, but nothing from it is used",
 954                          parens (ptext SLIT("except perhaps to re-export instances visible in") <+>
 955                                    quotes (ppr m))]
 956
 957 warnUnusedImports :: [(Name,Provenance)] -> RnM d ()
 958 warnUnusedImports names
 959   = ifOptRn Opt_WarnUnusedImports (warnUnusedBinds names)
 960
 961 warnUnusedLocalBinds, warnUnusedMatches :: [Name] -> RnM d ()
 962 warnUnusedLocalBinds names
 963   = ifOptRn Opt_WarnUnusedBinds (warnUnusedBinds [(n,LocalDef) | n<-names])
 964
 965 warnUnusedMatches names
 966   = ifOptRn Opt_WarnUnusedMatches (warnUnusedGroup [(n,LocalDef) | n<-names])
 967
 968 -------------------------
 969
 970 warnUnusedBinds :: [(Name,Provenance)] -> RnM d ()
 971 warnUnusedBinds names
 972   = mapRn_ warnUnusedGroup  groups
 973   where
 974         -- Group by provenance
 975    groups = equivClasses cmp names
 976    (_,prov1) `cmp` (_,prov2) = prov1 `compare` prov2
 977
 978
 979 -------------------------
 980
 981 warnUnusedGroup :: [(Name,Provenance)] -> RnM d ()
 982 warnUnusedGroup names
 983   | null filtered_names  = returnRn ()
 984   | not is_local         = returnRn ()
 985   | otherwise
 986   = pushSrcLocRn def_loc        $
 987     addWarnRn                   $
 988     sep [msg <> colon, nest 4 (fsep (punctuate comma (map (ppr.fst) filtered_names)))]
 989   where
 990     filtered_names = filter reportable names
 991     (name1, prov1) = head filtered_names
 992     (is_local, def_loc, msg)
 993         = case prov1 of
 994                 LocalDef -> (True, getSrcLoc name1, text "Defined but not used")
 995
 996                 NonLocalDef (UserImport mod loc _)
 997                         -> (True, loc, text "Imported from" <+> quotes (ppr mod) <+> text "but not used")
 998
 999     reportable (name,_) = case occNameUserString (nameOccName name) of
1000                                 ('_' : _) -> False
1001                                 zz_other  -> True
1002         -- Haskell 98 encourages compilers to suppress warnings about
1003         -- unused names in a pattern if they start with "_".
1004 \end{code}
1005
1006 \begin{code}
1007 addNameClashErrRn rdr_name (np1:nps)
1008   = addErrRn (vcat [ptext SLIT("Ambiguous occurrence") <+> quotes (ppr rdr_name),
1009                     ptext SLIT("It could refer to") <+> vcat (msg1 : msgs)])
1010   where
1011     msg1 = ptext  SLIT("either") <+> mk_ref np1
1012     msgs = [ptext SLIT("    or") <+> mk_ref np | np <- nps]
1013     mk_ref (GRE name prov _) = quotes (ppr name) <> comma <+> pprNameProvenance name prov
1014
1015 shadowedNameWarn shadow
1016   = hsep [ptext SLIT("This binding for"),
1017                quotes (ppr shadow),
1018                ptext SLIT("shadows an existing binding")]
1019
1020 unknownNameErr name
1021   = sep [text flavour, ptext SLIT("not in scope:"), quotes (ppr name)]
1022   where
1023     flavour = occNameFlavour (rdrNameOcc name)
1024
1025 qualNameErr descriptor (name,loc)
1026   = pushSrcLocRn loc $
1027     addErrRn (vcat [ ptext SLIT("Invalid use of qualified name") <+> quotes (ppr name),
1028                      descriptor])
1029
1030 dupNamesErr descriptor ((name,loc) : dup_things)
1031   = pushSrcLocRn loc $
1032     addErrRn ((ptext SLIT("Conflicting definitions for") <+> quotes (ppr name))
1033               $$
1034               descriptor)
1035
1036 warnDeprec :: Name -> DeprecTxt -> RnM d ()
1037 warnDeprec name txt
1038   = ifOptRn Opt_WarnDeprecations        $
1039     addWarnRn (sep [ text (occNameFlavour (nameOccName name)) <+>
1040                      quotes (ppr name) <+> text "is deprecated:",
1041                      nest 4 (ppr txt) ])
1042 \end{code}
1043