ghc/compiler/rename/RnSource.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[RnSource]{Main pass of renamer}
   5
   6 \begin{code}
   7 module RnSource ( rnDecl, rnSourceDecls, rnHsType, rnHsSigType ) where
   8
   9 #include "HsVersions.h"
  10
  11 import RnExpr
  12 import HsSyn
  13 import HsPragmas
  14 import HsTypes          ( getTyVarName, pprClassAssertion, cmpHsTypes )
  15 import RdrName          ( RdrName, isRdrDataCon, rdrNameOcc, isRdrTyVar )
  16 import RdrHsSyn         ( RdrNameContext, RdrNameHsType, RdrNameConDecl,
  17                           extractRuleBndrsTyVars, extractHsTyRdrTyVars
  18                         )
  19 import RnHsSyn
  20 import HsCore
  21
  22 import RnBinds          ( rnTopBinds, rnMethodBinds, renameSigs, unknownSigErr )
  23 import RnEnv            ( bindTyVarsRn, lookupBndrRn, lookupOccRn,
  24                           lookupImplicitOccRn,
  25                           bindLocalsRn, bindLocalRn, bindLocalsFVRn,
  26                           bindTyVarsFVRn, bindTyVarsFV2Rn, extendTyVarEnvFVRn,
  27                           bindCoreLocalFVRn, bindCoreLocalsFVRn,
  28                           checkDupOrQualNames, checkDupNames,
  29                           mkImportedGlobalName, mkImportedGlobalFromRdrName,
  30                           newDFunName, getDFunKey, newImplicitBinder,
  31                           FreeVars, emptyFVs, plusFV, plusFVs, unitFV, addOneFV, mapFvRn
  32                         )
  33 import RnMonad
  34
  35 import Name             ( Name, OccName,
  36                           ExportFlag(..), Provenance(..),
  37                           nameOccName, NamedThing(..)
  38                         )
  39 import NameSet
  40 import OccName          ( mkDefaultMethodOcc )
  41 import BasicTypes       ( TopLevelFlag(..) )
  42 import FiniteMap        ( elemFM )
  43 import PrelInfo         ( derivableClassKeys,
  44                           deRefStablePtr_NAME, makeStablePtr_NAME, bindIO_NAME
  45                         )
  46 import Bag              ( bagToList )
  47 import List             ( partition, nub )
  48 import Outputable
  49 import SrcLoc           ( SrcLoc )
  50 import CmdLineOpts      ( opt_WarnUnusedMatches )       -- Warn of unused for-all'd tyvars
  51 import Unique           ( Uniquable(..) )
  52 import UniqFM           ( lookupUFM )
  53 import Maybes           ( maybeToBool, catMaybes )
  54 import Util
  55 \end{code}
  56
  57 @rnDecl@ `renames' declarations.
  58 It simultaneously performs dependency analysis and precedence parsing.
  59 It also does the following error checks:
  60 \begin{enumerate}
  61 \item
  62 Checks that tyvars are used properly. This includes checking
  63 for undefined tyvars, and tyvars in contexts that are ambiguous.
  64 \item
  65 Checks that all variable occurences are defined.
  66 \item
  67 Checks the @(..)@ etc constraints in the export list.
  68 \end{enumerate}
  69
  70
  71 %*********************************************************
  72 %*                                                      *
  73 \subsection{Value declarations}
  74 %*                                                      *
  75 %*********************************************************
  76
  77 \begin{code}
  78 rnSourceDecls :: [RdrNameHsDecl] -> RnMS ([RenamedHsDecl], FreeVars)
  79         -- The decls get reversed, but that's ok
  80
  81 rnSourceDecls decls
  82   = go emptyFVs [] decls
  83   where
  84         -- Fixity decls have been dealt with already; ignore them
  85     go fvs ds' []          = returnRn (ds', fvs)
  86     go fvs ds' (FixD _:ds) = go fvs ds' ds
  87     go fvs ds' (d:ds)      = rnDecl d   `thenRn` \(d', fvs') ->
  88                              go (fvs `plusFV` fvs') (d':ds') ds
  89 \end{code}
  90
  91
  92 %*********************************************************
  93 %*                                                      *
  94 \subsection{Value declarations}
  95 %*                                                      *
  96 %*********************************************************
  97
  98 \begin{code}
  99 -- rnDecl does all the work
 100 rnDecl :: RdrNameHsDecl -> RnMS (RenamedHsDecl, FreeVars)
 101
 102 rnDecl (ValD binds) = rnTopBinds binds  `thenRn` \ (new_binds, fvs) ->
 103                       returnRn (ValD new_binds, fvs)
 104
 105
 106 rnDecl (SigD (IfaceSig name ty id_infos loc))
 107   = pushSrcLocRn loc $
 108     lookupBndrRn name           `thenRn` \ name' ->
 109     rnHsType doc_str ty         `thenRn` \ (ty',fvs1) ->
 110     mapFvRn rnIdInfo id_infos   `thenRn` \ (id_infos', fvs2) ->
 111     returnRn (SigD (IfaceSig name' ty' id_infos' loc), fvs1 `plusFV` fvs2)
 112   where
 113     doc_str = text "the interface signature for" <+> quotes (ppr name)
 114 \end{code}
 115
 116 %*********************************************************
 117 %*                                                      *
 118 \subsection{Type declarations}
 119 %*                                                      *
 120 %*********************************************************
 121
 122 @rnTyDecl@ uses the `global name function' to create a new type
 123 declaration in which local names have been replaced by their original
 124 names, reporting any unknown names.
 125
 126 Renaming type variables is a pain. Because they now contain uniques,
 127 it is necessary to pass in an association list which maps a parsed
 128 tyvar to its @Name@ representation.
 129 In some cases (type signatures of values),
 130 it is even necessary to go over the type first
 131 in order to get the set of tyvars used by it, make an assoc list,
 132 and then go over it again to rename the tyvars!
 133 However, we can also do some scoping checks at the same time.
 134
 135 \begin{code}
 136 rnDecl (TyClD (TyData new_or_data context tycon tyvars condecls derivings pragmas src_loc))
 137   = pushSrcLocRn src_loc $
 138     lookupBndrRn tycon                          `thenRn` \ tycon' ->
 139     bindTyVarsFVRn data_doc tyvars              $ \ tyvars' ->
 140     rnContext data_doc context                  `thenRn` \ (context', cxt_fvs) ->
 141     checkDupOrQualNames data_doc con_names      `thenRn_`
 142     mapFvRn rnConDecl condecls                  `thenRn` \ (condecls', con_fvs) ->
 143     rnDerivs derivings                          `thenRn` \ (derivings', deriv_fvs) ->
 144     ASSERT(isNoDataPragmas pragmas)
 145     returnRn (TyClD (TyData new_or_data context' tycon' tyvars' condecls'
 146                      derivings' noDataPragmas src_loc),
 147               cxt_fvs `plusFV` con_fvs `plusFV` deriv_fvs)
 148   where
 149     data_doc = text "the data type declaration for" <+> quotes (ppr tycon)
 150     con_names = map conDeclName condecls
 151
 152 rnDecl (TyClD (TySynonym name tyvars ty src_loc))
 153   = pushSrcLocRn src_loc $
 154     lookupBndrRn name                           `thenRn` \ name' ->
 155     bindTyVarsFVRn syn_doc tyvars               $ \ tyvars' ->
 156     rnHsType syn_doc ty                         `thenRn` \ (ty', ty_fvs) ->
 157     returnRn (TyClD (TySynonym name' tyvars' ty' src_loc), ty_fvs)
 158   where
 159     syn_doc = text "the declaration for type synonym" <+> quotes (ppr name)
 160
 161 rnDecl (TyClD (ClassDecl context cname tyvars sigs mbinds pragmas
 162                tname dname snames src_loc))
 163   = pushSrcLocRn src_loc $
 164
 165     lookupBndrRn cname                                  `thenRn` \ cname' ->
 166
 167         -- Deal with the implicit tycon and datacon name
 168         -- They aren't in scope (because they aren't visible to the user)
 169         -- and what we want to do is simply look them up in the cache;
 170         -- we jolly well ought to get a 'hit' there!
 171         -- So the 'Imported' part of this call is not relevant.
 172         -- Unclean; but since these two are the only place this happens
 173         -- I can't work up the energy to do it more beautifully
 174     mkImportedGlobalFromRdrName tname                   `thenRn` \ tname' ->
 175     mkImportedGlobalFromRdrName dname                   `thenRn` \ dname' ->
 176     mapRn mkImportedGlobalFromRdrName snames            `thenRn` \ snames' ->
 177
 178         -- Tyvars scope over bindings and context
 179     bindTyVarsFV2Rn cls_doc tyvars              ( \ clas_tyvar_names tyvars' ->
 180
 181         -- Check the superclasses
 182     rnContext cls_doc context                   `thenRn` \ (context', cxt_fvs) ->
 183
 184         -- Check the signatures
 185     let
 186             -- First process the class op sigs, then the fixity sigs.
 187           (op_sigs, non_op_sigs) = partition isClassOpSig sigs
 188           (fix_sigs, non_sigs)   = partition isFixitySig  non_op_sigs
 189     in
 190     checkDupOrQualNames sig_doc sig_rdr_names_w_locs    `thenRn_`
 191     mapFvRn (rn_op cname' clas_tyvar_names) op_sigs
 192     `thenRn` \ (sigs', sig_fvs) ->
 193     mapRn_  (unknownSigErr) non_sigs                    `thenRn_`
 194     let
 195      binders = mkNameSet [ nm | (ClassOpSig nm _ _ _) <- sigs' ]
 196     in
 197     renameSigs False binders lookupOccRn fix_sigs
 198     `thenRn` \ (fixs', fix_fvs) ->
 199
 200         -- Check the methods
 201     checkDupOrQualNames meth_doc meth_rdr_names_w_locs  `thenRn_`
 202     rnMethodBinds mbinds
 203     `thenRn` \ (mbinds', meth_fvs) ->
 204
 205         -- Typechecker is responsible for checking that we only
 206         -- give default-method bindings for things in this class.
 207         -- The renamer *could* check this for class decls, but can't
 208         -- for instance decls.
 209
 210     ASSERT(isNoClassPragmas pragmas)
 211     returnRn (TyClD (ClassDecl context' cname' tyvars' (fixs' ++ sigs') mbinds'
 212                                NoClassPragmas tname' dname' snames' src_loc),
 213               sig_fvs   `plusFV`
 214               fix_fvs   `plusFV`
 215               cxt_fvs   `plusFV`
 216               meth_fvs
 217              )
 218     )
 219   where
 220     cls_doc  = text "the declaration for class"         <+> ppr cname
 221     sig_doc  = text "the signatures for class"          <+> ppr cname
 222     meth_doc = text "the default-methods for class"     <+> ppr cname
 223
 224     sig_rdr_names_w_locs  = [(op,locn) | ClassOpSig op _ _ locn <- sigs]
 225     meth_rdr_names_w_locs = bagToList (collectMonoBinders mbinds)
 226     meth_rdr_names        = map fst meth_rdr_names_w_locs
 227
 228     rn_op clas clas_tyvars sig@(ClassOpSig op maybe_dm ty locn)
 229       = pushSrcLocRn locn $
 230         lookupBndrRn op                         `thenRn` \ op_name ->
 231
 232                 -- Check the signature
 233         rnHsSigType (quotes (ppr op)) ty        `thenRn` \ (new_ty, op_ty_fvs)  ->
 234         let
 235             check_in_op_ty clas_tyvar =
 236                  checkRn (clas_tyvar `elemNameSet` op_ty_fvs)
 237                          (classTyVarNotInOpTyErr clas_tyvar sig)
 238         in
 239         mapRn_ check_in_op_ty clas_tyvars                `thenRn_`
 240
 241                 -- Make the default-method name
 242         getModeRn                                       `thenRn` \ mode ->
 243         (case (mode, maybe_dm) of
 244             (SourceMode, _)
 245                 | op `elem` meth_rdr_names
 246                 -> -- Source class decl with an explicit method decl
 247                    newImplicitBinder (mkDefaultMethodOcc (rdrNameOcc op)) locn
 248                    `thenRn` \ dm_name ->
 249                    returnRn (Just dm_name, emptyFVs)
 250
 251                 | otherwise
 252                 ->      -- Source class dec, no explicit method decl
 253                         returnRn (Nothing, emptyFVs)
 254
 255             (InterfaceMode, Just dm_rdr_name)
 256                 ->      -- Imported class that has a default method decl
 257                         -- See comments with tname, snames, above
 258                     lookupImplicitOccRn dm_rdr_name     `thenRn` \ dm_name ->
 259                     returnRn (Just dm_name, unitFV dm_name)
 260                             -- An imported class decl mentions, rather than defines,
 261                             -- the default method, so we must arrange to pull it in
 262
 263             (InterfaceMode, Nothing)
 264                         -- Imported class with no default metho
 265                 ->      returnRn (Nothing, emptyFVs)
 266         )                                               `thenRn` \ (maybe_dm_name, dm_fvs) ->
 267
 268         returnRn (ClassOpSig op_name maybe_dm_name new_ty locn, op_ty_fvs `plusFV` dm_fvs)
 269 \end{code}
 270
 271
 272 %*********************************************************
 273 %*                                                      *
 274 \subsection{Instance declarations}
 275 %*                                                      *
 276 %*********************************************************
 277
 278 \begin{code}
 279 rnDecl (InstD (InstDecl inst_ty mbinds uprags dfun_rdr_name src_loc))
 280   = pushSrcLocRn src_loc $
 281     rnHsSigType (text "an instance decl") inst_ty `thenRn` \ (inst_ty', inst_fvs) ->
 282     let
 283         inst_tyvars = case inst_ty' of
 284                         HsForAllTy (Just inst_tyvars) _ _ -> inst_tyvars
 285                         other                             -> []
 286         -- (Slightly strangely) the forall-d tyvars scope over
 287         -- the method bindings too
 288     in
 289
 290         -- Rename the bindings
 291         -- NB meth_names can be qualified!
 292     checkDupNames meth_doc meth_names           `thenRn_`
 293     extendTyVarEnvFVRn inst_tyvars (
 294         rnMethodBinds mbinds
 295     )                                           `thenRn` \ (mbinds', meth_fvs) ->
 296     let
 297         binders = mkNameSet (map fst (bagToList (collectMonoBinders mbinds')))
 298
 299         -- Delete sigs (&report) sigs that aren't allowed inside an
 300         -- instance decl:
 301         --
 302         --  + type signatures
 303         --  + fixity decls
 304         --
 305         (ok_sigs, not_ok_idecl_sigs) = partition okInInstDecl uprags
 306
 307         okInInstDecl (FixSig _)  = False
 308         okInInstDecl (Sig _ _ _) = False
 309         okInInstDecl _           = True
 310
 311     in
 312       -- You can't have fixity decls & type signatures
 313       -- within an instance declaration.
 314     mapRn_ unknownSigErr not_ok_idecl_sigs       `thenRn_`
 315
 316         -- Rename the prags and signatures.
 317         -- Note that the type variables are not in scope here,
 318         -- so that      instance Eq a => Eq (T a) where
 319         --                      {-# SPECIALISE instance Eq a => Eq (T [a]) #-}
 320         -- works OK.
 321     renameSigs False binders lookupOccRn ok_sigs `thenRn` \ (new_uprags, prag_fvs) ->
 322
 323     getModeRn           `thenRn` \ mode ->
 324     (case mode of
 325         InterfaceMode -> lookupImplicitOccRn dfun_rdr_name      `thenRn` \ dfun_name ->
 326                          returnRn (dfun_name, unitFV dfun_name)
 327         SourceMode    -> newDFunName (getDFunKey inst_ty') src_loc
 328                          `thenRn` \ dfun_name ->
 329                          returnRn (dfun_name, emptyFVs)
 330     )
 331     `thenRn` \ (dfun_name, dfun_fv) ->
 332
 333     -- The typechecker checks that all the bindings are for the right class.
 334     returnRn (InstD (InstDecl inst_ty' mbinds' new_uprags dfun_name src_loc),
 335               inst_fvs `plusFV` meth_fvs `plusFV` prag_fvs `plusFV` dfun_fv)
 336   where
 337     meth_doc = text "the bindings in an instance declaration"
 338     meth_names   = bagToList (collectMonoBinders mbinds)
 339 \end{code}
 340
 341 %*********************************************************
 342 %*                                                      *
 343 \subsection{Default declarations}
 344 %*                                                      *
 345 %*********************************************************
 346
 347 \begin{code}
 348 rnDecl (DefD (DefaultDecl tys src_loc))
 349   = pushSrcLocRn src_loc $
 350     rnHsTypes doc_str tys               `thenRn` \ (tys', fvs) ->
 351     returnRn (DefD (DefaultDecl tys' src_loc), fvs)
 352   where
 353     doc_str = text "a `default' declaration"
 354 \end{code}
 355
 356 %*********************************************************
 357 %*                                                      *
 358 \subsection{Foreign declarations}
 359 %*                                                      *
 360 %*********************************************************
 361
 362 \begin{code}
 363 rnDecl (ForD (ForeignDecl name imp_exp ty ext_nm cconv src_loc))
 364   = pushSrcLocRn src_loc $
 365     lookupBndrRn name                   `thenRn` \ name' ->
 366     let
 367         fvs1 = case imp_exp of
 368                 FoImport _ | not isDyn  -> emptyFVs
 369                 FoLabel                 -> emptyFVs
 370                 FoExport   | isDyn      -> mkNameSet [makeStablePtr_NAME,
 371                                                       deRefStablePtr_NAME,
 372                                                       bindIO_NAME]
 373                 _ -> emptyFVs
 374     in
 375     rnHsSigType fo_decl_msg ty                  `thenRn` \ (ty', fvs2) ->
 376     returnRn (ForD (ForeignDecl name' imp_exp ty' ext_nm cconv src_loc),
 377               fvs1 `plusFV` fvs2)
 378  where
 379   fo_decl_msg = ptext SLIT("a foreign declaration")
 380   isDyn       = isDynamic ext_nm
 381 \end{code}
 382
 383 %*********************************************************
 384 %*                                                      *
 385 \subsection{Rules}
 386 %*                                                      *
 387 %*********************************************************
 388
 389 \begin{code}
 390 rnDecl (RuleD (IfaceRuleDecl var body src_loc))
 391   = pushSrcLocRn src_loc                        $
 392     lookupOccRn var             `thenRn` \ var' ->
 393     rnRuleBody body             `thenRn` \ (body', fvs) ->
 394     returnRn (RuleD (IfaceRuleDecl var' body' src_loc), fvs `addOneFV` var')
 395
 396 rnDecl (RuleD (RuleDecl rule_name tvs vars lhs rhs src_loc))
 397   = ASSERT( null tvs )
 398     pushSrcLocRn src_loc                        $
 399
 400     bindTyVarsFV2Rn doc (map UserTyVar sig_tvs) $ \ sig_tvs' _ ->
 401     bindLocalsFVRn doc (map get_var vars)       $ \ ids ->
 402     mapFvRn rn_var (vars `zip` ids)             `thenRn` \ (vars', fv_vars) ->
 403
 404     rnExpr lhs                                  `thenRn` \ (lhs', fv_lhs) ->
 405     rnExpr rhs                                  `thenRn` \ (rhs', fv_rhs) ->
 406     checkRn (validRuleLhs ids lhs')
 407             (badRuleLhsErr rule_name lhs')      `thenRn_`
 408     let
 409         bad_vars = [var | var <- ids, not (var `elemNameSet` fv_lhs)]
 410     in
 411     mapRn (addErrRn . badRuleVar rule_name) bad_vars    `thenRn_`
 412     returnRn (RuleD (RuleDecl rule_name sig_tvs' vars' lhs' rhs' src_loc),
 413               fv_vars `plusFV` fv_lhs `plusFV` fv_rhs)
 414   where
 415     doc = text "the transformation rule" <+> ptext rule_name
 416     sig_tvs = extractRuleBndrsTyVars vars
 417
 418     get_var (RuleBndr v)      = v
 419     get_var (RuleBndrSig v _) = v
 420
 421     rn_var (RuleBndr v, id)      = returnRn (RuleBndr id, emptyFVs)
 422     rn_var (RuleBndrSig v t, id) = rnHsType doc t       `thenRn` \ (t', fvs) ->
 423                                    returnRn (RuleBndrSig id t', fvs)
 424 \end{code}
 425
 426
 427 %*********************************************************
 428 %*                                                      *
 429 \subsection{Support code for type/data declarations}
 430 %*                                                      *
 431 %*********************************************************
 432
 433 \begin{code}
 434 rnDerivs :: Maybe [RdrName] -> RnMS (Maybe [Name], FreeVars)
 435
 436 rnDerivs Nothing -- derivs not specified
 437   = returnRn (Nothing, emptyFVs)
 438
 439 rnDerivs (Just clss)
 440   = mapRn do_one clss   `thenRn` \ clss' ->
 441     returnRn (Just clss', mkNameSet clss')
 442   where
 443     do_one cls = lookupOccRn cls        `thenRn` \ clas_name ->
 444                  checkRn (getUnique clas_name `elem` derivableClassKeys)
 445                          (derivingNonStdClassErr clas_name)     `thenRn_`
 446                  returnRn clas_name
 447 \end{code}
 448
 449 \begin{code}
 450 conDeclName :: RdrNameConDecl -> (RdrName, SrcLoc)
 451 conDeclName (ConDecl n _ _ _ l) = (n,l)
 452
 453 rnConDecl :: RdrNameConDecl -> RnMS (RenamedConDecl, FreeVars)
 454 rnConDecl (ConDecl name tvs cxt details locn)
 455   = pushSrcLocRn locn $
 456     checkConName name                   `thenRn_`
 457     lookupBndrRn name                   `thenRn` \ new_name ->
 458     bindTyVarsFVRn doc tvs              $ \ new_tyvars ->
 459     rnContext doc cxt                   `thenRn` \ (new_context, cxt_fvs) ->
 460     rnConDetails doc locn details       `thenRn` \ (new_details, det_fvs) ->
 461     returnRn (ConDecl new_name new_tyvars new_context new_details locn,
 462               cxt_fvs `plusFV` det_fvs)
 463   where
 464     doc = text "the definition of data constructor" <+> quotes (ppr name)
 465
 466 rnConDetails doc locn (VanillaCon tys)
 467   = mapFvRn (rnBangTy doc) tys  `thenRn` \ (new_tys, fvs)  ->
 468     returnRn (VanillaCon new_tys, fvs)
 469
 470 rnConDetails doc locn (InfixCon ty1 ty2)
 471   = rnBangTy doc ty1            `thenRn` \ (new_ty1, fvs1) ->
 472     rnBangTy doc ty2            `thenRn` \ (new_ty2, fvs2) ->
 473     returnRn (InfixCon new_ty1 new_ty2, fvs1 `plusFV` fvs2)
 474
 475 rnConDetails doc locn (NewCon ty mb_field)
 476   = rnHsType doc ty                     `thenRn` \ (new_ty, fvs) ->
 477     rn_field mb_field                   `thenRn` \ new_mb_field  ->
 478     returnRn (NewCon new_ty new_mb_field, fvs)
 479   where
 480     rn_field Nothing  = returnRn Nothing
 481     rn_field (Just f) =
 482        lookupBndrRn f       `thenRn` \ new_f ->
 483        returnRn (Just new_f)
 484
 485 rnConDetails doc locn (RecCon fields)
 486   = checkDupOrQualNames doc field_names `thenRn_`
 487     mapFvRn (rnField doc) fields        `thenRn` \ (new_fields, fvs) ->
 488     returnRn (RecCon new_fields, fvs)
 489   where
 490     field_names = [(fld, locn) | (flds, _) <- fields, fld <- flds]
 491
 492 rnField doc (names, ty)
 493   = mapRn lookupBndrRn names    `thenRn` \ new_names ->
 494     rnBangTy doc ty             `thenRn` \ (new_ty, fvs) ->
 495     returnRn ((new_names, new_ty), fvs)
 496
 497 rnBangTy doc (Banged ty)
 498   = rnHsType doc ty             `thenRn` \ (new_ty, fvs) ->
 499     returnRn (Banged new_ty, fvs)
 500
 501 rnBangTy doc (Unbanged ty)
 502   = rnHsType doc ty             `thenRn` \ (new_ty, fvs) ->
 503     returnRn (Unbanged new_ty, fvs)
 504
 505 rnBangTy doc (Unpacked ty)
 506   = rnHsType doc ty             `thenRn` \ (new_ty, fvs) ->
 507     returnRn (Unpacked new_ty, fvs)
 508
 509 -- This data decl will parse OK
 510 --      data T = a Int
 511 -- treating "a" as the constructor.
 512 -- It is really hard to make the parser spot this malformation.
 513 -- So the renamer has to check that the constructor is legal
 514 --
 515 -- We can get an operator as the constructor, even in the prefix form:
 516 --      data T = :% Int Int
 517 -- from interface files, which always print in prefix form
 518
 519 checkConName name
 520   = checkRn (isRdrDataCon name)
 521             (badDataCon name)
 522 \end{code}
 523
 524
 525 %*********************************************************
 526 %*                                                      *
 527 \subsection{Support code to rename types}
 528 %*                                                      *
 529 %*********************************************************
 530
 531 \begin{code}
 532 rnHsSigType :: SDoc -> RdrNameHsType -> RnMS (RenamedHsType, FreeVars)
 533         -- rnHsSigType is used for source-language type signatures,
 534         -- which use *implicit* universal quantification.
 535 rnHsSigType doc_str ty
 536   = rnHsType (text "the type signature for" <+> doc_str) ty
 537
 538 rnForAll doc forall_tyvars ctxt ty
 539   = bindTyVarsFVRn doc forall_tyvars    $ \ new_tyvars ->
 540     rnContext doc ctxt                  `thenRn` \ (new_ctxt, cxt_fvs) ->
 541     rnHsType doc ty                     `thenRn` \ (new_ty, ty_fvs) ->
 542     returnRn (mkHsForAllTy new_tyvars new_ctxt new_ty,
 543               cxt_fvs `plusFV` ty_fvs)
 544
 545 -- Check that each constraint mentions at least one of the forall'd type variables
 546 -- Since the forall'd type variables are a subset of the free tyvars
 547 -- of the tau-type part, this guarantees that every constraint mentions
 548 -- at least one of the free tyvars in ty
 549 checkConstraints explicit_forall doc forall_tyvars ctxt ty
 550    = mapRn check ctxt                   `thenRn` \ maybe_ctxt' ->
 551      returnRn (catMaybes maybe_ctxt')
 552             -- Remove problem ones, to avoid duplicate error message.
 553    where
 554      check ct@(_,tys)
 555         | forall_mentioned = returnRn (Just ct)
 556         | otherwise        = addErrRn (ctxtErr explicit_forall doc forall_tyvars ct ty)
 557                              `thenRn_` returnRn Nothing
 558         where
 559           forall_mentioned = foldr ((||) . any (`elem` forall_tyvars) . extractHsTyRdrTyVars)
 560                              False
 561                              tys
 562
 563 rnHsType :: SDoc -> RdrNameHsType -> RnMS (RenamedHsType, FreeVars)
 564
 565 rnHsType doc (HsForAllTy Nothing ctxt ty)
 566         -- From source code (no kinds on tyvars)
 567         -- Given the signature  C => T  we universally quantify
 568         -- over FV(T) \ {in-scope-tyvars}
 569   = getLocalNameEnv             `thenRn` \ name_env ->
 570     let
 571         mentioned_in_tau = extractHsTyRdrTyVars ty
 572         forall_tyvars    = filter (not . (`elemFM` name_env)) mentioned_in_tau
 573     in
 574     checkConstraints False doc forall_tyvars ctxt ty    `thenRn` \ ctxt' ->
 575     rnForAll doc (map UserTyVar forall_tyvars) ctxt' ty
 576
 577 rnHsType doc (HsForAllTy (Just forall_tyvars) ctxt tau)
 578         -- Explicit quantification.
 579         -- Check that the forall'd tyvars are a subset of the
 580         -- free tyvars in the tau-type part
 581         -- That's only a warning... unless the tyvar is constrained by a
 582         -- context in which case it's an error
 583   = let
 584         mentioned_in_tau  = extractHsTyRdrTyVars tau
 585         mentioned_in_ctxt = nub [tv | (_,tys) <- ctxt,
 586                                       ty <- tys,
 587                                       tv <- extractHsTyRdrTyVars ty]
 588
 589         dubious_guys          = filter (`notElem` mentioned_in_tau) forall_tyvar_names
 590                 -- dubious = explicitly quantified but not mentioned in tau type
 591
 592         (bad_guys, warn_guys) = partition (`elem` mentioned_in_ctxt) dubious_guys
 593                 -- bad  = explicitly quantified and constrained, but not mentioned in tau
 594                 -- warn = explicitly quantified but not mentioned in ctxt or tau
 595
 596         forall_tyvar_names    = map getTyVarName forall_tyvars
 597     in
 598     mapRn_ (forAllErr doc tau) bad_guys                         `thenRn_`
 599     mapRn_ (forAllWarn doc tau) warn_guys                       `thenRn_`
 600     checkConstraints True doc forall_tyvar_names ctxt tau       `thenRn` \ ctxt' ->
 601     rnForAll doc forall_tyvars ctxt' tau
 602
 603 rnHsType doc (MonoTyVar tyvar)
 604   = lookupOccRn tyvar           `thenRn` \ tyvar' ->
 605     returnRn (MonoTyVar tyvar', unitFV tyvar')
 606
 607 rnHsType doc (MonoFunTy ty1 ty2)
 608   = rnHsType doc ty1    `thenRn` \ (ty1', fvs1) ->
 609     rnHsType doc ty2    `thenRn` \ (ty2', fvs2) ->
 610     returnRn (MonoFunTy ty1' ty2', fvs1 `plusFV` fvs2)
 611
 612 rnHsType doc (MonoListTy ty)
 613   = rnHsType doc ty                             `thenRn` \ (ty', fvs) ->
 614     returnRn (MonoListTy ty', fvs `addOneFV` listTyCon_name)
 615
 616 rnHsType doc (MonoTupleTy tys boxed)
 617   = rnHsTypes doc tys                   `thenRn` \ (tys', fvs) ->
 618     returnRn (MonoTupleTy tys' boxed, fvs `addOneFV` tup_con_name)
 619   where
 620     tup_con_name = tupleTyCon_name boxed (length tys)
 621
 622 rnHsType doc (MonoTyApp ty1 ty2)
 623   = rnHsType doc ty1            `thenRn` \ (ty1', fvs1) ->
 624     rnHsType doc ty2            `thenRn` \ (ty2', fvs2) ->
 625     returnRn (MonoTyApp ty1' ty2', fvs1 `plusFV` fvs2)
 626
 627 rnHsType doc (MonoDictTy clas tys)
 628   = lookupOccRn clas            `thenRn` \ clas' ->
 629     rnHsTypes doc tys           `thenRn` \ (tys', fvs) ->
 630     returnRn (MonoDictTy clas' tys', fvs `addOneFV` clas')
 631
 632 rnHsType doc (MonoUsgTy usg ty)
 633   = rnHsType doc ty             `thenRn` \ (ty', fvs) ->
 634     returnRn (MonoUsgTy usg ty', fvs)
 635
 636 rnHsTypes doc tys = mapFvRn (rnHsType doc) tys
 637 \end{code}
 638
 639
 640 \begin{code}
 641 rnContext :: SDoc -> RdrNameContext -> RnMS (RenamedContext, FreeVars)
 642
 643 rnContext doc ctxt
 644   = mapAndUnzipRn rn_ctxt ctxt          `thenRn` \ (theta, fvs_s) ->
 645     let
 646         (_, dup_asserts) = removeDups cmp_assert theta
 647     in
 648         -- Check for duplicate assertions
 649         -- If this isn't an error, then it ought to be:
 650     mapRn_ (addWarnRn . dupClassAssertWarn theta) dup_asserts   `thenRn_`
 651
 652     returnRn (theta, plusFVs fvs_s)
 653   where
 654     rn_ctxt (clas, tys)
 655       = lookupOccRn clas                `thenRn` \ clas_name ->
 656         rnHsTypes doc tys               `thenRn` \ (tys', fvs) ->
 657         returnRn ((clas_name, tys'), fvs `addOneFV` clas_name)
 658
 659     cmp_assert (c1,tys1) (c2,tys2)
 660       = (c1 `compare` c2) `thenCmp` (cmpHsTypes compare tys1 tys2)
 661 \end{code}
 662
 663
 664 %*********************************************************
 665 %*                                                       *
 666 \subsection{IdInfo}
 667 %*                                                       *
 668 %*********************************************************
 669
 670 \begin{code}
 671 rnIdInfo (HsStrictness str) = returnRn (HsStrictness str, emptyFVs)
 672
 673 rnIdInfo (HsWorker worker)
 674   = lookupOccRn worker                  `thenRn` \ worker' ->
 675     returnRn (HsWorker worker', unitFV worker')
 676
 677 rnIdInfo (HsUnfold inline (Just expr))  = rnCoreExpr expr `thenRn` \ (expr', fvs) ->
 678                                           returnRn (HsUnfold inline (Just expr'), fvs)
 679 rnIdInfo (HsUnfold inline Nothing)      = returnRn (HsUnfold inline Nothing, emptyFVs)
 680 rnIdInfo (HsArity arity)        = returnRn (HsArity arity, emptyFVs)
 681 rnIdInfo (HsUpdate update)      = returnRn (HsUpdate update, emptyFVs)
 682 rnIdInfo (HsNoCafRefs)          = returnRn (HsNoCafRefs, emptyFVs)
 683 rnIdInfo (HsCprInfo cpr_info)   = returnRn (HsCprInfo cpr_info, emptyFVs)
 684 rnIdInfo (HsSpecialise rule_body) = rnRuleBody rule_body
 685                                     `thenRn` \ (rule_body', fvs) ->
 686                                     returnRn (HsSpecialise rule_body', fvs)
 687
 688 rnRuleBody (UfRuleBody str vars args rhs)
 689   = rnCoreBndrs vars            $ \ vars' ->
 690     mapFvRn rnCoreExpr args     `thenRn` \ (args', fvs1) ->
 691     rnCoreExpr rhs              `thenRn` \ (rhs',  fvs2) ->
 692     returnRn (UfRuleBody str vars' args' rhs', fvs1 `plusFV` fvs2)
 693 \end{code}
 694
 695 @UfCore@ expressions.
 696
 697 \begin{code}
 698 rnCoreExpr (UfType ty)
 699   = rnHsType (text "unfolding type") ty `thenRn` \ (ty', fvs) ->
 700     returnRn (UfType ty', fvs)
 701
 702 rnCoreExpr (UfVar v)
 703   = lookupOccRn v       `thenRn` \ v' ->
 704     returnRn (UfVar v', unitFV v')
 705
 706 rnCoreExpr (UfCon con args)
 707   = rnUfCon con                 `thenRn` \ (con', fvs1) ->
 708     mapFvRn rnCoreExpr args     `thenRn` \ (args', fvs2) ->
 709     returnRn (UfCon con' args', fvs1 `plusFV` fvs2)
 710
 711 rnCoreExpr (UfTuple con args)
 712   = lookupOccRn con             `thenRn` \ con' ->
 713     mapFvRn rnCoreExpr args     `thenRn` \ (args', fvs) ->
 714     returnRn (UfTuple con' args', fvs `addOneFV` con')
 715
 716 rnCoreExpr (UfApp fun arg)
 717   = rnCoreExpr fun              `thenRn` \ (fun', fv1) ->
 718     rnCoreExpr arg              `thenRn` \ (arg', fv2) ->
 719     returnRn (UfApp fun' arg', fv1 `plusFV` fv2)
 720
 721 rnCoreExpr (UfCase scrut bndr alts)
 722   = rnCoreExpr scrut                    `thenRn` \ (scrut', fvs1) ->
 723     bindCoreLocalFVRn bndr              ( \ bndr' ->
 724         mapFvRn rnCoreAlt alts          `thenRn` \ (alts', fvs2) ->
 725         returnRn (UfCase scrut' bndr' alts', fvs2)
 726     )                                           `thenRn` \ (case', fvs3) ->
 727     returnRn (case', fvs1 `plusFV` fvs3)
 728
 729 rnCoreExpr (UfNote note expr)
 730   = rnNote note                 `thenRn` \ (note', fvs1) ->
 731     rnCoreExpr expr             `thenRn` \ (expr', fvs2) ->
 732     returnRn  (UfNote note' expr', fvs1 `plusFV` fvs2)
 733
 734 rnCoreExpr (UfLam bndr body)
 735   = rnCoreBndr bndr             $ \ bndr' ->
 736     rnCoreExpr body             `thenRn` \ (body', fvs) ->
 737     returnRn (UfLam bndr' body', fvs)
 738
 739 rnCoreExpr (UfLet (UfNonRec bndr rhs) body)
 740   = rnCoreExpr rhs              `thenRn` \ (rhs', fvs1) ->
 741     rnCoreBndr bndr             ( \ bndr' ->
 742         rnCoreExpr body         `thenRn` \ (body', fvs2) ->
 743         returnRn (UfLet (UfNonRec bndr' rhs') body', fvs2)
 744     )                           `thenRn` \ (result, fvs3) ->
 745     returnRn (result, fvs1 `plusFV` fvs3)
 746
 747 rnCoreExpr (UfLet (UfRec pairs) body)
 748   = rnCoreBndrs bndrs           $ \ bndrs' ->
 749     mapFvRn rnCoreExpr rhss     `thenRn` \ (rhss', fvs1) ->
 750     rnCoreExpr body             `thenRn` \ (body', fvs2) ->
 751     returnRn (UfLet (UfRec (bndrs' `zip` rhss')) body', fvs1 `plusFV` fvs2)
 752   where
 753     (bndrs, rhss) = unzip pairs
 754 \end{code}
 755
 756 \begin{code}
 757 rnCoreBndr (UfValBinder name ty) thing_inside
 758   = rnHsType doc ty             `thenRn` \ (ty', fvs1) ->
 759     bindCoreLocalFVRn name      ( \ name' ->
 760             thing_inside (UfValBinder name' ty')
 761     )                           `thenRn` \ (result, fvs2) ->
 762     returnRn (result, fvs1 `plusFV` fvs2)
 763   where
 764     doc = text "unfolding id"
 765
 766 rnCoreBndr (UfTyBinder name kind) thing_inside
 767   = bindCoreLocalFVRn name              $ \ name' ->
 768     thing_inside (UfTyBinder name' kind)
 769
 770 rnCoreBndrs []     thing_inside = thing_inside []
 771 rnCoreBndrs (b:bs) thing_inside = rnCoreBndr b          $ \ name' ->
 772                                   rnCoreBndrs bs        $ \ names' ->
 773                                   thing_inside (name':names')
 774 \end{code}
 775
 776 \begin{code}
 777 rnCoreAlt (con, bndrs, rhs)
 778   = rnUfCon con                         `thenRn` \ (con', fvs1) ->
 779     bindCoreLocalsFVRn bndrs            ( \ bndrs' ->
 780         rnCoreExpr rhs                  `thenRn` \ (rhs', fvs2) ->
 781         returnRn ((con', bndrs', rhs'), fvs2)
 782     )                                   `thenRn` \ (result, fvs3) ->
 783     returnRn (result, fvs1 `plusFV` fvs3)
 784
 785 rnNote (UfCoerce ty)
 786   = rnHsType (text "unfolding coerce") ty       `thenRn` \ (ty', fvs) ->
 787     returnRn (UfCoerce ty', fvs)
 788
 789 rnNote (UfSCC cc)   = returnRn (UfSCC cc, emptyFVs)
 790 rnNote UfInlineCall = returnRn (UfInlineCall, emptyFVs)
 791 rnNote UfInlineMe   = returnRn (UfInlineMe, emptyFVs)
 792
 793
 794 rnUfCon UfDefault
 795   = returnRn (UfDefault, emptyFVs)
 796
 797 rnUfCon (UfDataCon con)
 798   = lookupOccRn con             `thenRn` \ con' ->
 799     returnRn (UfDataCon con', unitFV con')
 800
 801 rnUfCon (UfLitCon lit)
 802   = returnRn (UfLitCon lit, emptyFVs)
 803
 804 rnUfCon (UfLitLitCon lit ty)
 805   = rnHsType (text "litlit") ty         `thenRn` \ (ty', fvs) ->
 806     returnRn (UfLitLitCon lit ty', fvs)
 807
 808 rnUfCon (UfPrimOp op)
 809   = lookupOccRn op              `thenRn` \ op' ->
 810     returnRn (UfPrimOp op', emptyFVs)
 811
 812 rnUfCon (UfCCallOp str is_dyn casm gc)
 813   = returnRn (UfCCallOp str is_dyn casm gc, emptyFVs)
 814 \end{code}
 815
 816 %*********************************************************
 817 %*                                                       *
 818 \subsection{Rule shapes}
 819 %*                                                       *
 820 %*********************************************************
 821
 822 Check the shape of a transformation rule LHS.  Currently
 823 we only allow LHSs of the form @(f e1 .. en)@, where @f@ is
 824 not one of the @forall@'d variables.
 825
 826 \begin{code}
 827 validRuleLhs foralls lhs
 828   = check lhs
 829   where
 830     check (HsApp e1 e2)                   = check e1
 831     check (HsVar v) | v `notElem` foralls = True
 832     check other                           = False
 833 \end{code}
 834
 835
 836 %*********************************************************
 837 %*                                                       *
 838 \subsection{Errors}
 839 %*                                                       *
 840 %*********************************************************
 841
 842 \begin{code}
 843 derivingNonStdClassErr clas
 844   = hsep [ptext SLIT("non-standard class"), ppr clas, ptext SLIT("in deriving clause")]
 845
 846 classTyVarNotInOpTyErr clas_tyvar sig
 847   = hang (hsep [ptext SLIT("Class type variable"),
 848                        quotes (ppr clas_tyvar),
 849                        ptext SLIT("does not appear in method signature")])
 850          4 (ppr sig)
 851
 852 dupClassAssertWarn ctxt (assertion : dups)
 853   = sep [hsep [ptext SLIT("Duplicate class assertion"),
 854                quotes (pprClassAssertion assertion),
 855                ptext SLIT("in the context:")],
 856          nest 4 (pprContext ctxt <+> ptext SLIT("..."))]
 857
 858 badDataCon name
 859    = hsep [ptext SLIT("Illegal data constructor name"), quotes (ppr name)]
 860
 861 forAllWarn doc ty tyvar
 862   | not opt_WarnUnusedMatches = returnRn ()
 863   | otherwise
 864   = getModeRn           `thenRn` \ mode ->
 865     case mode of {
 866 #ifndef DEBUG
 867         InterfaceMode -> returnRn () ;  -- Don't warn of unused tyvars in interface files
 868                                         -- unless DEBUG is on, in which case it is slightly
 869                                         -- informative.  They can arise from mkRhsTyLam,
 870 #endif                                  -- leading to (say)     f :: forall a b. [b] -> [b]
 871         other ->
 872
 873     addWarnRn (
 874       sep [ptext SLIT("The universally quantified type variable") <+> quotes (ppr tyvar),
 875            nest 4 (ptext SLIT("does not appear in the type") <+> quotes (ppr ty))]
 876       $$
 877       (ptext SLIT("In") <+> doc))
 878     }
 879
 880 forAllErr doc ty tyvar
 881   = addErrRn (
 882       sep [ptext SLIT("The constrained type variable") <+> quotes (ppr tyvar),
 883            nest 4 (ptext SLIT("does not appear in the type") <+> quotes (ppr ty))]
 884       $$
 885       (ptext SLIT("In") <+> doc))
 886
 887 ctxtErr explicit_forall doc tyvars constraint ty
 888   = sep [ptext SLIT("None of the type variable(s) in the constraint")
 889           <+> quotes (pprClassAssertion constraint),
 890          if explicit_forall then
 891            nest 4 (ptext SLIT("is universally quantified (i.e. bound by the forall)"))
 892          else
 893            nest 4 (ptext SLIT("appears in the type") <+> quotes (ppr ty))
 894     ]
 895     $$
 896     (ptext SLIT("In") <+> doc)
 897
 898 badRuleLhsErr name lhs
 899   = sep [ptext SLIT("Rule") <+> ptext name <> colon,
 900          nest 4 (ptext SLIT("Illegal left-hand side:") <+> ppr lhs)]
 901     $$
 902     ptext SLIT("LHS must be of form (f e1 .. en) where f is not forall'd")
 903
 904 badRuleVar name var
 905   = sep [ptext SLIT("Rule") <+> ptext name <> colon,
 906          ptext SLIT("Forall'd variable") <+> quotes (ppr var) <+>
 907                 ptext SLIT("does not appear on left hand side")]
 908 \end{code}