ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9         Module,
  10         FiniteMap,
  11         Bag,
  12         Name,
  13         RdrNameHsDecl,
  14         RdrNameInstDecl,
  15         Version,
  16         NameSet,
  17         OccName,
  18         Fixity
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  24 import IOExts           ( fixIO )
  25 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  26 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  27 #else
  28 import IOBase           ( fixIO )
  29 #endif
  30 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  31
  32 import HsSyn
  33 import RdrHsSyn
  34 import RnHsSyn          ( RenamedFixitySig )
  35 import BasicTypes       ( Version )
  36 import SrcLoc           ( noSrcLoc )
  37 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  38                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  39                         )
  40 import Name             ( Name, OccName, NamedThing(..),
  41                           isLocallyDefinedName, nameModule, nameOccName,
  42                           decode, mkLocalName
  43                         )
  44 import Module           ( Module, ModuleName, ModuleHiMap, SearchPath, WhereFrom,
  45                           mkModuleHiMaps, moduleName, mkVanillaModule, mkSearchPath
  46                         )
  47 import NameSet
  48 import RdrName          ( RdrName, dummyRdrVarName, rdrNameOcc )
  49 import CmdLineOpts      ( opt_D_dump_rn_trace, opt_HiMap )
  50 import PrelInfo         ( builtinNames )
  51 import TysWiredIn       ( boolTyCon )
  52 import SrcLoc           ( SrcLoc, mkGeneratedSrcLoc )
  53 import Unique           ( Unique, getUnique, unboundKey )
  54 import UniqFM           ( UniqFM )
  55 import FiniteMap        ( FiniteMap, emptyFM, bagToFM, lookupFM, addToFM, addListToFM,
  56                           addListToFM_C, addToFM_C, eltsFM, fmToList
  57                         )
  58 import Bag              ( Bag, mapBag, emptyBag, isEmptyBag, snocBag )
  59 import Maybes           ( mapMaybe )
  60 import UniqSet
  61 import UniqFM
  62 import UniqSupply
  63 import Util
  64 import Outputable
  65
  66 infixr 9 `thenRn`, `thenRn_`
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Somewhat magical interface to other monads}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 ioToRnM :: IO r -> RnM d (Either IOError r)
  78 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  79                             `catch`
  80                             (\ err -> return (Left err))
  81
  82 traceRn :: SDoc -> RnM d ()
  83 traceRn msg | opt_D_dump_rn_trace = putDocRn msg
  84             | otherwise           = returnRn ()
  85
  86 putDocRn :: SDoc -> RnM d ()
  87 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
  88                returnRn ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{Data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 %===================================================
  99 \subsubsection{         MONAD TYPES}
 100 %===================================================
 101
 102 \begin{code}
 103 type RnM d r = RnDown -> d -> IO r
 104 type RnMS r  = RnM SDown r              -- Renaming source
 105 type RnMG r  = RnM ()    r              -- Getting global names etc
 106
 107         -- Common part
 108 data RnDown = RnDown {
 109                   rn_mod     :: ModuleName,
 110                   rn_loc     :: SrcLoc,
 111                   rn_ns      :: IORef RnNameSupply,
 112                   rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 113                   rn_ifaces  :: IORef Ifaces,
 114                   rn_hi_maps :: (ModuleHiMap,   -- for .hi files
 115                                  ModuleHiMap)   -- for .hi-boot files
 116                 }
 117
 118         -- For renaming source code
 119 data SDown = SDown {
 120                   rn_mode :: RnMode,
 121
 122                   rn_genv :: GlobalRdrEnv,
 123                         --   Global envt; the fixity component gets extended
 124                         --   with local fixity decls
 125
 126                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 127                         --   Does *not* include global name envt; may shadow it
 128                         --   Includes both ordinary variables and type variables;
 129                         --   they are kept distinct because tyvar have a different
 130                         --   occurrence contructor (Name.TvOcc)
 131                         -- We still need the unsullied global name env so that
 132                         --   we can look up record field names
 133
 134                   rn_fixenv :: FixityEnv        -- Local fixities
 135                         -- The global fixities are held in the
 136                         -- rn_ifaces field.  Why?  See the comments
 137                         -- with RnIfaces.lookupFixity
 138                 }
 139
 140 data RnMode     = SourceMode                    -- Renaming source code
 141                 | InterfaceMode                 -- Renaming interface declarations.
 142 \end{code}
 143
 144 %===================================================
 145 \subsubsection{         ENVIRONMENTS}
 146 %===================================================
 147
 148 \begin{code}
 149 --------------------------------
 150 type RdrNameEnv a = FiniteMap RdrName a
 151 type GlobalRdrEnv = RdrNameEnv [Name]   -- The list is because there may be name clashes
 152                                         -- These only get reported on lookup,
 153                                         -- not on construction
 154 type LocalRdrEnv  = RdrNameEnv Name
 155
 156 emptyRdrEnv  :: RdrNameEnv a
 157 lookupRdrEnv :: RdrNameEnv a -> RdrName -> Maybe a
 158 addListToRdrEnv :: RdrNameEnv a -> [(RdrName,a)] -> RdrNameEnv a
 159 extendRdrEnv    :: RdrNameEnv a -> RdrName -> a -> RdrNameEnv a
 160
 161 emptyRdrEnv  = emptyFM
 162 lookupRdrEnv = lookupFM
 163 addListToRdrEnv = addListToFM
 164 rdrEnvElts      = eltsFM
 165 extendRdrEnv    = addToFM
 166 rdrEnvToList    = fmToList
 167
 168 --------------------------------
 169 type NameEnv a = UniqFM a       -- Domain is Name
 170
 171 emptyNameEnv   :: NameEnv a
 172 nameEnvElts    :: NameEnv a -> [a]
 173 addToNameEnv_C :: (a->a->a) -> NameEnv a -> Name -> a -> NameEnv a
 174 addToNameEnv   :: NameEnv a -> Name -> a -> NameEnv a
 175 plusNameEnv    :: NameEnv a -> NameEnv a -> NameEnv a
 176 extendNameEnv  :: NameEnv a -> [(Name,a)] -> NameEnv a
 177 lookupNameEnv  :: NameEnv a -> Name -> Maybe a
 178 delFromNameEnv :: NameEnv a -> Name -> NameEnv a
 179 elemNameEnv    :: Name -> NameEnv a -> Bool
 180
 181 emptyNameEnv   = emptyUFM
 182 nameEnvElts    = eltsUFM
 183 addToNameEnv_C = addToUFM_C
 184 addToNameEnv   = addToUFM
 185 plusNameEnv    = plusUFM
 186 extendNameEnv  = addListToUFM
 187 lookupNameEnv  = lookupUFM
 188 delFromNameEnv = delFromUFM
 189 elemNameEnv    = elemUFM
 190
 191 --------------------------------
 192 type FixityEnv = NameEnv RenamedFixitySig
 193         -- We keep the whole fixity sig so that we
 194         -- can report line-number info when there is a duplicate
 195         -- fixity declaration
 196 \end{code}
 197
 198 \begin{code}
 199 --------------------------------
 200 type RnNameSupply
 201  = ( UniqSupply
 202
 203    , FiniteMap String Int
 204         -- This is used as a name supply for dictionary functions
 205         -- From the inst decl we derive a string, usually by glomming together
 206         -- the class and tycon name -- but it doesn't matter exactly how;
 207         -- this map then gives a unique int for each inst decl with that
 208         -- string.  (In Haskell 98 there can only be one,
 209         -- but not so in more extended versions; also class CC type T
 210         -- and class C type TT might both give the string CCT
 211         --
 212         -- We could just use one Int for all the instance decls, but this
 213         -- way the uniques change less when you add an instance decl,
 214         -- hence less recompilation
 215
 216    , FiniteMap (ModuleName, OccName) Name
 217         -- Ensures that one (module,occname) pair gets one unique
 218    , FiniteMap OccName Name
 219         -- Ensures that one implicit parameter name gets one unique
 220    )
 221
 222
 223 --------------------------------
 224 data ExportEnv    = ExportEnv Avails Fixities [ModuleName]
 225                         -- The list of modules is the modules exported
 226                         -- with 'module M' in the export list
 227
 228 type Avails       = [AvailInfo]
 229 type Fixities     = [(Name, Fixity)]
 230
 231 type ExportAvails = (FiniteMap ModuleName Avails,
 232         -- Used to figure out "module M" export specifiers
 233         -- Includes avails only from *unqualified* imports
 234         -- (see 1.4 Report Section 5.1.1)
 235
 236         NameEnv AvailInfo)      -- Used to figure out all other export specifiers.
 237                                 -- Maps a Name to the AvailInfo that contains it
 238
 239
 240 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 241                         | AvailTC name   -- The name of the type or class
 242                                   [name] -- The available pieces of type/class.
 243                                          -- NB: If the type or class is itself
 244                                          -- to be in scope, it must be in this list.
 245                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 246
 247 type AvailInfo    = GenAvailInfo Name
 248 type RdrAvailInfo = GenAvailInfo OccName
 249 \end{code}
 250
 251 %===================================================
 252 \subsubsection{         INTERFACE FILE STUFF}
 253 %===================================================
 254
 255 \begin{code}
 256 type ExportItem          = (ModuleName, [RdrAvailInfo])
 257 type VersionInfo name    = [ImportVersion name]
 258
 259 type ImportVersion name  = (ModuleName, Version, WhetherHasOrphans, WhatsImported name)
 260
 261 type WhetherHasOrphans   = Bool
 262         -- An "orphan" is
 263         --      * an instance decl in a module other than the defn module for
 264         --              one of the tycons or classes in the instance head
 265         --      * a transformation rule in a module other than the one defining
 266         --              the function in the head of the rule.
 267
 268 data WhatsImported name  = Everything
 269                          | Specifically [LocalVersion name] -- List guaranteed non-empty
 270
 271     -- ("M", hif, ver, Everything) means there was a "module M" in
 272     -- this module's export list, so we just have to go by M's version, "ver",
 273     -- not the list of LocalVersions.
 274
 275
 276 type LocalVersion name   = (name, Version)
 277
 278 data ParsedIface
 279   = ParsedIface {
 280       pi_mod       :: Version,                          -- Module version number
 281       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 282       pi_usages    :: [ImportVersion OccName],          -- Usages
 283       pi_exports   :: [ExportItem],                     -- Exports
 284       pi_decls     :: [(Version, RdrNameHsDecl)],       -- Local definitions
 285       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 286       pi_rules     :: [RdrNameRuleDecl],                -- Rules
 287       pi_deprecs   :: [(Maybe FAST_STRING, FAST_STRING)] -- Deprecations, the type is currently only a hack
 288     }
 289
 290 data InterfaceDetails
 291    = InterfaceDetails WhetherHasOrphans
 292                       (VersionInfo Name)   -- Version information for what this module imports
 293                       ExportEnv            -- What modules this one depends on
 294                       [Deprecation Name]
 295
 296
 297 -- needed by Main to fish out the fixities assoc list.
 298 getIfaceFixities :: InterfaceDetails -> Fixities
 299 getIfaceFixities (InterfaceDetails _ _ (ExportEnv _ fs _) _) = fs
 300
 301
 302 type RdrNamePragma = ()                         -- Fudge for now
 303 -------------------
 304
 305 data Ifaces = Ifaces {
 306                 iImpModInfo :: ImportedModuleInfo,
 307                                 -- Modules this one depends on: that is, the union
 308                                 -- of the modules its *direct* imports depend on.
 309                                 -- NB: The direct imports have .hi files that enumerate *all* the
 310                                 -- dependencies (direct or not) of the imported module.
 311
 312                 iDecls :: DeclsMap,     -- A single, global map of Names to decls
 313
 314                 iFixes :: FixityEnv,    -- A single, global map of Names to fixities
 315                                         -- See comments with RnIfaces.lookupFixity
 316
 317                 iSlurp :: NameSet,
 318                 -- All the names (whether "big" or "small", whether wired-in or not,
 319                 -- whether locally defined or not) that have been slurped in so far.
 320
 321                 iVSlurp :: [(Name,Version)],
 322                 -- All the (a) non-wired-in (b) "big" (c) non-locally-defined
 323                 -- names that have been slurped in so far, with their versions.
 324                 -- This is used to generate the "usage" information for this module.
 325                 -- Subset of the previous field.
 326
 327                 iInsts :: Bag GatedDecl,
 328                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 329                 -- slurp an instance decl so that we don't slurp the same one twice.
 330                 -- Each is 'gated' by the names that must be available before
 331                 -- this instance decl is needed.
 332
 333                 iRules :: Bag GatedDecl
 334                         -- Ditto transformation rules
 335         }
 336
 337 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 338
 339 type ImportedModuleInfo
 340      = FiniteMap ModuleName (Version, Bool, Maybe (Module, Bool, Avails))
 341                 -- Suppose the domain element is module 'A'
 342                 --
 343                 -- The first Bool is True if A contains
 344                 -- 'orphan' rules or instance decls
 345
 346                 -- The second Bool is true if the interface file actually
 347                 -- read was an .hi-boot file
 348
 349                 -- Nothing => A's interface not yet read, but this module has
 350                 --            imported a module, B, that itself depends on A
 351                 --
 352                 -- Just xx => A's interface has been read.  The Module in
 353                 --              the Just has the correct Dll flag
 354
 355                 -- This set is used to decide whether to look for
 356                 -- A.hi or A.hi-boot when importing A.f.
 357                 -- Basically, we look for A.hi if A is in the map, and A.hi-boot
 358                 -- otherwise
 359
 360 type DeclsMap = NameEnv (Version, AvailInfo, Bool, (Module, RdrNameHsDecl))
 361                 -- A DeclsMap contains a binding for each Name in the declaration
 362                 -- including the constructors of a type decl etc.
 363                 -- The Bool is True just for the 'main' Name.
 364 \end{code}
 365
 366
 367 %************************************************************************
 368 %*                                                                      *
 369 \subsection{Main monad code}
 370 %*                                                                      *
 371 %************************************************************************
 372
 373 \begin{code}
 374 initRn :: ModuleName -> UniqSupply -> SearchPath -> SrcLoc
 375        -> RnMG r
 376        -> IO (r, Bag ErrMsg, Bag WarnMsg)
 377
 378 initRn mod us dirs loc do_rn = do
 379   himaps    <- mkModuleHiMaps dirs
 380   names_var <- newIORef (us, emptyFM, builtins, emptyFM)
 381   errs_var  <- newIORef (emptyBag,emptyBag)
 382   iface_var <- newIORef emptyIfaces
 383   let
 384         rn_down = RnDown { rn_loc = loc, rn_ns = names_var,
 385                            rn_errs = errs_var,
 386                            rn_hi_maps = himaps,
 387                            rn_ifaces = iface_var,
 388                            rn_mod = mod }
 389
 390         -- do the business
 391   res <- do_rn rn_down ()
 392
 393         -- grab errors and return
 394   (warns, errs) <- readIORef errs_var
 395
 396   return (res, errs, warns)
 397
 398
 399 initRnMS :: GlobalRdrEnv -> FixityEnv -> RnMode -> RnMS r -> RnM d r
 400 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 401   = let
 402         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 403                          rn_fixenv = fixity_env, rn_mode = mode }
 404     in
 405     thing_inside rn_down s_down
 406
 407 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 408 initIfaceRnMS mod thing_inside
 409   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 410     setModuleRn (moduleName mod) thing_inside
 411
 412 emptyIfaces :: Ifaces
 413 emptyIfaces = Ifaces { iImpModInfo = emptyFM,
 414                        iDecls = emptyNameEnv,
 415                        iFixes = emptyNameEnv,
 416                        iSlurp = unitNameSet (mkUnboundName dummyRdrVarName),
 417                         -- Pretend that the dummy unbound name has already been
 418                         -- slurped.  This is what's returned for an out-of-scope name,
 419                         -- and we don't want thereby to try to suck it in!
 420                        iVSlurp = [],
 421                        iInsts = emptyBag,
 422                        iRules = emptyBag
 423               }
 424
 425 -- mkUnboundName makes a place-holder Name; it shouldn't be looked at except possibly
 426 -- during compiler debugging.
 427 mkUnboundName :: RdrName -> Name
 428 mkUnboundName rdr_name = mkLocalName unboundKey (rdrNameOcc rdr_name) noSrcLoc
 429
 430 isUnboundName :: Name -> Bool
 431 isUnboundName name = getUnique name == unboundKey
 432
 433 builtins :: FiniteMap (ModuleName,OccName) Name
 434 builtins =
 435    bagToFM (
 436    mapBag (\ name ->  ((moduleName (nameModule name), nameOccName name), name))
 437           builtinNames)
 438 \end{code}
 439
 440 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 441 that is, not as part of the main renamer.
 442 Sole examples: derived definitions,
 443 which are only generated in the type checker.
 444
 445 The @RnNameSupply@ includes a @UniqueSupply@, so if you call it more than
 446 once you must either split it, or install a fresh unique supply.
 447
 448 \begin{code}
 449 renameSourceCode :: ModuleName
 450                  -> RnNameSupply
 451                  -> RnMS r
 452                  -> r
 453
 454 renameSourceCode mod_name name_supply m
 455   = unsafePerformIO (
 456         -- It's not really unsafe!  When renaming source code we
 457         -- only do any I/O if we need to read in a fixity declaration;
 458         -- and that doesn't happen in pragmas etc
 459
 460         mkModuleHiMaps (mkSearchPath opt_HiMap) >>= \ himaps ->
 461         newIORef name_supply            >>= \ names_var ->
 462         newIORef (emptyBag,emptyBag)    >>= \ errs_var ->
 463         let
 464             rn_down = RnDown { rn_loc = mkGeneratedSrcLoc, rn_ns = names_var,
 465                                rn_errs = errs_var, rn_hi_maps = himaps,
 466                                rn_mod = mod_name,
 467                                rn_ifaces = panic "rnameSourceCode: rn_ifaces"  -- Not required
 468                              }
 469             s_down = SDown { rn_mode = InterfaceMode,
 470                                -- So that we can refer to PrelBase.True etc
 471                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 472                              rn_fixenv = emptyNameEnv }
 473         in
 474         m rn_down s_down                        >>= \ result ->
 475
 476         readIORef errs_var                      >>= \ (warns,errs) ->
 477
 478         (if not (isEmptyBag errs) then
 479                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 480 #ifdef DEBUG
 481          else if not (isEmptyBag warns) then
 482                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 483 #endif
 484          else
 485                 id) $
 486
 487         return result
 488     )
 489   where
 490     display errs = pprBagOfErrors errs
 491
 492 {-# INLINE thenRn #-}
 493 {-# INLINE thenRn_ #-}
 494 {-# INLINE returnRn #-}
 495 {-# INLINE andRn #-}
 496
 497 returnRn :: a -> RnM d a
 498 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 499 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 500 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 501 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 502 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 503 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 504 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 505 sequenceRn :: [RnM d a] -> RnM d [a]
 506 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 507 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 508 fixRn    :: (a -> RnM d a) -> RnM d a
 509
 510 returnRn v gdown ldown  = return v
 511 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 512 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 513 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 514 andRn combiner m1 m2 gdown ldown
 515   = m1 gdown ldown >>= \ res1 ->
 516     m2 gdown ldown >>= \ res2 ->
 517     return (combiner res1 res2)
 518
 519 sequenceRn []     = returnRn []
 520 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 521                      sequenceRn ms      `thenRn` \ rs ->
 522                      returnRn (r:rs)
 523
 524 mapRn f []     = returnRn []
 525 mapRn f (x:xs)
 526   = f x         `thenRn` \ r ->
 527     mapRn f xs  `thenRn` \ rs ->
 528     returnRn (r:rs)
 529
 530 mapRn_ f []     = returnRn ()
 531 mapRn_ f (x:xs) =
 532     f x         `thenRn_`
 533     mapRn_ f xs
 534
 535 foldlRn k z [] = returnRn z
 536 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 537                      foldlRn k z' xs
 538
 539 mapAndUnzipRn f [] = returnRn ([],[])
 540 mapAndUnzipRn f (x:xs)
 541   = f x                 `thenRn` \ (r1,  r2)  ->
 542     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 543     returnRn (r1:rs1, r2:rs2)
 544
 545 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 546 mapAndUnzip3Rn f (x:xs)
 547   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 548     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 549     returnRn (r1:rs1, r2:rs2, r3:rs3)
 550
 551 mapMaybeRn f []     = returnRn []
 552 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 553                       mapMaybeRn f xs   `thenRn` \ rs ->
 554                       case maybe_r of
 555                         Nothing -> returnRn rs
 556                         Just r  -> returnRn (r:rs)
 557
 558 flatMapRn f []     = returnRn []
 559 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 560                      flatMapRn f xs     `thenRn` \ rs ->
 561                      returnRn (r ++ rs)
 562 \end{code}
 563
 564
 565
 566 %************************************************************************
 567 %*                                                                      *
 568 \subsection{Boring plumbing for common part}
 569 %*                                                                      *
 570 %************************************************************************
 571
 572
 573 %================
 574 \subsubsection{  Errors and warnings}
 575 %=====================
 576
 577 \begin{code}
 578 failWithRn :: a -> Message -> RnM d a
 579 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 580   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 581     writeIORef errs_var (warns, errs `snocBag` err)             >>
 582     return res
 583   where
 584     err = addShortErrLocLine loc msg
 585
 586 warnWithRn :: a -> Message -> RnM d a
 587 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 588   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 589     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 590     return res
 591   where
 592     warn = addShortWarnLocLine loc msg
 593
 594 addErrRn :: Message -> RnM d ()
 595 addErrRn err = failWithRn () err
 596
 597 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 598 checkRn False err = addErrRn err
 599 checkRn True  err = returnRn ()
 600
 601 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 602 warnCheckRn False err = addWarnRn err
 603 warnCheckRn True  err = returnRn ()
 604
 605 addWarnRn :: Message -> RnM d ()
 606 addWarnRn warn = warnWithRn () warn
 607
 608 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 609 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 610   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 611     return (isEmptyBag errs)
 612 \end{code}
 613
 614
 615 %================
 616 \subsubsection{  Source location}
 617 %=====================
 618
 619 \begin{code}
 620 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 621 pushSrcLocRn loc' m down l_down
 622   = m (down {rn_loc = loc'}) l_down
 623
 624 getSrcLocRn :: RnM d SrcLoc
 625 getSrcLocRn down l_down
 626   = return (rn_loc down)
 627 \end{code}
 628
 629 %================
 630 \subsubsection{  Name supply}
 631 %=====================
 632
 633 \begin{code}
 634 getNameSupplyRn :: RnM d RnNameSupply
 635 getNameSupplyRn rn_down l_down
 636   = readIORef (rn_ns rn_down)
 637
 638 setNameSupplyRn :: RnNameSupply -> RnM d ()
 639 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 640   = writeIORef names_var names'
 641
 642 -- See comments with RnNameSupply above.
 643 newInstUniq :: String -> RnM d Int
 644 newInstUniq key (RnDown {rn_ns = names_var}) l_down
 645   = readIORef names_var                         >>= \ (us, mapInst, cache, ipcache) ->
 646     let
 647         uniq = case lookupFM mapInst key of
 648                    Just x  -> x+1
 649                    Nothing -> 0
 650         mapInst' = addToFM mapInst key uniq
 651     in
 652     writeIORef names_var (us, mapInst', cache, ipcache) >>
 653     return uniq
 654
 655 getUniqRn :: RnM d Unique
 656 getUniqRn (RnDown {rn_ns = names_var}) l_down
 657  = readIORef names_var >>= \ (us, mapInst, cache, ipcache) ->
 658    let
 659      (us1,us') = splitUniqSupply us
 660    in
 661    writeIORef names_var (us', mapInst, cache, ipcache)  >>
 662    return (uniqFromSupply us1)
 663 \end{code}
 664
 665 %================
 666 \subsubsection{  Module}
 667 %=====================
 668
 669 \begin{code}
 670 getModuleRn :: RnM d ModuleName
 671 getModuleRn (RnDown {rn_mod = mod_name}) l_down
 672   = return mod_name
 673
 674 setModuleRn :: ModuleName -> RnM d a -> RnM d a
 675 setModuleRn new_mod enclosed_thing rn_down l_down
 676   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 677 \end{code}
 678
 679
 680 %************************************************************************
 681 %*                                                                      *
 682 \subsection{Plumbing for rename-source part}
 683 %*                                                                      *
 684 %************************************************************************
 685
 686 %================
 687 \subsubsection{  RnEnv}
 688 %=====================
 689
 690 \begin{code}
 691 getNameEnvs :: RnMS (GlobalRdrEnv, LocalRdrEnv)
 692 getNameEnvs rn_down (SDown {rn_genv = global_env, rn_lenv = local_env})
 693   = return (global_env, local_env)
 694
 695 getLocalNameEnv :: RnMS LocalRdrEnv
 696 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 697   = return local_env
 698
 699 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 700 setLocalNameEnv local_env' m rn_down l_down
 701   = m rn_down (l_down {rn_lenv = local_env'})
 702
 703 getFixityEnv :: RnMS FixityEnv
 704 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 705   = return fixity_env
 706
 707 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 708 extendFixityEnv fixes enclosed_scope
 709                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 710   = let
 711         new_fixity_env = extendNameEnv fixity_env fixes
 712     in
 713     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 714 \end{code}
 715
 716 %================
 717 \subsubsection{  Mode}
 718 %=====================
 719
 720 \begin{code}
 721 getModeRn :: RnMS RnMode
 722 getModeRn rn_down (SDown {rn_mode = mode})
 723   = return mode
 724
 725 setModeRn :: RnMode -> RnMS a -> RnMS a
 726 setModeRn new_mode thing_inside rn_down l_down
 727   = thing_inside rn_down (l_down {rn_mode = new_mode})
 728 \end{code}
 729
 730
 731 %************************************************************************
 732 %*                                                                      *
 733 \subsection{Plumbing for rename-globals part}
 734 %*                                                                      *
 735 %************************************************************************
 736
 737 \begin{code}
 738 getIfacesRn :: RnM d Ifaces
 739 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 740   = readIORef iface_var
 741
 742 setIfacesRn :: Ifaces -> RnM d ()
 743 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 744   = writeIORef iface_var ifaces
 745
 746 getHiMaps :: RnM d (ModuleHiMap, ModuleHiMap)
 747 getHiMaps (RnDown {rn_hi_maps = himaps}) _
 748   = return himaps
 749 \end{code}
 750
 751 \begin{code}
 752 lookupModuleRn :: ModuleName -> RnM d Module
 753 lookupModuleRn x =
 754   getHiMaps `thenRn` \ (himap, _) ->
 755   case lookupFM himap x of
 756     Nothing    -> returnRn (mkVanillaModule x)
 757     Just (_,x) -> returnRn x
 758
 759 \end{code}