ghc/compiler/rename/RnMonad.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnMonad]{The monad used by the renamer}
   5
   6 \begin{code}
   7 module RnMonad(
   8         module RnMonad,
   9         Module,
  10         FiniteMap,
  11         Bag,
  12         Name,
  13         RdrNameHsDecl,
  14         RdrNameInstDecl,
  15         Version,
  16         NameSet,
  17         OccName,
  18         Fixity
  19     ) where
  20
  21 #include "HsVersions.h"
  22
  23 #if   defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 405
  24 import IOExts           ( fixIO )
  25 #elif defined(__GLASGOW_HASKELL__) && __GLASGOW_HASKELL__ >= 302
  26 import PrelIOBase       ( fixIO )       -- Should be in GlaExts
  27 #else
  28 import IOBase           ( fixIO )
  29 #endif
  30 import IOExts           ( IORef, newIORef, readIORef, writeIORef, unsafePerformIO )
  31
  32 import HsSyn
  33 import RdrHsSyn
  34 import RnHsSyn          ( RenamedFixitySig, RenamedDeprecation )
  35 import BasicTypes       ( Version )
  36 import SrcLoc           ( noSrcLoc )
  37 import ErrUtils         ( addShortErrLocLine, addShortWarnLocLine,
  38                           pprBagOfErrors, ErrMsg, WarnMsg, Message
  39                         )
  40 import Name             ( Name, OccName, NamedThing(..),
  41                           isLocallyDefinedName, nameModule, nameOccName,
  42                           decode, mkLocalName, mkUnboundName
  43                         )
  44 import Module           ( Module, ModuleName, ModuleHiMap, SearchPath, WhereFrom,
  45                           mkModuleHiMaps, moduleName, mkVanillaModule, mkSearchPath
  46                         )
  47 import NameSet
  48 import RdrName          ( RdrName, dummyRdrVarName, rdrNameOcc )
  49 import CmdLineOpts      ( opt_D_dump_rn_trace, opt_HiMap )
  50 import PrelInfo         ( builtinNames )
  51 import TysWiredIn       ( boolTyCon )
  52 import SrcLoc           ( SrcLoc, mkGeneratedSrcLoc )
  53 import Unique           ( Unique, getUnique, unboundKey )
  54 import UniqFM           ( UniqFM )
  55 import FiniteMap        ( FiniteMap, emptyFM, bagToFM, lookupFM, addToFM, addListToFM,
  56                           addListToFM_C, addToFM_C, eltsFM, fmToList
  57                         )
  58 import Bag              ( Bag, mapBag, emptyBag, isEmptyBag, snocBag )
  59 import Maybes           ( mapMaybe )
  60 import UniqSet
  61 import UniqFM
  62 import UniqSupply
  63 import Util
  64 import Outputable
  65
  66 infixr 9 `thenRn`, `thenRn_`
  67 \end{code}
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Somewhat magical interface to other monads}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 ioToRnM :: IO r -> RnM d (Either IOError r)
  78 ioToRnM io rn_down g_down = (io >>= \ ok -> return (Right ok))
  79                             `catch`
  80                             (\ err -> return (Left err))
  81
  82 traceRn :: SDoc -> RnM d ()
  83 traceRn msg | opt_D_dump_rn_trace = putDocRn msg
  84             | otherwise           = returnRn ()
  85
  86 putDocRn :: SDoc -> RnM d ()
  87 putDocRn msg = ioToRnM (printErrs msg)  `thenRn_`
  88                returnRn ()
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{Data types}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 %===================================================
  99 \subsubsection{         MONAD TYPES}
 100 %===================================================
 101
 102 \begin{code}
 103 type RnM d r = RnDown -> d -> IO r
 104 type RnMS r  = RnM SDown r              -- Renaming source
 105 type RnMG r  = RnM ()    r              -- Getting global names etc
 106
 107         -- Common part
 108 data RnDown = RnDown {
 109                   rn_mod     :: ModuleName,
 110                   rn_loc     :: SrcLoc,
 111                   rn_ns      :: IORef RnNameSupply,
 112                   rn_errs    :: IORef (Bag WarnMsg, Bag ErrMsg),
 113                   rn_ifaces  :: IORef Ifaces,
 114                   rn_hi_maps :: (ModuleHiMap,   -- for .hi files
 115                                  ModuleHiMap)   -- for .hi-boot files
 116                 }
 117
 118         -- For renaming source code
 119 data SDown = SDown {
 120                   rn_mode :: RnMode,
 121
 122                   rn_genv :: GlobalRdrEnv,
 123                         --   Global envt; the fixity component gets extended
 124                         --   with local fixity decls
 125
 126                   rn_lenv :: LocalRdrEnv,       -- Local name envt
 127                         --   Does *not* include global name envt; may shadow it
 128                         --   Includes both ordinary variables and type variables;
 129                         --   they are kept distinct because tyvar have a different
 130                         --   occurrence contructor (Name.TvOcc)
 131                         -- We still need the unsullied global name env so that
 132                         --   we can look up record field names
 133
 134                   rn_fixenv :: FixityEnv        -- Local fixities
 135                         -- The global fixities are held in the
 136                         -- rn_ifaces field.  Why?  See the comments
 137                         -- with RnIfaces.lookupFixity
 138                 }
 139
 140 data RnMode     = SourceMode                    -- Renaming source code
 141                 | InterfaceMode                 -- Renaming interface declarations.
 142 \end{code}
 143
 144 %===================================================
 145 \subsubsection{         ENVIRONMENTS}
 146 %===================================================
 147
 148 \begin{code}
 149 --------------------------------
 150 type RdrNameEnv a = FiniteMap RdrName a
 151 type GlobalRdrEnv = RdrNameEnv [Name]   -- The list is because there may be name clashes
 152                                         -- These only get reported on lookup,
 153                                         -- not on construction
 154 type LocalRdrEnv  = RdrNameEnv Name
 155
 156 emptyRdrEnv  :: RdrNameEnv a
 157 lookupRdrEnv :: RdrNameEnv a -> RdrName -> Maybe a
 158 addListToRdrEnv :: RdrNameEnv a -> [(RdrName,a)] -> RdrNameEnv a
 159 extendRdrEnv    :: RdrNameEnv a -> RdrName -> a -> RdrNameEnv a
 160
 161 emptyRdrEnv  = emptyFM
 162 lookupRdrEnv = lookupFM
 163 addListToRdrEnv = addListToFM
 164 rdrEnvElts      = eltsFM
 165 extendRdrEnv    = addToFM
 166 rdrEnvToList    = fmToList
 167
 168 --------------------------------
 169 type NameEnv a = UniqFM a       -- Domain is Name
 170
 171 emptyNameEnv   :: NameEnv a
 172 nameEnvElts    :: NameEnv a -> [a]
 173 addToNameEnv_C :: (a->a->a) -> NameEnv a -> Name -> a -> NameEnv a
 174 addToNameEnv   :: NameEnv a -> Name -> a -> NameEnv a
 175 plusNameEnv    :: NameEnv a -> NameEnv a -> NameEnv a
 176 plusNameEnv_C  :: (a->a->a) -> NameEnv a -> NameEnv a -> NameEnv a
 177 extendNameEnv  :: NameEnv a -> [(Name,a)] -> NameEnv a
 178 lookupNameEnv  :: NameEnv a -> Name -> Maybe a
 179 delFromNameEnv :: NameEnv a -> Name -> NameEnv a
 180 elemNameEnv    :: Name -> NameEnv a -> Bool
 181 unitNameEnv    :: Name -> a -> NameEnv a
 182
 183 emptyNameEnv   = emptyUFM
 184 nameEnvElts    = eltsUFM
 185 addToNameEnv_C = addToUFM_C
 186 addToNameEnv   = addToUFM
 187 plusNameEnv    = plusUFM
 188 plusNameEnv_C  = plusUFM_C
 189 extendNameEnv  = addListToUFM
 190 lookupNameEnv  = lookupUFM
 191 delFromNameEnv = delFromUFM
 192 elemNameEnv    = elemUFM
 193 unitNameEnv    = unitUFM
 194
 195 --------------------------------
 196 type FixityEnv = NameEnv RenamedFixitySig
 197         -- We keep the whole fixity sig so that we
 198         -- can report line-number info when there is a duplicate
 199         -- fixity declaration
 200
 201 --------------------------------
 202 type DeprecationEnv = NameEnv DeprecTxt
 203 \end{code}
 204
 205 \begin{code}
 206 --------------------------------
 207 type RnNameSupply
 208  = ( UniqSupply
 209
 210    , FiniteMap String Int
 211         -- This is used as a name supply for dictionary functions
 212         -- From the inst decl we derive a string, usually by glomming together
 213         -- the class and tycon name -- but it doesn't matter exactly how;
 214         -- this map then gives a unique int for each inst decl with that
 215         -- string.  (In Haskell 98 there can only be one,
 216         -- but not so in more extended versions; also class CC type T
 217         -- and class C type TT might both give the string CCT
 218         --
 219         -- We could just use one Int for all the instance decls, but this
 220         -- way the uniques change less when you add an instance decl,
 221         -- hence less recompilation
 222
 223    , FiniteMap (ModuleName, OccName) Name
 224         -- Ensures that one (module,occname) pair gets one unique
 225    , FiniteMap OccName Name
 226         -- Ensures that one implicit parameter name gets one unique
 227    )
 228
 229
 230 --------------------------------
 231 data ExportEnv    = ExportEnv Avails Fixities [ModuleName]
 232                         -- The list of modules is the modules exported
 233                         -- with 'module M' in the export list
 234
 235 type Avails       = [AvailInfo]
 236 type Fixities     = [(Name, Fixity)]
 237
 238 type ExportAvails = (FiniteMap ModuleName Avails,
 239         -- Used to figure out "module M" export specifiers
 240         -- Includes avails only from *unqualified* imports
 241         -- (see 1.4 Report Section 5.1.1)
 242
 243                      AvailEnv)  -- Used to figure out all other export specifiers.
 244
 245
 246 data GenAvailInfo name  = Avail name     -- An ordinary identifier
 247                         | AvailTC name   -- The name of the type or class
 248                                   [name] -- The available pieces of type/class.
 249                                          -- NB: If the type or class is itself
 250                                          -- to be in scope, it must be in this list.
 251                                          -- Thus, typically: AvailTC Eq [Eq, ==, /=]
 252
 253 type AvailEnv     = NameEnv AvailInfo   -- Maps a Name to the AvailInfo that contains it
 254 type AvailInfo    = GenAvailInfo Name
 255 type RdrAvailInfo = GenAvailInfo OccName
 256 \end{code}
 257
 258 %===================================================
 259 \subsubsection{         INTERFACE FILE STUFF}
 260 %===================================================
 261
 262 \begin{code}
 263 type ExportItem          = (ModuleName, [RdrAvailInfo])
 264 type VersionInfo name    = [ImportVersion name]
 265
 266 type ImportVersion name  = (ModuleName, Version,
 267                             WhetherHasOrphans, IsBootInterface, WhatsImported name)
 268
 269 type WhetherHasOrphans   = Bool
 270         -- An "orphan" is
 271         --      * an instance decl in a module other than the defn module for
 272         --              one of the tycons or classes in the instance head
 273         --      * a transformation rule in a module other than the one defining
 274         --              the function in the head of the rule.
 275
 276 type IsBootInterface     = Bool
 277
 278 data WhatsImported name  = Everything
 279                          | Specifically [LocalVersion name] -- List guaranteed non-empty
 280
 281     -- ("M", hif, ver, Everything) means there was a "module M" in
 282     -- this module's export list, so we just have to go by M's version, "ver",
 283     -- not the list of LocalVersions.
 284
 285
 286 type LocalVersion name   = (name, Version)
 287
 288 data ParsedIface
 289   = ParsedIface {
 290       pi_mod       :: Version,                          -- Module version number
 291       pi_orphan    :: WhetherHasOrphans,                -- Whether this module has orphans
 292       pi_usages    :: [ImportVersion OccName],          -- Usages
 293       pi_exports   :: [ExportItem],                     -- Exports
 294       pi_decls     :: [(Version, RdrNameHsDecl)],       -- Local definitions
 295       pi_insts     :: [RdrNameInstDecl],                -- Local instance declarations
 296       pi_rules     :: [RdrNameRuleDecl],                -- Rules
 297       pi_deprecs   :: [RdrNameDeprecation]              -- Deprecations
 298     }
 299
 300 data InterfaceDetails
 301    = InterfaceDetails WhetherHasOrphans
 302                       (VersionInfo Name)   -- Version information for what this module imports
 303                       ExportEnv            -- What modules this one depends on
 304                       [Deprecation Name]
 305
 306
 307 -- needed by Main to fish out the fixities assoc list.
 308 getIfaceFixities :: InterfaceDetails -> Fixities
 309 getIfaceFixities (InterfaceDetails _ _ (ExportEnv _ fs _) _) = fs
 310
 311
 312 type RdrNamePragma = ()                         -- Fudge for now
 313 -------------------
 314
 315 data Ifaces = Ifaces {
 316                 iImpModInfo :: ImportedModuleInfo,
 317                                 -- Modules this one depends on: that is, the union
 318                                 -- of the modules its *direct* imports depend on.
 319                                 -- NB: The direct imports have .hi files that enumerate *all* the
 320                                 -- dependencies (direct or not) of the imported module.
 321
 322                 iDecls :: DeclsMap,     -- A single, global map of Names to decls
 323
 324                 iFixes :: FixityEnv,    -- A single, global map of Names to fixities
 325                                         -- See comments with RnIfaces.lookupFixity
 326
 327                 iSlurp :: NameSet,
 328                 -- All the names (whether "big" or "small", whether wired-in or not,
 329                 -- whether locally defined or not) that have been slurped in so far.
 330
 331                 iVSlurp :: [(Name,Version)],
 332                 -- All the (a) non-wired-in (b) "big" (c) non-locally-defined
 333                 -- names that have been slurped in so far, with their versions.
 334                 -- This is used to generate the "usage" information for this module.
 335                 -- Subset of the previous field.
 336
 337                 iInsts :: Bag GatedDecl,
 338                 -- The as-yet un-slurped instance decls; this bag is depleted when we
 339                 -- slurp an instance decl so that we don't slurp the same one twice.
 340                 -- Each is 'gated' by the names that must be available before
 341                 -- this instance decl is needed.
 342
 343                 iRules :: Bag GatedDecl,
 344                         -- Ditto transformation rules
 345
 346                 iDeprecs :: DeprecationEnv
 347         }
 348
 349 type GatedDecl = (NameSet, (Module, RdrNameHsDecl))
 350
 351 type ImportedModuleInfo
 352      = FiniteMap ModuleName (Version, WhetherHasOrphans, IsBootInterface, Maybe (Module, Avails))
 353                 -- Suppose the domain element is module 'A'
 354                 --
 355                 -- The first Bool is True if A contains
 356                 -- 'orphan' rules or instance decls
 357
 358                 -- The second Bool is true if the interface file actually
 359                 -- read was an .hi-boot file
 360
 361                 -- Nothing => A's interface not yet read, but this module has
 362                 --            imported a module, B, that itself depends on A
 363                 --
 364                 -- Just xx => A's interface has been read.  The Module in
 365                 --              the Just has the correct Dll flag
 366
 367                 -- This set is used to decide whether to look for
 368                 -- A.hi or A.hi-boot when importing A.f.
 369                 -- Basically, we look for A.hi if A is in the map, and A.hi-boot
 370                 -- otherwise
 371
 372 type DeclsMap = NameEnv (Version, AvailInfo, Bool, (Module, RdrNameHsDecl))
 373                 -- A DeclsMap contains a binding for each Name in the declaration
 374                 -- including the constructors of a type decl etc.
 375                 -- The Bool is True just for the 'main' Name.
 376 \end{code}
 377
 378
 379 %************************************************************************
 380 %*                                                                      *
 381 \subsection{Main monad code}
 382 %*                                                                      *
 383 %************************************************************************
 384
 385 \begin{code}
 386 initRn :: ModuleName -> UniqSupply -> SearchPath -> SrcLoc
 387        -> RnMG r
 388        -> IO (r, Bag ErrMsg, Bag WarnMsg)
 389
 390 initRn mod us dirs loc do_rn = do
 391   himaps    <- mkModuleHiMaps dirs
 392   names_var <- newIORef (us, emptyFM, builtins, emptyFM)
 393   errs_var  <- newIORef (emptyBag,emptyBag)
 394   iface_var <- newIORef emptyIfaces
 395   let
 396         rn_down = RnDown { rn_loc = loc, rn_ns = names_var,
 397                            rn_errs = errs_var,
 398                            rn_hi_maps = himaps,
 399                            rn_ifaces = iface_var,
 400                            rn_mod = mod }
 401
 402         -- do the business
 403   res <- do_rn rn_down ()
 404
 405         -- grab errors and return
 406   (warns, errs) <- readIORef errs_var
 407
 408   return (res, errs, warns)
 409
 410
 411 initRnMS :: GlobalRdrEnv -> FixityEnv -> RnMode -> RnMS r -> RnM d r
 412 initRnMS rn_env fixity_env mode thing_inside rn_down g_down
 413   = let
 414         s_down = SDown { rn_genv = rn_env, rn_lenv = emptyRdrEnv,
 415                          rn_fixenv = fixity_env, rn_mode = mode }
 416     in
 417     thing_inside rn_down s_down
 418
 419 initIfaceRnMS :: Module -> RnMS r -> RnM d r
 420 initIfaceRnMS mod thing_inside
 421   = initRnMS emptyRdrEnv emptyNameEnv InterfaceMode $
 422     setModuleRn (moduleName mod) thing_inside
 423
 424 emptyIfaces :: Ifaces
 425 emptyIfaces = Ifaces { iImpModInfo = emptyFM,
 426                        iDecls = emptyNameEnv,
 427                        iFixes = emptyNameEnv,
 428                        iSlurp = unitNameSet (mkUnboundName dummyRdrVarName),
 429                         -- Pretend that the dummy unbound name has already been
 430                         -- slurped.  This is what's returned for an out-of-scope name,
 431                         -- and we don't want thereby to try to suck it in!
 432                        iVSlurp = [],
 433                        iInsts = emptyBag,
 434                        iRules = emptyBag,
 435                        iDeprecs = emptyNameEnv
 436               }
 437
 438 builtins :: FiniteMap (ModuleName,OccName) Name
 439 builtins =
 440    bagToFM (
 441    mapBag (\ name ->  ((moduleName (nameModule name), nameOccName name), name))
 442           builtinNames)
 443 \end{code}
 444
 445 @renameSourceCode@ is used to rename stuff ``out-of-line'';
 446 that is, not as part of the main renamer.
 447 Sole examples: derived definitions,
 448 which are only generated in the type checker.
 449
 450 The @RnNameSupply@ includes a @UniqueSupply@, so if you call it more than
 451 once you must either split it, or install a fresh unique supply.
 452
 453 \begin{code}
 454 renameSourceCode :: ModuleName
 455                  -> RnNameSupply
 456                  -> RnMS r
 457                  -> r
 458
 459 renameSourceCode mod_name name_supply m
 460   = unsafePerformIO (
 461         -- It's not really unsafe!  When renaming source code we
 462         -- only do any I/O if we need to read in a fixity declaration;
 463         -- and that doesn't happen in pragmas etc
 464
 465         mkModuleHiMaps (mkSearchPath opt_HiMap) >>= \ himaps ->
 466         newIORef name_supply            >>= \ names_var ->
 467         newIORef (emptyBag,emptyBag)    >>= \ errs_var ->
 468         let
 469             rn_down = RnDown { rn_loc = mkGeneratedSrcLoc, rn_ns = names_var,
 470                                rn_errs = errs_var, rn_hi_maps = himaps,
 471                                rn_mod = mod_name,
 472                                rn_ifaces = panic "rnameSourceCode: rn_ifaces"  -- Not required
 473                              }
 474             s_down = SDown { rn_mode = InterfaceMode,
 475                                -- So that we can refer to PrelBase.True etc
 476                              rn_genv = emptyRdrEnv, rn_lenv = emptyRdrEnv,
 477                              rn_fixenv = emptyNameEnv }
 478         in
 479         m rn_down s_down                        >>= \ result ->
 480
 481         readIORef errs_var                      >>= \ (warns,errs) ->
 482
 483         (if not (isEmptyBag errs) then
 484                 pprTrace "Urk! renameSourceCode found errors" (display errs)
 485 #ifdef DEBUG
 486          else if not (isEmptyBag warns) then
 487                 pprTrace "Note: renameSourceCode found warnings" (display warns)
 488 #endif
 489          else
 490                 id) $
 491
 492         return result
 493     )
 494   where
 495     display errs = pprBagOfErrors errs
 496
 497 {-# INLINE thenRn #-}
 498 {-# INLINE thenRn_ #-}
 499 {-# INLINE returnRn #-}
 500 {-# INLINE andRn #-}
 501
 502 returnRn :: a -> RnM d a
 503 thenRn   :: RnM d a -> (a -> RnM d b) -> RnM d b
 504 thenRn_  :: RnM d a -> RnM d b -> RnM d b
 505 andRn    :: (a -> a -> a) -> RnM d a -> RnM d a -> RnM d a
 506 mapRn    :: (a -> RnM d b) -> [a] -> RnM d [b]
 507 mapRn_   :: (a -> RnM d b) -> [a] -> RnM d ()
 508 mapMaybeRn :: (a -> RnM d (Maybe b)) -> [a] -> RnM d [b]
 509 flatMapRn  :: (a -> RnM d [b])       -> [a] -> RnM d [b]
 510 sequenceRn :: [RnM d a] -> RnM d [a]
 511 foldlRn :: (b  -> a -> RnM d b) -> b -> [a] -> RnM d b
 512 mapAndUnzipRn :: (a -> RnM d (b,c)) -> [a] -> RnM d ([b],[c])
 513 fixRn    :: (a -> RnM d a) -> RnM d a
 514
 515 returnRn v gdown ldown  = return v
 516 thenRn m k gdown ldown  = m gdown ldown >>= \ r -> k r gdown ldown
 517 thenRn_ m k gdown ldown = m gdown ldown >> k gdown ldown
 518 fixRn m gdown ldown = fixIO (\r -> m r gdown ldown)
 519 andRn combiner m1 m2 gdown ldown
 520   = m1 gdown ldown >>= \ res1 ->
 521     m2 gdown ldown >>= \ res2 ->
 522     return (combiner res1 res2)
 523
 524 sequenceRn []     = returnRn []
 525 sequenceRn (m:ms) =  m                  `thenRn` \ r ->
 526                      sequenceRn ms      `thenRn` \ rs ->
 527                      returnRn (r:rs)
 528
 529 mapRn f []     = returnRn []
 530 mapRn f (x:xs)
 531   = f x         `thenRn` \ r ->
 532     mapRn f xs  `thenRn` \ rs ->
 533     returnRn (r:rs)
 534
 535 mapRn_ f []     = returnRn ()
 536 mapRn_ f (x:xs) =
 537     f x         `thenRn_`
 538     mapRn_ f xs
 539
 540 foldlRn k z [] = returnRn z
 541 foldlRn k z (x:xs) = k z x      `thenRn` \ z' ->
 542                      foldlRn k z' xs
 543
 544 mapAndUnzipRn f [] = returnRn ([],[])
 545 mapAndUnzipRn f (x:xs)
 546   = f x                 `thenRn` \ (r1,  r2)  ->
 547     mapAndUnzipRn f xs  `thenRn` \ (rs1, rs2) ->
 548     returnRn (r1:rs1, r2:rs2)
 549
 550 mapAndUnzip3Rn f [] = returnRn ([],[],[])
 551 mapAndUnzip3Rn f (x:xs)
 552   = f x                 `thenRn` \ (r1,  r2,  r3)  ->
 553     mapAndUnzip3Rn f xs `thenRn` \ (rs1, rs2, rs3) ->
 554     returnRn (r1:rs1, r2:rs2, r3:rs3)
 555
 556 mapMaybeRn f []     = returnRn []
 557 mapMaybeRn f (x:xs) = f x               `thenRn` \ maybe_r ->
 558                       mapMaybeRn f xs   `thenRn` \ rs ->
 559                       case maybe_r of
 560                         Nothing -> returnRn rs
 561                         Just r  -> returnRn (r:rs)
 562
 563 flatMapRn f []     = returnRn []
 564 flatMapRn f (x:xs) = f x                `thenRn` \ r ->
 565                      flatMapRn f xs     `thenRn` \ rs ->
 566                      returnRn (r ++ rs)
 567 \end{code}
 568
 569
 570
 571 %************************************************************************
 572 %*                                                                      *
 573 \subsection{Boring plumbing for common part}
 574 %*                                                                      *
 575 %************************************************************************
 576
 577
 578 %================
 579 \subsubsection{  Errors and warnings}
 580 %=====================
 581
 582 \begin{code}
 583 failWithRn :: a -> Message -> RnM d a
 584 failWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 585   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 586     writeIORef errs_var (warns, errs `snocBag` err)             >>
 587     return res
 588   where
 589     err = addShortErrLocLine loc msg
 590
 591 warnWithRn :: a -> Message -> RnM d a
 592 warnWithRn res msg (RnDown {rn_errs = errs_var, rn_loc = loc}) l_down
 593   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 594     writeIORef errs_var (warns `snocBag` warn, errs)    >>
 595     return res
 596   where
 597     warn = addShortWarnLocLine loc msg
 598
 599 addErrRn :: Message -> RnM d ()
 600 addErrRn err = failWithRn () err
 601
 602 checkRn :: Bool -> Message -> RnM d ()  -- Check that a condition is true
 603 checkRn False err = addErrRn err
 604 checkRn True  err = returnRn ()
 605
 606 warnCheckRn :: Bool -> Message -> RnM d ()      -- Check that a condition is true
 607 warnCheckRn False err = addWarnRn err
 608 warnCheckRn True  err = returnRn ()
 609
 610 addWarnRn :: Message -> RnM d ()
 611 addWarnRn warn = warnWithRn () warn
 612
 613 checkErrsRn :: RnM d Bool               -- True <=> no errors so far
 614 checkErrsRn (RnDown {rn_errs = errs_var}) l_down
 615   = readIORef  errs_var                                         >>=  \ (warns,errs) ->
 616     return (isEmptyBag errs)
 617 \end{code}
 618
 619
 620 %================
 621 \subsubsection{  Source location}
 622 %=====================
 623
 624 \begin{code}
 625 pushSrcLocRn :: SrcLoc -> RnM d a -> RnM d a
 626 pushSrcLocRn loc' m down l_down
 627   = m (down {rn_loc = loc'}) l_down
 628
 629 getSrcLocRn :: RnM d SrcLoc
 630 getSrcLocRn down l_down
 631   = return (rn_loc down)
 632 \end{code}
 633
 634 %================
 635 \subsubsection{  Name supply}
 636 %=====================
 637
 638 \begin{code}
 639 getNameSupplyRn :: RnM d RnNameSupply
 640 getNameSupplyRn rn_down l_down
 641   = readIORef (rn_ns rn_down)
 642
 643 setNameSupplyRn :: RnNameSupply -> RnM d ()
 644 setNameSupplyRn names' (RnDown {rn_ns = names_var}) l_down
 645   = writeIORef names_var names'
 646
 647 -- See comments with RnNameSupply above.
 648 newInstUniq :: String -> RnM d Int
 649 newInstUniq key (RnDown {rn_ns = names_var}) l_down
 650   = readIORef names_var                         >>= \ (us, mapInst, cache, ipcache) ->
 651     let
 652         uniq = case lookupFM mapInst key of
 653                    Just x  -> x+1
 654                    Nothing -> 0
 655         mapInst' = addToFM mapInst key uniq
 656     in
 657     writeIORef names_var (us, mapInst', cache, ipcache) >>
 658     return uniq
 659
 660 getUniqRn :: RnM d Unique
 661 getUniqRn (RnDown {rn_ns = names_var}) l_down
 662  = readIORef names_var >>= \ (us, mapInst, cache, ipcache) ->
 663    let
 664      (us1,us') = splitUniqSupply us
 665    in
 666    writeIORef names_var (us', mapInst, cache, ipcache)  >>
 667    return (uniqFromSupply us1)
 668 \end{code}
 669
 670 %================
 671 \subsubsection{  Module}
 672 %=====================
 673
 674 \begin{code}
 675 getModuleRn :: RnM d ModuleName
 676 getModuleRn (RnDown {rn_mod = mod_name}) l_down
 677   = return mod_name
 678
 679 setModuleRn :: ModuleName -> RnM d a -> RnM d a
 680 setModuleRn new_mod enclosed_thing rn_down l_down
 681   = enclosed_thing (rn_down {rn_mod = new_mod}) l_down
 682 \end{code}
 683
 684
 685 %************************************************************************
 686 %*                                                                      *
 687 \subsection{Plumbing for rename-source part}
 688 %*                                                                      *
 689 %************************************************************************
 690
 691 %================
 692 \subsubsection{  RnEnv}
 693 %=====================
 694
 695 \begin{code}
 696 getNameEnvs :: RnMS (GlobalRdrEnv, LocalRdrEnv)
 697 getNameEnvs rn_down (SDown {rn_genv = global_env, rn_lenv = local_env})
 698   = return (global_env, local_env)
 699
 700 getLocalNameEnv :: RnMS LocalRdrEnv
 701 getLocalNameEnv rn_down (SDown {rn_lenv = local_env})
 702   = return local_env
 703
 704 setLocalNameEnv :: LocalRdrEnv -> RnMS a -> RnMS a
 705 setLocalNameEnv local_env' m rn_down l_down
 706   = m rn_down (l_down {rn_lenv = local_env'})
 707
 708 getFixityEnv :: RnMS FixityEnv
 709 getFixityEnv rn_down (SDown {rn_fixenv = fixity_env})
 710   = return fixity_env
 711
 712 extendFixityEnv :: [(Name, RenamedFixitySig)] -> RnMS a -> RnMS a
 713 extendFixityEnv fixes enclosed_scope
 714                 rn_down l_down@(SDown {rn_fixenv = fixity_env})
 715   = let
 716         new_fixity_env = extendNameEnv fixity_env fixes
 717     in
 718     enclosed_scope rn_down (l_down {rn_fixenv = new_fixity_env})
 719 \end{code}
 720
 721 %================
 722 \subsubsection{  Mode}
 723 %=====================
 724
 725 \begin{code}
 726 getModeRn :: RnMS RnMode
 727 getModeRn rn_down (SDown {rn_mode = mode})
 728   = return mode
 729
 730 setModeRn :: RnMode -> RnMS a -> RnMS a
 731 setModeRn new_mode thing_inside rn_down l_down
 732   = thing_inside rn_down (l_down {rn_mode = new_mode})
 733 \end{code}
 734
 735
 736 %************************************************************************
 737 %*                                                                      *
 738 \subsection{Plumbing for rename-globals part}
 739 %*                                                                      *
 740 %************************************************************************
 741
 742 \begin{code}
 743 getIfacesRn :: RnM d Ifaces
 744 getIfacesRn (RnDown {rn_ifaces = iface_var}) _
 745   = readIORef iface_var
 746
 747 setIfacesRn :: Ifaces -> RnM d ()
 748 setIfacesRn ifaces (RnDown {rn_ifaces = iface_var}) _
 749   = writeIORef iface_var ifaces
 750
 751 getHiMaps :: RnM d (ModuleHiMap, ModuleHiMap)
 752 getHiMaps (RnDown {rn_hi_maps = himaps}) _
 753   = return himaps
 754 \end{code}
 755
 756 \begin{code}
 757 lookupModuleRn :: ModuleName -> RnM d Module
 758 lookupModuleRn x =
 759   getHiMaps `thenRn` \ (himap, _) ->
 760   case lookupFM himap x of
 761     Nothing    -> returnRn (mkVanillaModule x)
 762     Just (_,x) -> returnRn x
 763 \end{code}