ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, loadInterface, loadHomeInterface,
   9         loadOrphanModules,
  10         loadOldIface,
  11         ParsedIface(..)
  12    ) where
  13
  14 #include "HsVersions.h"
  15
  16 import DriverState      ( v_GhcMode, isCompManagerMode )
  17 import DriverUtil       ( splitFilename, replaceFilenameSuffix )
  18 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  19 import Parser           ( parseIface )
  20 import HscTypes         ( ModIface(..), emptyModIface,
  21                           ExternalPackageState(..), noDependencies,
  22                           VersionInfo(..), Usage(..),
  23                           lookupIfaceByModName, RdrExportItem,
  24                           IsBootInterface,
  25                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules, mkIfaceDecls,
  26                           AvailInfo, GenAvailInfo(..), ParsedIface(..), IfaceDeprecs,
  27                           Avails, availNames, availName, Deprecations(..)
  28                          )
  29 import HsSyn            ( TyClDecl(..), InstDecl(..), RuleDecl(..), ConDecl(..),
  30                           hsTyVarNames, splitHsInstDeclTy, tyClDeclName, tyClDeclNames
  31                         )
  32 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl )
  33 import RnHsSyn          ( RenamedInstDecl, RenamedRuleDecl, RenamedTyClDecl,
  34                           extractHsTyNames_s )
  35 import BasicTypes       ( Version, FixitySig(..), Fixity(..), FixityDirection(..) )
  36 import RnSource         ( rnIfaceRuleDecl, rnTyClDecl, rnInstDecl )
  37 import RnTypes          ( rnHsType )
  38 import RnEnv
  39 import TcRnMonad
  40
  41 import PrelNames        ( gHC_PRIM_Name, gHC_PRIM )
  42 import PrelInfo         ( ghcPrimExports, cCallableClassDecl, cReturnableClassDecl )
  43 import Name             ( Name {-instance NamedThing-},
  44                           nameModule, isInternalName )
  45 import NameEnv
  46 import NameSet
  47 import Id               ( idName )
  48 import MkId             ( seqId )
  49 import Packages         ( basePackage )
  50 import Module           ( Module, ModuleName, ModLocation(ml_hi_file),
  51                           moduleName, isHomeModule, mkPackageModule,
  52                           extendModuleEnv, lookupModuleEnvByName
  53                         )
  54 import RdrName          ( RdrName, mkRdrUnqual, rdrNameOcc, nameRdrName )
  55 import OccName          ( OccName, mkWorkerOcc, mkClassTyConOcc, mkClassDataConOcc,
  56                           mkSuperDictSelOcc, mkGenOcc1, mkGenOcc2 )
  57 import TyCon            ( DataConDetails(..) )
  58 import SrcLoc           ( noSrcLoc, mkSrcLoc )
  59 import Maybes           ( maybeToBool )
  60 import StringBuffer     ( hGetStringBuffer )
  61 import FastString       ( mkFastString )
  62 import ErrUtils         ( Message )
  63 import Finder           ( findModule, findPackageModule,
  64                           hiBootExt, hiBootVerExt )
  65 import Lex
  66 import FiniteMap
  67 import ListSetOps       ( minusList )
  68 import Outputable
  69 import Bag
  70 import BinIface         ( readBinIface )
  71 import Panic
  72 import Config
  73
  74 import EXCEPTION as Exception
  75 import DATA_IOREF       ( readIORef )
  76
  77 import Directory
  78 \end{code}
  79
  80
  81 %*********************************************************
  82 %*                                                      *
  83 \subsection{Loading a new interface file}
  84 %*                                                      *
  85 %*********************************************************
  86
  87 \begin{code}
  88 loadHomeInterface :: SDoc -> Name -> TcRn m ModIface
  89 loadHomeInterface doc_str name
  90   = ASSERT2( not (isInternalName name), ppr name <+> parens doc_str )
  91     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  92
  93 loadOrphanModules :: [ModuleName] -> TcRn m ()
  94 loadOrphanModules mods
  95   | null mods = returnM ()
  96   | otherwise = traceRn (text "Loading orphan modules:" <+>
  97                          fsep (map ppr mods))                   `thenM_`
  98                 mappM_ load mods                                `thenM_`
  99                 returnM ()
 100   where
 101     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
 102     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
 103
 104 loadInterface :: SDoc -> ModuleName -> WhereFrom -> TcRn m ModIface
 105   -- Returns Nothing if failed
 106   -- If we can't find an interface file, and we are doing ImportForUsage,
 107   --    just fail in the monad, and modify anything else
 108   -- Otherwise, if we can't find an interface file,
 109   --    add an error message to the monad (the first time only)
 110   --    and return emptyIface
 111   -- The "first time only" part is done by modifying the PackageIfaceTable
 112   --            to have an empty entry
 113   --
 114   -- The ImportForUsage case is because when we read the usage information from
 115   -- an interface file, we try to read the interfaces it mentions.
 116   -- But it's OK to fail; perhaps the module has changed, and that interface
 117   -- is no longer used.
 118
 119 loadInterface doc_str mod_name from
 120  = getHpt               `thenM` \ hpt ->
 121    getModule            `thenM` \ this_mod ->
 122    getImports           `thenM` \ import_avails ->
 123    getEps               `thenM` \ eps@(EPS { eps_PIT = pit }) ->
 124
 125         -- CHECK WHETHER WE HAVE IT ALREADY
 126    case lookupIfaceByModName hpt pit mod_name of {
 127         Just iface |  case from of
 128                         ImportByUser   src_imp -> src_imp == mi_boot iface
 129                         ImportForUsage src_imp -> src_imp == mi_boot iface
 130                         ImportBySystem         -> True
 131                    -> returnM iface ;           -- Already loaded
 132                         -- The not (mi_boot iface) test checks that the already-loaded
 133                         -- interface isn't a boot iface.  This can conceivably happen,
 134                         -- if the version checking happened to load a boot interface
 135                         -- before we got to real imports.
 136         other       ->
 137
 138    let
 139         mod_map  = imp_dep_mods import_avails
 140         mod_info = lookupModuleEnvByName mod_map mod_name
 141
 142         hi_boot_file
 143           = case (from, mod_info) of
 144                 (ImportByUser   is_boot, _)         -> is_boot
 145                 (ImportForUsage is_boot, _)         -> is_boot
 146                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 147                 (ImportBySystem, Nothing)           -> False
 148                         -- We're importing a module we know absolutely
 149                         -- nothing about, so we assume it's from
 150                         -- another package, where we aren't doing
 151                         -- dependency tracking. So it won't be a hi-boot file.
 152
 153         redundant_source_import
 154           = case (from, mod_info) of
 155                 (ImportByUser True, Just (_, False)) -> True
 156                 other                                -> False
 157    in
 158
 159         -- Issue a warning for a redundant {- SOURCE -} import
 160         -- NB that we arrange to read all the ordinary imports before
 161         -- any of the {- SOURCE -} imports
 162    warnIf       redundant_source_import
 163                 (warnRedundantSourceImport mod_name)    `thenM_`
 164
 165         -- Check that we aren't importing ourselves.
 166         -- That only happens in Rename.checkOldIface,
 167         -- which doesn't call loadInterface
 168    warnIf
 169         (isHomeModule this_mod && moduleName this_mod == mod_name)
 170         (warnSelfImport this_mod)               `thenM_`
 171
 172         -- READ THE MODULE IN
 173    findAndReadIface doc_str mod_name hi_boot_file
 174                                             `thenM` \ read_result ->
 175    case read_result of {
 176         Left err
 177           | case from of { ImportForUsage _ -> True ; other -> False }
 178           -> failM      -- Fail with no error messages
 179
 180           |  otherwise
 181           -> let        -- Not found, so add an empty export env to
 182                         -- the EPS map so that we don't look again
 183                 fake_mod   = mkPackageModule mod_name
 184                 fake_iface = emptyModIface fake_mod
 185                 new_eps    = eps { eps_PIT = extendModuleEnv pit fake_mod fake_iface }
 186              in
 187              setEps new_eps             `thenM_`
 188              addErr (elaborate err)     `thenM_`
 189              returnM fake_iface
 190           where
 191             elaborate err = hang (ptext SLIT("Failed to load interface for") <+>
 192                                   quotes (ppr mod_name) <> colon) 4 err
 193           ;
 194
 195         -- Found and parsed!
 196         Right (mod, iface) ->
 197
 198         -- LOAD IT INTO EPS
 199
 200         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 201         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 202         --     If we do loadExport first the wrong info gets into the cache (unless we
 203         --      explicitly tag each export which seems a bit of a bore)
 204
 205
 206         -- Sanity check.  If we're system-importing a module we know nothing at all
 207         -- about, it should be from a different package to this one
 208     WARN( not (maybeToBool mod_info) &&
 209           case from of { ImportBySystem -> True; other -> False } &&
 210           isHomeModule mod,
 211           ppr mod )
 212
 213     initRn (InterfaceMode mod)                                  $
 214         -- Set the module, for use when looking up occurrences
 215         -- of names in interface decls and rules
 216     loadDecls mod       (eps_decls eps)   (pi_decls iface)      `thenM` \ (decls_vers, new_decls) ->
 217     loadRules     mod   (eps_rules eps)   (pi_rules iface)      `thenM` \ (rule_vers, new_rules) ->
 218     loadInstDecls mod   (eps_insts eps)   (pi_insts iface)      `thenM` \ new_insts ->
 219     loadExports                           (pi_exports iface)    `thenM` \ (export_vers, avails) ->
 220     loadFixDecls                          (pi_fixity iface)     `thenM` \ fix_env ->
 221     loadDeprecs                           (pi_deprecs iface)    `thenM` \ deprec_env ->
 222    let
 223         version = VersionInfo { vers_module  = pi_vers iface,
 224                                 vers_exports = export_vers,
 225                                 vers_rules = rule_vers,
 226                                 vers_decls = decls_vers }
 227
 228         this_mod_name = moduleName this_mod
 229         is_loaded m   =  m == this_mod_name
 230                       || maybeToBool (lookupIfaceByModName hpt pit m)
 231                 -- We treat the currently-being-compiled module as 'loaded' because
 232                 -- even though it isn't yet in the HIT or PIT; otherwise it gets
 233                 -- put into iImpModInfo, and then spat out into its own interface
 234                 -- file as a dependency
 235
 236         -- Now add info about this module to the PIT
 237         has_orphans = pi_orphan iface
 238         new_pit   = extendModuleEnv pit mod mod_iface
 239         mod_iface = ModIface { mi_module = mod, mi_package = pi_pkg iface,
 240                                mi_version = version,
 241                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 242                                mi_exports = avails,
 243                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 244                                mi_deps     = pi_deps iface,
 245                                mi_usages   = panic "No mi_usages in PIT",
 246                                mi_decls    = panic "No mi_decls in PIT",
 247                                mi_globals  = Nothing
 248                     }
 249
 250         new_eps = eps { eps_PIT      = new_pit,
 251                         eps_decls    = new_decls,
 252                         eps_insts    = new_insts,
 253                         eps_rules    = new_rules }
 254     in
 255     setEps new_eps              `thenM_`
 256     returnM mod_iface
 257     }}
 258
 259 -----------------------------------------------------
 260 --      Loading the export list
 261 -----------------------------------------------------
 262
 263 loadExports :: (Version, [RdrExportItem]) -> TcRn m (Version, [(ModuleName,Avails)])
 264 loadExports (vers, items)
 265   = mappM loadExport items      `thenM` \ avails_s ->
 266     returnM (vers, avails_s)
 267
 268
 269 loadExport :: RdrExportItem -> TcRn m (ModuleName, Avails)
 270 loadExport (mod, entities)
 271   = mappM (load_entity mod) entities    `thenM` \ avails ->
 272     returnM (mod, avails)
 273   where
 274     load_entity mod (Avail occ)
 275       = newGlobalName2 mod occ  `thenM` \ name ->
 276         returnM (Avail name)
 277     load_entity mod (AvailTC occ occs)
 278       = newGlobalName2 mod occ          `thenM` \ name ->
 279         mappM (newGlobalName2 mod) occs `thenM` \ names ->
 280         returnM (AvailTC name names)
 281
 282
 283 -----------------------------------------------------
 284 --      Loading type/class/value decls
 285 -----------------------------------------------------
 286
 287 loadDecls :: Module
 288           -> DeclsMap
 289           -> [(Version, RdrNameTyClDecl)]
 290           -> TcRn m (NameEnv Version, DeclsMap)
 291 loadDecls mod (decls_map, n_slurped) decls
 292   = foldlM (loadDecl mod) (emptyNameEnv, decls_map) decls       `thenM` \ (vers, decls_map') ->
 293     returnM (vers, (decls_map', n_slurped))
 294
 295 loadDecl mod (version_map, decls_map) (version, decl)
 296   = getTyClDeclBinders mod decl         `thenM` \ avail ->
 297     getSysBinders mod decl              `thenM` \ sys_names ->
 298     let
 299         full_avail    = case avail of
 300                           Avail n -> avail
 301                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 302         main_name     = availName full_avail
 303         new_decls_map = extendNameEnvList decls_map stuff
 304         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 305                         | name <- availNames full_avail]
 306
 307         new_version_map = extendNameEnv version_map main_name version
 308     in
 309     traceRn (text "Loading" <+> ppr full_avail) `thenM_`
 310     returnM (new_version_map, new_decls_map)
 311
 312
 313
 314 -----------------
 315 getTyClDeclBinders :: Module -> RdrNameTyClDecl -> TcRn m AvailInfo
 316
 317 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 318   = newTopBinder mod var src_loc                        `thenM` \ var_name ->
 319     returnM (Avail var_name)
 320
 321 getTyClDeclBinders mod tycl_decl
 322   = mapM new (tyClDeclNames tycl_decl)  `thenM` \ names@(main_name:_) ->
 323     returnM (AvailTC main_name names)
 324   where
 325     new (nm,loc) = newTopBinder mod nm loc
 326
 327 --------------------------------
 328 -- The "system names" are extra implicit names *bound* by the decl.
 329
 330 getSysBinders :: Module -> TyClDecl RdrName -> TcRn m [Name]
 331 -- Similar to tyClDeclNames, but returns the "implicit"
 332 -- or "system" names of the declaration.  And it only works
 333 -- on RdrNames, returning OccNames
 334
 335 getSysBinders mod (ClassDecl {tcdName = cname, tcdCtxt = cxt, tcdLoc = loc})
 336   = sequenceM [new_sys_bndr mod n loc | n <- sys_occs]
 337   where
 338         -- C.f. TcClassDcl.tcClassDecl1
 339     sys_occs    = tc_occ : data_occ : dw_occ : sc_sel_occs
 340     cls_occ     = rdrNameOcc cname
 341     data_occ    = mkClassDataConOcc cls_occ
 342     dw_occ      = mkWorkerOcc data_occ
 343     tc_occ      = mkClassTyConOcc   cls_occ
 344     sc_sel_occs = [mkSuperDictSelOcc n cls_occ | n <- [1..length cxt]]
 345
 346 getSysBinders mod (TyData {tcdName = tc_name, tcdCons = DataCons cons,
 347                            tcdGeneric = Just want_generic, tcdLoc = loc})
 348         -- The 'Just' is because this is an interface-file decl
 349         -- so it will say whether to derive generic stuff for it or not
 350   = sequenceM ([new_sys_bndr mod n loc | n <- gen_occs] ++
 351                map con_sys_occ cons)
 352   where
 353         -- c.f. TcTyDecls.tcTyDecl
 354     tc_occ = rdrNameOcc tc_name
 355     gen_occs | want_generic = [mkGenOcc1 tc_occ, mkGenOcc2 tc_occ]
 356              | otherwise    = []
 357     con_sys_occ (ConDecl name _ _ _ loc)
 358         = new_sys_bndr mod (mkWorkerOcc (rdrNameOcc name)) loc
 359
 360 getSysBinders mod decl = returnM []
 361
 362 new_sys_bndr mod occ loc = newTopBinder mod (mkRdrUnqual occ) loc
 363
 364
 365 -----------------------------------------------------
 366 --      Loading fixity decls
 367 -----------------------------------------------------
 368
 369 loadFixDecls decls
 370   = mappM loadFixDecl decls     `thenM` \ to_add ->
 371     returnM (mkNameEnv to_add)
 372
 373 loadFixDecl (FixitySig rdr_name fixity loc)
 374   = lookupGlobalOccRn rdr_name          `thenM` \ name ->
 375     returnM (name, FixitySig name fixity loc)
 376
 377
 378 -----------------------------------------------------
 379 --      Loading instance decls
 380 -----------------------------------------------------
 381
 382 loadInstDecls :: Module -> IfaceInsts
 383               -> [RdrNameInstDecl]
 384               -> RnM IfaceInsts
 385 loadInstDecls mod (insts, n_slurped) decls
 386   = foldlM (loadInstDecl mod) insts decls       `thenM` \ insts' ->
 387     returnM (insts', n_slurped)
 388
 389
 390 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 391   =     -- Find out what type constructors and classes are "gates" for the
 392         -- instance declaration.  If all these "gates" are slurped in then
 393         -- we should slurp the instance decl too.
 394         --
 395         -- We *don't* want to count names in the context part as gates, though.
 396         -- For example:
 397         --              instance Foo a => Baz (T a) where ...
 398         --
 399         -- Here the gates are Baz and T, but *not* Foo.
 400         --
 401         -- HOWEVER: functional dependencies make things more complicated
 402         --      class C a b | a->b where ...
 403         --      instance C Foo Baz where ...
 404         -- Here, the gates are really only C and Foo, *not* Baz.
 405         -- That is, if C and Foo are visible, even if Baz isn't, we must
 406         -- slurp the decl.
 407         --
 408         -- Rather than take fundeps into account "properly", we just slurp
 409         -- if C is visible and *any one* of the Names in the types
 410         -- This is a slightly brutal approximation, but most instance decls
 411         -- are regular H98 ones and it's perfect for them.
 412         --
 413         -- NOTICE that we rename the type before extracting its free
 414         -- variables.  The free-variable finder for a renamed HsType
 415         -- does the Right Thing for built-in syntax like [] and (,).
 416     rnHsType (text "In an interface instance decl") inst_ty     `thenM` \ inst_ty' ->
 417     let
 418         (tvs,_,cls,tys) = splitHsInstDeclTy inst_ty'
 419         free_tcs  = nameSetToList (extractHsTyNames_s tys) `minusList` hsTyVarNames tvs
 420
 421         gate_fn vis_fn = vis_fn cls && (null free_tcs || any vis_fn free_tcs)
 422         -- The 'vis_fn' returns True for visible names
 423         -- Here is the implementation of HOWEVER above
 424         -- (Note that we do let the inst decl in if it mentions
 425         --  no tycons at all.  Hence the null free_ty_names.)
 426     in
 427     traceRn ((text "Load instance for" <+> ppr inst_ty') $$ ppr free_tcs)       `thenM_`
 428     returnM ((gate_fn, (mod, decl)) `consBag` insts)
 429
 430
 431
 432 -----------------------------------------------------
 433 --      Loading Rules
 434 -----------------------------------------------------
 435
 436 loadRules :: Module
 437           -> IfaceRules
 438           -> (Version, [RdrNameRuleDecl])
 439           -> RnM (Version, IfaceRules)
 440 loadRules mod (rule_bag, n_slurped) (version, rules)
 441   | null rules || opt_IgnoreIfacePragmas
 442   = returnM (version, (rule_bag, n_slurped))
 443   | otherwise
 444   = mappM (loadRule mod) rules          `thenM` \ new_rules ->
 445     returnM (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 446
 447 loadRule :: Module -> RdrNameRuleDecl -> RnM (GatedDecl RdrNameRuleDecl)
 448 -- "Gate" the rule simply by whether the rule variable is
 449 -- needed.  We can refine this later.
 450 loadRule mod decl@(IfaceRule _ _ _ var _ _ src_loc)
 451   = lookupGlobalOccRn var               `thenM` \ var_name ->
 452     returnM (\vis_fn -> vis_fn var_name, (mod, decl))
 453
 454
 455 -----------------------------------------------------
 456 --      Loading Deprecations
 457 -----------------------------------------------------
 458
 459 loadDeprecs :: IfaceDeprecs -> RnM Deprecations
 460 loadDeprecs Nothing            = returnM NoDeprecs
 461 loadDeprecs (Just (Left txt))  = returnM (DeprecAll txt)
 462 loadDeprecs (Just (Right prs)) = foldlM loadDeprec emptyNameEnv prs     `thenM` \ env ->
 463                                  returnM (DeprecSome env)
 464 loadDeprec deprec_env (n, txt)
 465   = lookupGlobalOccRn n         `thenM` \ name ->
 466     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenM_`
 467     returnM (extendNameEnv deprec_env name (name,txt))
 468 \end{code}
 469
 470
 471 %********************************************************
 472 %*                                                      *
 473         Load the ParsedIface for the *current* module
 474         into a ModIface; then it can be checked
 475         for up-to-date-ness
 476 %*                                                      *
 477 %********************************************************
 478
 479 \begin{code}
 480 loadOldIface :: ParsedIface -> RnM ModIface
 481
 482 loadOldIface iface
 483   = loadHomeDecls       (pi_decls iface)        `thenM` \ (decls_vers, new_decls) ->
 484     loadHomeRules       (pi_rules iface)        `thenM` \ (rule_vers, new_rules) ->
 485     loadHomeInsts       (pi_insts iface)        `thenM` \ new_insts ->
 486     mappM loadHomeUsage (pi_usages iface)       `thenM` \ usages ->
 487     loadExports         (pi_exports iface)      `thenM` \ (export_vers, avails) ->
 488     loadFixDecls        (pi_fixity iface)       `thenM` \ fix_env ->
 489     loadDeprecs         (pi_deprecs iface)      `thenM` \ deprec_env ->
 490
 491     getModeRn                                   `thenM` \ (InterfaceMode mod) ->
 492                 -- Caller sets the module before the call; also needed
 493                 -- by the newGlobalName stuff in some of the loadHomeX calls
 494     let
 495         version = VersionInfo { vers_module  = pi_vers iface,
 496                                 vers_exports = export_vers,
 497                                 vers_rules   = rule_vers,
 498                                 vers_decls   = decls_vers }
 499
 500         decls = mkIfaceDecls new_decls new_rules new_insts
 501
 502         mod_iface = ModIface { mi_module = mod, mi_package = pi_pkg iface,
 503                                mi_version = version, mi_deps = pi_deps iface,
 504                                mi_exports = avails, mi_usages = usages,
 505                                mi_boot = False, mi_orphan = pi_orphan iface,
 506                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 507                                mi_decls   = decls,
 508                                mi_globals = Nothing
 509                     }
 510     in
 511     returnM mod_iface
 512 \end{code}
 513
 514 \begin{code}
 515 loadHomeDecls :: [(Version, RdrNameTyClDecl)]
 516               -> RnM (NameEnv Version, [RenamedTyClDecl])
 517 loadHomeDecls decls = foldlM loadHomeDecl (emptyNameEnv, []) decls
 518
 519 loadHomeDecl :: (NameEnv Version, [RenamedTyClDecl])
 520              -> (Version, RdrNameTyClDecl)
 521              -> RnM (NameEnv Version, [RenamedTyClDecl])
 522 loadHomeDecl (version_map, decls) (version, decl)
 523   = rnTyClDecl decl     `thenM` \ decl' ->
 524     returnM (extendNameEnv version_map (tyClDeclName decl') version, decl':decls)
 525
 526 ------------------
 527 loadHomeRules :: (Version, [RdrNameRuleDecl])
 528               -> RnM (Version, [RenamedRuleDecl])
 529 loadHomeRules (version, rules)
 530   = mappM rnIfaceRuleDecl rules `thenM` \ rules' ->
 531     returnM (version, rules')
 532
 533 ------------------
 534 loadHomeInsts :: [RdrNameInstDecl]
 535               -> RnM [RenamedInstDecl]
 536 loadHomeInsts insts = mappM rnInstDecl insts
 537
 538 ------------------
 539 loadHomeUsage :: Usage OccName -> TcRn m (Usage Name)
 540 loadHomeUsage usage
 541   = mappM rn_imp (usg_entities usage)   `thenM` \ entities' ->
 542     returnM (usage { usg_entities = entities' })
 543   where
 544     mod_name = usg_name usage
 545     rn_imp (occ,vers) = newGlobalName2 mod_name occ     `thenM` \ name ->
 546                         returnM (name,vers)
 547 \end{code}
 548
 549
 550 %*********************************************************
 551 %*                                                      *
 552 \subsection{Reading an interface file}
 553 %*                                                      *
 554 %*********************************************************
 555
 556 \begin{code}
 557 findAndReadIface :: SDoc -> ModuleName
 558                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 559                                         -- False <=> Look for .hi file
 560                  -> TcRn m (Either Message (Module, ParsedIface))
 561         -- Nothing <=> file not found, or unreadable, or illegible
 562         -- Just x  <=> successfully found and parsed
 563
 564         -- It *doesn't* add an error to the monad, because
 565         -- sometimes it's ok to fail... see notes with loadInterface
 566
 567 findAndReadIface doc_str mod_name hi_boot_file
 568   = traceRn trace_msg                   `thenM_`
 569
 570     -- Check for GHC.Prim, and return its static interface
 571     if mod_name == gHC_PRIM_Name
 572         then returnM (Right (gHC_PRIM, ghcPrimIface))
 573         else
 574
 575     ioToTcRn (findHiFile mod_name hi_boot_file) `thenM` \ maybe_found ->
 576
 577     case maybe_found of
 578       Nothing ->
 579         traceRn (ptext SLIT("...not found"))    `thenM_`
 580         returnM (Left (noIfaceErr mod_name hi_boot_file))
 581
 582       Just (wanted_mod, file_path) ->
 583         traceRn (ptext SLIT("readIFace") <+> text file_path)    `thenM_`
 584
 585         readIface wanted_mod file_path hi_boot_file     `thenM` \ read_result ->
 586                 -- Catch exceptions here
 587
 588         case read_result of
 589           Left exn    -> returnM (Left (badIfaceFile file_path
 590                                           (text (showException exn))))
 591
 592           Right iface -> returnM (Right (wanted_mod, iface))
 593
 594   where
 595     trace_msg = sep [hsep [ptext SLIT("Reading"),
 596                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 597                            ptext SLIT("interface for"),
 598                            ppr mod_name <> semi],
 599                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 600
 601 findHiFile :: ModuleName -> IsBootInterface -> IO (Maybe (Module, FilePath))
 602 findHiFile mod_name hi_boot_file
 603  = do {
 604         -- In interactive or --make mode, we are *not allowed* to demand-load
 605         -- a home package .hi file.  So don't even look for them.
 606         -- This helps in the case where you are sitting in eg. ghc/lib/std
 607         -- and start up GHCi - it won't complain that all the modules it tries
 608         -- to load are found in the home location.
 609         ghci_mode <- readIORef v_GhcMode ;
 610         let { home_allowed = hi_boot_file ||
 611                              not (isCompManagerMode ghci_mode) } ;
 612         maybe_found <-  if home_allowed
 613                         then findModule mod_name
 614                         else findPackageModule mod_name ;
 615
 616         case maybe_found of {
 617           Nothing -> return Nothing ;
 618
 619           Just (mod,loc) -> do {
 620
 621         -- Return the path to M.hi, M.hi-boot, or M.hi-boot-n as appropriate
 622         let { hi_path            = ml_hi_file loc ;
 623               hi_boot_path       = replaceFilenameSuffix hi_path hiBootExt ;
 624               hi_boot_ver_path   = replaceFilenameSuffix hi_path hiBootVerExt
 625             };
 626
 627         if not hi_boot_file then
 628            return (Just (mod, hi_path))
 629         else do {
 630                 hi_ver_exists <- doesFileExist hi_boot_ver_path ;
 631                 if hi_ver_exists then return (Just (mod, hi_boot_ver_path))
 632                                  else return (Just (mod, hi_boot_path))
 633         }}}}
 634 \end{code}
 635
 636 @readIface@ tries just the one file.
 637
 638 \begin{code}
 639 readIface :: Module -> String -> IsBootInterface -> TcRn m (Either Exception ParsedIface)
 640         -- Nothing <=> file not found, or unreadable, or illegible
 641         -- Just x  <=> successfully found and parsed
 642
 643 readIface mod file_path is_hi_boot_file
 644   = ioToTcRn (tryMost (read_iface mod file_path is_hi_boot_file))
 645
 646 read_iface mod file_path is_hi_boot_file
 647  | is_hi_boot_file              -- Read ascii
 648  = do { buffer <- hGetStringBuffer file_path ;
 649         case parseIface buffer (mkPState loc exts) of
 650           POk _ iface | wanted_mod_name == actual_mod_name
 651                       -> return iface
 652                       | otherwise
 653                       -> throwDyn (ProgramError (showSDoc err))
 654                                 -- 'showSDoc' is a bit yukky
 655                 where
 656                   wanted_mod_name = moduleName mod
 657                   actual_mod_name = pi_mod iface
 658                   err = hiModuleNameMismatchWarn wanted_mod_name actual_mod_name
 659
 660           PFailed err -> throwDyn (ProgramError (showSDoc err))
 661      }
 662
 663  | otherwise            -- Read binary
 664  = readBinIface file_path
 665
 666  where
 667     exts = ExtFlags {glasgowExtsEF = True,
 668                      ffiEF         = True,
 669                      withEF        = True,
 670                      parrEF        = True}
 671     loc  = mkSrcLoc (mkFastString file_path) 1
 672 \end{code}
 673
 674
 675 %*********************************************************
 676 %*                                                       *
 677         Wired-in interface for GHC.Prim
 678 %*                                                       *
 679 %*********************************************************
 680
 681 \begin{code}
 682 ghcPrimIface :: ParsedIface
 683 ghcPrimIface = ParsedIface {
 684       pi_mod     = gHC_PRIM_Name,
 685       pi_pkg     = basePackage,
 686       pi_deps    = noDependencies,
 687       pi_vers    = 1,
 688       pi_orphan  = False,
 689       pi_usages  = [],
 690       pi_exports = (1, [(gHC_PRIM_Name, ghcPrimExports)]),
 691       pi_decls   = [(1,cCallableClassDecl),
 692                     (1,cReturnableClassDecl)],
 693       pi_fixity  = [FixitySig (nameRdrName (idName seqId))
 694                               (Fixity 0 InfixR) noSrcLoc],
 695                 -- seq is infixr 0
 696       pi_insts   = [],
 697       pi_rules   = (1,[]),
 698       pi_deprecs = Nothing
 699  }
 700 \end{code}
 701
 702 %*********************************************************
 703 %*                                                       *
 704 \subsection{Errors}
 705 %*                                                       *
 706 %*********************************************************
 707
 708 \begin{code}
 709 noIfaceErr mod_name boot_file
 710   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 711         -- We used to print the search path, but we can't do that
 712         -- now, because it's hidden inside the finder.
 713         -- Maybe the finder should expose more functions.
 714
 715 badIfaceFile file err
 716   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 717           nest 4 err]
 718
 719 hiModuleNameMismatchWarn :: ModuleName -> ModuleName -> Message
 720 hiModuleNameMismatchWarn requested_mod read_mod =
 721     hsep [ ptext SLIT("Something is amiss; requested module name")
 722          , ppr requested_mod
 723          , ptext SLIT("differs from name found in the interface file")
 724          , ppr read_mod
 725          ]
 726
 727 warnRedundantSourceImport mod_name
 728   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 729           <+> quotes (ppr mod_name)
 730
 731 warnSelfImport mod
 732   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 733 \end{code}