ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, findAndReadIface, loadInterface, loadHomeInterface,
   9         tryLoadInterface, loadOrphanModules,
  10         loadExports, loadFixDecls, loadDeprecs,
  11
  12         lookupFixityRn,
  13
  14         getTyClDeclBinders,
  15         removeContext           -- removeContext probably belongs somewhere else
  16    ) where
  17
  18 #include "HsVersions.h"
  19
  20 import CmdLineOpts      ( DynFlag(..), opt_IgnoreIfacePragmas )
  21 import HscTypes         ( ModuleLocation(..),
  22                           ModIface(..), emptyModIface,
  23                           VersionInfo(..),
  24                           lookupIfaceByModName,
  25                           ImportVersion, WhetherHasOrphans, IsBootInterface,
  26                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules,
  27                           AvailInfo, GenAvailInfo(..), Avails, Deprecations(..)
  28                          )
  29 import HsSyn            ( HsDecl(..), TyClDecl(..), InstDecl(..),
  30                           HsType(..), ConDecl(..),
  31                           FixitySig(..), RuleDecl(..),
  32                           tyClDeclNames
  33                         )
  34 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl,
  35                           extractHsTyRdrNames
  36                         )
  37 import BasicTypes       ( Version, defaultFixity )
  38 import RnEnv
  39 import RnMonad
  40 import ParseIface       ( parseIface, IfaceStuff(..) )
  41
  42 import Name             ( Name {-instance NamedThing-}, nameOccName,
  43                           nameModule, isLocalName, nameIsLocalOrFrom,
  44                           NamedThing(..),
  45                          )
  46 import Name             ( mkNameEnv, extendNameEnv )
  47 import Module           ( Module,
  48                           moduleName, isModuleInThisPackage,
  49                           ModuleName, WhereFrom(..),
  50                           extendModuleEnv, mkVanillaModule
  51                         )
  52 import RdrName          ( RdrName, rdrNameOcc )
  53 import NameSet
  54 import SrcLoc           ( mkSrcLoc )
  55 import Maybes           ( maybeToBool, orElse )
  56 import StringBuffer     ( hGetStringBuffer )
  57 import FastString       ( mkFastString )
  58 import ErrUtils         ( Message )
  59 import Finder           ( findModule )
  60 import Util             ( unJust )
  61 import Lex
  62 import FiniteMap
  63 import Outputable
  64 import Bag
  65
  66 import Monad            ( when )
  67 \end{code}
  68
  69
  70 %*********************************************************
  71 %*                                                      *
  72 \subsection{Loading a new interface file}
  73 %*                                                      *
  74 %*********************************************************
  75
  76 \begin{code}
  77 loadHomeInterface :: SDoc -> Name -> RnM d ModIface
  78 loadHomeInterface doc_str name
  79   = ASSERT2( not (isLocalName name), ppr name <+> parens doc_str )
  80     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  81
  82 loadOrphanModules :: [ModuleName] -> RnM d ()
  83 loadOrphanModules mods
  84   | null mods = returnRn ()
  85   | otherwise = traceRn (text "Loading orphan modules:" <+>
  86                          fsep (map ppr mods))                   `thenRn_`
  87                 mapRn_ load mods                                `thenRn_`
  88                 returnRn ()
  89   where
  90     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
  91     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
  92
  93 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d ModIface
  94 loadInterface doc mod from
  95   = tryLoadInterface doc mod from       `thenRn` \ (ifaces, maybe_err) ->
  96     case maybe_err of
  97         Nothing  -> returnRn ifaces
  98         Just err -> failWithRn ifaces err
  99
 100 tryLoadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (ModIface, Maybe Message)
 101   -- Returns (Just err) if an error happened
 102   -- It *doesn't* add an error to the monad, because sometimes it's ok to fail...
 103   -- Specifically, when we read the usage information from an interface file,
 104   -- we try to read the interfaces it mentions.  But it's OK to fail; perhaps
 105   -- the module has changed, and that interface is no longer used.
 106
 107   -- tryLoadInterface guarantees to return with iImpModInfo m --> (..., True)
 108   -- (If the load fails, we plug in a vanilla placeholder)
 109 tryLoadInterface doc_str mod_name from
 110  = getHomeIfaceTableRn          `thenRn` \ hit ->
 111    getIfacesRn                  `thenRn` \ ifaces@(Ifaces { iPIT = pit }) ->
 112
 113         -- CHECK WHETHER WE HAVE IT ALREADY
 114    case lookupIfaceByModName hit pit mod_name of {
 115         Just iface  -> returnRn (iface, Nothing) ;      -- Already loaded
 116         Nothing     ->
 117
 118    let
 119         mod_map  = iImpModInfo ifaces
 120         mod_info = lookupFM mod_map mod_name
 121
 122         hi_boot_file
 123           = case (from, mod_info) of
 124                 (ImportByUser,       _)             -> False    -- Not hi-boot
 125                 (ImportByUserSource, _)             -> True     -- hi-boot
 126                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 127                 (ImportBySystem, Nothing)           -> False
 128                         -- We're importing a module we know absolutely
 129                         -- nothing about, so we assume it's from
 130                         -- another package, where we aren't doing
 131                         -- dependency tracking. So it won't be a hi-boot file.
 132
 133         redundant_source_import
 134           = case (from, mod_info) of
 135                 (ImportByUserSource, Just (_,False)) -> True
 136                 other                                -> False
 137    in
 138
 139         -- Issue a warning for a redundant {- SOURCE -} import
 140         -- NB that we arrange to read all the ordinary imports before
 141         -- any of the {- SOURCE -} imports
 142    warnCheckRn  (not redundant_source_import)
 143                 (warnRedundantSourceImport mod_name)    `thenRn_`
 144
 145         -- READ THE MODULE IN
 146    findAndReadIface doc_str mod_name hi_boot_file   `thenRn` \ read_result ->
 147    case read_result of {
 148         Left err ->     -- Not found, so add an empty export env to the Ifaces map
 149                         -- so that we don't look again
 150            let
 151                 fake_mod    = mkVanillaModule mod_name
 152                 fake_iface  = emptyModIface fake_mod
 153                 new_ifaces  = ifaces { iPIT = extendModuleEnv pit fake_mod fake_iface }
 154            in
 155            setIfacesRn new_ifaces               `thenRn_`
 156            returnRn (fake_iface, Just err) ;
 157
 158         -- Found and parsed!
 159         Right (mod, iface) ->
 160
 161         -- LOAD IT INTO Ifaces
 162
 163         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 164         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 165         --     If we do loadExport first the wrong info gets into the cache (unless we
 166         --      explicitly tag each export which seems a bit of a bore)
 167
 168
 169         -- Sanity check.  If we're system-importing a module we know nothing at all
 170         -- about, it should be from a different package to this one
 171     WARN( not (maybeToBool mod_info) &&
 172           case from of { ImportBySystem -> True; other -> False } &&
 173           isModuleInThisPackage mod,
 174           ppr mod )
 175
 176     loadDecls mod               (iDecls ifaces)   (pi_decls iface)      `thenRn` \ (decls_vers, new_decls) ->
 177     loadRules mod               (iRules ifaces)   (pi_rules iface)      `thenRn` \ (rule_vers, new_rules) ->
 178     foldlRn (loadInstDecl mod)  (iInsts ifaces)   (pi_insts iface)      `thenRn` \ new_insts ->
 179     loadExports                                   (pi_exports iface)    `thenRn` \ (export_vers, avails) ->
 180     loadFixDecls mod                              (pi_fixity iface)     `thenRn` \ fix_env ->
 181     loadDeprecs mod                               (pi_deprecs iface)    `thenRn` \ deprec_env ->
 182     let
 183         version = VersionInfo { vers_module  = pi_vers iface,
 184                                 vers_exports = export_vers,
 185                                 vers_rules = rule_vers,
 186                                 vers_decls = decls_vers }
 187
 188         -- For an explicit user import, add to mod_map info about
 189         -- the things the imported module depends on, extracted
 190         -- from its usage info; and delete the module itself, which is now in the PIT
 191         mod_map1 = case from of
 192                         ImportByUser -> addModDeps mod is_loaded (pi_usages iface) mod_map
 193                         other        -> mod_map
 194         mod_map2 = delFromFM mod_map1 mod_name
 195         is_loaded m = maybeToBool (lookupIfaceByModName hit pit m)
 196
 197         -- Now add info about this module to the PIT
 198         has_orphans = pi_orphan iface
 199         new_pit   = extendModuleEnv pit mod mod_iface
 200         mod_iface = ModIface { mi_module = mod, mi_version = version,
 201                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 202                                mi_exports = avails,
 203                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 204                                mi_usages  = [], -- Will be filled in later
 205                                mi_decls   = panic "No mi_decls in PIT",
 206                                mi_globals = panic "No mi_globals in PIT"
 207                     }
 208
 209         new_ifaces = ifaces { iPIT        = new_pit,
 210                               iDecls      = new_decls,
 211                               iInsts      = new_insts,
 212                               iRules      = new_rules,
 213                               iImpModInfo = mod_map2  }
 214     in
 215     setIfacesRn new_ifaces              `thenRn_`
 216     returnRn (mod_iface, Nothing)
 217     }}
 218
 219 -----------------------------------------------------
 220 --      Adding module dependencies from the
 221 --      import decls in the interface file
 222 -----------------------------------------------------
 223
 224 addModDeps :: Module
 225            -> (ModuleName -> Bool)      -- True for module interfaces
 226            -> [ImportVersion a]
 227            -> ImportedModuleInfo -> ImportedModuleInfo
 228 -- (addModDeps M ivs deps)
 229 -- We are importing module M, and M.hi contains 'import' decls given by ivs
 230 addModDeps mod is_loaded new_deps mod_deps
 231   = foldr add mod_deps filtered_new_deps
 232   where
 233         -- Don't record dependencies when importing a module from another package
 234         -- Except for its descendents which contain orphans,
 235         -- and in that case, forget about the boot indicator
 236     filtered_new_deps :: [(ModuleName, (WhetherHasOrphans, IsBootInterface))]
 237     filtered_new_deps
 238         | isModuleInThisPackage mod
 239                             = [ (imp_mod, (has_orphans, is_boot))
 240                               | (imp_mod, has_orphans, is_boot, _) <- new_deps,
 241                                 not (is_loaded imp_mod)
 242                               ]
 243         | otherwise         = [ (imp_mod, (True, False))
 244                               | (imp_mod, has_orphans, _, _) <- new_deps,
 245                                 not (is_loaded imp_mod) && has_orphans
 246                               ]
 247     add (imp_mod, dep) deps = addToFM_C combine deps imp_mod dep
 248
 249     combine old@(old_has_orphans, old_is_boot) new@(new_has_orphans, new_is_boot)
 250         | old_is_boot = new     -- Record the best is_boot info
 251         | otherwise   = old
 252
 253 -----------------------------------------------------
 254 --      Loading the export list
 255 -----------------------------------------------------
 256
 257 loadExports :: (Version, [ExportItem]) -> RnM d (Version, [(ModuleName,Avails)])
 258 loadExports (vers, items)
 259   = getModuleRn                                 `thenRn` \ this_mod ->
 260     mapRn (loadExport this_mod) items           `thenRn` \ avails_s ->
 261     returnRn (vers, avails_s)
 262
 263
 264 loadExport :: Module -> ExportItem -> RnM d (ModuleName, Avails)
 265 loadExport this_mod (mod, entities)
 266   | mod == moduleName this_mod = returnRn (mod, [])
 267         -- If the module exports anything defined in this module, just ignore it.
 268         -- Reason: otherwise it looks as if there are two local definition sites
 269         -- for the thing, and an error gets reported.  Easiest thing is just to
 270         -- filter them out up front. This situation only arises if a module
 271         -- imports itself, or another module that imported it.  (Necessarily,
 272         -- this invoves a loop.)  Consequence: if you say
 273         --      module A where
 274         --         import B( AType )
 275         --         type AType = ...
 276         --
 277         --      module B( AType ) where
 278         --         import {-# SOURCE #-} A( AType )
 279         --
 280         -- then you'll get a 'B does not export AType' message.  A bit bogus
 281         -- but it's a bogus thing to do!
 282
 283   | otherwise
 284   = mapRn (load_entity mod) entities    `thenRn` \ avails ->
 285     returnRn (mod, avails)
 286   where
 287     load_entity mod (Avail occ)
 288       = newGlobalName mod occ   `thenRn` \ name ->
 289         returnRn (Avail name)
 290     load_entity mod (AvailTC occ occs)
 291       = newGlobalName mod occ           `thenRn` \ name ->
 292         mapRn (newGlobalName mod) occs  `thenRn` \ names ->
 293         returnRn (AvailTC name names)
 294
 295
 296 -----------------------------------------------------
 297 --      Loading type/class/value decls
 298 -----------------------------------------------------
 299
 300 loadDecls :: Module
 301           -> DeclsMap
 302           -> [(Version, RdrNameTyClDecl)]
 303           -> RnM d (NameEnv Version, DeclsMap)
 304 loadDecls mod decls_map decls
 305   = foldlRn (loadDecl mod) (emptyNameEnv, decls_map) decls
 306
 307 loadDecl :: Module
 308          -> (NameEnv Version, DeclsMap)
 309          -> (Version, RdrNameTyClDecl)
 310          -> RnM d (NameEnv Version, DeclsMap)
 311 loadDecl mod (version_map, decls_map) (version, decl)
 312   = getIfaceDeclBinders mod decl        `thenRn` \ full_avail ->
 313     let
 314         main_name     = availName full_avail
 315         new_decls_map = extendNameEnvList decls_map stuff
 316         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 317                         | name <- availNames full_avail]
 318
 319         new_version_map = extendNameEnv version_map main_name version
 320     in
 321     returnRn (new_version_map, new_decls_map)
 322
 323 -----------------------------------------------------
 324 --      Loading fixity decls
 325 -----------------------------------------------------
 326
 327 loadFixDecls mod decls
 328   = mapRn (loadFixDecl mod_name) decls  `thenRn` \ to_add ->
 329     returnRn (mkNameEnv to_add)
 330   where
 331     mod_name = moduleName mod
 332
 333 loadFixDecl mod_name sig@(FixitySig rdr_name fixity loc)
 334   = newGlobalName mod_name (rdrNameOcc rdr_name)        `thenRn` \ name ->
 335     returnRn (name, fixity)
 336
 337
 338 -----------------------------------------------------
 339 --      Loading instance decls
 340 -----------------------------------------------------
 341
 342 loadInstDecl :: Module
 343              -> IfaceInsts
 344              -> RdrNameInstDecl
 345              -> RnM d IfaceInsts
 346 loadInstDecl mod insts decl@(InstDecl inst_ty binds uprags dfun_name src_loc)
 347   =
 348         -- Find out what type constructors and classes are "gates" for the
 349         -- instance declaration.  If all these "gates" are slurped in then
 350         -- we should slurp the instance decl too.
 351         --
 352         -- We *don't* want to count names in the context part as gates, though.
 353         -- For example:
 354         --              instance Foo a => Baz (T a) where ...
 355         --
 356         -- Here the gates are Baz and T, but *not* Foo.
 357     let
 358         munged_inst_ty = removeContext inst_ty
 359         free_names     = extractHsTyRdrNames munged_inst_ty
 360     in
 361     setModuleRn mod $
 362     mapRn lookupOrigName free_names     `thenRn` \ gate_names ->
 363     returnRn ((mkNameSet gate_names, (mod, InstD decl)) `consBag` insts)
 364
 365
 366 -- In interface files, the instance decls now look like
 367 --      forall a. Foo a -> Baz (T a)
 368 -- so we have to strip off function argument types as well
 369 -- as the bit before the '=>' (which is always empty in interface files)
 370 removeContext (HsForAllTy tvs cxt ty) = HsForAllTy tvs [] (removeFuns ty)
 371 removeContext ty                      = removeFuns ty
 372
 373 removeFuns (HsFunTy _ ty) = removeFuns ty
 374 removeFuns ty               = ty
 375
 376
 377 -----------------------------------------------------
 378 --      Loading Rules
 379 -----------------------------------------------------
 380
 381 loadRules :: Module -> IfaceRules
 382           -> (Version, [RdrNameRuleDecl])
 383           -> RnM d (Version, IfaceRules)
 384 loadRules mod rule_bag (version, rules)
 385   | null rules || opt_IgnoreIfacePragmas
 386   = returnRn (version, rule_bag)
 387   | otherwise
 388   = setModuleRn mod                     $
 389     mapRn (loadRule mod) rules          `thenRn` \ new_rules ->
 390     returnRn (version, rule_bag `unionBags` listToBag new_rules)
 391
 392 loadRule :: Module -> RdrNameRuleDecl -> RnM d GatedDecl
 393 -- "Gate" the rule simply by whether the rule variable is
 394 -- needed.  We can refine this later.
 395 loadRule mod decl@(IfaceRule _ _ var _ _ src_loc)
 396   = lookupOrigName var          `thenRn` \ var_name ->
 397     returnRn (unitNameSet var_name, (mod, RuleD decl))
 398
 399
 400 -----------------------------------------------------
 401 --      Loading Deprecations
 402 -----------------------------------------------------
 403
 404 loadDeprecs :: Module -> IfaceDeprecs -> RnM d Deprecations
 405 loadDeprecs m Nothing                                  = returnRn NoDeprecs
 406 loadDeprecs m (Just (Left txt))  = returnRn (DeprecAll txt)
 407 loadDeprecs m (Just (Right prs)) = setModuleRn m                                $
 408                                    foldlRn loadDeprec emptyNameEnv prs  `thenRn` \ env ->
 409                                    returnRn (DeprecSome env)
 410 loadDeprec deprec_env (n, txt)
 411   = lookupOrigName n            `thenRn` \ name ->
 412     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenRn_`
 413     returnRn (extendNameEnv deprec_env name (name,txt))
 414 \end{code}
 415
 416
 417 %*********************************************************
 418 %*                                                      *
 419 \subsection{Getting binders out of a declaration}
 420 %*                                                      *
 421 %*********************************************************
 422
 423 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 424 It's used for both source code (from @availsFromDecl@) and interface files
 425 (from @loadDecl@).
 426
 427 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 428 are handled by the sourc-code specific stuff in @RnNames@.
 429
 430 \begin{code}
 431 getIfaceDeclBinders, getTyClDeclBinders
 432         :: Module
 433         -> RdrNameTyClDecl
 434         -> RnM d AvailInfo
 435
 436 getIfaceDeclBinders mod tycl_decl
 437   = getTyClDeclBinders    mod tycl_decl `thenRn` \ avail ->
 438     getSysTyClDeclBinders mod tycl_decl `thenRn` \ extras ->
 439     returnRn (addSysAvails avail extras)
 440                 -- Add the sys-binders to avail.  When we import the decl,
 441                 -- it's full_avail that will get added to the 'already-slurped' set (iSlurp)
 442                 -- If we miss out sys-binders, we'll read the decl multiple times!
 443
 444 getTyClDeclBinders mod (IfaceSig var ty prags src_loc)
 445   = newTopBinder mod var src_loc                        `thenRn` \ var_name ->
 446     returnRn (Avail var_name)
 447
 448 getTyClDeclBinders mod tycl_decl
 449   = mapRn do_one (tyClDeclNames tycl_decl)      `thenRn` \ (main_name:sub_names) ->
 450     returnRn (AvailTC main_name (main_name : sub_names))
 451   where
 452     do_one (name,loc) = newTopBinder mod name loc
 453 \end{code}
 454
 455 @getDeclSysBinders@ gets the implicit binders introduced by a decl.
 456 A the moment that's just the tycon and datacon that come with a class decl.
 457 They aren't returned by @getDeclBinders@ because they aren't in scope;
 458 but they {\em should} be put into the @DeclsMap@ of this module.
 459
 460 Note that this excludes the default-method names of a class decl,
 461 and the dict fun of an instance decl, because both of these have
 462 bindings of their own elsewhere.
 463
 464 \begin{code}
 465 getSysTyClDeclBinders mod (ClassDecl _ cname _ _ sigs _ names src_loc)
 466   = sequenceRn [newTopBinder mod n src_loc | n <- names]
 467
 468 getSysTyClDeclBinders mod (TyData _ _ _ _ cons _ _ _ _ _)
 469   = sequenceRn [newTopBinder mod wkr_name src_loc | ConDecl _ wkr_name _ _ _ src_loc <- cons]
 470
 471 getSysTyClDeclBinders mod other_decl
 472   = returnRn []
 473 \end{code}
 474
 475 %*********************************************************
 476 %*                                                      *
 477 \subsection{Reading an interface file}
 478 %*                                                      *
 479 %*********************************************************
 480
 481 \begin{code}
 482 findAndReadIface :: SDoc -> ModuleName
 483                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 484                                         -- False <=> Look for .hi file
 485                  -> RnM d (Either Message (Module, ParsedIface))
 486         -- Nothing <=> file not found, or unreadable, or illegible
 487         -- Just x  <=> successfully found and parsed
 488
 489 findAndReadIface doc_str mod_name hi_boot_file
 490   = traceRn trace_msg                   `thenRn_`
 491     ioToRnM (findModule mod_name)       `thenRn` \ maybe_found ->
 492     doptRn Opt_D_dump_rn_trace          `thenRn` \ rn_trace ->
 493     case maybe_found of
 494       Right (Just (wanted_mod,locn))
 495         -> ioToRnM_no_fail (
 496               readIface rn_trace
 497                  (unJust (ml_hi_file locn) "findAndReadIface"
 498                   ++ if hi_boot_file then "-boot" else "")
 499            )
 500                                         `thenRn` \ read_result ->
 501            case read_result of
 502               Left bad -> returnRn (Left bad)
 503               Right iface
 504                  -> let read_mod = pi_mod iface
 505                     in warnCheckRn (wanted_mod == read_mod)
 506                                    (hiModuleNameMismatchWarn wanted_mod read_mod)
 507                                         `thenRn_`
 508                        returnRn (Right (wanted_mod, iface))
 509         -- Can't find it
 510       other   -> traceRn (ptext SLIT("...not found"))   `thenRn_`
 511                  returnRn (Left (noIfaceErr mod_name hi_boot_file))
 512
 513   where
 514     trace_msg = sep [hsep [ptext SLIT("Reading"),
 515                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 516                            ptext SLIT("interface for"),
 517                            ppr mod_name <> semi],
 518                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 519 \end{code}
 520
 521 @readIface@ tries just the one file.
 522
 523 \begin{code}
 524 readIface :: Bool -> String -> IO (Either Message ParsedIface)
 525         -- Nothing <=> file not found, or unreadable, or illegible
 526         -- Just x  <=> successfully found and parsed
 527 readIface tr file_path
 528   = when tr (printErrs (ptext SLIT("readIFace") <+> text file_path))
 529     >>
 530     ((hGetStringBuffer False file_path  >>= \ contents ->
 531         case parseIface contents
 532                         PState{ bol = 0#, atbol = 1#,
 533                                 context = [],
 534                                 glasgow_exts = 1#,
 535                                 loc = mkSrcLoc (mkFastString file_path) 1 } of
 536                   POk _  (PIface iface) -> return (Right iface)
 537                   PFailed err   -> bale_out err
 538                   parse_result  -> bale_out empty
 539                         -- This last case can happen if the interface file is (say) empty
 540                         -- in which case the parser thinks it looks like an IdInfo or
 541                         -- something like that.  Just an artefact of the fact that the
 542                         -- parser is used for several purposes at once.
 543    )
 544    `catch`
 545    (\ io_err -> bale_out (text (show io_err))))
 546   where
 547     bale_out err = return (Left (badIfaceFile file_path err))
 548 \end{code}
 549
 550
 551 %*********************************************************
 552 %*                                                      *
 553 \subsection{Looking up fixities}
 554 %*                                                      *
 555 %*********************************************************
 556
 557 @lookupFixityRn@ has to be in RnIfaces (or RnHiFiles) because
 558 it calls @loadHomeInterface@.
 559
 560 lookupFixity is a bit strange.
 561
 562 * Nested local fixity decls are put in the local fixity env, which we
 563   find with getFixtyEnv
 564
 565 * Imported fixities are found in the HIT or PIT
 566
 567 * Top-level fixity decls in this module may be for Names that are
 568     either  Global         (constructors, class operations)
 569     or      Local/Exported (everything else)
 570   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 571   We put them all in the local fixity environment
 572
 573 \begin{code}
 574 lookupFixityRn :: Name -> RnMS Fixity
 575 lookupFixityRn name
 576   = getModuleRn                         `thenRn` \ this_mod ->
 577     if nameIsLocalOrFrom this_mod name
 578     then        -- It's defined in this module
 579         getFixityEnv                    `thenRn` \ local_fix_env ->
 580         returnRn (lookupLocalFixity local_fix_env name)
 581
 582     else        -- It's imported
 583       -- For imported names, we have to get their fixities by doing a loadHomeInterface,
 584       -- and consulting the Ifaces that comes back from that, because the interface
 585       -- file for the Name might not have been loaded yet.  Why not?  Suppose you import module A,
 586       -- which exports a function 'f', which is defined in module B.  Then B isn't loaded
 587       -- right away (after all, it's possible that nothing from B will be used).
 588       -- When we come across a use of 'f', we need to know its fixity, and it's then,
 589       -- and only then, that we load B.hi.  That is what's happening here.
 590         loadHomeInterface doc name              `thenRn` \ iface ->
 591         returnRn (lookupNameEnv (mi_fixities iface) name `orElse` defaultFixity)
 592   where
 593     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 594 \end{code}
 595
 596
 597 %*********************************************************
 598 %*                                                       *
 599 \subsection{Errors}
 600 %*                                                       *
 601 %*********************************************************
 602
 603 \begin{code}
 604 noIfaceErr mod_name boot_file
 605   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 606         -- We used to print the search path, but we can't do that
 607         -- now, because it's hidden inside the finder.
 608         -- Maybe the finder should expose more functions.
 609
 610 badIfaceFile file err
 611   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 612           nest 4 err]
 613
 614 hiModuleNameMismatchWarn :: Module -> Module  -> Message
 615 hiModuleNameMismatchWarn requested_mod read_mod =
 616     hsep [ ptext SLIT("Something is amiss; requested module name")
 617          , ppr (moduleName requested_mod)
 618          , ptext SLIT("differs from name found in the interface file")
 619          , ppr read_mod
 620          ]
 621
 622 warnRedundantSourceImport mod_name
 623   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 624           <+> quotes (ppr mod_name)
 625 \end{code}
 626