ghc/compiler/rename/RnEnv.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnEnv]{Environment manipulation for the renamer monad}
   5
   6 \begin{code}
   7 module RnEnv where              -- Export everything
   8
   9 #include "HsVersions.h"
  10
  11 import {-# SOURCE #-} RnHiFiles
  12
  13 import HsSyn
  14 import RdrHsSyn         ( RdrNameIE, RdrNameHsType, extractHsTyRdrTyVars )
  15 import RdrName          ( RdrName, rdrNameModule, rdrNameOcc, isQual, isUnqual, isOrig,
  16                           mkRdrUnqual, mkRdrQual,
  17                           lookupRdrEnv, foldRdrEnv, rdrEnvToList, elemRdrEnv,
  18                           unqualifyRdrName
  19                         )
  20 import HsTypes          ( hsTyVarName, replaceTyVarName )
  21 import HscTypes         ( Provenance(..), pprNameProvenance, hasBetterProv,
  22                           ImportReason(..), GlobalRdrEnv, GlobalRdrElt(..), AvailEnv,
  23                           AvailInfo, Avails, GenAvailInfo(..), NameSupply(..),
  24                           ModIface(..),
  25                           Deprecations(..), lookupDeprec,
  26                           extendLocalRdrEnv
  27                         )
  28 import RnMonad
  29 import Name             ( Name,
  30                           getSrcLoc, nameIsLocalOrFrom,
  31                           mkLocalName, mkGlobalName, nameModule,
  32                           mkIPName, nameOccName, nameModule_maybe,
  33                           setNameModuleAndLoc
  34                         )
  35 import NameEnv
  36 import NameSet
  37 import OccName          ( OccName, occNameUserString, occNameFlavour )
  38 import Module           ( ModuleName, moduleName, mkVanillaModule,
  39                           mkSysModuleNameFS, moduleNameFS, WhereFrom(..) )
  40 import PrelNames        ( mkUnboundName,
  41                           derivingOccurrences,
  42                           mAIN_Name, pREL_MAIN_Name,
  43                           ioTyConName, intTyConName,
  44                           boolTyConName, funTyConName,
  45                           unpackCStringName, unpackCStringFoldrName, unpackCStringUtf8Name,
  46                           eqStringName, printName,
  47                           bindIOName, returnIOName, failIOName
  48                         )
  49 import TysWiredIn       ( unitTyCon )   -- A little odd
  50 import FiniteMap
  51 import UniqSupply
  52 import SrcLoc           ( SrcLoc, noSrcLoc )
  53 import Outputable
  54 import ListSetOps       ( removeDups, equivClasses )
  55 import Util             ( sortLt )
  56 import BasicTypes       ( mapIPName )
  57 import List             ( nub )
  58 import UniqFM           ( lookupWithDefaultUFM )
  59 import Maybe            ( mapMaybe )
  60 import CmdLineOpts
  61 import FastString       ( FastString )
  62 \end{code}
  63
  64 %*********************************************************
  65 %*                                                      *
  66 \subsection{Making new names}
  67 %*                                                      *
  68 %*********************************************************
  69
  70 \begin{code}
  71 newTopBinder :: Module -> RdrName -> SrcLoc -> RnM d Name
  72         -- newTopBinder puts into the cache the binder with the
  73         -- module information set correctly.  When the decl is later renamed,
  74         -- the binding site will thereby get the correct module.
  75         -- There maybe occurrences that don't have the correct Module, but
  76         -- by the typechecker will propagate the binding definition to all
  77         -- the occurrences, so that doesn't matter
  78
  79 newTopBinder mod rdr_name loc
  80   =     -- First check the cache
  81
  82         -- There should never be a qualified name in a binding position (except in instance decls)
  83         -- The parser doesn't check this because the same parser parses instance decls
  84     (if isQual rdr_name then
  85         qualNameErr (text "In its declaration") (rdr_name,loc)
  86      else
  87         returnRn ()
  88     )                           `thenRn_`
  89
  90     getNameSupplyRn             `thenRn` \ name_supply ->
  91     let
  92         occ = rdrNameOcc rdr_name
  93         key = (moduleName mod, occ)
  94         cache = nsNames name_supply
  95     in
  96     case lookupFM cache key of
  97
  98         -- A hit in the cache!  We are at the binding site of the name, and
  99         -- this is the moment when we know all about
 100         --      a) the Name's host Module (in particular, which
 101         --         package it comes from)
 102         --      b) its defining SrcLoc
 103         -- So we update this info
 104
 105         Just name -> let
 106                         new_name  = setNameModuleAndLoc name mod loc
 107                         new_cache = addToFM cache key new_name
 108                      in
 109                      setNameSupplyRn (name_supply {nsNames = new_cache})        `thenRn_`
 110 --                   traceRn (text "newTopBinder: overwrite" <+> ppr new_name) `thenRn_`
 111                      returnRn new_name
 112
 113         -- Miss in the cache!
 114         -- Build a completely new Name, and put it in the cache
 115         -- Even for locally-defined names we use implicitImportProvenance;
 116         -- updateProvenances will set it to rights
 117         Nothing -> let
 118                         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 119                         uniq       = uniqFromSupply us1
 120                         new_name   = mkGlobalName uniq mod occ loc
 121                         new_cache  = addToFM cache key new_name
 122                    in
 123                    setNameSupplyRn (name_supply {nsUniqs = us', nsNames = new_cache})   `thenRn_`
 124 --                 traceRn (text "newTopBinder: new" <+> ppr new_name) `thenRn_`
 125                    returnRn new_name
 126
 127
 128 newGlobalName :: ModuleName -> OccName -> RnM d Name
 129   -- Used for *occurrences*.  We make a place-holder Name, really just
 130   -- to agree on its unique, which gets overwritten when we read in
 131   -- the binding occurence later (newTopBinder)
 132   -- The place-holder Name doesn't have the right SrcLoc, and its
 133   -- Module won't have the right Package either.
 134   --
 135   -- (We have to pass a ModuleName, not a Module, because we may be
 136   -- simply looking at an occurrence M.x in an interface file.)
 137   --
 138   -- This means that a renamed program may have incorrect info
 139   -- on implicitly-imported occurrences, but the correct info on the
 140   -- *binding* declaration. It's the type checker that propagates the
 141   -- correct information to all the occurrences.
 142   -- Since implicitly-imported names never occur in error messages,
 143   -- it doesn't matter that we get the correct info in place till later,
 144   -- (but since it affects DLL-ery it does matter that we get it right
 145   --  in the end).
 146 newGlobalName mod_name occ
 147   = getNameSupplyRn             `thenRn` \ name_supply ->
 148     let
 149         key = (mod_name, occ)
 150         cache = nsNames name_supply
 151     in
 152     case lookupFM cache key of
 153         Just name -> -- traceRn (text "newGlobalName: hit" <+> ppr name) `thenRn_`
 154                      returnRn name
 155
 156         Nothing   -> setNameSupplyRn (name_supply {nsUniqs = us', nsNames = new_cache})  `thenRn_`
 157                      -- traceRn (text "newGlobalName: new" <+> ppr name)                  `thenRn_`
 158                      returnRn name
 159                   where
 160                      (us', us1) = splitUniqSupply (nsUniqs name_supply)
 161                      uniq       = uniqFromSupply us1
 162                      mod        = mkVanillaModule mod_name
 163                      name       = mkGlobalName uniq mod occ noSrcLoc
 164                      new_cache  = addToFM cache key name
 165
 166 newIPName rdr_name_ip
 167   = getNameSupplyRn             `thenRn` \ name_supply ->
 168     let
 169         ipcache = nsIPs name_supply
 170     in
 171     case lookupFM ipcache key of
 172         Just name_ip -> returnRn name_ip
 173         Nothing      -> setNameSupplyRn new_ns  `thenRn_`
 174                         returnRn name_ip
 175                   where
 176                      (us', us1)  = splitUniqSupply (nsUniqs name_supply)
 177                      uniq        = uniqFromSupply us1
 178                      name_ip     = mapIPName mk_name rdr_name_ip
 179                      mk_name rdr_name = mkIPName uniq (rdrNameOcc rdr_name)
 180                      new_ipcache = addToFM ipcache key name_ip
 181                      new_ns      = name_supply {nsUniqs = us', nsIPs = new_ipcache}
 182     where
 183         key = rdr_name_ip       -- Ensures that ?x and %x get distinct Names
 184 \end{code}
 185
 186 %*********************************************************
 187 %*                                                      *
 188 \subsection{Looking up names}
 189 %*                                                      *
 190 %*********************************************************
 191
 192 Looking up a name in the RnEnv.
 193
 194 \begin{code}
 195 lookupBndrRn rdr_name
 196   = getLocalNameEnv             `thenRn` \ local_env ->
 197     case lookupRdrEnv local_env rdr_name of
 198           Just name -> returnRn name
 199           Nothing   -> lookupTopBndrRn rdr_name
 200
 201 lookupTopBndrRn rdr_name
 202 -- Look up a top-level local binder.   We may be looking up an unqualified 'f',
 203 -- and there may be several imported 'f's too, which must not confuse us.
 204 -- So we have to filter out the non-local ones.
 205 -- A separate function (importsFromLocalDecls) reports duplicate top level
 206 -- decls, so here it's safe just to choose an arbitrary one.
 207
 208   | isOrig rdr_name
 209         -- This is here just to catch the PrelBase defn of (say) [] and similar
 210         -- The parser reads the special syntax and returns an Orig RdrName
 211         -- But the global_env contains only Qual RdrNames, so we won't
 212         -- find it there; instead just get the name via the Orig route
 213   = lookupOrigName rdr_name
 214
 215   | otherwise
 216   = getModeRn   `thenRn` \ mode ->
 217     if isInterfaceMode mode
 218         then lookupIfaceName rdr_name
 219     else
 220     getModuleRn         `thenRn` \ mod ->
 221     getGlobalNameEnv    `thenRn` \ global_env ->
 222     case lookup_local mod global_env rdr_name of
 223         Just name -> returnRn name
 224         Nothing   -> failWithRn (mkUnboundName rdr_name)
 225                                 (unknownNameErr rdr_name)
 226   where
 227     lookup_local mod global_env rdr_name
 228       = case lookupRdrEnv global_env rdr_name of
 229           Nothing   -> Nothing
 230           Just gres -> case [n | GRE n _ _ <- gres, nameIsLocalOrFrom mod n] of
 231                          []     -> Nothing
 232                          (n:ns) -> Just n
 233
 234
 235 -- lookupSigOccRn is used for type signatures and pragmas
 236 -- Is this valid?
 237 --   module A
 238 --      import M( f )
 239 --      f :: Int -> Int
 240 --      f x = x
 241 -- It's clear that the 'f' in the signature must refer to A.f
 242 -- The Haskell98 report does not stipulate this, but it will!
 243 -- So we must treat the 'f' in the signature in the same way
 244 -- as the binding occurrence of 'f', using lookupBndrRn
 245 lookupSigOccRn :: RdrName -> RnMS Name
 246 lookupSigOccRn = lookupBndrRn
 247
 248 -- lookupInstDeclBndr is used for the binders in an
 249 -- instance declaration.   Here we use the class name to
 250 -- disambiguate.
 251
 252 lookupInstDeclBndr :: Name -> RdrName -> RnMS Name
 253         -- We use the selector name as the binder
 254 lookupInstDeclBndr cls_name rdr_name
 255   | isOrig rdr_name     -- Occurs in derived instances, where we just
 256                         -- refer diectly to the right method
 257   = lookupOrigName rdr_name
 258
 259   | otherwise
 260   = getGlobalAvails     `thenRn` \ avail_env ->
 261     case lookupNameEnv avail_env cls_name of
 262           -- The class itself isn't in scope, so cls_name is unboundName
 263           -- e.g.   import Prelude hiding( Ord )
 264           --        instance Ord T where ...
 265           -- The program is wrong, but that should not cause a crash.
 266         Nothing -> returnRn (mkUnboundName rdr_name)
 267         Just (AvailTC _ ns) -> case [n | n <- ns, nameOccName n == occ] of
 268                                 (n:ns)-> ASSERT( null ns ) returnRn n
 269                                 []    -> failWithRn (mkUnboundName rdr_name)
 270                                                     (unknownNameErr rdr_name)
 271         other               -> pprPanic "lookupInstDeclBndr" (ppr cls_name)
 272   where
 273     occ = rdrNameOcc rdr_name
 274
 275 -- lookupOccRn looks up an occurrence of a RdrName
 276 lookupOccRn :: RdrName -> RnMS Name
 277 lookupOccRn rdr_name
 278   = getLocalNameEnv                     `thenRn` \ local_env ->
 279     case lookupRdrEnv local_env rdr_name of
 280           Just name -> returnRn name
 281           Nothing   -> lookupGlobalOccRn rdr_name
 282
 283 -- lookupGlobalOccRn is like lookupOccRn, except that it looks in the global
 284 -- environment.  It's used only for
 285 --      record field names
 286 --      class op names in class and instance decls
 287
 288 lookupGlobalOccRn rdr_name
 289   = getModeRn           `thenRn` \ mode ->
 290     if (isInterfaceMode mode)
 291         then lookupIfaceName rdr_name
 292         else
 293
 294     getGlobalNameEnv    `thenRn` \ global_env ->
 295     case mode of
 296         SourceMode -> lookupSrcName global_env rdr_name
 297
 298         CmdLineMode
 299          | not (isQual rdr_name) ->
 300                 lookupSrcName global_env rdr_name
 301
 302                 -- We allow qualified names on the command line to refer to
 303                 -- *any* name exported by any module in scope, just as if
 304                 -- there was an "import qualified M" declaration for every
 305                 -- module.
 306                 --
 307                 -- First look up the name in the normal environment.  If
 308                 -- it isn't there, we manufacture a new occurrence of an
 309                 -- original name.
 310          | otherwise ->
 311                 case lookupRdrEnv global_env rdr_name of
 312                        Just _  -> lookupSrcName global_env rdr_name
 313                        Nothing -> lookupQualifiedName rdr_name
 314
 315 -- a qualified name on the command line can refer to any module at all: we
 316 -- try to load the interface if we don't already have it.
 317 lookupQualifiedName :: RdrName -> RnM d Name
 318 lookupQualifiedName rdr_name
 319  = let
 320        mod = rdrNameModule rdr_name
 321        occ = rdrNameOcc rdr_name
 322    in
 323    loadInterface (ppr rdr_name) mod ImportByUser `thenRn` \ iface ->
 324    case  [ name | (_,avails) <- mi_exports iface,
 325            avail             <- avails,
 326            name              <- availNames avail,
 327            nameOccName name == occ ] of
 328       (n:ns) -> ASSERT (null ns) returnRn n
 329       _      -> failWithRn (mkUnboundName rdr_name) (unknownNameErr rdr_name)
 330
 331 lookupSrcName :: GlobalRdrEnv -> RdrName -> RnM d Name
 332 -- NB: passed GlobalEnv explicitly, not necessarily in RnMS monad
 333 lookupSrcName global_env rdr_name
 334   | isOrig rdr_name     -- Can occur in source code too
 335   = lookupOrigName rdr_name
 336
 337   | otherwise
 338   = case lookupRdrEnv global_env rdr_name of
 339         Just [GRE name _ Nothing]       -> returnRn name
 340         Just [GRE name _ (Just deprec)] -> warnDeprec name deprec       `thenRn_`
 341                                            returnRn name
 342         Just stuff@(GRE name _ _ : _)   -> addNameClashErrRn rdr_name stuff     `thenRn_`
 343                                            returnRn name
 344         Nothing                         -> failWithRn (mkUnboundName rdr_name)
 345                                                       (unknownNameErr rdr_name)
 346
 347 lookupOrigName :: RdrName -> RnM d Name
 348 lookupOrigName rdr_name
 349   = ASSERT( isOrig rdr_name )
 350     newGlobalName (rdrNameModule rdr_name) (rdrNameOcc rdr_name)
 351
 352 lookupIfaceUnqual :: RdrName -> RnM d Name
 353 lookupIfaceUnqual rdr_name
 354   = ASSERT( isUnqual rdr_name )
 355         -- An Unqual is allowed; interface files contain
 356         -- unqualified names for locally-defined things, such as
 357         -- constructors of a data type.
 358     getModuleRn                         `thenRn ` \ mod ->
 359     newGlobalName (moduleName mod) (rdrNameOcc rdr_name)
 360
 361 lookupIfaceName :: RdrName -> RnM d Name
 362 lookupIfaceName rdr_name
 363   | isUnqual rdr_name = lookupIfaceUnqual rdr_name
 364   | otherwise         = lookupOrigName rdr_name
 365 \end{code}
 366
 367 @lookupOrigName@ takes an RdrName representing an {\em original}
 368 name, and adds it to the occurrence pool so that it'll be loaded
 369 later.  This is used when language constructs (such as monad
 370 comprehensions, overloaded literals, or deriving clauses) require some
 371 stuff to be loaded that isn't explicitly mentioned in the code.
 372
 373 This doesn't apply in interface mode, where everything is explicit,
 374 but we don't check for this case: it does no harm to record an
 375 ``extra'' occurrence and @lookupOrigNames@ isn't used much in
 376 interface mode (it's only the @Nothing@ clause of @rnDerivs@ that
 377 calls it at all I think).
 378
 379   \fbox{{\em Jan 98: this comment is wrong: @rnHsType@ uses it quite a bit.}}
 380
 381 \begin{code}
 382 lookupOrigNames :: [RdrName] -> RnM d NameSet
 383 lookupOrigNames rdr_names
 384   = mapRn lookupOrigName rdr_names      `thenRn` \ names ->
 385     returnRn (mkNameSet names)
 386 \end{code}
 387
 388 lookupSysBinder is used for the "system binders" of a type, class, or
 389 instance decl.  It ensures that the module is set correctly in the
 390 name cache, and sets the provenance on the returned name too.  The
 391 returned name will end up actually in the type, class, or instance.
 392
 393 \begin{code}
 394 lookupSysBinder rdr_name
 395   = ASSERT( isUnqual rdr_name )
 396     getModuleRn                         `thenRn` \ mod ->
 397     getSrcLocRn                         `thenRn` \ loc ->
 398     newTopBinder mod rdr_name loc
 399 \end{code}
 400
 401
 402 %*********************************************************
 403 %*                                                      *
 404 \subsection{Implicit free vars and sugar names}
 405 %*                                                      *
 406 %*********************************************************
 407
 408 @getXImplicitFVs@ forces the renamer to slurp in some things which aren't
 409 mentioned explicitly, but which might be needed by the type checker.
 410
 411 \begin{code}
 412 getImplicitStmtFVs      -- Compiling a statement
 413   = returnRn (mkFVs [printName, bindIOName, returnIOName, failIOName]
 414               `plusFV` ubiquitousNames)
 415                 -- These are all needed implicitly when compiling a statement
 416                 -- See TcModule.tc_stmts
 417
 418 getImplicitModuleFVs mod_name decls     -- Compiling a module
 419   = lookupOrigNames deriv_occs          `thenRn` \ deriving_names ->
 420     returnRn (deriving_names `plusFV` implicit_main `plusFV` ubiquitousNames)
 421   where
 422         -- Add occurrences for IO or PrimIO
 423         implicit_main |  mod_name == mAIN_Name
 424                       || mod_name == pREL_MAIN_Name = unitFV ioTyConName
 425                       |  otherwise                  = emptyFVs
 426
 427         -- deriv_classes is now a list of HsTypes, so a "normal" one
 428         -- appears as a (HsClassP c []).  The non-normal ones for the new
 429         -- newtype-deriving extension, and they don't require any
 430         -- implicit names, so we can silently filter them out.
 431         deriv_occs = [occ | TyClD (TyData {tcdDerivs = Just deriv_classes}) <- decls,
 432                             HsClassP cls [] <- deriv_classes,
 433                             occ <- lookupWithDefaultUFM derivingOccurrences [] cls ]
 434
 435 -- ubiquitous_names are loaded regardless, because
 436 -- they are needed in virtually every program
 437 ubiquitousNames
 438   = mkFVs [unpackCStringName, unpackCStringFoldrName,
 439            unpackCStringUtf8Name, eqStringName]
 440         -- Virtually every program has error messages in it somewhere
 441
 442   `plusFV`
 443     mkFVs [getName unitTyCon, funTyConName, boolTyConName, intTyConName]
 444         -- Add occurrences for very frequently used types.
 445         --       (e.g. we don't want to be bothered with making funTyCon a
 446         --        free var at every function application!)
 447 \end{code}
 448
 449 %************************************************************************
 450 %*                                                                      *
 451 \subsection{Re-bindable desugaring names}
 452 %*                                                                      *
 453 %************************************************************************
 454
 455 Haskell 98 says that when you say "3" you get the "fromInteger" from the
 456 Standard Prelude, regardless of what is in scope.   However, to experiment
 457 with having a language that is less coupled to the standard prelude, we're
 458 trying a non-standard extension that instead gives you whatever "Prelude.fromInteger"
 459 happens to be in scope.  Then you can
 460         import Prelude ()
 461         import MyPrelude as Prelude
 462 to get the desired effect.
 463
 464 At the moment this just happens for
 465   * fromInteger, fromRational on literals (in expressions and patterns)
 466   * negate (in expressions)
 467   * minus  (arising from n+k patterns)
 468
 469 We store the relevant Name in the HsSyn tree, in
 470   * HsIntegral/HsFractional
 471   * NegApp
 472   * NPlusKPatIn
 473 respectively.  Initially, we just store the "standard" name (PrelNames.fromIntegralName,
 474 fromRationalName etc), but the renamer changes this to the appropriate user
 475 name if Opt_NoImplicitPrelude is on.  That is what lookupSyntaxName does.
 476
 477 \begin{code}
 478 lookupSyntaxName :: Name        -- The standard name
 479                  -> RnMS Name   -- Possibly a non-standard name
 480 lookupSyntaxName std_name
 481   = doptRn Opt_NoImplicitPrelude        `thenRn` \ no_prelude ->
 482     if not no_prelude then
 483         returnRn std_name       -- Normal case
 484     else
 485     let
 486         rdr_name = mkRdrUnqual (nameOccName std_name)
 487         -- Get the similarly named thing from the local environment
 488     in
 489     lookupOccRn rdr_name
 490 \end{code}
 491
 492
 493 %*********************************************************
 494 %*                                                      *
 495 \subsection{Binding}
 496 %*                                                      *
 497 %*********************************************************
 498
 499 \begin{code}
 500 newLocalsRn :: [(RdrName,SrcLoc)]
 501             -> RnMS [Name]
 502 newLocalsRn rdr_names_w_loc
 503  =  getNameSupplyRn             `thenRn` \ name_supply ->
 504     let
 505         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 506         uniqs      = uniqsFromSupply us1
 507         names      = [ mkLocalName uniq (rdrNameOcc rdr_name) loc
 508                      | ((rdr_name,loc), uniq) <- rdr_names_w_loc `zip` uniqs
 509                      ]
 510     in
 511     setNameSupplyRn (name_supply {nsUniqs = us'})       `thenRn_`
 512     returnRn names
 513
 514
 515 bindLocatedLocalsRn :: SDoc     -- Documentation string for error message
 516                     -> [(RdrName,SrcLoc)]
 517                     -> ([Name] -> RnMS a)
 518                     -> RnMS a
 519 bindLocatedLocalsRn doc_str rdr_names_w_loc enclosed_scope
 520   = getModeRn                           `thenRn` \ mode ->
 521     getLocalNameEnv                     `thenRn` \ local_env ->
 522     getGlobalNameEnv                    `thenRn` \ global_env ->
 523
 524         -- Check for duplicate names
 525     checkDupOrQualNames doc_str rdr_names_w_loc `thenRn_`
 526
 527         -- Warn about shadowing, but only in source modules
 528     let
 529       check_shadow (rdr_name,loc)
 530         |  rdr_name `elemRdrEnv` local_env
 531         || rdr_name `elemRdrEnv` global_env
 532         = pushSrcLocRn loc $ addWarnRn (shadowedNameWarn rdr_name)
 533         | otherwise
 534         = returnRn ()
 535     in
 536
 537     (case mode of
 538         SourceMode -> ifOptRn Opt_WarnNameShadowing     $
 539                       mapRn_ check_shadow rdr_names_w_loc
 540         other      -> returnRn ()
 541     )                                   `thenRn_`
 542
 543     newLocalsRn rdr_names_w_loc         `thenRn` \ names ->
 544     let
 545         new_local_env = addListToRdrEnv local_env (map fst rdr_names_w_loc `zip` names)
 546     in
 547     setLocalNameEnv new_local_env (enclosed_scope names)
 548
 549 bindCoreLocalRn :: RdrName -> (Name -> RnMS a) -> RnMS a
 550   -- A specialised variant when renaming stuff from interface
 551   -- files (of which there is a lot)
 552   --    * one at a time
 553   --    * no checks for shadowing
 554   --    * always imported
 555   --    * deal with free vars
 556 bindCoreLocalRn rdr_name enclosed_scope
 557   = getSrcLocRn                 `thenRn` \ loc ->
 558     getLocalNameEnv             `thenRn` \ name_env ->
 559     getNameSupplyRn             `thenRn` \ name_supply ->
 560     let
 561         (us', us1) = splitUniqSupply (nsUniqs name_supply)
 562         uniq       = uniqFromSupply us1
 563         name       = mkLocalName uniq (rdrNameOcc rdr_name) loc
 564     in
 565     setNameSupplyRn (name_supply {nsUniqs = us'})       `thenRn_`
 566     let
 567         new_name_env = extendRdrEnv name_env rdr_name name
 568     in
 569     setLocalNameEnv new_name_env (enclosed_scope name)
 570
 571 bindCoreLocalsRn []     thing_inside = thing_inside []
 572 bindCoreLocalsRn (b:bs) thing_inside = bindCoreLocalRn b        $ \ name' ->
 573                                        bindCoreLocalsRn bs      $ \ names' ->
 574                                        thing_inside (name':names')
 575
 576 bindLocalNames names enclosed_scope
 577   = getLocalNameEnv             `thenRn` \ name_env ->
 578     setLocalNameEnv (extendLocalRdrEnv name_env names)
 579                     enclosed_scope
 580
 581 bindLocalNamesFV names enclosed_scope
 582   = bindLocalNames names $
 583     enclosed_scope `thenRn` \ (thing, fvs) ->
 584     returnRn (thing, delListFromNameSet fvs names)
 585
 586
 587 -------------------------------------
 588 bindLocalRn doc rdr_name enclosed_scope
 589   = getSrcLocRn                                 `thenRn` \ loc ->
 590     bindLocatedLocalsRn doc [(rdr_name,loc)]    $ \ (n:ns) ->
 591     ASSERT( null ns )
 592     enclosed_scope n
 593
 594 bindLocalsRn doc rdr_names enclosed_scope
 595   = getSrcLocRn         `thenRn` \ loc ->
 596     bindLocatedLocalsRn doc
 597                         (rdr_names `zip` repeat loc)
 598                         enclosed_scope
 599
 600         -- binLocalsFVRn is the same as bindLocalsRn
 601         -- except that it deals with free vars
 602 bindLocalsFVRn doc rdr_names enclosed_scope
 603   = bindLocalsRn doc rdr_names          $ \ names ->
 604     enclosed_scope names                `thenRn` \ (thing, fvs) ->
 605     returnRn (thing, delListFromNameSet fvs names)
 606
 607 -------------------------------------
 608 extendTyVarEnvFVRn :: [Name] -> RnMS (a, FreeVars) -> RnMS (a, FreeVars)
 609         -- This tiresome function is used only in rnSourceDecl on InstDecl
 610 extendTyVarEnvFVRn tyvars enclosed_scope
 611   = bindLocalNames tyvars enclosed_scope        `thenRn` \ (thing, fvs) ->
 612     returnRn (thing, delListFromNameSet fvs tyvars)
 613
 614 bindTyVarsRn :: SDoc -> [HsTyVarBndr RdrName]
 615               -> ([HsTyVarBndr Name] -> RnMS a)
 616               -> RnMS a
 617 bindTyVarsRn doc_str tyvar_names enclosed_scope
 618   = getSrcLocRn                                 `thenRn` \ loc ->
 619     let
 620         located_tyvars = [(hsTyVarName tv, loc) | tv <- tyvar_names]
 621     in
 622     bindLocatedLocalsRn doc_str located_tyvars  $ \ names ->
 623     enclosed_scope (zipWith replaceTyVarName tyvar_names names)
 624
 625 bindPatSigTyVars :: [RdrNameHsType]
 626                  -> RnMS (a, FreeVars)
 627                  -> RnMS (a, FreeVars)
 628   -- Find the type variables in the pattern type
 629   -- signatures that must be brought into scope
 630
 631 bindPatSigTyVars tys enclosed_scope
 632   = getLocalNameEnv                     `thenRn` \ name_env ->
 633     getSrcLocRn                         `thenRn` \ loc ->
 634     let
 635         forall_tyvars  = nub [ tv | ty <- tys,
 636                                     tv <- extractHsTyRdrTyVars ty,
 637                                     not (tv `elemFM` name_env)
 638                          ]
 639                 -- The 'nub' is important.  For example:
 640                 --      f (x :: t) (y :: t) = ....
 641                 -- We don't want to complain about binding t twice!
 642
 643         located_tyvars = [(tv, loc) | tv <- forall_tyvars]
 644         doc_sig        = text "In a pattern type-signature"
 645     in
 646     bindLocatedLocalsRn doc_sig located_tyvars  $ \ names ->
 647     enclosed_scope                              `thenRn` \ (thing, fvs) ->
 648     returnRn (thing, delListFromNameSet fvs names)
 649
 650
 651 -------------------------------------
 652 checkDupOrQualNames, checkDupNames :: SDoc
 653                                    -> [(RdrName, SrcLoc)]
 654                                    -> RnM d ()
 655         -- Works in any variant of the renamer monad
 656
 657 checkDupOrQualNames doc_str rdr_names_w_loc
 658   =     -- Check for use of qualified names
 659     mapRn_ (qualNameErr doc_str) quals  `thenRn_`
 660     checkDupNames doc_str rdr_names_w_loc
 661   where
 662     quals = filter (isQual . fst) rdr_names_w_loc
 663
 664 checkDupNames doc_str rdr_names_w_loc
 665   =     -- Check for duplicated names in a binding group
 666     mapRn_ (dupNamesErr doc_str) dups
 667   where
 668     (_, dups) = removeDups (\(n1,l1) (n2,l2) -> n1 `compare` n2) rdr_names_w_loc
 669 \end{code}
 670
 671
 672 %************************************************************************
 673 %*                                                                      *
 674 \subsection{GlobalRdrEnv}
 675 %*                                                                      *
 676 %************************************************************************
 677
 678 \begin{code}
 679 mkGlobalRdrEnv :: ModuleName            -- Imported module (after doing the "as M" name change)
 680                -> Bool                  -- True <=> want unqualified import
 681                -> (Name -> Provenance)
 682                -> Avails                -- Whats imported
 683                -> Deprecations
 684                -> GlobalRdrEnv
 685
 686 mkGlobalRdrEnv this_mod unqual_imp mk_provenance avails deprecs
 687   = gbl_env2
 688   where
 689         -- Make the name environment.  We're talking about a
 690         -- single module here, so there must be no name clashes.
 691         -- In practice there only ever will be if it's the module
 692         -- being compiled.
 693
 694         -- Add qualified names for the things that are available
 695         -- (Qualified names are always imported)
 696     gbl_env1 = foldl add_avail emptyRdrEnv avails
 697
 698         -- Add unqualified names
 699     gbl_env2 | unqual_imp = foldl add_unqual gbl_env1 (rdrEnvToList gbl_env1)
 700              | otherwise  = gbl_env1
 701
 702     add_unqual env (qual_name, elts)
 703         = foldl add_one env elts
 704         where
 705           add_one env elt = addOneToGlobalRdrEnv env unqual_name elt
 706           unqual_name     = unqualifyRdrName qual_name
 707         -- The qualified import should only have added one
 708         -- binding for each qualified name!  But if there's an error in
 709         -- the module (multiple bindings for the same name) we may get
 710         -- duplicates.  So the simple thing is to do the fold.
 711
 712     add_avail :: GlobalRdrEnv -> AvailInfo -> GlobalRdrEnv
 713     add_avail env avail = foldl add_name env (availNames avail)
 714
 715     add_name env name   -- Add qualified name only
 716         = addOneToGlobalRdrEnv env  (mkRdrQual this_mod occ) elt
 717         where
 718           occ  = nameOccName name
 719           elt  = GRE name (mk_provenance name) (lookupDeprec deprecs name)
 720
 721 mkIfaceGlobalRdrEnv :: [(ModuleName,Avails)] -> GlobalRdrEnv
 722 -- Used to construct a GlobalRdrEnv for an interface that we've
 723 -- read from a .hi file.  We can't construct the original top-level
 724 -- environment because we don't have enough info, but we compromise
 725 -- by making an environment from its exports
 726 mkIfaceGlobalRdrEnv m_avails
 727   = foldl add emptyRdrEnv m_avails
 728   where
 729     add env (mod,avails) = plusGlobalRdrEnv env (mkGlobalRdrEnv mod True
 730                                                                 (\n -> LocalDef) avails NoDeprecs)
 731                 -- The NoDeprecs is a bit of a hack I suppose
 732 \end{code}
 733
 734 \begin{code}
 735 plusGlobalRdrEnv :: GlobalRdrEnv -> GlobalRdrEnv -> GlobalRdrEnv
 736 plusGlobalRdrEnv env1 env2 = plusFM_C combine_globals env1 env2
 737
 738 addOneToGlobalRdrEnv :: GlobalRdrEnv -> RdrName -> GlobalRdrElt -> GlobalRdrEnv
 739 addOneToGlobalRdrEnv env rdr_name name = addToFM_C combine_globals env rdr_name [name]
 740
 741 delOneFromGlobalRdrEnv :: GlobalRdrEnv -> RdrName -> GlobalRdrEnv
 742 delOneFromGlobalRdrEnv env rdr_name = delFromFM env rdr_name
 743
 744 combine_globals :: [GlobalRdrElt]       -- Old
 745                 -> [GlobalRdrElt]       -- New
 746                 -> [GlobalRdrElt]
 747 combine_globals ns_old ns_new   -- ns_new is often short
 748   = foldr add ns_old ns_new
 749   where
 750     add n ns | any (is_duplicate n) ns_old = map (choose n) ns  -- Eliminate duplicates
 751              | otherwise                   = n:ns
 752
 753     choose n m | n `beats` m = n
 754                | otherwise   = m
 755
 756     (GRE n pn _) `beats` (GRE m pm _) = n==m && pn `hasBetterProv` pm
 757
 758     is_duplicate :: GlobalRdrElt -> GlobalRdrElt -> Bool
 759     is_duplicate (GRE n1 LocalDef _) (GRE n2 LocalDef _) = False
 760     is_duplicate (GRE n1 _        _) (GRE n2 _        _) = n1 == n2
 761 \end{code}
 762
 763 We treat two bindings of a locally-defined name as a duplicate,
 764 because they might be two separate, local defns and we want to report
 765 and error for that, {\em not} eliminate a duplicate.
 766
 767 On the other hand, if you import the same name from two different
 768 import statements, we {\em do} want to eliminate the duplicate, not report
 769 an error.
 770
 771 If a module imports itself then there might be a local defn and an imported
 772 defn of the same name; in this case the names will compare as equal, but
 773 will still have different provenances.
 774
 775
 776 @unQualInScope@ returns a function that takes a @Name@ and tells whether
 777 its unqualified name is in scope.  This is put as a boolean flag in
 778 the @Name@'s provenance to guide whether or not to print the name qualified
 779 in error messages.
 780
 781 \begin{code}
 782 unQualInScope :: GlobalRdrEnv -> Name -> Bool
 783 -- True if 'f' is in scope, and has only one binding,
 784 -- and the thing it is bound to is the name we are looking for
 785 -- (i.e. false if A.f and B.f are both in scope as unqualified 'f')
 786 --
 787 -- This fn is only efficient if the shared
 788 -- partial application is used a lot.
 789 unQualInScope env
 790   = (`elemNameSet` unqual_names)
 791   where
 792     unqual_names :: NameSet
 793     unqual_names = foldRdrEnv add emptyNameSet env
 794     add rdr_name [GRE name _ _] unquals | isUnqual rdr_name = addOneToNameSet unquals name
 795     add _        _              unquals                     = unquals
 796 \end{code}
 797
 798
 799 %************************************************************************
 800 %*                                                                      *
 801 \subsection{Avails}
 802 %*                                                                      *
 803 %************************************************************************
 804
 805 \begin{code}
 806 plusAvail (Avail n1)       (Avail n2)       = Avail n1
 807 plusAvail (AvailTC n1 ns1) (AvailTC n2 ns2) = AvailTC n2 (nub (ns1 ++ ns2))
 808 -- Added SOF 4/97
 809 #ifdef DEBUG
 810 plusAvail a1 a2 = pprPanic "RnEnv.plusAvail" (hsep [ppr a1,ppr a2])
 811 #endif
 812
 813 addAvail :: AvailEnv -> AvailInfo -> AvailEnv
 814 addAvail avails avail = extendNameEnv_C plusAvail avails (availName avail) avail
 815
 816 unitAvailEnv :: AvailInfo -> AvailEnv
 817 unitAvailEnv a = unitNameEnv (availName a) a
 818
 819 plusAvailEnv :: AvailEnv -> AvailEnv -> AvailEnv
 820 plusAvailEnv = plusNameEnv_C plusAvail
 821
 822 availEnvElts = nameEnvElts
 823
 824 addAvailToNameSet :: NameSet -> AvailInfo -> NameSet
 825 addAvailToNameSet names avail = addListToNameSet names (availNames avail)
 826
 827 availsToNameSet :: [AvailInfo] -> NameSet
 828 availsToNameSet avails = foldl addAvailToNameSet emptyNameSet avails
 829
 830 availName :: GenAvailInfo name -> name
 831 availName (Avail n)     = n
 832 availName (AvailTC n _) = n
 833
 834 availNames :: GenAvailInfo name -> [name]
 835 availNames (Avail n)      = [n]
 836 availNames (AvailTC n ns) = ns
 837
 838 -------------------------------------
 839 filterAvail :: RdrNameIE        -- Wanted
 840             -> AvailInfo        -- Available
 841             -> Maybe AvailInfo  -- Resulting available;
 842                                 -- Nothing if (any of the) wanted stuff isn't there
 843
 844 filterAvail ie@(IEThingWith want wants) avail@(AvailTC n ns)
 845   | sub_names_ok = Just (AvailTC n (filter is_wanted ns))
 846   | otherwise    = Nothing
 847   where
 848     is_wanted name = nameOccName name `elem` wanted_occs
 849     sub_names_ok   = all (`elem` avail_occs) wanted_occs
 850     avail_occs     = map nameOccName ns
 851     wanted_occs    = map rdrNameOcc (want:wants)
 852
 853 filterAvail (IEThingAbs _) (AvailTC n ns)       = ASSERT( n `elem` ns )
 854                                                   Just (AvailTC n [n])
 855
 856 filterAvail (IEThingAbs _) avail@(Avail n)      = Just avail            -- Type synonyms
 857
 858 filterAvail (IEVar _)      avail@(Avail n)      = Just avail
 859 filterAvail (IEVar v)      avail@(AvailTC n ns) = Just (AvailTC n (filter wanted ns))
 860                                                 where
 861                                                   wanted n = nameOccName n == occ
 862                                                   occ      = rdrNameOcc v
 863         -- The second equation happens if we import a class op, thus
 864         --      import A( op )
 865         -- where op is a class operation
 866
 867 filterAvail (IEThingAll _) avail@(AvailTC _ _)   = Just avail
 868         -- We don't complain even if the IE says T(..), but
 869         -- no constrs/class ops of T are available
 870         -- Instead that's caught with a warning by the caller
 871
 872 filterAvail ie avail = Nothing
 873
 874 -------------------------------------
 875 groupAvails :: Module -> Avails -> [(ModuleName, Avails)]
 876   -- Group by module and sort by occurrence
 877   -- This keeps the list in canonical order
 878 groupAvails this_mod avails
 879   = [ (mkSysModuleNameFS fs, sortLt lt avails)
 880     | (fs,avails) <- fmToList groupFM
 881     ]
 882   where
 883     groupFM :: FiniteMap FastString Avails
 884         -- Deliberately use the FastString so we
 885         -- get a canonical ordering
 886     groupFM = foldl add emptyFM avails
 887
 888     add env avail = addToFM_C combine env mod_fs [avail']
 889                   where
 890                     mod_fs = moduleNameFS (moduleName avail_mod)
 891                     avail_mod = case nameModule_maybe (availName avail) of
 892                                           Just m  -> m
 893                                           Nothing -> this_mod
 894                     combine old _ = avail':old
 895                     avail'        = sortAvail avail
 896
 897     a1 `lt` a2 = occ1 < occ2
 898                where
 899                  occ1  = nameOccName (availName a1)
 900                  occ2  = nameOccName (availName a2)
 901
 902 sortAvail :: AvailInfo -> AvailInfo
 903 -- Sort the sub-names into canonical order.
 904 -- The canonical order has the "main name" at the beginning
 905 -- (if it's there at all)
 906 sortAvail (Avail n) = Avail n
 907 sortAvail (AvailTC n ns) | n `elem` ns = AvailTC n (n : sortLt lt (filter (/= n) ns))
 908                          | otherwise   = AvailTC n (    sortLt lt ns)
 909                          where
 910                            n1 `lt` n2 = nameOccName n1 < nameOccName n2
 911 \end{code}
 912
 913 \begin{code}
 914 pruneAvails :: (Name -> Bool)   -- Keep if this is True
 915             -> [AvailInfo]
 916             -> [AvailInfo]
 917 pruneAvails keep avails
 918   = mapMaybe del avails
 919   where
 920     del :: AvailInfo -> Maybe AvailInfo -- Nothing => nothing left!
 921     del (Avail n) | keep n    = Just (Avail n)
 922                   | otherwise = Nothing
 923     del (AvailTC n ns) | null ns'  = Nothing
 924                        | otherwise = Just (AvailTC n ns')
 925                        where
 926                          ns' = filter keep ns
 927 \end{code}
 928
 929 %************************************************************************
 930 %*                                                                      *
 931 \subsection{Free variable manipulation}
 932 %*                                                                      *
 933 %************************************************************************
 934
 935 \begin{code}
 936 -- A useful utility
 937 mapFvRn f xs = mapRn f xs       `thenRn` \ stuff ->
 938                let
 939                   (ys, fvs_s) = unzip stuff
 940                in
 941                returnRn (ys, plusFVs fvs_s)
 942 \end{code}
 943
 944
 945 %************************************************************************
 946 %*                                                                      *
 947 \subsection{Envt utility functions}
 948 %*                                                                      *
 949 %************************************************************************
 950
 951 \begin{code}
 952 warnUnusedModules :: [ModuleName] -> RnM d ()
 953 warnUnusedModules mods
 954   = ifOptRn Opt_WarnUnusedImports (mapRn_ (addWarnRn . unused_mod) mods)
 955   where
 956     unused_mod m = vcat [ptext SLIT("Module") <+> quotes (ppr m) <+>
 957                            text "is imported, but nothing from it is used",
 958                          parens (ptext SLIT("except perhaps to re-export instances visible in") <+>
 959                                    quotes (ppr m))]
 960
 961 warnUnusedImports :: [(Name,Provenance)] -> RnM d ()
 962 warnUnusedImports names
 963   = ifOptRn Opt_WarnUnusedImports (warnUnusedBinds names)
 964
 965 warnUnusedLocalBinds, warnUnusedMatches :: [Name] -> RnM d ()
 966 warnUnusedLocalBinds names
 967   = ifOptRn Opt_WarnUnusedBinds (warnUnusedBinds [(n,LocalDef) | n<-names])
 968
 969 warnUnusedMatches names
 970   = ifOptRn Opt_WarnUnusedMatches (warnUnusedGroup [(n,LocalDef) | n<-names])
 971
 972 -------------------------
 973
 974 warnUnusedBinds :: [(Name,Provenance)] -> RnM d ()
 975 warnUnusedBinds names
 976   = mapRn_ warnUnusedGroup  groups
 977   where
 978         -- Group by provenance
 979    groups = equivClasses cmp names
 980    (_,prov1) `cmp` (_,prov2) = prov1 `compare` prov2
 981
 982
 983 -------------------------
 984
 985 warnUnusedGroup :: [(Name,Provenance)] -> RnM d ()
 986 warnUnusedGroup names
 987   | null filtered_names  = returnRn ()
 988   | not is_local         = returnRn ()
 989   | otherwise
 990   = pushSrcLocRn def_loc        $
 991     addWarnRn                   $
 992     sep [msg <> colon, nest 4 (fsep (punctuate comma (map (ppr.fst) filtered_names)))]
 993   where
 994     filtered_names = filter reportable names
 995     (name1, prov1) = head filtered_names
 996     (is_local, def_loc, msg)
 997         = case prov1 of
 998                 LocalDef -> (True, getSrcLoc name1, text "Defined but not used")
 999
1000                 NonLocalDef (UserImport mod loc _)
1001                         -> (True, loc, text "Imported from" <+> quotes (ppr mod) <+> text "but not used")
1002
1003     reportable (name,_) = case occNameUserString (nameOccName name) of
1004                                 ('_' : _) -> False
1005                                 zz_other  -> True
1006         -- Haskell 98 encourages compilers to suppress warnings about
1007         -- unused names in a pattern if they start with "_".
1008 \end{code}
1009
1010 \begin{code}
1011 addNameClashErrRn rdr_name (np1:nps)
1012   = addErrRn (vcat [ptext SLIT("Ambiguous occurrence") <+> quotes (ppr rdr_name),
1013                     ptext SLIT("It could refer to") <+> vcat (msg1 : msgs)])
1014   where
1015     msg1 = ptext  SLIT("either") <+> mk_ref np1
1016     msgs = [ptext SLIT("    or") <+> mk_ref np | np <- nps]
1017     mk_ref (GRE name prov _) = quotes (ppr name) <> comma <+> pprNameProvenance name prov
1018
1019 shadowedNameWarn shadow
1020   = hsep [ptext SLIT("This binding for"),
1021                quotes (ppr shadow),
1022                ptext SLIT("shadows an existing binding")]
1023
1024 unknownNameErr name
1025   = sep [text flavour, ptext SLIT("not in scope:"), quotes (ppr name)]
1026   where
1027     flavour = occNameFlavour (rdrNameOcc name)
1028
1029 qualNameErr descriptor (name,loc)
1030   = pushSrcLocRn loc $
1031     addErrRn (vcat [ ptext SLIT("Invalid use of qualified name") <+> quotes (ppr name),
1032                      descriptor])
1033
1034 dupNamesErr descriptor ((name,loc) : dup_things)
1035   = pushSrcLocRn loc $
1036     addErrRn ((ptext SLIT("Conflicting definitions for") <+> quotes (ppr name))
1037               $$
1038               descriptor)
1039
1040 warnDeprec :: Name -> DeprecTxt -> RnM d ()
1041 warnDeprec name txt
1042   = ifOptRn Opt_WarnDeprecations        $
1043     addWarnRn (sep [ text (occNameFlavour (nameOccName name)) <+>
1044                      quotes (ppr name) <+> text "is deprecated:",
1045                      nest 4 (ppr txt) ])
1046 \end{code}
1047