ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9         Module,
  10         FiniteMap,
  11         Bag,
  12         Name,
  13         RdrNameHsDecl,
  14         RdrNameInstDecl,
  15         Version,
  16         NameSet,
  17         OccName,
  18         Fixity
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 #if defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  24 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  25 #else
  26 import IOBase           ( fixIO )
  27 #endif
  28 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  29
  30 import HsSyn
  31 import RdrHsSyn
  32 import RnHsSyn          ( RenamedFixitySig )
  33 import BasicTypes       ( Version )
  34 import SrcLoc           ( noSrcLoc )
  35 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  36                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  37                         )
  38 import Name             ( Name, OccName, NamedThing(..),
  39                           isLocallyDefinedName, nameModule, nameOccName,
  40                           decode, mkLocalName
  41                         )
  42 import Module           ( Module, ModuleName, ModuleHiMap, SearchPath, WhereFrom,
  43                           mkModuleHiMaps, moduleName
  44                         )
  45 import NameSet
  46 import RdrName          ( RdrName, dummyRdrVarName, rdrNameOcc )
  47 import CmdLineOpts      ( opt_D_dump_rn_trace, opt_IgnoreIfacePragmas )
  48 import PrelInfo         ( builtinNames )
  49 import TysWiredIn       ( boolTyCon )
  50 import SrcLoc           ( SrcLoc, mkGeneratedSrcLoc )
  51 import Unique           ( Unique, getUnique, unboundKey )
  52 import UniqFM           ( UniqFM )
  53 import FiniteMap        ( FiniteMap, emptyFM, bagToFM, lookupFM, addToFM, addListToFM,
  54                           addListToFM_C, addToFM_C, eltsFM, fmToList
  55                         )
  56 import Bag              ( Bag, mapBag, emptyBag, isEmptyBag, snocBag )
  57 import Maybes           ( mapMaybe )
  58 import UniqSet
  59 import UniqFM
  60 import UniqSupply
  61 import Util
  62 import Outputable
  63
  64 infixr 9 `thenRn`, `thenRn_`
  65 \end{code}
  66
  67
  68 %************************************************************************
  69 %*                                                                      *
  70 \subsection{Somewhat magical interface to other monads}
  71 %*                                                                      *
  72 %************************************************************************
  73
  74 \begin{code}
  75 ioToRnM :: IO r -> RnM d (Either IOError r)
  76 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  77                             `catch`
  78                             (\ err -> return (Left err))
  79
  80 traceRn :: SDoc -> RnM d ()
  81 traceRn msg | opt_D_dump_rn_trace = putDocRn msg
  82             | otherwise           = returnRn ()
  83
  84 putDocRn :: SDoc -> RnM d ()
  85 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
  86                returnRn ()
  87 \end{code}
  88
  89
  90 %************************************************************************
  91 %*                                                                      *
  92 \subsection{Data types}
  93 %*                                                                      *
  94 %************************************************************************
  95
  96 %===================================================
  97 \subsubsection{         MONAD TYPES}
  98 %===================================================
  99
 100 \begin{code}
 101 type RnM d r = RnDown -> d -> IO r
 102 type RnMS r  = RnM SDown r              -- Renaming source
 103 type RnMG r  = RnM ()    r              -- Getting global names etc
 104
 105         -- Common part
 106 data RnDown = RnDown {
 107                   rn_mod     :: ModuleName,
 108                   rn_loc     :: SrcLoc,
 109                   rn_ns      :: IORef RnNameSupply,
 110                   rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 111                   rn_ifaces  :: IORef Ifaces,
 112                   rn_hi_maps :: (ModuleHiMap,   -- for .hi files
 113                                  ModuleHiMap)   -- for .hi-boot files
 114                 }
 115
 116         -- For renaming source code
 117 data SDown = SDown {
 118                   rn_mode :: RnMode,
 119
 120                   rn_genv :: GlobalRdrEnv,
 121                         --   Global envt; the fixity component gets extended
 122                         --   with local fixity decls
 123
 124                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 125                         --   Does *not* include global name envt; may shadow it
 126                         --   Includes both ordinary variables and type variables;
 127                         --   they are kept distinct because tyvar have a different
 128                         --   occurrence contructor (Name.TvOcc)
 129                         -- We still need the unsullied global name env so that
 130                         --   we can look up record field names
 131
 132                   rn_fixenv :: FixityEnv        -- Local fixities
 133                                                 -- The global ones are held in the
 134                                                 -- rn_ifaces field
 135                 }
 136
 137 data RnMode     = SourceMode                    -- Renaming source code
 138                 | InterfaceMode                 -- Renaming interface declarations.
 139 \end{code}
 140
 141 %===================================================
 142 \subsubsection{         ENVIRONMENTS}
 143 %===================================================
 144
 145 \begin{code}
 146 --------------------------------
 147 type RdrNameEnv a = FiniteMap RdrName a
 148 type GlobalRdrEnv = RdrNameEnv [Name]   -- The list is because there may be name clashes
 149                                         -- These only get reported on lookup,
 150                                         -- not on construction
 151 type LocalRdrEnv  = RdrNameEnv Name
 152
 153 emptyRdrEnv  :: RdrNameEnv a
 154 lookupRdrEnv :: RdrNameEnv a -> RdrName -> Maybe a
 155 addListToRdrEnv :: RdrNameEnv a -> [(RdrName,a)] -> RdrNameEnv a
 156 extendRdrEnv    :: RdrNameEnv a -> RdrName -> a -> RdrNameEnv a
 157
 158 emptyRdrEnv  = emptyFM
 159 lookupRdrEnv = lookupFM
 160 addListToRdrEnv = addListToFM
 161 rdrEnvElts      = eltsFM
 162 extendRdrEnv    = addToFM
 163 rdrEnvToList    = fmToList
 164
 165 --------------------------------
 166 type NameEnv a = UniqFM a       -- Domain is Name
 167
 168 emptyNameEnv   :: NameEnv a
 169 nameEnvElts    :: NameEnv a -> [a]
 170 addToNameEnv_C :: (a->a->a) -> NameEnv a -> Name -> a -> NameEnv a
 171 addToNameEnv   :: NameEnv a -> Name -> a -> NameEnv a
 172 plusNameEnv    :: NameEnv a -> NameEnv a -> NameEnv a
 173 extendNameEnv  :: NameEnv a -> [(Name,a)] -> NameEnv a
 174 lookupNameEnv  :: NameEnv a -> Name -> Maybe a
 175 delFromNameEnv :: NameEnv a -> Name -> NameEnv a
 176 elemNameEnv    :: Name -> NameEnv a -> Bool
 177
 178 emptyNameEnv   = emptyUFM
 179 nameEnvElts    = eltsUFM
 180 addToNameEnv_C = addToUFM_C
 181 addToNameEnv   = addToUFM
 182 plusNameEnv    = plusUFM
 183 extendNameEnv  = addListToUFM
 184 lookupNameEnv  = lookupUFM
 185 delFromNameEnv = delFromUFM
 186 elemNameEnv    = elemUFM
 187
 188 --------------------------------
 189 type FixityEnv = NameEnv RenamedFixitySig
 190         -- We keep the whole fixity sig so that we
 191         -- can report line-number info when there is a duplicate
 192         -- fixity declaration
 193 \end{code}
 194
 195 \begin{code}
 196 --------------------------------
 197 type RnNameSupply
 198  = ( UniqSupply
 199
 200    , FiniteMap String Int
 201         -- This is used as a name supply for dictionary functions
 202         -- From the inst decl we derive a string, usually by glomming together
 203         -- the class and tycon name -- but it doesn't matter exactly how;
 204         -- this map then gives a unique int for each inst decl with that
 205         -- string.  (In Haskell 98 there can only be one,
 206         -- but not so in more extended versions; also class CC type T
 207         -- and class C type TT might both give the string CCT
 208         --
 209         -- We could just use one Int for all the instance decls, but this
 210         -- way the uniques change less when you add an instance decl,
 211         -- hence less recompilation
 212
 213    , FiniteMap (ModuleName, OccName) Name
 214         -- Ensures that one (module,occname) pair gets one unique
 215    )
 216
 217
 218 --------------------------------
 219 data ExportEnv    = ExportEnv Avails Fixities
 220 type Avails       = [AvailInfo]
 221 type Fixities     = [(Name, Fixity)]
 222
 223 type ExportAvails = (FiniteMap ModuleName Avails,
 224         -- Used to figure out "module M" export specifiers
 225         -- Includes avails only from *unqualified* imports
 226         -- (see 1.4 Report Section 5.1.1)
 227
 228         NameEnv AvailInfo)      -- Used to figure out all other export specifiers.
 229                                 -- Maps a Name to the AvailInfo that contains it
 230
 231
 232 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 233                         | AvailTC name   -- The name of the type or class
 234                                   [name] -- The available pieces of type/class.
 235                                          -- NB: If the type or class is itself
 236                                          -- to be in scope, it must be in this list.
 237                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 238
 239 type AvailInfo    = GenAvailInfo Name
 240 type RdrAvailInfo = GenAvailInfo OccName
 241 \end{code}
 242
 243 %===================================================
 244 \subsubsection{         INTERFACE FILE STUFF}
 245 %===================================================
 246
 247 \begin{code}
 248 type ExportItem          = (ModuleName, [RdrAvailInfo])
 249 type VersionInfo name    = [ImportVersion name]
 250
 251 type ImportVersion name  = (ModuleName, Version, WhetherHasOrphans, WhatsImported name)
 252
 253 type WhetherHasOrphans   = Bool
 254         -- An "orphan" is
 255         --      * an instance decl in a module other than the defn module for
 256         --              one of the tycons or classes in the instance head
 257         --      * a transformation rule in a module other than the one defining
 258         --              the function in the head of the rule.
 259
 260 data WhatsImported name  = Everything
 261                          | Specifically [LocalVersion name] -- List guaranteed non-empty
 262
 263     -- ("M", hif, ver, Everything) means there was a "module M" in
 264     -- this module's export list, so we just have to go by M's version, "ver",
 265     -- not the list of LocalVersions.
 266
 267
 268 type LocalVersion name   = (name, Version)
 269
 270 data ParsedIface
 271   = ParsedIface {
 272       pi_mod       :: Version,                          -- Module version number
 273       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 274       pi_usages    :: [ImportVersion OccName],          -- Usages
 275       pi_exports   :: [ExportItem],                     -- Exports
 276       pi_decls     :: [(Version, RdrNameHsDecl)],       -- Local definitions
 277       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 278       pi_rules     :: [RdrNameRuleDecl]                 -- Rules
 279     }
 280
 281 type InterfaceDetails = (WhetherHasOrphans,
 282                          VersionInfo Name, -- Version information for what this module imports
 283                          ExportEnv)        -- What modules this one depends on
 284
 285
 286 -- needed by Main to fish out the fixities assoc list.
 287 getIfaceFixities :: InterfaceDetails -> Fixities
 288 getIfaceFixities (_, _, ExportEnv _ fs) = fs
 289
 290
 291 type RdrNamePragma = ()                         -- Fudge for now
 292 -------------------
 293
 294 data Ifaces = Ifaces {
 295                 iImpModInfo :: ImportedModuleInfo,
 296                                 -- Modules this one depends on: that is, the union
 297                                 -- of the modules its direct imports depend on.
 298
 299                 iDecls :: DeclsMap,     -- A single, global map of Names to decls
 300
 301                 iFixes :: FixityEnv,    -- A single, global map of Names to fixities
 302
 303                 iSlurp :: NameSet,
 304                 -- All the names (whether "big" or "small", whether wired-in or not,
 305                 -- whether locally defined or not) that have been slurped in so far.
 306
 307                 iVSlurp :: [(Name,Version)],
 308                 -- All the (a) non-wired-in (b) "big" (c) non-locally-defined
 309                 -- names that have been slurped in so far, with their versions.
 310                 -- This is used to generate the "usage" information for this module.
 311                 -- Subset of the previous field.
 312
 313                 iInsts :: Bag GatedDecl,
 314                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 315                 -- slurp an instance decl so that we don't slurp the same one twice.
 316                 -- Each is 'gated' by the names that must be available before
 317                 -- this instance decl is needed.
 318
 319                 iRules :: Bag GatedDecl
 320                         -- Ditto transformation rules
 321         }
 322
 323 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 324
 325 type ImportedModuleInfo
 326      = FiniteMap ModuleName (Version, Bool, Maybe (Module, Bool, Avails))
 327                 -- Suppose the domain element is module 'A'
 328                 --
 329                 -- The first Bool is True if A contains
 330                 -- 'orphan' rules or instance decls
 331
 332                 -- The second Bool is true if the interface file actually
 333                 -- read was an .hi-boot file
 334
 335                 -- Nothing => A's interface not yet read, but this module has
 336                 --            imported a module, B, that itself depends on A
 337                 --
 338                 -- Just xx => A's interface has been read.  The Module in
 339                 --              the Just has the correct Dll flag
 340
 341                 -- This set is used to decide whether to look for
 342                 -- A.hi or A.hi-boot when importing A.f.
 343                 -- Basically, we look for A.hi if A is in the map, and A.hi-boot
 344                 -- otherwise
 345
 346 type DeclsMap = NameEnv (Version, AvailInfo, Bool, (Module, RdrNameHsDecl))
 347                 -- A DeclsMap contains a binding for each Name in the declaration
 348                 -- including the constructors of a type decl etc.
 349                 -- The Bool is True just for the 'main' Name.
 350 \end{code}
 351
 352
 353 %************************************************************************
 354 %*                                                                      *
 355 \subsection{Main monad code}
 356 %*                                                                      *
 357 %************************************************************************
 358
 359 \begin{code}
 360 initRn :: ModuleName -> UniqSupply -> SearchPath -> SrcLoc
 361        -> RnMG r
 362        -> IO (r, Bag ErrMsg, Bag WarnMsg)
 363
 364 initRn mod us dirs loc do_rn = do
 365   himaps    <- mkModuleHiMaps dirs
 366   names_var <- newIORef (us, emptyFM, builtins)
 367   errs_var  <- newIORef (emptyBag,emptyBag)
 368   iface_var <- newIORef emptyIfaces
 369   let
 370         rn_down = RnDown { rn_loc = loc, rn_ns = names_var,
 371                            rn_errs = errs_var,
 372                            rn_hi_maps = himaps,
 373                            rn_ifaces = iface_var,
 374                            rn_mod = mod }
 375
 376         -- do the business
 377   res <- do_rn rn_down ()
 378
 379         -- grab errors and return
 380   (warns, errs) <- readIORef errs_var
 381
 382   return (res, errs, warns)
 383
 384
 385 initRnMS :: GlobalRdrEnv -> FixityEnv -> RnMode -> RnMS r -> RnM d r
 386 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 387   = let
 388         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 389                          rn_fixenv = fixity_env, rn_mode = mode }
 390     in
 391     thing_inside rn_down s_down
 392
 393 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 394 initIfaceRnMS mod thing_inside
 395   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 396     setModuleRn (moduleName mod) thing_inside
 397
 398 emptyIfaces :: Ifaces
 399 emptyIfaces = Ifaces { iImpModInfo = emptyFM,
 400                        iDecls = emptyNameEnv,
 401                        iFixes = emptyNameEnv,
 402                        iSlurp = unitNameSet (mkUnboundName dummyRdrVarName),
 403                         -- Pretend that the dummy unbound name has already been
 404                         -- slurped.  This is what's returned for an out-of-scope name,
 405                         -- and we don't want thereby to try to suck it in!
 406                        iVSlurp = [],
 407                        iInsts = emptyBag,
 408                        iRules = emptyBag
 409               }
 410
 411 -- mkUnboundName makes a place-holder Name; it shouldn't be looked at except possibly
 412 -- during compiler debugging.
 413 mkUnboundName :: RdrName -> Name
 414 mkUnboundName rdr_name = mkLocalName unboundKey (rdrNameOcc rdr_name) noSrcLoc
 415
 416 isUnboundName :: Name -> Bool
 417 isUnboundName name = getUnique name == unboundKey
 418
 419 builtins :: FiniteMap (ModuleName,OccName) Name
 420 builtins =
 421    bagToFM (
 422    mapBag (\ name ->  ((moduleName (nameModule name), nameOccName name), name))
 423           builtinNames)
 424 \end{code}
 425
 426 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 427 that is, not as part of the main renamer.
 428 Sole examples: derived definitions,
 429 which are only generated in the type checker.
 430
 431 The @RnNameSupply@ includes a @UniqueSupply@, so if you call it more than
 432 once you must either split it, or install a fresh unique supply.
 433
 434 \begin{code}
 435 renameSourceCode :: ModuleName
 436                  -> RnNameSupply
 437                  -> RnMS r
 438                  -> r
 439
 440 renameSourceCode mod_name name_supply m
 441   = unsafePerformIO (
 442         -- It's not really unsafe!  When renaming source code we
 443         -- only do any I/O if we need to read in a fixity declaration;
 444         -- and that doesn't happen in pragmas etc
 445
 446         newIORef name_supply            >>= \ names_var ->
 447         newIORef (emptyBag,emptyBag)    >>= \ errs_var ->
 448         let
 449             rn_down = RnDown { rn_loc = mkGeneratedSrcLoc, rn_ns = names_var,
 450                                rn_errs = errs_var,
 451                                rn_mod = mod_name }
 452             s_down = SDown { rn_mode = InterfaceMode,
 453                                -- So that we can refer to PrelBase.True etc
 454                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 455                              rn_fixenv = emptyNameEnv }
 456         in
 457         m rn_down s_down                        >>= \ result ->
 458
 459         readIORef errs_var                      >>= \ (warns,errs) ->
 460
 461         (if not (isEmptyBag errs) then
 462                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 463 #ifdef DEBUG
 464          else if not (isEmptyBag warns) then
 465                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 466 #endif
 467          else
 468                 id) $
 469
 470         return result
 471     )
 472   where
 473     display errs = pprBagOfErrors errs
 474
 475 {-# INLINE thenRn #-}
 476 {-# INLINE thenRn_ #-}
 477 {-# INLINE returnRn #-}
 478 {-# INLINE andRn #-}
 479
 480 returnRn :: a -> RnM d a
 481 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 482 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 483 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 484 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 485 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 486 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 487 sequenceRn :: [RnM d a] -> RnM d [a]
 488 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 489 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 490 fixRn    :: (a -> RnM d a) -> RnM d a
 491
 492 returnRn v gdown ldown  = return v
 493 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 494 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 495 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 496 andRn combiner m1 m2 gdown ldown
 497   = m1 gdown ldown >>= \ res1 ->
 498     m2 gdown ldown >>= \ res2 ->
 499     return (combiner res1 res2)
 500
 501 sequenceRn []     = returnRn []
 502 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 503                      sequenceRn ms      `thenRn` \ rs ->
 504                      returnRn (r:rs)
 505
 506 mapRn f []     = returnRn []
 507 mapRn f (x:xs)
 508   = f x         `thenRn` \ r ->
 509     mapRn f xs  `thenRn` \ rs ->
 510     returnRn (r:rs)
 511
 512 mapRn_ f []     = returnRn ()
 513 mapRn_ f (x:xs) =
 514     f x         `thenRn_`
 515     mapRn_ f xs
 516
 517 foldlRn k z [] = returnRn z
 518 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 519                      foldlRn k z' xs
 520
 521 mapAndUnzipRn f [] = returnRn ([],[])
 522 mapAndUnzipRn f (x:xs)
 523   = f x                 `thenRn` \ (r1,  r2)  ->
 524     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 525     returnRn (r1:rs1, r2:rs2)
 526
 527 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 528 mapAndUnzip3Rn f (x:xs)
 529   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 530     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 531     returnRn (r1:rs1, r2:rs2, r3:rs3)
 532
 533 mapMaybeRn f []     = returnRn []
 534 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 535                       mapMaybeRn f xs   `thenRn` \ rs ->
 536                       case maybe_r of
 537                         Nothing -> returnRn rs
 538                         Just r  -> returnRn (r:rs)
 539 \end{code}
 540
 541
 542
 543 %************************************************************************
 544 %*                                                                      *
 545 \subsection{Boring plumbing for common part}
 546 %*                                                                      *
 547 %************************************************************************
 548
 549
 550 %================
 551 \subsubsection{  Errors and warnings}
 552 %=====================
 553
 554 \begin{code}
 555 failWithRn :: a -> Message -> RnM d a
 556 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 557   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 558     writeIORef errs_var (warns, errs `snocBag` err)             >>
 559     return res
 560   where
 561     err = addShortErrLocLine loc msg
 562
 563 warnWithRn :: a -> Message -> RnM d a
 564 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 565   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 566     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 567     return res
 568   where
 569     warn = addShortWarnLocLine loc msg
 570
 571 addErrRn :: Message -> RnM d ()
 572 addErrRn err = failWithRn () err
 573
 574 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 575 checkRn False err = addErrRn err
 576 checkRn True  err = returnRn ()
 577
 578 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 579 warnCheckRn False err = addWarnRn err
 580 warnCheckRn True  err = returnRn ()
 581
 582 addWarnRn :: Message -> RnM d ()
 583 addWarnRn warn = warnWithRn () warn
 584
 585 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 586 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 587   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 588     return (isEmptyBag errs)
 589 \end{code}
 590
 591
 592 %================
 593 \subsubsection{  Source location}
 594 %=====================
 595
 596 \begin{code}
 597 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 598 pushSrcLocRn loc' m down l_down
 599   = m (down {rn_loc = loc'}) l_down
 600
 601 getSrcLocRn :: RnM d SrcLoc
 602 getSrcLocRn down l_down
 603   = return (rn_loc down)
 604 \end{code}
 605
 606 %================
 607 \subsubsection{  Name supply}
 608 %=====================
 609
 610 \begin{code}
 611 getNameSupplyRn :: RnM d RnNameSupply
 612 getNameSupplyRn rn_down l_down
 613   = readIORef (rn_ns rn_down)
 614
 615 setNameSupplyRn :: RnNameSupply -> RnM d ()
 616 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 617   = writeIORef names_var names'
 618
 619 -- See comments with RnNameSupply above.
 620 newInstUniq :: String -> RnM d Int
 621 newInstUniq key (RnDown {rn_ns = names_var}) l_down
 622   = readIORef names_var                         >>= \ (us, mapInst, cache) ->
 623     let
 624         uniq = case lookupFM mapInst key of
 625                    Just x  -> x+1
 626                    Nothing -> 0
 627         mapInst' = addToFM mapInst key uniq
 628     in
 629     writeIORef names_var (us, mapInst', cache)  >>
 630     return uniq
 631
 632 getUniqRn :: RnM d Unique
 633 getUniqRn (RnDown {rn_ns = names_var}) l_down
 634  = readIORef names_var >>= \ (us, mapInst, cache) ->
 635    let
 636      (us1,us') = splitUniqSupply us
 637    in
 638    writeIORef names_var (us', mapInst, cache)  >>
 639    return (uniqFromSupply us1)
 640 \end{code}
 641
 642 %================
 643 \subsubsection{  Module}
 644 %=====================
 645
 646 \begin{code}
 647 getModuleRn :: RnM d ModuleName
 648 getModuleRn (RnDown {rn_mod = mod_name}) l_down
 649   = return mod_name
 650
 651 setModuleRn :: ModuleName -> RnM d a -> RnM d a
 652 setModuleRn new_mod enclosed_thing rn_down l_down
 653   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 654 \end{code}
 655
 656
 657 %************************************************************************
 658 %*                                                                      *
 659 \subsection{Plumbing for rename-source part}
 660 %*                                                                      *
 661 %************************************************************************
 662
 663 %================
 664 \subsubsection{  RnEnv}
 665 %=====================
 666
 667 \begin{code}
 668 getNameEnvs :: RnMS (GlobalRdrEnv, LocalRdrEnv)
 669 getNameEnvs rn_down (SDown {rn_genv = global_env, rn_lenv = local_env})
 670   = return (global_env, local_env)
 671
 672 getLocalNameEnv :: RnMS LocalRdrEnv
 673 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 674   = return local_env
 675
 676 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 677 setLocalNameEnv local_env' m rn_down l_down
 678   = m rn_down (l_down {rn_lenv = local_env'})
 679
 680 getFixityEnv :: RnMS FixityEnv
 681 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 682   = return fixity_env
 683
 684 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 685 extendFixityEnv fixes enclosed_scope
 686                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 687   = let
 688         new_fixity_env = extendNameEnv fixity_env fixes
 689     in
 690     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 691 \end{code}
 692
 693 %================
 694 \subsubsection{  Mode}
 695 %=====================
 696
 697 \begin{code}
 698 getModeRn :: RnMS RnMode
 699 getModeRn rn_down (SDown {rn_mode = mode})
 700   = return mode
 701
 702 setModeRn :: RnMode -> RnMS a -> RnMS a
 703 setModeRn new_mode thing_inside rn_down l_down
 704   = thing_inside rn_down (l_down {rn_mode = new_mode})
 705 \end{code}
 706
 707
 708 %************************************************************************
 709 %*                                                                      *
 710 \subsection{Plumbing for rename-globals part}
 711 %*                                                                      *
 712 %************************************************************************
 713
 714 \begin{code}
 715 getIfacesRn :: RnM d Ifaces
 716 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 717   = readIORef iface_var
 718
 719 setIfacesRn :: Ifaces -> RnM d ()
 720 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 721   = writeIORef iface_var ifaces
 722
 723 getHiMaps :: RnM d (ModuleHiMap, ModuleHiMap)
 724 getHiMaps (RnDown {rn_hi_maps = himaps}) _
 725   = return himaps
 726 \end{code}