ghc/compiler/rename/RnIfaces.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnIfaces]{Cacheing and Renaming of Interfaces}
   5
   6 \begin{code}
   7 module RnIfaces (
   8         getInterfaceExports,
   9         getImportedInstDecls, getImportedRules,
  10         lookupFixity, loadHomeInterface,
  11         importDecl, recordSlurp,
  12         getImportVersions, getSlurped,
  13
  14         checkUpToDate,
  15
  16         getDeclBinders, getDeclSysBinders,
  17         removeContext           -- removeContext probably belongs somewhere else
  18     ) where
  19
  20 #include "HsVersions.h"
  21
  22 import CmdLineOpts      ( opt_NoPruneDecls, opt_IgnoreIfacePragmas )
  23 import HsSyn            ( HsDecl(..), TyClDecl(..), InstDecl(..), IfaceSig(..),
  24                           HsType(..), ConDecl(..), IE(..), ConDetails(..), Sig(..),
  25                           ForeignDecl(..), ForKind(..), isDynamic,
  26                           FixitySig(..), RuleDecl(..),
  27                           isClassOpSig
  28                         )
  29 import BasicTypes       ( Version, NewOrData(..), defaultFixity )
  30 import RdrHsSyn         ( RdrNameHsDecl, RdrNameInstDecl, RdrNameTyClDecl, RdrNameRuleDecl,
  31                           extractHsTyRdrNames
  32                         )
  33 import RnEnv            ( mkImportedGlobalName, newImportedBinder, mkImportedGlobalFromRdrName,
  34                           lookupOccRn, lookupImplicitOccRn,
  35                           pprAvail,
  36                           availName, availNames, addAvailToNameSet,
  37                           FreeVars, emptyFVs
  38                         )
  39 import RnMonad
  40 import RnHsSyn          ( RenamedHsDecl )
  41 import ParseIface       ( parseIface, IfaceStuff(..) )
  42
  43 import FiniteMap        ( FiniteMap, sizeFM, emptyFM, delFromFM, listToFM,
  44                           lookupFM, addToFM, addToFM_C, addListToFM,
  45                           fmToList, elemFM, foldFM
  46                         )
  47 import Name             ( Name {-instance NamedThing-},
  48                           nameModule, isLocallyDefined,
  49                           isWiredInName, nameUnique, NamedThing(..)
  50                          )
  51 import Module           ( Module, moduleString, pprModule,
  52                           mkVanillaModule, pprModuleName,
  53                           moduleUserString, moduleName, isLibModule,
  54                           ModuleName, WhereFrom(..),
  55                         )
  56 import RdrName          ( RdrName, rdrNameOcc )
  57 import NameSet
  58 import Var              ( Id )
  59 import SrcLoc           ( mkSrcLoc, SrcLoc )
  60 import PrelMods         ( pREL_GHC )
  61 import PrelInfo         ( cCallishTyKeys, thinAirModules )
  62 import Bag
  63 import Maybes           ( MaybeErr(..), maybeToBool, orElse )
  64 import ListSetOps       ( unionLists )
  65 import Outputable
  66 import Unique           ( Unique )
  67 import StringBuffer     ( StringBuffer, hGetStringBuffer )
  68 import FastString       ( mkFastString )
  69 import ErrUtils         ( Message )
  70 import Lex
  71 import Outputable
  72
  73 import IO       ( isDoesNotExistError )
  74 import List     ( nub )
  75 \end{code}
  76
  77
  78 %*********************************************************
  79 %*                                                      *
  80 \subsection{Loading a new interface file}
  81 %*                                                      *
  82 %*********************************************************
  83
  84 \begin{code}
  85 loadHomeInterface :: SDoc -> Name -> RnM d Ifaces
  86 loadHomeInterface doc_str name
  87   = loadInterface doc_str (moduleName (nameModule name)) ImportBySystem         `thenRn` \ (_, ifaces) ->
  88     returnRn ifaces
  89
  90 loadOrphanModules :: [ModuleName] -> RnM d ()
  91 loadOrphanModules mods
  92   | null mods = returnRn ()
  93   | otherwise = traceRn (text "Loading orphan modules:" <+> fsep (map pprModuleName mods))      `thenRn_`
  94                 mapRn_ load mods        `thenRn_`
  95                 returnRn ()
  96   where
  97     load mod = loadInterface (pprModuleName mod <+> ptext SLIT("is a orphan-instance module")) mod ImportBySystem
  98
  99 loadInterface :: SDoc -> ModuleName -> WhereFrom -> RnM d (Module, Ifaces)
 100 loadInterface doc_str mod_name from
 101  = getIfacesRn                  `thenRn` \ ifaces ->
 102    let
 103         mod_map  = iImpModInfo ifaces
 104         mod_info = lookupFM mod_map mod_name
 105         in_map   = maybeToBool mod_info
 106    in
 107
 108         -- Issue a warning for a redundant {- SOURCE -} import
 109         -- It's redundant if the moduld is in the iImpModInfo at all,
 110         -- because we arrange to read all the ordinary imports before
 111         -- any of the {- SOURCE -} imports
 112    warnCheckRn  (not (in_map && case from of {ImportByUserSource -> True; other -> False}))
 113                 (warnRedundantSourceImport mod_name)    `thenRn_`
 114
 115         -- CHECK WHETHER WE HAVE IT ALREADY
 116    case mod_info of {
 117         Just (_, _, Just (load_mod, _, _))
 118                 ->      -- We're read it already so don't re-read it
 119                     returnRn (load_mod, ifaces) ;
 120
 121         mod_map_result ->
 122
 123         -- READ THE MODULE IN
 124    findAndReadIface doc_str mod_name from in_map
 125    `thenRn` \ (hi_boot_read, read_result) ->
 126    case read_result of {
 127         Nothing ->      -- Not found, so add an empty export env to the Ifaces map
 128                         -- so that we don't look again
 129            let
 130                 mod         = mkVanillaModule mod_name
 131                 new_mod_map = addToFM mod_map mod_name (0, False, Just (mod, False, []))
 132                 new_ifaces  = ifaces { iImpModInfo = new_mod_map }
 133            in
 134            setIfacesRn new_ifaces               `thenRn_`
 135            failWithRn (mod, new_ifaces) (noIfaceErr mod hi_boot_read) ;
 136
 137         -- Found and parsed!
 138         Just (mod, iface) ->
 139
 140         -- LOAD IT INTO Ifaces
 141
 142         -- NB: *first* we do loadDecl, so that the provenance of all the locally-defined
 143         ---    names is done correctly (notably, whether this is an .hi file or .hi-boot file).
 144         --     If we do loadExport first the wrong info gets into the cache (unless we
 145         --      explicitly tag each export which seems a bit of a bore)
 146
 147     getModuleRn                 `thenRn` \ this_mod_nm ->
 148     let
 149         rd_decls = pi_decls iface
 150     in
 151     foldlRn (loadDecl mod)           (iDecls ifaces) rd_decls           `thenRn` \ new_decls ->
 152     foldlRn (loadInstDecl mod)       (iInsts ifaces) (pi_insts iface)   `thenRn` \ new_insts ->
 153     (if (opt_IgnoreIfacePragmas)
 154         then returnRn emptyBag
 155         else foldlRn (loadRule mod)  (iRules ifaces) (pi_rules iface))  `thenRn` \ new_rules ->
 156     foldlRn (loadFixDecl mod_name)   (iFixes ifaces) rd_decls           `thenRn` \ new_fixities ->
 157     mapRn   (loadExport this_mod_nm) (pi_exports iface)                 `thenRn` \ avails_s ->
 158     let
 159         -- For an explicit user import, add to mod_map info about
 160         -- the things the imported module depends on, extracted
 161         -- from its usage info.
 162         mod_map1 = case from of
 163                         ImportByUser -> addModDeps mod mod_map (pi_usages iface)
 164                         other        -> mod_map
 165
 166         -- Now add info about this module
 167         mod_map2    = addToFM mod_map1 mod_name mod_details
 168         mod_details = (pi_mod iface, pi_orphan iface, Just (mod, hi_boot_read, concat avails_s))
 169
 170         new_ifaces = ifaces { iImpModInfo = mod_map2,
 171                               iDecls      = new_decls,
 172                               iFixes      = new_fixities,
 173                               iRules      = new_rules,
 174                               iInsts      = new_insts }
 175     in
 176     setIfacesRn new_ifaces              `thenRn_`
 177     returnRn (mod, new_ifaces)
 178     }}
 179
 180 addModDeps :: Module -> ImportedModuleInfo
 181            -> [ImportVersion a] -> ImportedModuleInfo
 182 addModDeps mod mod_deps new_deps
 183   = foldr add mod_deps new_deps
 184   where
 185     is_lib = isLibModule mod    -- Don't record dependencies when importing a library module
 186     add (imp_mod, version, has_orphans, _) deps
 187         | is_lib && not has_orphans = deps
 188         | otherwise  =  addToFM_C combine deps imp_mod (version, has_orphans, Nothing)
 189         -- Record dependencies for modules that are
 190         --      either are dependent via a non-library module
 191         --      or contain orphan rules or instance decls
 192
 193         -- Don't ditch a module that's already loaded!!
 194     combine old@(_, _, Just _)  new = old
 195     combine old@(_, _, Nothing) new = new
 196
 197 loadExport :: ModuleName -> ExportItem -> RnM d [AvailInfo]
 198 loadExport this_mod (mod, entities)
 199   | mod == this_mod = returnRn []
 200         -- If the module exports anything defined in this module, just ignore it.
 201         -- Reason: otherwise it looks as if there are two local definition sites
 202         -- for the thing, and an error gets reported.  Easiest thing is just to
 203         -- filter them out up front. This situation only arises if a module
 204         -- imports itself, or another module that imported it.  (Necessarily,
 205         -- this invoves a loop.)  Consequence: if you say
 206         --      module A where
 207         --         import B( AType )
 208         --         type AType = ...
 209         --
 210         --      module B( AType ) where
 211         --         import {-# SOURCE #-} A( AType )
 212         --
 213         -- then you'll get a 'B does not export AType' message.  A bit bogus
 214         -- but it's a bogus thing to do!
 215
 216   | otherwise
 217   = mapRn (load_entity mod) entities
 218   where
 219     new_name mod occ = mkImportedGlobalName mod occ
 220
 221     load_entity mod (Avail occ)
 222       = new_name mod occ        `thenRn` \ name ->
 223         returnRn (Avail name)
 224     load_entity mod (AvailTC occ occs)
 225       = new_name mod occ              `thenRn` \ name ->
 226         mapRn (new_name mod) occs     `thenRn` \ names ->
 227         returnRn (AvailTC name names)
 228
 229
 230 loadFixDecl :: ModuleName -> FixityEnv
 231             -> (Version, RdrNameHsDecl)
 232             -> RnM d FixityEnv
 233 loadFixDecl mod_name fixity_env (version, FixD sig@(FixitySig rdr_name fixity loc))
 234   =     -- Ignore the version; when the fixity changes the version of
 235         -- its 'host' entity changes, so we don't need a separate version
 236         -- number for fixities
 237     mkImportedGlobalName mod_name (rdrNameOcc rdr_name)         `thenRn` \ name ->
 238     let
 239         new_fixity_env = addToNameEnv fixity_env name (FixitySig name fixity loc)
 240     in
 241     returnRn new_fixity_env
 242
 243         -- Ignore the other sorts of decl
 244 loadFixDecl mod_name fixity_env other_decl = returnRn fixity_env
 245
 246 loadDecl :: Module
 247          -> DeclsMap
 248          -> (Version, RdrNameHsDecl)
 249          -> RnM d DeclsMap
 250
 251 loadDecl mod decls_map (version, decl)
 252   = getDeclBinders new_name decl        `thenRn` \ maybe_avail ->
 253     case maybe_avail of {
 254         Nothing -> returnRn decls_map;  -- No bindings
 255         Just avail ->
 256
 257     getDeclSysBinders new_name decl     `thenRn` \ sys_bndrs ->
 258     let
 259         main_name     = availName avail
 260         new_decls_map = foldl add_decl decls_map
 261                                        [ (name, (version, avail, name==main_name, (mod, decl')))
 262                                        | name <- sys_bndrs ++ availNames avail]
 263         add_decl decls_map (name, stuff)
 264           = WARN( name `elemNameEnv` decls_map, ppr name )
 265             addToNameEnv decls_map name stuff
 266     in
 267     returnRn new_decls_map
 268     }
 269   where
 270         -- newImportedBinder puts into the cache the binder with the
 271         -- module information set correctly.  When the decl is later renamed,
 272         -- the binding site will thereby get the correct module.
 273     new_name rdr_name loc = newImportedBinder mod rdr_name
 274
 275     {-
 276       If a signature decl is being loaded, and optIgnoreIfacePragmas is on,
 277       we toss away unfolding information.
 278
 279       Also, if the signature is loaded from a module we're importing from source,
 280       we do the same. This is to avoid situations when compiling a pair of mutually
 281       recursive modules, peering at unfolding info in the interface file of the other,
 282       e.g., you compile A, it looks at B's interface file and may as a result change
 283       its interface file. Hence, B is recompiled, maybe changing its interface file,
 284       which will the unfolding info used in A to become invalid. Simple way out is to
 285       just ignore unfolding info.
 286
 287       [Jan 99: I junked the second test above.  If we're importing from an hi-boot
 288        file there isn't going to *be* any pragma info.  Maybe the above comment
 289        dates from a time where we picked up a .hi file first if it existed?]
 290     -}
 291     decl' = case decl of
 292                SigD (IfaceSig name tp ls loc) | opt_IgnoreIfacePragmas
 293                          ->  SigD (IfaceSig name tp [] loc)
 294                other     -> decl
 295
 296 loadInstDecl :: Module
 297              -> Bag GatedDecl
 298              -> RdrNameInstDecl
 299              -> RnM d (Bag GatedDecl)
 300 loadInstDecl mod insts decl@(InstDecl inst_ty binds uprags dfun_name src_loc)
 301   =
 302         -- Find out what type constructors and classes are "gates" for the
 303         -- instance declaration.  If all these "gates" are slurped in then
 304         -- we should slurp the instance decl too.
 305         --
 306         -- We *don't* want to count names in the context part as gates, though.
 307         -- For example:
 308         --              instance Foo a => Baz (T a) where ...
 309         --
 310         -- Here the gates are Baz and T, but *not* Foo.
 311     let
 312         munged_inst_ty = removeContext inst_ty
 313         free_names     = extractHsTyRdrNames munged_inst_ty
 314     in
 315     setModuleRn (moduleName mod) $
 316     mapRn mkImportedGlobalFromRdrName free_names        `thenRn` \ gate_names ->
 317     returnRn ((mkNameSet gate_names, (mod, InstD decl)) `consBag` insts)
 318
 319
 320 -- In interface files, the instance decls now look like
 321 --      forall a. Foo a -> Baz (T a)
 322 -- so we have to strip off function argument types as well
 323 -- as the bit before the '=>' (which is always empty in interface files)
 324 removeContext (HsForAllTy tvs cxt ty) = HsForAllTy tvs [] (removeFuns ty)
 325 removeContext ty                      = removeFuns ty
 326
 327 removeFuns (MonoFunTy _ ty) = removeFuns ty
 328 removeFuns ty               = ty
 329
 330
 331 loadRule :: Module -> Bag GatedDecl
 332          -> RdrNameRuleDecl -> RnM d (Bag GatedDecl)
 333 -- "Gate" the rule simply by whether the rule variable is
 334 -- needed.  We can refine this later.
 335 loadRule mod rules decl@(IfaceRuleDecl var body src_loc)
 336   = setModuleRn (moduleName mod) $
 337     mkImportedGlobalFromRdrName var             `thenRn` \ var_name ->
 338     returnRn ((unitNameSet var_name, (mod, RuleD decl)) `consBag` rules)
 339 \end{code}
 340
 341
 342 %********************************************************
 343 %*                                                      *
 344 \subsection{Loading usage information}
 345 %*                                                      *
 346 %********************************************************
 347
 348 \begin{code}
 349 checkUpToDate :: ModuleName -> RnMG Bool                -- True <=> no need to recompile
 350 checkUpToDate mod_name
 351   = getIfacesRn                                 `thenRn` \ ifaces ->
 352     findAndReadIface doc_str mod_name
 353                      ImportByUser
 354                      (error "checkUpToDate")    `thenRn` \ (_, read_result) ->
 355
 356         -- CHECK WHETHER WE HAVE IT ALREADY
 357     case read_result of
 358         Nothing ->      -- Old interface file not found, so we'd better bail out
 359                     traceRn (sep [ptext SLIT("Didnt find old iface"),
 360                                   pprModuleName mod_name])      `thenRn_`
 361                     returnRn False
 362
 363         Just (_, iface)
 364                 ->      -- Found it, so now check it
 365                     checkModUsage (pi_usages iface)
 366   where
 367         -- Only look in current directory, with suffix .hi
 368     doc_str = sep [ptext SLIT("need usage info from"), pprModuleName mod_name]
 369
 370 checkModUsage [] = returnRn True                -- Yes!  Everything is up to date!
 371
 372 checkModUsage ((mod_name, old_mod_vers, _, whats_imported) : rest)
 373   = loadInterface doc_str mod_name ImportBySystem       `thenRn` \ (mod, ifaces) ->
 374     let
 375         maybe_mod_vers = case lookupFM (iImpModInfo ifaces) mod_name of
 376                            Just (version, _, Just (_, _, _)) -> Just version
 377                            other                             -> Nothing
 378     in
 379     case maybe_mod_vers of {
 380         Nothing ->      -- If we can't find a version number for the old module then
 381                         -- bail out saying things aren't up to date
 382                 traceRn (sep [ptext SLIT("Can't find version number for module"),
 383                               pprModuleName mod_name])
 384                 `thenRn_` returnRn False ;
 385
 386         Just new_mod_vers ->
 387
 388         -- If the module version hasn't changed, just move on
 389     if new_mod_vers == old_mod_vers then
 390         traceRn (sep [ptext SLIT("Module version unchanged:"), pprModuleName mod_name])
 391         `thenRn_` checkModUsage rest
 392     else
 393     traceRn (sep [ptext SLIT("Module version has changed:"), pprModuleName mod_name])
 394     `thenRn_`
 395         -- Module version changed, so check entities inside
 396
 397         -- If the usage info wants to say "I imported everything from this module"
 398         --     it does so by making whats_imported equal to Everything
 399         -- In that case, we must recompile
 400     case whats_imported of {
 401       Everything -> traceRn (ptext SLIT("...and I needed the whole module"))    `thenRn_`
 402                     returnRn False;                -- Bale out
 403
 404       Specifically old_local_vers ->
 405
 406         -- Non-empty usage list, so check item by item
 407     checkEntityUsage mod_name (iDecls ifaces) old_local_vers    `thenRn` \ up_to_date ->
 408     if up_to_date then
 409         traceRn (ptext SLIT("...but the bits I use haven't."))  `thenRn_`
 410         checkModUsage rest      -- This one's ok, so check the rest
 411     else
 412         returnRn False          -- This one failed, so just bail out now
 413     }}
 414   where
 415     doc_str = sep [ptext SLIT("need version info for"), pprModuleName mod_name]
 416
 417
 418 checkEntityUsage mod decls []
 419   = returnRn True       -- Yes!  All up to date!
 420
 421 checkEntityUsage mod decls ((occ_name,old_vers) : rest)
 422   = mkImportedGlobalName mod occ_name   `thenRn` \ name ->
 423     case lookupNameEnv decls name of
 424
 425         Nothing       ->        -- We used it before, but it ain't there now
 426                           traceRn (sep [ptext SLIT("No longer exported:"), ppr name])
 427                           `thenRn_` returnRn False
 428
 429         Just (new_vers,_,_,_)   -- It's there, but is it up to date?
 430                 | new_vers == old_vers
 431                         -- Up to date, so check the rest
 432                 -> checkEntityUsage mod decls rest
 433
 434                 | otherwise
 435                         -- Out of date, so bale out
 436                 -> traceRn (sep [ptext SLIT("Out of date:"), ppr name])  `thenRn_`
 437                    returnRn False
 438 \end{code}
 439
 440
 441 %*********************************************************
 442 %*                                                      *
 443 \subsection{Getting in a declaration}
 444 %*                                                      *
 445 %*********************************************************
 446
 447 \begin{code}
 448 importDecl :: Name -> RnMG (Maybe (Module, RdrNameHsDecl))
 449         -- Returns Nothing for
 450         --      (a) wired in name
 451         --      (b) local decl
 452         --      (c) already slurped
 453
 454 importDecl name
 455   | isWiredInName name
 456   = returnRn Nothing
 457   | otherwise
 458   = getSlurped                          `thenRn` \ already_slurped ->
 459     if name `elemNameSet` already_slurped then
 460         returnRn Nothing        -- Already dealt with
 461     else
 462         if isLocallyDefined name then   -- Don't bring in decls from
 463                                         -- the renamed module's own interface file
 464                   addWarnRn (importDeclWarn name) `thenRn_`
 465                   returnRn Nothing
 466         else
 467         getNonWiredInDecl name
 468 \end{code}
 469
 470 \begin{code}
 471 getNonWiredInDecl :: Name -> RnMG (Maybe (Module, RdrNameHsDecl))
 472 getNonWiredInDecl needed_name
 473   = traceRn doc_str                             `thenRn_`
 474     loadHomeInterface doc_str needed_name       `thenRn` \ ifaces ->
 475     case lookupNameEnv (iDecls ifaces) needed_name of
 476
 477       Just (version,avail,_,decl)
 478         -> recordSlurp (Just version) avail     `thenRn_`
 479            returnRn (Just decl)
 480
 481       Nothing           -- Can happen legitimately for "Optional" occurrences
 482         -> addErrRn (getDeclErr needed_name)    `thenRn_`
 483            returnRn Nothing
 484   where
 485      doc_str = ptext SLIT("need decl for") <+> ppr needed_name
 486 \end{code}
 487
 488 @getWiredInDecl@ maps a wired-in @Name@ to what it makes available.
 489 It behaves exactly as if the wired in decl were actually in an interface file.
 490 Specifically,
 491 \begin{itemize}
 492 \item   if the wired-in name is a data type constructor or a data constructor,
 493         it brings in the type constructor and all the data constructors; and
 494         marks as ``occurrences'' any free vars of the data con.
 495
 496 \item   similarly for synonum type constructor
 497
 498 \item   if the wired-in name is another wired-in Id, it marks as ``occurrences''
 499         the free vars of the Id's type.
 500
 501 \item   it loads the interface file for the wired-in thing for the
 502         sole purpose of making sure that its instance declarations are available
 503 \end{itemize}
 504 All this is necessary so that we know all types that are ``in play'', so
 505 that we know just what instances to bring into scope.
 506
 507
 508
 509
 510 %*********************************************************
 511 %*                                                      *
 512 \subsection{Getting what a module exports}
 513 %*                                                      *
 514 %*********************************************************
 515
 516 @getInterfaceExports@ is called only for directly-imported modules.
 517
 518 \begin{code}
 519 getInterfaceExports :: ModuleName -> WhereFrom -> RnMG (Module, Avails)
 520 getInterfaceExports mod_name from
 521   = loadInterface doc_str mod_name from `thenRn` \ (mod, ifaces) ->
 522     case lookupFM (iImpModInfo ifaces) mod_name of
 523         Nothing -> -- Not there; it must be that the interface file wasn't found;
 524                    -- the error will have been reported already.
 525                    -- (Actually loadInterface should put the empty export env in there
 526                    --  anyway, but this does no harm.)
 527                    returnRn (mod, [])
 528
 529         Just (_, _, Just (mod, _, avails)) -> returnRn (mod, avails)
 530   where
 531     doc_str = sep [pprModuleName mod_name, ptext SLIT("is directly imported")]
 532 \end{code}
 533
 534
 535 %*********************************************************
 536 %*                                                      *
 537 \subsection{Instance declarations are handled specially}
 538 %*                                                      *
 539 %*********************************************************
 540
 541 \begin{code}
 542 getImportedInstDecls :: NameSet -> RnMG [(Module,RdrNameHsDecl)]
 543 getImportedInstDecls gates
 544   =     -- First, load any orphan-instance modules that aren't aready loaded
 545         -- Orphan-instance modules are recorded in the module dependecnies
 546     getIfacesRn                                         `thenRn` \ ifaces ->
 547     let
 548         orphan_mods =
 549           [mod | (mod, (_, True, Nothing)) <- fmToList (iImpModInfo ifaces)]
 550     in
 551     loadOrphanModules orphan_mods                       `thenRn_`
 552
 553         -- Now we're ready to grab the instance declarations
 554         -- Find the un-gated ones and return them,
 555         -- removing them from the bag kept in Ifaces
 556     getIfacesRn                                         `thenRn` \ ifaces ->
 557     let
 558         (decls, new_insts) = selectGated gates (iInsts ifaces)
 559     in
 560     setIfacesRn (ifaces { iInsts = new_insts })         `thenRn_`
 561
 562     traceRn (sep [text "getImportedInstDecls:",
 563                   nest 4 (fsep (map ppr gate_list)),
 564                   text "Slurped" <+> int (length decls) <+> text "instance declarations",
 565                   nest 4 (vcat (map ppr_brief_inst_decl decls))])       `thenRn_`
 566     returnRn decls
 567   where
 568     gate_list      = nameSetToList gates
 569
 570     load_home gate | isLocallyDefined gate
 571                    = returnRn ()
 572                    | otherwise
 573                    = loadHomeInterface (ppr gate <+> text "is an instance gate") gate   `thenRn_`
 574                      returnRn ()
 575
 576 ppr_brief_inst_decl (mod, InstD (InstDecl inst_ty _ _ _ _))
 577   = case inst_ty of
 578         HsForAllTy _ _ tau -> ppr tau
 579         other              -> ppr inst_ty
 580
 581 getImportedRules :: RnMG [(Module,RdrNameHsDecl)]
 582 getImportedRules
 583   | opt_IgnoreIfacePragmas = returnRn []
 584   | otherwise
 585   = getIfacesRn         `thenRn` \ ifaces ->
 586     let
 587         gates              = iSlurp ifaces      -- Anything at all that's been slurped
 588         (decls, new_rules) = selectGated gates (iRules ifaces)
 589     in
 590     setIfacesRn (ifaces { iRules = new_rules })         `thenRn_`
 591     traceRn (sep [text "getImportedRules:",
 592                   text "Slurped" <+> int (length decls) <+> text "rules"])      `thenRn_`
 593     returnRn decls
 594
 595 selectGated gates decl_bag
 596         -- Select only those decls whose gates are *all* in 'gates'
 597 #ifdef DEBUG
 598   | opt_NoPruneDecls    -- Just to try the effect of not gating at all
 599   = (foldrBag (\ (_,d) ds -> d:ds) [] decl_bag, emptyBag)       -- Grab them all
 600
 601   | otherwise
 602 #endif
 603   = foldrBag select ([], emptyBag) decl_bag
 604   where
 605     select (reqd, decl) (yes, no)
 606         | isEmptyNameSet (reqd `minusNameSet` gates) = (decl:yes, no)
 607         | otherwise                                  = (yes,      (reqd,decl) `consBag` no)
 608
 609 lookupFixity :: Name -> RnMS Fixity
 610 lookupFixity name
 611   | isLocallyDefined name
 612   = getFixityEnv                        `thenRn` \ local_fix_env ->
 613     case lookupNameEnv local_fix_env name of
 614         Just (FixitySig _ fix _) -> returnRn fix
 615         Nothing                  -> returnRn defaultFixity
 616
 617   | otherwise   -- Imported
 618   = loadHomeInterface doc name          `thenRn` \ ifaces ->
 619     case lookupNameEnv (iFixes ifaces) name of
 620         Just (FixitySig _ fix _) -> returnRn fix
 621         Nothing                  -> returnRn defaultFixity
 622   where
 623     doc = ptext SLIT("Checking fixity for") <+> ppr name
 624 \end{code}
 625
 626
 627 %*********************************************************
 628 %*                                                      *
 629 \subsection{Keeping track of what we've slurped, and version numbers}
 630 %*                                                      *
 631 %*********************************************************
 632
 633 getImportVersions figures out what the ``usage information'' for this
 634 moudule is; that is, what it must record in its interface file as the
 635 things it uses.  It records:
 636
 637 \begin{itemize}
 638 \item   anything reachable from its body code
 639 \item   any module exported with a @module Foo@.
 640 \end{itemize}
 641 %
 642 Why the latter?  Because if @Foo@ changes then this module's export list
 643 will change, so we must recompile this module at least as far as
 644 making a new interface file --- but in practice that means complete
 645 recompilation.
 646
 647 What about this?
 648 \begin{verbatim}
 649         module A( f, g ) where  |       module B( f ) where
 650           import B( f )         |         f = h 3
 651           g = ...               |         h = ...
 652 \end{verbatim}
 653
 654 Should we record @B.f@ in @A@'s usages?  In fact we don't.  Certainly,
 655 if anything about @B.f@ changes than anyone who imports @A@ should be
 656 recompiled; they'll get an early exit if they don't use @B.f@.
 657 However, even if @B.f@ doesn't change at all, @B.h@ may do so, and
 658 this change may not be reflected in @f@'s version number.  So there
 659 are two things going on when compiling module @A@:
 660
 661 \begin{enumerate}
 662 \item   Are @A.o@ and @A.hi@ correct?  Then we can bale out early.
 663 \item   Should modules that import @A@ be recompiled?
 664 \end{enumerate}
 665
 666 For (1) it is slightly harmful to record @B.f@ in @A@'s usages,
 667 because a change in @B.f@'s version will provoke full recompilation of
 668 @A@, producing an identical @A.o@, and @A.hi@ differing only in its
 669 usage-version of @B.f@ (and this usage-version info isn't used by any
 670 importer).
 671
 672 For (2), because of the tricky @B.h@ question above, we ensure that
 673 @A.hi@ is touched (even if identical to its previous version) if A's
 674 recompilation was triggered by an imported @.hi@ file date change.
 675 Given that, there's no need to record @B.f@ in @A@'s usages.
 676
 677 On the other hand, if @A@ exports @module B@, then we {\em do} count
 678 @module B@ among @A@'s usages, because we must recompile @A@ to ensure
 679 that @A.hi@ changes appropriately.
 680
 681 HOWEVER, we *do* record the usage
 682         import B <n> :: ;
 683 in A.hi, to record the fact that A does import B.  This is used to decide
 684 to look to look for B.hi rather than B.hi-boot when compiling a module that
 685 imports A.  This line says that A imports B, but uses nothing in it.
 686 So we'll get an early bale-out when compiling A if B's version changes.
 687
 688 \begin{code}
 689 getImportVersions :: ModuleName                 -- Name of this module
 690                   -> ExportEnv                  -- Info about exports
 691                   -> RnMG (VersionInfo Name)    -- Version info for these names
 692
 693 getImportVersions this_mod (ExportEnv export_avails _ export_all_mods)
 694   = getIfacesRn                                 `thenRn` \ ifaces ->
 695     let
 696         mod_map   = iImpModInfo ifaces
 697         imp_names = iVSlurp     ifaces
 698
 699         export_mods :: FiniteMap ModuleName ()          -- Set of home modules for
 700                                                         -- things in the export list
 701         export_mods = listToFM [(moduleName (nameModule (availName a)), ()) | a <- export_avails]
 702
 703         -- mv_map groups together all the things imported from a particular module.
 704         mv_map :: FiniteMap ModuleName [(Name,Version)]
 705         mv_map = foldr add_mv emptyFM imp_names
 706
 707         -- Build the result list by adding info for each module.
 708         -- For (a) a library module, we don't record it at all unless it contains orphans
 709         --         (We must never lose track of orphans.)
 710         --
 711         --     (b) a source-imported module, don't record the dependency at all
 712         --
 713         -- (b) may seem a bit strange.  The idea is that the usages in a .hi file records
 714         -- *all* the module's dependencies other than the loop-breakers.  We use
 715         -- this info in findAndReadInterface to decide whether to look for a .hi file or
 716         -- a .hi-boot file.
 717         --
 718         -- This means we won't track version changes, or orphans, from .hi-boot files.
 719         -- The former is potentially rather bad news.  It could be fixed by recording
 720         -- whether something is a boot file along with the usage info for it, but
 721         -- I can't be bothered just now.
 722
 723         mk_version_info mod_name (version, has_orphans, Nothing) so_far
 724            = ASSERT( not has_orphans )  -- If has_orphans is true we will have opened it
 725              so_far     -- We didn't even read this module's interface
 726                         -- so don't record dependency on it.
 727
 728         mk_version_info mod_name (version, has_orphans, Just (mod, boot_import, _)) so_far
 729            |  boot_import                       -- Don't record any usage info for this module
 730            || (is_lib_module && not has_orphans)
 731            = so_far
 732
 733            |  is_lib_module                     -- Record the module but not
 734            || mod_name `elem` export_all_mods   -- detailed version information for the imports
 735            = go_for_it Everything
 736
 737            |  otherwise
 738            = case lookupFM mv_map mod_name of
 739                 Just whats_imported
 740                   -> go_for_it (Specifically whats_imported)
 741
 742                 Nothing         -- This happens if you have
 743                                 --      import Foo
 744                                 -- but don't actually *use* anything from Foo
 745                   |  has_orphans                        -- Check for (a) orphans (we must never forget them)
 746                   || mod_name `elemFM` export_mods      -- or (b) something from the module is exported
 747                   ->    -- ...in which case record an empty dependency list
 748                      go_for_it (Specifically [])
 749
 750                   | otherwise   -> so_far       -- No point in recording any dependency
 751            where
 752              is_lib_module     = isLibModule mod
 753              go_for_it exports = (mod_name, version, has_orphans, exports) : so_far
 754
 755     in
 756         -- A module shouldn't load its own interface
 757         -- This seems like a convenient place to check
 758     WARN( maybeToBool (lookupFM mod_map this_mod),
 759           ptext SLIT("Wierd:") <+> ppr this_mod <+> ptext SLIT("loads its own interface") )
 760
 761     returnRn (foldFM mk_version_info [] mod_map)
 762   where
 763      add_mv v@(name, version) mv_map
 764       = addToFM_C add_item mv_map mod [v]
 765       where
 766          mod = moduleName (nameModule name)
 767          add_item vs _ = (v:vs)
 768 \end{code}
 769
 770 \begin{code}
 771 getSlurped
 772   = getIfacesRn         `thenRn` \ ifaces ->
 773     returnRn (iSlurp ifaces)
 774
 775 recordSlurp maybe_version avail
 776   = getIfacesRn         `thenRn` \ ifaces@(Ifaces { iSlurp  = slurped_names,
 777                                                     iVSlurp = imp_names }) ->
 778     let
 779         new_slurped_names = addAvailToNameSet slurped_names avail
 780
 781         new_imp_names = case maybe_version of
 782                            Just version -> (availName avail, version) : imp_names
 783                            Nothing      -> imp_names
 784     in
 785     setIfacesRn (ifaces { iSlurp  = new_slurped_names,
 786                           iVSlurp = new_imp_names })
 787 \end{code}
 788
 789
 790 %*********************************************************
 791 %*                                                      *
 792 \subsection{Getting binders out of a declaration}
 793 %*                                                      *
 794 %*********************************************************
 795
 796 @getDeclBinders@ returns the names for a @RdrNameHsDecl@.
 797 It's used for both source code (from @availsFromDecl@) and interface files
 798 (from @loadDecl@).
 799
 800 It doesn't deal with source-code specific things: @ValD@, @DefD@.  They
 801 are handled by the sourc-code specific stuff in @RnNames@.
 802
 803 \begin{code}
 804 getDeclBinders :: (RdrName -> SrcLoc -> RnM d Name)     -- New-name function
 805                 -> RdrNameHsDecl
 806                 -> RnM d (Maybe AvailInfo)
 807
 808 getDeclBinders new_name (TyClD (TyData _ _ tycon _ condecls _ _ src_loc))
 809   = new_name tycon src_loc                      `thenRn` \ tycon_name ->
 810     getConFieldNames new_name condecls          `thenRn` \ sub_names ->
 811     returnRn (Just (AvailTC tycon_name (tycon_name : nub sub_names)))
 812         -- The "nub" is because getConFieldNames can legitimately return duplicates,
 813         -- when a record declaration has the same field in multiple constructors
 814
 815 getDeclBinders new_name (TyClD (TySynonym tycon _ _ src_loc))
 816   = new_name tycon src_loc              `thenRn` \ tycon_name ->
 817     returnRn (Just (AvailTC tycon_name [tycon_name]))
 818
 819 getDeclBinders new_name (TyClD (ClassDecl _ cname _ _ sigs _ _ _ _ _ src_loc))
 820   = new_name cname src_loc                      `thenRn` \ class_name ->
 821
 822         -- Record the names for the class ops
 823     let
 824         -- just want class-op sigs
 825         op_sigs = filter isClassOpSig sigs
 826     in
 827     mapRn (getClassOpNames new_name) op_sigs    `thenRn` \ sub_names ->
 828
 829     returnRn (Just (AvailTC class_name (class_name : sub_names)))
 830
 831 getDeclBinders new_name (SigD (IfaceSig var ty prags src_loc))
 832   = new_name var src_loc                        `thenRn` \ var_name ->
 833     returnRn (Just (Avail var_name))
 834
 835 getDeclBinders new_name (FixD _)  = returnRn Nothing
 836
 837     -- foreign declarations
 838 getDeclBinders new_name (ForD (ForeignDecl nm kind _ dyn _ loc))
 839   | binds_haskell_name kind dyn
 840   = new_name nm loc                 `thenRn` \ name ->
 841     returnRn (Just (Avail name))
 842
 843   | otherwise -- a foreign export
 844   = lookupImplicitOccRn nm `thenRn_`
 845     returnRn Nothing
 846
 847 getDeclBinders new_name (DefD _)  = returnRn Nothing
 848 getDeclBinders new_name (InstD _) = returnRn Nothing
 849 getDeclBinders new_name (RuleD _) = returnRn Nothing
 850
 851 binds_haskell_name (FoImport _) _   = True
 852 binds_haskell_name FoLabel      _   = True
 853 binds_haskell_name FoExport  ext_nm = isDynamic ext_nm
 854
 855 ----------------
 856 getConFieldNames new_name (ConDecl con _ _ (RecCon fielddecls) src_loc : rest)
 857   = mapRn (\n -> new_name n src_loc) (con:fields)       `thenRn` \ cfs ->
 858     getConFieldNames new_name rest                      `thenRn` \ ns  ->
 859     returnRn (cfs ++ ns)
 860   where
 861     fields = concat (map fst fielddecls)
 862
 863 getConFieldNames new_name (ConDecl con _ _ condecl src_loc : rest)
 864   = new_name con src_loc                `thenRn` \ n ->
 865     (case condecl of
 866       NewCon _ (Just f) ->
 867         new_name f src_loc `thenRn` \ new_f ->
 868         returnRn [n,new_f]
 869       _ -> returnRn [n])                `thenRn` \ nn ->
 870     getConFieldNames new_name rest      `thenRn` \ ns ->
 871     returnRn (nn ++ ns)
 872
 873 getConFieldNames new_name [] = returnRn []
 874
 875 getClassOpNames new_name (ClassOpSig op _ _ _ src_loc) = new_name op src_loc
 876 \end{code}
 877
 878 @getDeclSysBinders@ gets the implicit binders introduced by a decl.
 879 A the moment that's just the tycon and datacon that come with a class decl.
 880 They aren't returned by @getDeclBinders@ because they aren't in scope;
 881 but they {\em should} be put into the @DeclsMap@ of this module.
 882
 883 Note that this excludes the default-method names of a class decl,
 884 and the dict fun of an instance decl, because both of these have
 885 bindings of their own elsewhere.
 886
 887 \begin{code}
 888 getDeclSysBinders new_name (TyClD (ClassDecl _ cname _ _ sigs _ _ tname dname snames src_loc))
 889   = new_name dname src_loc                              `thenRn` \ datacon_name ->
 890     new_name tname src_loc                              `thenRn` \ tycon_name ->
 891     sequenceRn [new_name n src_loc | n <- snames]       `thenRn` \ scsel_names ->
 892     returnRn (tycon_name : datacon_name : scsel_names)
 893
 894 getDeclSysBinders new_name other_decl
 895   = returnRn []
 896 \end{code}
 897
 898 %*********************************************************
 899 %*                                                      *
 900 \subsection{Reading an interface file}
 901 %*                                                      *
 902 %*********************************************************
 903
 904 \begin{code}
 905 findAndReadIface :: SDoc -> ModuleName -> WhereFrom
 906                  -> Bool        -- Only relevant for SystemImport
 907                                 -- True  <=> Look for a .hi file
 908                                 -- False <=> Look for .hi-boot file unless there's
 909                                 --           a library .hi file
 910                  -> RnM d (Bool, Maybe (Module, ParsedIface))
 911         -- Bool is True if the interface actually read was a .hi-boot one
 912         -- Nothing <=> file not found, or unreadable, or illegible
 913         -- Just x  <=> successfully found and parsed
 914
 915 findAndReadIface doc_str mod_name from hi_file
 916   = traceRn trace_msg                   `thenRn_`
 917       -- we keep two maps for interface files,
 918       -- one for 'normal' ones, the other for .hi-boot files,
 919       -- hence the need to signal which kind we're interested.
 920
 921     getHiMaps                   `thenRn` \ hi_maps ->
 922
 923     case find_path from hi_maps of
 924          -- Found the file
 925        (hi_boot, Just (fpath, mod)) -> traceRn (ptext SLIT("...reading from") <+> text fpath)
 926                                        `thenRn_`
 927                                        readIface mod fpath      `thenRn` \ result ->
 928                                        returnRn (hi_boot, result)
 929        (hi_boot, Nothing)           -> traceRn (ptext SLIT("...not found"))     `thenRn_`
 930                                        returnRn (hi_boot, Nothing)
 931   where
 932     find_path ImportByUser       (hi_map, _)     = (False, lookupFM hi_map mod_name)
 933     find_path ImportByUserSource (_, hiboot_map) = (True,  lookupFM hiboot_map mod_name)
 934
 935     find_path ImportBySystem     (hi_map, hiboot_map)
 936       | hi_file
 937       =         -- If the module we seek is in our dependent set,
 938                 -- Look for a .hi file
 939          (False, lookupFM hi_map mod_name)
 940
 941       | otherwise
 942                 -- Check if there's a library module of that name
 943                 -- If not, look for an hi-boot file
 944       = case lookupFM hi_map mod_name of
 945            stuff@(Just (_, mod)) | isLibModule mod -> (False, stuff)
 946            other                                   -> (True, lookupFM hiboot_map mod_name)
 947
 948     trace_msg = sep [hsep [ptext SLIT("Reading"),
 949                            ppr from,
 950                            ptext SLIT("interface for"),
 951                            pprModuleName mod_name <> semi],
 952                      nest 4 (ptext SLIT("reason:") <+> doc_str)]
 953 \end{code}
 954
 955 @readIface@ tries just the one file.
 956
 957 \begin{code}
 958 readIface :: Module -> String -> RnM d (Maybe (Module, ParsedIface))
 959         -- Nothing <=> file not found, or unreadable, or illegible
 960         -- Just x  <=> successfully found and parsed
 961 readIface the_mod file_path
 962   = ioToRnM (hGetStringBuffer False file_path)       `thenRn` \ read_result ->
 963     case read_result of
 964         Right contents    ->
 965              case parseIface contents
 966                         PState{ bol = 0#, atbol = 1#,
 967                                 context = [],
 968                                 glasgow_exts = 1#,
 969                                 loc = mkSrcLoc (mkFastString file_path) 1 } of
 970                   PFailed err                    -> failWithRn Nothing err
 971                   POk _  (PIface mod_nm iface) ->
 972                     warnCheckRn (mod_nm == moduleName the_mod)
 973                                 (hiModuleNameMismatchWarn the_mod mod_nm) `thenRn_`
 974                     returnRn (Just (the_mod, iface))
 975
 976         Left err
 977           | isDoesNotExistError err -> returnRn Nothing
 978           | otherwise               -> failWithRn Nothing (cannaeReadFile file_path err)
 979 \end{code}
 980
 981 %*********************************************************
 982 %*                                                       *
 983 \subsection{Errors}
 984 %*                                                       *
 985 %*********************************************************
 986
 987 \begin{code}
 988 noIfaceErr filename boot_file
 989   = hsep [ptext SLIT("Could not find valid"), boot,
 990           ptext SLIT("interface file"), quotes (pprModule filename)]
 991   where
 992     boot | boot_file = ptext SLIT("[boot]")
 993          | otherwise = empty
 994
 995 cannaeReadFile file err
 996   = hcat [ptext SLIT("Failed in reading file: "),
 997           text file,
 998           ptext SLIT("; error="),
 999           text (show err)]
1000
1001 getDeclErr name
1002   = ptext SLIT("Failed to find interface decl for") <+> quotes (ppr name)
1003
1004 getDeclWarn name loc
1005   = sep [ptext SLIT("Failed to find (optional) interface decl for") <+> quotes (ppr name),
1006          ptext SLIT("desired at") <+> ppr loc]
1007
1008 importDeclWarn name
1009   = sep [ptext SLIT(
1010     "Compiler tried to import decl from interface file with same name as module."),
1011          ptext SLIT(
1012     "(possible cause: module name clashes with interface file already in scope.)")
1013         ] $$
1014     hsep [ptext SLIT("name:"), quotes (ppr name)]
1015
1016 warnRedundantSourceImport mod_name
1017   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
1018           <+> quotes (pprModuleName mod_name)
1019
1020 hiModuleNameMismatchWarn :: Module -> ModuleName -> Message
1021 hiModuleNameMismatchWarn requested_mod mod_nm =
1022     hsep [ ptext SLIT("Something is amiss; requested module name")
1023          , pprModule requested_mod
1024          , ptext SLIT("differs from name found in the interface file ")
1025          , pprModuleName mod_nm
1026          ]
1027
1028 \end{code}