ghc/compiler/rename/RnNames.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnNames]{Extracting imported and top-level names in scope}
   5
   6 \begin{code}
   7 module RnNames (
   8         rnImports, importsFromLocalDecls, exportsFromAvail,
   9         reportUnusedNames, mkModDeps
  10     ) where
  11
  12 #include "HsVersions.h"
  13
  14 import {-# SOURCE #-} RnHiFiles ( loadInterface )
  15
  16 import CmdLineOpts      ( DynFlag(..) )
  17
  18 import HsSyn            ( IE(..), ieName, ImportDecl(..),
  19                           ForeignDecl(..), HsGroup(..),
  20                           collectLocatedHsBinders, tyClDeclNames
  21                         )
  22 import RdrHsSyn         ( RdrNameIE, RdrNameImportDecl )
  23 import RnEnv
  24 import TcRnMonad
  25
  26 import FiniteMap
  27 import PrelNames        ( pRELUDE_Name, mAIN_Name, isBuiltInSyntaxName )
  28 import Module           ( Module, ModuleName, ModuleEnv, moduleName,
  29                           moduleNameUserString, isHomeModule,
  30                           emptyModuleEnv, unitModuleEnvByName, unitModuleEnv,
  31                           lookupModuleEnvByName, extendModuleEnvByName, moduleEnvElts )
  32 import Name             ( Name, nameSrcLoc, nameOccName, nameModule, isExternalName )
  33 import NameSet
  34 import NameEnv
  35 import OccName          ( OccName, dataName, isTcOcc )
  36 import HscTypes         ( Provenance(..), ImportReason(..), GlobalRdrEnv,
  37                           GenAvailInfo(..), AvailInfo, Avails,
  38                           IsBootInterface,
  39                           availName, availNames, availsToNameSet,
  40                           Deprecations(..), ModIface(..), Dependencies(..),
  41                           GlobalRdrElt(..), unQualInScope, isLocalGRE
  42                         )
  43 import RdrName          ( RdrName, rdrNameOcc, setRdrNameSpace,
  44                           emptyRdrEnv, foldRdrEnv, isQual )
  45 import Outputable
  46 import Maybes           ( maybeToBool, catMaybes )
  47 import ListSetOps       ( removeDups )
  48 import Util             ( sortLt, notNull )
  49 import List             ( partition, insert )
  50 import IO               ( openFile, IOMode(..) )
  51 \end{code}
  52
  53
  54
  55 %************************************************************************
  56 %*                                                                      *
  57                 rnImports
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 \begin{code}
  62 rnImports :: [RdrNameImportDecl]
  63           -> TcRn m (GlobalRdrEnv, ImportAvails)
  64
  65 rnImports imports
  66   =             -- PROCESS IMPORT DECLS
  67                 -- Do the non {- SOURCE -} ones first, so that we get a helpful
  68                 -- warning for {- SOURCE -} ones that are unnecessary
  69         getModule                               `thenM` \ this_mod ->
  70         getSrcLocM                              `thenM` \ loc ->
  71         doptM Opt_NoImplicitPrelude             `thenM` \ opt_no_prelude ->
  72         let
  73           all_imports        = mk_prel_imports this_mod loc opt_no_prelude ++ imports
  74           (source, ordinary) = partition is_source_import all_imports
  75           is_source_import (ImportDecl _ is_boot _ _ _ _) = is_boot
  76
  77           get_imports = importsFromImportDecl this_mod
  78         in
  79         mappM get_imports ordinary      `thenM` \ stuff1 ->
  80         mappM get_imports source        `thenM` \ stuff2 ->
  81
  82                 -- COMBINE RESULTS
  83         let
  84             (imp_gbl_envs, imp_avails) = unzip (stuff1 ++ stuff2)
  85             gbl_env :: GlobalRdrEnv
  86             gbl_env = foldr plusGlobalRdrEnv emptyRdrEnv imp_gbl_envs
  87
  88             all_avails :: ImportAvails
  89             all_avails = foldr plusImportAvails emptyImportAvails imp_avails
  90         in
  91                 -- ALL DONE
  92         returnM (gbl_env, all_avails)
  93   where
  94         -- NB: opt_NoImplicitPrelude is slightly different to import Prelude ();
  95         -- because the former doesn't even look at Prelude.hi for instance
  96         -- declarations, whereas the latter does.
  97     mk_prel_imports this_mod loc no_prelude
  98         |  moduleName this_mod == pRELUDE_Name
  99         || explicit_prelude_import
 100         || no_prelude
 101         = []
 102
 103         | otherwise = [preludeImportDecl loc]
 104
 105     explicit_prelude_import
 106       = notNull [ () | (ImportDecl mod _ _ _ _ _) <- imports,
 107                        mod == pRELUDE_Name ]
 108
 109 preludeImportDecl loc
 110   = ImportDecl pRELUDE_Name
 111                False {- Not a boot interface -}
 112                False    {- Not qualified -}
 113                Nothing  {- No "as" -}
 114                Nothing  {- No import list -}
 115                loc
 116 \end{code}
 117
 118 \begin{code}
 119 importsFromImportDecl :: Module
 120                       -> RdrNameImportDecl
 121                       -> TcRn m (GlobalRdrEnv, ImportAvails)
 122
 123 importsFromImportDecl this_mod
 124         (ImportDecl imp_mod_name is_boot qual_only as_mod imp_spec iloc)
 125   = addSrcLoc iloc $
 126     let
 127         doc = ppr imp_mod_name <+> ptext SLIT("is directly imported")
 128     in
 129
 130         -- If there's an error in loadInterface, (e.g. interface
 131         -- file not found) we get lots of spurious errors from 'filterImports'
 132     tryM (loadInterface doc imp_mod_name (ImportByUser is_boot))        `thenM` \ mb_iface ->
 133
 134     case mb_iface of {
 135         Left exn    -> returnM (emptyRdrEnv, emptyImportAvails ) ;
 136         Right iface ->
 137
 138     let
 139         imp_mod          = mi_module iface
 140         avails_by_module = mi_exports iface
 141         deprecs          = mi_deprecs iface
 142         is_orph          = mi_orphan iface
 143         deps             = mi_deps iface
 144
 145         avails :: Avails
 146         avails = [ avail | (mod_name, avails) <- avails_by_module,
 147                            mod_name /= this_mod_name,
 148                            avail <- avails ]
 149         this_mod_name = moduleName this_mod
 150         -- If the module exports anything defined in this module, just ignore it.
 151         -- Reason: otherwise it looks as if there are two local definition sites
 152         -- for the thing, and an error gets reported.  Easiest thing is just to
 153         -- filter them out up front. This situation only arises if a module
 154         -- imports itself, or another module that imported it.  (Necessarily,
 155         -- this invoves a loop.)
 156         --
 157         -- Tiresome consequence: if you say
 158         --      module A where
 159         --         import B( AType )
 160         --         type AType = ...
 161         --
 162         --      module B( AType ) where
 163         --         import {-# SOURCE #-} A( AType )
 164         --
 165         -- then you'll get a 'B does not export AType' message.  Oh well.
 166
 167     in
 168         -- Filter the imports according to the import list
 169     filterImports imp_mod is_boot imp_spec avails    `thenM` \ (filtered_avails, explicits) ->
 170
 171     let
 172         -- Compute new transitive dependencies
 173         orphans | is_orph   = insert imp_mod_name (dep_orphs deps)
 174                 | otherwise = dep_orphs deps
 175
 176         (dependent_mods, dependent_pkgs)
 177            | isHomeModule imp_mod
 178            =    -- Imported module is from the home package
 179                 -- Take its dependent modules and
 180                 --      (a) remove this_mod (might be there as a hi-boot)
 181                 --      (b) add imp_mod itself
 182                 -- Take its dependent packages unchanged
 183              ((imp_mod_name, is_boot) : filter not_self (dep_mods deps), dep_pkgs deps)
 184
 185            | otherwise
 186            =    -- Imported module is from another package
 187                 -- Dump the dependent modules
 188                 -- Add the package imp_mod comes from to the dependent packages
 189                 -- from imp_mod
 190              ([], insert (mi_package iface) (dep_pkgs deps))
 191
 192         not_self (m, _) = m /= this_mod_name
 193
 194         import_all = case imp_spec of
 195                         (Just (False, _)) -> False      -- Imports are spec'd explicitly
 196                         other             -> True       -- Everything is imported,
 197                                                         -- (or almost everything [hiding])
 198
 199         qual_mod_name = case as_mod of
 200                           Nothing           -> imp_mod_name
 201                           Just another_name -> another_name
 202
 203         -- unqual_avails is the Avails that are visible in *unqualified* form
 204         -- We need to know this so we know what to export when we see
 205         --      module M ( module P ) where ...
 206         -- Then we must export whatever came from P unqualified.
 207         avail_env = mkAvailEnv filtered_avails
 208         unqual_avails | qual_only = emptyAvailEnv       -- Qualified import
 209                       | otherwise = avail_env           -- Unqualified import
 210
 211         mk_prov name = NonLocalDef (UserImport imp_mod iloc (name `elemNameSet` explicits))
 212         gbl_env      = mkGlobalRdrEnv qual_mod_name (not qual_only)
 213                                       mk_prov filtered_avails deprecs
 214         imports      = ImportAvails {
 215                         imp_unqual = unitModuleEnvByName qual_mod_name unqual_avails,
 216                         imp_env    = avail_env,
 217                         imp_mods   = unitModuleEnv imp_mod (imp_mod, import_all),
 218                         imp_orphs  = orphans,
 219                         imp_dep_mods   = mkModDeps dependent_mods,
 220                         imp_dep_pkgs   = dependent_pkgs }
 221
 222     in
 223         -- Complain if we import a deprecated module
 224     ifOptM Opt_WarnDeprecations (
 225        case deprecs of
 226           DeprecAll txt -> addWarn (moduleDeprec imp_mod_name txt)
 227           other         -> returnM ()
 228     )                                                   `thenM_`
 229
 230     returnM (gbl_env, imports)
 231     }
 232
 233 mkModDeps :: [(ModuleName, IsBootInterface)]
 234           -> ModuleEnv (ModuleName, IsBootInterface)
 235 mkModDeps deps = foldl add emptyModuleEnv deps
 236                where
 237                  add env elt@(m,_) = extendModuleEnvByName env m elt
 238 \end{code}
 239
 240
 241 %************************************************************************
 242 %*                                                                      *
 243                 importsFromLocalDecls
 244 %*                                                                      *
 245 %************************************************************************
 246
 247 From the top-level declarations of this module produce
 248         * the lexical environment
 249         * the ImportAvails
 250 created by its bindings.
 251
 252 Complain about duplicate bindings
 253
 254 \begin{code}
 255 importsFromLocalDecls :: HsGroup RdrName
 256                       -> TcRn m (GlobalRdrEnv, ImportAvails)
 257 importsFromLocalDecls group
 258   = getModule                           `thenM` \ this_mod ->
 259     getLocalDeclBinders this_mod group  `thenM` \ avails ->
 260         -- The avails that are returned don't include the "system" names
 261     let
 262         all_names :: [Name]     -- All the defns; no dups eliminated
 263         all_names = [name | avail <- avails, name <- availNames avail]
 264
 265         dups :: [[Name]]
 266         (_, dups) = removeDups compare all_names
 267     in
 268         -- Check for duplicate definitions
 269         -- The complaint will come out as "Multiple declarations of Foo.f" because
 270         -- since 'f' is in the env twice, the unQualInScope used by the error-msg
 271         -- printer returns False.  It seems awkward to fix, unfortunately.
 272     mappM_ (addErr . dupDeclErr) dups                   `thenM_`
 273
 274     doptM Opt_NoImplicitPrelude                 `thenM` \ implicit_prelude ->
 275     let
 276         mod_name   = moduleName this_mod
 277         mk_prov n  = LocalDef   -- Provenance is local
 278
 279         unqual_imp = True       -- Want unqualified names in scope
 280         gbl_env = mkGlobalRdrEnv mod_name unqual_imp mk_prov avails NoDeprecs
 281             -- NoDeprecs: don't complain about locally defined names
 282             -- For a start, we may be exporting a deprecated thing
 283             -- Also we may use a deprecated thing in the defn of another
 284             -- deprecated things.  We may even use a deprecated thing in
 285             -- the defn of a non-deprecated thing, when changing a module's
 286             -- interface
 287
 288
 289             -- Optimisation: filter out names for built-in syntax
 290             -- They just clutter up the environment (esp tuples), and the parser
 291             -- will generate Exact RdrNames for them, so the cluttered
 292             -- envt is no use.  To avoid doing this filter all the time,
 293             -- we use -fno-implicit-prelude as a clue that the filter is
 294             -- worth while.  Really, it's only useful for GHC.Base and GHC.Tuple.
 295             --
 296             -- It's worth doing because it makes the environment smaller for
 297             -- every module that imports the Prelude
 298             --
 299             -- Note: don't filter the gbl_env (hence avails, not avails' in
 300             -- defn of gbl_env above).      Stupid reason: when parsing
 301             -- data type decls, the constructors start as Exact tycon-names,
 302             -- and then get turned into data con names by zapping the name space;
 303             -- but that stops them being Exact, so they get looked up.  Sigh.
 304             -- It doesn't matter because it only affects the Data.Tuple really.
 305             -- The important thing is to trim down the exports.
 306
 307         avails' | implicit_prelude = filter not_built_in_syntax avails
 308                 | otherwise        = avails
 309         not_built_in_syntax a = not (all isBuiltInSyntaxName (availNames a))
 310                 -- Only filter it if all the names of the avail are built-in
 311                 -- In particular, lists have (:) which is not built in syntax
 312                 -- so we don't filter it out.
 313
 314         avail_env = mkAvailEnv avails'
 315         imports   = emptyImportAvails {
 316                         imp_unqual = unitModuleEnv this_mod avail_env,
 317                         imp_env    = avail_env
 318                     }
 319     in
 320     returnM (gbl_env, imports)
 321 \end{code}
 322
 323
 324 %*********************************************************
 325 %*                                                      *
 326 \subsection{Getting binders out of a declaration}
 327 %*                                                      *
 328 %*********************************************************
 329
 330 @getLocalDeclBinders@ returns the names for a @RdrNameHsDecl@.  It's
 331 used for both source code (from @importsFromLocalDecls@) and interface
 332 files (@loadDecl@ calls @getTyClDeclBinders@).
 333
 334         *** See "THE NAMING STORY" in HsDecls ****
 335
 336 \begin{code}
 337 getLocalDeclBinders :: Module -> HsGroup RdrName -> TcRn m [AvailInfo]
 338 getLocalDeclBinders mod (HsGroup {hs_valds = val_decls,
 339                                   hs_tyclds = tycl_decls,
 340                                   hs_fords = foreign_decls })
 341   =     -- For type and class decls, we generate Global names, with
 342         -- no export indicator.  They need to be global because they get
 343         -- permanently bound into the TyCons and Classes.  They don't need
 344         -- an export indicator because they are all implicitly exported.
 345
 346     mappM new_tc tycl_decls                             `thenM` \ tc_avails ->
 347     mappM new_bndr (for_hs_bndrs ++ val_hs_bndrs)       `thenM` \ simple_bndrs ->
 348
 349     returnM (tc_avails ++ map Avail simple_bndrs)
 350   where
 351     new_bndr (rdr_name,loc) = newTopBinder mod rdr_name loc
 352
 353     val_hs_bndrs = collectLocatedHsBinders val_decls
 354     for_hs_bndrs = [(nm,loc) | ForeignImport nm _ _ _ loc <- foreign_decls]
 355
 356     new_tc tc_decl = mappM new_bndr (tyClDeclNames tc_decl)     `thenM` \ names@(main_name:_) ->
 357                      returnM (AvailTC main_name names)
 358 \end{code}
 359
 360
 361 %************************************************************************
 362 %*                                                                      *
 363 \subsection{Filtering imports}
 364 %*                                                                      *
 365 %************************************************************************
 366
 367 @filterImports@ takes the @ExportEnv@ telling what the imported module makes
 368 available, and filters it through the import spec (if any).
 369
 370 \begin{code}
 371 filterImports :: Module                         -- The module being imported
 372               -> IsBootInterface                -- Tells whether it's a {-# SOURCE #-} import
 373               -> Maybe (Bool, [RdrNameIE])      -- Import spec; True => hiding
 374               -> [AvailInfo]                    -- What's available
 375               -> TcRn m ([AvailInfo],           -- What's imported
 376                        NameSet)                 -- What was imported explicitly
 377
 378         -- Complains if import spec mentions things that the module doesn't export
 379         -- Warns/informs if import spec contains duplicates.
 380 filterImports mod from Nothing imports
 381   = returnM (imports, emptyNameSet)
 382
 383 filterImports mod from (Just (want_hiding, import_items)) total_avails
 384   = mappM get_item import_items         `thenM` \ avails_w_explicits_s ->
 385     let
 386         (item_avails, explicits_s) = unzip (concat avails_w_explicits_s)
 387         explicits                  = foldl addListToNameSet emptyNameSet explicits_s
 388     in
 389     if want_hiding then
 390         let     -- All imported; item_avails to be hidden
 391            hidden = availsToNameSet item_avails
 392            keep n = not (n `elemNameSet` hidden)
 393         in
 394         returnM (pruneAvails keep total_avails, emptyNameSet)
 395     else
 396         -- Just item_avails imported; nothing to be hidden
 397         returnM (item_avails, explicits)
 398   where
 399     import_fm :: FiniteMap OccName AvailInfo
 400     import_fm = listToFM [ (nameOccName name, avail)
 401                          | avail <- total_avails,
 402                            name  <- availNames avail]
 403         -- Even though availNames returns data constructors too,
 404         -- they won't make any difference because naked entities like T
 405         -- in an import list map to TcOccs, not VarOccs.
 406
 407     bale_out item = addErr (badImportItemErr mod from item)     `thenM_`
 408                     returnM []
 409
 410     get_item :: RdrNameIE -> TcRn m [(AvailInfo, [Name])]
 411         -- Empty list for a bad item.
 412         -- Singleton is typical case.
 413         -- Can have two when we are hiding, and mention C which might be
 414         --      both a class and a data constructor.
 415         -- The [Name] is the list of explicitly-mentioned names
 416     get_item item@(IEModuleContents _) = bale_out item
 417
 418     get_item item@(IEThingAll _)
 419       = case check_item item of
 420           Nothing                    -> bale_out item
 421           Just avail@(AvailTC _ [n]) ->         -- This occurs when you import T(..), but
 422                                                 -- only export T abstractly.  The single [n]
 423                                                 -- in the AvailTC is the type or class itself
 424                                         ifOptM Opt_WarnMisc (addWarn (dodgyImportWarn mod item))        `thenM_`
 425                                         returnM [(avail, [availName avail])]
 426           Just avail                 -> returnM [(avail, [availName avail])]
 427
 428     get_item item@(IEThingAbs n)
 429       | want_hiding     -- hiding( C )
 430                         -- Here the 'C' can be a data constructor *or* a type/class
 431       = case catMaybes [check_item item, check_item (IEVar data_n)] of
 432                 []     -> bale_out item
 433                 avails -> returnM [(a, []) | a <- avails]
 434                                 -- The 'explicits' list is irrelevant when hiding
 435       where
 436         data_n = setRdrNameSpace n dataName
 437
 438     get_item item
 439       = case check_item item of
 440           Nothing    -> bale_out item
 441           Just avail -> returnM [(avail, availNames avail)]
 442
 443     check_item item
 444       | not (maybeToBool maybe_in_import_avails) ||
 445         not (maybeToBool maybe_filtered_avail)
 446       = Nothing
 447
 448       | otherwise
 449       = Just filtered_avail
 450
 451       where
 452         wanted_occ             = rdrNameOcc (ieName item)
 453         maybe_in_import_avails = lookupFM import_fm wanted_occ
 454
 455         Just avail             = maybe_in_import_avails
 456         maybe_filtered_avail   = filterAvail item avail
 457         Just filtered_avail    = maybe_filtered_avail
 458 \end{code}
 459
 460 \begin{code}
 461 filterAvail :: RdrNameIE        -- Wanted
 462             -> AvailInfo        -- Available
 463             -> Maybe AvailInfo  -- Resulting available;
 464                                 -- Nothing if (any of the) wanted stuff isn't there
 465
 466 filterAvail ie@(IEThingWith want wants) avail@(AvailTC n ns)
 467   | sub_names_ok = Just (AvailTC n (filter is_wanted ns))
 468   | otherwise    = Nothing
 469   where
 470     is_wanted name = nameOccName name `elem` wanted_occs
 471     sub_names_ok   = all (`elem` avail_occs) wanted_occs
 472     avail_occs     = map nameOccName ns
 473     wanted_occs    = map rdrNameOcc (want:wants)
 474
 475 filterAvail (IEThingAbs _) (AvailTC n ns)       = ASSERT( n `elem` ns )
 476                                                   Just (AvailTC n [n])
 477
 478 filterAvail (IEThingAbs _) avail@(Avail n)      = Just avail            -- Type synonyms
 479
 480 filterAvail (IEVar _)      avail@(Avail n)      = Just avail
 481 filterAvail (IEVar v)      avail@(AvailTC n ns) = Just (AvailTC n (filter wanted ns))
 482                                                 where
 483                                                   wanted n = nameOccName n == occ
 484                                                   occ      = rdrNameOcc v
 485         -- The second equation happens if we import a class op, thus
 486         --      import A( op )
 487         -- where op is a class operation
 488
 489 filterAvail (IEThingAll _) avail@(AvailTC _ _)   = Just avail
 490         -- We don't complain even if the IE says T(..), but
 491         -- no constrs/class ops of T are available
 492         -- Instead that's caught with a warning by the caller
 493
 494 filterAvail ie avail = Nothing
 495 \end{code}
 496
 497
 498 %************************************************************************
 499 %*                                                                      *
 500 \subsection{Export list processing}
 501 %*                                                                      *
 502 %************************************************************************
 503
 504 Processing the export list.
 505
 506 You might think that we should record things that appear in the export
 507 list as ``occurrences'' (using @addOccurrenceName@), but you'd be
 508 wrong.  We do check (here) that they are in scope, but there is no
 509 need to slurp in their actual declaration (which is what
 510 @addOccurrenceName@ forces).
 511
 512 Indeed, doing so would big trouble when compiling @PrelBase@, because
 513 it re-exports @GHC@, which includes @takeMVar#@, whose type includes
 514 @ConcBase.StateAndSynchVar#@, and so on...
 515
 516 \begin{code}
 517 type ExportAccum        -- The type of the accumulating parameter of
 518                         -- the main worker function in exportsFromAvail
 519      = ([ModuleName],           -- 'module M's seen so far
 520         ExportOccMap,           -- Tracks exported occurrence names
 521         AvailEnv)               -- The accumulated exported stuff, kept in an env
 522                                 --   so we can common-up related AvailInfos
 523 emptyExportAccum = ([], emptyFM, emptyAvailEnv)
 524
 525 type ExportOccMap = FiniteMap OccName (Name, RdrNameIE)
 526         -- Tracks what a particular exported OccName
 527         --   in an export list refers to, and which item
 528         --   it came from.  It's illegal to export two distinct things
 529         --   that have the same occurrence name
 530
 531
 532 exportsFromAvail :: Maybe [RdrNameIE] -> TcRn m Avails
 533         -- Complains if two distinct exports have same OccName
 534         -- Warns about identical exports.
 535         -- Complains about exports items not in scope
 536 exportsFromAvail Nothing
 537  = do { this_mod <- getModule ;
 538         if moduleName this_mod == mAIN_Name then
 539            return []
 540               -- Export nothing; Main.$main is automatically exported
 541         else
 542           exportsFromAvail (Just [IEModuleContents (moduleName this_mod)])
 543               -- but for all other modules export everything.
 544     }
 545
 546 exportsFromAvail (Just exports)
 547  = do { TcGblEnv { tcg_imports = imports } <- getGblEnv ;
 548         warn_dup_exports <- doptM Opt_WarnDuplicateExports ;
 549         exports_from_avail exports warn_dup_exports imports }
 550
 551 exports_from_avail export_items warn_dup_exports
 552                    (ImportAvails { imp_unqual = mod_avail_env,
 553                                    imp_env = entity_avail_env })
 554   = foldlM exports_from_item emptyExportAccum
 555             export_items                        `thenM` \ (_, _, export_avail_map) ->
 556     returnM (nameEnvElts export_avail_map)
 557
 558   where
 559     exports_from_item :: ExportAccum -> RdrNameIE -> TcRn m ExportAccum
 560
 561     exports_from_item acc@(mods, occs, avails) ie@(IEModuleContents mod)
 562         | mod `elem` mods       -- Duplicate export of M
 563         = warnIf warn_dup_exports (dupModuleExport mod) `thenM_`
 564           returnM acc
 565
 566         | otherwise
 567         = case lookupModuleEnvByName mod_avail_env mod of
 568             Nothing             -> addErr (modExportErr mod)    `thenM_`
 569                                    returnM acc
 570             Just avail_env
 571                 -> let
 572                         mod_avails = availEnvElts avail_env
 573                         avails' = foldl addAvail avails mod_avails
 574                    in
 575                    foldlM (check_occs warn_dup_exports ie)
 576                           occs mod_avails       `thenM` \ occs' ->
 577
 578                    returnM (mod:mods, occs', avails')
 579
 580     exports_from_item acc@(mods, occs, avails) ie
 581         = lookupGRE (ieName ie)                 `thenM` \ mb_gre ->
 582           case mb_gre of {
 583                 Nothing -> addErr (unknownNameErr (ieName ie))  `thenM_`
 584                            returnM acc ;
 585                 Just gre ->
 586
 587                 -- Get the AvailInfo for the parent of the specified name
 588           case lookupAvailEnv entity_avail_env (gre_parent gre) of {
 589              Nothing -> pprPanic "exportsFromAvail"
 590                                 ((ppr (ieName ie)) <+> ppr gre) ;
 591              Just avail ->
 592
 593                 -- Filter out the bits we want
 594           case filterAvail ie avail of {
 595             Nothing ->  -- Not enough availability
 596                         addErr (exportItemErr ie) `thenM_`
 597                         returnM acc ;
 598
 599             Just export_avail ->
 600
 601                 -- Phew!  It's OK!  Now to check the occurrence stuff!
 602           warnIf (not (ok_item ie avail)) (dodgyExportWarn ie)  `thenM_`
 603           check_occs warn_dup_exports ie occs export_avail      `thenM` \ occs' ->
 604           returnM (mods, occs', addAvail avails export_avail)
 605           }}}
 606
 607
 608
 609 ok_item (IEThingAll _) (AvailTC _ [n]) = False
 610   -- This occurs when you import T(..), but
 611   -- only export T abstractly.  The single [n]
 612   -- in the AvailTC is the type or class itself
 613 ok_item _ _ = True
 614
 615 check_occs :: Bool -> RdrNameIE -> ExportOccMap -> AvailInfo -> TcRn m ExportOccMap
 616 check_occs warn_dup_exports ie occs avail
 617   = foldlM check occs (availNames avail)
 618   where
 619     check occs name
 620       = case lookupFM occs name_occ of
 621           Nothing           -> returnM (addToFM occs name_occ (name, ie))
 622           Just (name', ie')
 623             | name == name' ->  -- Duplicate export
 624                                 warnIf warn_dup_exports
 625                                         (dupExportWarn name_occ ie ie')
 626                                 `thenM_` returnM occs
 627
 628             | otherwise     ->  -- Same occ name but different names: an error
 629                                 addErr (exportClashErr name_occ ie ie') `thenM_`
 630                                 returnM occs
 631       where
 632         name_occ = nameOccName name
 633 \end{code}
 634
 635 %*********************************************************
 636 %*                                                       *
 637 \subsection{Unused names}
 638 %*                                                       *
 639 %*********************************************************
 640
 641 \begin{code}
 642 reportUnusedNames :: TcGblEnv
 643                   -> NameSet            -- Used in this module
 644                   -> TcRn m ()
 645 reportUnusedNames gbl_env used_names
 646   = warnUnusedModules unused_imp_mods                   `thenM_`
 647     warnUnusedTopBinds bad_locals                       `thenM_`
 648     warnUnusedImports bad_imports                       `thenM_`
 649     printMinimalImports minimal_imports
 650   where
 651     direct_import_mods :: [ModuleName]
 652     direct_import_mods = map (moduleName . fst)
 653                              (moduleEnvElts (imp_mods (tcg_imports gbl_env)))
 654
 655     -- Now, a use of C implies a use of T,
 656     -- if C was brought into scope by T(..) or T(C)
 657     really_used_names :: NameSet
 658     really_used_names = used_names `unionNameSets`
 659                         mkNameSet [ gre_parent gre
 660                                   | gre <- defined_names,
 661                                     gre_name gre `elemNameSet` used_names]
 662
 663         -- Collect the defined names from the in-scope environment
 664         -- Look for the qualified ones only, else get duplicates
 665     defined_names :: [GlobalRdrElt]
 666     defined_names = foldRdrEnv add [] (tcg_rdr_env gbl_env)
 667     add rdr_name ns acc | isQual rdr_name = ns ++ acc
 668                         | otherwise       = acc
 669
 670     defined_and_used, defined_but_not_used :: [GlobalRdrElt]
 671     (defined_and_used, defined_but_not_used) = partition used defined_names
 672     used gre = gre_name gre `elemNameSet` really_used_names
 673
 674     -- Filter out the ones that are
 675     --  (a) defined in this module, and
 676     --  (b) not defined by a 'deriving' clause
 677     -- The latter have an Internal Name, so we can filter them out easily
 678     bad_locals :: [GlobalRdrElt]
 679     bad_locals = filter is_bad defined_but_not_used
 680
 681     is_bad :: GlobalRdrElt -> Bool
 682     is_bad gre = isLocalGRE gre && isExternalName (gre_name gre)
 683
 684     bad_imports :: [GlobalRdrElt]
 685     bad_imports = filter bad_imp defined_but_not_used
 686     bad_imp (GRE {gre_prov = NonLocalDef (UserImport mod _ True)}) = not (module_unused mod)
 687     bad_imp other                                                  = False
 688
 689     -- To figure out the minimal set of imports, start with the things
 690     -- that are in scope (i.e. in gbl_env).  Then just combine them
 691     -- into a bunch of avails, so they are properly grouped
 692     minimal_imports :: FiniteMap ModuleName AvailEnv
 693     minimal_imports0 = emptyFM
 694     minimal_imports1 = foldr add_name     minimal_imports0 defined_and_used
 695     minimal_imports  = foldr add_inst_mod minimal_imports1 direct_import_mods
 696         -- The last line makes sure that we retain all direct imports
 697         -- even if we import nothing explicitly.
 698         -- It's not necessarily redundant to import such modules. Consider
 699         --            module This
 700         --              import M ()
 701         --
 702         -- The import M() is not *necessarily* redundant, even if
 703         -- we suck in no instance decls from M (e.g. it contains
 704         -- no instance decls, or This contains no code).  It may be
 705         -- that we import M solely to ensure that M's orphan instance
 706         -- decls (or those in its imports) are visible to people who
 707         -- import This.  Sigh.
 708         -- There's really no good way to detect this, so the error message
 709         -- in RnEnv.warnUnusedModules is weakened instead
 710
 711
 712         -- We've carefully preserved the provenance so that we can
 713         -- construct minimal imports that import the name by (one of)
 714         -- the same route(s) as the programmer originally did.
 715     add_name (GRE {gre_name = n, gre_parent = p,
 716                    gre_prov = NonLocalDef (UserImport m _ _)}) acc
 717         = addToFM_C plusAvailEnv acc (moduleName m)
 718                     (unitAvailEnv (mk_avail n p))
 719     add_name other acc
 720         = acc
 721
 722         -- n is the name of the thing, p is the name of its parent
 723     mk_avail n p | n/=p                    = AvailTC p [p,n]
 724                  | isTcOcc (nameOccName p) = AvailTC n [n]
 725                  | otherwise               = Avail n
 726
 727     add_inst_mod m acc
 728       | m `elemFM` acc = acc    -- We import something already
 729       | otherwise      = addToFM acc m emptyAvailEnv
 730         -- Add an empty collection of imports for a module
 731         -- from which we have sucked only instance decls
 732
 733     -- unused_imp_mods are the directly-imported modules
 734     -- that are not mentioned in minimal_imports1
 735     -- [Note: not 'minimal_imports', because that includes direcly-imported
 736     --        modules even if we use nothing from them; see notes above]
 737     unused_imp_mods = [m | m <- direct_import_mods,
 738                        not (maybeToBool (lookupFM minimal_imports1 m)),
 739                        m /= pRELUDE_Name]
 740
 741     module_unused :: Module -> Bool
 742     module_unused mod = moduleName mod `elem` unused_imp_mods
 743
 744
 745 -- ToDo: deal with original imports with 'qualified' and 'as M' clauses
 746 printMinimalImports :: FiniteMap ModuleName AvailEnv    -- Minimal imports
 747                     -> TcRn m ()
 748 printMinimalImports imps
 749  = ifOptM Opt_D_dump_minimal_imports $ do {
 750
 751    mod_ies  <-  mappM to_ies (fmToList imps) ;
 752    this_mod <- getModule ;
 753    rdr_env  <- getGlobalRdrEnv ;
 754    ioToTcRn (do { h <- openFile (mkFilename this_mod) WriteMode ;
 755                   printForUser h (unQualInScope rdr_env)
 756                                  (vcat (map ppr_mod_ie mod_ies)) })
 757    }
 758   where
 759     mkFilename this_mod = moduleNameUserString (moduleName this_mod) ++ ".imports"
 760     ppr_mod_ie (mod_name, ies)
 761         | mod_name == pRELUDE_Name
 762         = empty
 763         | null ies      -- Nothing except instances comes from here
 764         = ptext SLIT("import") <+> ppr mod_name <> ptext SLIT("()    -- Instances only")
 765         | otherwise
 766         = ptext SLIT("import") <+> ppr mod_name <>
 767                     parens (fsep (punctuate comma (map ppr ies)))
 768
 769     to_ies (mod, avail_env) = mappM to_ie (availEnvElts avail_env)      `thenM` \ ies ->
 770                               returnM (mod, ies)
 771
 772     to_ie :: AvailInfo -> TcRn m (IE Name)
 773         -- The main trick here is that if we're importing all the constructors
 774         -- we want to say "T(..)", but if we're importing only a subset we want
 775         -- to say "T(A,B,C)".  So we have to find out what the module exports.
 776     to_ie (Avail n)       = returnM (IEVar n)
 777     to_ie (AvailTC n [m]) = ASSERT( n==m )
 778                             returnM (IEThingAbs n)
 779     to_ie (AvailTC n ns)
 780         = loadInterface (text "Compute minimal imports from" <+> ppr n_mod)
 781                         n_mod ImportBySystem                            `thenM` \ iface ->
 782           case [xs | (m,as) <- mi_exports iface,
 783                      m == n_mod,
 784                      AvailTC x xs <- as,
 785                      x == n] of
 786               [xs] | all (`elem` ns) xs -> returnM (IEThingAll n)
 787                    | otherwise          -> returnM (IEThingWith n (filter (/= n) ns))
 788               other                     -> pprTrace "to_ie" (ppr n <+> ppr (nameModule n) <+> ppr other) $
 789                                            returnM (IEVar n)
 790         where
 791           n_mod = moduleName (nameModule n)
 792 \end{code}
 793
 794
 795 %************************************************************************
 796 %*                                                                      *
 797 \subsection{Errors}
 798 %*                                                                      *
 799 %************************************************************************
 800
 801 \begin{code}
 802 badImportItemErr mod from ie
 803   = sep [ptext SLIT("Module"), quotes (ppr mod), source_import,
 804          ptext SLIT("does not export"), quotes (ppr ie)]
 805   where
 806     source_import = case from of
 807                       True  -> ptext SLIT("(hi-boot interface)")
 808                       other -> empty
 809
 810 dodgyImportWarn mod item = dodgyMsg (ptext SLIT("import")) item
 811 dodgyExportWarn     item = dodgyMsg (ptext SLIT("export")) item
 812
 813 dodgyMsg kind item@(IEThingAll tc)
 814   = sep [ ptext SLIT("The") <+> kind <+> ptext SLIT("item") <+> quotes (ppr item),
 815           ptext SLIT("suggests that") <+> quotes (ppr tc) <+> ptext SLIT("has constructor or class methods"),
 816           ptext SLIT("but it has none; it is a type synonym or abstract type or class") ]
 817
 818 modExportErr mod
 819   = hsep [ ptext SLIT("Unknown module in export list: module"), quotes (ppr mod)]
 820
 821 exportItemErr export_item
 822   = sep [ ptext SLIT("The export item") <+> quotes (ppr export_item),
 823           ptext SLIT("attempts to export constructors or class methods that are not visible here") ]
 824
 825 exportClashErr occ_name ie1 ie2
 826   = hsep [ptext SLIT("The export items"), quotes (ppr ie1)
 827          ,ptext SLIT("and"), quotes (ppr ie2)
 828          ,ptext SLIT("create conflicting exports for"), quotes (ppr occ_name)]
 829
 830 dupDeclErr (n:ns)
 831   = vcat [ptext SLIT("Multiple declarations of") <+> quotes (ppr n),
 832           nest 4 (vcat (map ppr sorted_locs))]
 833   where
 834     sorted_locs = sortLt occ'ed_before (map nameSrcLoc (n:ns))
 835     occ'ed_before a b = LT == compare a b
 836
 837 dupExportWarn occ_name ie1 ie2
 838   = hsep [quotes (ppr occ_name),
 839           ptext SLIT("is exported by"), quotes (ppr ie1),
 840           ptext SLIT("and"),            quotes (ppr ie2)]
 841
 842 dupModuleExport mod
 843   = hsep [ptext SLIT("Duplicate"),
 844           quotes (ptext SLIT("Module") <+> ppr mod),
 845           ptext SLIT("in export list")]
 846
 847 moduleDeprec mod txt
 848   = sep [ ptext SLIT("Module") <+> quotes (ppr mod) <+> ptext SLIT("is deprecated:"),
 849           nest 4 (ppr txt) ]
 850 \end{code}