ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9         Module,
  10         FiniteMap,
  11         Bag,
  12         Name,
  13         RdrNameHsDecl,
  14         RdrNameInstDecl,
  15         Version,
  16         NameSet,
  17         OccName,
  18         Fixity
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  24 import IOExts           ( fixIO )
  25 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  26 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  27 #else
  28 import IOBase           ( fixIO )
  29 #endif
  30 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  31
  32 import HsSyn
  33 import RdrHsSyn
  34 import RnHsSyn          ( RenamedFixitySig )
  35 import BasicTypes       ( Version )
  36 import SrcLoc           ( noSrcLoc )
  37 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  38                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  39                         )
  40 import Name             ( Name, OccName, NamedThing(..),
  41                           isLocallyDefinedName, nameModule, nameOccName,
  42                           decode, mkLocalName
  43                         )
  44 import Module           ( Module, ModuleName, ModuleHiMap, SearchPath, WhereFrom,
  45                           mkModuleHiMaps, moduleName, mkVanillaModule, mkSearchPath
  46                         )
  47 import NameSet
  48 import RdrName          ( RdrName, dummyRdrVarName, rdrNameOcc )
  49 import CmdLineOpts      ( opt_D_dump_rn_trace, opt_HiMap )
  50 import PrelInfo         ( builtinNames )
  51 import TysWiredIn       ( boolTyCon )
  52 import SrcLoc           ( SrcLoc, mkGeneratedSrcLoc )
  53 import Unique           ( Unique, getUnique, unboundKey )
  54 import UniqFM           ( UniqFM )
  55 import FiniteMap        ( FiniteMap, emptyFM, bagToFM, lookupFM, addToFM, addListToFM,
  56                           addListToFM_C, addToFM_C, eltsFM, fmToList
  57                         )
  58 import Bag              ( Bag, mapBag, emptyBag, isEmptyBag, snocBag )
  59 import Maybes           ( mapMaybe )
  60 import UniqSet
  61 import UniqFM
  62 import UniqSupply
  63 import Util
  64 import Outputable
  65
  66 infixr 9 `thenRn`, `thenRn_`
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Somewhat magical interface to other monads}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 ioToRnM :: IO r -> RnM d (Either IOError r)
  78 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  79                             `catch`
  80                             (\ err -> return (Left err))
  81
  82 traceRn :: SDoc -> RnM d ()
  83 traceRn msg | opt_D_dump_rn_trace = putDocRn msg
  84             | otherwise           = returnRn ()
  85
  86 putDocRn :: SDoc -> RnM d ()
  87 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
  88                returnRn ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{Data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 %===================================================
  99 \subsubsection{         MONAD TYPES}
 100 %===================================================
 101
 102 \begin{code}
 103 type RnM d r = RnDown -> d -> IO r
 104 type RnMS r  = RnM SDown r              -- Renaming source
 105 type RnMG r  = RnM ()    r              -- Getting global names etc
 106
 107         -- Common part
 108 data RnDown = RnDown {
 109                   rn_mod     :: ModuleName,
 110                   rn_loc     :: SrcLoc,
 111                   rn_ns      :: IORef RnNameSupply,
 112                   rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 113                   rn_ifaces  :: IORef Ifaces,
 114                   rn_hi_maps :: (ModuleHiMap,   -- for .hi files
 115                                  ModuleHiMap)   -- for .hi-boot files
 116                 }
 117
 118         -- For renaming source code
 119 data SDown = SDown {
 120                   rn_mode :: RnMode,
 121
 122                   rn_genv :: GlobalRdrEnv,
 123                         --   Global envt; the fixity component gets extended
 124                         --   with local fixity decls
 125
 126                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 127                         --   Does *not* include global name envt; may shadow it
 128                         --   Includes both ordinary variables and type variables;
 129                         --   they are kept distinct because tyvar have a different
 130                         --   occurrence contructor (Name.TvOcc)
 131                         -- We still need the unsullied global name env so that
 132                         --   we can look up record field names
 133
 134                   rn_fixenv :: FixityEnv        -- Local fixities
 135                         -- The global fixities are held in the
 136                         -- rn_ifaces field.  Why?  See the comments
 137                         -- with RnIfaces.lookupFixity
 138                 }
 139
 140 data RnMode     = SourceMode                    -- Renaming source code
 141                 | InterfaceMode                 -- Renaming interface declarations.
 142 \end{code}
 143
 144 %===================================================
 145 \subsubsection{         ENVIRONMENTS}
 146 %===================================================
 147
 148 \begin{code}
 149 --------------------------------
 150 type RdrNameEnv a = FiniteMap RdrName a
 151 type GlobalRdrEnv = RdrNameEnv [Name]   -- The list is because there may be name clashes
 152                                         -- These only get reported on lookup,
 153                                         -- not on construction
 154 type LocalRdrEnv  = RdrNameEnv Name
 155
 156 emptyRdrEnv  :: RdrNameEnv a
 157 lookupRdrEnv :: RdrNameEnv a -> RdrName -> Maybe a
 158 addListToRdrEnv :: RdrNameEnv a -> [(RdrName,a)] -> RdrNameEnv a
 159 extendRdrEnv    :: RdrNameEnv a -> RdrName -> a -> RdrNameEnv a
 160
 161 emptyRdrEnv  = emptyFM
 162 lookupRdrEnv = lookupFM
 163 addListToRdrEnv = addListToFM
 164 rdrEnvElts      = eltsFM
 165 extendRdrEnv    = addToFM
 166 rdrEnvToList    = fmToList
 167
 168 --------------------------------
 169 type NameEnv a = UniqFM a       -- Domain is Name
 170
 171 emptyNameEnv   :: NameEnv a
 172 nameEnvElts    :: NameEnv a -> [a]
 173 addToNameEnv_C :: (a->a->a) -> NameEnv a -> Name -> a -> NameEnv a
 174 addToNameEnv   :: NameEnv a -> Name -> a -> NameEnv a
 175 plusNameEnv    :: NameEnv a -> NameEnv a -> NameEnv a
 176 extendNameEnv  :: NameEnv a -> [(Name,a)] -> NameEnv a
 177 lookupNameEnv  :: NameEnv a -> Name -> Maybe a
 178 delFromNameEnv :: NameEnv a -> Name -> NameEnv a
 179 elemNameEnv    :: Name -> NameEnv a -> Bool
 180
 181 emptyNameEnv   = emptyUFM
 182 nameEnvElts    = eltsUFM
 183 addToNameEnv_C = addToUFM_C
 184 addToNameEnv   = addToUFM
 185 plusNameEnv    = plusUFM
 186 extendNameEnv  = addListToUFM
 187 lookupNameEnv  = lookupUFM
 188 delFromNameEnv = delFromUFM
 189 elemNameEnv    = elemUFM
 190
 191 --------------------------------
 192 type FixityEnv = NameEnv RenamedFixitySig
 193         -- We keep the whole fixity sig so that we
 194         -- can report line-number info when there is a duplicate
 195         -- fixity declaration
 196 \end{code}
 197
 198 \begin{code}
 199 --------------------------------
 200 type RnNameSupply
 201  = ( UniqSupply
 202
 203    , FiniteMap String Int
 204         -- This is used as a name supply for dictionary functions
 205         -- From the inst decl we derive a string, usually by glomming together
 206         -- the class and tycon name -- but it doesn't matter exactly how;
 207         -- this map then gives a unique int for each inst decl with that
 208         -- string.  (In Haskell 98 there can only be one,
 209         -- but not so in more extended versions; also class CC type T
 210         -- and class C type TT might both give the string CCT
 211         --
 212         -- We could just use one Int for all the instance decls, but this
 213         -- way the uniques change less when you add an instance decl,
 214         -- hence less recompilation
 215
 216    , FiniteMap (ModuleName, OccName) Name
 217         -- Ensures that one (module,occname) pair gets one unique
 218    , FiniteMap OccName Name
 219         -- Ensures that one implicit parameter name gets one unique
 220    )
 221
 222
 223 --------------------------------
 224 data ExportEnv    = ExportEnv Avails Fixities [ModuleName]
 225                         -- The list of modules is the modules exported
 226                         -- with 'module M' in the export list
 227
 228 type Avails       = [AvailInfo]
 229 type Fixities     = [(Name, Fixity)]
 230
 231 type ExportAvails = (FiniteMap ModuleName Avails,
 232         -- Used to figure out "module M" export specifiers
 233         -- Includes avails only from *unqualified* imports
 234         -- (see 1.4 Report Section 5.1.1)
 235
 236         NameEnv AvailInfo)      -- Used to figure out all other export specifiers.
 237                                 -- Maps a Name to the AvailInfo that contains it
 238
 239
 240 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 241                         | AvailTC name   -- The name of the type or class
 242                                   [name] -- The available pieces of type/class.
 243                                          -- NB: If the type or class is itself
 244                                          -- to be in scope, it must be in this list.
 245                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 246
 247 type AvailInfo    = GenAvailInfo Name
 248 type RdrAvailInfo = GenAvailInfo OccName
 249 \end{code}
 250
 251 %===================================================
 252 \subsubsection{         INTERFACE FILE STUFF}
 253 %===================================================
 254
 255 \begin{code}
 256 type ExportItem          = (ModuleName, [RdrAvailInfo])
 257 type VersionInfo name    = [ImportVersion name]
 258
 259 type ImportVersion name  = (ModuleName, Version, WhetherHasOrphans, WhatsImported name)
 260
 261 type WhetherHasOrphans   = Bool
 262         -- An "orphan" is
 263         --      * an instance decl in a module other than the defn module for
 264         --              one of the tycons or classes in the instance head
 265         --      * a transformation rule in a module other than the one defining
 266         --              the function in the head of the rule.
 267
 268 data WhatsImported name  = Everything
 269                          | Specifically [LocalVersion name] -- List guaranteed non-empty
 270
 271     -- ("M", hif, ver, Everything) means there was a "module M" in
 272     -- this module's export list, so we just have to go by M's version, "ver",
 273     -- not the list of LocalVersions.
 274
 275
 276 type LocalVersion name   = (name, Version)
 277
 278 data ParsedIface
 279   = ParsedIface {
 280       pi_mod       :: Version,                          -- Module version number
 281       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 282       pi_usages    :: [ImportVersion OccName],          -- Usages
 283       pi_exports   :: [ExportItem],                     -- Exports
 284       pi_decls     :: [(Version, RdrNameHsDecl)],       -- Local definitions
 285       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 286       pi_rules     :: [RdrNameRuleDecl]                 -- Rules
 287     }
 288
 289 type InterfaceDetails = (WhetherHasOrphans,
 290                          VersionInfo Name, -- Version information for what this module imports
 291                          ExportEnv)        -- What modules this one depends on
 292
 293
 294 -- needed by Main to fish out the fixities assoc list.
 295 getIfaceFixities :: InterfaceDetails -> Fixities
 296 getIfaceFixities (_, _, ExportEnv _ fs _) = fs
 297
 298
 299 type RdrNamePragma = ()                         -- Fudge for now
 300 -------------------
 301
 302 data Ifaces = Ifaces {
 303                 iImpModInfo :: ImportedModuleInfo,
 304                                 -- Modules this one depends on: that is, the union
 305                                 -- of the modules its *direct* imports depend on.
 306                                 -- NB: The direct imports have .hi files that enumerate *all* the
 307                                 -- dependencies (direct or not) of the imported module.
 308
 309                 iDecls :: DeclsMap,     -- A single, global map of Names to decls
 310
 311                 iFixes :: FixityEnv,    -- A single, global map of Names to fixities
 312                                         -- See comments with RnIfaces.lookupFixity
 313
 314                 iSlurp :: NameSet,
 315                 -- All the names (whether "big" or "small", whether wired-in or not,
 316                 -- whether locally defined or not) that have been slurped in so far.
 317
 318                 iVSlurp :: [(Name,Version)],
 319                 -- All the (a) non-wired-in (b) "big" (c) non-locally-defined
 320                 -- names that have been slurped in so far, with their versions.
 321                 -- This is used to generate the "usage" information for this module.
 322                 -- Subset of the previous field.
 323
 324                 iInsts :: Bag GatedDecl,
 325                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 326                 -- slurp an instance decl so that we don't slurp the same one twice.
 327                 -- Each is 'gated' by the names that must be available before
 328                 -- this instance decl is needed.
 329
 330                 iRules :: Bag GatedDecl
 331                         -- Ditto transformation rules
 332         }
 333
 334 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 335
 336 type ImportedModuleInfo
 337      = FiniteMap ModuleName (Version, Bool, Maybe (Module, Bool, Avails))
 338                 -- Suppose the domain element is module 'A'
 339                 --
 340                 -- The first Bool is True if A contains
 341                 -- 'orphan' rules or instance decls
 342
 343                 -- The second Bool is true if the interface file actually
 344                 -- read was an .hi-boot file
 345
 346                 -- Nothing => A's interface not yet read, but this module has
 347                 --            imported a module, B, that itself depends on A
 348                 --
 349                 -- Just xx => A's interface has been read.  The Module in
 350                 --              the Just has the correct Dll flag
 351
 352                 -- This set is used to decide whether to look for
 353                 -- A.hi or A.hi-boot when importing A.f.
 354                 -- Basically, we look for A.hi if A is in the map, and A.hi-boot
 355                 -- otherwise
 356
 357 type DeclsMap = NameEnv (Version, AvailInfo, Bool, (Module, RdrNameHsDecl))
 358                 -- A DeclsMap contains a binding for each Name in the declaration
 359                 -- including the constructors of a type decl etc.
 360                 -- The Bool is True just for the 'main' Name.
 361 \end{code}
 362
 363
 364 %************************************************************************
 365 %*                                                                      *
 366 \subsection{Main monad code}
 367 %*                                                                      *
 368 %************************************************************************
 369
 370 \begin{code}
 371 initRn :: ModuleName -> UniqSupply -> SearchPath -> SrcLoc
 372        -> RnMG r
 373        -> IO (r, Bag ErrMsg, Bag WarnMsg)
 374
 375 initRn mod us dirs loc do_rn = do
 376   himaps    <- mkModuleHiMaps dirs
 377   names_var <- newIORef (us, emptyFM, builtins, emptyFM)
 378   errs_var  <- newIORef (emptyBag,emptyBag)
 379   iface_var <- newIORef emptyIfaces
 380   let
 381         rn_down = RnDown { rn_loc = loc, rn_ns = names_var,
 382                            rn_errs = errs_var,
 383                            rn_hi_maps = himaps,
 384                            rn_ifaces = iface_var,
 385                            rn_mod = mod }
 386
 387         -- do the business
 388   res <- do_rn rn_down ()
 389
 390         -- grab errors and return
 391   (warns, errs) <- readIORef errs_var
 392
 393   return (res, errs, warns)
 394
 395
 396 initRnMS :: GlobalRdrEnv -> FixityEnv -> RnMode -> RnMS r -> RnM d r
 397 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 398   = let
 399         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 400                          rn_fixenv = fixity_env, rn_mode = mode }
 401     in
 402     thing_inside rn_down s_down
 403
 404 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 405 initIfaceRnMS mod thing_inside
 406   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 407     setModuleRn (moduleName mod) thing_inside
 408
 409 emptyIfaces :: Ifaces
 410 emptyIfaces = Ifaces { iImpModInfo = emptyFM,
 411                        iDecls = emptyNameEnv,
 412                        iFixes = emptyNameEnv,
 413                        iSlurp = unitNameSet (mkUnboundName dummyRdrVarName),
 414                         -- Pretend that the dummy unbound name has already been
 415                         -- slurped.  This is what's returned for an out-of-scope name,
 416                         -- and we don't want thereby to try to suck it in!
 417                        iVSlurp = [],
 418                        iInsts = emptyBag,
 419                        iRules = emptyBag
 420               }
 421
 422 -- mkUnboundName makes a place-holder Name; it shouldn't be looked at except possibly
 423 -- during compiler debugging.
 424 mkUnboundName :: RdrName -> Name
 425 mkUnboundName rdr_name = mkLocalName unboundKey (rdrNameOcc rdr_name) noSrcLoc
 426
 427 isUnboundName :: Name -> Bool
 428 isUnboundName name = getUnique name == unboundKey
 429
 430 builtins :: FiniteMap (ModuleName,OccName) Name
 431 builtins =
 432    bagToFM (
 433    mapBag (\ name ->  ((moduleName (nameModule name), nameOccName name), name))
 434           builtinNames)
 435 \end{code}
 436
 437 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 438 that is, not as part of the main renamer.
 439 Sole examples: derived definitions,
 440 which are only generated in the type checker.
 441
 442 The @RnNameSupply@ includes a @UniqueSupply@, so if you call it more than
 443 once you must either split it, or install a fresh unique supply.
 444
 445 \begin{code}
 446 renameSourceCode :: ModuleName
 447                  -> RnNameSupply
 448                  -> RnMS r
 449                  -> r
 450
 451 renameSourceCode mod_name name_supply m
 452   = unsafePerformIO (
 453         -- It's not really unsafe!  When renaming source code we
 454         -- only do any I/O if we need to read in a fixity declaration;
 455         -- and that doesn't happen in pragmas etc
 456
 457         mkModuleHiMaps (mkSearchPath opt_HiMap) >>= \ himaps ->
 458         newIORef name_supply            >>= \ names_var ->
 459         newIORef (emptyBag,emptyBag)    >>= \ errs_var ->
 460         let
 461             rn_down = RnDown { rn_loc = mkGeneratedSrcLoc, rn_ns = names_var,
 462                                rn_errs = errs_var, rn_hi_maps = himaps,
 463                                rn_mod = mod_name,
 464                                rn_ifaces = panic "rnameSourceCode: rn_ifaces"  -- Not required
 465                              }
 466             s_down = SDown { rn_mode = InterfaceMode,
 467                                -- So that we can refer to PrelBase.True etc
 468                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 469                              rn_fixenv = emptyNameEnv }
 470         in
 471         m rn_down s_down                        >>= \ result ->
 472
 473         readIORef errs_var                      >>= \ (warns,errs) ->
 474
 475         (if not (isEmptyBag errs) then
 476                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 477 #ifdef DEBUG
 478          else if not (isEmptyBag warns) then
 479                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 480 #endif
 481          else
 482                 id) $
 483
 484         return result
 485     )
 486   where
 487     display errs = pprBagOfErrors errs
 488
 489 {-# INLINE thenRn #-}
 490 {-# INLINE thenRn_ #-}
 491 {-# INLINE returnRn #-}
 492 {-# INLINE andRn #-}
 493
 494 returnRn :: a -> RnM d a
 495 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 496 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 497 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 498 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 499 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 500 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 501 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 502 sequenceRn :: [RnM d a] -> RnM d [a]
 503 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 504 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 505 fixRn    :: (a -> RnM d a) -> RnM d a
 506
 507 returnRn v gdown ldown  = return v
 508 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 509 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 510 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 511 andRn combiner m1 m2 gdown ldown
 512   = m1 gdown ldown >>= \ res1 ->
 513     m2 gdown ldown >>= \ res2 ->
 514     return (combiner res1 res2)
 515
 516 sequenceRn []     = returnRn []
 517 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 518                      sequenceRn ms      `thenRn` \ rs ->
 519                      returnRn (r:rs)
 520
 521 mapRn f []     = returnRn []
 522 mapRn f (x:xs)
 523   = f x         `thenRn` \ r ->
 524     mapRn f xs  `thenRn` \ rs ->
 525     returnRn (r:rs)
 526
 527 mapRn_ f []     = returnRn ()
 528 mapRn_ f (x:xs) =
 529     f x         `thenRn_`
 530     mapRn_ f xs
 531
 532 foldlRn k z [] = returnRn z
 533 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 534                      foldlRn k z' xs
 535
 536 mapAndUnzipRn f [] = returnRn ([],[])
 537 mapAndUnzipRn f (x:xs)
 538   = f x                 `thenRn` \ (r1,  r2)  ->
 539     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 540     returnRn (r1:rs1, r2:rs2)
 541
 542 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 543 mapAndUnzip3Rn f (x:xs)
 544   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 545     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 546     returnRn (r1:rs1, r2:rs2, r3:rs3)
 547
 548 mapMaybeRn f []     = returnRn []
 549 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 550                       mapMaybeRn f xs   `thenRn` \ rs ->
 551                       case maybe_r of
 552                         Nothing -> returnRn rs
 553                         Just r  -> returnRn (r:rs)
 554
 555 flatMapRn f []     = returnRn []
 556 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 557                      flatMapRn f xs     `thenRn` \ rs ->
 558                      returnRn (r ++ rs)
 559 \end{code}
 560
 561
 562
 563 %************************************************************************
 564 %*                                                                      *
 565 \subsection{Boring plumbing for common part}
 566 %*                                                                      *
 567 %************************************************************************
 568
 569
 570 %================
 571 \subsubsection{  Errors and warnings}
 572 %=====================
 573
 574 \begin{code}
 575 failWithRn :: a -> Message -> RnM d a
 576 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 577   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 578     writeIORef errs_var (warns, errs `snocBag` err)             >>
 579     return res
 580   where
 581     err = addShortErrLocLine loc msg
 582
 583 warnWithRn :: a -> Message -> RnM d a
 584 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 585   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 586     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 587     return res
 588   where
 589     warn = addShortWarnLocLine loc msg
 590
 591 addErrRn :: Message -> RnM d ()
 592 addErrRn err = failWithRn () err
 593
 594 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 595 checkRn False err = addErrRn err
 596 checkRn True  err = returnRn ()
 597
 598 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 599 warnCheckRn False err = addWarnRn err
 600 warnCheckRn True  err = returnRn ()
 601
 602 addWarnRn :: Message -> RnM d ()
 603 addWarnRn warn = warnWithRn () warn
 604
 605 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 606 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 607   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 608     return (isEmptyBag errs)
 609 \end{code}
 610
 611
 612 %================
 613 \subsubsection{  Source location}
 614 %=====================
 615
 616 \begin{code}
 617 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 618 pushSrcLocRn loc' m down l_down
 619   = m (down {rn_loc = loc'}) l_down
 620
 621 getSrcLocRn :: RnM d SrcLoc
 622 getSrcLocRn down l_down
 623   = return (rn_loc down)
 624 \end{code}
 625
 626 %================
 627 \subsubsection{  Name supply}
 628 %=====================
 629
 630 \begin{code}
 631 getNameSupplyRn :: RnM d RnNameSupply
 632 getNameSupplyRn rn_down l_down
 633   = readIORef (rn_ns rn_down)
 634
 635 setNameSupplyRn :: RnNameSupply -> RnM d ()
 636 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 637   = writeIORef names_var names'
 638
 639 -- See comments with RnNameSupply above.
 640 newInstUniq :: String -> RnM d Int
 641 newInstUniq key (RnDown {rn_ns = names_var}) l_down
 642   = readIORef names_var                         >>= \ (us, mapInst, cache, ipcache) ->
 643     let
 644         uniq = case lookupFM mapInst key of
 645                    Just x  -> x+1
 646                    Nothing -> 0
 647         mapInst' = addToFM mapInst key uniq
 648     in
 649     writeIORef names_var (us, mapInst', cache, ipcache) >>
 650     return uniq
 651
 652 getUniqRn :: RnM d Unique
 653 getUniqRn (RnDown {rn_ns = names_var}) l_down
 654  = readIORef names_var >>= \ (us, mapInst, cache, ipcache) ->
 655    let
 656      (us1,us') = splitUniqSupply us
 657    in
 658    writeIORef names_var (us', mapInst, cache, ipcache)  >>
 659    return (uniqFromSupply us1)
 660 \end{code}
 661
 662 %================
 663 \subsubsection{  Module}
 664 %=====================
 665
 666 \begin{code}
 667 getModuleRn :: RnM d ModuleName
 668 getModuleRn (RnDown {rn_mod = mod_name}) l_down
 669   = return mod_name
 670
 671 setModuleRn :: ModuleName -> RnM d a -> RnM d a
 672 setModuleRn new_mod enclosed_thing rn_down l_down
 673   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 674 \end{code}
 675
 676
 677 %************************************************************************
 678 %*                                                                      *
 679 \subsection{Plumbing for rename-source part}
 680 %*                                                                      *
 681 %************************************************************************
 682
 683 %================
 684 \subsubsection{  RnEnv}
 685 %=====================
 686
 687 \begin{code}
 688 getNameEnvs :: RnMS (GlobalRdrEnv, LocalRdrEnv)
 689 getNameEnvs rn_down (SDown {rn_genv = global_env, rn_lenv = local_env})
 690   = return (global_env, local_env)
 691
 692 getLocalNameEnv :: RnMS LocalRdrEnv
 693 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 694   = return local_env
 695
 696 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 697 setLocalNameEnv local_env' m rn_down l_down
 698   = m rn_down (l_down {rn_lenv = local_env'})
 699
 700 getFixityEnv :: RnMS FixityEnv
 701 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 702   = return fixity_env
 703
 704 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 705 extendFixityEnv fixes enclosed_scope
 706                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 707   = let
 708         new_fixity_env = extendNameEnv fixity_env fixes
 709     in
 710     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 711 \end{code}
 712
 713 %================
 714 \subsubsection{  Mode}
 715 %=====================
 716
 717 \begin{code}
 718 getModeRn :: RnMS RnMode
 719 getModeRn rn_down (SDown {rn_mode = mode})
 720   = return mode
 721
 722 setModeRn :: RnMode -> RnMS a -> RnMS a
 723 setModeRn new_mode thing_inside rn_down l_down
 724   = thing_inside rn_down (l_down {rn_mode = new_mode})
 725 \end{code}
 726
 727
 728 %************************************************************************
 729 %*                                                                      *
 730 \subsection{Plumbing for rename-globals part}
 731 %*                                                                      *
 732 %************************************************************************
 733
 734 \begin{code}
 735 getIfacesRn :: RnM d Ifaces
 736 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 737   = readIORef iface_var
 738
 739 setIfacesRn :: Ifaces -> RnM d ()
 740 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 741   = writeIORef iface_var ifaces
 742
 743 getHiMaps :: RnM d (ModuleHiMap, ModuleHiMap)
 744 getHiMaps (RnDown {rn_hi_maps = himaps}) _
 745   = return himaps
 746 \end{code}
 747
 748 \begin{code}
 749 lookupModuleRn :: ModuleName -> RnM d Module
 750 lookupModuleRn x =
 751   getHiMaps `thenRn` \ (himap, _) ->
 752   case lookupFM himap x of
 753     Nothing    -> returnRn (mkVanillaModule x)
 754     Just (_,x) -> returnRn x
 755
 756 \end{code}