ghc/compiler/rename/RnIfaces.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnIfaces]{Cacheing and Renaming of Interfaces}
   5
   6 \begin{code}
   7 module RnIfaces
   8      (
   9         recordLocalSlurps,
  10         mkImportInfo,
  11
  12         slurpImpDecls, closeDecls,
  13
  14         RecompileRequired, outOfDate, upToDate, recompileRequired
  15        )
  16 where
  17
  18 #include "HsVersions.h"
  19
  20 import CmdLineOpts      ( opt_IgnoreIfacePragmas, opt_NoPruneDecls )
  21 import HscTypes
  22 import HsSyn            ( HsDecl(..), Sig(..), TyClDecl(..), ConDecl(..), ConDetails(..),
  23                           InstDecl(..), HsType(..), hsTyVarNames, getBangType
  24                         )
  25 import HsImpExp         ( ImportDecl(..) )
  26 import RdrHsSyn         ( RdrNameTyClDecl, RdrNameInstDecl, RdrNameRuleDecl )
  27 import RnHsSyn          ( RenamedHsDecl, RenamedTyClDecl,
  28                           extractHsTyNames, extractHsCtxtTyNames,
  29                           tyClDeclFVs, ruleDeclFVs, instDeclFVs
  30                         )
  31 import RnHiFiles        ( tryLoadInterface, loadHomeInterface,
  32                           loadOrphanModules
  33                         )
  34 import RnSource         ( rnTyClDecl, rnInstDecl, rnIfaceRuleDecl )
  35 import RnEnv
  36 import RnMonad
  37 import Id               ( idType, idName, globalIdDetails )
  38 import IdInfo           ( GlobalIdDetails(..) )
  39 import TcType           ( namesOfType )
  40 import FieldLabel       ( fieldLabelTyCon )
  41 import DataCon          ( dataConTyCon )
  42 import TyCon            ( isSynTyCon, getSynTyConDefn, tyConClass_maybe, tyConName )
  43 import Class            ( className )
  44 import Name             ( Name {-instance NamedThing-}, nameOccName,
  45                           nameModule, isLocalName, NamedThing(..)
  46                          )
  47 import NameEnv          ( elemNameEnv, delFromNameEnv, lookupNameEnv )
  48 import NameSet
  49 import Module           ( Module, ModuleEnv,
  50                           moduleName, isHomeModule,
  51                           ModuleName, WhereFrom(..),
  52                           emptyModuleEnv,
  53                           extendModuleEnv_C, foldModuleEnv, lookupModuleEnv,
  54                           elemModuleSet, extendModuleSet
  55                         )
  56 import PrelInfo         ( wiredInThingEnv, hasKey, fractionalClassKey, numClassKey,
  57                           integerTyConName, doubleTyConName )
  58 import Maybes           ( maybeToBool )
  59 import FiniteMap
  60 import Outputable
  61 import Bag
  62 import Util             ( sortLt )
  63 \end{code}
  64
  65
  66 %*********************************************************
  67 %*                                                      *
  68 \subsection{Keeping track of what we've slurped, and version numbers}
  69 %*                                                      *
  70 %*********************************************************
  71
  72 mkImportInfo figures out what the ``usage information'' for this
  73 moudule is; that is, what it must record in its interface file as the
  74 things it uses.
  75
  76 We produce a line for every module B below the module, A, currently being
  77 compiled:
  78         import B <n> ;
  79 to record the fact that A does import B indirectly.  This is used to decide
  80 to look to look for B.hi rather than B.hi-boot when compiling a module that
  81 imports A.  This line says that A imports B, but uses nothing in it.
  82 So we'll get an early bale-out when compiling A if B's version changes.
  83
  84 The usage information records:
  85
  86 \begin{itemize}
  87 \item   (a) anything reachable from its body code
  88 \item   (b) any module exported with a @module Foo@
  89 \item   (c) anything reachable from an exported item
  90 \end{itemize}
  91
  92 Why (b)?  Because if @Foo@ changes then this module's export list
  93 will change, so we must recompile this module at least as far as
  94 making a new interface file --- but in practice that means complete
  95 recompilation.
  96
  97 Why (c)?  Consider this:
  98 \begin{verbatim}
  99         module A( f, g ) where  |       module B( f ) where
 100           import B( f )         |         f = h 3
 101           g = ...               |         h = ...
 102 \end{verbatim}
 103
 104 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
 105 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
 106 *identical* to what it was before.  If anything about @B.f@ changes
 107 than anyone who imports @A@ should be recompiled in case they use
 108 @B.f@ (they'll get an early exit if they don't).  So, if anything
 109 about @B.f@ changes we'd better make sure that something in A.hi
 110 changes, and the convenient way to do that is to record the version
 111 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
 112 complete recompiation of A, which is overkill but it's the only way to
 113 write a new, slightly different, A.hi.
 114
 115 But the example is tricker.  Even if @B.f@ doesn't change at all,
 116 @B.h@ may do so, and this change may not be reflected in @f@'s version
 117 number.  But with -O, a module that imports A must be recompiled if
 118 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
 119 the occurrence of @B.f@ in the export list *just as if* it were in the
 120 code of A, and thereby haul in all the stuff reachable from it.
 121
 122         *** Conclusion: if A mentions B.f in its export list,
 123             behave just as if A mentioned B.f in its source code,
 124             and slurp in B.f and all its transitive closure ***
 125
 126 [NB: If B was compiled with -O, but A isn't, we should really *still*
 127 haul in all the unfoldings for B, in case the module that imports A *is*
 128 compiled with -O.  I think this is the case.]
 129
 130 \begin{code}
 131 mkImportInfo :: ModuleName                      -- Name of this module
 132              -> [ImportDecl n]                  -- The import decls
 133              -> RnMG [ImportVersion Name]
 134
 135 mkImportInfo this_mod imports
 136   = getIfacesRn                                 `thenRn` \ ifaces ->
 137     getHomeIfaceTableRn                         `thenRn` \ hit ->
 138     let
 139         (imp_pkg_mods, imp_home_names) = iVSlurp ifaces
 140         pit                            = iPIT    ifaces
 141
 142         import_all_mods :: [ModuleName]
 143                 -- Modules where we imported all the names
 144                 -- (apart from hiding some, perhaps)
 145         import_all_mods = [ m | ImportDecl m _ _ _ imp_list _ <- imports,
 146                                 import_all imp_list ]
 147           where
 148            import_all (Just (False, _)) = False -- Imports are spec'd explicitly
 149            import_all other             = True  -- Everything is imported
 150
 151         -- mv_map groups together all the things imported and used
 152         -- from a particular module in this package
 153         -- We use a finite map because we want the domain
 154         mv_map :: ModuleEnv [Name]
 155         mv_map  = foldNameSet add_mv emptyModuleEnv imp_home_names
 156         add_mv name mv_map = extendModuleEnv_C add_item mv_map mod [name]
 157                            where
 158                              mod = nameModule name
 159                              add_item names _ = name:names
 160
 161         -- In our usage list we record
 162         --
 163         --      a) Specifically: Detailed version info for imports
 164         --         from modules in this package Gotten from iVSlurp plus
 165         --         import_all_mods
 166         --
 167         --      b) Everything: Just the module version for imports
 168         --         from modules in other packages Gotten from iVSlurp plus
 169         --         import_all_mods
 170         --
 171         --      c) NothingAtAll: The name only of modules, Baz, in
 172         --         this package that are 'below' us, but which we didn't need
 173         --         at all (this is needed only to decide whether to open Baz.hi
 174         --         or Baz.hi-boot higher up the tree).  This happens when a
 175         --         module, Foo, that we explicitly imported has 'import Baz' in
 176         --         its interface file, recording that Baz is below Foo in the
 177         --         module dependency hierarchy.  We want to propagate this
 178         --         info.  These modules are in a combination of HIT/PIT and
 179         --         iImpModInfo
 180         --
 181         --      d) NothingAtAll: The name only of all orphan modules
 182         --         we know of (this is needed so that anyone who imports us can
 183         --         find the orphan modules) These modules are in a combination
 184         --         of HIT/PIT and iImpModInfo
 185
 186         import_info0 = foldModuleEnv mk_imp_info  []           pit
 187         import_info1 = foldModuleEnv mk_imp_info  import_info0 hit
 188         import_info  = not_even_opened_imports ++ import_info1
 189
 190                 -- Recall that iImpModInfo describes modules that have
 191                 -- been mentioned in the import lists of interfaces we
 192                 -- have opened, but which we have not even opened when
 193                 -- compiling this module
 194         not_even_opened_imports =
 195           [ (mod_name, orphans, is_boot, NothingAtAll)
 196           | (mod_name, (orphans, is_boot)) <- fmToList (iImpModInfo ifaces) ]
 197
 198
 199         mk_imp_info :: ModIface -> [ImportVersion Name] -> [ImportVersion Name]
 200         mk_imp_info iface so_far
 201
 202           | Just ns <- lookupModuleEnv mv_map mod       -- Case (a)
 203           = go_for_it (Specifically mod_vers maybe_export_vers
 204                                     (mk_import_items ns) rules_vers)
 205
 206           | mod `elemModuleSet` imp_pkg_mods            -- Case (b)
 207           = go_for_it (Everything mod_vers)
 208
 209           | import_all_mod                              -- Case (a) and (b); the import-all part
 210           = if is_home_pkg_mod then
 211                 go_for_it (Specifically mod_vers (Just export_vers) [] rules_vers)
 212                 -- Since the module isn't in the mv_map, presumably we
 213                 -- didn't actually import anything at all from it
 214             else
 215                 go_for_it (Everything mod_vers)
 216
 217           | is_home_pkg_mod || has_orphans              -- Case (c) or (d)
 218           = go_for_it NothingAtAll
 219
 220           | otherwise = so_far
 221           where
 222             go_for_it exports = (mod_name, has_orphans, mi_boot iface, exports) : so_far
 223
 224             mod             = mi_module iface
 225             mod_name        = moduleName mod
 226             is_home_pkg_mod = isHomeModule mod
 227             version_info    = mi_version iface
 228             version_env     = vers_decls   version_info
 229             mod_vers        = vers_module  version_info
 230             rules_vers      = vers_rules   version_info
 231             export_vers     = vers_exports version_info
 232             import_all_mod  = mod_name `elem` import_all_mods
 233             has_orphans     = mi_orphan iface
 234
 235                 -- The sort is to put them into canonical order
 236             mk_import_items ns = [(n,v) | n <- sortLt lt_occ ns,
 237                                           let v = lookupVersion version_env n
 238                                  ]
 239                          where
 240                            lt_occ n1 n2 = nameOccName n1 < nameOccName n2
 241
 242             maybe_export_vers | import_all_mod = Just (vers_exports version_info)
 243                               | otherwise      = Nothing
 244     in
 245     returnRn import_info
 246 \end{code}
 247
 248 %*********************************************************
 249 %*                                                       *
 250 \subsection{Slurping declarations}
 251 %*                                                       *
 252 %*********************************************************
 253
 254 \begin{code}
 255 -------------------------------------------------------
 256 slurpImpDecls source_fvs
 257   = traceRn (text "slurpImp" <+> fsep (map ppr (nameSetToList source_fvs))) `thenRn_`
 258
 259         -- The current slurped-set records all local things
 260     slurpSourceRefs source_fvs  `thenRn` \ (decls, needed) ->
 261
 262         -- Then get everything else
 263     closeDecls decls needed
 264
 265
 266 -------------------------------------------------------
 267 slurpSourceRefs :: FreeVars                     -- Variables referenced in source
 268                 -> RnMG ([RenamedHsDecl],
 269                          FreeVars)              -- Un-satisfied needs
 270 -- The declaration (and hence home module) of each gate has
 271 -- already been loaded
 272
 273 slurpSourceRefs source_fvs
 274   = go_outer []                         -- Accumulating decls
 275              emptyFVs                   -- Unsatisfied needs
 276              emptyFVs                   -- Accumulating gates
 277              (nameSetToList source_fvs) -- Things whose defn hasn't been loaded yet
 278   where
 279         -- The outer loop repeatedly slurps the decls for the current gates
 280         -- and the instance decls
 281
 282         -- The outer loop is needed because consider
 283         --      instance Foo a => Baz (Maybe a) where ...
 284         -- It may be that Baz and Maybe are used in the source module,
 285         -- but not Foo; so we need to chase Foo too.
 286         --
 287         -- We also need to follow superclass refs.  In particular, 'chasing Foo' must
 288         -- include actually getting in Foo's class decl
 289         --      class Wib a => Foo a where ..
 290         -- so that its superclasses are discovered.  The point is that Wib is a gate too.
 291         -- We do this for tycons too, so that we look through type synonyms.
 292
 293     go_outer decls fvs all_gates []
 294         = returnRn (decls, fvs)
 295
 296     go_outer decls fvs all_gates refs   -- refs are not necessarily slurped yet
 297         = traceRn (text "go_outer" <+> ppr refs)                `thenRn_`
 298           foldlRn go_inner (decls, fvs, emptyFVs) refs          `thenRn` \ (decls1, fvs1, gates1) ->
 299           getImportedInstDecls (all_gates `plusFV` gates1)      `thenRn` \ inst_decls ->
 300           rnIfaceInstDecls decls1 fvs1 gates1 inst_decls        `thenRn` \ (decls2, fvs2, gates2) ->
 301           go_outer decls2 fvs2 (all_gates `plusFV` gates2)
 302                                (nameSetToList (gates2 `minusNameSet` all_gates))
 303                 -- Knock out the all_gates because even if we don't slurp any new
 304                 -- decls we can get some apparently-new gates from wired-in names
 305                 -- and we get an infinite loop
 306
 307     go_inner (decls, fvs, gates) wanted_name
 308         = importDecl wanted_name                `thenRn` \ import_result ->
 309           case import_result of
 310             AlreadySlurped     -> returnRn (decls, fvs, gates)
 311             InTypeEnv ty_thing -> returnRn (decls, fvs, gates `plusFV` getWiredInGates ty_thing)
 312
 313             HereItIs decl -> rnIfaceTyClDecl decl               `thenRn` \ (new_decl, fvs1) ->
 314                              returnRn (TyClD new_decl : decls,
 315                                        fvs1 `plusFV` fvs,
 316                                        gates `plusFV` getGates source_fvs new_decl)
 317 \end{code}
 318
 319
 320 \begin{code}
 321 -------------------------------------------------------
 322 -- closeDecls keeps going until the free-var set is empty
 323 closeDecls decls needed
 324   | not (isEmptyFVs needed)
 325   = slurpDecls decls needed     `thenRn` \ (decls1, needed1) ->
 326     closeDecls decls1 needed1
 327
 328   | otherwise
 329   = getImportedRules                    `thenRn` \ rule_decls ->
 330     case rule_decls of
 331         []    -> returnRn decls -- No new rules, so we are done
 332         other -> rnIfaceDecls rnIfaceRuleDecl rule_decls        `thenRn` \ rule_decls' ->
 333                  let
 334                         rule_fvs = plusFVs (map ruleDeclFVs rule_decls')
 335                  in
 336                  traceRn (text "closeRules" <+> ppr rule_decls' $$ fsep (map ppr (nameSetToList rule_fvs)))     `thenRn_`
 337                  closeDecls (map RuleD rule_decls' ++ decls) rule_fvs
 338
 339
 340
 341 -------------------------------------------------------
 342 -- Augment decls with any decls needed by needed.
 343 -- Return also free vars of the new decls (only)
 344 slurpDecls decls needed
 345   = go decls emptyFVs (nameSetToList needed)
 346   where
 347     go decls fvs []         = returnRn (decls, fvs)
 348     go decls fvs (ref:refs) = slurpDecl decls fvs ref   `thenRn` \ (decls1, fvs1) ->
 349                               go decls1 fvs1 refs
 350
 351 -------------------------------------------------------
 352 slurpDecl decls fvs wanted_name
 353   = importDecl wanted_name              `thenRn` \ import_result ->
 354     case import_result of
 355         -- Found a declaration... rename it
 356         HereItIs decl -> rnIfaceTyClDecl decl           `thenRn` \ (new_decl, fvs1) ->
 357                          returnRn (TyClD new_decl:decls, fvs1 `plusFV` fvs)
 358
 359         -- No declaration... (wired in thing, or deferred, or already slurped)
 360         other -> returnRn (decls, fvs)
 361
 362
 363 -------------------------------------------------------
 364 rnIfaceDecls rn decls      = mapRn (rnIfaceDecl rn) decls
 365 rnIfaceDecl rn (mod, decl) = initIfaceRnMS mod (rn decl)
 366
 367 rnIfaceInstDecls decls fvs gates inst_decls
 368   = rnIfaceDecls rnInstDecl inst_decls  `thenRn` \ inst_decls' ->
 369     returnRn (map InstD inst_decls' ++ decls,
 370               fvs `plusFV` plusFVs (map instDeclFVs inst_decls'),
 371               gates `plusFV` plusFVs (map getInstDeclGates inst_decls'))
 372
 373 rnIfaceTyClDecl (mod, decl) = initIfaceRnMS mod (rnTyClDecl decl)       `thenRn` \ decl' ->
 374                               returnRn (decl', tyClDeclFVs decl')
 375 \end{code}
 376
 377
 378 \begin{code}
 379 recordDeclSlurp ifaces@(Ifaces { iDecls  = (decls_map, n_slurped),
 380                                  iSlurp  = slurped_names,
 381                                  iVSlurp = vslurp })
 382             avail
 383   = ASSERT2( not (isLocalName (availName avail)), ppr avail )
 384     ifaces { iDecls = (new_decls_map, n_slurped+1),
 385              iSlurp  = new_slurped_names,
 386              iVSlurp = updateVSlurp vslurp (availName avail) }
 387   where
 388     new_decls_map     = foldl delFromNameEnv decls_map (availNames avail)
 389     new_slurped_names = addAvailToNameSet slurped_names avail
 390
 391
 392 -- recordTypeEnvSlurp is used when we slurp something that's
 393 -- already in the type environment, that was not slurped in an earlier compilation.
 394 -- We record it in the iVSlurp set, because that's used to
 395 -- generate usage information
 396
 397 recordTypeEnvSlurp ifaces ty_thing
 398   = ifaces { iVSlurp = updateVSlurp (iVSlurp ifaces) (get_main_name ty_thing) }
 399   where
 400         -- Tiresomely, we must get the "main" name for the
 401         -- thing, because that's what VSlurp contains, and what
 402         -- is recorded in the usage information
 403     get_main_name (AClass cl) = className cl
 404     get_main_name (ATyCon tc)
 405         | Just clas <- tyConClass_maybe tc = get_main_name (AClass clas)
 406         | otherwise                        = tyConName tc
 407     get_main_name (AnId id)
 408         = case globalIdDetails id of
 409             DataConId     dc -> get_main_name (ATyCon (dataConTyCon dc))
 410             DataConWrapId dc -> get_main_name (ATyCon (dataConTyCon dc))
 411             RecordSelId lbl  -> get_main_name (ATyCon (fieldLabelTyCon lbl))
 412             other            -> idName id
 413
 414 updateVSlurp (imp_mods, imp_names) main_name
 415   | isHomeModule mod = (imp_mods,                     addOneToNameSet imp_names main_name)
 416   | otherwise        = (extendModuleSet imp_mods mod, imp_names)
 417   where
 418     mod = nameModule main_name
 419
 420 recordLocalSlurps new_names
 421   = getIfacesRn         `thenRn` \ ifaces ->
 422     setIfacesRn (ifaces { iSlurp  = iSlurp ifaces `unionNameSets` new_names })
 423 \end{code}
 424
 425
 426
 427 %*********************************************************
 428 %*                                                       *
 429 \subsection{Extracting the `gates'}
 430 %*                                                       *
 431 %*********************************************************
 432
 433 The gating story
 434 ~~~~~~~~~~~~~~~~~
 435 We want to avoid sucking in too many instance declarations.
 436 An instance decl is only useful if the types and classes mentioned in
 437 its 'head' are all available in the program being compiled.  E.g.
 438
 439         instance (..) => C (T1 a) (T2 b) where ...
 440
 441 is only useful if C, T1 and T2 are all "available".  So we keep
 442 instance decls that have been parsed from .hi files, but not yet
 443 slurped in, in a pool called the 'gated instance pool'.
 444 Each has its set of 'gates': {C, T1, T2} in the above example.
 445
 446 More precisely, the gates of a module are the types and classes
 447 that are mentioned in:
 448
 449         a) the source code
 450         b) the type of an Id that's mentioned in the source code
 451            [includes constructors and selectors]
 452         c) the RHS of a type synonym that is a gate
 453         d) the superclasses of a class that is a gate
 454         e) the context of an instance decl that is slurped in
 455
 456 We slurp in an instance decl from the gated instance pool iff
 457
 458         all its gates are either in the gates of the module,
 459         or are a previously-loaded class.
 460
 461 The latter constraint is because there might have been an instance
 462 decl slurped in during an earlier compilation, like this:
 463
 464         instance Foo a => Baz (Maybe a) where ...
 465
 466 In the module being compiled we might need (Baz (Maybe T)), where T
 467 is defined in this module, and hence we need (Foo T).  So @Foo@ becomes
 468 a gate.  But there's no way to 'see' that, so
 469
 470         we simply treat all previously-loaded classes as gates.
 471
 472 Consructors and class operations
 473 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 474 When we import a declaration like
 475
 476         data T = T1 Wibble | T2 Wobble
 477
 478 we don't want to treat @Wibble@ and @Wobble@ as gates {\em unless}
 479 @T1@, @T2@ respectively are mentioned by the user program. If only
 480 @T@ is mentioned we want only @T@ to be a gate; that way we don't suck
 481 in useless instance decls for (say) @Eq Wibble@, when they can't
 482 possibly be useful.
 483
 484 And that's just what (b) says: we only treat T1's type as a gate if
 485 T1 is mentioned.  getGates, which deals with decls we are slurping in,
 486 has to be a bit careful, because a mention of T1 will slurp in T's whole
 487 declaration.
 488
 489 -----------------------------
 490 @getGates@ takes a newly imported (and renamed) decl, and the free
 491 vars of the source program, and extracts from the decl the gate names.
 492
 493 \begin{code}
 494 getGates :: FreeVars            -- Things mentioned in the source program
 495                                 -- Used for the cunning "constructors and
 496                                 -- class ops" story described 10 lines above.
 497          -> RenamedTyClDecl
 498          -> FreeVars
 499
 500 getGates source_fvs decl
 501   = get_gates (\n -> n `elemNameSet` source_fvs) decl
 502
 503 get_gates is_used (ForeignType {tcdName = tycon}) = unitNameSet tycon
 504 get_gates is_used (IfaceSig    {tcdType = ty})    = extractHsTyNames ty
 505
 506 get_gates is_used (ClassDecl { tcdCtxt = ctxt, tcdName = cls, tcdTyVars = tvs, tcdSigs = sigs})
 507   = (super_cls_and_sigs `addOneToNameSet` cls) `unionNameSets`
 508     implicitClassGates cls
 509   where
 510     super_cls_and_sigs = delListFromNameSet (foldr (plusFV . get) (extractHsCtxtTyNames ctxt) sigs)
 511                                             (hsTyVarNames tvs)
 512     get (ClassOpSig n _ ty _)
 513         | is_used n = extractHsTyNames ty
 514         | otherwise = emptyFVs
 515
 516 get_gates is_used (TySynonym {tcdTyVars = tvs, tcdSynRhs = ty})
 517   = delListFromNameSet (extractHsTyNames ty) (hsTyVarNames tvs)
 518         -- A type synonym type constructor isn't a "gate" for instance decls
 519
 520 get_gates is_used (TyData {tcdCtxt = ctxt, tcdName = tycon, tcdTyVars = tvs, tcdCons = cons})
 521   = delListFromNameSet (foldr (plusFV . get) (extractHsCtxtTyNames ctxt) cons)
 522                        (hsTyVarNames tvs)
 523     `addOneToNameSet` tycon
 524   where
 525     get (ConDecl n _ tvs ctxt details _)
 526         | is_used n
 527                 -- If the constructor is method, get fvs from all its fields
 528         = delListFromNameSet (get_details details `plusFV`
 529                               extractHsCtxtTyNames ctxt)
 530                              (hsTyVarNames tvs)
 531     get (ConDecl n _ tvs ctxt (RecCon fields) _)
 532                 -- Even if the constructor isn't mentioned, the fields
 533                 -- might be, as selectors.  They can't mention existentially
 534                 -- bound tyvars (typechecker checks for that) so no need for
 535                 -- the deleteListFromNameSet part
 536         = foldr (plusFV . get_field) emptyFVs fields
 537
 538     get other_con = emptyFVs
 539
 540     get_details (VanillaCon tys) = plusFVs (map get_bang tys)
 541     get_details (InfixCon t1 t2) = get_bang t1 `plusFV` get_bang t2
 542     get_details (RecCon fields)  = plusFVs [get_bang t | (_, t) <- fields]
 543
 544     get_field (fs,t) | any is_used fs = get_bang t
 545                      | otherwise      = emptyFVs
 546
 547     get_bang bty = extractHsTyNames (getBangType bty)
 548
 549 implicitClassGates :: Name -> FreeVars
 550 implicitClassGates cls
 551         -- If we load class Num, add Integer to the free gates
 552         -- This takes account of the fact that Integer might be needed for
 553         -- defaulting, but we don't want to load Integer (and all its baggage)
 554         -- if there's no numeric stuff needed.
 555         -- Similarly for class Fractional and Double
 556         --
 557         -- NB: adding T to the gates will force T to be loaded
 558         --
 559         -- NB: If we load (say) Floating, we'll end up loading Fractional too,
 560         --     since Fractional is a superclass of Floating
 561   | cls `hasKey` numClassKey        = unitFV integerTyConName
 562   | cls `hasKey` fractionalClassKey = unitFV doubleTyConName
 563   | otherwise                       = emptyFVs
 564 \end{code}
 565
 566 @getWiredInGates@ is just like @getGates@, but it sees a previously-loaded
 567 thing rather than a declaration.
 568
 569 \begin{code}
 570 getWiredInGates :: TyThing -> FreeVars
 571 -- The TyThing is one that we already have in our type environment, either
 572 --      a) because the TyCon or Id is wired in, or
 573 --      b) from a previous compile
 574 -- Either way, we might have instance decls in the (persistent) collection
 575 -- of parsed-but-not-slurped instance decls that should be slurped in.
 576 -- This might be the first module that mentions both the type and the class
 577 -- for that instance decl, even though both the type and the class were
 578 -- mentioned in other modules, and hence are in the type environment
 579
 580 getWiredInGates (AnId the_id) = namesOfType (idType the_id)
 581 getWiredInGates (AClass cl)   = implicitClassGates (getName cl)
 582         -- The superclasses must also be previously
 583         -- loaded, and hence are automatically gates
 584         -- All previously-loaded classes are automatically gates
 585         -- See "The gating story" above
 586 getWiredInGates (ATyCon tc)
 587   | isSynTyCon tc = delListFromNameSet (namesOfType ty) (map getName tyvars)
 588   | otherwise     = unitFV (getName tc)
 589   where
 590     (tyvars,ty)  = getSynTyConDefn tc
 591
 592 getInstDeclGates (InstDecl inst_ty _ _ _ _) = extractHsTyNames inst_ty
 593 \end{code}
 594
 595 \begin{code}
 596 getImportedInstDecls :: NameSet -> RnMG [(Module,RdrNameInstDecl)]
 597 getImportedInstDecls gates
 598   =     -- First, load any orphan-instance modules that aren't aready loaded
 599         -- Orphan-instance modules are recorded in the module dependecnies
 600     getIfacesRn                                         `thenRn` \ ifaces ->
 601     let
 602         orphan_mods =
 603           [mod | (mod, (True, _)) <- fmToList (iImpModInfo ifaces)]
 604     in
 605     loadOrphanModules orphan_mods                       `thenRn_`
 606
 607         -- Now we're ready to grab the instance declarations
 608         -- Find the un-gated ones and return them,
 609         -- removing them from the bag kept in Ifaces
 610     getIfacesRn                                         `thenRn` \ ifaces ->
 611     getTypeEnvRn                                        `thenRn` \ lookup ->
 612     let
 613         available n
 614           | n `elemNameSet` gates = True
 615           | otherwise             = case lookup n of { Just (AClass c) -> True; other -> False }
 616                 -- See "The gating story" above for the AClass thing
 617
 618         (decls, new_insts) = selectGated available (iInsts ifaces)
 619     in
 620     setIfacesRn (ifaces { iInsts = new_insts })         `thenRn_`
 621
 622     traceRn (sep [text "getImportedInstDecls:",
 623                   nest 4 (fsep (map ppr gate_list)),
 624                   text "Slurped" <+> int (length decls) <+> text "instance declarations",
 625                   nest 4 (vcat (map ppr_brief_inst_decl decls))])       `thenRn_`
 626     returnRn decls
 627   where
 628     gate_list      = nameSetToList gates
 629
 630 ppr_brief_inst_decl (mod, InstDecl inst_ty _ _ _ _)
 631   = case inst_ty of
 632         HsForAllTy _ _ tau -> ppr tau
 633         other              -> ppr inst_ty
 634
 635 getImportedRules :: RnMG [(Module,RdrNameRuleDecl)]
 636 getImportedRules
 637   | opt_IgnoreIfacePragmas = returnRn []
 638   | otherwise
 639   = getIfacesRn         `thenRn` \ ifaces ->
 640     getTypeEnvRn        `thenRn` \ lookup ->
 641     let
 642                 -- Slurp rules for anything that is slurped,
 643                 -- either now or previously
 644         gates              = iSlurp ifaces
 645         available n        = n `elemNameSet` gates || maybeToBool (lookup n)
 646         (decls, new_rules) = selectGated available (iRules ifaces)
 647     in
 648     if null decls then
 649         returnRn []
 650     else
 651     setIfacesRn (ifaces { iRules = new_rules })              `thenRn_`
 652     traceRn (sep [text "getImportedRules:",
 653                   text "Slurped" <+> int (length decls) <+> text "rules"])   `thenRn_`
 654     returnRn decls
 655
 656 selectGated :: (Name->Bool) -> GatedDecls d
 657             -> ([(Module,d)], GatedDecls d)
 658 selectGated available (decl_bag, n_slurped)
 659         -- Select only those decls whose gates are *all* available
 660 #ifdef DEBUG
 661   | opt_NoPruneDecls    -- Just to try the effect of not gating at all
 662   = let
 663         decls = foldrBag (\ (_,d) ds -> d:ds) [] decl_bag       -- Grab them all
 664     in
 665     (decls, (emptyBag, n_slurped + length decls))
 666
 667   | otherwise
 668 #endif
 669   = case foldrBag select ([], emptyBag) decl_bag of
 670         (decls, new_bag) -> (decls, (new_bag, n_slurped + length decls))
 671   where
 672     select (gate_fn, decl) (yes, no)
 673         | gate_fn available  = (decl:yes, no)
 674         | otherwise          = (yes,      (gate_fn,decl) `consBag` no)
 675 \end{code}
 676
 677
 678 %*********************************************************
 679 %*                                                      *
 680 \subsection{Getting in a declaration}
 681 %*                                                      *
 682 %*********************************************************
 683
 684 \begin{code}
 685 importDecl :: Name -> RnMG ImportDeclResult
 686
 687 data ImportDeclResult
 688   = AlreadySlurped
 689   | InTypeEnv TyThing
 690   | HereItIs (Module, RdrNameTyClDecl)
 691
 692 importDecl name
 693   =     -- STEP 1: Check if we've slurped it in while compiling this module
 694     getIfacesRn                         `thenRn` \ ifaces ->
 695     if name `elemNameSet` iSlurp ifaces then
 696         returnRn AlreadySlurped
 697     else
 698
 699
 700         -- STEP 2: Check if it's already in the type environment
 701     getTypeEnvRn                        `thenRn` \ lookup ->
 702     case lookup name of {
 703         Just ty_thing
 704             |   name `elemNameEnv` wiredInThingEnv
 705             ->  -- When we find a wired-in name we must load its home
 706                 -- module so that we find any instance decls lurking therein
 707                 loadHomeInterface wi_doc name   `thenRn_`
 708                 returnRn (InTypeEnv ty_thing)
 709
 710             |   otherwise
 711             ->  -- Very important: record that we've seen it
 712                 -- See comments with recordTypeEnvSlurp
 713                 setIfacesRn (recordTypeEnvSlurp ifaces ty_thing)        `thenRn_`
 714                 returnRn (InTypeEnv ty_thing) ;
 715
 716         Nothing ->
 717
 718         -- STEP 3: OK, we have to slurp it in from an interface file
 719         --         First load the interface file
 720     traceRn nd_doc                      `thenRn_`
 721     loadHomeInterface nd_doc name       `thenRn_`
 722     getIfacesRn                         `thenRn` \ ifaces ->
 723
 724         -- STEP 4: Get the declaration out
 725     let
 726         (decls_map, _) = iDecls ifaces
 727     in
 728     case lookupNameEnv decls_map name of
 729       Just (avail,_,decl) -> setIfacesRn (recordDeclSlurp ifaces avail) `thenRn_`
 730                              returnRn (HereItIs decl)
 731
 732       Nothing -> addErrRn (getDeclErr name)     `thenRn_`
 733                  returnRn AlreadySlurped
 734     }
 735   where
 736     wi_doc = ptext SLIT("need home module for wired in thing") <+> ppr name
 737     nd_doc = ptext SLIT("need decl for") <+> ppr name
 738
 739 \end{code}
 740
 741
 742 %********************************************************
 743 %*                                                      *
 744 \subsection{Checking usage information}
 745 %*                                                      *
 746 %********************************************************
 747
 748 @recompileRequired@ is called from the HscMain.   It checks whether
 749 a recompilation is required.  It needs access to the persistent state,
 750 finder, etc, because it may have to load lots of interface files to
 751 check their versions.
 752
 753 \begin{code}
 754 type RecompileRequired = Bool
 755 upToDate  = False       -- Recompile not required
 756 outOfDate = True        -- Recompile required
 757
 758 recompileRequired :: FilePath           -- Only needed for debug msgs
 759                   -> ModIface           -- Old interface
 760                   -> RnMG RecompileRequired
 761 recompileRequired iface_path iface
 762   = traceHiDiffsRn (text "Considering whether compilation is required for" <+> text iface_path <> colon)        `thenRn_`
 763
 764         -- Source code unchanged and no errors yet... carry on
 765     checkList [checkModUsage u | u <- mi_usages iface]
 766
 767 checkList :: [RnMG RecompileRequired] -> RnMG RecompileRequired
 768 checkList []             = returnRn upToDate
 769 checkList (check:checks) = check        `thenRn` \ recompile ->
 770                            if recompile then
 771                                 returnRn outOfDate
 772                            else
 773                                 checkList checks
 774 \end{code}
 775
 776 \begin{code}
 777 checkModUsage :: ImportVersion Name -> RnMG RecompileRequired
 778 -- Given the usage information extracted from the old
 779 -- M.hi file for the module being compiled, figure out
 780 -- whether M needs to be recompiled.
 781
 782 checkModUsage (mod_name, _, _, NothingAtAll)
 783         -- If CurrentModule.hi contains
 784         --      import Foo :: ;
 785         -- then that simply records that Foo lies below CurrentModule in the
 786         -- hierarchy, but CurrentModule doesn't depend in any way on Foo.
 787         -- In this case we don't even want to open Foo's interface.
 788   = up_to_date (ptext SLIT("Nothing used from:") <+> ppr mod_name)
 789
 790 checkModUsage (mod_name, _, is_boot, whats_imported)
 791   =     -- Load the imported interface is possible
 792         -- We use tryLoadInterface, because failure is not an error
 793         -- (might just be that the old .hi file for this module is out of date)
 794         -- We use ImportByUser/ImportByUserSource as the 'from' flag,
 795         --      a) because we need to know whether to load the .hi-boot file
 796         --      b) because loadInterface things matters are amiss if we
 797         --         ImportBySystem an interface it knows nothing about
 798     let
 799         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
 800         from    | is_boot   = ImportByUserSource
 801                 | otherwise = ImportByUser
 802     in
 803     traceHiDiffsRn (text "Checking usages for module" <+> ppr mod_name) `thenRn_`
 804     tryLoadInterface doc_str mod_name from      `thenRn` \ (iface, maybe_err) ->
 805
 806     case maybe_err of {
 807         Just err -> out_of_date (sep [ptext SLIT("Can't find version number for module"),
 808                                       ppr mod_name]) ;
 809                 -- Couldn't find or parse a module mentioned in the
 810                 -- old interface file.  Don't complain -- it might just be that
 811                 -- the current module doesn't need that import and it's been deleted
 812
 813         Nothing ->
 814     let
 815         new_vers      = mi_version iface
 816         new_decl_vers = vers_decls new_vers
 817     in
 818     case whats_imported of {    -- NothingAtAll dealt with earlier
 819
 820       Everything old_mod_vers -> checkModuleVersion old_mod_vers new_vers       `thenRn` \ recompile ->
 821                                  if recompile then
 822                                         out_of_date (ptext SLIT("...and I needed the whole module"))
 823                                  else
 824                                         returnRn upToDate ;
 825
 826       Specifically old_mod_vers maybe_old_export_vers old_decl_vers old_rule_vers ->
 827
 828         -- CHECK MODULE
 829     checkModuleVersion old_mod_vers new_vers    `thenRn` \ recompile ->
 830     if not recompile then
 831         returnRn upToDate
 832     else
 833
 834         -- CHECK EXPORT LIST
 835     if checkExportList maybe_old_export_vers new_vers then
 836         out_of_date (ptext SLIT("Export list changed"))
 837     else
 838
 839         -- CHECK RULES
 840     if old_rule_vers /= vers_rules new_vers then
 841         out_of_date (ptext SLIT("Rules changed"))
 842     else
 843
 844         -- CHECK ITEMS ONE BY ONE
 845     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenRn` \ recompile ->
 846     if recompile then
 847         returnRn outOfDate      -- This one failed, so just bail out now
 848     else
 849         up_to_date (ptext SLIT("...but the bits I use haven't."))
 850
 851     }}
 852
 853 ------------------------
 854 checkModuleVersion old_mod_vers new_vers
 855   | vers_module new_vers == old_mod_vers
 856   = up_to_date (ptext SLIT("Module version unchanged"))
 857
 858   | otherwise
 859   = out_of_date (ptext SLIT("Module version has changed"))
 860
 861 ------------------------
 862 checkExportList Nothing  new_vers = upToDate
 863 checkExportList (Just v) new_vers = v /= vers_exports new_vers
 864
 865 ------------------------
 866 checkEntityUsage new_vers (name,old_vers)
 867   = case lookupNameEnv new_vers name of
 868
 869         Nothing       ->        -- We used it before, but it ain't there now
 870                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
 871
 872         Just new_vers   -- It's there, but is it up to date?
 873           | new_vers == old_vers -> traceHiDiffsRn (text "Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenRn_`
 874                                     returnRn upToDate
 875           | otherwise            -> out_of_date (sep [ptext SLIT("Out of date:"), ppr name, ppr
 876                                                       old_vers, ptext SLIT("->"), ppr new_vers])
 877
 878 up_to_date  msg = traceHiDiffsRn msg `thenRn_` returnRn upToDate
 879 out_of_date msg = traceHiDiffsRn msg `thenRn_` returnRn outOfDate
 880 \end{code}
 881
 882
 883 %*********************************************************
 884 %*                                                       *
 885 \subsection{Errors}
 886 %*                                                       *
 887 %*********************************************************
 888
 889 \begin{code}
 890 getDeclErr name
 891   = vcat [ptext SLIT("Failed to find interface decl for") <+> quotes (ppr name),
 892           ptext SLIT("from module") <+> quotes (ppr (nameModule name))
 893          ]
 894 \end{code}