ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, findAndReadIface, loadInterface, loadHomeInterface,
   9         tryLoadInterface, loadOrphanModules,
  10         loadExports, loadFixDecls, loadDeprecs,
  11
  12         lookupFixityRn,
  13
  14         getTyClDeclBinders
  15    ) where
  16
  17 #include "HsVersions.h"
  18
  19 import DriverState      ( GhcMode(..), v_GhcMode )
  20 import DriverUtil       ( splitFilename )
  21 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  22 import HscTypes         ( ModuleLocation(..),
  23                           ModIface(..), emptyModIface,
  24                           VersionInfo(..), ImportedModuleInfo,
  25                           lookupIfaceByModName,
  26                           ImportVersion, WhetherHasOrphans, IsBootInterface,
  27                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules,
  28                           AvailInfo, GenAvailInfo(..), Avails, Deprecations(..)
  29                          )
  30 import HsSyn            ( TyClDecl(..), InstDecl(..),
  31                           HsType(..), HsPred(..), FixitySig(..), RuleDecl(..),
  32                           tyClDeclNames, tyClDeclSysNames, hsTyVarNames, getHsInstHead,
  33                         )
  34 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl )
  35 import RnHsSyn          ( extractHsTyNames_s )
  36 import BasicTypes       ( Version, defaultFixity )
  37 import RnTypes          ( rnHsType )
  38 import RnEnv
  39 import RnMonad
  40 import ParseIface       ( parseIface )
  41
  42 import Name             ( Name {-instance NamedThing-},
  43                           nameModule, isLocalName, nameIsLocalOrFrom
  44                          )
  45 import NameEnv
  46 import NameSet
  47 import Module
  48 import RdrName          ( rdrNameOcc )
  49 import SrcLoc           ( mkSrcLoc )
  50 import Maybes           ( maybeToBool, orElse )
  51 import StringBuffer     ( hGetStringBuffer )
  52 import FastString       ( mkFastString )
  53 import ErrUtils         ( Message )
  54 import Finder           ( findModule, findPackageModule )
  55 import Lex
  56 import FiniteMap
  57 import ListSetOps       ( minusList )
  58 import Outputable
  59 import Bag
  60 import Config
  61
  62 import IOExts
  63 import Directory
  64 \end{code}
  65
  66
  67 %*********************************************************
  68 %*                                                      *
  69 \subsection{Loading a new interface file}
  70 %*                                                      *
  71 %*********************************************************
  72
  73 \begin{code}
  74 loadHomeInterface :: SDoc -> Name -> RnM d ModIface
  75 loadHomeInterface doc_str name
  76   = ASSERT2( not (isLocalName name), ppr name <+> parens doc_str )
  77     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  78
  79 loadOrphanModules :: [ModuleName] -> RnM d ()
  80 loadOrphanModules mods
  81   | null mods = returnRn ()
  82   | otherwise = traceRn (text "Loading orphan modules:" <+>
  83                          fsep (map ppr mods))                   `thenRn_`
  84                 mapRn_ load mods                                `thenRn_`
  85                 returnRn ()
  86   where
  87     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
  88     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
  89
  90 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d ModIface
  91 loadInterface doc mod from
  92   = tryLoadInterface doc mod from       `thenRn` \ (ifaces, maybe_err) ->
  93     case maybe_err of
  94         Nothing  -> returnRn ifaces
  95         Just err -> failWithRn ifaces (elaborate err)
  96   where
  97     elaborate err = hang (ptext SLIT("failed to load interface for") <+> quotes (ppr mod) <> colon)
  98                          4 err
  99
 100 tryLoadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (ModIface, Maybe Message)
 101   -- Returns (Just err) if an error happened
 102   -- It *doesn't* add an error to the monad, because sometimes it's ok to fail...
 103   -- Specifically, when we read the usage information from an interface file,
 104   -- we try to read the interfaces it mentions.  But it's OK to fail; perhaps
 105   -- the module has changed, and that interface is no longer used.
 106
 107   -- tryLoadInterface guarantees to return with iImpModInfo m --> (..., True)
 108   -- (If the load fails, we plug in a vanilla placeholder)
 109 tryLoadInterface doc_str mod_name from
 110  = getHomeIfaceTableRn          `thenRn` \ hit ->
 111    getModuleRn                  `thenRn` \ this_mod ->
 112    getIfacesRn                  `thenRn` \ ifaces@(Ifaces { iPIT = pit }) ->
 113
 114         -- CHECK WHETHER WE HAVE IT ALREADY
 115    case lookupIfaceByModName hit pit mod_name of {
 116         Just iface |  case from of
 117                         ImportByUser       -> not (mi_boot iface)
 118                         ImportByUserSource -> mi_boot iface
 119                         ImportBySystem     -> True
 120                    -> returnRn (iface, Nothing) ;       -- Already loaded
 121                         -- The not (mi_boot iface) test checks that the already-loaded
 122                         -- interface isn't a boot iface.  This can conceivably happen,
 123                         -- if the version checking happened to load a boot interface
 124                         -- before we got to real imports.
 125         other       ->
 126
 127    let
 128         mod_map  = iImpModInfo ifaces
 129         mod_info = lookupFM mod_map mod_name
 130
 131         hi_boot_file
 132           = case (from, mod_info) of
 133                 (ImportByUser,       _)             -> False    -- Not hi-boot
 134                 (ImportByUserSource, _)             -> True     -- hi-boot
 135                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 136                 (ImportBySystem, Nothing)           -> False
 137                         -- We're importing a module we know absolutely
 138                         -- nothing about, so we assume it's from
 139                         -- another package, where we aren't doing
 140                         -- dependency tracking. So it won't be a hi-boot file.
 141
 142         redundant_source_import
 143           = case (from, mod_info) of
 144                 (ImportByUserSource, Just (_,False)) -> True
 145                 other                                -> False
 146    in
 147
 148         -- Issue a warning for a redundant {- SOURCE -} import
 149         -- NB that we arrange to read all the ordinary imports before
 150         -- any of the {- SOURCE -} imports
 151    warnCheckRn  (not redundant_source_import)
 152                 (warnRedundantSourceImport mod_name)    `thenRn_`
 153
 154         -- Check that we aren't importing ourselves.
 155         -- That only happens in Rename.checkOldIface,
 156         -- which doesn't call tryLoadInterface
 157    warnCheckRn
 158         (not (isHomeModule this_mod) || moduleName this_mod /= mod_name)
 159         (warnSelfImport this_mod)               `thenRn_`
 160
 161         -- READ THE MODULE IN
 162    findAndReadIface doc_str mod_name hi_boot_file
 163                                             `thenRn` \ read_result ->
 164    case read_result of {
 165         Left err ->     -- Not found, so add an empty export env to the Ifaces map
 166                         -- so that we don't look again
 167            let
 168                 fake_mod    = mkVanillaModule mod_name
 169                 fake_iface  = emptyModIface fake_mod
 170                 new_ifaces  = ifaces { iPIT = extendModuleEnv pit fake_mod fake_iface }
 171            in
 172            setIfacesRn new_ifaces               `thenRn_`
 173            returnRn (fake_iface, Just err) ;
 174
 175         -- Found and parsed!
 176         Right (mod, iface) ->
 177
 178         -- LOAD IT INTO Ifaces
 179
 180         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 181         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 182         --     If we do loadExport first the wrong info gets into the cache (unless we
 183         --      explicitly tag each export which seems a bit of a bore)
 184
 185
 186         -- Sanity check.  If we're system-importing a module we know nothing at all
 187         -- about, it should be from a different package to this one
 188     WARN( not (maybeToBool mod_info) &&
 189           case from of { ImportBySystem -> True; other -> False } &&
 190           isHomeModule mod,
 191           ppr mod )
 192
 193     loadDecls mod               (iDecls ifaces)   (pi_decls iface)      `thenRn` \ (decls_vers, new_decls) ->
 194     loadRules mod               (iRules ifaces)   (pi_rules iface)      `thenRn` \ (rule_vers, new_rules) ->
 195     loadInstDecls mod           (iInsts ifaces)   (pi_insts iface)      `thenRn` \ new_insts ->
 196     loadExports                                   (pi_exports iface)    `thenRn` \ (export_vers, avails) ->
 197     loadFixDecls mod                              (pi_fixity iface)     `thenRn` \ fix_env ->
 198     loadDeprecs mod                               (pi_deprecs iface)    `thenRn` \ deprec_env ->
 199     let
 200         version = VersionInfo { vers_module  = pi_vers iface,
 201                                 vers_exports = export_vers,
 202                                 vers_rules = rule_vers,
 203                                 vers_decls = decls_vers }
 204
 205         -- For an explicit user import, add to mod_map info about
 206         -- the things the imported module depends on, extracted
 207         -- from its usage info; and delete the module itself, which is now in the PIT
 208         mod_map1 = case from of
 209                         ImportByUser -> addModDeps mod is_loaded (pi_usages iface) mod_map
 210                         other        -> mod_map
 211         mod_map2 = delFromFM mod_map1 mod_name
 212
 213         this_mod_name = moduleName this_mod
 214         is_loaded m   =  m == this_mod_name
 215                       || maybeToBool (lookupIfaceByModName hit pit m)
 216                 -- We treat the currently-being-compiled module as 'loaded' because
 217                 -- even though it isn't yet in the HIT or PIT; otherwise it gets
 218                 -- put into iImpModInfo, and then spat out into its own interface
 219                 -- file as a dependency
 220
 221         -- Now add info about this module to the PIT
 222         has_orphans = pi_orphan iface
 223         new_pit   = extendModuleEnv pit mod mod_iface
 224         mod_iface = ModIface { mi_module = mod, mi_version = version,
 225                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 226                                mi_exports = avails,
 227                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 228                                mi_usages  = [], -- Will be filled in later
 229                                mi_decls   = panic "No mi_decls in PIT",
 230                                mi_globals = mkIfaceGlobalRdrEnv avails
 231                     }
 232
 233         new_ifaces = ifaces { iPIT        = new_pit,
 234                               iDecls      = new_decls,
 235                               iInsts      = new_insts,
 236                               iRules      = new_rules,
 237                               iImpModInfo = mod_map2  }
 238     in
 239     setIfacesRn new_ifaces              `thenRn_`
 240     returnRn (mod_iface, Nothing)
 241     }}
 242
 243 -----------------------------------------------------
 244 --      Adding module dependencies from the
 245 --      import decls in the interface file
 246 -----------------------------------------------------
 247
 248 addModDeps :: Module
 249            -> (ModuleName -> Bool)      -- True for modules that are already loaded
 250            -> [ImportVersion a]
 251            -> ImportedModuleInfo -> ImportedModuleInfo
 252 -- (addModDeps M ivs deps)
 253 -- We are importing module M, and M.hi contains 'import' decls given by ivs
 254 addModDeps mod is_loaded new_deps mod_deps
 255   = foldr add mod_deps filtered_new_deps
 256   where
 257         -- Don't record dependencies when importing a module from another package
 258         -- Except for its descendents which contain orphans,
 259         -- and in that case, forget about the boot indicator
 260     filtered_new_deps :: [(ModuleName, (WhetherHasOrphans, IsBootInterface))]
 261     filtered_new_deps
 262         | isHomeModule mod  = [ (imp_mod, (has_orphans, is_boot))
 263                               | (imp_mod, has_orphans, is_boot, _) <- new_deps,
 264                                 not (is_loaded imp_mod)
 265                               ]
 266         | otherwise         = [ (imp_mod, (True, False))
 267                               | (imp_mod, has_orphans, _, _) <- new_deps,
 268                                 not (is_loaded imp_mod) && has_orphans
 269                               ]
 270     add (imp_mod, dep) deps = addToFM_C combine deps imp_mod dep
 271
 272     combine old@(old_has_orphans, old_is_boot) new@(new_has_orphans, new_is_boot)
 273         | old_is_boot = new     -- Record the best is_boot info
 274         | otherwise   = old
 275
 276 -----------------------------------------------------
 277 --      Loading the export list
 278 -----------------------------------------------------
 279
 280 loadExports :: (Version, [ExportItem]) -> RnM d (Version, [(ModuleName,Avails)])
 281 loadExports (vers, items)
 282   = mapRn loadExport items      `thenRn` \ avails_s ->
 283     returnRn (vers, avails_s)
 284
 285
 286 loadExport :: ExportItem -> RnM d (ModuleName, Avails)
 287 loadExport (mod, entities)
 288   = mapRn (load_entity mod) entities    `thenRn` \ avails ->
 289     returnRn (mod, avails)
 290   where
 291     load_entity mod (Avail occ)
 292       = newGlobalName mod occ   `thenRn` \ name ->
 293         returnRn (Avail name)
 294     load_entity mod (AvailTC occ occs)
 295       = newGlobalName mod occ           `thenRn` \ name ->
 296         mapRn (newGlobalName mod) occs  `thenRn` \ names ->
 297         returnRn (AvailTC name names)
 298
 299
 300 -----------------------------------------------------
 301 --      Loading type/class/value decls
 302 -----------------------------------------------------
 303
 304 loadDecls :: Module
 305           -> DeclsMap
 306           -> [(Version, RdrNameTyClDecl)]
 307           -> RnM d (NameEnv Version, DeclsMap)
 308 loadDecls mod (decls_map, n_slurped) decls
 309   = foldlRn (loadDecl mod) (emptyNameEnv, decls_map) decls      `thenRn` \ (vers, decls_map') ->
 310     returnRn (vers, (decls_map', n_slurped))
 311
 312 loadDecl mod (version_map, decls_map) (version, decl)
 313   = getTyClDeclBinders mod decl `thenRn` \ (avail, sys_names) ->
 314     let
 315         full_avail    = case avail of
 316                           Avail n -> avail
 317                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 318         main_name     = availName full_avail
 319         new_decls_map = extendNameEnvList decls_map stuff
 320         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 321                         | name <- availNames full_avail]
 322
 323         new_version_map = extendNameEnv version_map main_name version
 324     in
 325     traceRn (text "Loading" <+> ppr full_avail) `thenRn_`
 326     returnRn (new_version_map, new_decls_map)
 327
 328 -----------------------------------------------------
 329 --      Loading fixity decls
 330 -----------------------------------------------------
 331
 332 loadFixDecls mod decls
 333   = mapRn (loadFixDecl mod_name) decls  `thenRn` \ to_add ->
 334     returnRn (mkNameEnv to_add)
 335   where
 336     mod_name = moduleName mod
 337
 338 loadFixDecl mod_name sig@(FixitySig rdr_name fixity loc)
 339   = newGlobalName mod_name (rdrNameOcc rdr_name)        `thenRn` \ name ->
 340     returnRn (name, fixity)
 341
 342
 343 -----------------------------------------------------
 344 --      Loading instance decls
 345 -----------------------------------------------------
 346
 347 loadInstDecls :: Module
 348               -> IfaceInsts
 349               -> [RdrNameInstDecl]
 350               -> RnM d IfaceInsts
 351 loadInstDecls mod (insts, n_slurped) decls
 352   = setModuleRn mod $
 353     foldlRn (loadInstDecl mod) insts decls      `thenRn` \ insts' ->
 354     returnRn (insts', n_slurped)
 355
 356
 357 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 358   =     -- Find out what type constructors and classes are "gates" for the
 359         -- instance declaration.  If all these "gates" are slurped in then
 360         -- we should slurp the instance decl too.
 361         --
 362         -- We *don't* want to count names in the context part as gates, though.
 363         -- For example:
 364         --              instance Foo a => Baz (T a) where ...
 365         --
 366         -- Here the gates are Baz and T, but *not* Foo.
 367         --
 368         -- HOWEVER: functional dependencies make things more complicated
 369         --      class C a b | a->b where ...
 370         --      instance C Foo Baz where ...
 371         -- Here, the gates are really only C and Foo, *not* Baz.
 372         -- That is, if C and Foo are visible, even if Baz isn't, we must
 373         -- slurp the decl.
 374         --
 375         -- Rather than take fundeps into account "properly", we just slurp
 376         -- if C is visible and *any one* of the Names in the types
 377         -- This is a slightly brutal approximation, but most instance decls
 378         -- are regular H98 ones and it's perfect for them.
 379         --
 380         -- NOTICE that we rename the type before extracting its free
 381         -- variables.  The free-variable finder for a renamed HsType
 382         -- does the Right Thing for built-in syntax like [] and (,).
 383     initIfaceRnMS mod (
 384         rnHsType (text "In an interface instance decl") inst_ty
 385     )                                   `thenRn` \ inst_ty' ->
 386     let
 387         (tvs,(cls,tys)) = getHsInstHead inst_ty'
 388         free_tcs  = nameSetToList (extractHsTyNames_s tys) `minusList` hsTyVarNames tvs
 389
 390         gate_fn vis_fn = vis_fn cls && (null free_tcs || any vis_fn free_tcs)
 391         -- Here is the implementation of HOWEVER above
 392         -- (Note that we do let the inst decl in if it mentions
 393         --  no tycons at all.  Hence the null free_ty_names.)
 394     in
 395     returnRn ((gate_fn, (mod, decl)) `consBag` insts)
 396
 397
 398
 399 -----------------------------------------------------
 400 --      Loading Rules
 401 -----------------------------------------------------
 402
 403 loadRules :: Module -> IfaceRules
 404           -> (Version, [RdrNameRuleDecl])
 405           -> RnM d (Version, IfaceRules)
 406 loadRules mod (rule_bag, n_slurped) (version, rules)
 407   | null rules || opt_IgnoreIfacePragmas
 408   = returnRn (version, (rule_bag, n_slurped))
 409   | otherwise
 410   = setModuleRn mod                     $
 411     mapRn (loadRule mod) rules          `thenRn` \ new_rules ->
 412     returnRn (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 413
 414 loadRule :: Module -> RdrNameRuleDecl -> RnM d (GatedDecl RdrNameRuleDecl)
 415 -- "Gate" the rule simply by whether the rule variable is
 416 -- needed.  We can refine this later.
 417 loadRule mod decl@(IfaceRule _ _ _ var _ _ src_loc)
 418   = lookupIfaceName var         `thenRn` \ var_name ->
 419     returnRn (\vis_fn -> vis_fn var_name, (mod, decl))
 420
 421
 422 -----------------------------------------------------
 423 --      Loading Deprecations
 424 -----------------------------------------------------
 425
 426 loadDeprecs :: Module -> IfaceDeprecs -> RnM d Deprecations
 427 loadDeprecs m Nothing                                  = returnRn NoDeprecs
 428 loadDeprecs m (Just (Left txt))  = returnRn (DeprecAll txt)
 429 loadDeprecs m (Just (Right prs)) = setModuleRn m                                $
 430                                    foldlRn loadDeprec emptyNameEnv prs  `thenRn` \ env ->
 431                                    returnRn (DeprecSome env)
 432 loadDeprec deprec_env (n, txt)
 433   = lookupIfaceName n           `thenRn` \ name ->
 434     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenRn_`
 435     returnRn (extendNameEnv deprec_env name (name,txt))
 436 \end{code}
 437
 438
 439 %*********************************************************
 440 %*                                                      *
 441 \subsection{Getting binders out of a declaration}
 442 %*                                                      *
 443 %*********************************************************
 444
 445 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 446 It's used for both source code (from @availsFromDecl@) and interface files
 447 (from @loadDecl@).
 448
 449 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 450 are handled by the sourc-code specific stuff in @RnNames@.
 451
 452         *** See "THE NAMING STORY" in HsDecls ****
 453
 454
 455 \begin{code}
 456 getTyClDeclBinders
 457         :: Module
 458         -> RdrNameTyClDecl
 459         -> RnM d (AvailInfo, [Name])    -- The [Name] are the system names
 460
 461 -----------------
 462 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 463   = newTopBinder mod var src_loc                        `thenRn` \ var_name ->
 464     returnRn (Avail var_name, [])
 465
 466 getTyClDeclBinders mod tycl_decl
 467   = new_top_bndrs mod (tyClDeclNames tycl_decl)         `thenRn` \ names@(main_name:_) ->
 468     new_top_bndrs mod (tyClDeclSysNames tycl_decl)      `thenRn` \ sys_names ->
 469     returnRn (AvailTC main_name names, sys_names)
 470
 471 -----------------
 472 new_top_bndrs mod names_w_locs
 473   = sequenceRn [newTopBinder mod name loc | (name,loc) <- names_w_locs]
 474 \end{code}
 475
 476
 477 %*********************************************************
 478 %*                                                      *
 479 \subsection{Reading an interface file}
 480 %*                                                      *
 481 %*********************************************************
 482
 483 \begin{code}
 484 findAndReadIface :: SDoc -> ModuleName
 485                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 486                                         -- False <=> Look for .hi file
 487                  -> RnM d (Either Message (Module, ParsedIface))
 488         -- Nothing <=> file not found, or unreadable, or illegible
 489         -- Just x  <=> successfully found and parsed
 490
 491 findAndReadIface doc_str mod_name hi_boot_file
 492   = traceRn trace_msg                   `thenRn_`
 493
 494     -- In interactive or --make mode, we are *not allowed* to demand-load
 495     -- a home package .hi file.  So don't even look for them.
 496     -- This helps in the case where you are sitting in eg. ghc/lib/std
 497     -- and start up GHCi - it won't complain that all the modules it tries
 498     -- to load are found in the home location.
 499     ioToRnM_no_fail (readIORef v_GhcMode) `thenRn` \ mode ->
 500     let home_allowed = hi_boot_file ||
 501                        mode `notElem` [ DoInteractive, DoMake ]
 502     in
 503
 504     ioToRnM (if home_allowed
 505                 then findModule mod_name
 506                 else findPackageModule mod_name) `thenRn` \ maybe_found ->
 507
 508     case maybe_found of
 509
 510       Right (Just (wanted_mod,locn))
 511         -> mkHiPath hi_boot_file locn `thenRn` \ file ->
 512            readIface file `thenRn` \ read_result ->
 513            case read_result of
 514                 Left bad -> returnRn (Left bad)
 515                 Right iface
 516                    -> let read_mod = pi_mod iface
 517                       in -- check that the module names agree
 518                          checkRn
 519                            (wanted_mod == read_mod)
 520                            (hiModuleNameMismatchWarn wanted_mod read_mod)
 521                                         `thenRn_`
 522                          -- check that the package names agree
 523                          warnCheckRn
 524                            (modulePackage wanted_mod == modulePackage read_mod)
 525                            (packageNameMismatchWarn wanted_mod read_mod)
 526                                          `thenRn_`
 527                          returnRn (Right (wanted_mod, iface))
 528         -- Can't find it
 529       other   -> traceRn (ptext SLIT("...not found"))   `thenRn_`
 530                  returnRn (Left (noIfaceErr mod_name hi_boot_file))
 531
 532   where
 533     trace_msg = sep [hsep [ptext SLIT("Reading"),
 534                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 535                            ptext SLIT("interface for"),
 536                            ppr mod_name <> semi],
 537                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 538
 539 mkHiPath hi_boot_file locn
 540   | hi_boot_file =
 541         ioToRnM_no_fail (doesFileExist hi_boot_ver_path) `thenRn` \ b ->
 542         if b then returnRn hi_boot_ver_path
 543              else returnRn hi_boot_path
 544   | otherwise    = returnRn hi_path
 545         where hi_path            = ml_hi_file locn
 546               (hi_base, _hi_suf) = splitFilename hi_path
 547               hi_boot_path       = hi_base ++ ".hi-boot"
 548               hi_boot_ver_path   = hi_base ++ ".hi-boot-" ++ cHscIfaceFileVersion
 549 \end{code}
 550
 551 @readIface@ tries just the one file.
 552
 553 \begin{code}
 554 readIface :: String -> RnM d (Either Message ParsedIface)
 555         -- Nothing <=> file not found, or unreadable, or illegible
 556         -- Just x  <=> successfully found and parsed
 557 readIface file_path
 558   = --ioToRnM (putStrLn ("reading iface " ++ file_path)) `thenRn_`
 559     traceRn (ptext SLIT("readIFace") <+> text file_path)        `thenRn_`
 560
 561     ioToRnM (hGetStringBuffer False file_path)                  `thenRn` \ read_result ->
 562     case read_result of {
 563         Left io_error  -> bale_out (text (show io_error)) ;
 564         Right contents ->
 565
 566     case parseIface contents init_parser_state of
 567         POk _ iface          -> returnRn (Right iface)
 568         PFailed err          -> bale_out err
 569     }
 570   where
 571     init_parser_state = PState{ bol = 0#, atbol = 1#,
 572                                 context = [],
 573                                 glasgow_exts = 1#,
 574                                 loc = mkSrcLoc (mkFastString file_path) 1 }
 575
 576     bale_out err = returnRn (Left (badIfaceFile file_path err))
 577 \end{code}
 578
 579 %*********************************************************
 580 %*                                                      *
 581 \subsection{Looking up fixities}
 582 %*                                                      *
 583 %*********************************************************
 584
 585 @lookupFixityRn@ has to be in RnIfaces (or RnHiFiles), instead of
 586 its obvious home in RnEnv,  because it calls @loadHomeInterface@.
 587
 588 lookupFixity is a bit strange.
 589
 590 * Nested local fixity decls are put in the local fixity env, which we
 591   find with getFixtyEnv
 592
 593 * Imported fixities are found in the HIT or PIT
 594
 595 * Top-level fixity decls in this module may be for Names that are
 596     either  Global         (constructors, class operations)
 597     or      Local/Exported (everything else)
 598   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 599   We put them all in the local fixity environment
 600
 601 \begin{code}
 602 lookupFixityRn :: Name -> RnMS Fixity
 603 lookupFixityRn name
 604   = getModuleRn                         `thenRn` \ this_mod ->
 605     if nameIsLocalOrFrom this_mod name
 606     then        -- It's defined in this module
 607         getFixityEnv                    `thenRn` \ local_fix_env ->
 608         returnRn (lookupLocalFixity local_fix_env name)
 609
 610     else        -- It's imported
 611       -- For imported names, we have to get their fixities by doing a
 612       -- loadHomeInterface, and consulting the Ifaces that comes back
 613       -- from that, because the interface file for the Name might not
 614       -- have been loaded yet.  Why not?  Suppose you import module A,
 615       -- which exports a function 'f', which is defined in module B.
 616       -- Then B isn't loaded right away (after all, it's possible that
 617       -- nothing from B will be used).  When we come across a use of
 618       -- 'f', we need to know its fixity, and it's then, and only
 619       -- then, that we load B.hi.  That is what's happening here.
 620         loadHomeInterface doc name              `thenRn` \ iface ->
 621         returnRn (lookupNameEnv (mi_fixities iface) name `orElse` defaultFixity)
 622   where
 623     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 624 \end{code}
 625
 626
 627 %*********************************************************
 628 %*                                                       *
 629 \subsection{Errors}
 630 %*                                                       *
 631 %*********************************************************
 632
 633 \begin{code}
 634 noIfaceErr mod_name boot_file
 635   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 636         -- We used to print the search path, but we can't do that
 637         -- now, because it's hidden inside the finder.
 638         -- Maybe the finder should expose more functions.
 639
 640 badIfaceFile file err
 641   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 642           nest 4 err]
 643
 644 hiModuleNameMismatchWarn :: Module -> Module  -> Message
 645 hiModuleNameMismatchWarn requested_mod read_mod =
 646     hsep [ ptext SLIT("Something is amiss; requested module name")
 647          , ppr (moduleName requested_mod)
 648          , ptext SLIT("differs from name found in the interface file")
 649          , ppr read_mod
 650          ]
 651
 652 packageNameMismatchWarn :: Module -> Module  -> Message
 653 packageNameMismatchWarn requested_mod read_mod =
 654     fsep [ ptext SLIT("Module"), quotes (ppr requested_mod),
 655           ptext SLIT("is located in package"),
 656           quotes (ptext (modulePackage requested_mod)),
 657           ptext SLIT("but its interface file claims it is part of package"),
 658           quotes (ptext (modulePackage read_mod))
 659         ]
 660
 661 warnRedundantSourceImport mod_name
 662   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 663           <+> quotes (ppr mod_name)
 664
 665 warnSelfImport mod
 666   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 667 \end{code}