ghc/compiler/simplCore/FloatOut.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[FloatOut]{Float bindings outwards (towards the top level)}
   5
   6 ``Long-distance'' floating of bindings towards the top level.
   7
   8 \begin{code}
   9 module FloatOut ( floatOutwards ) where
  10
  11 #include "HsVersions.h"
  12
  13 import CoreSyn
  14 import CoreUtils        ( mkSCC )
  15
  16 import CmdLineOpts      ( DynFlags, DynFlag(..), FloatOutSwitches(..) )
  17 import ErrUtils         ( dumpIfSet_dyn )
  18 import CostCentre       ( dupifyCC, CostCentre )
  19 import Id               ( Id )
  20 import CoreLint         ( showPass, endPass )
  21 import SetLevels        ( Level(..), LevelledExpr, LevelledBind,
  22                           setLevels, ltMajLvl, ltLvl, isTopLvl )
  23 import UniqSupply       ( UniqSupply )
  24 import List             ( partition )
  25 import Outputable
  26 import Util             ( notNull )
  27 \end{code}
  28
  29         -----------------
  30         Overall game plan
  31         -----------------
  32
  33 The Big Main Idea is:
  34
  35         To float out sub-expressions that can thereby get outside
  36         a non-one-shot value lambda, and hence may be shared.
  37
  38
  39 To achieve this we may need to do two thing:
  40
  41    a) Let-bind the sub-expression:
  42
  43         f (g x)  ==>  let lvl = f (g x) in lvl
  44
  45       Now we can float the binding for 'lvl'.
  46
  47    b) More than that, we may need to abstract wrt a type variable
  48
  49         \x -> ... /\a -> let v = ...a... in ....
  50
  51       Here the binding for v mentions 'a' but not 'x'.  So we
  52       abstract wrt 'a', to give this binding for 'v':
  53
  54             vp = /\a -> ...a...
  55             v  = vp a
  56
  57       Now the binding for vp can float out unimpeded.
  58       I can't remember why this case seemed important enough to
  59       deal with, but I certainly found cases where important floats
  60       didn't happen if we did not abstract wrt tyvars.
  61
  62 With this in mind we can also achieve another goal: lambda lifting.
  63 We can make an arbitrary (function) binding float to top level by
  64 abstracting wrt *all* local variables, not just type variables, leaving
  65 a binding that can be floated right to top level.  Whether or not this
  66 happens is controlled by a flag.
  67
  68
  69 Random comments
  70 ~~~~~~~~~~~~~~~
  71
  72 At the moment we never float a binding out to between two adjacent
  73 lambdas.  For example:
  74
  75 @
  76         \x y -> let t = x+x in ...
  77 ===>
  78         \x -> let t = x+x in \y -> ...
  79 @
  80 Reason: this is less efficient in the case where the original lambda
  81 is never partially applied.
  82
  83 But there's a case I've seen where this might not be true.  Consider:
  84 @
  85 elEm2 x ys
  86   = elem' x ys
  87   where
  88     elem' _ []  = False
  89     elem' x (y:ys)      = x==y || elem' x ys
  90 @
  91 It turns out that this generates a subexpression of the form
  92 @
  93         \deq x ys -> let eq = eqFromEqDict deq in ...
  94 @
  95 vwhich might usefully be separated to
  96 @
  97         \deq -> let eq = eqFromEqDict deq in \xy -> ...
  98 @
  99 Well, maybe.  We don't do this at the moment.
 100
 101 \begin{code}
 102 type FloatBind     = (Level, CoreBind)
 103 type FloatBinds    = [FloatBind]
 104 \end{code}
 105
 106 %************************************************************************
 107 %*                                                                      *
 108 \subsection[floatOutwards]{@floatOutwards@: let-floating interface function}
 109 %*                                                                      *
 110 %************************************************************************
 111
 112 \begin{code}
 113 floatOutwards :: DynFlags
 114               -> FloatOutSwitches
 115               -> UniqSupply
 116               -> [CoreBind] -> IO [CoreBind]
 117
 118 floatOutwards dflags float_sws us pgm
 119   = do {
 120         showPass dflags float_msg ;
 121
 122         let { annotated_w_levels = setLevels float_sws pgm us ;
 123               (fss, binds_s')    = unzip (map floatTopBind annotated_w_levels)
 124             } ;
 125
 126         dumpIfSet_dyn dflags Opt_D_verbose_core2core "Levels added:"
 127                   (vcat (map ppr annotated_w_levels));
 128
 129         let { (tlets, ntlets, lams) = get_stats (sum_stats fss) };
 130
 131         dumpIfSet_dyn dflags Opt_D_dump_simpl_stats "FloatOut stats:"
 132                 (hcat [ int tlets,  ptext SLIT(" Lets floated to top level; "),
 133                         int ntlets, ptext SLIT(" Lets floated elsewhere; from "),
 134                         int lams,   ptext SLIT(" Lambda groups")]);
 135
 136         endPass dflags float_msg  Opt_D_verbose_core2core (concat binds_s')
 137                         {- no specific flag for dumping float-out -}
 138     }
 139   where
 140     float_msg = showSDoc (text "Float out" <+> parens (sws float_sws))
 141     sws (FloatOutSw lam const) = pp_not lam   <+> text "lambdas" <> comma <+>
 142                                  pp_not const <+> text "constants"
 143     pp_not True  = empty
 144     pp_not False = text "not"
 145
 146 floatTopBind bind@(NonRec _ _)
 147   = case (floatBind bind) of { (fs, floats, bind') ->
 148     (fs, floatsToBinds floats ++ [bind'])
 149     }
 150
 151 floatTopBind bind@(Rec _)
 152   = case (floatBind bind) of { (fs, floats, Rec pairs') ->
 153     WARN( notNull floats, ppr bind $$ ppr floats )
 154     (fs, [Rec (floatsToBindPairs floats ++ pairs')]) }
 155 \end{code}
 156
 157 %************************************************************************
 158 %*                                                                      *
 159 \subsection[FloatOut-Bind]{Floating in a binding (the business end)}
 160 %*                                                                      *
 161 %************************************************************************
 162
 163
 164 \begin{code}
 165 floatBind :: LevelledBind
 166           -> (FloatStats, FloatBinds, CoreBind)
 167
 168 floatBind (NonRec (TB name level) rhs)
 169   = case (floatRhs level rhs) of { (fs, rhs_floats, rhs') ->
 170     (fs, rhs_floats, NonRec name rhs') }
 171
 172 floatBind bind@(Rec pairs)
 173   = case (unzip3 (map do_pair pairs)) of { (fss, rhss_floats, new_pairs) ->
 174
 175     if not (isTopLvl bind_level) then
 176         -- Standard case
 177         (sum_stats fss, concat rhss_floats, Rec new_pairs)
 178     else
 179         -- In a recursive binding, *destined for* the top level
 180         -- (only), the rhs floats may contain references to the
 181         -- bound things.  For example
 182         --
 183         --      f = ...(let v = ...f... in b) ...
 184         --
 185         --  might get floated to
 186         --
 187         --      v = ...f...
 188         --      f = ... b ...
 189         --
 190         -- and hence we must (pessimistically) make all the floats recursive
 191         -- with the top binding.  Later dependency analysis will unravel it.
 192         --
 193         -- Can't happen on nested bindings because floatRhs will dump
 194         -- the bindings in the RHS (partitionByMajorLevel treats top specially)
 195         (sum_stats fss, [],
 196          Rec (new_pairs ++ floatsToBindPairs (concat rhss_floats)))
 197     }
 198   where
 199     bind_level = getBindLevel bind
 200
 201     do_pair (TB name level, rhs)
 202       = case (floatRhs level rhs) of { (fs, rhs_floats, rhs') ->
 203         (fs, rhs_floats, (name, rhs'))
 204         }
 205 \end{code}
 206
 207 %************************************************************************
 208
 209 \subsection[FloatOut-Expr]{Floating in expressions}
 210 %*                                                                      *
 211 %************************************************************************
 212
 213 \begin{code}
 214 floatExpr, floatRhs
 215          :: Level
 216          -> LevelledExpr
 217          -> (FloatStats, FloatBinds, CoreExpr)
 218
 219 floatRhs lvl arg
 220   = case (floatExpr lvl arg) of { (fsa, floats, arg') ->
 221     case (partitionByMajorLevel lvl floats) of { (floats', heres) ->
 222         -- Dump bindings that aren't going to escape from a lambda
 223         -- This is to avoid floating the x binding out of
 224         --      f (let x = e in b)
 225         -- unnecessarily.  It even causes a bug to do so if we have
 226         --      y = writeArr# a n (let x = e in b)
 227         -- because the y binding is an expr-ok-for-speculation one.
 228         -- [SLPJ Dec 01: I don't understand this last comment;
 229         --               writeArr# is not ok-for-spec because of its side effect]
 230     (fsa, floats', install heres arg') }}
 231
 232 floatExpr _ (Var v)   = (zeroStats, [], Var v)
 233 floatExpr _ (Type ty) = (zeroStats, [], Type ty)
 234 floatExpr _ (Lit lit) = (zeroStats, [], Lit lit)
 235
 236 floatExpr lvl (App e a)
 237   = case (floatExpr lvl e) of { (fse, floats_e, e') ->
 238     case (floatRhs  lvl a) of { (fsa, floats_a, a') ->
 239     (fse `add_stats` fsa, floats_e ++ floats_a, App e' a') }}
 240
 241 floatExpr lvl lam@(Lam _ _)
 242   = let
 243         (bndrs_w_lvls, body) = collectBinders lam
 244         bndrs                = [b | TB b _ <- bndrs_w_lvls]
 245         lvls                 = [l | TB b l <- bndrs_w_lvls]
 246
 247         -- For the all-tyvar case we are prepared to pull
 248         -- the lets out, to implement the float-out-of-big-lambda
 249         -- transform; but otherwise we only float bindings that are
 250         -- going to escape a value lambda.
 251         -- In particular, for one-shot lambdas we don't float things
 252         -- out; we get no saving by so doing.
 253         partition_fn | all isTyVar bndrs = partitionByLevel
 254                      | otherwise         = partitionByMajorLevel
 255     in
 256     case (floatExpr (last lvls) body) of { (fs, floats, body') ->
 257
 258         -- Dump any bindings which absolutely cannot go any further
 259     case (partition_fn (head lvls) floats)      of { (floats', heres) ->
 260
 261     (add_to_stats fs floats', floats', mkLams bndrs (install heres body'))
 262     }}
 263
 264 floatExpr lvl (Note note@(SCC cc) expr)
 265   = case (floatExpr lvl expr)    of { (fs, floating_defns, expr') ->
 266     let
 267         -- Annotate bindings floated outwards past an scc expression
 268         -- with the cc.  We mark that cc as "duplicated", though.
 269
 270         annotated_defns = annotate (dupifyCC cc) floating_defns
 271     in
 272     (fs, annotated_defns, Note note expr') }
 273   where
 274     annotate :: CostCentre -> FloatBinds -> FloatBinds
 275
 276     annotate dupd_cc defn_groups
 277       = [ (level, ann_bind floater) | (level, floater) <- defn_groups ]
 278       where
 279         ann_bind (NonRec binder rhs)
 280           = NonRec binder (mkSCC dupd_cc rhs)
 281
 282         ann_bind (Rec pairs)
 283           = Rec [(binder, mkSCC dupd_cc rhs) | (binder, rhs) <- pairs]
 284
 285 floatExpr lvl (Note InlineMe expr)      -- Other than SCCs
 286   = case floatExpr InlineCtxt expr of { (fs, floating_defns, expr') ->
 287         -- There can be some floating_defns, arising from
 288         -- ordinary lets that were there all the time.  It seems
 289         -- more efficient to test once here than to avoid putting
 290         -- them into floating_defns (which would mean testing for
 291         -- inlineCtxt  at every let)
 292     (fs, [], Note InlineMe (install floating_defns expr')) }    -- See notes in SetLevels
 293
 294 floatExpr lvl (Note note expr)  -- Other than SCCs
 295   = case (floatExpr lvl expr)    of { (fs, floating_defns, expr') ->
 296     (fs, floating_defns, Note note expr') }
 297
 298 floatExpr lvl (Let bind body)
 299   = case (floatBind bind)     of { (fsb, rhs_floats,  bind') ->
 300     case (floatExpr lvl body) of { (fse, body_floats, body') ->
 301 --    if isInlineCtxt lvl then  -- No floating inside an InlineMe
 302 --      ASSERT( null rhs_floats && null body_floats )
 303 --      (add_stats fsb fse, [], Let bind' body')
 304 --    else
 305         (add_stats fsb fse,
 306          rhs_floats ++ [(bind_lvl, bind')] ++ body_floats,
 307          body')
 308     }}
 309   where
 310     bind_lvl = getBindLevel bind
 311
 312 floatExpr lvl (Case scrut (TB case_bndr case_lvl) alts)
 313   = case floatExpr lvl scrut    of { (fse, fde, scrut') ->
 314     case floatList float_alt alts       of { (fsa, fda, alts')  ->
 315     (add_stats fse fsa, fda ++ fde, Case scrut' case_bndr alts')
 316     }}
 317   where
 318         -- Use floatRhs for the alternatives, so that we
 319         -- don't gratuitiously float bindings out of the RHSs
 320     float_alt (con, bs, rhs)
 321         = case (floatRhs case_lvl rhs)  of { (fs, rhs_floats, rhs') ->
 322           (fs, rhs_floats, (con, [b | TB b _ <- bs], rhs')) }
 323
 324
 325 floatList :: (a -> (FloatStats, FloatBinds, b)) -> [a] -> (FloatStats, FloatBinds, [b])
 326 floatList f [] = (zeroStats, [], [])
 327 floatList f (a:as) = case f a            of { (fs_a,  binds_a,  b)  ->
 328                      case floatList f as of { (fs_as, binds_as, bs) ->
 329                      (fs_a `add_stats` fs_as, binds_a ++ binds_as, b:bs) }}
 330 \end{code}
 331
 332 %************************************************************************
 333 %*                                                                      *
 334 \subsection{Utility bits for floating stats}
 335 %*                                                                      *
 336 %************************************************************************
 337
 338 I didn't implement this with unboxed numbers.  I don't want to be too
 339 strict in this stuff, as it is rarely turned on.  (WDP 95/09)
 340
 341 \begin{code}
 342 data FloatStats
 343   = FlS Int  -- Number of top-floats * lambda groups they've been past
 344         Int  -- Number of non-top-floats * lambda groups they've been past
 345         Int  -- Number of lambda (groups) seen
 346
 347 get_stats (FlS a b c) = (a, b, c)
 348
 349 zeroStats = FlS 0 0 0
 350
 351 sum_stats xs = foldr add_stats zeroStats xs
 352
 353 add_stats (FlS a1 b1 c1) (FlS a2 b2 c2)
 354   = FlS (a1 + a2) (b1 + b2) (c1 + c2)
 355
 356 add_to_stats (FlS a b c) floats
 357   = FlS (a + length top_floats) (b + length other_floats) (c + 1)
 358   where
 359     (top_floats, other_floats) = partition to_very_top floats
 360
 361     to_very_top (my_lvl, _) = isTopLvl my_lvl
 362 \end{code}
 363
 364
 365 %************************************************************************
 366 %*                                                                      *
 367 \subsection{Utility bits for floating}
 368 %*                                                                      *
 369 %************************************************************************
 370
 371 \begin{code}
 372 getBindLevel (NonRec (TB _ lvl) _)      = lvl
 373 getBindLevel (Rec (((TB _ lvl), _) : _)) = lvl
 374 \end{code}
 375
 376 \begin{code}
 377 partitionByMajorLevel, partitionByLevel
 378         :: Level                -- Partitioning level
 379
 380         -> FloatBinds           -- Defns to be divided into 2 piles...
 381
 382         -> (FloatBinds, -- Defns  with level strictly < partition level,
 383             FloatBinds) -- The rest
 384
 385
 386 partitionByMajorLevel ctxt_lvl defns
 387   = partition float_further defns
 388   where
 389         -- Float it if we escape a value lambda, or if we get to the top level
 390     float_further (my_lvl, bind) = my_lvl `ltMajLvl` ctxt_lvl || isTopLvl my_lvl
 391         -- The isTopLvl part says that if we can get to the top level, say "yes" anyway
 392         -- This means that
 393         --      x = f e
 394         -- transforms to
 395         --    lvl = e
 396         --    x = f lvl
 397         -- which is as it should be
 398
 399 partitionByLevel ctxt_lvl defns
 400   = partition float_further defns
 401   where
 402     float_further (my_lvl, _) = my_lvl `ltLvl` ctxt_lvl
 403 \end{code}
 404
 405 \begin{code}
 406 floatsToBinds :: FloatBinds -> [CoreBind]
 407 floatsToBinds floats = map snd floats
 408
 409 floatsToBindPairs :: FloatBinds -> [(Id,CoreExpr)]
 410
 411 floatsToBindPairs floats = concat (map mk_pairs floats)
 412   where
 413    mk_pairs (_, Rec pairs)         = pairs
 414    mk_pairs (_, NonRec binder rhs) = [(binder,rhs)]
 415
 416 install :: FloatBinds -> CoreExpr -> CoreExpr
 417
 418 install defn_groups expr
 419   = foldr install_group expr defn_groups
 420   where
 421     install_group (_, defns) body = Let defns body
 422 \end{code}