ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9
  10         module RdrName,         -- Re-exports
  11         module Name,            -- from these two
  12
  13         Module,
  14         FiniteMap,
  15         Bag,
  16         RdrNameHsDecl,
  17         RdrNameInstDecl,
  18         Version,
  19         NameSet,
  20         OccName,
  21         Fixity
  22     ) where
  23
  24 #include "HsVersions.h"
  25
  26 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  27 import IOExts           ( fixIO )
  28 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  29 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  30 #else
  31 import IOBase           ( fixIO )
  32 #endif
  33 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  34
  35 import HsSyn
  36 import RdrHsSyn
  37 import RnHsSyn          ( RenamedFixitySig )
  38 import HscTypes         ( AvailEnv, lookupType,
  39                           OrigNameEnv(..), OrigNameNameEnv, OrigNameIParamEnv,
  40                           WhetherHasOrphans, ImportVersion,
  41                           PersistentRenamerState(..), IsBootInterface, Avails,
  42                           DeclsMap, IfaceInsts, IfaceRules,
  43                           HomeSymbolTable, PackageTypeEnv,
  44                           PersistentCompilerState(..), GlobalRdrEnv,
  45                           HomeIfaceTable, PackageIfaceTable,
  46                           RdrAvailInfo )
  47 import BasicTypes       ( Version, defaultFixity )
  48 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  49                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  50                         )
  51 import RdrName          ( RdrName, dummyRdrVarName, rdrNameModule, rdrNameOcc,
  52                           RdrNameEnv, emptyRdrEnv, extendRdrEnv,
  53                           addListToRdrEnv, rdrEnvToList, rdrEnvElts
  54                         )
  55 import Name             ( Name, OccName, NamedThing(..), getSrcLoc,
  56                           isLocallyDefinedName, nameOccName,
  57                           decode, mkLocalName, mkKnownKeyGlobal,
  58                           NameEnv, lookupNameEnv, emptyNameEnv, unitNameEnv,
  59                           extendNameEnvList
  60                         )
  61 import Module           ( Module, ModuleName, ModuleSet, emptyModuleSet )
  62 import NameSet
  63 import CmdLineOpts      ( DynFlags, DynFlag(..), dopt )
  64 import SrcLoc           ( SrcLoc, generatedSrcLoc, noSrcLoc )
  65 import Unique           ( Unique )
  66 import FiniteMap        ( FiniteMap, emptyFM )
  67 import Bag              ( Bag, emptyBag, isEmptyBag, snocBag )
  68 import UniqSupply
  69 import Outputable
  70 import PrelNames        ( mkUnboundName )
  71 import Maybes           ( maybeToBool, seqMaybe )
  72 import ErrUtils         ( printErrorsAndWarnings )
  73
  74 infixr 9 `thenRn`, `thenRn_`
  75 \end{code}
  76
  77
  78 %************************************************************************
  79 %*                                                                      *
  80 \subsection{Somewhat magical interface to other monads}
  81 %*                                                                      *
  82 %************************************************************************
  83
  84 \begin{code}
  85 ioToRnM :: IO r -> RnM d (Either IOError r)
  86 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  87                             `catch`
  88                             (\ err -> return (Left err))
  89
  90 ioToRnM_no_fail :: IO r -> RnM d r
  91 ioToRnM_no_fail io rn_down g_down
  92    = (io >>= \ ok -> return ok)
  93      `catch`
  94      (\ err -> panic "ioToRnM_no_fail: the I/O operation failed!")
  95
  96 traceRn :: SDoc -> RnM d ()
  97 traceRn msg
  98    = doptRn Opt_D_dump_rn_trace `thenRn` \b ->
  99      if b then putDocRn msg else returnRn ()
 100
 101 putDocRn :: SDoc -> RnM d ()
 102 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
 103                returnRn ()
 104 \end{code}
 105
 106
 107 %************************************************************************
 108 %*                                                                      *
 109 \subsection{Data types}
 110 %*                                                                      *
 111 %************************************************************************
 112
 113 %===================================================
 114 \subsubsection{         MONAD TYPES}
 115 %===================================================
 116
 117 \begin{code}
 118 type RnM d r = RnDown -> d -> IO r
 119 type RnMS r  = RnM SDown r              -- Renaming source
 120 type RnMG r  = RnM ()    r              -- Getting global names etc
 121
 122         -- Common part
 123 data RnDown
 124   = RnDown {
 125         rn_mod     :: Module,           -- This module
 126         rn_loc     :: SrcLoc,           -- Current locn
 127
 128         rn_dflags  :: DynFlags,
 129
 130         rn_hit     :: HomeIfaceTable,
 131         rn_done    :: Name -> Bool,     -- Tells what things (both in the
 132                                         -- home package and other packages)
 133                                         -- were already available (i.e. in
 134                                         -- the relevant SymbolTable) before
 135                                         -- compiling this module
 136
 137         rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 138
 139         -- The second and third components are a flattened-out OrigNameEnv
 140         rn_ns      :: IORef (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv),
 141         rn_ifaces  :: IORef Ifaces
 142     }
 143
 144         -- For renaming source code
 145 data SDown = SDown {
 146                   rn_mode :: RnMode,
 147
 148                   rn_genv :: GlobalRdrEnv,      -- Global envt
 149
 150                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 151                         --   Does *not* include global name envt; may shadow it
 152                         --   Includes both ordinary variables and type variables;
 153                         --   they are kept distinct because tyvar have a different
 154                         --   occurrence contructor (Name.TvOcc)
 155                         -- We still need the unsullied global name env so that
 156                         --   we can look up record field names
 157
 158                   rn_fixenv :: LocalFixityEnv   -- Local fixities
 159                         -- The global fixities are held in the
 160                         -- rn_ifaces field.  Why?  See the comments
 161                         -- with RnIfaces.lookupLocalFixity
 162                 }
 163
 164 data RnMode     = SourceMode                    -- Renaming source code
 165                 | InterfaceMode                 -- Renaming interface declarations.
 166 \end{code}
 167
 168 %===================================================
 169 \subsubsection{         ENVIRONMENTS}
 170 %===================================================
 171
 172 \begin{code}
 173 --------------------------------
 174 type LocalRdrEnv    = RdrNameEnv Name
 175 type LocalFixityEnv = NameEnv RenamedFixitySig
 176         -- We keep the whole fixity sig so that we
 177         -- can report line-number info when there is a duplicate
 178         -- fixity declaration
 179
 180 lookupLocalFixity :: LocalFixityEnv -> Name -> Fixity
 181 lookupLocalFixity env name
 182   = case lookupNameEnv env name of
 183         Just (FixitySig _ fix _) -> fix
 184         Nothing                  -> defaultFixity
 185 \end{code}
 186
 187 \begin{code}
 188 type ExportAvails = (FiniteMap ModuleName Avails,
 189         -- Used to figure out "module M" export specifiers
 190         -- Includes avails only from *unqualified* imports
 191         -- (see 1.4 Report Section 5.1.1)
 192
 193                      AvailEnv)  -- Used to figure out all other export specifiers.
 194 \end{code}
 195
 196 %===================================================
 197 \subsubsection{         INTERFACE FILE STUFF}
 198 %===================================================
 199
 200 \begin{code}
 201 type ExportItem   = (ModuleName, [RdrAvailInfo])
 202 type IfaceDeprecs = Maybe (Either DeprecTxt [(RdrName,DeprecTxt)])
 203         -- Nothing        => NoDeprecs
 204         -- Just (Left t)  => DeprecAll
 205         -- Just (Right p) => DeprecSome
 206
 207 data ParsedIface
 208   = ParsedIface {
 209       pi_mod       :: Module,                           -- Complete with package info
 210       pi_vers      :: Version,                          -- Module version number
 211       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 212       pi_usages    :: [ImportVersion OccName],          -- Usages
 213       pi_exports   :: (Version, [ExportItem]),          -- Exports
 214       pi_decls     :: [(Version, RdrNameTyClDecl)],     -- Local definitions
 215       pi_fixity    :: [RdrNameFixitySig],               -- Local fixity declarations,
 216       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 217       pi_rules     :: (Version, [RdrNameRuleDecl]),     -- Rules, with their version
 218       pi_deprecs   :: IfaceDeprecs                      -- Deprecations
 219     }
 220 \end{code}
 221
 222 %************************************************************************
 223 %*                                                                      *
 224 \subsection{The renamer state}
 225 %*                                                                      *
 226 %************************************************************************
 227
 228 \begin{code}
 229 data Ifaces = Ifaces {
 230     -- PERSISTENT FIELDS
 231         iPIT :: PackageIfaceTable,
 232                 -- The ModuleIFaces for modules in other packages
 233                 -- whose interfaces we have opened
 234                 -- The declarations in these interface files are held in
 235                 -- iDecls, iInsts, iRules (below), not in the mi_decls fields
 236                 -- of the iPIT.  What _is_ in the iPIT is:
 237                 --      * The Module
 238                 --      * Version info
 239                 --      * Its exports
 240                 --      * Fixities
 241                 --      * Deprecations
 242                 -- The iPIT field is initialised from the compiler's persistent
 243                 -- package symbol table, and the renamer incrementally adds
 244                 -- to it.
 245
 246         iDecls :: DeclsMap,
 247                 -- A single, global map of Names to unslurped decls
 248
 249         iInsts :: IfaceInsts,
 250                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 251                 -- slurp an instance decl so that we don't slurp the same one twice.
 252                 -- Each is 'gated' by the names that must be available before
 253                 -- this instance decl is needed.
 254
 255         iRules :: IfaceRules,
 256                 -- Similar to instance decls, only for rules
 257
 258     -- EPHEMERAL FIELDS
 259     -- These fields persist during the compilation of a single module only
 260         iImpModInfo :: ImportedModuleInfo,
 261                         -- Modules this one depends on: that is, the union
 262                         -- of the modules its *direct* imports depend on.
 263                         -- NB: The direct imports have .hi files that enumerate *all* the
 264                         -- dependencies (direct or not) of the imported module.
 265
 266         iSlurp :: NameSet,
 267                 -- All the names (whether "big" or "small", whether wired-in or not,
 268                 -- whether locally defined or not) that have been slurped in so far.
 269
 270         iVSlurp :: (ModuleSet, NameSet)
 271                 -- The Names are all the (a) non-wired-in
 272                 --                       (b) "big"
 273                 --                       (c) non-locally-defined
 274                 --                       (d) home-package
 275                 -- names that have been slurped in so far, with their versions.
 276                 -- This is used to generate the "usage" information for this module.
 277                 -- Subset of the previous field.
 278                 -- The module set is the non-home-package modules from which we have
 279                 -- slurped at least one name.
 280                 -- It's worth keeping separately, because there's no very easy
 281                 -- way to distinguish the "big" names from the "non-big" ones.
 282                 -- But this is a decision we might want to revisit.
 283     }
 284
 285 type ImportedModuleInfo = FiniteMap ModuleName (WhetherHasOrphans, IsBootInterface)
 286         -- Contains info ONLY about modules that have not yet
 287         --- been loaded into the iPIT
 288 \end{code}
 289
 290
 291 %************************************************************************
 292 %*                                                                      *
 293 \subsection{Main monad code}
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 \begin{code}
 298 initRn :: DynFlags
 299        -> HomeIfaceTable -> HomeSymbolTable
 300        -> PersistentCompilerState
 301        -> Module
 302        -> RnMG t
 303        -> IO (PersistentCompilerState, Bool, t)
 304                 -- True <=> found errors
 305
 306 initRn dflags hit hst pcs mod do_rn
 307   = do
 308         let prs = pcs_PRS pcs
 309         let pte = pcs_PTE pcs
 310         let ifaces = Ifaces { iPIT   = pcs_PIT pcs,
 311                               iDecls = prsDecls prs,
 312                               iInsts = prsInsts prs,
 313                               iRules = prsRules prs,
 314
 315                               iImpModInfo = emptyFM,
 316                               iSlurp      = unitNameSet (mkUnboundName dummyRdrVarName),
 317                                 -- Pretend that the dummy unbound name has already been
 318                                 -- slurped.  This is what's returned for an out-of-scope name,
 319                                 -- and we don't want thereby to try to suck it in!
 320                               iVSlurp = (emptyModuleSet, emptyNameSet)
 321                       }
 322         let uniqs = prsNS prs
 323
 324         names_var <- newIORef (uniqs, origNames (prsOrig prs),
 325                                       origIParam (prsOrig prs))
 326         errs_var  <- newIORef (emptyBag,emptyBag)
 327         iface_var <- newIORef ifaces
 328         let rn_down = RnDown { rn_mod = mod,
 329                                rn_loc = noSrcLoc,
 330
 331                                rn_dflags = dflags,
 332                                rn_hit    = hit,
 333                                rn_done   = is_done hst pte,
 334
 335                                rn_ns     = names_var,
 336                                rn_errs   = errs_var,
 337                                rn_ifaces = iface_var,
 338                              }
 339
 340         -- do the business
 341         res <- do_rn rn_down ()
 342
 343         -- Grab state and record it
 344         (warns, errs)                   <- readIORef errs_var
 345         new_ifaces                      <- readIORef iface_var
 346         (new_NS, new_origN, new_origIP) <- readIORef names_var
 347         let new_orig = Orig { origNames = new_origN, origIParam = new_origIP }
 348         let new_prs = prs { prsOrig = new_orig,
 349                             prsDecls = iDecls new_ifaces,
 350                             prsInsts = iInsts new_ifaces,
 351                             prsRules = iRules new_ifaces,
 352                             prsNS    = new_NS }
 353         let new_pcs = pcs { pcs_PIT = iPIT new_ifaces,
 354                             pcs_PRS = new_prs }
 355
 356         -- Check for warnings
 357         printErrorsAndWarnings (warns, errs) ;
 358
 359         return (new_pcs, not (isEmptyBag errs), res)
 360
 361 is_done :: HomeSymbolTable -> PackageTypeEnv -> Name -> Bool
 362 -- Returns True iff the name is in either symbol table
 363 is_done hst pte n = maybeToBool (lookupType hst pte n)
 364
 365 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 366   = let
 367         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 368                          rn_fixenv = fixity_env, rn_mode = mode }
 369     in
 370     thing_inside rn_down s_down
 371
 372 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 373 initIfaceRnMS mod thing_inside
 374   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 375     setModuleRn mod thing_inside
 376
 377 \end{code}
 378
 379 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 380 that is, not as part of the main renamer.
 381 Sole examples: derived definitions,
 382 which are only generated in the type checker.
 383
 384 The @NameSupply@ includes a @UniqueSupply@, so if you call it more than
 385 once you must either split it, or install a fresh unique supply.
 386
 387 \begin{code}
 388 renameSourceCode :: DynFlags
 389                  -> Module
 390                  -> PersistentRenamerState
 391                  -> RnMS r
 392                  -> r
 393
 394 renameSourceCode dflags mod prs m
 395   = unsafePerformIO (
 396         -- It's not really unsafe!  When renaming source code we
 397         -- only do any I/O if we need to read in a fixity declaration;
 398         -- and that doesn't happen in pragmas etc
 399
 400         mkSplitUniqSupply 'r'                           >>= \ new_us ->
 401         newIORef (new_us, origNames (prsOrig prs),
 402                           origIParam (prsOrig prs))     >>= \ names_var ->
 403         newIORef (emptyBag,emptyBag)                    >>= \ errs_var ->
 404         let
 405             rn_down = RnDown { rn_dflags = dflags,
 406                                rn_loc = generatedSrcLoc, rn_ns = names_var,
 407                                rn_errs = errs_var,
 408                                rn_mod = mod,
 409                                rn_done   = bogus "rn_done",     rn_hit    = bogus "rn_hit",
 410                                rn_ifaces = bogus "rn_ifaces"
 411                              }
 412             s_down = SDown { rn_mode = InterfaceMode,
 413                                -- So that we can refer to PrelBase.True etc
 414                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 415                              rn_fixenv = emptyNameEnv }
 416         in
 417         m rn_down s_down                        >>= \ result ->
 418
 419         readIORef errs_var                      >>= \ (warns,errs) ->
 420
 421         (if not (isEmptyBag errs) then
 422                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 423 #ifdef DEBUG
 424          else if not (isEmptyBag warns) then
 425                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 426 #endif
 427          else
 428                 id) $
 429
 430         return result
 431     )
 432   where
 433     display errs = pprBagOfErrors errs
 434
 435 bogus s = panic ("rnameSourceCode: " ++ s)  -- Used for unused record fields
 436
 437 {-# INLINE thenRn #-}
 438 {-# INLINE thenRn_ #-}
 439 {-# INLINE returnRn #-}
 440 {-# INLINE andRn #-}
 441
 442 returnRn :: a -> RnM d a
 443 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 444 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 445 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 446 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 447 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 448 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 449 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 450 sequenceRn :: [RnM d a] -> RnM d [a]
 451 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 452 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 453 fixRn    :: (a -> RnM d a) -> RnM d a
 454
 455 returnRn v gdown ldown  = return v
 456 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 457 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 458 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 459 andRn combiner m1 m2 gdown ldown
 460   = m1 gdown ldown >>= \ res1 ->
 461     m2 gdown ldown >>= \ res2 ->
 462     return (combiner res1 res2)
 463
 464 sequenceRn []     = returnRn []
 465 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 466                      sequenceRn ms      `thenRn` \ rs ->
 467                      returnRn (r:rs)
 468
 469 mapRn f []     = returnRn []
 470 mapRn f (x:xs)
 471   = f x         `thenRn` \ r ->
 472     mapRn f xs  `thenRn` \ rs ->
 473     returnRn (r:rs)
 474
 475 mapRn_ f []     = returnRn ()
 476 mapRn_ f (x:xs) =
 477     f x         `thenRn_`
 478     mapRn_ f xs
 479
 480 foldlRn k z [] = returnRn z
 481 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 482                      foldlRn k z' xs
 483
 484 mapAndUnzipRn f [] = returnRn ([],[])
 485 mapAndUnzipRn f (x:xs)
 486   = f x                 `thenRn` \ (r1,  r2)  ->
 487     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 488     returnRn (r1:rs1, r2:rs2)
 489
 490 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 491 mapAndUnzip3Rn f (x:xs)
 492   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 493     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 494     returnRn (r1:rs1, r2:rs2, r3:rs3)
 495
 496 mapMaybeRn f []     = returnRn []
 497 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 498                       mapMaybeRn f xs   `thenRn` \ rs ->
 499                       case maybe_r of
 500                         Nothing -> returnRn rs
 501                         Just r  -> returnRn (r:rs)
 502
 503 flatMapRn f []     = returnRn []
 504 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 505                      flatMapRn f xs     `thenRn` \ rs ->
 506                      returnRn (r ++ rs)
 507 \end{code}
 508
 509
 510
 511 %************************************************************************
 512 %*                                                                      *
 513 \subsection{Boring plumbing for common part}
 514 %*                                                                      *
 515 %************************************************************************
 516
 517
 518 %================
 519 \subsubsection{  Errors and warnings}
 520 %=====================
 521
 522 \begin{code}
 523 failWithRn :: a -> Message -> RnM d a
 524 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 525   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 526     writeIORef errs_var (warns, errs `snocBag` err)             >>
 527     return res
 528   where
 529     err = addShortErrLocLine loc msg
 530
 531 warnWithRn :: a -> Message -> RnM d a
 532 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 533   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 534     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 535     return res
 536   where
 537     warn = addShortWarnLocLine loc msg
 538
 539 addErrRn :: Message -> RnM d ()
 540 addErrRn err = failWithRn () err
 541
 542 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 543 checkRn False err = addErrRn err
 544 checkRn True  err = returnRn ()
 545
 546 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 547 warnCheckRn False err = addWarnRn err
 548 warnCheckRn True  err = returnRn ()
 549
 550 addWarnRn :: Message -> RnM d ()
 551 addWarnRn warn = warnWithRn () warn
 552
 553 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 554 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 555   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 556     return (isEmptyBag errs)
 557
 558 doptRn :: DynFlag -> RnM d Bool
 559 doptRn dflag (RnDown { rn_dflags = dflags}) l_down
 560    = return (dopt dflag dflags)
 561
 562 getDOptsRn :: RnM d DynFlags
 563 getDOptsRn (RnDown { rn_dflags = dflags}) l_down
 564    = return dflags
 565 \end{code}
 566
 567
 568 %================
 569 \subsubsection{Source location}
 570 %=====================
 571
 572 \begin{code}
 573 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 574 pushSrcLocRn loc' m down l_down
 575   = m (down {rn_loc = loc'}) l_down
 576
 577 getSrcLocRn :: RnM d SrcLoc
 578 getSrcLocRn down l_down
 579   = return (rn_loc down)
 580 \end{code}
 581
 582 %================
 583 \subsubsection{The finder and home symbol table}
 584 %=====================
 585
 586 \begin{code}
 587 getHomeIfaceTableRn :: RnM d HomeIfaceTable
 588 getHomeIfaceTableRn down l_down = return (rn_hit down)
 589
 590 checkAlreadyAvailable :: Name -> RnM d Bool
 591 checkAlreadyAvailable name down l_down = return (rn_done down name)
 592 \end{code}
 593
 594 %================
 595 \subsubsection{Name supply}
 596 %=====================
 597
 598 \begin{code}
 599 getNameSupplyRn :: RnM d (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv)
 600 getNameSupplyRn rn_down l_down
 601   = readIORef (rn_ns rn_down)
 602
 603 setNameSupplyRn :: (UniqSupply, OrigNameNameEnv, OrigNameIParamEnv) -> RnM d ()
 604 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 605   = writeIORef names_var names'
 606
 607 getUniqRn :: RnM d Unique
 608 getUniqRn (RnDown {rn_ns = names_var}) l_down
 609  = readIORef names_var >>= \ (us, cache, ipcache) ->
 610    let
 611      (us1,us') = splitUniqSupply us
 612    in
 613    writeIORef names_var (us', cache, ipcache)  >>
 614    return (uniqFromSupply us1)
 615 \end{code}
 616
 617 %================
 618 \subsubsection{  Module}
 619 %=====================
 620
 621 \begin{code}
 622 getModuleRn :: RnM d Module
 623 getModuleRn (RnDown {rn_mod = mod}) l_down
 624   = return mod
 625
 626 setModuleRn :: Module -> RnM d a -> RnM d a
 627 setModuleRn new_mod enclosed_thing rn_down l_down
 628   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 629 \end{code}
 630
 631
 632 %************************************************************************
 633 %*                                                                      *
 634 \subsection{Plumbing for rename-source part}
 635 %*                                                                      *
 636 %************************************************************************
 637
 638 %================
 639 \subsubsection{  RnEnv}
 640 %=====================
 641
 642 \begin{code}
 643 getLocalNameEnv :: RnMS LocalRdrEnv
 644 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 645   = return local_env
 646
 647 getGlobalNameEnv :: RnMS GlobalRdrEnv
 648 getGlobalNameEnv rn_down (SDown {rn_genv = global_env})
 649   = return global_env
 650
 651 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 652 setLocalNameEnv local_env' m rn_down l_down
 653   = m rn_down (l_down {rn_lenv = local_env'})
 654
 655 getFixityEnv :: RnMS LocalFixityEnv
 656 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 657   = return fixity_env
 658
 659 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 660 extendFixityEnv fixes enclosed_scope
 661                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 662   = let
 663         new_fixity_env = extendNameEnvList fixity_env fixes
 664     in
 665     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 666 \end{code}
 667
 668 %================
 669 \subsubsection{  Mode}
 670 %=====================
 671
 672 \begin{code}
 673 getModeRn :: RnMS RnMode
 674 getModeRn rn_down (SDown {rn_mode = mode})
 675   = return mode
 676
 677 setModeRn :: RnMode -> RnMS a -> RnMS a
 678 setModeRn new_mode thing_inside rn_down l_down
 679   = thing_inside rn_down (l_down {rn_mode = new_mode})
 680 \end{code}
 681
 682
 683 %************************************************************************
 684 %*                                                                      *
 685 \subsection{Plumbing for rename-globals part}
 686 %*                                                                      *
 687 %************************************************************************
 688
 689 \begin{code}
 690 getIfacesRn :: RnM d Ifaces
 691 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 692   = readIORef iface_var
 693
 694 setIfacesRn :: Ifaces -> RnM d ()
 695 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 696   = writeIORef iface_var ifaces
 697 \end{code}