ghc/compiler/rename/RnNames.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnNames]{Extracting imported and top-level names in scope}
   5
   6 \begin{code}
   7 module RnNames (
   8         rnImports, importsFromLocalDecls, exportsFromAvail,
   9         reportUnusedNames, reportDeprecations,
  10         mkModDeps, exportsToAvails
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import CmdLineOpts      ( DynFlag(..) )
  16 import HsSyn            ( IE(..), ieName, ImportDecl(..), LImportDecl,
  17                           ForeignDecl(..), HsGroup(..),
  18                           collectGroupBinders, tyClDeclNames
  19                         )
  20 import RnEnv
  21 import IfaceEnv         ( lookupOrig, newGlobalBinder )
  22 import LoadIface        ( loadSrcInterface )
  23 import TcRnMonad
  24
  25 import FiniteMap
  26 import PrelNames        ( pRELUDE_Name, isBuiltInSyntaxName, isUnboundName,
  27                           main_RDR_Unqual )
  28 import Module           ( Module, ModuleName, moduleName, mkPackageModule,
  29                           moduleNameUserString, isHomeModule,
  30                           unitModuleEnvByName, unitModuleEnv,
  31                           lookupModuleEnvByName, moduleEnvElts )
  32 import Name             ( Name, nameSrcLoc, nameOccName, nameModuleName,
  33                           nameParent, nameParent_maybe, isExternalName, nameModule )
  34 import NameSet
  35 import NameEnv
  36 import OccName          ( srcDataName, isTcOcc, occNameFlavour, OccEnv,
  37                           mkOccEnv, lookupOccEnv, emptyOccEnv, extendOccEnv )
  38 import HscTypes         ( GenAvailInfo(..), AvailInfo, Avails, GhciMode(..),
  39                           IfaceExport, HomePackageTable, PackageIfaceTable,
  40                           availName, availNames, availsToNameSet, unQualInScope,
  41                           Deprecs(..), ModIface(..), Dependencies(..), lookupIface,
  42                           ExternalPackageState(..)
  43                         )
  44 import RdrName          ( RdrName, rdrNameOcc, setRdrNameSpace,
  45                           GlobalRdrEnv, mkGlobalRdrEnv, GlobalRdrElt(..),
  46                           emptyGlobalRdrEnv, plusGlobalRdrEnv, globalRdrEnvElts,
  47                           unQualOK, lookupGRE_Name,
  48                           Provenance(..), ImportSpec(..),
  49                           isLocalGRE, pprNameProvenance )
  50 import Outputable
  51 import Maybes           ( isJust, isNothing, catMaybes, mapCatMaybes, seqMaybe )
  52 import SrcLoc           ( noSrcLoc, Located(..), mkGeneralSrcSpan,
  53                           unLoc, noLoc )
  54 import BasicTypes       ( DeprecTxt )
  55 import ListSetOps       ( removeDups )
  56 import Util             ( sortLt, notNull, isSingleton )
  57 import List             ( partition )
  58 import IO               ( openFile, IOMode(..) )
  59 \end{code}
  60
  61
  62
  63 %************************************************************************
  64 %*                                                                      *
  65                 rnImports
  66 %*                                                                      *
  67 %************************************************************************
  68
  69 \begin{code}
  70 rnImports :: [LImportDecl RdrName]
  71           -> RnM (GlobalRdrEnv, ImportAvails)
  72
  73 rnImports imports
  74   =             -- PROCESS IMPORT DECLS
  75                 -- Do the non {- SOURCE -} ones first, so that we get a helpful
  76                 -- warning for {- SOURCE -} ones that are unnecessary
  77         getModule                               `thenM` \ this_mod ->
  78         doptM Opt_NoImplicitPrelude             `thenM` \ opt_no_prelude ->
  79         let
  80           all_imports        = mk_prel_imports this_mod opt_no_prelude ++ imports
  81           (source, ordinary) = partition is_source_import all_imports
  82           is_source_import (L _ (ImportDecl _ is_boot _ _ _)) = is_boot
  83
  84           get_imports = importsFromImportDecl this_mod
  85         in
  86         mappM get_imports ordinary      `thenM` \ stuff1 ->
  87         mappM get_imports source        `thenM` \ stuff2 ->
  88
  89                 -- COMBINE RESULTS
  90         let
  91             (imp_gbl_envs, imp_avails) = unzip (stuff1 ++ stuff2)
  92             gbl_env :: GlobalRdrEnv
  93             gbl_env = foldr plusGlobalRdrEnv emptyGlobalRdrEnv imp_gbl_envs
  94
  95             all_avails :: ImportAvails
  96             all_avails = foldr plusImportAvails emptyImportAvails imp_avails
  97         in
  98                 -- ALL DONE
  99         returnM (gbl_env, all_avails)
 100   where
 101         -- NB: opt_NoImplicitPrelude is slightly different to import Prelude ();
 102         -- because the former doesn't even look at Prelude.hi for instance
 103         -- declarations, whereas the latter does.
 104     mk_prel_imports this_mod no_prelude
 105         |  moduleName this_mod == pRELUDE_Name
 106         || explicit_prelude_import
 107         || no_prelude
 108         = []
 109
 110         | otherwise = [preludeImportDecl]
 111
 112     explicit_prelude_import
 113       = notNull [ () | L _ (ImportDecl mod _ _ _ _) <- imports,
 114                        unLoc mod == pRELUDE_Name ]
 115
 116 preludeImportDecl
 117   = L loc $
 118         ImportDecl (L loc pRELUDE_Name)
 119                False {- Not a boot interface -}
 120                False    {- Not qualified -}
 121                Nothing  {- No "as" -}
 122                Nothing  {- No import list -}
 123   where
 124     loc = mkGeneralSrcSpan FSLIT("Implicit import declaration")
 125 \end{code}
 126
 127 \begin{code}
 128 importsFromImportDecl :: Module
 129                       -> LImportDecl RdrName
 130                       -> RnM (GlobalRdrEnv, ImportAvails)
 131
 132 importsFromImportDecl this_mod
 133         (L loc (ImportDecl loc_imp_mod_name want_boot qual_only as_mod imp_details))
 134   =
 135     addSrcSpan loc $
 136
 137         -- If there's an error in loadInterface, (e.g. interface
 138         -- file not found) we get lots of spurious errors from 'filterImports'
 139     let
 140         imp_mod_name = unLoc loc_imp_mod_name
 141         this_mod_name = moduleName this_mod
 142         doc = ppr imp_mod_name <+> ptext SLIT("is directly imported")
 143     in
 144     loadSrcInterface doc imp_mod_name want_boot `thenM` \ iface ->
 145
 146         -- Compiler sanity check: if the import didn't say
 147         -- {-# SOURCE #-} we should not get a hi-boot file
 148     WARN( not want_boot && mi_boot iface, ppr imp_mod_name )
 149
 150         -- Issue a user warning for a redundant {- SOURCE -} import
 151         -- NB that we arrange to read all the ordinary imports before
 152         -- any of the {- SOURCE -} imports
 153     warnIf (want_boot && not (mi_boot iface))
 154            (warnRedundantSourceImport imp_mod_name)     `thenM_`
 155
 156     let
 157         imp_mod = mi_module iface
 158         deprecs = mi_deprecs iface
 159         is_orph = mi_orphan iface
 160         deps    = mi_deps iface
 161
 162         filtered_exports = filter not_this_mod (mi_exports iface)
 163         not_this_mod (mod,_) = mod /= this_mod_name
 164         -- If the module exports anything defined in this module, just ignore it.
 165         -- Reason: otherwise it looks as if there are two local definition sites
 166         -- for the thing, and an error gets reported.  Easiest thing is just to
 167         -- filter them out up front. This situation only arises if a module
 168         -- imports itself, or another module that imported it.  (Necessarily,
 169         -- this invoves a loop.)
 170         --
 171         -- Tiresome consequence: if you say
 172         --      module A where
 173         --         import B( AType )
 174         --         type AType = ...
 175         --
 176         --      module B( AType ) where
 177         --         import {-# SOURCE #-} A( AType )
 178         --
 179         -- then you'll get a 'B does not export AType' message.  Oh well.
 180
 181         qual_mod_name = case as_mod of
 182                           Nothing           -> imp_mod_name
 183                           Just another_name -> another_name
 184         imp_spec  = ImportSpec { is_mod = imp_mod_name, is_qual = qual_only,
 185                                  is_loc = loc, is_as = qual_mod_name }
 186     in
 187
 188         -- Get the total imports, and filter them according to the import list
 189     exportsToAvails filtered_exports            `thenM` \ total_avails ->
 190     filterImports iface imp_spec
 191                   imp_details total_avails      `thenM` \ (avail_env, gbl_env) ->
 192
 193     let
 194         -- Compute new transitive dependencies
 195
 196         orphans | is_orph   = ASSERT( not (imp_mod_name `elem` dep_orphs deps) )
 197                               imp_mod_name : dep_orphs deps
 198                 | otherwise = dep_orphs deps
 199
 200         (dependent_mods, dependent_pkgs)
 201            | isHomeModule imp_mod
 202            =    -- Imported module is from the home package
 203                 -- Take its dependent modules and
 204                 --      (a) remove this_mod (might be there as a hi-boot)
 205                 --      (b) add imp_mod itself
 206                 -- Take its dependent packages unchanged
 207              ((imp_mod_name, want_boot) : filter not_self (dep_mods deps), dep_pkgs deps)
 208
 209            | otherwise
 210            =    -- Imported module is from another package
 211                 -- Dump the dependent modules
 212                 -- Add the package imp_mod comes from to the dependent packages
 213              ASSERT( not (mi_package iface `elem` dep_pkgs deps) )
 214              ([], mi_package iface : dep_pkgs deps)
 215
 216         not_self (m, _) = m /= this_mod_name
 217
 218         import_all = case imp_details of
 219                         Just (is_hiding, ls)     -- Imports are spec'd explicitly
 220                           | not is_hiding -> Just (not (null ls))
 221                         _ -> Nothing            -- Everything is imported,
 222                                                 -- (or almost everything [hiding])
 223
 224         -- unqual_avails is the Avails that are visible in *unqualified* form
 225         -- We need to know this so we know what to export when we see
 226         --      module M ( module P ) where ...
 227         -- Then we must export whatever came from P unqualified.
 228         imports   = ImportAvails {
 229                         imp_qual     = unitModuleEnvByName qual_mod_name avail_env,
 230                         imp_env      = avail_env,
 231                         imp_mods     = unitModuleEnv imp_mod (imp_mod, import_all),
 232                         imp_orphs    = orphans,
 233                         imp_dep_mods = mkModDeps dependent_mods,
 234                         imp_dep_pkgs = dependent_pkgs }
 235
 236     in
 237         -- Complain if we import a deprecated module
 238     ifOptM Opt_WarnDeprecations (
 239        case deprecs of
 240           DeprecAll txt -> addWarn (moduleDeprec imp_mod_name txt)
 241           other         -> returnM ()
 242     )                                                   `thenM_`
 243
 244     returnM (gbl_env, imports)
 245
 246 exportsToAvails :: [IfaceExport] -> TcRnIf gbl lcl Avails
 247 exportsToAvails exports
 248   = do  { avails_by_module <- mappM do_one exports
 249         ; return (concat avails_by_module) }
 250   where
 251     do_one (mod_name, exports) = mapM (do_avail mod_name) exports
 252     do_avail mod_nm (Avail n)      = do { n' <- lookupOrig mod_nm n;
 253                                         ; return (Avail n') }
 254     do_avail mod_nm (AvailTC n ns) = do { n' <- lookupOrig mod_nm n
 255                                         ; ns' <- mappM (lookup_sub n') ns
 256                                         ; return (AvailTC n' ns') }
 257         where
 258           mod = mkPackageModule mod_nm  -- Not necessarily right yet
 259           lookup_sub parent occ = newGlobalBinder mod occ (Just parent) noSrcLoc
 260                 -- Hack alert! Notice the newGlobalBinder.  It ensures that the subordinate
 261                 -- names record their parent; and that in turn ensures that the GlobalRdrEnv
 262                 -- has the correct parent for all the names in its range.
 263                 -- For imported things, we only suck in the binding site later, if ever.
 264         -- Reason for all this:
 265         --   Suppose module M exports type A.T, and constructor A.MkT
 266         --   Then, we know that A.MkT is a subordinate name of A.T,
 267         --   even though we aren't at the binding site of A.T
 268         --   And it's important, because we may simply re-export A.T
 269         --   without ever sucking in the declaration itself.
 270
 271 warnRedundantSourceImport mod_name
 272   = ptext SLIT("Unnecessary {- SOURCE -} in the import of module")
 273           <+> quotes (ppr mod_name)
 274 \end{code}
 275
 276
 277 %************************************************************************
 278 %*                                                                      *
 279                 importsFromLocalDecls
 280 %*                                                                      *
 281 %************************************************************************
 282
 283 From the top-level declarations of this module produce
 284         * the lexical environment
 285         * the ImportAvails
 286 created by its bindings.
 287
 288 Complain about duplicate bindings
 289
 290 \begin{code}
 291 importsFromLocalDecls :: HsGroup RdrName
 292                       -> RnM (GlobalRdrEnv, ImportAvails)
 293 importsFromLocalDecls group
 294   = getModule                           `thenM` \ this_mod ->
 295     getLocalDeclBinders this_mod group  `thenM` \ avails ->
 296         -- The avails that are returned don't include the "system" names
 297     let
 298         all_names :: [Name]     -- All the defns; no dups eliminated
 299         all_names = [name | avail <- avails, name <- availNames avail]
 300
 301         dups :: [[Name]]
 302         (_, dups) = removeDups compare all_names
 303     in
 304         -- Check for duplicate definitions
 305         -- The complaint will come out as "Multiple declarations of Foo.f" because
 306         -- since 'f' is in the env twice, the unQualInScope used by the error-msg
 307         -- printer returns False.  It seems awkward to fix, unfortunately.
 308     mappM_ (addErr . dupDeclErr) dups                   `thenM_`
 309
 310     doptM Opt_NoImplicitPrelude                 `thenM` \ implicit_prelude ->
 311     let
 312         mod_name = moduleName this_mod
 313         prov     = LocalDef mod_name
 314         gbl_env  = mkGlobalRdrEnv gres
 315         gres     = [ GRE { gre_name = name, gre_prov = prov}
 316                    | name <- all_names]
 317
 318             -- Optimisation: filter out names for built-in syntax
 319             -- They just clutter up the environment (esp tuples), and the parser
 320             -- will generate Exact RdrNames for them, so the cluttered
 321             -- envt is no use.  To avoid doing this filter all the time,
 322             -- we use -fno-implicit-prelude as a clue that the filter is
 323             -- worth while.  Really, it's only useful for GHC.Base and GHC.Tuple.
 324             --
 325             -- It's worth doing because it makes the environment smaller for
 326             -- every module that imports the Prelude
 327             --
 328             -- Note: don't filter the gbl_env (hence avails, not avails' in
 329             -- defn of gbl_env above).      Stupid reason: when parsing
 330             -- data type decls, the constructors start as Exact tycon-names,
 331             -- and then get turned into data con names by zapping the name space;
 332             -- but that stops them being Exact, so they get looked up.
 333             -- Ditto in fixity decls; e.g.      infix 5 :
 334             -- Sigh. It doesn't matter because it only affects the Data.Tuple really.
 335             -- The important thing is to trim down the exports.
 336
 337         avails' | implicit_prelude = filter not_built_in_syntax avails
 338                 | otherwise        = avails
 339         not_built_in_syntax a = not (all isBuiltInSyntaxName (availNames a))
 340                 -- Only filter it if all the names of the avail are built-in
 341                 -- In particular, lists have (:) which is not built in syntax
 342                 -- so we don't filter it out.  [Sept 03: wrong: see isBuiltInSyntaxName]
 343
 344         avail_env = mkAvailEnv avails'
 345         imports   = emptyImportAvails {
 346                         imp_qual = unitModuleEnv this_mod avail_env,
 347                         imp_env  = avail_env
 348                     }
 349     in
 350     returnM (gbl_env, imports)
 351 \end{code}
 352
 353
 354 %*********************************************************
 355 %*                                                      *
 356 \subsection{Getting binders out of a declaration}
 357 %*                                                      *
 358 %*********************************************************
 359
 360 @getLocalDeclBinders@ returns the names for an @HsDecl@.  It's
 361 used for source code.
 362
 363         *** See "THE NAMING STORY" in HsDecls ****
 364
 365 \begin{code}
 366 getLocalDeclBinders :: Module -> HsGroup RdrName -> RnM [AvailInfo]
 367 getLocalDeclBinders mod (HsGroup {hs_valds = val_decls,
 368                                   hs_tyclds = tycl_decls,
 369                                   hs_fords = foreign_decls })
 370   =     -- For type and class decls, we generate Global names, with
 371         -- no export indicator.  They need to be global because they get
 372         -- permanently bound into the TyCons and Classes.  They don't need
 373         -- an export indicator because they are all implicitly exported.
 374
 375     mappM new_tc     tycl_decls                         `thenM` \ tc_avails ->
 376     mappM new_simple (for_hs_bndrs ++ val_hs_bndrs)     `thenM` \ simple_avails ->
 377     returnM (tc_avails ++ simple_avails)
 378   where
 379     new_simple rdr_name = newTopSrcBinder mod Nothing rdr_name `thenM` \ name ->
 380                           returnM (Avail name)
 381
 382     val_hs_bndrs = collectGroupBinders val_decls
 383     for_hs_bndrs = [nm | L _ (ForeignImport nm _ _ _) <- foreign_decls]
 384
 385     new_tc tc_decl
 386         = newTopSrcBinder mod Nothing main_rdr                  `thenM` \ main_name ->
 387           mappM (newTopSrcBinder mod (Just main_name)) sub_rdrs `thenM` \ sub_names ->
 388           returnM (AvailTC main_name (main_name : sub_names))
 389         where
 390           (main_rdr : sub_rdrs) = tyClDeclNames (unLoc tc_decl)
 391 \end{code}
 392
 393
 394 %************************************************************************
 395 %*                                                                      *
 396 \subsection{Filtering imports}
 397 %*                                                                      *
 398 %************************************************************************
 399
 400 @filterImports@ takes the @ExportEnv@ telling what the imported module makes
 401 available, and filters it through the import spec (if any).
 402
 403 \begin{code}
 404 filterImports :: ModIface
 405               -> ImportSpec                     -- The span for the entire import decl
 406               -> Maybe (Bool, [Located (IE RdrName)])   -- Import spec; True => hiding
 407               -> [AvailInfo]                    -- What's available
 408               -> RnM (AvailEnv,                 -- What's imported
 409                       GlobalRdrEnv)             -- ...in two forms
 410
 411         -- Complains if import spec mentions things that the module doesn't export
 412         -- Warns/informs if import spec contains duplicates.
 413 mkGenericRdrEnv imp_spec avails
 414   = mkGlobalRdrEnv [ GRE { gre_name = name, gre_prov = Imported [imp_spec] False }
 415                    | avail <- avails, name <- availNames avail ]
 416
 417 filterImports iface imp_spec Nothing total_avails
 418   = returnM (mkAvailEnv total_avails, mkGenericRdrEnv imp_spec total_avails)
 419
 420 filterImports iface imp_spec (Just (want_hiding, import_items)) total_avails
 421   = mapAndUnzipM (addLocM get_item) import_items        `thenM` \ (avails, gres) ->
 422     let
 423         all_avails = foldr plusAvailEnv     emptyAvailEnv     avails
 424         rdr_env    = foldr plusGlobalRdrEnv emptyGlobalRdrEnv gres
 425     in
 426     if not want_hiding then
 427         returnM (all_avails, rdr_env)
 428     else
 429     let -- Hide stuff in all_avails
 430            hidden = availsToNameSet (availEnvElts all_avails)
 431            keep n = not (n `elemNameSet` hidden)
 432            pruned_avails = pruneAvails keep total_avails
 433     in
 434     returnM (mkAvailEnv pruned_avails, mkGenericRdrEnv imp_spec pruned_avails)
 435   where
 436     import_fm :: OccEnv AvailInfo
 437     import_fm = mkOccEnv [ (nameOccName name, avail)
 438                          | avail <- total_avails,
 439                            name  <- availNames avail]
 440         -- Even though availNames returns data constructors too,
 441         -- they won't make any difference because naked entities like T
 442         -- in an import list map to TcOccs, not VarOccs.
 443
 444     bale_out item = addErr (badImportItemErr iface imp_spec item)       `thenM_`
 445                     returnM (emptyAvailEnv, emptyGlobalRdrEnv)
 446
 447     succeed_with :: Bool -> AvailInfo -> RnM (AvailEnv, GlobalRdrEnv)
 448     succeed_with all_explicit avail
 449       = do { loc <- getSrcSpanM
 450            ; returnM (unitAvailEnv avail,
 451                       mkGlobalRdrEnv (map (mk_gre loc) (availNames avail))) }
 452       where
 453         mk_gre loc name = GRE { gre_name = name,
 454                                 gre_prov = Imported [this_imp_spec loc] (explicit name) }
 455         this_imp_spec loc = imp_spec { is_loc = loc }
 456         explicit name = all_explicit || name == main_name
 457         main_name = availName avail
 458
 459     get_item :: IE RdrName -> RnM (AvailEnv, GlobalRdrEnv)
 460         -- Empty result for a bad item.
 461         -- Singleton result is typical case.
 462         -- Can have two when we are hiding, and mention C which might be
 463         --      both a class and a data constructor.
 464     get_item item@(IEModuleContents _)
 465       = bale_out item
 466
 467     get_item item@(IEThingAll tc)
 468       = case check_item item of
 469           Nothing                    -> bale_out item
 470           Just avail@(AvailTC _ [n]) ->         -- This occurs when you import T(..), but
 471                                                 -- only export T abstractly.  The single [n]
 472                                                 -- in the AvailTC is the type or class itself
 473                                         ifOptM Opt_WarnMisc (addWarn (dodgyImportWarn tc))      `thenM_`
 474                                         succeed_with False avail
 475           Just avail                 -> succeed_with False avail
 476
 477     get_item item@(IEThingAbs n)
 478       | want_hiding     -- hiding( C )
 479                         -- Here the 'C' can be a data constructor *or* a type/class
 480       = case catMaybes [check_item item, check_item (IEVar data_n)] of
 481           []     -> bale_out item
 482           avails -> returnM (mkAvailEnv avails, emptyGlobalRdrEnv)
 483                         -- The GlobalRdrEnv result is irrelevant when hiding
 484       where
 485         data_n = setRdrNameSpace n srcDataName
 486
 487     get_item item
 488       = case check_item item of
 489           Nothing    -> bale_out item
 490           Just avail -> succeed_with True avail
 491
 492     check_item item
 493       | isNothing maybe_in_import_avails ||
 494         isNothing maybe_filtered_avail
 495       = Nothing
 496
 497       | otherwise
 498       = Just filtered_avail
 499
 500       where
 501         wanted_occ             = rdrNameOcc (ieName item)
 502         maybe_in_import_avails = lookupOccEnv import_fm wanted_occ
 503
 504         Just avail             = maybe_in_import_avails
 505         maybe_filtered_avail   = filterAvail item avail
 506         Just filtered_avail    = maybe_filtered_avail
 507 \end{code}
 508
 509 \begin{code}
 510 filterAvail :: IE RdrName       -- Wanted
 511             -> AvailInfo        -- Available
 512             -> Maybe AvailInfo  -- Resulting available;
 513                                 -- Nothing if (any of the) wanted stuff isn't there
 514
 515 filterAvail ie@(IEThingWith want wants) avail@(AvailTC n ns)
 516   | sub_names_ok = Just (AvailTC n (filter is_wanted ns))
 517   | otherwise    = Nothing
 518   where
 519     is_wanted name = nameOccName name `elem` wanted_occs
 520     sub_names_ok   = all (`elem` avail_occs) wanted_occs
 521     avail_occs     = map nameOccName ns
 522     wanted_occs    = map rdrNameOcc (want:wants)
 523
 524 filterAvail (IEThingAbs _) (AvailTC n ns)       = ASSERT( n `elem` ns )
 525                                                   Just (AvailTC n [n])
 526
 527 filterAvail (IEThingAbs _) avail@(Avail n)      = Just avail            -- Type synonyms
 528
 529 filterAvail (IEVar _)      avail@(Avail n)      = Just avail
 530 filterAvail (IEVar v)      avail@(AvailTC n ns) = Just (AvailTC n (filter wanted ns))
 531                                                 where
 532                                                   wanted n = nameOccName n == occ
 533                                                   occ      = rdrNameOcc v
 534         -- The second equation happens if we import a class op, thus
 535         --      import A( op )
 536         -- where op is a class operation
 537
 538 filterAvail (IEThingAll _) avail@(AvailTC _ _)   = Just avail
 539         -- We don't complain even if the IE says T(..), but
 540         -- no constrs/class ops of T are available
 541         -- Instead that's caught with a warning by the caller
 542
 543 filterAvail ie avail = Nothing
 544 \end{code}
 545
 546
 547 %************************************************************************
 548 %*                                                                      *
 549 \subsection{Export list processing}
 550 %*                                                                      *
 551 %************************************************************************
 552
 553 Processing the export list.
 554
 555 You might think that we should record things that appear in the export
 556 list as ``occurrences'' (using @addOccurrenceName@), but you'd be
 557 wrong.  We do check (here) that they are in scope, but there is no
 558 need to slurp in their actual declaration (which is what
 559 @addOccurrenceName@ forces).
 560
 561 Indeed, doing so would big trouble when compiling @PrelBase@, because
 562 it re-exports @GHC@, which includes @takeMVar#@, whose type includes
 563 @ConcBase.StateAndSynchVar#@, and so on...
 564
 565 \begin{code}
 566 type ExportAccum        -- The type of the accumulating parameter of
 567                         -- the main worker function in exportsFromAvail
 568      = ([ModuleName],           -- 'module M's seen so far
 569         ExportOccMap,           -- Tracks exported occurrence names
 570         NameSet)                -- The accumulated exported stuff
 571 emptyExportAccum = ([], emptyOccEnv, emptyNameSet)
 572
 573 type ExportOccMap = OccEnv (Name, IE RdrName)
 574         -- Tracks what a particular exported OccName
 575         --   in an export list refers to, and which item
 576         --   it came from.  It's illegal to export two distinct things
 577         --   that have the same occurrence name
 578
 579
 580 exportsFromAvail :: Bool  -- False => no 'module M(..) where' header at all
 581                  -> Maybe [Located (IE RdrName)] -- Nothing => no explicit export list
 582                  -> RnM NameSet
 583         -- Complains if two distinct exports have same OccName
 584         -- Warns about identical exports.
 585         -- Complains about exports items not in scope
 586
 587 exportsFromAvail explicit_mod exports
 588  = do { TcGblEnv { tcg_rdr_env = rdr_env,
 589                    tcg_imports = imports } <- getGblEnv ;
 590
 591         -- If the module header is omitted altogether, then behave
 592         -- as if the user had written "module Main(main) where..."
 593         -- EXCEPT in interactive mode, when we behave as if he had
 594         -- written "module Main where ..."
 595         -- Reason: don't want to complain about 'main' not in scope
 596         --         in interactive mode
 597         ghci_mode <- getGhciMode ;
 598         let { real_exports
 599                 | explicit_mod             = exports
 600                 | ghci_mode == Interactive = Nothing
 601                 | otherwise                = Just [noLoc (IEVar main_RDR_Unqual)] } ;
 602         exports_from_avail real_exports rdr_env imports }
 603
 604
 605 exports_from_avail Nothing rdr_env imports
 606  =      -- Export all locally-defined things
 607         -- We do this by filtering the global RdrEnv,
 608         -- keeping only things that are locally-defined
 609    return (mkNameSet [ gre_name gre
 610                      | gre <- globalRdrEnvElts rdr_env,
 611                        isLocalGRE gre ])
 612
 613 exports_from_avail (Just export_items) rdr_env
 614                    (ImportAvails { imp_qual = mod_avail_env,
 615                                    imp_env  = entity_avail_env })
 616   = foldlM (exports_from_litem) emptyExportAccum
 617             export_items                        `thenM` \ (_, _, exports) ->
 618     returnM exports
 619
 620   where
 621     exports_from_litem :: ExportAccum -> Located (IE RdrName) -> RnM ExportAccum
 622     exports_from_litem acc = addLocM (exports_from_item acc)
 623
 624     exports_from_item :: ExportAccum -> IE RdrName -> RnM ExportAccum
 625     exports_from_item acc@(mods, occs, exports) ie@(IEModuleContents mod)
 626         | mod `elem` mods       -- Duplicate export of M
 627         = do { warn_dup_exports <- doptM Opt_WarnDuplicateExports ;
 628                warnIf warn_dup_exports (dupModuleExport mod) ;
 629                returnM acc }
 630
 631         | otherwise
 632         = case lookupModuleEnvByName mod_avail_env mod of
 633             Nothing -> addErr (modExportErr mod)        `thenM_`
 634                        returnM acc
 635
 636             Just avail_env
 637                 -> let
 638                         new_exports = [ name | avail <- availEnvElts avail_env,
 639                                                name  <- availNames avail,
 640                                                inScopeUnqual rdr_env name ]
 641                    in
 642
 643                 -- This check_occs not only finds conflicts between this item
 644                 -- and others, but also internally within this item.  That is,
 645                 -- if 'M.x' is in scope in several ways, we'll have several
 646                 -- members of mod_avails with the same OccName.
 647                    check_occs ie occs new_exports       `thenM` \ occs' ->
 648                    returnM (mod:mods, occs', addListToNameSet exports new_exports)
 649
 650     exports_from_item acc@(mods, occs, exports) ie
 651         = lookupGlobalOccRn (ieName ie)                 `thenM` \ name ->
 652           if isUnboundName name then
 653                 returnM acc     -- Avoid error cascade
 654           else
 655                 -- Get the AvailInfo for the parent of the specified name
 656           let
 657             parent = nameParent name
 658             avail  = lookupAvailEnv entity_avail_env parent
 659           in
 660                 -- Filter out the bits we want
 661           case filterAvail ie avail of {
 662             Nothing ->  -- Not enough availability
 663                         addErr (exportItemErr ie) `thenM_`
 664                         returnM acc ;
 665
 666             Just export_avail ->
 667
 668                 -- Phew!  It's OK!  Now to check the occurrence stuff!
 669
 670           let
 671               new_exports = availNames export_avail
 672           in
 673           checkForDodgyExport ie new_exports            `thenM_`
 674           check_occs ie occs new_exports                `thenM` \ occs' ->
 675           returnM (mods, occs', addListToNameSet exports new_exports)
 676           }
 677
 678
 679 -------------------------------
 680 inScopeUnqual :: GlobalRdrEnv -> Name -> Bool
 681 -- Checks whether the Name is in scope unqualified,
 682 -- regardless of whether it's ambiguous or not
 683 inScopeUnqual env n = any unQualOK (lookupGRE_Name env n)
 684
 685 -------------------------------
 686 checkForDodgyExport :: IE RdrName -> [Name] -> RnM ()
 687 checkForDodgyExport (IEThingAll tc) [n] = addWarn (dodgyExportWarn tc)
 688   -- This occurs when you import T(..), but
 689   -- only export T abstractly.  The single [n]
 690   -- in the AvailTC is the type or class itself
 691 checkForDodgyExport _ _ = return ()
 692
 693 -------------------------------
 694 check_occs :: IE RdrName -> ExportOccMap -> [Name] -> RnM ExportOccMap
 695 check_occs ie occs names
 696   = foldlM check occs names
 697   where
 698     check occs name
 699       = case lookupOccEnv occs name_occ of
 700           Nothing -> returnM (extendOccEnv occs name_occ (name, ie))
 701
 702           Just (name', ie')
 703             | name == name'     -- Duplicate export
 704             ->  do { warn_dup_exports <- doptM Opt_WarnDuplicateExports ;
 705                      warnIf warn_dup_exports (dupExportWarn name_occ ie ie') ;
 706                      returnM occs }
 707
 708             | otherwise         -- Same occ name but different names: an error
 709             ->  do { global_env <- getGlobalRdrEnv ;
 710                      addErr (exportClashErr global_env name name' ie ie') ;
 711                      returnM occs }
 712       where
 713         name_occ = nameOccName name
 714 \end{code}
 715
 716 %*********************************************************
 717 %*                                                       *
 718                 Deprecations
 719 %*                                                       *
 720 %*********************************************************
 721
 722 \begin{code}
 723 reportDeprecations :: TcGblEnv -> RnM ()
 724 reportDeprecations tcg_env
 725   = ifOptM Opt_WarnDeprecations $
 726     do  { hpt <- getHpt
 727         ; eps <- getEps
 728         ; mapM_ (check hpt (eps_PIT eps)) all_gres }
 729   where
 730     used_names = findUses (tcg_dus tcg_env) emptyNameSet
 731     all_gres   = globalRdrEnvElts (tcg_rdr_env tcg_env)
 732
 733     check hpt pit (GRE {gre_name = name, gre_prov = Imported (imp_spec:_) _})
 734       | name `elemNameSet` used_names
 735       , Just deprec_txt <- lookupDeprec hpt pit name
 736       = addSrcSpan (is_loc imp_spec) $
 737         addWarn (sep [ptext SLIT("Deprecated use of") <+>
 738                         text (occNameFlavour (nameOccName name)) <+>
 739                         quotes (ppr name),
 740                       (parens imp_msg),
 741                       (ppr deprec_txt) ])
 742         where
 743           name_mod = nameModuleName name
 744           imp_mod  = is_mod imp_spec
 745           imp_msg  = ptext SLIT("imported from") <+> ppr imp_mod <> extra
 746           extra | imp_mod == name_mod = empty
 747                 | otherwise = ptext SLIT(", but defined in") <+> ppr name_mod
 748
 749     check hpt pit ok_gre = returnM ()   -- Local, or not used, or not deprectated
 750             -- The Imported pattern-match: don't deprecate locally defined names
 751             -- For a start, we may be exporting a deprecated thing
 752             -- Also we may use a deprecated thing in the defn of another
 753             -- deprecated things.  We may even use a deprecated thing in
 754             -- the defn of a non-deprecated thing, when changing a module's
 755             -- interface
 756
 757 lookupDeprec :: HomePackageTable -> PackageIfaceTable
 758              -> Name -> Maybe DeprecTxt
 759 lookupDeprec hpt pit n
 760   = case lookupIface hpt pit (nameModule n) of
 761         Just iface -> mi_dep_fn iface n `seqMaybe`      -- Bleat if the thing, *or
 762                       mi_dep_fn iface (nameParent n)    -- its parent*, is deprec'd
 763         Nothing    -> pprPanic "lookupDeprec" (ppr n)
 764                 -- By now all the interfaces should have been loaded
 765
 766 gre_is_used :: NameSet -> GlobalRdrElt -> Bool
 767 gre_is_used used_names gre = gre_name gre `elemNameSet` used_names
 768 \end{code}
 769
 770 %*********************************************************
 771 %*                                                       *
 772                 Unused names
 773 %*                                                       *
 774 %*********************************************************
 775
 776 \begin{code}
 777 reportUnusedNames :: TcGblEnv -> RnM ()
 778 reportUnusedNames gbl_env
 779   = do  { warnUnusedTopBinds   unused_locals
 780         ; warnUnusedModules    unused_imp_mods
 781         ; warnUnusedImports    unused_imports
 782         ; warnDuplicateImports dup_imps
 783         ; printMinimalImports  minimal_imports }
 784   where
 785     used_names, all_used_names :: NameSet
 786     used_names = findUses (tcg_dus gbl_env) emptyNameSet
 787     all_used_names = used_names `unionNameSets`
 788                      mkNameSet (mapCatMaybes nameParent_maybe (nameSetToList used_names))
 789                         -- A use of C implies a use of T,
 790                         -- if C was brought into scope by T(..) or T(C)
 791
 792         -- Collect the defined names from the in-scope environment
 793     defined_names :: [GlobalRdrElt]
 794     defined_names = globalRdrEnvElts (tcg_rdr_env gbl_env)
 795
 796         -- Note that defined_and_used, defined_but_not_used
 797         -- are both [GRE]; that's why we need defined_and_used
 798         -- rather than just all_used_names
 799     defined_and_used, defined_but_not_used :: [GlobalRdrElt]
 800     (defined_and_used, defined_but_not_used)
 801         = partition (gre_is_used all_used_names) defined_names
 802
 803         -- Find the duplicate imports
 804     dup_imps = filter is_dup defined_and_used
 805     is_dup (GRE {gre_prov = Imported imp_spec True}) = not (isSingleton imp_spec)
 806     is_dup other                                     = False
 807
 808         -- Filter out the ones that are
 809         --  (a) defined in this module, and
 810         --  (b) not defined by a 'deriving' clause
 811         -- The latter have an Internal Name, so we can filter them out easily
 812     unused_locals :: [GlobalRdrElt]
 813     unused_locals = filter is_unused_local defined_but_not_used
 814     is_unused_local :: GlobalRdrElt -> Bool
 815     is_unused_local gre = isLocalGRE gre && isExternalName (gre_name gre)
 816
 817     unused_imports :: [GlobalRdrElt]
 818     unused_imports = filter unused_imp defined_but_not_used
 819     unused_imp (GRE {gre_prov = Imported imp_specs True})
 820         = not (all (module_unused . is_mod) imp_specs)
 821                 -- Don't complain about unused imports if we've already said the
 822                 -- entire import is unused
 823     unused_imp other = False
 824
 825     -- To figure out the minimal set of imports, start with the things
 826     -- that are in scope (i.e. in gbl_env).  Then just combine them
 827     -- into a bunch of avails, so they are properly grouped
 828     minimal_imports :: FiniteMap ModuleName AvailEnv
 829     minimal_imports0 = emptyFM
 830     minimal_imports1 = foldr add_name     minimal_imports0 defined_and_used
 831     minimal_imports  = foldr add_inst_mod minimal_imports1 direct_import_mods
 832         -- The last line makes sure that we retain all direct imports
 833         -- even if we import nothing explicitly.
 834         -- It's not necessarily redundant to import such modules. Consider
 835         --            module This
 836         --              import M ()
 837         --
 838         -- The import M() is not *necessarily* redundant, even if
 839         -- we suck in no instance decls from M (e.g. it contains
 840         -- no instance decls, or This contains no code).  It may be
 841         -- that we import M solely to ensure that M's orphan instance
 842         -- decls (or those in its imports) are visible to people who
 843         -- import This.  Sigh.
 844         -- There's really no good way to detect this, so the error message
 845         -- in RnEnv.warnUnusedModules is weakened instead
 846
 847         -- We've carefully preserved the provenance so that we can
 848         -- construct minimal imports that import the name by (one of)
 849         -- the same route(s) as the programmer originally did.
 850     add_name (GRE {gre_name = n,
 851                    gre_prov = Imported imp_specs _}) acc
 852         = addToFM_C plusAvailEnv acc (is_mod (head imp_specs))
 853                     (unitAvailEnv (mk_avail n (nameParent_maybe n)))
 854     add_name other acc
 855         = acc
 856
 857         -- n is the name of the thing, p is the name of its parent
 858     mk_avail n (Just p)                          = AvailTC p [p,n]
 859     mk_avail n Nothing | isTcOcc (nameOccName n) = AvailTC n [n]
 860                        | otherwise               = Avail n
 861
 862     add_inst_mod m acc
 863       | m `elemFM` acc = acc    -- We import something already
 864       | otherwise      = addToFM acc m emptyAvailEnv
 865         -- Add an empty collection of imports for a module
 866         -- from which we have sucked only instance decls
 867
 868     imports = tcg_imports gbl_env
 869
 870     direct_import_mods :: [ModuleName]
 871     direct_import_mods = map (moduleName . fst)
 872                              (moduleEnvElts (imp_mods imports))
 873
 874     hasEmptyImpList :: ModuleName -> Bool
 875     hasEmptyImpList m =
 876        case lookupModuleEnvByName (imp_mods imports) m of
 877          Just (_,Just x) -> not x
 878          _ -> False
 879
 880     -- unused_imp_mods are the directly-imported modules
 881     -- that are not mentioned in minimal_imports1
 882     -- [Note: not 'minimal_imports', because that includes directly-imported
 883     --        modules even if we use nothing from them; see notes above]
 884     unused_imp_mods = [m | m <- direct_import_mods,
 885                        isNothing (lookupFM minimal_imports1 m),
 886                        m /= pRELUDE_Name,
 887                        not (hasEmptyImpList m)]
 888         -- hasEmptyImpList arranges not to complain about
 889         -- import M (), which is an idiom for importing
 890         -- instance declarations
 891
 892     module_unused :: ModuleName -> Bool
 893     module_unused mod = mod `elem` unused_imp_mods
 894
 895 ---------------------
 896 warnDuplicateImports :: [GlobalRdrElt] -> RnM ()
 897 warnDuplicateImports gres
 898   = ifOptM Opt_WarnUnusedImports (mapM_ warn gres)
 899   where
 900     warn (GRE { gre_name = name, gre_prov = Imported imps _ })
 901         = addWarn ((quotes (ppr name) <+> ptext SLIT("is imported more than once:"))
 902                $$ nest 2 (vcat (map ppr imps)))
 903
 904
 905 -- ToDo: deal with original imports with 'qualified' and 'as M' clauses
 906 printMinimalImports :: FiniteMap ModuleName AvailEnv    -- Minimal imports
 907                     -> RnM ()
 908 printMinimalImports imps
 909  = ifOptM Opt_D_dump_minimal_imports $ do {
 910
 911    mod_ies  <-  mappM to_ies (fmToList imps) ;
 912    this_mod <- getModule ;
 913    rdr_env  <- getGlobalRdrEnv ;
 914    ioToTcRn (do { h <- openFile (mkFilename this_mod) WriteMode ;
 915                   printForUser h (unQualInScope rdr_env)
 916                                  (vcat (map ppr_mod_ie mod_ies)) })
 917    }
 918   where
 919     mkFilename this_mod = moduleNameUserString (moduleName this_mod) ++ ".imports"
 920     ppr_mod_ie (mod_name, ies)
 921         | mod_name == pRELUDE_Name
 922         = empty
 923         | null ies      -- Nothing except instances comes from here
 924         = ptext SLIT("import") <+> ppr mod_name <> ptext SLIT("()    -- Instances only")
 925         | otherwise
 926         = ptext SLIT("import") <+> ppr mod_name <>
 927                     parens (fsep (punctuate comma (map ppr ies)))
 928
 929     to_ies (mod, avail_env) = mappM to_ie (availEnvElts avail_env)      `thenM` \ ies ->
 930                               returnM (mod, ies)
 931
 932     to_ie :: AvailInfo -> RnM (IE Name)
 933         -- The main trick here is that if we're importing all the constructors
 934         -- we want to say "T(..)", but if we're importing only a subset we want
 935         -- to say "T(A,B,C)".  So we have to find out what the module exports.
 936     to_ie (Avail n)       = returnM (IEVar n)
 937     to_ie (AvailTC n [m]) = ASSERT( n==m )
 938                             returnM (IEThingAbs n)
 939     to_ie (AvailTC n ns)
 940         = loadSrcInterface doc n_mod False                      `thenM` \ iface ->
 941           case [xs | (m,as) <- mi_exports iface,
 942                      m == n_mod,
 943                      AvailTC x xs <- as,
 944                      x == nameOccName n] of
 945               [xs] | all_used xs -> returnM (IEThingAll n)
 946                    | otherwise   -> returnM (IEThingWith n (filter (/= n) ns))
 947               other              -> pprTrace "to_ie" (ppr n <+> ppr n_mod <+> ppr other) $
 948                                     returnM (IEVar n)
 949         where
 950           all_used avail_occs = all (`elem` map nameOccName ns) avail_occs
 951           doc = text "Compute minimal imports from" <+> ppr n
 952           n_mod = nameModuleName n
 953 \end{code}
 954
 955
 956 %************************************************************************
 957 %*                                                                      *
 958 \subsection{Errors}
 959 %*                                                                      *
 960 %************************************************************************
 961
 962 \begin{code}
 963 badImportItemErr iface imp_spec ie
 964   = sep [ptext SLIT("Module"), quotes (ppr (is_mod imp_spec)), source_import,
 965          ptext SLIT("does not export"), quotes (ppr ie)]
 966   where
 967     source_import | mi_boot iface = ptext SLIT("(hi-boot interface)")
 968                   | otherwise     = empty
 969
 970 dodgyImportWarn item = dodgyMsg (ptext SLIT("import")) item
 971 dodgyExportWarn item = dodgyMsg (ptext SLIT("export")) item
 972
 973 dodgyMsg kind tc
 974   = sep [ ptext SLIT("The") <+> kind <+> ptext SLIT("item") <+> quotes (ppr (IEThingAll tc)),
 975           ptext SLIT("suggests that") <+> quotes (ppr tc) <+> ptext SLIT("has constructor or class methods"),
 976           ptext SLIT("but it has none; it is a type synonym or abstract type or class") ]
 977
 978 modExportErr mod
 979   = hsep [ ptext SLIT("Unknown module in export list: module"), quotes (ppr mod)]
 980
 981 exportItemErr export_item
 982   = sep [ ptext SLIT("The export item") <+> quotes (ppr export_item),
 983           ptext SLIT("attempts to export constructors or class methods that are not visible here") ]
 984
 985 exportClashErr global_env name1 name2 ie1 ie2
 986   = vcat [ ptext SLIT("Conflicting exports for") <+> quotes (ppr occ) <> colon
 987          , ppr_export ie1 name1
 988          , ppr_export ie2 name2  ]
 989   where
 990     occ = nameOccName name1
 991     ppr_export ie name = nest 2 (quotes (ppr ie) <+> ptext SLIT("exports") <+>
 992                                  quotes (ppr name) <+> pprNameProvenance (get_gre name))
 993
 994         -- get_gre finds a GRE for the Name, so that we can show its provenance
 995     get_gre name
 996         = case lookupGRE_Name global_env name of
 997              (gre:_) -> gre
 998              []      -> pprPanic "exportClashErr" (ppr name)
 999
1000 dupDeclErr (n:ns)
1001   = vcat [ptext SLIT("Multiple declarations of") <+> quotes (ppr n),
1002           nest 4 (vcat (map ppr sorted_locs))]
1003   where
1004     sorted_locs = sortLt occ'ed_before (map nameSrcLoc (n:ns))
1005     occ'ed_before a b = LT == compare a b
1006
1007 dupExportWarn occ_name ie1 ie2
1008   = hsep [quotes (ppr occ_name),
1009           ptext SLIT("is exported by"), quotes (ppr ie1),
1010           ptext SLIT("and"),            quotes (ppr ie2)]
1011
1012 dupModuleExport mod
1013   = hsep [ptext SLIT("Duplicate"),
1014           quotes (ptext SLIT("Module") <+> ppr mod),
1015           ptext SLIT("in export list")]
1016
1017 moduleDeprec mod txt
1018   = sep [ ptext SLIT("Module") <+> quotes (ppr mod) <+> ptext SLIT("is deprecated:"),
1019           nest 4 (ppr txt) ]
1020 \end{code}