ghc/compiler/rename/RnHiFiles.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Dealing with interface files}
   5
   6 \begin{code}
   7 module RnHiFiles (
   8         readIface, findAndReadIface, loadInterface, loadHomeInterface,
   9         tryLoadInterface, loadOrphanModules,
  10         loadExports, loadFixDecls, loadDeprecs,
  11
  12         lookupFixityRn,
  13
  14         getTyClDeclBinders,
  15         removeContext           -- removeContext probably belongs somewhere else
  16    ) where
  17
  18 #include "HsVersions.h"
  19
  20 import DriverUtil       ( splitFilename )
  21 import CmdLineOpts      ( opt_IgnoreIfacePragmas )
  22 import HscTypes         ( ModuleLocation(..),
  23                           ModIface(..), emptyModIface,
  24                           VersionInfo(..), ImportedModuleInfo,
  25                           lookupIfaceByModName,
  26                           ImportVersion, WhetherHasOrphans, IsBootInterface,
  27                           DeclsMap, GatedDecl, IfaceInsts, IfaceRules,
  28                           AvailInfo, GenAvailInfo(..), Avails, Deprecations(..)
  29                          )
  30 import HsSyn            ( TyClDecl(..), InstDecl(..),
  31                           HsType(..), FixitySig(..), RuleDecl(..),
  32                           tyClDeclNames, tyClDeclSysNames
  33                         )
  34 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl,
  35                           extractHsTyRdrNames
  36                         )
  37 import BasicTypes       ( Version, defaultFixity )
  38 import RnEnv
  39 import RnMonad
  40 import ParseIface       ( parseIface )
  41
  42 import Name             ( Name {-instance NamedThing-},
  43                           nameModule, isLocalName, nameIsLocalOrFrom
  44                          )
  45 import Name             ( mkNameEnv, extendNameEnv )
  46 import Module           ( Module,
  47                           moduleName, isHomeModule,
  48                           ModuleName, WhereFrom(..),
  49                           extendModuleEnv, mkVanillaModule
  50                         )
  51 import RdrName          ( rdrNameOcc )
  52 import SrcLoc           ( mkSrcLoc )
  53 import Maybes           ( maybeToBool, orElse )
  54 import StringBuffer     ( hGetStringBuffer )
  55 import FastString       ( mkFastString )
  56 import ErrUtils         ( Message )
  57 import Finder           ( findModule )
  58 import Lex
  59 import FiniteMap
  60 import Outputable
  61 import Bag
  62 import Config
  63
  64 import Directory
  65 \end{code}
  66
  67
  68 %*********************************************************
  69 %*                                                      *
  70 \subsection{Loading a new interface file}
  71 %*                                                      *
  72 %*********************************************************
  73
  74 \begin{code}
  75 loadHomeInterface :: SDoc -> Name -> RnM d ModIface
  76 loadHomeInterface doc_str name
  77   = ASSERT2( not (isLocalName name), ppr name <+> parens doc_str )
  78     loadInterface doc_str (moduleName (nameModule name)) ImportBySystem
  79
  80 loadOrphanModules :: [ModuleName] -> RnM d ()
  81 loadOrphanModules mods
  82   | null mods = returnRn ()
  83   | otherwise = traceRn (text "Loading orphan modules:" <+>
  84                          fsep (map ppr mods))                   `thenRn_`
  85                 mapRn_ load mods                                `thenRn_`
  86                 returnRn ()
  87   where
  88     load mod   = loadInterface (mk_doc mod) mod ImportBySystem
  89     mk_doc mod = ppr mod <+> ptext SLIT("is a orphan-instance module")
  90
  91 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d ModIface
  92 loadInterface doc mod from
  93   = tryLoadInterface doc mod from       `thenRn` \ (ifaces, maybe_err) ->
  94     case maybe_err of
  95         Nothing  -> returnRn ifaces
  96         Just err -> failWithRn ifaces (elaborate err)
  97   where
  98     elaborate err = hang (ptext SLIT("failed to load interface for") <+> quotes (ppr mod) <> colon)
  99                          4 err
 100
 101 tryLoadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (ModIface, Maybe Message)
 102   -- Returns (Just err) if an error happened
 103   -- It *doesn't* add an error to the monad, because sometimes it's ok to fail...
 104   -- Specifically, when we read the usage information from an interface file,
 105   -- we try to read the interfaces it mentions.  But it's OK to fail; perhaps
 106   -- the module has changed, and that interface is no longer used.
 107
 108   -- tryLoadInterface guarantees to return with iImpModInfo m --> (..., True)
 109   -- (If the load fails, we plug in a vanilla placeholder)
 110 tryLoadInterface doc_str mod_name from
 111  = getHomeIfaceTableRn          `thenRn` \ hit ->
 112    getModuleRn                  `thenRn` \ this_mod ->
 113    getIfacesRn                  `thenRn` \ ifaces@(Ifaces { iPIT = pit }) ->
 114
 115         -- CHECK WHETHER WE HAVE IT ALREADY
 116    case lookupIfaceByModName hit pit mod_name of {
 117         Just iface |  case from of
 118                         ImportByUser       -> not (mi_boot iface)
 119                         ImportByUserSource -> mi_boot iface
 120                         ImportBySystem     -> True
 121                    -> returnRn (iface, Nothing) ;       -- Already loaded
 122                         -- The not (mi_boot iface) test checks that the already-loaded
 123                         -- interface isn't a boot iface.  This can conceivably happen,
 124                         -- if the version checking happened to load a boot interface
 125                         -- before we got to real imports.
 126         other       ->
 127
 128    let
 129         mod_map  = iImpModInfo ifaces
 130         mod_info = lookupFM mod_map mod_name
 131
 132         hi_boot_file
 133           = case (from, mod_info) of
 134                 (ImportByUser,       _)             -> False    -- Not hi-boot
 135                 (ImportByUserSource, _)             -> True     -- hi-boot
 136                 (ImportBySystem, Just (_, is_boot)) -> is_boot
 137                 (ImportBySystem, Nothing)           -> False
 138                         -- We're importing a module we know absolutely
 139                         -- nothing about, so we assume it's from
 140                         -- another package, where we aren't doing
 141                         -- dependency tracking. So it won't be a hi-boot file.
 142
 143         redundant_source_import
 144           = case (from, mod_info) of
 145                 (ImportByUserSource, Just (_,False)) -> True
 146                 other                                -> False
 147    in
 148
 149         -- Issue a warning for a redundant {- SOURCE -} import
 150         -- NB that we arrange to read all the ordinary imports before
 151         -- any of the {- SOURCE -} imports
 152    warnCheckRn  (not redundant_source_import)
 153                 (warnRedundantSourceImport mod_name)    `thenRn_`
 154
 155         -- Check that we aren't importing ourselves.
 156         -- That only happens in Rename.checkOldIface,
 157         -- which doesn't call tryLoadInterface
 158    warnCheckRn
 159         (not (isHomeModule this_mod) || moduleName this_mod /= mod_name)
 160         (warnSelfImport this_mod)               `thenRn_`
 161
 162         -- READ THE MODULE IN
 163    findAndReadIface doc_str mod_name hi_boot_file   `thenRn` \ read_result ->
 164    case read_result of {
 165         Left err ->     -- Not found, so add an empty export env to the Ifaces map
 166                         -- so that we don't look again
 167            let
 168                 fake_mod    = mkVanillaModule mod_name
 169                 fake_iface  = emptyModIface fake_mod
 170                 new_ifaces  = ifaces { iPIT = extendModuleEnv pit fake_mod fake_iface }
 171            in
 172            setIfacesRn new_ifaces               `thenRn_`
 173            returnRn (fake_iface, Just err) ;
 174
 175         -- Found and parsed!
 176         Right (mod, iface) ->
 177
 178         -- LOAD IT INTO Ifaces
 179
 180         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 181         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 182         --     If we do loadExport first the wrong info gets into the cache (unless we
 183         --      explicitly tag each export which seems a bit of a bore)
 184
 185
 186         -- Sanity check.  If we're system-importing a module we know nothing at all
 187         -- about, it should be from a different package to this one
 188     WARN( not (maybeToBool mod_info) &&
 189           case from of { ImportBySystem -> True; other -> False } &&
 190           isHomeModule mod,
 191           ppr mod )
 192
 193     loadDecls mod               (iDecls ifaces)   (pi_decls iface)      `thenRn` \ (decls_vers, new_decls) ->
 194     loadRules mod               (iRules ifaces)   (pi_rules iface)      `thenRn` \ (rule_vers, new_rules) ->
 195     loadInstDecls mod           (iInsts ifaces)   (pi_insts iface)      `thenRn` \ new_insts ->
 196     loadExports                                   (pi_exports iface)    `thenRn` \ (export_vers, avails) ->
 197     loadFixDecls mod                              (pi_fixity iface)     `thenRn` \ fix_env ->
 198     loadDeprecs mod                               (pi_deprecs iface)    `thenRn` \ deprec_env ->
 199     let
 200         version = VersionInfo { vers_module  = pi_vers iface,
 201                                 vers_exports = export_vers,
 202                                 vers_rules = rule_vers,
 203                                 vers_decls = decls_vers }
 204
 205         -- For an explicit user import, add to mod_map info about
 206         -- the things the imported module depends on, extracted
 207         -- from its usage info; and delete the module itself, which is now in the PIT
 208         mod_map1 = case from of
 209                         ImportByUser -> addModDeps mod is_loaded (pi_usages iface) mod_map
 210                         other        -> mod_map
 211         mod_map2 = delFromFM mod_map1 mod_name
 212
 213         this_mod_name = moduleName this_mod
 214         is_loaded m   =  m == this_mod_name
 215                       || maybeToBool (lookupIfaceByModName hit pit m)
 216                 -- We treat the currently-being-compiled module as 'loaded' because
 217                 -- even though it isn't yet in the HIT or PIT; otherwise it gets
 218                 -- put into iImpModInfo, and then spat out into its own interface
 219                 -- file as a dependency
 220
 221         -- Now add info about this module to the PIT
 222         has_orphans = pi_orphan iface
 223         new_pit   = extendModuleEnv pit mod mod_iface
 224         mod_iface = ModIface { mi_module = mod, mi_version = version,
 225                                mi_orphan = has_orphans, mi_boot = hi_boot_file,
 226                                mi_exports = avails,
 227                                mi_fixities = fix_env, mi_deprecs = deprec_env,
 228                                mi_usages  = [], -- Will be filled in later
 229                                mi_decls   = panic "No mi_decls in PIT",
 230                                mi_globals = mkIfaceGlobalRdrEnv avails
 231                     }
 232
 233         new_ifaces = ifaces { iPIT        = new_pit,
 234                               iDecls      = new_decls,
 235                               iInsts      = new_insts,
 236                               iRules      = new_rules,
 237                               iImpModInfo = mod_map2  }
 238     in
 239     setIfacesRn new_ifaces              `thenRn_`
 240     returnRn (mod_iface, Nothing)
 241     }}
 242
 243 -----------------------------------------------------
 244 --      Adding module dependencies from the
 245 --      import decls in the interface file
 246 -----------------------------------------------------
 247
 248 addModDeps :: Module
 249            -> (ModuleName -> Bool)      -- True for modules that are already loaded
 250            -> [ImportVersion a]
 251            -> ImportedModuleInfo -> ImportedModuleInfo
 252 -- (addModDeps M ivs deps)
 253 -- We are importing module M, and M.hi contains 'import' decls given by ivs
 254 addModDeps mod is_loaded new_deps mod_deps
 255   = foldr add mod_deps filtered_new_deps
 256   where
 257         -- Don't record dependencies when importing a module from another package
 258         -- Except for its descendents which contain orphans,
 259         -- and in that case, forget about the boot indicator
 260     filtered_new_deps :: [(ModuleName, (WhetherHasOrphans, IsBootInterface))]
 261     filtered_new_deps
 262         | isHomeModule mod  = [ (imp_mod, (has_orphans, is_boot))
 263                               | (imp_mod, has_orphans, is_boot, _) <- new_deps,
 264                                 not (is_loaded imp_mod)
 265                               ]
 266         | otherwise         = [ (imp_mod, (True, False))
 267                               | (imp_mod, has_orphans, _, _) <- new_deps,
 268                                 not (is_loaded imp_mod) && has_orphans
 269                               ]
 270     add (imp_mod, dep) deps = addToFM_C combine deps imp_mod dep
 271
 272     combine old@(old_has_orphans, old_is_boot) new@(new_has_orphans, new_is_boot)
 273         | old_is_boot = new     -- Record the best is_boot info
 274         | otherwise   = old
 275
 276 -----------------------------------------------------
 277 --      Loading the export list
 278 -----------------------------------------------------
 279
 280 loadExports :: (Version, [ExportItem]) -> RnM d (Version, [(ModuleName,Avails)])
 281 loadExports (vers, items)
 282   = mapRn loadExport items      `thenRn` \ avails_s ->
 283     returnRn (vers, avails_s)
 284
 285
 286 loadExport :: ExportItem -> RnM d (ModuleName, Avails)
 287 loadExport (mod, entities)
 288   = mapRn (load_entity mod) entities    `thenRn` \ avails ->
 289     returnRn (mod, avails)
 290   where
 291     load_entity mod (Avail occ)
 292       = newGlobalName mod occ   `thenRn` \ name ->
 293         returnRn (Avail name)
 294     load_entity mod (AvailTC occ occs)
 295       = newGlobalName mod occ           `thenRn` \ name ->
 296         mapRn (newGlobalName mod) occs  `thenRn` \ names ->
 297         returnRn (AvailTC name names)
 298
 299
 300 -----------------------------------------------------
 301 --      Loading type/class/value decls
 302 -----------------------------------------------------
 303
 304 loadDecls :: Module
 305           -> DeclsMap
 306           -> [(Version, RdrNameTyClDecl)]
 307           -> RnM d (NameEnv Version, DeclsMap)
 308 loadDecls mod (decls_map, n_slurped) decls
 309   = foldlRn (loadDecl mod) (emptyNameEnv, decls_map) decls      `thenRn` \ (vers, decls_map') ->
 310     returnRn (vers, (decls_map', n_slurped))
 311
 312 loadDecl mod (version_map, decls_map) (version, decl)
 313   = getTyClDeclBinders mod decl `thenRn` \ (avail, sys_names) ->
 314     let
 315         full_avail    = case avail of
 316                           Avail n -> avail
 317                           AvailTC n ns -> AvailTC n (sys_names ++ ns)
 318         main_name     = availName full_avail
 319         new_decls_map = extendNameEnvList decls_map stuff
 320         stuff         = [ (name, (full_avail, name==main_name, (mod, decl)))
 321                         | name <- availNames full_avail]
 322
 323         new_version_map = extendNameEnv version_map main_name version
 324     in
 325     returnRn (new_version_map, new_decls_map)
 326
 327 -----------------------------------------------------
 328 --      Loading fixity decls
 329 -----------------------------------------------------
 330
 331 loadFixDecls mod decls
 332   = mapRn (loadFixDecl mod_name) decls  `thenRn` \ to_add ->
 333     returnRn (mkNameEnv to_add)
 334   where
 335     mod_name = moduleName mod
 336
 337 loadFixDecl mod_name sig@(FixitySig rdr_name fixity loc)
 338   = newGlobalName mod_name (rdrNameOcc rdr_name)        `thenRn` \ name ->
 339     returnRn (name, fixity)
 340
 341
 342 -----------------------------------------------------
 343 --      Loading instance decls
 344 -----------------------------------------------------
 345
 346 loadInstDecls :: Module
 347               -> IfaceInsts
 348               -> [RdrNameInstDecl]
 349               -> RnM d IfaceInsts
 350 loadInstDecls mod (insts, n_slurped) decls
 351   = setModuleRn mod $
 352     foldlRn (loadInstDecl mod) insts decls      `thenRn` \ insts' ->
 353     returnRn (insts', n_slurped)
 354
 355
 356 loadInstDecl mod insts decl@(InstDecl inst_ty _ _ _ _)
 357   =     -- Find out what type constructors and classes are "gates" for the
 358         -- instance declaration.  If all these "gates" are slurped in then
 359         -- we should slurp the instance decl too.
 360         --
 361         -- We *don't* want to count names in the context part as gates, though.
 362         -- For example:
 363         --              instance Foo a => Baz (T a) where ...
 364         --
 365         -- Here the gates are Baz and T, but *not* Foo.
 366     let
 367         munged_inst_ty = removeContext inst_ty
 368         free_names     = extractHsTyRdrNames munged_inst_ty
 369     in
 370     mapRn lookupIfaceName free_names    `thenRn` \ gate_names ->
 371     returnRn ((gate_names, (mod, decl)) `consBag` insts)
 372
 373
 374 -- In interface files, the instance decls now look like
 375 --      forall a. Foo a -> Baz (T a)
 376 -- so we have to strip off function argument types as well
 377 -- as the bit before the '=>' (which is always empty in interface files)
 378 removeContext (HsForAllTy tvs cxt ty) = HsForAllTy tvs [] (removeFuns ty)
 379 removeContext ty                      = removeFuns ty
 380
 381 removeFuns (HsFunTy _ ty) = removeFuns ty
 382 removeFuns ty               = ty
 383
 384
 385 -----------------------------------------------------
 386 --      Loading Rules
 387 -----------------------------------------------------
 388
 389 loadRules :: Module -> IfaceRules
 390           -> (Version, [RdrNameRuleDecl])
 391           -> RnM d (Version, IfaceRules)
 392 loadRules mod (rule_bag, n_slurped) (version, rules)
 393   | null rules || opt_IgnoreIfacePragmas
 394   = returnRn (version, (rule_bag, n_slurped))
 395   | otherwise
 396   = setModuleRn mod                     $
 397     mapRn (loadRule mod) rules          `thenRn` \ new_rules ->
 398     returnRn (version, (rule_bag `unionBags` listToBag new_rules, n_slurped))
 399
 400 loadRule :: Module -> RdrNameRuleDecl -> RnM d (GatedDecl RdrNameRuleDecl)
 401 -- "Gate" the rule simply by whether the rule variable is
 402 -- needed.  We can refine this later.
 403 loadRule mod decl@(IfaceRule _ _ var _ _ src_loc)
 404   = lookupIfaceName var         `thenRn` \ var_name ->
 405     returnRn ([var_name], (mod, decl))
 406
 407
 408 -----------------------------------------------------
 409 --      Loading Deprecations
 410 -----------------------------------------------------
 411
 412 loadDeprecs :: Module -> IfaceDeprecs -> RnM d Deprecations
 413 loadDeprecs m Nothing                                  = returnRn NoDeprecs
 414 loadDeprecs m (Just (Left txt))  = returnRn (DeprecAll txt)
 415 loadDeprecs m (Just (Right prs)) = setModuleRn m                                $
 416                                    foldlRn loadDeprec emptyNameEnv prs  `thenRn` \ env ->
 417                                    returnRn (DeprecSome env)
 418 loadDeprec deprec_env (n, txt)
 419   = lookupIfaceName n           `thenRn` \ name ->
 420     traceRn (text "Loaded deprecation(s) for" <+> ppr name <> colon <+> ppr txt) `thenRn_`
 421     returnRn (extendNameEnv deprec_env name (name,txt))
 422 \end{code}
 423
 424
 425 %*********************************************************
 426 %*                                                      *
 427 \subsection{Getting binders out of a declaration}
 428 %*                                                      *
 429 %*********************************************************
 430
 431 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 432 It's used for both source code (from @availsFromDecl@) and interface files
 433 (from @loadDecl@).
 434
 435 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 436 are handled by the sourc-code specific stuff in @RnNames@.
 437
 438         *** See "THE NAMING STORY" in HsDecls ****
 439
 440
 441 \begin{code}
 442 getTyClDeclBinders
 443         :: Module
 444         -> RdrNameTyClDecl
 445         -> RnM d (AvailInfo, [Name])    -- The [Name] are the system names
 446
 447 -----------------
 448 getTyClDeclBinders mod (IfaceSig {tcdName = var, tcdLoc = src_loc})
 449   = newTopBinder mod var src_loc                        `thenRn` \ var_name ->
 450     returnRn (Avail var_name, [])
 451
 452 getTyClDeclBinders mod tycl_decl
 453   = new_top_bndrs mod (tyClDeclNames tycl_decl)         `thenRn` \ names@(main_name:_) ->
 454     new_top_bndrs mod (tyClDeclSysNames tycl_decl)      `thenRn` \ sys_names ->
 455     returnRn (AvailTC main_name names, sys_names)
 456
 457 -----------------
 458 new_top_bndrs mod names_w_locs
 459   = sequenceRn [newTopBinder mod name loc | (name,loc) <- names_w_locs]
 460 \end{code}
 461
 462
 463 %*********************************************************
 464 %*                                                      *
 465 \subsection{Reading an interface file}
 466 %*                                                      *
 467 %*********************************************************
 468
 469 \begin{code}
 470 findAndReadIface :: SDoc -> ModuleName
 471                  -> IsBootInterface     -- True  <=> Look for a .hi-boot file
 472                                         -- False <=> Look for .hi file
 473                  -> RnM d (Either Message (Module, ParsedIface))
 474         -- Nothing <=> file not found, or unreadable, or illegible
 475         -- Just x  <=> successfully found and parsed
 476
 477 findAndReadIface doc_str mod_name hi_boot_file
 478   = traceRn trace_msg                   `thenRn_`
 479
 480     ioToRnM (findModule mod_name)       `thenRn` \ maybe_found ->
 481     case maybe_found of
 482
 483       Right (Just (wanted_mod,locn))
 484         -> mkHiPath hi_boot_file locn `thenRn` \ file ->
 485            readIface file `thenRn` \ read_result ->
 486            case read_result of
 487                 Left bad -> returnRn (Left bad)
 488                 Right iface
 489                    -> let read_mod = pi_mod iface
 490                       in warnCheckRn (wanted_mod == read_mod)
 491                                      (hiModuleNameMismatchWarn wanted_mod
 492                                         read_mod) `thenRn_`
 493                          returnRn (Right (wanted_mod, iface))
 494         -- Can't find it
 495       other   -> traceRn (ptext SLIT("...not found"))   `thenRn_`
 496                  returnRn (Left (noIfaceErr mod_name hi_boot_file))
 497
 498   where
 499     trace_msg = sep [hsep [ptext SLIT("Reading"),
 500                            if hi_boot_file then ptext SLIT("[boot]") else empty,
 501                            ptext SLIT("interface for"),
 502                            ppr mod_name <> semi],
 503                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 504
 505 mkHiPath hi_boot_file locn
 506   | hi_boot_file =
 507         ioToRnM_no_fail (doesFileExist hi_boot_ver_path) `thenRn` \ b ->
 508         if b then returnRn hi_boot_ver_path
 509              else returnRn hi_boot_path
 510   | otherwise    = returnRn hi_path
 511         where (Just hi_path)    = ml_hi_file locn
 512               (hi_base, hi_suf) = splitFilename hi_path
 513               hi_boot_path      = hi_base ++ ".hi-boot"
 514               hi_boot_ver_path  = hi_base ++ ".hi-boot-" ++ cHscIfaceFileVersion
 515 \end{code}
 516
 517 @readIface@ tries just the one file.
 518
 519 \begin{code}
 520 readIface :: String -> RnM d (Either Message ParsedIface)
 521         -- Nothing <=> file not found, or unreadable, or illegible
 522         -- Just x  <=> successfully found and parsed
 523 readIface file_path
 524   = --ioToRnM (putStrLn ("reading iface " ++ file_path)) `thenRn_`
 525     traceRn (ptext SLIT("readIFace") <+> text file_path)        `thenRn_`
 526
 527     ioToRnM (hGetStringBuffer False file_path)                  `thenRn` \ read_result ->
 528     case read_result of {
 529         Left io_error  -> bale_out (text (show io_error)) ;
 530         Right contents ->
 531
 532     case parseIface contents init_parser_state of
 533         POk _ iface          -> returnRn (Right iface)
 534         PFailed err          -> bale_out err
 535     }
 536   where
 537     init_parser_state = PState{ bol = 0#, atbol = 1#,
 538                                 context = [],
 539                                 glasgow_exts = 1#,
 540                                 loc = mkSrcLoc (mkFastString file_path) 1 }
 541
 542     bale_out err = returnRn (Left (badIfaceFile file_path err))
 543 \end{code}
 544
 545
 546 %*********************************************************
 547 %*                                                      *
 548 \subsection{Looking up fixities}
 549 %*                                                      *
 550 %*********************************************************
 551
 552 @lookupFixityRn@ has to be in RnIfaces (or RnHiFiles) because
 553 it calls @loadHomeInterface@.
 554
 555 lookupFixity is a bit strange.
 556
 557 * Nested local fixity decls are put in the local fixity env, which we
 558   find with getFixtyEnv
 559
 560 * Imported fixities are found in the HIT or PIT
 561
 562 * Top-level fixity decls in this module may be for Names that are
 563     either  Global         (constructors, class operations)
 564     or      Local/Exported (everything else)
 565   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
 566   We put them all in the local fixity environment
 567
 568 \begin{code}
 569 lookupFixityRn :: Name -> RnMS Fixity
 570 lookupFixityRn name
 571   = getModuleRn                         `thenRn` \ this_mod ->
 572     if nameIsLocalOrFrom this_mod name
 573     then        -- It's defined in this module
 574         getFixityEnv                    `thenRn` \ local_fix_env ->
 575         returnRn (lookupLocalFixity local_fix_env name)
 576
 577     else        -- It's imported
 578       -- For imported names, we have to get their fixities by doing a loadHomeInterface,
 579       -- and consulting the Ifaces that comes back from that, because the interface
 580       -- file for the Name might not have been loaded yet.  Why not?  Suppose you import module A,
 581       -- which exports a function 'f', which is defined in module B.  Then B isn't loaded
 582       -- right away (after all, it's possible that nothing from B will be used).
 583       -- When we come across a use of 'f', we need to know its fixity, and it's then,
 584       -- and only then, that we load B.hi.  That is what's happening here.
 585         loadHomeInterface doc name              `thenRn` \ iface ->
 586         returnRn (lookupNameEnv (mi_fixities iface) name `orElse` defaultFixity)
 587   where
 588     doc      = ptext SLIT("Checking fixity for") <+> ppr name
 589 \end{code}
 590
 591
 592 %*********************************************************
 593 %*                                                       *
 594 \subsection{Errors}
 595 %*                                                       *
 596 %*********************************************************
 597
 598 \begin{code}
 599 noIfaceErr mod_name boot_file
 600   = ptext SLIT("Could not find interface file for") <+> quotes (ppr mod_name)
 601         -- We used to print the search path, but we can't do that
 602         -- now, because it's hidden inside the finder.
 603         -- Maybe the finder should expose more functions.
 604
 605 badIfaceFile file err
 606   = vcat [ptext SLIT("Bad interface file:") <+> text file,
 607           nest 4 err]
 608
 609 hiModuleNameMismatchWarn :: Module -> Module  -> Message
 610 hiModuleNameMismatchWarn requested_mod read_mod =
 611     hsep [ ptext SLIT("Something is amiss; requested module name")
 612          , ppr (moduleName requested_mod)
 613          , ptext SLIT("differs from name found in the interface file")
 614          , ppr read_mod
 615          ]
 616
 617 warnRedundantSourceImport mod_name
 618   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 619           <+> quotes (ppr mod_name)
 620
 621 warnSelfImport mod
 622   = ptext SLIT("Importing my own interface: module") <+> ppr mod
 623 \end{code}
 624