ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9         Module,
  10         FiniteMap,
  11         Bag,
  12         Name,
  13         RdrNameHsDecl,
  14         RdrNameInstDecl,
  15         Version,
  16         NameSet,
  17         OccName,
  18         Fixity
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  24 import IOExts           ( fixIO )
  25 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  26 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  27 #else
  28 import IOBase           ( fixIO )
  29 #endif
  30 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  31
  32 import HsSyn
  33 import RdrHsSyn
  34 import RnHsSyn          ( RenamedFixitySig, RenamedDeprecation )
  35 import BasicTypes       ( Version )
  36 import SrcLoc           ( noSrcLoc )
  37 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  38                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  39                         )
  40 import Name             ( Name, OccName, NamedThing(..),
  41                           isLocallyDefinedName, nameModule, nameOccName,
  42                           decode, mkLocalName
  43                         )
  44 import Module           ( Module, ModuleName, ModuleHiMap, SearchPath, WhereFrom,
  45                           mkModuleHiMaps, moduleName, mkVanillaModule, mkSearchPath
  46                         )
  47 import NameSet
  48 import RdrName          ( RdrName, dummyRdrVarName, rdrNameOcc )
  49 import CmdLineOpts      ( opt_D_dump_rn_trace, opt_HiMap )
  50 import PrelInfo         ( builtinNames )
  51 import TysWiredIn       ( boolTyCon )
  52 import SrcLoc           ( SrcLoc, mkGeneratedSrcLoc )
  53 import Unique           ( Unique, getUnique, unboundKey )
  54 import UniqFM           ( UniqFM )
  55 import FiniteMap        ( FiniteMap, emptyFM, bagToFM, lookupFM, addToFM, addListToFM,
  56                           addListToFM_C, addToFM_C, eltsFM, fmToList
  57                         )
  58 import Bag              ( Bag, mapBag, emptyBag, isEmptyBag, snocBag )
  59 import Maybes           ( mapMaybe )
  60 import UniqSet
  61 import UniqFM
  62 import UniqSupply
  63 import Util
  64 import Outputable
  65
  66 infixr 9 `thenRn`, `thenRn_`
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Somewhat magical interface to other monads}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 ioToRnM :: IO r -> RnM d (Either IOError r)
  78 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  79                             `catch`
  80                             (\ err -> return (Left err))
  81
  82 traceRn :: SDoc -> RnM d ()
  83 traceRn msg | opt_D_dump_rn_trace = putDocRn msg
  84             | otherwise           = returnRn ()
  85
  86 putDocRn :: SDoc -> RnM d ()
  87 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
  88                returnRn ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{Data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 %===================================================
  99 \subsubsection{         MONAD TYPES}
 100 %===================================================
 101
 102 \begin{code}
 103 type RnM d r = RnDown -> d -> IO r
 104 type RnMS r  = RnM SDown r              -- Renaming source
 105 type RnMG r  = RnM ()    r              -- Getting global names etc
 106
 107         -- Common part
 108 data RnDown = RnDown {
 109                   rn_mod     :: ModuleName,
 110                   rn_loc     :: SrcLoc,
 111                   rn_ns      :: IORef RnNameSupply,
 112                   rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 113                   rn_ifaces  :: IORef Ifaces,
 114                   rn_hi_maps :: (ModuleHiMap,   -- for .hi files
 115                                  ModuleHiMap)   -- for .hi-boot files
 116                 }
 117
 118         -- For renaming source code
 119 data SDown = SDown {
 120                   rn_mode :: RnMode,
 121
 122                   rn_genv :: GlobalRdrEnv,
 123                         --   Global envt; the fixity component gets extended
 124                         --   with local fixity decls
 125
 126                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 127                         --   Does *not* include global name envt; may shadow it
 128                         --   Includes both ordinary variables and type variables;
 129                         --   they are kept distinct because tyvar have a different
 130                         --   occurrence contructor (Name.TvOcc)
 131                         -- We still need the unsullied global name env so that
 132                         --   we can look up record field names
 133
 134                   rn_fixenv :: FixityEnv        -- Local fixities
 135                         -- The global fixities are held in the
 136                         -- rn_ifaces field.  Why?  See the comments
 137                         -- with RnIfaces.lookupFixity
 138                 }
 139
 140 data RnMode     = SourceMode                    -- Renaming source code
 141                 | InterfaceMode                 -- Renaming interface declarations.
 142 \end{code}
 143
 144 %===================================================
 145 \subsubsection{         ENVIRONMENTS}
 146 %===================================================
 147
 148 \begin{code}
 149 --------------------------------
 150 type RdrNameEnv a = FiniteMap RdrName a
 151 type GlobalRdrEnv = RdrNameEnv [Name]   -- The list is because there may be name clashes
 152                                         -- These only get reported on lookup,
 153                                         -- not on construction
 154 type LocalRdrEnv  = RdrNameEnv Name
 155
 156 emptyRdrEnv  :: RdrNameEnv a
 157 lookupRdrEnv :: RdrNameEnv a -> RdrName -> Maybe a
 158 addListToRdrEnv :: RdrNameEnv a -> [(RdrName,a)] -> RdrNameEnv a
 159 extendRdrEnv    :: RdrNameEnv a -> RdrName -> a -> RdrNameEnv a
 160
 161 emptyRdrEnv  = emptyFM
 162 lookupRdrEnv = lookupFM
 163 addListToRdrEnv = addListToFM
 164 rdrEnvElts      = eltsFM
 165 extendRdrEnv    = addToFM
 166 rdrEnvToList    = fmToList
 167
 168 --------------------------------
 169 type NameEnv a = UniqFM a       -- Domain is Name
 170
 171 emptyNameEnv   :: NameEnv a
 172 nameEnvElts    :: NameEnv a -> [a]
 173 addToNameEnv_C :: (a->a->a) -> NameEnv a -> Name -> a -> NameEnv a
 174 addToNameEnv   :: NameEnv a -> Name -> a -> NameEnv a
 175 plusNameEnv    :: NameEnv a -> NameEnv a -> NameEnv a
 176 extendNameEnv  :: NameEnv a -> [(Name,a)] -> NameEnv a
 177 lookupNameEnv  :: NameEnv a -> Name -> Maybe a
 178 delFromNameEnv :: NameEnv a -> Name -> NameEnv a
 179 elemNameEnv    :: Name -> NameEnv a -> Bool
 180
 181 emptyNameEnv   = emptyUFM
 182 nameEnvElts    = eltsUFM
 183 addToNameEnv_C = addToUFM_C
 184 addToNameEnv   = addToUFM
 185 plusNameEnv    = plusUFM
 186 extendNameEnv  = addListToUFM
 187 lookupNameEnv  = lookupUFM
 188 delFromNameEnv = delFromUFM
 189 elemNameEnv    = elemUFM
 190
 191 --------------------------------
 192 type FixityEnv = NameEnv RenamedFixitySig
 193         -- We keep the whole fixity sig so that we
 194         -- can report line-number info when there is a duplicate
 195         -- fixity declaration
 196
 197 --------------------------------
 198 type DeprecationEnv = NameEnv DeprecTxt
 199 \end{code}
 200
 201 \begin{code}
 202 --------------------------------
 203 type RnNameSupply
 204  = ( UniqSupply
 205
 206    , FiniteMap String Int
 207         -- This is used as a name supply for dictionary functions
 208         -- From the inst decl we derive a string, usually by glomming together
 209         -- the class and tycon name -- but it doesn't matter exactly how;
 210         -- this map then gives a unique int for each inst decl with that
 211         -- string.  (In Haskell 98 there can only be one,
 212         -- but not so in more extended versions; also class CC type T
 213         -- and class C type TT might both give the string CCT
 214         --
 215         -- We could just use one Int for all the instance decls, but this
 216         -- way the uniques change less when you add an instance decl,
 217         -- hence less recompilation
 218
 219    , FiniteMap (ModuleName, OccName) Name
 220         -- Ensures that one (module,occname) pair gets one unique
 221    , FiniteMap OccName Name
 222         -- Ensures that one implicit parameter name gets one unique
 223    )
 224
 225
 226 --------------------------------
 227 data ExportEnv    = ExportEnv Avails Fixities [ModuleName]
 228                         -- The list of modules is the modules exported
 229                         -- with 'module M' in the export list
 230
 231 type Avails       = [AvailInfo]
 232 type Fixities     = [(Name, Fixity)]
 233
 234 type ExportAvails = (FiniteMap ModuleName Avails,
 235         -- Used to figure out "module M" export specifiers
 236         -- Includes avails only from *unqualified* imports
 237         -- (see 1.4 Report Section 5.1.1)
 238
 239         NameEnv AvailInfo)      -- Used to figure out all other export specifiers.
 240                                 -- Maps a Name to the AvailInfo that contains it
 241
 242
 243 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 244                         | AvailTC name   -- The name of the type or class
 245                                   [name] -- The available pieces of type/class.
 246                                          -- NB: If the type or class is itself
 247                                          -- to be in scope, it must be in this list.
 248                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 249
 250 type AvailInfo    = GenAvailInfo Name
 251 type RdrAvailInfo = GenAvailInfo OccName
 252 \end{code}
 253
 254 %===================================================
 255 \subsubsection{         INTERFACE FILE STUFF}
 256 %===================================================
 257
 258 \begin{code}
 259 type ExportItem          = (ModuleName, [RdrAvailInfo])
 260 type VersionInfo name    = [ImportVersion name]
 261
 262 type ImportVersion name  = (ModuleName, Version, WhetherHasOrphans, WhatsImported name)
 263
 264 type WhetherHasOrphans   = Bool
 265         -- An "orphan" is
 266         --      * an instance decl in a module other than the defn module for
 267         --              one of the tycons or classes in the instance head
 268         --      * a transformation rule in a module other than the one defining
 269         --              the function in the head of the rule.
 270
 271 data WhatsImported name  = Everything
 272                          | Specifically [LocalVersion name] -- List guaranteed non-empty
 273
 274     -- ("M", hif, ver, Everything) means there was a "module M" in
 275     -- this module's export list, so we just have to go by M's version, "ver",
 276     -- not the list of LocalVersions.
 277
 278
 279 type LocalVersion name   = (name, Version)
 280
 281 data ParsedIface
 282   = ParsedIface {
 283       pi_mod       :: Version,                          -- Module version number
 284       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 285       pi_usages    :: [ImportVersion OccName],          -- Usages
 286       pi_exports   :: [ExportItem],                     -- Exports
 287       pi_decls     :: [(Version, RdrNameHsDecl)],       -- Local definitions
 288       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 289       pi_rules     :: [RdrNameRuleDecl],                -- Rules
 290       pi_deprecs   :: [RdrNameDeprecation]              -- Deprecations
 291     }
 292
 293 data InterfaceDetails
 294    = InterfaceDetails WhetherHasOrphans
 295                       (VersionInfo Name)   -- Version information for what this module imports
 296                       ExportEnv            -- What modules this one depends on
 297                       [Deprecation Name]
 298
 299
 300 -- needed by Main to fish out the fixities assoc list.
 301 getIfaceFixities :: InterfaceDetails -> Fixities
 302 getIfaceFixities (InterfaceDetails _ _ (ExportEnv _ fs _) _) = fs
 303
 304
 305 type RdrNamePragma = ()                         -- Fudge for now
 306 -------------------
 307
 308 data Ifaces = Ifaces {
 309                 iImpModInfo :: ImportedModuleInfo,
 310                                 -- Modules this one depends on: that is, the union
 311                                 -- of the modules its *direct* imports depend on.
 312                                 -- NB: The direct imports have .hi files that enumerate *all* the
 313                                 -- dependencies (direct or not) of the imported module.
 314
 315                 iDecls :: DeclsMap,     -- A single, global map of Names to decls
 316
 317                 iFixes :: FixityEnv,    -- A single, global map of Names to fixities
 318                                         -- See comments with RnIfaces.lookupFixity
 319
 320                 iSlurp :: NameSet,
 321                 -- All the names (whether "big" or "small", whether wired-in or not,
 322                 -- whether locally defined or not) that have been slurped in so far.
 323
 324                 iVSlurp :: [(Name,Version)],
 325                 -- All the (a) non-wired-in (b) "big" (c) non-locally-defined
 326                 -- names that have been slurped in so far, with their versions.
 327                 -- This is used to generate the "usage" information for this module.
 328                 -- Subset of the previous field.
 329
 330                 iInsts :: Bag GatedDecl,
 331                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 332                 -- slurp an instance decl so that we don't slurp the same one twice.
 333                 -- Each is 'gated' by the names that must be available before
 334                 -- this instance decl is needed.
 335
 336                 iRules :: Bag GatedDecl,
 337                         -- Ditto transformation rules
 338
 339                 iDeprecs :: DeprecationEnv
 340         }
 341
 342 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 343
 344 type ImportedModuleInfo
 345      = FiniteMap ModuleName (Version, Bool, Maybe (Module, Bool, Avails))
 346                 -- Suppose the domain element is module 'A'
 347                 --
 348                 -- The first Bool is True if A contains
 349                 -- 'orphan' rules or instance decls
 350
 351                 -- The second Bool is true if the interface file actually
 352                 -- read was an .hi-boot file
 353
 354                 -- Nothing => A's interface not yet read, but this module has
 355                 --            imported a module, B, that itself depends on A
 356                 --
 357                 -- Just xx => A's interface has been read.  The Module in
 358                 --              the Just has the correct Dll flag
 359
 360                 -- This set is used to decide whether to look for
 361                 -- A.hi or A.hi-boot when importing A.f.
 362                 -- Basically, we look for A.hi if A is in the map, and A.hi-boot
 363                 -- otherwise
 364
 365 type DeclsMap = NameEnv (Version, AvailInfo, Bool, (Module, RdrNameHsDecl))
 366                 -- A DeclsMap contains a binding for each Name in the declaration
 367                 -- including the constructors of a type decl etc.
 368                 -- The Bool is True just for the 'main' Name.
 369 \end{code}
 370
 371
 372 %************************************************************************
 373 %*                                                                      *
 374 \subsection{Main monad code}
 375 %*                                                                      *
 376 %************************************************************************
 377
 378 \begin{code}
 379 initRn :: ModuleName -> UniqSupply -> SearchPath -> SrcLoc
 380        -> RnMG r
 381        -> IO (r, Bag ErrMsg, Bag WarnMsg)
 382
 383 initRn mod us dirs loc do_rn = do
 384   himaps    <- mkModuleHiMaps dirs
 385   names_var <- newIORef (us, emptyFM, builtins, emptyFM)
 386   errs_var  <- newIORef (emptyBag,emptyBag)
 387   iface_var <- newIORef emptyIfaces
 388   let
 389         rn_down = RnDown { rn_loc = loc, rn_ns = names_var,
 390                            rn_errs = errs_var,
 391                            rn_hi_maps = himaps,
 392                            rn_ifaces = iface_var,
 393                            rn_mod = mod }
 394
 395         -- do the business
 396   res <- do_rn rn_down ()
 397
 398         -- grab errors and return
 399   (warns, errs) <- readIORef errs_var
 400
 401   return (res, errs, warns)
 402
 403
 404 initRnMS :: GlobalRdrEnv -> FixityEnv -> RnMode -> RnMS r -> RnM d r
 405 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 406   = let
 407         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 408                          rn_fixenv = fixity_env, rn_mode = mode }
 409     in
 410     thing_inside rn_down s_down
 411
 412 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 413 initIfaceRnMS mod thing_inside
 414   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 415     setModuleRn (moduleName mod) thing_inside
 416
 417 emptyIfaces :: Ifaces
 418 emptyIfaces = Ifaces { iImpModInfo = emptyFM,
 419                        iDecls = emptyNameEnv,
 420                        iFixes = emptyNameEnv,
 421                        iSlurp = unitNameSet (mkUnboundName dummyRdrVarName),
 422                         -- Pretend that the dummy unbound name has already been
 423                         -- slurped.  This is what's returned for an out-of-scope name,
 424                         -- and we don't want thereby to try to suck it in!
 425                        iVSlurp = [],
 426                        iInsts = emptyBag,
 427                        iRules = emptyBag,
 428                        iDeprecs = emptyNameEnv
 429               }
 430
 431 -- mkUnboundName makes a place-holder Name; it shouldn't be looked at except possibly
 432 -- during compiler debugging.
 433 mkUnboundName :: RdrName -> Name
 434 mkUnboundName rdr_name = mkLocalName unboundKey (rdrNameOcc rdr_name) noSrcLoc
 435
 436 isUnboundName :: Name -> Bool
 437 isUnboundName name = getUnique name == unboundKey
 438
 439 builtins :: FiniteMap (ModuleName,OccName) Name
 440 builtins =
 441    bagToFM (
 442    mapBag (\ name ->  ((moduleName (nameModule name), nameOccName name), name))
 443           builtinNames)
 444 \end{code}
 445
 446 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 447 that is, not as part of the main renamer.
 448 Sole examples: derived definitions,
 449 which are only generated in the type checker.
 450
 451 The @RnNameSupply@ includes a @UniqueSupply@, so if you call it more than
 452 once you must either split it, or install a fresh unique supply.
 453
 454 \begin{code}
 455 renameSourceCode :: ModuleName
 456                  -> RnNameSupply
 457                  -> RnMS r
 458                  -> r
 459
 460 renameSourceCode mod_name name_supply m
 461   = unsafePerformIO (
 462         -- It's not really unsafe!  When renaming source code we
 463         -- only do any I/O if we need to read in a fixity declaration;
 464         -- and that doesn't happen in pragmas etc
 465
 466         mkModuleHiMaps (mkSearchPath opt_HiMap) >>= \ himaps ->
 467         newIORef name_supply            >>= \ names_var ->
 468         newIORef (emptyBag,emptyBag)    >>= \ errs_var ->
 469         let
 470             rn_down = RnDown { rn_loc = mkGeneratedSrcLoc, rn_ns = names_var,
 471                                rn_errs = errs_var, rn_hi_maps = himaps,
 472                                rn_mod = mod_name,
 473                                rn_ifaces = panic "rnameSourceCode: rn_ifaces"  -- Not required
 474                              }
 475             s_down = SDown { rn_mode = InterfaceMode,
 476                                -- So that we can refer to PrelBase.True etc
 477                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 478                              rn_fixenv = emptyNameEnv }
 479         in
 480         m rn_down s_down                        >>= \ result ->
 481
 482         readIORef errs_var                      >>= \ (warns,errs) ->
 483
 484         (if not (isEmptyBag errs) then
 485                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 486 #ifdef DEBUG
 487          else if not (isEmptyBag warns) then
 488                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 489 #endif
 490          else
 491                 id) $
 492
 493         return result
 494     )
 495   where
 496     display errs = pprBagOfErrors errs
 497
 498 {-# INLINE thenRn #-}
 499 {-# INLINE thenRn_ #-}
 500 {-# INLINE returnRn #-}
 501 {-# INLINE andRn #-}
 502
 503 returnRn :: a -> RnM d a
 504 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 505 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 506 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 507 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 508 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 509 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 510 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 511 sequenceRn :: [RnM d a] -> RnM d [a]
 512 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 513 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 514 fixRn    :: (a -> RnM d a) -> RnM d a
 515
 516 returnRn v gdown ldown  = return v
 517 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 518 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 519 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 520 andRn combiner m1 m2 gdown ldown
 521   = m1 gdown ldown >>= \ res1 ->
 522     m2 gdown ldown >>= \ res2 ->
 523     return (combiner res1 res2)
 524
 525 sequenceRn []     = returnRn []
 526 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 527                      sequenceRn ms      `thenRn` \ rs ->
 528                      returnRn (r:rs)
 529
 530 mapRn f []     = returnRn []
 531 mapRn f (x:xs)
 532   = f x         `thenRn` \ r ->
 533     mapRn f xs  `thenRn` \ rs ->
 534     returnRn (r:rs)
 535
 536 mapRn_ f []     = returnRn ()
 537 mapRn_ f (x:xs) =
 538     f x         `thenRn_`
 539     mapRn_ f xs
 540
 541 foldlRn k z [] = returnRn z
 542 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 543                      foldlRn k z' xs
 544
 545 mapAndUnzipRn f [] = returnRn ([],[])
 546 mapAndUnzipRn f (x:xs)
 547   = f x                 `thenRn` \ (r1,  r2)  ->
 548     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 549     returnRn (r1:rs1, r2:rs2)
 550
 551 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 552 mapAndUnzip3Rn f (x:xs)
 553   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 554     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 555     returnRn (r1:rs1, r2:rs2, r3:rs3)
 556
 557 mapMaybeRn f []     = returnRn []
 558 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 559                       mapMaybeRn f xs   `thenRn` \ rs ->
 560                       case maybe_r of
 561                         Nothing -> returnRn rs
 562                         Just r  -> returnRn (r:rs)
 563
 564 flatMapRn f []     = returnRn []
 565 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 566                      flatMapRn f xs     `thenRn` \ rs ->
 567                      returnRn (r ++ rs)
 568 \end{code}
 569
 570
 571
 572 %************************************************************************
 573 %*                                                                      *
 574 \subsection{Boring plumbing for common part}
 575 %*                                                                      *
 576 %************************************************************************
 577
 578
 579 %================
 580 \subsubsection{  Errors and warnings}
 581 %=====================
 582
 583 \begin{code}
 584 failWithRn :: a -> Message -> RnM d a
 585 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 586   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 587     writeIORef errs_var (warns, errs `snocBag` err)             >>
 588     return res
 589   where
 590     err = addShortErrLocLine loc msg
 591
 592 warnWithRn :: a -> Message -> RnM d a
 593 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 594   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 595     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 596     return res
 597   where
 598     warn = addShortWarnLocLine loc msg
 599
 600 addErrRn :: Message -> RnM d ()
 601 addErrRn err = failWithRn () err
 602
 603 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 604 checkRn False err = addErrRn err
 605 checkRn True  err = returnRn ()
 606
 607 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 608 warnCheckRn False err = addWarnRn err
 609 warnCheckRn True  err = returnRn ()
 610
 611 addWarnRn :: Message -> RnM d ()
 612 addWarnRn warn = warnWithRn () warn
 613
 614 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 615 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 616   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 617     return (isEmptyBag errs)
 618 \end{code}
 619
 620
 621 %================
 622 \subsubsection{  Source location}
 623 %=====================
 624
 625 \begin{code}
 626 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 627 pushSrcLocRn loc' m down l_down
 628   = m (down {rn_loc = loc'}) l_down
 629
 630 getSrcLocRn :: RnM d SrcLoc
 631 getSrcLocRn down l_down
 632   = return (rn_loc down)
 633 \end{code}
 634
 635 %================
 636 \subsubsection{  Name supply}
 637 %=====================
 638
 639 \begin{code}
 640 getNameSupplyRn :: RnM d RnNameSupply
 641 getNameSupplyRn rn_down l_down
 642   = readIORef (rn_ns rn_down)
 643
 644 setNameSupplyRn :: RnNameSupply -> RnM d ()
 645 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 646   = writeIORef names_var names'
 647
 648 -- See comments with RnNameSupply above.
 649 newInstUniq :: String -> RnM d Int
 650 newInstUniq key (RnDown {rn_ns = names_var}) l_down
 651   = readIORef names_var                         >>= \ (us, mapInst, cache, ipcache) ->
 652     let
 653         uniq = case lookupFM mapInst key of
 654                    Just x  -> x+1
 655                    Nothing -> 0
 656         mapInst' = addToFM mapInst key uniq
 657     in
 658     writeIORef names_var (us, mapInst', cache, ipcache) >>
 659     return uniq
 660
 661 getUniqRn :: RnM d Unique
 662 getUniqRn (RnDown {rn_ns = names_var}) l_down
 663  = readIORef names_var >>= \ (us, mapInst, cache, ipcache) ->
 664    let
 665      (us1,us') = splitUniqSupply us
 666    in
 667    writeIORef names_var (us', mapInst, cache, ipcache)  >>
 668    return (uniqFromSupply us1)
 669 \end{code}
 670
 671 %================
 672 \subsubsection{  Module}
 673 %=====================
 674
 675 \begin{code}
 676 getModuleRn :: RnM d ModuleName
 677 getModuleRn (RnDown {rn_mod = mod_name}) l_down
 678   = return mod_name
 679
 680 setModuleRn :: ModuleName -> RnM d a -> RnM d a
 681 setModuleRn new_mod enclosed_thing rn_down l_down
 682   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 683 \end{code}
 684
 685
 686 %************************************************************************
 687 %*                                                                      *
 688 \subsection{Plumbing for rename-source part}
 689 %*                                                                      *
 690 %************************************************************************
 691
 692 %================
 693 \subsubsection{  RnEnv}
 694 %=====================
 695
 696 \begin{code}
 697 getNameEnvs :: RnMS (GlobalRdrEnv, LocalRdrEnv)
 698 getNameEnvs rn_down (SDown {rn_genv = global_env, rn_lenv = local_env})
 699   = return (global_env, local_env)
 700
 701 getLocalNameEnv :: RnMS LocalRdrEnv
 702 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 703   = return local_env
 704
 705 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 706 setLocalNameEnv local_env' m rn_down l_down
 707   = m rn_down (l_down {rn_lenv = local_env'})
 708
 709 getFixityEnv :: RnMS FixityEnv
 710 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 711   = return fixity_env
 712
 713 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 714 extendFixityEnv fixes enclosed_scope
 715                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 716   = let
 717         new_fixity_env = extendNameEnv fixity_env fixes
 718     in
 719     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 720 \end{code}
 721
 722 %================
 723 \subsubsection{  Mode}
 724 %=====================
 725
 726 \begin{code}
 727 getModeRn :: RnMS RnMode
 728 getModeRn rn_down (SDown {rn_mode = mode})
 729   = return mode
 730
 731 setModeRn :: RnMode -> RnMS a -> RnMS a
 732 setModeRn new_mode thing_inside rn_down l_down
 733   = thing_inside rn_down (l_down {rn_mode = new_mode})
 734 \end{code}
 735
 736
 737 %************************************************************************
 738 %*                                                                      *
 739 \subsection{Plumbing for rename-globals part}
 740 %*                                                                      *
 741 %************************************************************************
 742
 743 \begin{code}
 744 getIfacesRn :: RnM d Ifaces
 745 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 746   = readIORef iface_var
 747
 748 setIfacesRn :: Ifaces -> RnM d ()
 749 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 750   = writeIORef iface_var ifaces
 751
 752 getHiMaps :: RnM d (ModuleHiMap, ModuleHiMap)
 753 getHiMaps (RnDown {rn_hi_maps = himaps}) _
 754   = return himaps
 755 \end{code}
 756
 757 \begin{code}
 758 lookupModuleRn :: ModuleName -> RnM d Module
 759 lookupModuleRn x =
 760   getHiMaps `thenRn` \ (himap, _) ->
 761   case lookupFM himap x of
 762     Nothing    -> returnRn (mkVanillaModule x)
 763     Just (_,x) -> returnRn x
 764
 765 \end{code}