ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, findAndReadIface, loadInterface, loadHomeInterface,
   9         tryLoadInterface, loadOrphanModules,
  10         loadExports, loadFixDecls, loadDeprecs,
  11
  12         lookupFixityRn,
  13
  14         getTyClDeclBinders
  15    ) where
  16
  17 #include "HsVersions.h"
  18
  19 import DriverState      ( GhcMode(..), v_GhcMode )
  20 import DriverUtil       ( splitFilename )
  21 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  22 import HscTypes         ( ModuleLocation(..),
  23                           ModIface(..), emptyModIface,
  24                           VersionInfo(..), ImportedModuleInfo,
  25                           lookupIfaceByModName,
  26                           ImportVersion, WhetherHasOrphans, IsBootInterface,
  27                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules,
  28                           AvailInfo, GenAvailInfo(..), Avails, Deprecations(..)
  29                          )
  30 import HsSyn            ( TyClDecl(..), InstDecl(..),
  31                           HsType(..), HsPred(..), FixitySig(..), RuleDecl(..),
  32                           tyClDeclNames, tyClDeclSysNames, hsTyVarNames
  33                         )
  34 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl )
  35 import RnHsSyn          ( extractHsTyNames_s )
  36 import BasicTypes       ( Version, defaultFixity )
  37 import RnTypes          ( rnHsType )
  38 import RnEnv
  39 import RnMonad
  40 import ParseIface       ( parseIface )
  41
  42 import Name             ( Name {-instance NamedThing-},
  43                           nameModule, isLocalName, nameIsLocalOrFrom
  44                          )
  45 import NameEnv
  46 import NameSet
  47 import Module
  48 import RdrName          ( rdrNameOcc )
  49 import SrcLoc           ( mkSrcLoc )
  50 import Maybes           ( maybeToBool, orElse )
  51 import StringBuffer     ( hGetStringBuffer )
  52 import FastString       ( mkFastString )
  53 import ErrUtils         ( Message )
  54 import Finder           ( findModule, findPackageModule )
  55 import Lex
  56 import FiniteMap
  57 import ListSetOps       ( minusList )
  58 import Outputable
  59 import Bag
  60 import Config
  61
  62 import IOExts
  63 import Directory
  64 \end{code}
  65
  66
  67 %*********************************************************
  68 %*                                                      *
  69 \subsection{Loading a new interface file}
  70 %*                                                      *
  71 %*********************************************************
  72
  73 \begin{code}
  74 loadHomeInterface :: SDoc -> Name -> RnM d ModIface
  75 loadHomeInterface doc_str name
  76   = ASSERT2( not (isLocalName name), ppr name <+> parens doc_str )
  77     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  78
  79 loadOrphanModules :: [ModuleName] -> RnM d ()
  80 loadOrphanModules mods
  81   | null mods = returnRn ()
  82   | otherwise = traceRn (text "Loading orphan modules:" <+>
  83                          fsep (map ppr mods))                   `thenRn_`
  84                 mapRn_ load mods                                `thenRn_`
  85                 returnRn ()
  86   where
  87     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
  88     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
  89
  90 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d ModIface
  91 loadInterface doc mod from
  92   = tryLoadInterface doc mod from       `thenRn` \ (ifaces, maybe_err) ->
  93     case maybe_err of
  94         Nothing  -> returnRn ifaces
  95         Just err -> failWithRn ifaces (elaborate err)
  96   where
  97     elaborate err = hang (ptext SLIT("failed to load interface for") <+> quotes (ppr mod) <> colon)
  98                          4 err
  99
 100 tryLoadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (ModIface, Maybe Message)
 101   -- Returns (Just err) if an error happened
 102   -- It *doesn't* add an error to the monad, because sometimes it's ok to fail...
 103   -- Specifically, when we read the usage information from an interface file,
 104   -- we try to read the interfaces it mentions.  But it's OK to fail; perhaps
 105   -- the module has changed, and that interface is no longer used.
 106
 107   -- tryLoadInterface guarantees to return with iImpModInfo m --> (..., True)
 108   -- (If the load fails, we plug in a vanilla placeholder)
 109 tryLoadInterface doc_str mod_name from
 110  = getHomeIfaceTableRn          `thenRn` \ hit ->
 111    getModuleRn                  `thenRn` \ this_mod ->
 112    getIfacesRn                  `thenRn` \ ifaces@(Ifaces { iPIT = pit }) ->
 113
 114         -- CHECK WHETHER WE HAVE IT ALREADY
 115    case lookupIfaceByModName hit pit mod_name of {
 116         Just iface |  case from of
 117                         ImportByUser       -> not (mi_boot iface)
 118                         ImportByUserSource -> mi_boot iface
 119                         ImportBySystem     -> True
 120                    -> returnRn (iface, Nothing) ;       -- Already loaded
 121                         -- The not (mi_boot iface) test checks that the already-loaded
 122                         -- interface isn't a boot iface.  This can conceivably happen,
 123                         -- if the version checking happened to load a boot interface
 124                         -- before we got to real imports.
 125         other       ->
 126
 127    let
 128         mod_map  = iImpModInfo ifaces
 129         mod_info = lookupFM mod_map mod_name
 130
 131         hi_boot_file
 132           = case (from, mod_info) of
 133                 (ImportByUser,       _)             -> False    -- Not hi-boot
 134                 (ImportByUserSource, _)             -> True     -- hi-boot
 135                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 136                 (ImportBySystem, Nothing)           -> False
 137                         -- We're importing a module we know absolutely
 138                         -- nothing about, so we assume it's from
 139                         -- another package, where we aren't doing
 140                         -- dependency tracking. So it won't be a hi-boot file.
 141
 142         redundant_source_import
 143           = case (from, mod_info) of
 144                 (ImportByUserSource, Just (_,False)) -> True
 145                 other                                -> False
 146    in
 147
 148         -- Issue a warning for a redundant {- SOURCE -} import
 149         -- NB that we arrange to read all the ordinary imports before
 150         -- any of the {- SOURCE -} imports
 151    warnCheckRn  (not redundant_source_import)
 152                 (warnRedundantSourceImport mod_name)    `thenRn_`
 153
 154         -- Check that we aren't importing ourselves.
 155         -- That only happens in Rename.checkOldIface,
 156         -- which doesn't call tryLoadInterface
 157    warnCheckRn
 158         (not (isHomeModule this_mod) || moduleName this_mod /= mod_name)
 159         (warnSelfImport this_mod)               `thenRn_`
 160
 161         -- READ THE MODULE IN
 162    findAndReadIface doc_str mod_name hi_boot_file
 163                                             `thenRn` \ read_result ->
 164    case read_result of {
 165         Left err ->     -- Not found, so add an empty export env to the Ifaces map
 166                         -- so that we don't look again
 167            let
 168                 fake_mod    = mkVanillaModule mod_name
 169                 fake_iface  = emptyModIface fake_mod
 170                 new_ifaces  = ifaces { iPIT = extendModuleEnv pit fake_mod fake_iface }
 171            in
 172            setIfacesRn new_ifaces               `thenRn_`
 173            returnRn (fake_iface, Just err) ;
 174
 175         -- Found and parsed!
 176         Right (mod, iface) ->
 177
 178         -- LOAD IT INTO Ifaces
 179
 180         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 181         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 182         --     If we do loadExport first the wrong info gets into the cache (unless we
 183         --      explicitly tag each export which seems a bit of a bore)
 184
 185
 186         -- Sanity check.  If we're system-importing a module we know nothing at all
 187         -- about, it should be from a different package to this one
 188     WARN( not (maybeToBool mod_info) &&
 189           case from of { ImportBySystem -> True; other -> False } &&
 190           isHomeModule mod,
 191           ppr mod )
 192
 193     loadDecls mod               (iDecls ifaces)   (pi_decls iface)      `thenRn` \ (decls_vers, new_decls) ->
 194     loadRules mod               (iRules ifaces)   (pi_rules iface)      `thenRn` \ (rule_vers, new_rules) ->
 195     loadInstDecls mod           (iInsts ifaces)   (pi_insts iface)      `thenRn` \ new_insts ->
 196     loadExports                                   (pi_exports iface)    `thenRn` \ (export_vers, avails) ->
 197     loadFixDecls mod                              (pi_fixity iface)     `thenRn` \ fix_env ->
 198     loadDeprecs mod                               (pi_deprecs iface)    `thenRn` \ deprec_env ->
 199     let
 200         version = VersionInfo { vers_module  = pi_vers iface,
 201                                 vers_exports = export_vers,
 202                                 vers_rules = rule_vers,
 203                                 vers_decls = decls_vers }
 204
 205         -- For an explicit user import, add to mod_map info about
 206         -- the things the imported module depends on, extracted
 207         -- from its usage info; and delete the module itself, which is now in the PIT
 208         mod_map1 = case from of
 209                         ImportByUser -> addModDeps mod is_loaded (pi_usages iface) mod_map
 210                         other        -> mod_map
 211         mod_map2 = delFromFM mod_map1 mod_name
 212
 213         this_mod_name = moduleName this_mod
 214         is_loaded m   =  m == this_mod_name
 215                       || maybeToBool (lookupIfaceByModName hit pit m)
 216                 -- We treat the currently-being-compiled module as 'loaded' because
 217                 -- even though it isn't yet in the HIT or PIT; otherwise it gets
 218                 -- put into iImpModInfo, and then spat out into its own interface
 219                 -- file as a dependency
 220
 221         -- Now add info about this module to the PIT
 222         has_orphans = pi_orphan iface
 223         new_pit   = extendModuleEnv pit mod mod_iface
 224         mod_iface = ModIface { mi_module = mod, mi_version = version,
 225                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 226                                mi_exports = avails,
 227                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 228                                mi_usages  = [], -- Will be filled in later
 229                                mi_decls   = panic "No mi_decls in PIT",
 230                                mi_globals = mkIfaceGlobalRdrEnv avails
 231                     }
 232
 233         new_ifaces = ifaces { iPIT        = new_pit,
 234                               iDecls      = new_decls,
 235                               iInsts      = new_insts,
 236                               iRules      = new_rules,
 237                               iImpModInfo = mod_map2  }
 238     in
 239     setIfacesRn new_ifaces              `thenRn_`
 240     returnRn (mod_iface, Nothing)
 241     }}
 242
 243 -----------------------------------------------------
 244 --      Adding module dependencies from the
 245 --      import decls in the interface file
 246 -----------------------------------------------------
 247
 248 addModDeps :: Module
 249            -> (ModuleName -> Bool)      -- True for modules that are already loaded
 250            -> [ImportVersion a]
 251            -> ImportedModuleInfo -> ImportedModuleInfo
 252 -- (addModDeps M ivs deps)
 253 -- We are importing module M, and M.hi contains 'import' decls given by ivs
 254 addModDeps mod is_loaded new_deps mod_deps
 255   = foldr add mod_deps filtered_new_deps
 256   where
 257         -- Don't record dependencies when importing a module from another package
 258         -- Except for its descendents which contain orphans,
 259         -- and in that case, forget about the boot indicator
 260     filtered_new_deps :: [(ModuleName, (WhetherHasOrphans, IsBootInterface))]
 261     filtered_new_deps
 262         | isHomeModule mod  = [ (imp_mod, (has_orphans, is_boot))
 263                               | (imp_mod, has_orphans, is_boot, _) <- new_deps,
 264                                 not (is_loaded imp_mod)
 265                               ]
 266         | otherwise         = [ (imp_mod, (True, False))
 267                               | (imp_mod, has_orphans, _, _) <- new_deps,
 268                                 not (is_loaded imp_mod) && has_orphans
 269                               ]
 270     add (imp_mod, dep) deps = addToFM_C combine deps imp_mod dep
 271
 272     combine old@(old_has_orphans, old_is_boot) new@(new_has_orphans, new_is_boot)
 273         | old_is_boot = new     -- Record the best is_boot info
 274         | otherwise   = old
 275
 276 -----------------------------------------------------
 277 --      Loading the export list
 278 -----------------------------------------------------
 279
 280 loadExports :: (Version, [ExportItem]) -> RnM d (Version, [(ModuleName,Avails)])
 281 loadExports (vers, items)
 282   = mapRn loadExport items      `thenRn` \ avails_s ->
 283     returnRn (vers, avails_s)
 284
 285
 286 loadExport :: ExportItem -> RnM d (ModuleName, Avails)
 287 loadExport (mod, entities)
 288   = mapRn (load_entity mod) entities    `thenRn` \ avails ->
 289     returnRn (mod, avails)
 290   where
 291     load_entity mod (Avail occ)
 292       = newGlobalName mod occ   `thenRn` \ name ->
 293         returnRn (Avail name)
 294     load_entity mod (AvailTC occ occs)
 295       = newGlobalName mod occ           `thenRn` \ name ->
 296         mapRn (newGlobalName mod) occs  `thenRn` \ names ->
 297         returnRn (AvailTC name names)
 298
 299
 300 -----------------------------------------------------
 301 --      Loading type/class/value decls
 302 -----------------------------------------------------
 303
 304 loadDecls :: Module
 305           -> DeclsMap
 306           -> [(Version, RdrNameTyClDecl)]
 307           -> RnM d (NameEnv Version, DeclsMap)
 308 loadDecls mod (decls_map, n_slurped) decls
 309   = foldlRn (loadDecl mod) (emptyNameEnv, decls_map) decls      `thenRn` \ (vers, decls_map') ->
 310     returnRn (vers, (decls_map', n_slurped))
 311
 312 loadDecl mod (version_map, decls_map) (version, decl)
 313   = getTyClDeclBinders mod decl `thenRn` \ (avail, sys_names) ->
 314     let
 315         full_avail    = case avail of
 316                           Avail n -> avail
 317                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 318         main_name     = availName full_avail
 319         new_decls_map = extendNameEnvList decls_map stuff
 320         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 321                         | name <- availNames full_avail]
 322
 323         new_version_map = extendNameEnv version_map main_name version
 324     in
 325     returnRn (new_version_map, new_decls_map)
 326
 327 -----------------------------------------------------
 328 --      Loading fixity decls
 329 -----------------------------------------------------
 330
 331 loadFixDecls mod decls
 332   = mapRn (loadFixDecl mod_name) decls  `thenRn` \ to_add ->
 333     returnRn (mkNameEnv to_add)
 334   where
 335     mod_name = moduleName mod
 336
 337 loadFixDecl mod_name sig@(FixitySig rdr_name fixity loc)
 338   = newGlobalName mod_name (rdrNameOcc rdr_name)        `thenRn` \ name ->
 339     returnRn (name, fixity)
 340
 341
 342 -----------------------------------------------------
 343 --      Loading instance decls
 344 -----------------------------------------------------
 345
 346 loadInstDecls :: Module
 347               -> IfaceInsts
 348               -> [RdrNameInstDecl]
 349               -> RnM d IfaceInsts
 350 loadInstDecls mod (insts, n_slurped) decls
 351   = setModuleRn mod $
 352     foldlRn (loadInstDecl mod) insts decls      `thenRn` \ insts' ->
 353     returnRn (insts', n_slurped)
 354
 355
 356 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 357   =     -- Find out what type constructors and classes are "gates" for the
 358         -- instance declaration.  If all these "gates" are slurped in then
 359         -- we should slurp the instance decl too.
 360         --
 361         -- We *don't* want to count names in the context part as gates, though.
 362         -- For example:
 363         --              instance Foo a => Baz (T a) where ...
 364         --
 365         -- Here the gates are Baz and T, but *not* Foo.
 366         --
 367         -- HOWEVER: functional dependencies make things more complicated
 368         --      class C a b | a->b where ...
 369         --      instance C Foo Baz where ...
 370         -- Here, the gates are really only C and Foo, *not* Baz.
 371         -- That is, if C and Foo are visible, even if Baz isn't, we must
 372         -- slurp the decl.
 373         --
 374         -- Rather than take fundeps into account "properly", we just slurp
 375         -- if C is visible and *any one* of the Names in the types
 376         -- This is a slightly brutal approximation, but most instance decls
 377         -- are regular H98 ones and it's perfect for them.
 378         --
 379         -- NOTICE that we rename the type before extracting its free
 380         -- variables.  The free-variable finder for a renamed HsType
 381         -- does the Right Thing for built-in syntax like [] and (,).
 382     initIfaceRnMS mod (
 383         rnHsType (text "In an interface instance decl") inst_ty
 384     )                                   `thenRn` \ inst_ty' ->
 385     let
 386         (tvs,(cls,tys)) = get_head inst_ty'
 387         free_tcs  = nameSetToList (extractHsTyNames_s tys) `minusList` hsTyVarNames tvs
 388
 389         gate_fn vis_fn = vis_fn cls && (null free_tcs || any vis_fn free_tcs)
 390         -- Here is the implementation of HOWEVER above
 391         -- (Note that we do let the inst decl in if it mentions
 392         --  no tycons at all.  Hence the null free_ty_names.)
 393     in
 394     returnRn ((gate_fn, (mod, decl)) `consBag` insts)
 395
 396
 397 -- In interface files, the instance decls now look like
 398 --      forall a. Foo a -> Baz (T a)
 399 -- so we have to strip off function argument types,
 400 -- as well as the bit before the '=>' (which is always
 401 -- empty in interface files)
 402 --
 403 -- The parser ensures the type will have the right shape.
 404 -- (e.g. see ParseUtil.checkInstType)
 405
 406 get_head  (HsForAllTy (Just tvs) _ tau) = (tvs, get_head1 tau)
 407 get_head  tau                           = ([],  get_head1 tau)
 408
 409 get_head1 (HsFunTy _ ty)                = get_head1 ty
 410 get_head1 (HsPredTy (HsClassP cls tys)) = (cls,tys)
 411
 412
 413
 414 -----------------------------------------------------
 415 --      Loading Rules
 416 -----------------------------------------------------
 417
 418 loadRules :: Module -> IfaceRules
 419           -> (Version, [RdrNameRuleDecl])
 420           -> RnM d (Version, IfaceRules)
 421 loadRules mod (rule_bag, n_slurped) (version, rules)
 422   | null rules || opt_IgnoreIfacePragmas
 423   = returnRn (version, (rule_bag, n_slurped))
 424   | otherwise
 425   = setModuleRn mod                     $
 426     mapRn (loadRule mod) rules          `thenRn` \ new_rules ->
 427     returnRn (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 428
 429 loadRule :: Module -> RdrNameRuleDecl -> RnM d (GatedDecl RdrNameRuleDecl)
 430 -- "Gate" the rule simply by whether the rule variable is
 431 -- needed.  We can refine this later.
 432 loadRule mod decl@(IfaceRule _ _ _ var _ _ src_loc)
 433   = lookupIfaceName var         `thenRn` \ var_name ->
 434     returnRn (\vis_fn -> vis_fn var_name, (mod, decl))
 435
 436
 437 -----------------------------------------------------
 438 --      Loading Deprecations
 439 -----------------------------------------------------
 440
 441 loadDeprecs :: Module -> IfaceDeprecs -> RnM d Deprecations
 442 loadDeprecs m Nothing                                  = returnRn NoDeprecs
 443 loadDeprecs m (Just (Left txt))  = returnRn (DeprecAll txt)
 444 loadDeprecs m (Just (Right prs)) = setModuleRn m                                $
 445                                    foldlRn loadDeprec emptyNameEnv prs  `thenRn` \ env ->
 446                                    returnRn (DeprecSome env)
 447 loadDeprec deprec_env (n, txt)
 448   = lookupIfaceName n           `thenRn` \ name ->
 449     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenRn_`
 450     returnRn (extendNameEnv deprec_env name (name,txt))
 451 \end{code}
 452
 453
 454 %*********************************************************
 455 %*                                                      *
 456 \subsection{Getting binders out of a declaration}
 457 %*                                                      *
 458 %*********************************************************
 459
 460 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 461 It's used for both source code (from @availsFromDecl@) and interface files
 462 (from @loadDecl@).
 463
 464 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 465 are handled by the sourc-code specific stuff in @RnNames@.
 466
 467         *** See "THE NAMING STORY" in HsDecls ****
 468
 469
 470 \begin{code}
 471 getTyClDeclBinders
 472         :: Module
 473         -> RdrNameTyClDecl
 474         -> RnM d (AvailInfo, [Name])    -- The [Name] are the system names
 475
 476 -----------------
 477 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 478   = newTopBinder mod var src_loc                        `thenRn` \ var_name ->
 479     returnRn (Avail var_name, [])
 480
 481 getTyClDeclBinders mod tycl_decl
 482   = new_top_bndrs mod (tyClDeclNames tycl_decl)         `thenRn` \ names@(main_name:_) ->
 483     new_top_bndrs mod (tyClDeclSysNames tycl_decl)      `thenRn` \ sys_names ->
 484     returnRn (AvailTC main_name names, sys_names)
 485
 486 -----------------
 487 new_top_bndrs mod names_w_locs
 488   = sequenceRn [newTopBinder mod name loc | (name,loc) <- names_w_locs]
 489 \end{code}
 490
 491
 492 %*********************************************************
 493 %*                                                      *
 494 \subsection{Reading an interface file}
 495 %*                                                      *
 496 %*********************************************************
 497
 498 \begin{code}
 499 findAndReadIface :: SDoc -> ModuleName
 500                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 501                                         -- False <=> Look for .hi file
 502                  -> RnM d (Either Message (Module, ParsedIface))
 503         -- Nothing <=> file not found, or unreadable, or illegible
 504         -- Just x  <=> successfully found and parsed
 505
 506 findAndReadIface doc_str mod_name hi_boot_file
 507   = traceRn trace_msg                   `thenRn_`
 508
 509     -- In interactive or --make mode, we are *not allowed* to demand-load
 510     -- a home package .hi file.  So don't even look for them.
 511     -- This helps in the case where you are sitting in eg. ghc/lib/std
 512     -- and start up GHCi - it won't complain that all the modules it tries
 513     -- to load are found in the home location.
 514     ioToRnM_no_fail (readIORef v_GhcMode) `thenRn` \ mode ->
 515     let home_allowed = hi_boot_file ||
 516                        mode `notElem` [ DoInteractive, DoMake ]
 517     in
 518
 519     ioToRnM (if home_allowed
 520                 then findModule mod_name
 521                 else findPackageModule mod_name) `thenRn` \ maybe_found ->
 522
 523     case maybe_found of
 524
 525       Right (Just (wanted_mod,locn))
 526         -> mkHiPath hi_boot_file locn `thenRn` \ file ->
 527            readIface file `thenRn` \ read_result ->
 528            case read_result of
 529                 Left bad -> returnRn (Left bad)
 530                 Right iface
 531                    -> let read_mod = pi_mod iface
 532                       in -- check that the module names agree
 533                          checkRn
 534                            (wanted_mod == read_mod)
 535                            (hiModuleNameMismatchWarn wanted_mod read_mod)
 536                                         `thenRn_`
 537                          -- check that the package names agree
 538                          checkRn
 539                            (modulePackage wanted_mod == modulePackage read_mod)
 540                            (packageNameMismatchWarn wanted_mod read_mod)
 541                                          `thenRn_`
 542                          returnRn (Right (wanted_mod, iface))
 543         -- Can't find it
 544       other   -> traceRn (ptext SLIT("...not found"))   `thenRn_`
 545                  returnRn (Left (noIfaceErr mod_name hi_boot_file))
 546
 547   where
 548     trace_msg = sep [hsep [ptext SLIT("Reading"),
 549                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 550                            ptext SLIT("interface for"),
 551                            ppr mod_name <> semi],
 552                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 553
 554 mkHiPath hi_boot_file locn
 555   | hi_boot_file =
 556         ioToRnM_no_fail (doesFileExist hi_boot_ver_path) `thenRn` \ b ->
 557         if b then returnRn hi_boot_ver_path
 558              else returnRn hi_boot_path
 559   | otherwise    = returnRn hi_path
 560         where hi_path            = ml_hi_file locn
 561               (hi_base, _hi_suf) = splitFilename hi_path
 562               hi_boot_path       = hi_base ++ ".hi-boot"
 563               hi_boot_ver_path   = hi_base ++ ".hi-boot-" ++ cHscIfaceFileVersion
 564 \end{code}
 565
 566 @readIface@ tries just the one file.
 567
 568 \begin{code}
 569 readIface :: String -> RnM d (Either Message ParsedIface)
 570         -- Nothing <=> file not found, or unreadable, or illegible
 571         -- Just x  <=> successfully found and parsed
 572 readIface file_path
 573   = --ioToRnM (putStrLn ("reading iface " ++ file_path)) `thenRn_`
 574     traceRn (ptext SLIT("readIFace") <+> text file_path)        `thenRn_`
 575
 576     ioToRnM (hGetStringBuffer False file_path)                  `thenRn` \ read_result ->
 577     case read_result of {
 578         Left io_error  -> bale_out (text (show io_error)) ;
 579         Right contents ->
 580
 581     case parseIface contents init_parser_state of
 582         POk _ iface          -> returnRn (Right iface)
 583         PFailed err          -> bale_out err
 584     }
 585   where
 586     init_parser_state = PState{ bol = 0#, atbol = 1#,
 587                                 context = [],
 588                                 glasgow_exts = 1#,
 589                                 loc = mkSrcLoc (mkFastString file_path) 1 }
 590
 591     bale_out err = returnRn (Left (badIfaceFile file_path err))
 592 \end{code}
 593
 594 %*********************************************************
 595 %*                                                      *
 596 \subsection{Looking up fixities}
 597 %*                                                      *
 598 %*********************************************************
 599
 600 @lookupFixityRn@ has to be in RnIfaces (or RnHiFiles), instead of
 601 its obvious home in RnEnv,  because it calls @loadHomeInterface@.
 602
 603 lookupFixity is a bit strange.
 604
 605 * Nested local fixity decls are put in the local fixity env, which we
 606   find with getFixtyEnv
 607
 608 * Imported fixities are found in the HIT or PIT
 609
 610 * Top-level fixity decls in this module may be for Names that are
 611     either  Global         (constructors, class operations)
 612     or      Local/Exported (everything else)
 613   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 614   We put them all in the local fixity environment
 615
 616 \begin{code}
 617 lookupFixityRn :: Name -> RnMS Fixity
 618 lookupFixityRn name
 619   = getModuleRn                         `thenRn` \ this_mod ->
 620     if nameIsLocalOrFrom this_mod name
 621     then        -- It's defined in this module
 622         getFixityEnv                    `thenRn` \ local_fix_env ->
 623         returnRn (lookupLocalFixity local_fix_env name)
 624
 625     else        -- It's imported
 626       -- For imported names, we have to get their fixities by doing a
 627       -- loadHomeInterface, and consulting the Ifaces that comes back
 628       -- from that, because the interface file for the Name might not
 629       -- have been loaded yet.  Why not?  Suppose you import module A,
 630       -- which exports a function 'f', which is defined in module B.
 631       -- Then B isn't loaded right away (after all, it's possible that
 632       -- nothing from B will be used).  When we come across a use of
 633       -- 'f', we need to know its fixity, and it's then, and only
 634       -- then, that we load B.hi.  That is what's happening here.
 635         loadHomeInterface doc name              `thenRn` \ iface ->
 636         returnRn (lookupNameEnv (mi_fixities iface) name `orElse` defaultFixity)
 637   where
 638     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 639 \end{code}
 640
 641
 642 %*********************************************************
 643 %*                                                       *
 644 \subsection{Errors}
 645 %*                                                       *
 646 %*********************************************************
 647
 648 \begin{code}
 649 noIfaceErr mod_name boot_file
 650   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 651         -- We used to print the search path, but we can't do that
 652         -- now, because it's hidden inside the finder.
 653         -- Maybe the finder should expose more functions.
 654
 655 badIfaceFile file err
 656   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 657           nest 4 err]
 658
 659 hiModuleNameMismatchWarn :: Module -> Module  -> Message
 660 hiModuleNameMismatchWarn requested_mod read_mod =
 661     hsep [ ptext SLIT("Something is amiss; requested module name")
 662          , ppr (moduleName requested_mod)
 663          , ptext SLIT("differs from name found in the interface file")
 664          , ppr read_mod
 665          ]
 666
 667 packageNameMismatchWarn :: Module -> Module  -> Message
 668 packageNameMismatchWarn requested_mod read_mod =
 669     fsep [ ptext SLIT("Module"), quotes (ppr requested_mod),
 670           ptext SLIT("is located in package"),
 671           quotes (ptext (modulePackage requested_mod)),
 672           ptext SLIT("but its interface file claims it is part of package"),
 673           quotes (ptext (modulePackage read_mod))
 674         ]
 675
 676 warnRedundantSourceImport mod_name
 677   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 678           <+> quotes (ppr mod_name)
 679
 680 warnSelfImport mod
 681   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 682 \end{code}