ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9
  10         module RdrName,         -- Re-exports
  11         module Name,            -- from these two
  12
  13         Module,
  14         FiniteMap,
  15         Bag,
  16         RdrNameHsDecl,
  17         RdrNameInstDecl,
  18         Version,
  19         NameSet,
  20         OccName,
  21         Fixity
  22     ) where
  23
  24 #include "HsVersions.h"
  25
  26 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  27 import IOExts           ( fixIO )
  28 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  29 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  30 #else
  31 import IOBase           ( fixIO )
  32 #endif
  33 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  34
  35 import HsSyn
  36 import RdrHsSyn
  37 import RnHsSyn          ( RenamedFixitySig )
  38 import HscTypes         ( AvailEnv, lookupType,
  39                           OrigNameEnv(..), OrigNameNameEnv, OrigNameIParamEnv,
  40                           WhetherHasOrphans, ImportVersion,
  41                           PersistentRenamerState(..), IsBootInterface, Avails,
  42                           DeclsMap, IfaceInsts, IfaceRules,
  43                           HomeSymbolTable, TyThing,
  44                           PersistentCompilerState(..), GlobalRdrEnv,
  45                           HomeIfaceTable, PackageIfaceTable,
  46                           RdrAvailInfo )
  47 import BasicTypes       ( Version, defaultFixity )
  48 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  49                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  50                         )
  51 import RdrName          ( RdrName, dummyRdrVarName, rdrNameModule, rdrNameOcc,
  52                           RdrNameEnv, emptyRdrEnv, extendRdrEnv,
  53                           addListToRdrEnv, rdrEnvToList, rdrEnvElts
  54                         )
  55 import Name             ( Name, OccName, NamedThing(..), getSrcLoc,
  56                           nameOccName,
  57                           decode, mkLocalName, mkKnownKeyGlobal
  58                         )
  59 import Name             ( NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv, extendNameEnvList )
  60 import Module           ( Module, ModuleName, ModuleSet, emptyModuleSet )
  61 import NameSet
  62 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt )
  63 import SrcLoc           ( SrcLoc, generatedSrcLoc, noSrcLoc )
  64 import Unique           ( Unique )
  65 import FiniteMap        ( FiniteMap, emptyFM )
  66 import Bag              ( Bag, emptyBag, isEmptyBag, snocBag )
  67 import UniqSupply
  68 import Outputable
  69 import PrelNames        ( mkUnboundName )
  70 import ErrUtils         ( printErrorsAndWarnings )
  71
  72 infixr 9 `thenRn`, `thenRn_`
  73 \end{code}
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 \subsection{Somewhat magical interface to other monads}
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 \begin{code}
  83 ioToRnM :: IO r -> RnM d (Either IOError r)
  84 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  85                             `catch`
  86                             (\ err -> return (Left err))
  87
  88 ioToRnM_no_fail :: IO r -> RnM d r
  89 ioToRnM_no_fail io rn_down g_down
  90    = (io >>= \ ok -> return ok)
  91      `catch`
  92      (\ err -> panic "ioToRnM_no_fail: the I/O operation failed!")
  93
  94 traceRn :: SDoc -> RnM d ()
  95 traceRn msg
  96    = doptRn Opt_D_dump_rn_trace `thenRn` \b ->
  97      if b then putDocRn msg else returnRn ()
  98
  99 traceHiDiffsRn :: SDoc -> RnM d ()
 100 traceHiDiffsRn msg
 101    = doptRn Opt_D_dump_hi_diffs `thenRn` \b ->
 102      if b then putDocRn msg else returnRn ()
 103
 104 putDocRn :: SDoc -> RnM d ()
 105 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
 106                returnRn ()
 107 \end{code}
 108
 109
 110 %************************************************************************
 111 %*                                                                      *
 112 \subsection{Data types}
 113 %*                                                                      *
 114 %************************************************************************
 115
 116 %===================================================
 117 \subsubsection{         MONAD TYPES}
 118 %===================================================
 119
 120 \begin{code}
 121 type RnM d r = RnDown -> d -> IO r
 122 type RnMS r  = RnM SDown r              -- Renaming source
 123 type RnMG r  = RnM ()    r              -- Getting global names etc
 124
 125         -- Common part
 126 data RnDown
 127   = RnDown {
 128         rn_mod     :: Module,           -- This module
 129         rn_loc     :: SrcLoc,           -- Current locn
 130
 131         rn_dflags  :: DynFlags,
 132
 133         rn_hit     :: HomeIfaceTable,
 134         rn_done    :: Name -> Maybe TyThing,    -- Tells what things (both in the
 135                                                 -- home package and other packages)
 136                                                 -- were already available (i.e. in
 137                                                 -- the relevant SymbolTable) before
 138                                                 -- compiling this module
 139                         -- The Name passed to rn_done is guaranteed to be a Global,
 140                         -- so it has a Module, so it can be looked up
 141
 142         rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 143
 144         -- The second and third components are a flattened-out OrigNameEnv
 145         rn_ns      :: IORef (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv),
 146         rn_ifaces  :: IORef Ifaces
 147     }
 148
 149         -- For renaming source code
 150 data SDown = SDown {
 151                   rn_mode :: RnMode,
 152
 153                   rn_genv :: GlobalRdrEnv,      -- Top level environment
 154
 155                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 156                         --   Does *not* include global name envt; may shadow it
 157                         --   Includes both ordinary variables and type variables;
 158                         --   they are kept distinct because tyvar have a different
 159                         --   occurrence contructor (Name.TvOcc)
 160                         -- We still need the unsullied global name env so that
 161                         --   we can look up record field names
 162
 163                   rn_fixenv :: LocalFixityEnv   -- Local fixities (for non-top-level
 164                                                 -- declarations)
 165                         -- The global fixities are held in the
 166                         -- HIT or PIT.  Why?  See the comments
 167                         -- with RnIfaces.lookupLocalFixity
 168                 }
 169
 170 data RnMode     = SourceMode                    -- Renaming source code
 171                 | InterfaceMode                 -- Renaming interface declarations.
 172 \end{code}
 173
 174 %===================================================
 175 \subsubsection{         ENVIRONMENTS}
 176 %===================================================
 177
 178 \begin{code}
 179 --------------------------------
 180 type LocalRdrEnv    = RdrNameEnv Name
 181 type LocalFixityEnv = NameEnv RenamedFixitySig
 182         -- We keep the whole fixity sig so that we
 183         -- can report line-number info when there is a duplicate
 184         -- fixity declaration
 185
 186 lookupLocalFixity :: LocalFixityEnv -> Name -> Fixity
 187 lookupLocalFixity env name
 188   = case lookupNameEnv env name of
 189         Just (FixitySig _ fix _) -> fix
 190         Nothing                  -> defaultFixity
 191 \end{code}
 192
 193 \begin{code}
 194 type ExportAvails = (FiniteMap ModuleName Avails,
 195         -- Used to figure out "module M" export specifiers
 196         -- Includes avails only from *unqualified* imports
 197         -- (see 1.4 Report Section 5.1.1)
 198
 199                      AvailEnv)  -- Used to figure out all other export specifiers.
 200 \end{code}
 201
 202 %===================================================
 203 \subsubsection{         INTERFACE FILE STUFF}
 204 %===================================================
 205
 206 \begin{code}
 207 type ExportItem   = (ModuleName, [RdrAvailInfo])
 208 type IfaceDeprecs = Maybe (Either DeprecTxt [(RdrName,DeprecTxt)])
 209         -- Nothing        => NoDeprecs
 210         -- Just (Left t)  => DeprecAll
 211         -- Just (Right p) => DeprecSome
 212
 213 data ParsedIface
 214   = ParsedIface {
 215       pi_mod       :: Module,                           -- Complete with package info
 216       pi_vers      :: Version,                          -- Module version number
 217       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 218       pi_usages    :: [ImportVersion OccName],          -- Usages
 219       pi_exports   :: (Version, [ExportItem]),          -- Exports
 220       pi_decls     :: [(Version, RdrNameTyClDecl)],     -- Local definitions
 221       pi_fixity    :: [RdrNameFixitySig],               -- Local fixity declarations,
 222       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 223       pi_rules     :: (Version, [RdrNameRuleDecl]),     -- Rules, with their version
 224       pi_deprecs   :: IfaceDeprecs                      -- Deprecations
 225     }
 226 \end{code}
 227
 228 %************************************************************************
 229 %*                                                                      *
 230 \subsection{The renamer state}
 231 %*                                                                      *
 232 %************************************************************************
 233
 234 \begin{code}
 235 data Ifaces = Ifaces {
 236     -- PERSISTENT FIELDS
 237         iPIT :: PackageIfaceTable,
 238                 -- The ModuleIFaces for modules in other packages
 239                 -- whose interfaces we have opened
 240                 -- The declarations in these interface files are held in
 241                 -- iDecls, iInsts, iRules (below), not in the mi_decls fields
 242                 -- of the iPIT.  What _is_ in the iPIT is:
 243                 --      * The Module
 244                 --      * Version info
 245                 --      * Its exports
 246                 --      * Fixities
 247                 --      * Deprecations
 248                 -- The iPIT field is initialised from the compiler's persistent
 249                 -- package symbol table, and the renamer incrementally adds
 250                 -- to it.
 251
 252         iDecls :: DeclsMap,
 253                 -- A single, global map of Names to unslurped decls
 254
 255         iInsts :: IfaceInsts,
 256                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 257                 -- slurp an instance decl so that we don't slurp the same one twice.
 258                 -- Each is 'gated' by the names that must be available before
 259                 -- this instance decl is needed.
 260
 261         iRules :: IfaceRules,
 262                 -- Similar to instance decls, only for rules
 263
 264     -- EPHEMERAL FIELDS
 265     -- These fields persist during the compilation of a single module only
 266         iImpModInfo :: ImportedModuleInfo,
 267                         -- Modules this one depends on: that is, the union
 268                         -- of the modules its *direct* imports depend on.
 269                         -- NB: The direct imports have .hi files that enumerate *all* the
 270                         -- dependencies (direct or not) of the imported module.
 271
 272         iSlurp :: NameSet,
 273                 -- All the names (whether "big" or "small", whether wired-in or not,
 274                 -- whether locally defined or not) that have been slurped in so far.
 275
 276         iVSlurp :: (ModuleSet, NameSet)
 277                 -- The Names are all the (a) non-wired-in
 278                 --                       (b) "big"
 279                 --                       (c) non-locally-defined
 280                 --                       (d) home-package
 281                 -- names that have been slurped in so far, with their versions.
 282                 -- This is used to generate the "usage" information for this module.
 283                 -- Subset of the previous field.
 284                 -- The module set is the non-home-package modules from which we have
 285                 -- slurped at least one name.
 286                 -- It's worth keeping separately, because there's no very easy
 287                 -- way to distinguish the "big" names from the "non-big" ones.
 288                 -- But this is a decision we might want to revisit.
 289     }
 290
 291 type ImportedModuleInfo = FiniteMap ModuleName (WhetherHasOrphans, IsBootInterface)
 292         -- Contains info ONLY about modules that have not yet
 293         --- been loaded into the iPIT
 294 \end{code}
 295
 296
 297 %************************************************************************
 298 %*                                                                      *
 299 \subsection{Main monad code}
 300 %*                                                                      *
 301 %************************************************************************
 302
 303 \begin{code}
 304 initRn :: DynFlags
 305        -> HomeIfaceTable -> HomeSymbolTable
 306        -> PersistentCompilerState
 307        -> Module
 308        -> RnMG t
 309        -> IO (PersistentCompilerState, Bool, t)
 310                 -- True <=> found errors
 311
 312 initRn dflags hit hst pcs mod do_rn
 313   = do
 314         let prs = pcs_PRS pcs
 315         let pte = pcs_PTE pcs
 316         let ifaces = Ifaces { iPIT   = pcs_PIT pcs,
 317                               iDecls = prsDecls prs,
 318                               iInsts = prsInsts prs,
 319                               iRules = prsRules prs,
 320
 321                               iImpModInfo = emptyFM,
 322                               iSlurp      = unitNameSet (mkUnboundName dummyRdrVarName),
 323                                 -- Pretend that the dummy unbound name has already been
 324                                 -- slurped.  This is what's returned for an out-of-scope name,
 325                                 -- and we don't want thereby to try to suck it in!
 326                               iVSlurp = (emptyModuleSet, emptyNameSet)
 327                       }
 328         let uniqs = prsNS prs
 329
 330         names_var <- newIORef (uniqs, origNames (prsOrig prs),
 331                                       origIParam (prsOrig prs))
 332         errs_var  <- newIORef (emptyBag,emptyBag)
 333         iface_var <- newIORef ifaces
 334         let rn_down = RnDown { rn_mod = mod,
 335                                rn_loc = noSrcLoc,
 336
 337                                rn_dflags = dflags,
 338                                rn_hit    = hit,
 339                                rn_done   = lookupType hst pte,
 340
 341                                rn_ns     = names_var,
 342                                rn_errs   = errs_var,
 343                                rn_ifaces = iface_var,
 344                              }
 345
 346         -- do the business
 347         res <- do_rn rn_down ()
 348
 349         -- Grab state and record it
 350         (warns, errs)                   <- readIORef errs_var
 351         new_ifaces                      <- readIORef iface_var
 352         (new_NS, new_origN, new_origIP) <- readIORef names_var
 353         let new_orig = Orig { origNames = new_origN, origIParam = new_origIP }
 354         let new_prs = prs { prsOrig = new_orig,
 355                             prsDecls = iDecls new_ifaces,
 356                             prsInsts = iInsts new_ifaces,
 357                             prsRules = iRules new_ifaces,
 358                             prsNS    = new_NS }
 359         let new_pcs = pcs { pcs_PIT = iPIT new_ifaces,
 360                             pcs_PRS = new_prs }
 361
 362         -- Check for warnings
 363         printErrorsAndWarnings (warns, errs) ;
 364
 365         return (new_pcs, not (isEmptyBag errs), res)
 366
 367 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 368         -- The fixity_env appears in both the rn_fixenv field
 369         -- and in the HIT.  See comments with RnHiFiles.lookupFixityRn
 370   = let
 371         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 372                          rn_fixenv = fixity_env, rn_mode = mode }
 373     in
 374     thing_inside rn_down s_down
 375
 376 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 377 initIfaceRnMS mod thing_inside
 378   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 379     setModuleRn mod thing_inside
 380 \end{code}
 381
 382 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 383 that is, not as part of the main renamer.
 384 Sole examples: derived definitions,
 385 which are only generated in the type checker.
 386
 387 The @NameSupply@ includes a @UniqueSupply@, so if you call it more than
 388 once you must either split it, or install a fresh unique supply.
 389
 390 \begin{code}
 391 renameSourceCode :: DynFlags
 392                  -> Module
 393                  -> PersistentRenamerState
 394                  -> RnMS r
 395                  -> r
 396
 397 renameSourceCode dflags mod prs m
 398   = unsafePerformIO (
 399         -- It's not really unsafe!  When renaming source code we
 400         -- only do any I/O if we need to read in a fixity declaration;
 401         -- and that doesn't happen in pragmas etc
 402
 403         mkSplitUniqSupply 'r'                           >>= \ new_us ->
 404         newIORef (new_us, origNames (prsOrig prs),
 405                           origIParam (prsOrig prs))     >>= \ names_var ->
 406         newIORef (emptyBag,emptyBag)                    >>= \ errs_var ->
 407         let
 408             rn_down = RnDown { rn_dflags = dflags,
 409                                rn_loc = generatedSrcLoc, rn_ns = names_var,
 410                                rn_errs = errs_var,
 411                                rn_mod = mod,
 412                                rn_done   = bogus "rn_done",     rn_hit    = bogus "rn_hit",
 413                                rn_ifaces = bogus "rn_ifaces"
 414                              }
 415             s_down = SDown { rn_mode = InterfaceMode,
 416                                -- So that we can refer to PrelBase.True etc
 417                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 418                              rn_fixenv = emptyNameEnv }
 419         in
 420         m rn_down s_down                        >>= \ result ->
 421
 422         readIORef errs_var                      >>= \ (warns,errs) ->
 423
 424         (if not (isEmptyBag errs) then
 425                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 426 #ifdef DEBUG
 427          else if not (isEmptyBag warns) then
 428                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 429 #endif
 430          else
 431                 id) $
 432
 433         return result
 434     )
 435   where
 436     display errs = pprBagOfErrors errs
 437
 438 bogus s = panic ("rnameSourceCode: " ++ s)  -- Used for unused record fields
 439
 440 {-# INLINE thenRn #-}
 441 {-# INLINE thenRn_ #-}
 442 {-# INLINE returnRn #-}
 443 {-# INLINE andRn #-}
 444
 445 returnRn :: a -> RnM d a
 446 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 447 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 448 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 449 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 450 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 451 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 452 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 453 sequenceRn :: [RnM d a] -> RnM d [a]
 454 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 455 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 456 fixRn    :: (a -> RnM d a) -> RnM d a
 457
 458 returnRn v gdown ldown  = return v
 459 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 460 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 461 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 462 andRn combiner m1 m2 gdown ldown
 463   = m1 gdown ldown >>= \ res1 ->
 464     m2 gdown ldown >>= \ res2 ->
 465     return (combiner res1 res2)
 466
 467 sequenceRn []     = returnRn []
 468 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 469                      sequenceRn ms      `thenRn` \ rs ->
 470                      returnRn (r:rs)
 471
 472 mapRn f []     = returnRn []
 473 mapRn f (x:xs)
 474   = f x         `thenRn` \ r ->
 475     mapRn f xs  `thenRn` \ rs ->
 476     returnRn (r:rs)
 477
 478 mapRn_ f []     = returnRn ()
 479 mapRn_ f (x:xs) =
 480     f x         `thenRn_`
 481     mapRn_ f xs
 482
 483 foldlRn k z [] = returnRn z
 484 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 485                      foldlRn k z' xs
 486
 487 mapAndUnzipRn f [] = returnRn ([],[])
 488 mapAndUnzipRn f (x:xs)
 489   = f x                 `thenRn` \ (r1,  r2)  ->
 490     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 491     returnRn (r1:rs1, r2:rs2)
 492
 493 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 494 mapAndUnzip3Rn f (x:xs)
 495   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 496     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 497     returnRn (r1:rs1, r2:rs2, r3:rs3)
 498
 499 mapMaybeRn f []     = returnRn []
 500 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 501                       mapMaybeRn f xs   `thenRn` \ rs ->
 502                       case maybe_r of
 503                         Nothing -> returnRn rs
 504                         Just r  -> returnRn (r:rs)
 505
 506 flatMapRn f []     = returnRn []
 507 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 508                      flatMapRn f xs     `thenRn` \ rs ->
 509                      returnRn (r ++ rs)
 510 \end{code}
 511
 512
 513
 514 %************************************************************************
 515 %*                                                                      *
 516 \subsection{Boring plumbing for common part}
 517 %*                                                                      *
 518 %************************************************************************
 519
 520
 521 %================
 522 \subsubsection{  Errors and warnings}
 523 %=====================
 524
 525 \begin{code}
 526 failWithRn :: a -> Message -> RnM d a
 527 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 528   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 529     writeIORef errs_var (warns, errs `snocBag` err)             >>
 530     return res
 531   where
 532     err = addShortErrLocLine loc msg
 533
 534 warnWithRn :: a -> Message -> RnM d a
 535 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 536   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 537     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 538     return res
 539   where
 540     warn = addShortWarnLocLine loc msg
 541
 542 addErrRn :: Message -> RnM d ()
 543 addErrRn err = failWithRn () err
 544
 545 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 546 checkRn False err = addErrRn err
 547 checkRn True  err = returnRn ()
 548
 549 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 550 warnCheckRn False err = addWarnRn err
 551 warnCheckRn True  err = returnRn ()
 552
 553 addWarnRn :: Message -> RnM d ()
 554 addWarnRn warn = warnWithRn () warn
 555
 556 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 557 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 558   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 559     return (isEmptyBag errs)
 560
 561 doptRn :: DynFlag -> RnM d Bool
 562 doptRn dflag (RnDown { rn_dflags = dflags}) l_down
 563    = return (dopt dflag dflags)
 564
 565 getDOptsRn :: RnM d DynFlags
 566 getDOptsRn (RnDown { rn_dflags = dflags}) l_down
 567    = return dflags
 568 \end{code}
 569
 570
 571 %================
 572 \subsubsection{Source location}
 573 %=====================
 574
 575 \begin{code}
 576 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 577 pushSrcLocRn loc' m down l_down
 578   = m (down {rn_loc = loc'}) l_down
 579
 580 getSrcLocRn :: RnM d SrcLoc
 581 getSrcLocRn down l_down
 582   = return (rn_loc down)
 583 \end{code}
 584
 585 %================
 586 \subsubsection{The finder and home symbol table}
 587 %=====================
 588
 589 \begin{code}
 590 getHomeIfaceTableRn :: RnM d HomeIfaceTable
 591 getHomeIfaceTableRn down l_down = return (rn_hit down)
 592
 593 getTypeEnvRn :: RnM d (Name -> Maybe TyThing)
 594 getTypeEnvRn down l_down = return (rn_done down)
 595 \end{code}
 596
 597 %================
 598 \subsubsection{Name supply}
 599 %=====================
 600
 601 \begin{code}
 602 getNameSupplyRn :: RnM d (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv)
 603 getNameSupplyRn rn_down l_down
 604   = readIORef (rn_ns rn_down)
 605
 606 setNameSupplyRn :: (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv) -> RnM d ()
 607 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 608   = writeIORef names_var names'
 609
 610 getUniqRn :: RnM d Unique
 611 getUniqRn (RnDown {rn_ns = names_var}) l_down
 612  = readIORef names_var >>= \ (us, cache, ipcache) ->
 613    let
 614      (us1,us') = splitUniqSupply us
 615    in
 616    writeIORef names_var (us', cache, ipcache)  >>
 617    return (uniqFromSupply us1)
 618 \end{code}
 619
 620 %================
 621 \subsubsection{  Module}
 622 %=====================
 623
 624 \begin{code}
 625 getModuleRn :: RnM d Module
 626 getModuleRn (RnDown {rn_mod = mod}) l_down
 627   = return mod
 628
 629 setModuleRn :: Module -> RnM d a -> RnM d a
 630 setModuleRn new_mod enclosed_thing rn_down l_down
 631   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 632 \end{code}
 633
 634
 635 %************************************************************************
 636 %*                                                                      *
 637 \subsection{Plumbing for rename-source part}
 638 %*                                                                      *
 639 %************************************************************************
 640
 641 %================
 642 \subsubsection{  RnEnv}
 643 %=====================
 644
 645 \begin{code}
 646 getLocalNameEnv :: RnMS LocalRdrEnv
 647 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 648   = return local_env
 649
 650 getGlobalNameEnv :: RnMS GlobalRdrEnv
 651 getGlobalNameEnv rn_down (SDown {rn_genv = global_env})
 652   = return global_env
 653
 654 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 655 setLocalNameEnv local_env' m rn_down l_down
 656   = m rn_down (l_down {rn_lenv = local_env'})
 657
 658 getFixityEnv :: RnMS LocalFixityEnv
 659 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 660   = return fixity_env
 661
 662 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 663 extendFixityEnv fixes enclosed_scope
 664                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 665   = let
 666         new_fixity_env = extendNameEnvList fixity_env fixes
 667     in
 668     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 669 \end{code}
 670
 671 %================
 672 \subsubsection{  Mode}
 673 %=====================
 674
 675 \begin{code}
 676 getModeRn :: RnMS RnMode
 677 getModeRn rn_down (SDown {rn_mode = mode})
 678   = return mode
 679
 680 setModeRn :: RnMode -> RnMS a -> RnMS a
 681 setModeRn new_mode thing_inside rn_down l_down
 682   = thing_inside rn_down (l_down {rn_mode = new_mode})
 683 \end{code}
 684
 685
 686 %************************************************************************
 687 %*                                                                      *
 688 \subsection{Plumbing for rename-globals part}
 689 %*                                                                      *
 690 %************************************************************************
 691
 692 \begin{code}
 693 getIfacesRn :: RnM d Ifaces
 694 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 695   = readIORef iface_var
 696
 697 setIfacesRn :: Ifaces -> RnM d ()
 698 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 699   = writeIORef iface_var ifaces
 700 \end{code}